data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetCamera()\r
 100 {\r
 101         /*if not(self.stat_eaten)\r
 102                 return;*/\r
 103 \r
 104         local entity head;\r
 105         local vector oldforward, oldright, oldup;\r
 106         local float position_counter;\r
 107         local vector origin_apply;\r
 108         oldforward = v_forward;\r
 109         oldright = v_right;\r
 110         oldup = v_up;\r
 111 \r
 112         makevectors(self.v_angle);\r
 113         v_forward_z = 0;\r
 114 \r
 115         FOR_EACH_PLAYER(head)\r
 116         {\r
 117                 if(head.predator == self)\r
 118                 {\r
 119                         switch(position_counter)\r
 120                         {\r
 121                                 case 0:\r
 122                                         break;\r
 123                                 case 1:\r
 124                                         origin_apply = '1 0 0';\r
 125                                         break;\r
 126                                 default:\r
 127                                         break;\r
 128                         }\r
 129                         head.view_ofs = PL_PREY_VIEW_OFS + (v_forward + origin_apply * 16);\r
 130                         position_counter += 1;\r
 131                 }\r
 132         }\r
 133 \r
 134         v_forward = oldforward;\r
 135         v_right = oldright;\r
 136         v_up = oldup;\r
 137 \r
 138         /*float prey_height;\r
 139         if(self.fakeprey)\r
 140                 prey_height = (self.scale - self.fakepredator.scale) * cvar("g_healthsize_vore_pos");\r
 141         else\r
 142                 prey_height = (self.scale - self.predator.scale) * cvar("g_healthsize_vore_pos");\r
 143         self.view_ofs_z += prey_height;*/\r
 144 }\r
 145 \r
 146 .float gurgle_oldstomachload;\r
 147 void Vore_GurgleSound()\r
 148 {\r
 149         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 150         {\r
 151                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 152 \r
 153                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 154                 self.gurgle_oldstomachload = self.stomach_load;\r
 155         }\r
 156 }\r
 157 \r
 158 void Vore_WeightApply(entity e)\r
 159 {\r
 160         // apply stomach weight that makes you heavier the more you eat\r
 161         // slowing the player is done in cl_physics.qc\r
 162 \r
 163         if(e.stomach_load != e.vore_oldstomachload)\r
 164                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 165         if(e.gravity == 0)\r
 166                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 167         e.vore_oldstomachload = e.stomach_load;\r
 168 }\r
 169 \r
 170 void Vore_AutoDigest(entity e)\r
 171 {\r
 172         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 173 \r
 174         if(!cvar("g_vore_digestion") || e.digesting)\r
 175                 return;\r
 176         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 177                 return; // this feature is only for players, not bots\r
 178         if(e.stomach_load > 1)\r
 179                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 180         if(Stomach_TeamMates_check(e))\r
 181                 return; // never begin automatic digestion if we've swallowed a team mate\r
 182 \r
 183         e.digesting = TRUE;\r
 184 }\r
 185 \r
 186 .entity pusher;\r
 187 .float pushltime;\r
 188 void Vore_Swallow(entity e)\r
 189 {\r
 190         // this player is being swallowed by another player, apply the proper changes\r
 191 \r
 192         e.vore_oldmovetype = e.movetype;\r
 193         e.vore_oldsolid = e.solid;\r
 194 \r
 195         e.predator = self;\r
 196         setorigin(e, e.predator.origin);\r
 197         e.velocity = '0 0 0';\r
 198         e.movetype = MOVETYPE_FOLLOW;\r
 199         e.solid = SOLID_NOT;\r
 200         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 201 \r
 202         // drop keys (KH) and flags (CTF) when we get swallowed\r
 203         kh_Key_DropAll(e, FALSE);\r
 204         if(e.flagcarried)\r
 205                 DropFlag(e.flagcarried, world, e.predator);\r
 206 \r
 207         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 208                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 209 \r
 210         if(teams_matter && e.team == e.predator.team)\r
 211         {\r
 212                 if(cvar("g_vore_kick"))\r
 213                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 214                 if(cvar("g_vore_digestion"))\r
 215                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 216         }\r
 217 \r
 218         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 219         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 220         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 221         e.predator.stomach_load += 1;\r
 222         e.predator.regurgitate_prepare = 0;\r
 223         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 224         Vore_WeightApply(e.predator);\r
 225         Vore_AutoDigest(e.predator);\r
 226 \r
 227         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 228         e.predator.weapon_delay = time + button_delay_time;\r
 229         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 230         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 231         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 232 }\r
 233 \r
 234 void Vore_Regurgitate(entity e)\r
 235 {\r
 236         // this player is being regurgitated by their predator, apply the proper changes\r
 237 \r
 238         e.movetype = e.vore_oldmovetype;\r
 239         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 240                 e.solid = e.vore_oldsolid;\r
 241         e.view_ofs_z = PL_VIEW_OFS_z;\r
 242 \r
 243         // apply velocities\r
 244         local vector oldforward, oldright, oldup;\r
 245         oldforward = v_forward;\r
 246         oldright = v_right;\r
 247         oldup = v_up;\r
 248         makevectors(e.predator.v_angle);\r
 249         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 250         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 251         v_forward = oldforward;\r
 252         v_right = oldright;\r
 253         v_up = oldup;\r
 254 \r
 255         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 256         e.pushltime = time + cvar("g_maxpushtime");\r
 257 \r
 258         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 259         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 260         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 261         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 262         e.predator.stomach_load -= 1;\r
 263         e.predator.regurgitate_prepare = 0;\r
 264         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 265         Vore_WeightApply(e.predator);\r
 266 \r
 267         // block firing for a small amount of time, or we'll be firing the next frame\r
 268         e.weapon_delay = time + button_delay_time;\r
 269         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 270         e.predator = world;\r
 271 }\r
 272 \r
 273 void Vore_DeadPrey_Configure(entity e)\r
 274 {\r
 275         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 276 \r
 277         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 278                 return;\r
 279 \r
 280         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 281         e.fakepredator = e.predator;\r
 282         e.fakeprey = TRUE;\r
 283 \r
 284         // first release the prey from the predator, as dead prey needs to be attached differently\r
 285         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 286         e.predator.stomach_load -= 1;\r
 287         Vore_WeightApply(e.predator);\r
 288         e.predator = world;\r
 289 \r
 290         // now put our dead prey inside the predator's stomach, but only as an effect\r
 291         e.movetype = MOVETYPE_FOLLOW;\r
 292         e.takedamage = DAMAGE_NO;\r
 293         e.solid = SOLID_NOT;\r
 294         e.aiment = e.fakepredator;\r
 295 }\r
 296 \r
 297 void Vore_DeadPrey_Detach(entity e)\r
 298 {\r
 299         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 300         // should only execute after Vore_DeadPrey_Configure has ran first\r
 301 \r
 302         if not(cvar("g_vore_keepdeadprey"))\r
 303                 return;\r
 304 \r
 305         e.fakepredator = world;\r
 306         e.fakeprey = TRUE; // keep fakeprey status\r
 307         e.stat_eaten = 0;\r
 308         e.aiment = world;\r
 309         e.movetype = MOVETYPE_TOSS;\r
 310 }\r
 311 \r
 312 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 313 {\r
 314         if(pred_disconnect)\r
 315         {\r
 316                 if(e.fakeprey)\r
 317                         Vore_DeadPrey_Detach(e);\r
 318                 else\r
 319                         Vore_Regurgitate(e);\r
 320         }\r
 321         else if(self.stat_eaten && !self.fakeprey)\r
 322         {\r
 323                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 324                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 325                         Vore_DeadPrey_Configure(e);\r
 326                 else\r
 327                         Vore_Regurgitate(e);\r
 328         }\r
 329 }\r
 330 \r
 331 void Vore_Disconnect()\r
 332 {\r
 333         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 334 \r
 335         // prey disconnects or goes spectating while inside someone's belly\r
 336         if(self.stat_eaten)\r
 337                 Vore_PreyRelease(self, TRUE);\r
 338 \r
 339         // pred disconnects or goes spectating with players in their belly\r
 340         entity head;\r
 341         FOR_EACH_PLAYER(head)\r
 342         {\r
 343                 if(head.predator == self || head.fakepredator == self)\r
 344                         Vore_PreyRelease(head, TRUE);\r
 345         }\r
 346         Vore_GurgleSound(); // stop the gurgling sound\r
 347 \r
 348         self.stomach_load = self.gravity = 0; // prevents a bug\r
 349 }\r
 350 \r
 351 .float digestion_step;\r
 352 void Vore_Digest()\r
 353 {\r
 354         // apply digestion to prey\r
 355 \r
 356         if(time > self.predator.digestion_step)\r
 357         {\r
 358                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 359                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 360                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 361 \r
 362                 if (self.predator.digestsound_finished < time)\r
 363                 {\r
 364                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 365                         self.predator.digestsound_finished = time + 0.5;\r
 366                 }\r
 367                 self.predator.digestion_step = time + steptime;\r
 368         }\r
 369 \r
 370         if(self.deadflag != DEAD_NO)\r
 371         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 372                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 373 }\r
 374 \r
 375 .float teamheal_step;\r
 376 void Vore_Teamheal()\r
 377 {\r
 378         // apply teamheal\r
 379 \r
 380         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 381         if(time > self.teamheal_step)\r
 382         {\r
 383                 self.health += cvar("g_balance_vore_teamheal");\r
 384                 self.teamheal_step = time + steptime;\r
 385 \r
 386                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 387                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 388                 {\r
 389                         play2(self, "misc/beep.wav");\r
 390                         play2(self.predator, "misc/beep.wav");\r
 391                 }\r
 392         }\r
 393 }\r
 394 \r
 395 void Vore_StomachKick()\r
 396 {\r
 397         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 398 \r
 399         if(time > self.stomachkick_delay)\r
 400         {\r
 401                 float damage;\r
 402                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 403 \r
 404                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 405                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 406                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 407                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 408 \r
 409                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 410                         Vore_Regurgitate(self);\r
 411 \r
 412                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 413         }\r
 414 }\r
 415 \r
 416 void Vore_StomachLeave()\r
 417 {\r
 418         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 419 \r
 420         if(Vore_CanLeave())\r
 421                 Vore_Regurgitate(self);\r
 422         else if(time > self.complain_vore)\r
 423         {\r
 424                 play2(self, "misc/forbidden.wav");\r
 425                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 426                 self.complain_vore = time + complain_delay_time;\r
 427         }\r
 428 }\r
 429 \r
 430 void Vore_AutoTaunt()\r
 431 {\r
 432         // triggers ambient vore taunts, for both pred and prey\r
 433 \r
 434         float taunt_time;\r
 435 \r
 436         // predator taunts\r
 437         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 438         {\r
 439                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 440                 {\r
 441                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 442                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 443                 }\r
 444         }\r
 445         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 446         {\r
 447                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 448                 SetAutoTaunt(self, 0, 0);\r
 449         }\r
 450 \r
 451         // prey taunts\r
 452         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 453         {\r
 454                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 455                 {\r
 456                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 457                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 458                 }\r
 459         }\r
 460         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 461         {\r
 462                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 463                 SetAutoTaunt(self, 0, 0);\r
 464         }\r
 465 }\r
 466 \r
 467 void Vore_SetSbarRings()\r
 468 {\r
 469         // first clear the ring stats, then configure them if needed\r
 470         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 471         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 472 \r
 473         if(self.stat_eaten)\r
 474         {\r
 475                 if(time <= self.stomachkick_delay)\r
 476                 {\r
 477                         self.stat_sbring1_type = 2; // ring shows stomach kick delay, empties with progress\r
 478                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 479                 }\r
 480         }\r
 481         else\r
 482         {\r
 483                 if(time <= self.action_delay)\r
 484                 {\r
 485                         self.stat_sbring1_type = 1; // ring shows vore action delay, empties with progress\r
 486                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 487                 }\r
 488                 if(time <= self.regurgitate_prepare)\r
 489                 {\r
 490                         self.stat_sbring2_type = 1; // ring shows regurgitation preparing, fills with progress\r
 491                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 492                 }\r
 493         }\r
 494 }\r
 495 \r
 496 void Vore()\r
 497 {\r
 498         // main vore code, this is where it all happens\r
 499 \r
 500         if(!cvar("g_vore")) // the vore system is disabled\r
 501         {\r
 502                 Vore_Disconnect();\r
 503                 return;\r
 504         }\r
 505 \r
 506         Vore_AutoTaunt();\r
 507 \r
 508         // wash the goo away from players once they leave the stomach\r
 509         if(!self.stat_eaten)\r
 510         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 511         if(self.colormod)\r
 512         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 513         {\r
 514                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 515                 if(self.colormod_x > 1)\r
 516                         self.colormod_x = 1;\r
 517                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 518                 if(self.colormod_y > 1)\r
 519                         self.colormod_y = 1;\r
 520                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 521                 if(self.colormod_z > 1)\r
 522                         self.colormod_z = 1;\r
 523         }\r
 524 \r
 525         // set all vore stats\r
 526         Vore_SetSbarRings();\r
 527         if(self.fakepredator.classname == "player")\r
 528                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 529         else if(self.predator.classname == "player")\r
 530         {\r
 531                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 532                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 533                 self.stat_eaten = num_for_edict(self.predator);\r
 534         }\r
 535         else\r
 536         {\r
 537                 self.stat_stomachload = self.stomach_load;\r
 538                 self.stat_digesting = self.digesting;\r
 539                 self.stat_eaten = 0;\r
 540         }\r
 541         self.stat_canleave = Vore_CanLeave();\r
 542 \r
 543         // don't allow a player inside a player inside another player :)\r
 544         // prevent this by checking if such has happened, and taking the proper measures\r
 545         // this code has a high priority and must not be stopped by any delay, so run it here\r
 546         if(self.predator.stat_eaten)\r
 547         {\r
 548                 entity target_predator, target_predator_predator, oldself;\r
 549                 target_predator = self.predator;\r
 550                 target_predator_predator = self.predator.predator;\r
 551 \r
 552                 Vore_Regurgitate(self);\r
 553 \r
 554                 // now steal our prey's prey if this probability applies\r
 555                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 556                 {\r
 557                         oldself = self;\r
 558                         self = target_predator_predator;\r
 559                         if(Swallow_condition_check(oldself))\r
 560                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 561                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 562                                 Vore_Swallow(oldself);\r
 563                         self = oldself;\r
 564                 }\r
 565         }\r
 566 \r
 567         // apply delays and skip the vore system under some circumstances\r
 568         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 569         {\r
 570                 Vore_Disconnect();\r
 571                 return;\r
 572         }\r
 573         if(self.spectatee_status)\r
 574                 return;\r
 575         if(time < self.system_delay)\r
 576                 return;\r
 577 \r
 578 // --------------------------------\r
 579 // Code that addresses predators:\r
 580 // --------------------------------\r
 581 \r
 582         entity prey;\r
 583         prey = Swallow_player_check();\r
 584 \r
 585         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 586         self.stat_canswallow = 0;\r
 587         if(Swallow_condition_check(prey))\r
 588         {\r
 589                 // canswallow stat, used by the HUD\r
 590                 if(teams_matter && prey.team == self.team)\r
 591                         self.stat_canswallow = 2;\r
 592                 else\r
 593                         self.stat_canswallow = 1;\r
 594 \r
 595                 if(self.BUTTON_ATCK)\r
 596                         Vore_Swallow(prey);\r
 597         }\r
 598         else if(prey != world)\r
 599                 self.stat_canswallow = -1;\r
 600 \r
 601         // toggle digestion, if the player has someone in their stomach\r
 602         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 603         {\r
 604                 if(self.stomach_load)\r
 605                 {\r
 606                         if(time > self.digest_button_delay_time)\r
 607                         {\r
 608                                 self.digesting = !self.digesting;\r
 609                                 self.digest_button_delay_time = time + button_delay_time;\r
 610                         }\r
 611                 }\r
 612                 else if(time > self.complain_vore)\r
 613                 {\r
 614                         play2(self, "misc/forbidden.wav");\r
 615                         sprint(self, "There is nothing to digest\n");\r
 616                         self.complain_vore = time + complain_delay_time;\r
 617                 }\r
 618         }\r
 619         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 620                 self.digesting = FALSE;\r
 621 \r
 622         // predator wishes to regurgitate his prey\r
 623         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 624         {\r
 625                 if(self.stomach_load)\r
 626                 {\r
 627                         if(time > self.regurgitate_button_delay_time)\r
 628                         {\r
 629                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 630                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 631                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 632                         }\r
 633                 }\r
 634                 else if(time > self.complain_vore)\r
 635                 {\r
 636                         play2(self, "misc/forbidden.wav");\r
 637                         sprint(self, "There is nothing to regurgitate\n");\r
 638                         self.complain_vore = time + complain_delay_time;\r
 639                 }\r
 640         }\r
 641 \r
 642         if(cvar("g_vore_gurglesound"))\r
 643                 Vore_GurgleSound();\r
 644 \r
 645 // --------------------------------\r
 646 // Code that addresses the prey:\r
 647 // --------------------------------\r
 648 \r
 649         Vore_SetCamera();\r
 650 \r
 651         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 652         if(self.fakeprey)\r
 653         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 654                 Vore_DeadPrey_Detach(self);\r
 655 \r
 656         if(!self.stat_eaten)\r
 657                 return;\r
 658 \r
 659         if(self.deadflag != DEAD_NO)\r
 660         {\r
 661                 Vore_PreyRelease(self, FALSE);\r
 662                 return;\r
 663         }\r
 664 \r
 665         if(self.predator.deadflag != DEAD_NO)\r
 666                 Vore_Regurgitate(self);\r
 667         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 668                 Vore_Regurgitate(self);\r
 669 \r
 670         // apply delayed regurgitating if it was scheduled\r
 671         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 672         {\r
 673                 self.predator.regurgitate_prepare = 0;\r
 674                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 675                 Vore_Regurgitate(self);\r
 676         }\r
 677 \r
 678         // execute digesting and team healing\r
 679         if(self.predator.digesting == TRUE)\r
 680                 Vore_Digest();\r
 681         if(teams_matter && self.team == self.predator.team)\r
 682         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 683                 Vore_Teamheal();\r
 684 \r
 685         // execute prey commands\r
 686         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 687                 Vore_StomachKick();\r
 688         if(self.BUTTON_JUMP)\r
 689                 Vore_StomachLeave();\r
 690 \r
 691         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 692         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 693         kh_Key_DropAll(self, FALSE);\r
 694 }