data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  34         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  35         {\r
  36                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  37                 {\r
  38                         if(time > self.complain_vore)\r
  39                         {\r
  40                                 play2(self, "misc/unavailable.wav");\r
  41                                 sprint(self, "You cannot swallow your team mates\n");\r
  42                                 self.complain_vore = time + complain_delay_time;\r
  43                         }\r
  44                         return FALSE;\r
  45                 }\r
  46 \r
  47                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  48                 {\r
  49                         if(time > self.complain_vore)\r
  50                         {\r
  51                                 play2(self, "misc/unavailable.wav");\r
  52                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 if(cvar("g_vore_biggergut"))\r
  59                 if(prey.stomach_load > self.stomach_load)\r
  60                 {\r
  61                         if(time > self.complain_vore)\r
  62                         {\r
  63                                 play2(self, "misc/unavailable.wav");\r
  64                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69 \r
  70                 return TRUE;\r
  71         }\r
  72         return FALSE;\r
  73 }\r
  74 \r
  75 float Vore_CanLeave()\r
  76 {\r
  77         if(self.predator.classname == "player")\r
  78         {\r
  79                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  80                         return TRUE;\r
  81                 if(teams_matter && self.team == self.predator.team)\r
  82                         return TRUE;\r
  83                 if(g_rpg && cvar("g_rpg_canleave"))\r
  84                         return TRUE;\r
  85         }\r
  86         return FALSE;\r
  87 }\r
  88 \r
  89 // make the camera smoothly lower itself when we get swallowed\r
  90 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  91 .float cameraeffect_current, cameraeffect_target;\r
  92 void Vore_CameraEffect_Set(entity e)\r
  93 {\r
  94         e.cameraeffect_current = 1;\r
  95         e.cameraeffect_target = 2;\r
  96 }\r
  97 void Vore_CameraEffect_Apply()\r
  98 {\r
  99         if(self.predator.classname != "player")\r
 100                 return;\r
 101 \r
 102         if(self.cvar_cl_vore_cameraspeed)\r
 103         {\r
 104                 local float step;\r
 105                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 106 \r
 107                 // not sure if these maths are good, as the effect should be smoother\r
 108                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 109                         self.cameraeffect_current -= step;\r
 110                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 111                         self.cameraeffect_current += step;\r
 112         }\r
 113         else\r
 114                 self.cameraeffect_current = self.cameraeffect_target;\r
 115 \r
 116         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 117 }\r
 118 \r
 119 .float gurgle_oldstomachload;\r
 120 void Vore_GurgleSound()\r
 121 {\r
 122         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 123         {\r
 124                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 125 \r
 126                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 127                 self.gurgle_oldstomachload = self.stomach_load;\r
 128         }\r
 129 }\r
 130 \r
 131 void Vore_WeightApply(entity e)\r
 132 {\r
 133         // apply stomach weight that makes you heavier the more you eat\r
 134         // slowing the player is done in cl_physics.qc\r
 135 \r
 136         if(e.stomach_load != e.vore_oldstomachload)\r
 137                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 138         if(e.gravity == 0)\r
 139                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 140         e.vore_oldstomachload = e.stomach_load;\r
 141 }\r
 142 \r
 143 void Vore_AutoDigest(entity e)\r
 144 {\r
 145         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 146 \r
 147         if not(e.cvar_cl_vore_autodigest)\r
 148                 return;\r
 149         if not(cvar("g_vore_digestion"))\r
 150                 return;\r
 151 \r
 152         entity head;\r
 153         if(teams_matter)\r
 154         {\r
 155                 FOR_EACH_PLAYER(head)\r
 156                 {\r
 157                         // never begin automatic digestion if we've swallowed a team mate\r
 158                         if(head.team == e.team)\r
 159                                 return;\r
 160                 }\r
 161         }\r
 162 \r
 163         e.digesting = TRUE;\r
 164 }\r
 165 \r
 166 .entity pusher;\r
 167 .float pushltime;\r
 168 void Vore_Swallow(entity e)\r
 169 {\r
 170         // this player is being swallowed by another player, apply the proper changes\r
 171 \r
 172         e.vore_oldmovetype = e.movetype;\r
 173         e.vore_oldsolid = e.solid;\r
 174 \r
 175         e.predator = self;\r
 176         setorigin(e, e.predator.origin);\r
 177         e.velocity = '0 0 0';\r
 178         e.movetype = MOVETYPE_FOLLOW;\r
 179         e.solid = SOLID_NOT;\r
 180         e.alpha = -1; // best way of hiding the eaten player\r
 181         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 182 \r
 183         // drop keys (KH) and flags (CTF) when we get swallowed\r
 184         kh_Key_DropAll(e, FALSE);\r
 185         if(e.flagcarried)\r
 186                 DropFlag(e.flagcarried, world, e.predator);\r
 187 \r
 188         Vore_CameraEffect_Set(e);\r
 189 \r
 190         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 191                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 192 \r
 193         if(teams_matter && e.team == e.predator.team)\r
 194         {\r
 195                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 196                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 197         }\r
 198 \r
 199         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 200         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 201         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 202         e.predator.stomach_load += 1;\r
 203         e.predator.regurgitate_prepare = 0;\r
 204         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 205         Vore_WeightApply(e.predator);\r
 206         Vore_AutoDigest(e.predator);\r
 207 \r
 208         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 209         e.predator.weapon_delay = time + button_delay_time;\r
 210         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 211         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 212 }\r
 213 \r
 214 void Vore_Regurgitate(entity e)\r
 215 {\r
 216         // this player is being regurgitated by their predator, apply the proper changes\r
 217 \r
 218         e.movetype = e.vore_oldmovetype;\r
 219         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 220                 e.solid = e.vore_oldsolid;\r
 221         e.view_ofs_z = PL_VIEW_OFS_z;\r
 222         e.alpha = default_player_alpha;\r
 223 \r
 224         // apply velocities\r
 225         local vector oldforward, oldright, oldup;\r
 226         oldforward = v_forward;\r
 227         oldright = v_right;\r
 228         oldup = v_up;\r
 229         makevectors(e.predator.v_angle);\r
 230         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 231         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 232         v_forward = oldforward;\r
 233         v_right = oldright;\r
 234         v_up = oldup;\r
 235 \r
 236         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 237         e.pushltime = time + cvar("g_maxpushtime");\r
 238 \r
 239         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 240         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 241         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 242         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 243         e.predator.stomach_load -= 1;\r
 244         e.predator.regurgitate_prepare = 0;\r
 245         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 246         Vore_WeightApply(e.predator);\r
 247 \r
 248         // block firing for a small amount of time, or we'll be firing the next frame\r
 249         e.weapon_delay = time + button_delay_time;\r
 250         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 251         e.predator = world;\r
 252 }\r
 253 \r
 254 void Vore_DeadPrey_Configure(entity e)\r
 255 {\r
 256         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 257 \r
 258         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 259                 return;\r
 260 \r
 261         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 262         e.fakepredator = e.predator;\r
 263         e.fakeprey = TRUE;\r
 264 \r
 265         // first release the prey from the predator, as dead prey needs to be attached differently\r
 266         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 267         e.predator.stomach_load -= 1;\r
 268         Vore_WeightApply(e.predator);\r
 269         e.predator = world;\r
 270 \r
 271         // now put our dead prey inside the predator's stomach, but only as an effect\r
 272         e.movetype = MOVETYPE_FOLLOW;\r
 273         e.takedamage = DAMAGE_NO;\r
 274         e.solid = SOLID_NOT;\r
 275         e.aiment = e.fakepredator;\r
 276 \r
 277         // completely remove the dead body\r
 278         e.alpha = -1;\r
 279 }\r
 280 \r
 281 void Vore_DeadPrey_Detach(entity e)\r
 282 {\r
 283         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 284         // should only execute after Vore_DeadPrey_Configure has ran first\r
 285 \r
 286         if not(cvar("g_vore_keepdeadprey"))\r
 287                 return;\r
 288 \r
 289         e.fakepredator = world;\r
 290         e.aiment = world;\r
 291 \r
 292         if(!e.deadflag)\r
 293                 e.fakeprey = FALSE;\r
 294 }\r
 295 \r
 296 void Vore_PreyRelease(entity e)\r
 297 {\r
 298         // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 299         if(e.health <= 0 && cvar("g_vore_keepdeadprey"))\r
 300         {\r
 301                 Vore_DeadPrey_Configure(e);\r
 302 \r
 303                 // if keepdeadprey is enabled and the predator disconnected, detach the dead prey\r
 304                 if(e.fakepredator.classname != "player")\r
 305                         Vore_DeadPrey_Detach(e);\r
 306         }\r
 307         else\r
 308                 Vore_Regurgitate(e);\r
 309 }\r
 310 \r
 311 void Vore_Disconnect()\r
 312 {\r
 313         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 314 \r
 315         // prey disconnects or goes spectating while inside someone's belly\r
 316         if(self.predator.classname == "player")\r
 317                 Vore_PreyRelease(self);\r
 318 \r
 319         // pred disconnects or goes spectating with players in their belly\r
 320         else if(self.stomach_load > 0)\r
 321         {\r
 322                 entity head;\r
 323                 FOR_EACH_PLAYER(head)\r
 324                 {\r
 325                         if(head.predator == self)\r
 326                                 Vore_PreyRelease(head);\r
 327                 }\r
 328                 Vore_GurgleSound(); // stop the gurgling sound\r
 329         }\r
 330 \r
 331         self.stomach_load = self.gravity = 0; // prevents a bug\r
 332 }\r
 333 \r
 334 .float digestion_step;\r
 335 void Vore_Digest()\r
 336 {\r
 337         // apply digestion to prey\r
 338 \r
 339         if(time > self.predator.digestion_step)\r
 340         {\r
 341                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 342                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 343                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 344 \r
 345                 if (self.predator.digestsound_finished < time)\r
 346                 {\r
 347                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 348                         self.predator.digestsound_finished = time + 0.5;\r
 349                 }\r
 350                 self.predator.digestion_step = time + steptime;\r
 351         }\r
 352 \r
 353         if(self.health <= 0)\r
 354         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 355                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 356 }\r
 357 \r
 358 .float teamheal_step;\r
 359 void Vore_Teamheal()\r
 360 {\r
 361         // apply teamheal\r
 362 \r
 363         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 364         if(time > self.teamheal_step)\r
 365         {\r
 366                 self.health += cvar("g_balance_vore_teamheal");\r
 367                 self.teamheal_step = time + steptime;\r
 368         }\r
 369 }\r
 370 \r
 371 .float stomachkick_delay;\r
 372 void Vore_StomachKick()\r
 373 {\r
 374         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 375 \r
 376         if(time > self.stomachkick_delay)\r
 377         {\r
 378                 float damage;\r
 379                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 380                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 381                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 382 \r
 383                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 384                         Vore_Regurgitate(self);\r
 385 \r
 386                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 387         }\r
 388 }\r
 389 \r
 390 void Vore_StomachLeave()\r
 391 {\r
 392         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 393 \r
 394         if(Vore_CanLeave())\r
 395                 Vore_Regurgitate(self);\r
 396         else if(time > self.complain_vore)\r
 397         {\r
 398                 play2(self, "misc/unavailable.wav");\r
 399                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 400                 self.complain_vore = time + complain_delay_time;\r
 401         }\r
 402 }\r
 403 \r
 404 void Vore()\r
 405 {\r
 406         // main vore code, this is where it all happens\r
 407 \r
 408         if(!cvar("g_vore")) // the vore system is disabled\r
 409         {\r
 410                 Vore_Disconnect();\r
 411                 return;\r
 412         }\r
 413 \r
 414         // wash the goo away from players once they leave the stomach\r
 415         if(self.predator.classname != "player")\r
 416         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 417         if(self.colormod)\r
 418         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 419         {\r
 420                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 421                 if(self.colormod_x > 1)\r
 422                         self.colormod_x = 1;\r
 423                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 424                 if(self.colormod_y > 1)\r
 425                         self.colormod_y = 1;\r
 426                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 427                 if(self.colormod_z > 1)\r
 428                         self.colormod_z = 1;\r
 429         }\r
 430 \r
 431         // set all vore related stats\r
 432         if(self.predator.classname == "player")\r
 433         {\r
 434                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 435                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 436                 self.stat_eaten = num_for_edict(self.predator);\r
 437         }\r
 438         else\r
 439         {\r
 440                 self.stat_stomachload = self.stomach_load;\r
 441                 self.stat_digesting = self.digesting;\r
 442                 self.stat_eaten = 0;\r
 443         }\r
 444         self.stat_canleave = Vore_CanLeave();\r
 445 \r
 446         // don't allow a player inside a player inside another player :)\r
 447         // prevent this by checking if such has happened, and taking the proper measures\r
 448         // this code has a high priority and must not be stopped by any delay, so run it here\r
 449         if(self.predator.predator.classname == "player")\r
 450         {\r
 451                 entity target_predator, target_predator_predator, oldself;\r
 452                 target_predator = self.predator;\r
 453                 target_predator_predator = self.predator.predator;\r
 454 \r
 455                 Vore_Regurgitate(self);\r
 456 \r
 457                 // now steal our prey's prey if this probability applies\r
 458                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 459                 {\r
 460                         oldself = self;\r
 461                         self = target_predator_predator;\r
 462                         if(Swallow_condition_check(oldself))\r
 463                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 464                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 465                                 Vore_Swallow(oldself);\r
 466                         self = oldself;\r
 467                 }\r
 468         }\r
 469 \r
 470         // apply delays and skip the vore system under some circumstances\r
 471         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 472         {\r
 473                 Vore_Disconnect();\r
 474                 return;\r
 475         }\r
 476         if(self.spectatee_status)\r
 477                 return;\r
 478         if(time < self.system_delay)\r
 479                 return;\r
 480 \r
 481 // --------------------------------\r
 482 // Code that addresses predators:\r
 483 // --------------------------------\r
 484 \r
 485         entity prey;\r
 486         prey = Swallow_player_check();\r
 487 \r
 488         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 489         if(self.BUTTON_ATCK)\r
 490         if(Swallow_condition_check(prey))\r
 491                 Vore_Swallow(prey);\r
 492 \r
 493         // toggle digestion, if the player has someone in their stomach\r
 494         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 495         {\r
 496                 if(self.stomach_load)\r
 497                 {\r
 498                         if(time > self.digest_button_delay_time)\r
 499                         {\r
 500                                 self.digesting = !self.digesting;\r
 501                                 self.digest_button_delay_time = time + button_delay_time;\r
 502                         }\r
 503                 }\r
 504                 else if(time > self.complain_vore)\r
 505                 {\r
 506                         play2(self, "misc/unavailable.wav");\r
 507                         sprint(self, "There is nothing to digest\n");\r
 508                         self.complain_vore = time + complain_delay_time;\r
 509                 }\r
 510         }\r
 511         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 512                 self.digesting = FALSE;\r
 513 \r
 514         // predator wishes to regurgitate his prey\r
 515         if(self.BUTTON_REGURGITATE)\r
 516         {\r
 517                 if(self.stomach_load)\r
 518                 {\r
 519                         if(time > self.regurgitate_button_delay_time)\r
 520                         {\r
 521                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 522                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 523                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 524                         }\r
 525                 }\r
 526                 else if(time > self.complain_vore)\r
 527                 {\r
 528                         play2(self, "misc/unavailable.wav");\r
 529                         sprint(self, "There is nothing to regurgitate\n");\r
 530                         self.complain_vore = time + complain_delay_time;\r
 531                 }\r
 532         }\r
 533 \r
 534         if(cvar("g_vore_gurglesound"))\r
 535                 Vore_GurgleSound();\r
 536 \r
 537 // --------------------------------\r
 538 // Code that addresses the prey:\r
 539 // --------------------------------\r
 540 \r
 541         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 542         if(self.fakepredator.classname == "player")\r
 543         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 544                 Vore_DeadPrey_Detach(self);\r
 545 \r
 546         if(self.predator.classname != "player")\r
 547                 return;\r
 548 \r
 549         if(self.deadflag)\r
 550         {\r
 551                 Vore_PreyRelease(self);\r
 552                 return;\r
 553         }\r
 554 \r
 555         if(self.predator.deadflag)\r
 556                 Vore_Regurgitate(self);\r
 557         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 558                 Vore_Regurgitate(self);\r
 559 \r
 560         // apply delayed regurgitating if it was scheduled\r
 561         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 562         {\r
 563                 self.predator.regurgitate_prepare = 0;\r
 564                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 565                 Vore_Regurgitate(self);\r
 566         }\r
 567 \r
 568         // execute digesting and team healing\r
 569         if(self.predator.digesting == TRUE)\r
 570                 Vore_Digest();\r
 571         if(teams_matter && self.team == self.predator.team)\r
 572         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 573                 Vore_Teamheal();\r
 574 \r
 575         // execute prey commands\r
 576         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 577                 Vore_StomachKick();\r
 578         if(self.BUTTON_JUMP)\r
 579                 Vore_StomachLeave();\r
 580 \r
 581         Vore_CameraEffect_Apply();\r
 582 }