data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  42                 {\r
  43                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  44                         {\r
  45                                 play2(self, "misc/forbidden.wav");\r
  46                                 sprint(self, "You cannot swallow your team mates\n");\r
  47                                 self.complain_vore = time + complain_delay_time;\r
  48                         }\r
  49                         return FALSE;\r
  50                 }\r
  51 \r
  52                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  53                 {\r
  54                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  55                         {\r
  56                                 play2(self, "misc/forbidden.wav");\r
  57                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  58                                 self.complain_vore = time + complain_delay_time;\r
  59                         }\r
  60                         return FALSE;\r
  61                 }\r
  62 \r
  63                 if(cvar("g_vore_biggergut"))\r
  64                 if(prey.stomach_load > self.stomach_load)\r
  65                 {\r
  66                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  67                         {\r
  68                                 play2(self, "misc/forbidden.wav");\r
  69                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  70                                 self.complain_vore = time + complain_delay_time;\r
  71                         }\r
  72                         return FALSE;\r
  73                 }\r
  74 \r
  75                 if(!cvar("g_vore_spawnshield"))\r
  76                 if(prey.spawnshieldtime > time)\r
  77                 {\r
  78                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  79                         {\r
  80                                 play2(self, "misc/forbidden.wav");\r
  81                                 sprint(self, "You cannot swallow someone protected by the spawn shield\n");\r
  82                                 self.complain_vore = time + complain_delay_time;\r
  83                         }\r
  84                         return FALSE;\r
  85                 }\r
  86 \r
  87                 return TRUE;\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_TeamMates_check(entity pred)\r
  93 {\r
  94         // checks if a player's stomach contains any team mates\r
  95 \r
  96         entity head;\r
  97         if(teams_matter)\r
  98         {\r
  99                 FOR_EACH_PLAYER(head)\r
 100                 {\r
 101                         if(head.predator == pred && head.team == pred.team)\r
 102                                 return TRUE;\r
 103                 }\r
 104         }\r
 105         return FALSE;\r
 106 }\r
 107 \r
 108 float Vore_CanLeave()\r
 109 {\r
 110         if(self.predator.classname == "player")\r
 111         {\r
 112                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 113                         return TRUE;\r
 114                 if(teams_matter && self.team == self.predator.team)\r
 115                         return TRUE;\r
 116                 if(g_rpg && cvar("g_rpg_canleave"))\r
 117                         return TRUE;\r
 118         }\r
 119         return FALSE;\r
 120 }\r
 121 \r
 122 // make the camera smoothly lower itself when we get swallowed\r
 123 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
 124 .float cameraeffect_current, cameraeffect_target;\r
 125 void Vore_CameraEffect_Set(entity e)\r
 126 {\r
 127         e.cameraeffect_current = 1;\r
 128         e.cameraeffect_target = 2;\r
 129 }\r
 130 void Vore_CameraEffect_Apply()\r
 131 {\r
 132         if not(self.predator.classname == "player" || self.fakeprey)\r
 133                 return;\r
 134 \r
 135         if(self.cvar_cl_vore_cameraspeed)\r
 136         {\r
 137                 local float step;\r
 138                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 139 \r
 140                 // not sure if these maths are good, as the effect should be smoother\r
 141                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 142                         self.cameraeffect_current -= step;\r
 143                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 144                         self.cameraeffect_current += step;\r
 145         }\r
 146         else\r
 147                 self.cameraeffect_current = self.cameraeffect_target;\r
 148 \r
 149         self.view_ofs_z = PL_PREY_VIEW_OFS_z / self.cameraeffect_current;\r
 150         if(self.predator.scale)\r
 151                 self.view_ofs_z *= self.predator.scale;\r
 152 }\r
 153 \r
 154 .float gurgle_oldstomachload;\r
 155 void Vore_GurgleSound()\r
 156 {\r
 157         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 158         {\r
 159                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 160 \r
 161                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 162                 self.gurgle_oldstomachload = self.stomach_load;\r
 163         }\r
 164 }\r
 165 \r
 166 void Vore_WeightApply(entity e)\r
 167 {\r
 168         // apply stomach weight that makes you heavier the more you eat\r
 169         // slowing the player is done in cl_physics.qc\r
 170 \r
 171         if(e.stomach_load != e.vore_oldstomachload)\r
 172                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 173         if(e.gravity == 0)\r
 174                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 175         e.vore_oldstomachload = e.stomach_load;\r
 176 }\r
 177 \r
 178 void Vore_AutoDigest(entity e)\r
 179 {\r
 180         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 181 \r
 182         if(!cvar("g_vore_digestion") || e.digesting)\r
 183                 return;\r
 184         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 185                 return; // this feature is only for players, not bots\r
 186         if(e.stomach_load > 1)\r
 187                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 188         if(Stomach_TeamMates_check(e))\r
 189                 return; // never begin automatic digestion if we've swallowed a team mate\r
 190 \r
 191         e.digesting = TRUE;\r
 192 }\r
 193 \r
 194 .entity pusher;\r
 195 .float pushltime;\r
 196 void Vore_Swallow(entity e)\r
 197 {\r
 198         // this player is being swallowed by another player, apply the proper changes\r
 199 \r
 200         e.vore_oldmovetype = e.movetype;\r
 201         e.vore_oldsolid = e.solid;\r
 202 \r
 203         e.predator = self;\r
 204         setorigin(e, e.predator.origin);\r
 205         e.velocity = '0 0 0';\r
 206         e.movetype = MOVETYPE_FOLLOW;\r
 207         e.solid = SOLID_NOT;\r
 208         e.alpha = -1; // best way of hiding the eaten player\r
 209         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 210 \r
 211         // drop keys (KH) and flags (CTF) when we get swallowed\r
 212         kh_Key_DropAll(e, FALSE);\r
 213         if(e.flagcarried)\r
 214                 DropFlag(e.flagcarried, world, e.predator);\r
 215 \r
 216         Vore_CameraEffect_Set(e);\r
 217 \r
 218         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 219                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 220 \r
 221         if(teams_matter && e.team == e.predator.team)\r
 222         {\r
 223                 if(cvar("g_vore_kick"))\r
 224                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 225                 if(cvar("g_vore_digestion"))\r
 226                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 227         }\r
 228 \r
 229         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 230         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 231         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 232         e.predator.stomach_load += 1;\r
 233         e.predator.regurgitate_prepare = 0;\r
 234         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 235         Vore_WeightApply(e.predator);\r
 236         Vore_AutoDigest(e.predator);\r
 237 \r
 238         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 239         e.predator.weapon_delay = time + button_delay_time;\r
 240         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 241         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 242 }\r
 243 \r
 244 void Vore_Regurgitate(entity e)\r
 245 {\r
 246         // this player is being regurgitated by their predator, apply the proper changes\r
 247 \r
 248         e.movetype = e.vore_oldmovetype;\r
 249         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 250                 e.solid = e.vore_oldsolid;\r
 251         e.view_ofs_z = PL_VIEW_OFS_z;\r
 252         e.alpha = default_player_alpha;\r
 253 \r
 254         // apply velocities\r
 255         local vector oldforward, oldright, oldup;\r
 256         oldforward = v_forward;\r
 257         oldright = v_right;\r
 258         oldup = v_up;\r
 259         makevectors(e.predator.v_angle);\r
 260         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 261         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 262         v_forward = oldforward;\r
 263         v_right = oldright;\r
 264         v_up = oldup;\r
 265 \r
 266         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 267         e.pushltime = time + cvar("g_maxpushtime");\r
 268 \r
 269         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 270         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 271         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 272         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 273         e.predator.stomach_load -= 1;\r
 274         e.predator.regurgitate_prepare = 0;\r
 275         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 276         Vore_WeightApply(e.predator);\r
 277 \r
 278         // block firing for a small amount of time, or we'll be firing the next frame\r
 279         e.weapon_delay = time + button_delay_time;\r
 280         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 281         e.predator = world;\r
 282 }\r
 283 \r
 284 void Vore_DeadPrey_Configure(entity e)\r
 285 {\r
 286         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 287 \r
 288         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 289                 return;\r
 290 \r
 291         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 292         e.fakepredator = e.predator;\r
 293         e.fakeprey = TRUE;\r
 294 \r
 295         // first release the prey from the predator, as dead prey needs to be attached differently\r
 296         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 297         e.predator.stomach_load -= 1;\r
 298         Vore_WeightApply(e.predator);\r
 299         e.predator = world;\r
 300 \r
 301         // now put our dead prey inside the predator's stomach, but only as an effect\r
 302         e.movetype = MOVETYPE_FOLLOW;\r
 303         e.takedamage = DAMAGE_NO;\r
 304         e.solid = SOLID_NOT;\r
 305         e.aiment = e.fakepredator;\r
 306 \r
 307         // completely remove the dead body\r
 308         e.modelindex = 0;\r
 309 }\r
 310 \r
 311 void Vore_DeadPrey_Detach(entity e)\r
 312 {\r
 313         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 314         // should only execute after Vore_DeadPrey_Configure has ran first\r
 315 \r
 316         if not(cvar("g_vore_keepdeadprey"))\r
 317                 return;\r
 318 \r
 319         e.fakepredator = world;\r
 320         e.fakeprey = FALSE;\r
 321         e.aiment = world;\r
 322         e.movetype = MOVETYPE_TOSS;\r
 323 }\r
 324 \r
 325 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 326 {\r
 327         if(pred_disconnect)\r
 328         {\r
 329                 if(e.fakeprey)\r
 330                         Vore_DeadPrey_Detach(e);\r
 331                 else\r
 332                         Vore_Regurgitate(e);\r
 333         }\r
 334         else\r
 335         {\r
 336                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 337                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 338                         Vore_DeadPrey_Configure(e);\r
 339                 else\r
 340                         Vore_Regurgitate(e);\r
 341         }\r
 342 }\r
 343 \r
 344 void Vore_Disconnect()\r
 345 {\r
 346         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 347 \r
 348         // prey disconnects or goes spectating while inside someone's belly\r
 349         if(self.predator.classname == "player")\r
 350                 Vore_PreyRelease(self, TRUE);\r
 351 \r
 352         // pred disconnects or goes spectating with players in their belly\r
 353         entity head;\r
 354         FOR_EACH_PLAYER(head)\r
 355         {\r
 356                 if(head.predator == self || head.fakepredator == self)\r
 357                         Vore_PreyRelease(head, TRUE);\r
 358         }\r
 359         Vore_GurgleSound(); // stop the gurgling sound\r
 360 \r
 361         self.stomach_load = self.gravity = 0; // prevents a bug\r
 362 }\r
 363 \r
 364 .float digestion_step;\r
 365 void Vore_Digest()\r
 366 {\r
 367         // apply digestion to prey\r
 368 \r
 369         if(time > self.predator.digestion_step)\r
 370         {\r
 371                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 372                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 373                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 374 \r
 375                 if (self.predator.digestsound_finished < time)\r
 376                 {\r
 377                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 378                         self.predator.digestsound_finished = time + 0.5;\r
 379                 }\r
 380                 self.predator.digestion_step = time + steptime;\r
 381         }\r
 382 \r
 383         if(self.deadflag != DEAD_NO)\r
 384         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 385                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 386 }\r
 387 \r
 388 .float teamheal_step;\r
 389 void Vore_Teamheal()\r
 390 {\r
 391         // apply teamheal\r
 392 \r
 393         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 394         if(time > self.teamheal_step)\r
 395         {\r
 396                 self.health += cvar("g_balance_vore_teamheal");\r
 397                 self.teamheal_step = time + steptime;\r
 398 \r
 399                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 400                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 401                 {\r
 402                         play2(self, "misc/beep.wav");\r
 403                         play2(self.predator, "misc/beep.wav");\r
 404                 }\r
 405         }\r
 406 }\r
 407 \r
 408 .float stomachkick_delay;\r
 409 void Vore_StomachKick()\r
 410 {\r
 411         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 412 \r
 413         if(time > self.stomachkick_delay)\r
 414         {\r
 415                 float damage;\r
 416                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 417 \r
 418                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 419                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 420                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 421                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 422 \r
 423                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 424                         Vore_Regurgitate(self);\r
 425 \r
 426                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 427         }\r
 428 }\r
 429 \r
 430 void Vore_StomachLeave()\r
 431 {\r
 432         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 433 \r
 434         if(Vore_CanLeave())\r
 435                 Vore_Regurgitate(self);\r
 436         else if(time > self.complain_vore)\r
 437         {\r
 438                 play2(self, "misc/forbidden.wav");\r
 439                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 440                 self.complain_vore = time + complain_delay_time;\r
 441         }\r
 442 }\r
 443 \r
 444 void Vore_AutoTaunt()\r
 445 {\r
 446         // triggers ambient vore taunts, for both pred and prey\r
 447 \r
 448         float taunt_time;\r
 449 \r
 450         // predator taunts\r
 451         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 452         {\r
 453                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 454                 {\r
 455                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 456                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 457                 }\r
 458         }\r
 459         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 460         {\r
 461                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 462                 SetAutoTaunt(self, 0, 0);\r
 463         }\r
 464 \r
 465         // prey taunts\r
 466         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 467         {\r
 468                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 469                 {\r
 470                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 471                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 472                 }\r
 473         }\r
 474         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 475         {\r
 476                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 477                 SetAutoTaunt(self, 0, 0);\r
 478         }\r
 479 }\r
 480 \r
 481 void Vore()\r
 482 {\r
 483         // main vore code, this is where it all happens\r
 484 \r
 485         if(!cvar("g_vore")) // the vore system is disabled\r
 486         {\r
 487                 Vore_Disconnect();\r
 488                 return;\r
 489         }\r
 490 \r
 491         Vore_AutoTaunt();\r
 492 \r
 493         // wash the goo away from players once they leave the stomach\r
 494         if(self.predator.classname != "player")\r
 495         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 496         if(self.colormod)\r
 497         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 498         {\r
 499                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 500                 if(self.colormod_x > 1)\r
 501                         self.colormod_x = 1;\r
 502                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 503                 if(self.colormod_y > 1)\r
 504                         self.colormod_y = 1;\r
 505                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 506                 if(self.colormod_z > 1)\r
 507                         self.colormod_z = 1;\r
 508         }\r
 509 \r
 510         // set all vore stats\r
 511         if(self.fakeprey)\r
 512                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 513         else if(self.predator.classname == "player")\r
 514         {\r
 515                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 516                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 517                 self.stat_eaten = num_for_edict(self.predator);\r
 518         }\r
 519         else\r
 520         {\r
 521                 self.stat_stomachload = self.stomach_load;\r
 522                 self.stat_digesting = self.digesting;\r
 523                 self.stat_eaten = 0;\r
 524         }\r
 525         self.stat_canleave = Vore_CanLeave();\r
 526 \r
 527         // don't allow a player inside a player inside another player :)\r
 528         // prevent this by checking if such has happened, and taking the proper measures\r
 529         // this code has a high priority and must not be stopped by any delay, so run it here\r
 530         if(self.predator.predator.classname == "player")\r
 531         {\r
 532                 entity target_predator, target_predator_predator, oldself;\r
 533                 target_predator = self.predator;\r
 534                 target_predator_predator = self.predator.predator;\r
 535 \r
 536                 Vore_Regurgitate(self);\r
 537 \r
 538                 // now steal our prey's prey if this probability applies\r
 539                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 540                 {\r
 541                         oldself = self;\r
 542                         self = target_predator_predator;\r
 543                         if(Swallow_condition_check(oldself))\r
 544                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 545                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 546                                 Vore_Swallow(oldself);\r
 547                         self = oldself;\r
 548                 }\r
 549         }\r
 550 \r
 551         // apply delays and skip the vore system under some circumstances\r
 552         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 553         {\r
 554                 Vore_Disconnect();\r
 555                 return;\r
 556         }\r
 557         if(self.spectatee_status)\r
 558                 return;\r
 559         if(time < self.system_delay)\r
 560                 return;\r
 561 \r
 562 // --------------------------------\r
 563 // Code that addresses predators:\r
 564 // --------------------------------\r
 565 \r
 566         entity prey;\r
 567         prey = Swallow_player_check();\r
 568 \r
 569         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 570         self.stat_canswallow = 0;\r
 571         if(Swallow_condition_check(prey))\r
 572         {\r
 573                 // canswallow stat, used by the HUD\r
 574                 if(teams_matter && prey.team == self.team)\r
 575                         self.stat_canswallow = 2;\r
 576                 else\r
 577                         self.stat_canswallow = 1;\r
 578 \r
 579                 if(self.BUTTON_ATCK)\r
 580                         Vore_Swallow(prey);\r
 581         }\r
 582         else if(prey != world)\r
 583                 self.stat_canswallow = -1;\r
 584 \r
 585         // toggle digestion, if the player has someone in their stomach\r
 586         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 587         {\r
 588                 if(self.stomach_load)\r
 589                 {\r
 590                         if(time > self.digest_button_delay_time)\r
 591                         {\r
 592                                 self.digesting = !self.digesting;\r
 593                                 self.digest_button_delay_time = time + button_delay_time;\r
 594                         }\r
 595                 }\r
 596                 else if(time > self.complain_vore)\r
 597                 {\r
 598                         play2(self, "misc/forbidden.wav");\r
 599                         sprint(self, "There is nothing to digest\n");\r
 600                         self.complain_vore = time + complain_delay_time;\r
 601                 }\r
 602         }\r
 603         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 604                 self.digesting = FALSE;\r
 605 \r
 606         // predator wishes to regurgitate his prey\r
 607         if(self.BUTTON_REGURGITATE)\r
 608         {\r
 609                 if(self.stomach_load)\r
 610                 {\r
 611                         if(time > self.regurgitate_button_delay_time)\r
 612                         {\r
 613                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 614                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 615                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 616                         }\r
 617                 }\r
 618                 else if(time > self.complain_vore)\r
 619                 {\r
 620                         play2(self, "misc/forbidden.wav");\r
 621                         sprint(self, "There is nothing to regurgitate\n");\r
 622                         self.complain_vore = time + complain_delay_time;\r
 623                 }\r
 624         }\r
 625 \r
 626         if(cvar("g_vore_gurglesound"))\r
 627                 Vore_GurgleSound();\r
 628 \r
 629 // --------------------------------\r
 630 // Code that addresses the prey:\r
 631 // --------------------------------\r
 632 \r
 633         Vore_CameraEffect_Apply();\r
 634 \r
 635         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 636         if(self.fakepredator.classname == "player")\r
 637         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 638                 Vore_DeadPrey_Detach(self);\r
 639 \r
 640         if(self.predator.classname != "player")\r
 641                 return;\r
 642 \r
 643         if(self.deadflag != DEAD_NO)\r
 644         {\r
 645                 Vore_PreyRelease(self, FALSE);\r
 646                 return;\r
 647         }\r
 648 \r
 649         if(self.predator.deadflag != DEAD_NO)\r
 650                 Vore_Regurgitate(self);\r
 651         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 652                 Vore_Regurgitate(self);\r
 653 \r
 654         // apply delayed regurgitating if it was scheduled\r
 655         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 656         {\r
 657                 self.predator.regurgitate_prepare = 0;\r
 658                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 659                 Vore_Regurgitate(self);\r
 660         }\r
 661 \r
 662         // execute digesting and team healing\r
 663         if(self.predator.digesting == TRUE)\r
 664                 Vore_Digest();\r
 665         if(teams_matter && self.team == self.predator.team)\r
 666         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 667                 Vore_Teamheal();\r
 668 \r
 669         // execute prey commands\r
 670         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 671                 Vore_StomachKick();\r
 672         if(self.BUTTON_JUMP)\r
 673                 Vore_StomachLeave();\r
 674 \r
 675         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 676         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 677         kh_Key_DropAll(self, FALSE);\r
 678 }