data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         {\r
  44                 float prey_mass;\r
  45                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  46                 if(cvar("g_healthsize"))\r
  47                         prey_mass *= prey.scale;\r
  48 \r
  49                 string swallow_complain;\r
  50                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  51                         swallow_complain = "You cannot swallow your team mates\n";\r
  52                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  53                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  54                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  55                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  56                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  57                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  58                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  59                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  60 \r
  61                 if(swallow_complain != "")\r
  62                 {\r
  63                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  64                         {\r
  65                                 play2(self, "misc/forbidden.wav");\r
  66                                 sprint(self, swallow_complain);\r
  67                                 self.complain_vore = time + complain_delay_time;\r
  68                         }\r
  69                         return FALSE;\r
  70                 }\r
  71                 return TRUE;\r
  72         }\r
  73         return FALSE;\r
  74 }\r
  75 \r
  76 float Stomach_TeamMates_check(entity pred)\r
  77 {\r
  78         // checks if a player's stomach contains any team mates\r
  79 \r
  80         entity head;\r
  81         if(teams_matter)\r
  82         {\r
  83                 FOR_EACH_PLAYER(head)\r
  84                 {\r
  85                         if(head.predator == pred && head.team == pred.team)\r
  86                                 return TRUE;\r
  87                 }\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_HasLivePrey(entity pred)\r
  93 {\r
  94         entity head;\r
  95         FOR_EACH_PLAYER(head)\r
  96         {\r
  97                 if(head.predator == pred)\r
  98                 if(head.deadflag == DEAD_NO)\r
  99                         return TRUE;\r
 100         }\r
 101         return FALSE;\r
 102 }\r
 103 \r
 104 float Vore_CanLeave()\r
 105 {\r
 106         if(self.stat_eaten)\r
 107         {\r
 108                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 109                         return TRUE;\r
 110                 if(teams_matter && self.team == self.predator.team)\r
 111                         return TRUE;\r
 112                 if(g_rpg && cvar("g_rpg_canleave"))\r
 113                         return TRUE;\r
 114         }\r
 115         return FALSE;\r
 116 }\r
 117 \r
 118 // position the camera properly for prey\r
 119 void Vore_SetPreyPositions(entity pred)\r
 120 {\r
 121         // pred is the predator and head is the prey\r
 122 \r
 123         local entity head;\r
 124         local vector origin_apply;\r
 125 \r
 126         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 127         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 128         FOR_EACH_PLAYER(head)\r
 129         {\r
 130                 if(head.predator == pred)\r
 131                 {\r
 132                         origin_apply_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 133                         origin_apply_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 134                         origin_apply_z = PL_PREY_VIEW_OFS_z;\r
 135 \r
 136                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 137                         head.view_ofs = origin_apply;\r
 138                 }\r
 139         }\r
 140 }\r
 141 \r
 142 .float gurgle_oldstomachload;\r
 143 void Vore_GurgleSound()\r
 144 {\r
 145         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 146         {\r
 147                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 148 \r
 149                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 150                 self.gurgle_oldstomachload = self.stomach_load;\r
 151         }\r
 152 }\r
 153 \r
 154 void Vore_StomachLoad_Apply()\r
 155 {\r
 156         // apply stomach weight that makes you heavier and larger the more you eat\r
 157         // slowing the player is done in cl_physics.qc\r
 158         if(self.classname != "player")\r
 159                 return;\r
 160 \r
 161         entity e;\r
 162         float prey_mass;\r
 163 \r
 164         // apply the stomach capacity of the predator\r
 165         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 166         if(cvar("g_healthsize"))\r
 167                 self.stomach_maxload *= self.scale;\r
 168         self.stomach_maxload = floor(self.stomach_maxload);\r
 169 \r
 170         self.stomach_load = 0; // start from zero\r
 171         FOR_EACH_PLAYER(e)\r
 172         {\r
 173                 if(e.predator == self)\r
 174                 {\r
 175                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 176                         if(cvar("g_healthsize"))\r
 177                                 prey_mass *= e.scale;\r
 178                         self.stomach_load += floor(prey_mass);\r
 179                 }\r
 180         }\r
 181 \r
 182         // apply weight\r
 183         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 184         if(!self.gravity && self.stomach_load)\r
 185                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 186 }\r
 187 \r
 188 void Vore_AutoDigest(entity e)\r
 189 {\r
 190         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 191 \r
 192         if(!cvar("g_vore_digestion") || e.digesting)\r
 193                 return;\r
 194         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 195                 return; // this feature is only for players, not bots\r
 196         if(e.stomach_load > 1)\r
 197                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 198         if(Stomach_TeamMates_check(e))\r
 199                 return; // never begin automatic digestion if we've swallowed a team mate\r
 200 \r
 201         e.digesting = TRUE;\r
 202 }\r
 203 \r
 204 .entity swallow_model;\r
 205 float Vore_SwallowModel_CustomizeEntityForClient()\r
 206 {\r
 207         // use the same system as the weapon model\r
 208 \r
 209         self.viewmodelforclient = self.owner;\r
 210         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 211 \r
 212         if(other.classname == "spectator")\r
 213         if(other.enemy == self.owner)\r
 214         {\r
 215                 self.viewmodelforclient = other;\r
 216                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 217         }\r
 218 \r
 219         return TRUE;\r
 220 }\r
 221 \r
 222 void Vore_SwallowModel_Think()\r
 223 {\r
 224         // update the position of the swallow model to match our swallow progress\r
 225         float dist;\r
 226         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 227         if(cvar("g_healthsize"))\r
 228                 dist *= self.scale;\r
 229         self.view_ofs = '1 0 0' * dist;\r
 230 \r
 231         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 232         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 233         {\r
 234                 remove(self.owner.swallow_model);\r
 235                 self.owner.swallow_model = world;\r
 236                 return;\r
 237         }\r
 238 \r
 239         // properties that should update whenever possible, but when the predator is not available\r
 240         self.nextthink = time;\r
 241 }\r
 242 \r
 243 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 244 {\r
 245         // if we don't have a swallow model already, spawn one\r
 246         if(!prey.swallow_model)\r
 247         {\r
 248                 prey.swallow_model = spawn();\r
 249                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 250                 prey.swallow_model.solid = SOLID_NOT;\r
 251                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 252                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 253                 prey.swallow_model.owner = prey;\r
 254                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 255                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 256                 prey.swallow_model.nextthink = time;\r
 257         }\r
 258 \r
 259         // properties that should update whenever possible, but when the predator is available\r
 260         string player_swallowmodel;\r
 261         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 262         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 263                 setmodel(prey.swallow_model, player_swallowmodel);\r
 264         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 265                 prey.swallow_model.skin = pred.skin;\r
 266         if(cvar("g_healthsize"))\r
 267                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 268         if(prey.swallow_model.enemy != pred)\r
 269                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 270         if(prey.swallow_model.colormap != pred.colormap)\r
 271                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 272         if(prey.swallow_model.glowmod != pred.glowmod)\r
 273                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 274 }\r
 275 \r
 276 .entity pusher;\r
 277 .float pushltime;\r
 278 void Vore_Swallow(entity e)\r
 279 {\r
 280         // this player is being swallowed by another player, apply the proper changes\r
 281 \r
 282         e.vore_oldmovetype = e.movetype;\r
 283         e.vore_oldsolid = e.solid;\r
 284         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 285 \r
 286         e.predator = self;\r
 287         setorigin(e, e.predator.origin);\r
 288         e.velocity = '0 0 0';\r
 289         e.movetype = MOVETYPE_FOLLOW;\r
 290         e.solid = SOLID_NOT;\r
 291         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 292 \r
 293         // drop keys (KH) and flags (CTF) when we get swallowed\r
 294         kh_Key_DropAll(e, FALSE);\r
 295         if(e.flagcarried)\r
 296                 DropFlag(e.flagcarried, world, e.predator);\r
 297 \r
 298         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 299                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 300 \r
 301         if(teams_matter && e.team == e.predator.team)\r
 302         {\r
 303                 if(cvar("g_vore_kick"))\r
 304                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 305                 if(cvar("g_vore_digestion"))\r
 306                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 307         }\r
 308 \r
 309         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 310         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 311         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_predator_punchangle");\r
 312         e.predator.regurgitate_prepare = 0;\r
 313         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 314         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 315         Vore_AutoDigest(e.predator);\r
 316         Vore_SetPreyPositions(e.predator);\r
 317 \r
 318         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 319         e.predator.weapon_delay = time + button_delay_time;\r
 320         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 321         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 322         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 323 }\r
 324 \r
 325 void Vore_SwallowStep(entity e)\r
 326 {\r
 327         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 328         {\r
 329                 Vore_Swallow(e);\r
 330                 return;\r
 331         }\r
 332 \r
 333         Vore_SwallowModel_Update(e, self);\r
 334 \r
 335         // increase the progress value until it reaches 1, then swallow the player\r
 336         if(e.swallow_progress_prey < 1)\r
 337         {\r
 338                 float fill;\r
 339                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 340                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 341                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 342                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 343                         fill /= e.stomach_load;\r
 344 \r
 345                 e.swallow_progress_prey += fill;\r
 346         }\r
 347         else\r
 348         {\r
 349                 Vore_Swallow(e);\r
 350                 e.swallow_progress_prey = 0;\r
 351         }\r
 352 \r
 353         // the predator's progress is how much the prey got swallowed\r
 354         self.swallow_progress_pred = e.swallow_progress_prey;\r
 355 }\r
 356 \r
 357 void Vore_Regurgitate(entity e)\r
 358 {\r
 359         // this player is being regurgitated by their predator, apply the proper changes\r
 360 \r
 361         e.movetype = e.vore_oldmovetype;\r
 362         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 363                 e.solid = e.vore_oldsolid;\r
 364         e.view_ofs_z = PL_VIEW_OFS_z;\r
 365         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 366 \r
 367         // if the prey has been fully digested, silently detach them\r
 368         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 369         {\r
 370                 e.predator = world;\r
 371                 e.modelindex = 0; // hide the dead body\r
 372                 return;\r
 373         }\r
 374 \r
 375         // apply velocities\r
 376         local vector oldforward, oldright, oldup;\r
 377         oldforward = v_forward;\r
 378         oldright = v_right;\r
 379         oldup = v_up;\r
 380         makevectors(e.predator.v_angle);\r
 381         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 382         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 383         v_forward = oldforward;\r
 384         v_right = oldright;\r
 385         v_up = oldup;\r
 386 \r
 387         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 388         e.pushltime = time + cvar("g_maxpushtime");\r
 389 \r
 390         // if the dead body of the prey is below gibbing health, gib it\r
 391         e.stat_eaten = 0; // necessary for gibs to show\r
 392         PlayerGib(e, e.predator);\r
 393 \r
 394         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 395         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 396         {\r
 397                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 398                 Vore_SwallowModel_Update(e, e.predator);\r
 399         }\r
 400 \r
 401         // apply regurgitation damage to the predator\r
 402         if(cvar("g_balance_vore_regurgitate_damage"))\r
 403         {\r
 404                 float regurgitate_dmg;\r
 405                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 406                 if(cvar("g_healthsize"))\r
 407                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 408                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 409         }\r
 410 \r
 411         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 412         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 413         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 414         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_predator_punchangle");\r
 415         e.predator.regurgitate_prepare = 0;\r
 416         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 417         Vore_SetPreyPositions(e.predator);\r
 418 \r
 419         // block firing for a small amount of time, or we'll be firing the next frame\r
 420         e.weapon_delay = time + button_delay_time;\r
 421         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 422         e.predator = world;\r
 423 }\r
 424 \r
 425 void Vore_Disconnect()\r
 426 {\r
 427         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 428 \r
 429         // prey disconnects or goes spectating while inside someone's belly\r
 430         if(self.stat_eaten)\r
 431                 Vore_Regurgitate(self);\r
 432 \r
 433         // pred disconnects or goes spectating with players in their belly\r
 434         entity head;\r
 435         FOR_EACH_PLAYER(head)\r
 436         {\r
 437                 if(head.predator == self)\r
 438                         Vore_Regurgitate(head);\r
 439         }\r
 440         Vore_GurgleSound(); // stop the gurgling sound\r
 441 \r
 442         self.stomach_load = self.gravity = 0; // prevents a bug\r
 443 }\r
 444 \r
 445 .float digestion_step;\r
 446 void Vore_Digest()\r
 447 {\r
 448         // apply digestion to prey\r
 449 \r
 450         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 451         {\r
 452                 self.predator.digesting = FALSE;\r
 453                 return;\r
 454         }\r
 455         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 456                 return;\r
 457 \r
 458         if(time > self.digestion_step)\r
 459         {\r
 460                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 461                 float damage, damage_offset;\r
 462 \r
 463                 damage_offset = 1;\r
 464                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 465                         damage_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 466                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 467                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 468                 damage_offset = ceil(damage_offset);\r
 469 \r
 470                 damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 471                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 472                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 473 \r
 474                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 475                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 476                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 477 \r
 478                 if (self.predator.digestsound_finished < time)\r
 479                 {\r
 480                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 481                         self.predator.digestsound_finished = time + 0.5;\r
 482                 }\r
 483                 self.digestion_step = time + steptime;\r
 484         }\r
 485 \r
 486         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 487                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 488 }\r
 489 \r
 490 .float teamheal_step;\r
 491 void Vore_Teamheal()\r
 492 {\r
 493         // apply teamheal\r
 494 \r
 495         if(self.deadflag != DEAD_NO)\r
 496                 return;\r
 497 \r
 498         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 499         if(time > self.teamheal_step)\r
 500         {\r
 501                 self.health += cvar("g_balance_vore_teamheal");\r
 502                 self.teamheal_step = time + steptime;\r
 503 \r
 504                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 505                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 506                 {\r
 507                         play2(self, "misc/beep.wav");\r
 508                         play2(self.predator, "misc/beep.wav");\r
 509                 }\r
 510         }\r
 511 }\r
 512 \r
 513 .float kick_pressed;\r
 514 void Vore_StomachKick()\r
 515 {\r
 516         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 517 \r
 518         if(self.deadflag != DEAD_NO)\r
 519                 return;\r
 520 \r
 521         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 522         {\r
 523                 float damage, vol;\r
 524                 vector force;\r
 525                 damage = cvar("g_balance_vore_kick_damage");\r
 526                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 527                 vol = VOL_BASE;\r
 528 \r
 529                 // apply player scale to the damage / force of the kick\r
 530                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 531                 {\r
 532                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 533                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 534                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 535                 }\r
 536                 vol = bound(0, vol, 1);\r
 537 \r
 538                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 539                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 540                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 541                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 542 \r
 543                 // abort the predator's scheduled regurgitation\r
 544                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 545                         self.predator.regurgitate_prepare = 0;\r
 546 \r
 547                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 548                 if(cvar("g_balance_vore_kick_repress"))\r
 549                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 550                         self.kick_pressed = TRUE;\r
 551         }\r
 552 }\r
 553 \r
 554 void Vore_StomachLeave()\r
 555 {\r
 556         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 557 \r
 558         if(self.deadflag != DEAD_NO)\r
 559                 return;\r
 560 \r
 561         if(Vore_CanLeave())\r
 562                 Vore_Regurgitate(self);\r
 563         else if(time > self.complain_vore)\r
 564         {\r
 565                 play2(self, "misc/forbidden.wav");\r
 566                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 567                 self.complain_vore = time + complain_delay_time;\r
 568         }\r
 569 }\r
 570 \r
 571 void Vore_AutoTaunt()\r
 572 {\r
 573         // triggers ambient vore taunts, for both pred and prey\r
 574 \r
 575         float taunt_time;\r
 576 \r
 577         // predator taunts\r
 578         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 579         {\r
 580                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 581                 {\r
 582                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 583                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 584                 }\r
 585         }\r
 586         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 587         {\r
 588                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 589                 SetAutoTaunt(self, 0, 0);\r
 590         }\r
 591 \r
 592         // prey taunts\r
 593         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 594         {\r
 595                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 596                 {\r
 597                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 598                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 599                 }\r
 600         }\r
 601         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 602         {\r
 603                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 604                 SetAutoTaunt(self, 0, 0);\r
 605         }\r
 606 }\r
 607 \r
 608 void Vore_SetSbarRings()\r
 609 {\r
 610         // first clear the ring stats, then configure them if needed\r
 611         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 612         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 613 \r
 614         if(self.stat_eaten)\r
 615         {\r
 616                 if(time <= self.stomachkick_delay)\r
 617                 {\r
 618                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 619                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 620                 }\r
 621         }\r
 622         else\r
 623         {\r
 624                 if(self.swallow_progress_pred)\r
 625                 {\r
 626                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 627                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 628                 }\r
 629                 else if(time <= self.action_delay)\r
 630                 {\r
 631                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 632                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 633                 }\r
 634 \r
 635                 if(self.swallow_progress_prey)\r
 636                 {\r
 637                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 638                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 639                 }\r
 640                 else if(time <= self.regurgitate_prepare)\r
 641                 {\r
 642                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 643                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 644                 }\r
 645         }\r
 646 }\r
 647 \r
 648 .float regurgitatecolor_particles_tick;\r
 649 void Vore()\r
 650 {\r
 651         // main vore code, this is where it all happens\r
 652 \r
 653         Vore_AutoTaunt();\r
 654 \r
 655         if(!self.stat_eaten)\r
 656         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 657         if(self.colormod)\r
 658         if(self.colormod != '1 1 1')\r
 659         {\r
 660                 // slowly wash stomach fluids off players once they're out of the stomach\r
 661                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 662                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 663                 {\r
 664                         float goo_fade;\r
 665                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 666                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 667 \r
 668                         self.colormod_x += goo_fade;\r
 669                         if(self.colormod_x > 1)\r
 670                                 self.colormod_x = 1;\r
 671                         self.colormod_y += goo_fade;\r
 672                         if(self.colormod_y > 1)\r
 673                                 self.colormod_y = 1;\r
 674                         self.colormod_z += goo_fade;\r
 675                         if(self.colormod_z > 1)\r
 676                                 self.colormod_z = 1;\r
 677                 }\r
 678 \r
 679                 // constant particles falling off dirty players\r
 680                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 681                 if(self.regurgitatecolor_particles_tick < time)\r
 682                 {\r
 683                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 684                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 685                 }\r
 686         }\r
 687 \r
 688         // set all vore stats\r
 689         Vore_SetSbarRings();\r
 690         if(self.predator.classname == "player")\r
 691         {\r
 692                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 693                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 694                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 695                 self.stat_eaten = num_for_edict(self.predator);\r
 696         }\r
 697         else\r
 698         {\r
 699                 self.stat_stomachload = self.stomach_load;\r
 700                 self.stat_stomachmaxload = self.stomach_maxload;\r
 701                 self.stat_digesting = self.digesting;\r
 702                 self.stat_eaten = 0;\r
 703         }\r
 704         self.stat_canleave = Vore_CanLeave();\r
 705 \r
 706         // don't allow a player inside a player inside another player :)\r
 707         // prevent this by checking if such has happened, and taking the proper measures\r
 708         // this code has a high priority and must not be stopped by any delay, so run it here\r
 709         if(self.predator.stat_eaten)\r
 710         {\r
 711                 entity target_predator, target_predator_predator, oldself;\r
 712                 target_predator = self.predator;\r
 713                 target_predator_predator = self.predator.predator;\r
 714 \r
 715                 Vore_Regurgitate(self);\r
 716 \r
 717                 // now steal our prey's prey if this probability applies\r
 718                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 719                 {\r
 720                         oldself = self;\r
 721                         self = target_predator_predator;\r
 722                         if(Swallow_condition_check(oldself))\r
 723                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 724                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 725                                 Vore_Swallow(oldself);\r
 726                         self = oldself;\r
 727                 }\r
 728         }\r
 729 \r
 730         // the swallow progress of prey and preds idly decrease by this amount\r
 731         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 732         {\r
 733                 if(self.swallow_progress_pred)\r
 734                 {\r
 735                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 736                         if(self.swallow_progress_pred < 0)\r
 737                                 self.swallow_progress_pred = 0;\r
 738                 }\r
 739                 if(self.swallow_progress_prey)\r
 740                 {\r
 741                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 742                         if(self.swallow_progress_prey < 0)\r
 743                                 self.swallow_progress_prey = 0;\r
 744                 }\r
 745         }\r
 746 \r
 747         // set the predator's stomach load and capacity\r
 748         Vore_StomachLoad_Apply();\r
 749 \r
 750         // apply delays and skip the vore system under some circumstances\r
 751         if(!cvar("g_vore")) // the vore system is disabled\r
 752         {\r
 753                 Vore_Disconnect();\r
 754                 return;\r
 755         }\r
 756         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 757         {\r
 758                 Vore_Disconnect();\r
 759                 return;\r
 760         }\r
 761         if(self.spectatee_status)\r
 762                 return;\r
 763         if(time < self.system_delay)\r
 764                 return;\r
 765 \r
 766 // --------------------------------\r
 767 // Code that addresses predators:\r
 768 // --------------------------------\r
 769 \r
 770         entity prey;\r
 771         prey = Swallow_player_check();\r
 772 \r
 773         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 774         self.stat_canswallow = 0;\r
 775         if(Swallow_condition_check(prey))\r
 776         {\r
 777                 // canswallow stat, used by the HUD\r
 778                 if(teams_matter && prey.team == self.team)\r
 779                         self.stat_canswallow = 2;\r
 780                 else\r
 781                         self.stat_canswallow = 1;\r
 782 \r
 783                 if(self.BUTTON_ATCK)\r
 784                         Vore_SwallowStep(prey);\r
 785         }\r
 786         else if(prey != world)\r
 787                 self.stat_canswallow = -1;\r
 788 \r
 789         // toggle digestion, if the player has someone in their stomach\r
 790         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 791         {\r
 792                 if(self.stomach_load)\r
 793                 {\r
 794                         if(time > self.digest_button_delay_time)\r
 795                         {\r
 796                                 self.digesting = !self.digesting;\r
 797                                 self.digest_button_delay_time = time + button_delay_time;\r
 798                         }\r
 799                 }\r
 800                 else if(time > self.complain_vore)\r
 801                 {\r
 802                         play2(self, "misc/forbidden.wav");\r
 803                         sprint(self, "There is nothing to digest\n");\r
 804                         self.complain_vore = time + complain_delay_time;\r
 805                 }\r
 806         }\r
 807         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 808                 self.digesting = FALSE;\r
 809 \r
 810         // predator wishes to regurgitate his prey\r
 811         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 812         {\r
 813                 if(self.stomach_load)\r
 814                 {\r
 815                         if(time > self.regurgitate_button_delay_time)\r
 816                         {\r
 817                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 818                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 819                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 820                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 821                         }\r
 822                 }\r
 823                 else if(time > self.complain_vore)\r
 824                 {\r
 825                         play2(self, "misc/forbidden.wav");\r
 826                         sprint(self, "There is nothing to regurgitate\n");\r
 827                         self.complain_vore = time + complain_delay_time;\r
 828                 }\r
 829         }\r
 830 \r
 831         if(cvar("g_vore_gurglesound"))\r
 832                 Vore_GurgleSound();\r
 833 \r
 834 // --------------------------------\r
 835 // Code that addresses the prey:\r
 836 // --------------------------------\r
 837 \r
 838         if(!self.stat_eaten)\r
 839                 return;\r
 840 \r
 841         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 842                 self.health = cvar("g_balance_vore_digestion_limit");\r
 843 \r
 844         // automatically regurgitate prey that has reached their digestion limit\r
 845         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 846         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 847         {\r
 848                 Vore_Regurgitate(self);\r
 849                 return;\r
 850         }\r
 851 \r
 852         // do we stick around inside dead furries? x_x\r
 853         if(self.predator.deadflag != DEAD_NO)\r
 854         {\r
 855                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 856                 {\r
 857                         Vore_Regurgitate(self);\r
 858                         return;\r
 859                 }\r
 860                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 861                         self.predator.regurgitate_prepare = 0;\r
 862         }\r
 863 \r
 864         if(self.predator.stomach_load > self.predator.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 865         {\r
 866                 Vore_Regurgitate(self);\r
 867                 return;\r
 868         }\r
 869         if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.predator.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.predator.stomach_load / self.predator.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 870         {\r
 871                 Vore_Regurgitate(self);\r
 872                 return;\r
 873         }\r
 874 \r
 875         // apply delayed regurgitating if it was scheduled\r
 876         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 877         {\r
 878                 self.predator.regurgitate_prepare = 0;\r
 879                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 880                 Vore_Regurgitate(self);\r
 881         }\r
 882 \r
 883         // execute digesting and team healing\r
 884         if(self.predator.digesting == TRUE)\r
 885                 Vore_Digest();\r
 886         if(teams_matter && self.team == self.predator.team)\r
 887         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 888                 Vore_Teamheal();\r
 889 \r
 890         // execute prey commands\r
 891         if(self.BUTTON_ATCK)\r
 892         {\r
 893                 if(cvar("g_vore_kick"))\r
 894                         Vore_StomachKick();\r
 895         }\r
 896         else\r
 897                 self.kick_pressed = FALSE;\r
 898         if(self.BUTTON_JUMP)\r
 899                 Vore_StomachLeave();\r
 900 \r
 901         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 902         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 903         kh_Key_DropAll(self, FALSE);\r
 904 \r
 905         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 906         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 907 }