data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float swallow_delay, digest_button_delay, regurgitate_button_delay;\r
   3 .float complain_swallow;\r
   4 const float complain_delay = 1;\r
   5 const float button_delay = 0.5;\r
   6 const float steptime = 0.1;\r
   7 \r
   8 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   9 \r
  10 entity Swallow_distance_check()\r
  11 {\r
  12         // check if we can swallow a player instead of firing our weapon\r
  13         vector w_shotorg, w_shotdir;\r
  14         w_shotorg = self.origin + self.view_ofs;\r
  15         w_shotdir = v_forward;\r
  16 \r
  17         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  18         if(trace_fraction < 1)\r
  19         if(trace_ent.classname == "player")\r
  20                 return trace_ent;\r
  21         return world;\r
  22 }\r
  23 \r
  24 float Swallow_condition_check(entity prey)\r
  25 {\r
  26         // checks the necessary conditions for swallowing another player\r
  27         if(prey.classname == "player" && prey.eater.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  28         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_velocitylimit"))\r
  29         if(self.eater.classname != "player") // we can't swallow players while inside someone's stomach ourselves\r
  30         {\r
  31                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  32                 {\r
  33                         if(time > self.complain_swallow)\r
  34                         {\r
  35                                 play2(self, "weapons/unavailable.wav");\r
  36                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  37                                 self.complain_swallow = time + complain_delay;\r
  38                         }\r
  39                         return FALSE;\r
  40                 }\r
  41 \r
  42                 if(cvar("g_vore_biggergut"))\r
  43                 if(prey.stomach_load > self.stomach_load)\r
  44                 {\r
  45                         if(time > self.complain_swallow)\r
  46                         {\r
  47                                 play2(self, "weapons/unavailable.wav");\r
  48                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  49                                 self.complain_swallow = time + complain_delay;\r
  50                         }\r
  51                         return FALSE;\r
  52                 }\r
  53                 return TRUE;\r
  54         }\r
  55         return FALSE;\r
  56 }\r
  57 \r
  58 void Vore_Weight_apply(entity e)\r
  59 {\r
  60         // apply stomach weight that makes you heavier the more you eat\r
  61         // slowing the player is applied in cl_physics.qc\r
  62         if(e.stomach_load != e.vore_oldstomachload)\r
  63                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
  64         if(e.gravity == 0)\r
  65                 e.gravity = 0.00001; // 0 becomes 1 for .gravity, so do this to allow 0 gravity\r
  66         e.vore_oldstomachload = e.stomach_load;\r
  67 }\r
  68 \r
  69 void Vore_Swallow(entity e)\r
  70 {\r
  71         // this player is beening swallowed by another player, apply the proper changes\r
  72         e.vore_oldmovetype = e.movetype;\r
  73         e.vore_oldsolid = e.solid;\r
  74 \r
  75         setorigin(e, e.eater.origin);\r
  76         e.velocity = '0 0 0';\r
  77         e.movetype = MOVETYPE_FOLLOW;\r
  78         e.solid = SOLID_NOT;\r
  79         e.alpha = -1; // best way of hiding / showing the eaten player\r
  80         e.aiment = e.eater; // follow the predator. Is automatically unset\r
  81         e.view_ofs_z /= 2; // best positioning for the stomach model\r
  82         e.stat_eaten = TRUE;\r
  83 \r
  84         // drop keys (KH) and flags (CTF) when we get swallowed\r
  85         kh_Key_DropAll(e, FALSE);\r
  86         if(e.flagcarried)\r
  87                 DropFlag(e.flagcarried, world, e.eater);\r
  88 \r
  89         if(stov(cvar_string("g_vore_regurgitatecolor_released")))\r
  90                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_released"));\r
  91 \r
  92         PlayerSound(e.eater, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
  93         setanim(e.eater, e.eater.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing \ regurgitating\r
  94         e.eater.stomach_load += 1;\r
  95         e.eater.regurgitate_prepare = 0;\r
  96         Vore_Weight_apply(e.eater);\r
  97 }\r
  98 \r
  99 void Vore_Regurgitate(entity e)\r
 100 {\r
 101         // this player is being released from their predator, apply the proper changes\r
 102         e.movetype = e.vore_oldmovetype;\r
 103         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 104                 e.solid = e.vore_oldsolid;\r
 105         e.alpha = 0; // best way of hiding / showing the eaten player\r
 106         e.view_ofs_z *= 2; // best positioning for the stomach model\r
 107         e.stat_eaten = FALSE;\r
 108 \r
 109         PlayerSound(e.eater, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 110         setanim(e.eater, e.eater.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing \ regurgitating\r
 111         pointparticles(particleeffectnum("regurgitate"), e.eater.origin, '0 0 0', 1);\r
 112         e.eater.stomach_load -= 1;\r
 113         e.eater.regurgitate_prepare = 0;\r
 114         Vore_Weight_apply(e.eater);\r
 115         e.eater = world;\r
 116 }\r
 117 \r
 118 void Vore_Disconnect()\r
 119 {\r
 120         // frees prey from their predators when someone disconnects or goes spectating\r
 121 \r
 122         // prey disconnects or goes spectating while inside someone's belly:\r
 123         if(self.eater.classname == "player")\r
 124         {\r
 125                 self.view_ofs_z += 25;\r
 126                 self.stat_eaten = FALSE;\r
 127                 self.eater.stomach_load -= 1;\r
 128                 Vore_Weight_apply(self.eater);\r
 129                 self.eater = world;\r
 130         }\r
 131 \r
 132         // pred disconnects or goes spectating with players in their belly:\r
 133         else if(self.stomach_load > 0)\r
 134         {\r
 135                 entity head;\r
 136                 FOR_EACH_PLAYER(head)\r
 137                 {\r
 138                         if(head.eater == self)\r
 139                                 Vore_Regurgitate(head);\r
 140                 }\r
 141         }\r
 142 }\r
 143 \r
 144 .float digestion_step;\r
 145 void Vore_Digest()\r
 146 {\r
 147         // apply digestion to prey\r
 148         if(time > self.eater.digestion_step + steptime)\r
 149         {\r
 150                 Damage(self, self.eater, self.eater, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 151                 if(cvar("g_balance_vore_digestion_vampire") && self.eater.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 152                         self.eater.health += cvar("g_balance_vore_digestion_vampire");\r
 153 \r
 154                 if (self.eater.digestsound_finished < time)\r
 155                 {\r
 156                         self.eater.digestsound_finished = time + 0.5;\r
 157                         sound (self.eater, CHAN_PLAYER, "player/digest.wav", VOL_BASE, ATTN_NORM);\r
 158                 }\r
 159                 self.eater.digestion_step = time;\r
 160         }\r
 161 \r
 162         if(self.health <= 0)\r
 163         if(stov(cvar_string("g_vore_regurgitatecolor_digested")))\r
 164                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digested"));\r
 165 }\r
 166 \r
 167 .float teamheal_step;\r
 168 void Vore_Teamheal()\r
 169 {\r
 170         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 171         if(time > self.teamheal_step + steptime)\r
 172         {\r
 173                 self.health += cvar("g_balance_vore_teamheal");\r
 174                 self.teamheal_step = time;\r
 175         }\r
 176 }\r
 177 \r
 178 .float stomachkick_delay;\r
 179 void Vore_StomachKick()\r
 180 {\r
 181         // allows prey to kick the predator's stomach and do some damage, or bring the predator's digestion upon their self when there's no other option\r
 182         if(self.eater.classname != "player")\r
 183                 return;\r
 184 \r
 185         // kick the predator's stomach and do damage\r
 186         if(self.BUTTON_ATCK)\r
 187         if(time > self.stomachkick_delay)\r
 188         {\r
 189                 float damage;\r
 190                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 191 \r
 192                 Damage(self.eater, self, self, damage, DEATH_STOMACHKICK, self.eater.origin, '0 0 0');\r
 193                 sound(self.eater, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 194                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 195         }\r
 196 \r
 197         // start the predator's digestion\r
 198         if(self.BUTTON_ATCK2)\r
 199         {\r
 200                 centerprint(self.eater, strcat(self.netname, " triggered your digestion"));\r
 201                 self.eater.digesting = TRUE;\r
 202         }\r
 203 }\r
 204 \r
 205 void Vore()\r
 206 {\r
 207         // skip the vore system under some circumstances\r
 208         if(time < game_starttime)\r
 209         {\r
 210                 Vore_Disconnect();\r
 211                 return;\r
 212         }\r
 213         if(self.spectatee_status)\r
 214                 return;\r
 215 \r
 216 // --------------------------------\r
 217 // Code that addresses predators:\r
 218 // --------------------------------\r
 219 \r
 220         entity prey;\r
 221         prey = Swallow_distance_check();\r
 222 \r
 223         // attempt to swallow our new prey if there's any in range\r
 224         if(self.BUTTON_ATCK && !self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
 225         if(Swallow_condition_check(prey))\r
 226         {\r
 227                 prey.eater = self;\r
 228                 Vore_Swallow(prey);\r
 229                 self.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 230 \r
 231                 if(self.team == prey.team && teamplay)\r
 232                         centerprint(self, "You have swallowed a team mate, use caution!");\r
 233 \r
 234                 // block firing for a small amount of time when voring, or we'll be firing the next frame after we swallow\r
 235                 self.weapon_delay = time + 0.25;\r
 236         }\r
 237 \r
 238         // start / stop digestion on command, if the player has someone in their stomach\r
 239         if(self.BUTTON_DIGEST)\r
 240         {\r
 241                 if(self.stomach_load)\r
 242                 {\r
 243                         if(time > self.digest_button_delay)\r
 244                         {\r
 245                                 self.digesting = !self.digesting;\r
 246                                 self.digest_button_delay = time + button_delay;\r
 247                         }\r
 248                 }\r
 249                 else if(time > self.complain_swallow)\r
 250                 {\r
 251                         play2(self, "weapons/unavailable.wav");\r
 252                         sprint(self, "There is nothing to digest\n");\r
 253                         self.complain_swallow = time + complain_delay;\r
 254                 }\r
 255         }\r
 256         if(!self.stomach_load)\r
 257                 self.digesting = FALSE;\r
 258 \r
 259         // release players from this player's stomach on command\r
 260         if(self.BUTTON_REGURGITATE)\r
 261         {\r
 262                 if(self.stomach_load)\r
 263                 {\r
 264                         if(time > self.regurgitate_button_delay)\r
 265                         {\r
 266                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 267                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 268                                 self.regurgitate_button_delay = time + button_delay;\r
 269                         }\r
 270                 }\r
 271                 else if(time > self.complain_swallow)\r
 272                 {\r
 273                         play2(self, "weapons/unavailable.wav");\r
 274                         sprint(self, "There is nothing to regurgitate\n");\r
 275                         self.complain_swallow = time + complain_delay;\r
 276                 }\r
 277         }\r
 278 \r
 279 // --------------------------------\r
 280 // Code that addresses the prey:\r
 281 // --------------------------------\r
 282 \r
 283         if(self.eater.classname != "player")\r
 284                 return;\r
 285 \r
 286         if(self.eater.deadflag || self.deadflag)\r
 287                 Vore_Regurgitate(self);\r
 288         else if(self.eater.eater.classname == "player") // don't allow a player inside a player inside another player :)\r
 289                 Vore_Regurgitate(self);\r
 290         else if(vlen(self.eater.velocity) > cvar("g_balance_vore_regurgitate_velocitylimit"))\r
 291                 Vore_Regurgitate(self);\r
 292 \r
 293         // apply delayed regurgitating\r
 294         if(self.eater.regurgitate_prepare && time > self.eater.regurgitate_prepare)\r
 295         {\r
 296                 self.eater.regurgitate_prepare = 0;\r
 297                 self.eater.complain_swallow = time + complain_delay;\r
 298                 Vore_Regurgitate(self);\r
 299         }\r
 300 \r
 301         if(self.eater.digesting == TRUE)\r
 302                 Vore_Digest();\r
 303         if(teams_matter && self.team == self.eater.team)\r
 304                 Vore_Teamheal();\r
 305 \r
 306         Vore_StomachKick();\r
 307 }