data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload, vore_oldview_ofs_z;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  34         {\r
  35                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  36                 {\r
  37                         if(time > self.complain_vore)\r
  38                         {\r
  39                                 play2(self, "weapons/unavailable.wav");\r
  40                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  41                                 self.complain_vore = time + complain_delay_time;\r
  42                         }\r
  43                         return FALSE;\r
  44                 }\r
  45 \r
  46                 if(cvar("g_vore_biggergut"))\r
  47                 if(prey.stomach_load > self.stomach_load)\r
  48                 {\r
  49                         if(time > self.complain_vore)\r
  50                         {\r
  51                                 play2(self, "weapons/unavailable.wav");\r
  52                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 return TRUE;\r
  59         }\r
  60         return FALSE;\r
  61 }\r
  62 \r
  63 float Vore_CanLeave()\r
  64 {\r
  65         if(teams_matter && self.team == self.predator.team)\r
  66                 return TRUE;\r
  67         return FALSE;\r
  68 }\r
  69 \r
  70 // make the camera smoothly lower itself when we get swallowed\r
  71 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  72 .float cameraeffect_current, cameraeffect_target;\r
  73 void Vore_CameraEffect_Set(entity e)\r
  74 {\r
  75         e.cameraeffect_current = 1;\r
  76         e.cameraeffect_target = 2;\r
  77 }\r
  78 void Vore_CameraEffect_Apply()\r
  79 {\r
  80         if(self.predator.classname != "player")\r
  81                 return;\r
  82 \r
  83         if(self.cvar_cl_vore_cameraspeed)\r
  84         {\r
  85                 local float step;\r
  86                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
  87 \r
  88                 // not sure if these maths are good, as the effect should be smoother\r
  89                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
  90                         self.cameraeffect_current -= step;\r
  91                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
  92                         self.cameraeffect_current += step;\r
  93         }\r
  94         else\r
  95                 self.cameraeffect_current = self.cameraeffect_target;\r
  96 \r
  97         self.view_ofs_z = self.vore_oldview_ofs_z / self.cameraeffect_current;\r
  98 }\r
  99 \r
 100 .float gurgle_oldstomachload;\r
 101 void Vore_Gurglesound()\r
 102 {\r
 103         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 104         {\r
 105                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 106 \r
 107                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 108                 self.gurgle_oldstomachload = self.stomach_load;\r
 109         }\r
 110 }\r
 111 \r
 112 void Vore_Weight_apply(entity e)\r
 113 {\r
 114         // apply stomach weight that makes you heavier the more you eat\r
 115         // slowing the player is done in cl_physics.qc\r
 116 \r
 117         if(e.stomach_load != e.vore_oldstomachload)\r
 118                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 119         if(e.gravity == 0)\r
 120                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 121         e.vore_oldstomachload = e.stomach_load;\r
 122 }\r
 123 \r
 124 .entity pusher;\r
 125 .float pushltime;\r
 126 void Vore_Swallow(entity e)\r
 127 {\r
 128         // this player is being swallowed by another player, apply the proper changes\r
 129 \r
 130         e.vore_oldmovetype = e.movetype;\r
 131         e.vore_oldsolid = e.solid;\r
 132         e.vore_oldview_ofs_z = e.view_ofs_z;\r
 133 \r
 134         e.predator = self;\r
 135         setorigin(e, e.predator.origin);\r
 136         e.velocity = '0 0 0';\r
 137         e.movetype = MOVETYPE_FOLLOW;\r
 138         e.solid = SOLID_NOT;\r
 139         e.alpha = -1; // best way of hiding the eaten player\r
 140         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 141 \r
 142         // drop keys (KH) and flags (CTF) when we get swallowed\r
 143         kh_Key_DropAll(e, FALSE);\r
 144         if(e.flagcarried)\r
 145                 DropFlag(e.flagcarried, world, e.predator);\r
 146 \r
 147         Vore_CameraEffect_Set(e);\r
 148 \r
 149         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 150                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 151 \r
 152         if(teams_matter && e.team == e.predator.team)\r
 153         {\r
 154                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 155                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 156         }\r
 157 \r
 158         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 159         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 160         e.predator.stomach_load += 1;\r
 161         e.predator.regurgitate_prepare = 0;\r
 162         Vore_Weight_apply(e.predator);\r
 163 \r
 164         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 165         e.predator.weapon_delay = time + button_delay_time;\r
 166         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 167         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 168 }\r
 169 \r
 170 void Vore_Regurgitate(entity e)\r
 171 {\r
 172         // this player is being regurgitated by their predator, apply the proper changes\r
 173 \r
 174         e.movetype = e.vore_oldmovetype;\r
 175         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 176                 e.solid = e.vore_oldsolid;\r
 177         e.view_ofs_z = e.vore_oldview_ofs_z;\r
 178         e.alpha = default_player_alpha;\r
 179 \r
 180         // apply velocities\r
 181         local vector oldforward, oldright, oldup;\r
 182         oldforward = v_forward;\r
 183         oldright = v_right;\r
 184         oldup = v_up;\r
 185         makevectors(e.predator.v_angle);\r
 186         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 187         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 188         v_forward = oldforward;\r
 189         v_right = oldright;\r
 190         v_up = oldup;\r
 191 \r
 192         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 193         e.pushltime = time + cvar("g_maxpushtime");\r
 194 \r
 195         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 196         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 197         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 198         e.predator.stomach_load -= 1;\r
 199         e.predator.regurgitate_prepare = 0;\r
 200         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 201         Vore_Weight_apply(e.predator);\r
 202 \r
 203         // block firing for a small amount of time, or we'll be firing the next frame\r
 204         e.weapon_delay = time + button_delay_time;\r
 205         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 206         e.predator = world;\r
 207 }\r
 208 \r
 209 void Vore_Disconnect()\r
 210 {\r
 211         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 212 \r
 213         // prey disconnects or goes spectating while inside someone's belly\r
 214         if(self.predator.classname == "player")\r
 215                 Vore_Regurgitate(self);\r
 216 \r
 217         // pred disconnects or goes spectating with players in their belly\r
 218         else if(self.stomach_load > 0)\r
 219         {\r
 220                 entity head;\r
 221                 FOR_EACH_PLAYER(head)\r
 222                 {\r
 223                         if(head.predator == self)\r
 224                                 Vore_Regurgitate(head);\r
 225                 }\r
 226                 Vore_Gurglesound(); // stop the gurgling sound\r
 227         }\r
 228 }\r
 229 \r
 230 .float digestion_step;\r
 231 void Vore_Digest()\r
 232 {\r
 233         // apply digestion to prey\r
 234 \r
 235         if(time > self.predator.digestion_step)\r
 236         {\r
 237                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 238                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 239                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 240 \r
 241                 if (self.predator.digestsound_finished < time)\r
 242                 {\r
 243                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 244                         self.predator.digestsound_finished = time + 0.5;\r
 245                 }\r
 246                 self.predator.digestion_step = time + steptime;\r
 247         }\r
 248 \r
 249         if(self.health <= 0)\r
 250         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 251                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 252 }\r
 253 \r
 254 .float teamheal_step;\r
 255 void Vore_Teamheal()\r
 256 {\r
 257         // apply teamheal\r
 258 \r
 259         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 260         if(time > self.teamheal_step)\r
 261         {\r
 262                 self.health += cvar("g_balance_vore_teamheal");\r
 263                 self.teamheal_step = time + steptime;\r
 264         }\r
 265 }\r
 266 \r
 267 .float stomachkick_delay;\r
 268 void Vore_StomachKick()\r
 269 {\r
 270         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 271 \r
 272         if(time > self.stomachkick_delay)\r
 273         {\r
 274                 float damage;\r
 275                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 276                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, '0 0 0');\r
 277                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 278 \r
 279                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 280                         Vore_Regurgitate(self);\r
 281 \r
 282                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 283         }\r
 284 }\r
 285 \r
 286 void Vore_StomachLeave()\r
 287 {\r
 288         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 289 \r
 290         if(Vore_CanLeave())\r
 291                 Vore_Regurgitate(self);\r
 292         else if(time > self.complain_vore)\r
 293         {\r
 294                 play2(self, "weapons/unavailable.wav");\r
 295                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 296                 self.complain_vore = time + complain_delay_time;\r
 297         }\r
 298 }\r
 299 \r
 300 void Vore()\r
 301 {\r
 302         // main vore code, this is where it all happens\r
 303 \r
 304         // set all vore related stats\r
 305         if(self.predator.classname == "player")\r
 306         {\r
 307                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 308                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 309                 self.stat_eaten = num_for_edict(self.predator);\r
 310         }\r
 311         else\r
 312         {\r
 313                 self.stat_stomachload = self.stomach_load;\r
 314                 self.stat_digesting = self.digesting;\r
 315                 self.stat_eaten = 0;\r
 316         }\r
 317         self.stat_canleave = Vore_CanLeave();\r
 318 \r
 319         // skip the vore system under some circumstances\r
 320         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 321         {\r
 322                 Vore_Disconnect();\r
 323                 return;\r
 324         }\r
 325         if(self.spectatee_status)\r
 326                 return;\r
 327         if(time < self.system_delay)\r
 328                 return;\r
 329 \r
 330 // --------------------------------\r
 331 // Code that addresses predators:\r
 332 // --------------------------------\r
 333 \r
 334         entity prey;\r
 335         prey = Swallow_player_check();\r
 336 \r
 337         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 338         if(self.BUTTON_ATCK && !self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
 339         if(Swallow_condition_check(prey))\r
 340                 Vore_Swallow(prey);\r
 341 \r
 342         // toggle digestion, if the player has someone in their stomach\r
 343         if(self.BUTTON_DIGEST)\r
 344         {\r
 345                 if(self.stomach_load)\r
 346                 {\r
 347                         if(time > self.digest_button_delay_time)\r
 348                         {\r
 349                                 self.digesting = !self.digesting;\r
 350                                 self.digest_button_delay_time = time + button_delay_time;\r
 351                         }\r
 352                 }\r
 353                 else if(time > self.complain_vore)\r
 354                 {\r
 355                         play2(self, "weapons/unavailable.wav");\r
 356                         sprint(self, "There is nothing to digest\n");\r
 357                         self.complain_vore = time + complain_delay_time;\r
 358                 }\r
 359         }\r
 360         if(!self.stomach_load)\r
 361                 self.digesting = FALSE;\r
 362 \r
 363         // predator wishes to regurgitate his prey\r
 364         if(self.BUTTON_REGURGITATE)\r
 365         {\r
 366                 if(self.stomach_load)\r
 367                 {\r
 368                         if(time > self.regurgitate_button_delay_time)\r
 369                         {\r
 370                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 371                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 372                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 373                         }\r
 374                 }\r
 375                 else if(time > self.complain_vore)\r
 376                 {\r
 377                         play2(self, "weapons/unavailable.wav");\r
 378                         sprint(self, "There is nothing to regurgitate\n");\r
 379                         self.complain_vore = time + complain_delay_time;\r
 380                 }\r
 381         }\r
 382 \r
 383         if(cvar("g_vore_gurglesound"))\r
 384                 Vore_Gurglesound();\r
 385 \r
 386 // --------------------------------\r
 387 // Code that addresses the prey:\r
 388 // --------------------------------\r
 389 \r
 390         if(self.predator.classname != "player")\r
 391                 return;\r
 392 \r
 393         if(self.predator.deadflag || self.deadflag)\r
 394                 Vore_Regurgitate(self);\r
 395         else if(self.predator.predator.classname == "player") // don't allow a player inside a player inside another player :)\r
 396         {\r
 397                 entity target_predator, oldself;\r
 398                 target_predator = self.predator.predator;\r
 399 \r
 400                 Vore_Regurgitate(self);\r
 401                 if(random() < cvar("g_vore_stealprey")) // steal our prey's prey if this probability returns true\r
 402                 if not(teams_matter && self.predator.team == target_predator.team) // don't steal a team mate's prey\r
 403                 if(Swallow_condition_check(self))\r
 404                 {\r
 405                         oldself = self;\r
 406                         self = target_predator;\r
 407                         Vore_Swallow(oldself);\r
 408                         self = oldself;\r
 409                 }\r
 410         }\r
 411         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 412                 Vore_Regurgitate(self);\r
 413 \r
 414         // apply delayed regurgitating if it was scheduled\r
 415         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 416         {\r
 417                 self.predator.regurgitate_prepare = 0;\r
 418                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 419                 Vore_Regurgitate(self);\r
 420         }\r
 421 \r
 422         // execute digesting and team healing\r
 423         if(self.predator.digesting == TRUE)\r
 424                 Vore_Digest();\r
 425         if(teams_matter && self.team == self.predator.team)\r
 426                 Vore_Teamheal();\r
 427 \r
 428         // execute prey commands\r
 429         if(self.BUTTON_ATCK)\r
 430                 Vore_StomachKick();\r
 431         if(self.BUTTON_JUMP)\r
 432                 Vore_StomachLeave();\r
 433 \r
 434         Vore_CameraEffect_Apply();\r
 435 }