data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  42                 {\r
  43                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  44                         {\r
  45                                 play2(self, "misc/forbidden.wav");\r
  46                                 sprint(self, "You cannot swallow your team mates\n");\r
  47                                 self.complain_vore = time + complain_delay_time;\r
  48                         }\r
  49                         return FALSE;\r
  50                 }\r
  51 \r
  52                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  53                 {\r
  54                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  55                         {\r
  56                                 play2(self, "misc/forbidden.wav");\r
  57                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  58                                 self.complain_vore = time + complain_delay_time;\r
  59                         }\r
  60                         return FALSE;\r
  61                 }\r
  62 \r
  63                 if(cvar("g_vore_biggergut"))\r
  64                 if(prey.stomach_load > self.stomach_load)\r
  65                 {\r
  66                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  67                         {\r
  68                                 play2(self, "misc/forbidden.wav");\r
  69                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  70                                 self.complain_vore = time + complain_delay_time;\r
  71                         }\r
  72                         return FALSE;\r
  73                 }\r
  74 \r
  75                 if(!cvar("g_vore_spawnshield"))\r
  76                 if(prey.spawnshieldtime > time)\r
  77                 {\r
  78                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  79                         {\r
  80                                 play2(self, "misc/forbidden.wav");\r
  81                                 sprint(self, "You cannot swallow someone protected by the spawn shield\n");\r
  82                                 self.complain_vore = time + complain_delay_time;\r
  83                         }\r
  84                         return FALSE;\r
  85                 }\r
  86 \r
  87                 return TRUE;\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_TeamMates_check(entity pred)\r
  93 {\r
  94         // checks if a player's stomach contains any team mates\r
  95 \r
  96         entity head;\r
  97         if(teams_matter)\r
  98         {\r
  99                 FOR_EACH_PLAYER(head)\r
 100                 {\r
 101                         if(head.predator == pred && head.team == pred.team)\r
 102                                 return TRUE;\r
 103                 }\r
 104         }\r
 105         return FALSE;\r
 106 }\r
 107 \r
 108 float Vore_CanLeave()\r
 109 {\r
 110         if(self.predator.classname == "player")\r
 111         {\r
 112                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 113                         return TRUE;\r
 114                 if(teams_matter && self.team == self.predator.team)\r
 115                         return TRUE;\r
 116                 if(g_rpg && cvar("g_rpg_canleave"))\r
 117                         return TRUE;\r
 118         }\r
 119         return FALSE;\r
 120 }\r
 121 \r
 122 // make the camera smoothly lower itself when we get swallowed\r
 123 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
 124 .float cameraeffect_current, cameraeffect_target;\r
 125 void Vore_CameraEffect_Set(entity e)\r
 126 {\r
 127         e.cameraeffect_current = 1;\r
 128         e.cameraeffect_target = 2;\r
 129 }\r
 130 void Vore_CameraEffect_Apply()\r
 131 {\r
 132         if not(self.predator.classname == "player" || self.fakeprey)\r
 133                 return;\r
 134 \r
 135         if(self.cvar_cl_vore_cameraspeed)\r
 136         {\r
 137                 local float step;\r
 138                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 139 \r
 140                 // not sure if these maths are good, as the effect should be smoother\r
 141                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 142                         self.cameraeffect_current -= step;\r
 143                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 144                         self.cameraeffect_current += step;\r
 145         }\r
 146         else\r
 147                 self.cameraeffect_current = self.cameraeffect_target;\r
 148 \r
 149         self.view_ofs_z = PL_PREY_VIEW_OFS_z / self.cameraeffect_current;\r
 150         if(self.predator.scale)\r
 151                 self.view_ofs_z *= self.predator.scale;\r
 152         else if(self.fakepredator.scale)\r
 153                 self.view_ofs_z *= self.fakepredator.scale;\r
 154 }\r
 155 \r
 156 .float gurgle_oldstomachload;\r
 157 void Vore_GurgleSound()\r
 158 {\r
 159         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 160         {\r
 161                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 162 \r
 163                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 164                 self.gurgle_oldstomachload = self.stomach_load;\r
 165         }\r
 166 }\r
 167 \r
 168 void Vore_WeightApply(entity e)\r
 169 {\r
 170         // apply stomach weight that makes you heavier the more you eat\r
 171         // slowing the player is done in cl_physics.qc\r
 172 \r
 173         if(e.stomach_load != e.vore_oldstomachload)\r
 174                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 175         if(e.gravity == 0)\r
 176                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 177         e.vore_oldstomachload = e.stomach_load;\r
 178 }\r
 179 \r
 180 void Vore_AutoDigest(entity e)\r
 181 {\r
 182         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 183 \r
 184         if(!cvar("g_vore_digestion") || e.digesting)\r
 185                 return;\r
 186         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 187                 return; // this feature is only for players, not bots\r
 188         if(e.stomach_load > 1)\r
 189                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 190         if(Stomach_TeamMates_check(e))\r
 191                 return; // never begin automatic digestion if we've swallowed a team mate\r
 192 \r
 193         e.digesting = TRUE;\r
 194 }\r
 195 \r
 196 .entity pusher;\r
 197 .float pushltime;\r
 198 void Vore_Swallow(entity e)\r
 199 {\r
 200         // this player is being swallowed by another player, apply the proper changes\r
 201 \r
 202         e.vore_oldmovetype = e.movetype;\r
 203         e.vore_oldsolid = e.solid;\r
 204 \r
 205         e.predator = self;\r
 206         setorigin(e, e.predator.origin);\r
 207         e.velocity = '0 0 0';\r
 208         e.movetype = MOVETYPE_FOLLOW;\r
 209         e.solid = SOLID_NOT;\r
 210         e.alpha = -1; // best way of hiding the eaten player\r
 211         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 212 \r
 213         // drop keys (KH) and flags (CTF) when we get swallowed\r
 214         kh_Key_DropAll(e, FALSE);\r
 215         if(e.flagcarried)\r
 216                 DropFlag(e.flagcarried, world, e.predator);\r
 217 \r
 218         Vore_CameraEffect_Set(e);\r
 219 \r
 220         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 221                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 222 \r
 223         if(teams_matter && e.team == e.predator.team)\r
 224         {\r
 225                 if(cvar("g_vore_kick"))\r
 226                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 227                 if(cvar("g_vore_digestion"))\r
 228                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 229         }\r
 230 \r
 231         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 232         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 233         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 234         e.predator.stomach_load += 1;\r
 235         e.predator.regurgitate_prepare = 0;\r
 236         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 237         Vore_WeightApply(e.predator);\r
 238         Vore_AutoDigest(e.predator);\r
 239 \r
 240         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 241         e.predator.weapon_delay = time + button_delay_time;\r
 242         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 243         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 244 }\r
 245 \r
 246 void Vore_Regurgitate(entity e)\r
 247 {\r
 248         // this player is being regurgitated by their predator, apply the proper changes\r
 249 \r
 250         e.movetype = e.vore_oldmovetype;\r
 251         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 252                 e.solid = e.vore_oldsolid;\r
 253         e.view_ofs_z = PL_VIEW_OFS_z;\r
 254         e.alpha = default_player_alpha;\r
 255 \r
 256         // apply velocities\r
 257         local vector oldforward, oldright, oldup;\r
 258         oldforward = v_forward;\r
 259         oldright = v_right;\r
 260         oldup = v_up;\r
 261         makevectors(e.predator.v_angle);\r
 262         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 263         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 264         v_forward = oldforward;\r
 265         v_right = oldright;\r
 266         v_up = oldup;\r
 267 \r
 268         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 269         e.pushltime = time + cvar("g_maxpushtime");\r
 270 \r
 271         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 272         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 273         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 274         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 275         e.predator.stomach_load -= 1;\r
 276         e.predator.regurgitate_prepare = 0;\r
 277         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 278         Vore_WeightApply(e.predator);\r
 279 \r
 280         // block firing for a small amount of time, or we'll be firing the next frame\r
 281         e.weapon_delay = time + button_delay_time;\r
 282         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 283         e.predator = world;\r
 284 }\r
 285 \r
 286 void Vore_DeadPrey_Configure(entity e)\r
 287 {\r
 288         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 289 \r
 290         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 291                 return;\r
 292 \r
 293         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 294         e.fakepredator = e.predator;\r
 295         e.fakeprey = TRUE;\r
 296 \r
 297         // first release the prey from the predator, as dead prey needs to be attached differently\r
 298         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 299         e.predator.stomach_load -= 1;\r
 300         Vore_WeightApply(e.predator);\r
 301         e.predator = world;\r
 302 \r
 303         // now put our dead prey inside the predator's stomach, but only as an effect\r
 304         e.movetype = MOVETYPE_FOLLOW;\r
 305         e.takedamage = DAMAGE_NO;\r
 306         e.solid = SOLID_NOT;\r
 307         e.aiment = e.fakepredator;\r
 308 \r
 309         // completely remove the dead body\r
 310         e.modelindex = 0;\r
 311 }\r
 312 \r
 313 void Vore_DeadPrey_Detach(entity e)\r
 314 {\r
 315         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 316         // should only execute after Vore_DeadPrey_Configure has ran first\r
 317 \r
 318         if not(cvar("g_vore_keepdeadprey"))\r
 319                 return;\r
 320 \r
 321         e.fakepredator = world;\r
 322         e.fakeprey = FALSE;\r
 323         e.aiment = world;\r
 324         e.movetype = MOVETYPE_TOSS;\r
 325 }\r
 326 \r
 327 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 328 {\r
 329         if(pred_disconnect)\r
 330         {\r
 331                 if(e.fakeprey)\r
 332                         Vore_DeadPrey_Detach(e);\r
 333                 else\r
 334                         Vore_Regurgitate(e);\r
 335         }\r
 336         else\r
 337         {\r
 338                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 339                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 340                         Vore_DeadPrey_Configure(e);\r
 341                 else\r
 342                         Vore_Regurgitate(e);\r
 343         }\r
 344 }\r
 345 \r
 346 void Vore_Disconnect()\r
 347 {\r
 348         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 349 \r
 350         // prey disconnects or goes spectating while inside someone's belly\r
 351         if(self.predator.classname == "player")\r
 352                 Vore_PreyRelease(self, TRUE);\r
 353 \r
 354         // pred disconnects or goes spectating with players in their belly\r
 355         entity head;\r
 356         FOR_EACH_PLAYER(head)\r
 357         {\r
 358                 if(head.predator == self || head.fakepredator == self)\r
 359                         Vore_PreyRelease(head, TRUE);\r
 360         }\r
 361         Vore_GurgleSound(); // stop the gurgling sound\r
 362 \r
 363         self.stomach_load = self.gravity = 0; // prevents a bug\r
 364 }\r
 365 \r
 366 .float digestion_step;\r
 367 void Vore_Digest()\r
 368 {\r
 369         // apply digestion to prey\r
 370 \r
 371         if(time > self.predator.digestion_step)\r
 372         {\r
 373                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 374                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 375                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 376 \r
 377                 if (self.predator.digestsound_finished < time)\r
 378                 {\r
 379                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 380                         self.predator.digestsound_finished = time + 0.5;\r
 381                 }\r
 382                 self.predator.digestion_step = time + steptime;\r
 383         }\r
 384 \r
 385         if(self.deadflag != DEAD_NO)\r
 386         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 387                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 388 }\r
 389 \r
 390 .float teamheal_step;\r
 391 void Vore_Teamheal()\r
 392 {\r
 393         // apply teamheal\r
 394 \r
 395         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 396         if(time > self.teamheal_step)\r
 397         {\r
 398                 self.health += cvar("g_balance_vore_teamheal");\r
 399                 self.teamheal_step = time + steptime;\r
 400 \r
 401                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 402                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 403                 {\r
 404                         play2(self, "misc/beep.wav");\r
 405                         play2(self.predator, "misc/beep.wav");\r
 406                 }\r
 407         }\r
 408 }\r
 409 \r
 410 .float stomachkick_delay;\r
 411 void Vore_StomachKick()\r
 412 {\r
 413         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 414 \r
 415         if(time > self.stomachkick_delay)\r
 416         {\r
 417                 float damage;\r
 418                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 419 \r
 420                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 421                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 422                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 423                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 424 \r
 425                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 426                         Vore_Regurgitate(self);\r
 427 \r
 428                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 429         }\r
 430 }\r
 431 \r
 432 void Vore_StomachLeave()\r
 433 {\r
 434         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 435 \r
 436         if(Vore_CanLeave())\r
 437                 Vore_Regurgitate(self);\r
 438         else if(time > self.complain_vore)\r
 439         {\r
 440                 play2(self, "misc/forbidden.wav");\r
 441                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 442                 self.complain_vore = time + complain_delay_time;\r
 443         }\r
 444 }\r
 445 \r
 446 void Vore_AutoTaunt()\r
 447 {\r
 448         // triggers ambient vore taunts, for both pred and prey\r
 449 \r
 450         float taunt_time;\r
 451 \r
 452         // predator taunts\r
 453         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 454         {\r
 455                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 456                 {\r
 457                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 458                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 459                 }\r
 460         }\r
 461         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 462         {\r
 463                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 464                 SetAutoTaunt(self, 0, 0);\r
 465         }\r
 466 \r
 467         // prey taunts\r
 468         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 469         {\r
 470                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 471                 {\r
 472                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 473                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 474                 }\r
 475         }\r
 476         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 477         {\r
 478                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 479                 SetAutoTaunt(self, 0, 0);\r
 480         }\r
 481 }\r
 482 \r
 483 void Vore()\r
 484 {\r
 485         // main vore code, this is where it all happens\r
 486 \r
 487         if(!cvar("g_vore")) // the vore system is disabled\r
 488         {\r
 489                 Vore_Disconnect();\r
 490                 return;\r
 491         }\r
 492 \r
 493         Vore_AutoTaunt();\r
 494 \r
 495         // wash the goo away from players once they leave the stomach\r
 496         if(self.predator.classname != "player")\r
 497         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 498         if(self.colormod)\r
 499         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 500         {\r
 501                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 502                 if(self.colormod_x > 1)\r
 503                         self.colormod_x = 1;\r
 504                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 505                 if(self.colormod_y > 1)\r
 506                         self.colormod_y = 1;\r
 507                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 508                 if(self.colormod_z > 1)\r
 509                         self.colormod_z = 1;\r
 510         }\r
 511 \r
 512         // set all vore stats\r
 513         if(self.fakeprey)\r
 514                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 515         else if(self.predator.classname == "player")\r
 516         {\r
 517                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 518                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 519                 self.stat_eaten = num_for_edict(self.predator);\r
 520         }\r
 521         else\r
 522         {\r
 523                 self.stat_stomachload = self.stomach_load;\r
 524                 self.stat_digesting = self.digesting;\r
 525                 self.stat_eaten = 0;\r
 526         }\r
 527         self.stat_canleave = Vore_CanLeave();\r
 528 \r
 529         // don't allow a player inside a player inside another player :)\r
 530         // prevent this by checking if such has happened, and taking the proper measures\r
 531         // this code has a high priority and must not be stopped by any delay, so run it here\r
 532         if(self.predator.predator.classname == "player")\r
 533         {\r
 534                 entity target_predator, target_predator_predator, oldself;\r
 535                 target_predator = self.predator;\r
 536                 target_predator_predator = self.predator.predator;\r
 537 \r
 538                 Vore_Regurgitate(self);\r
 539 \r
 540                 // now steal our prey's prey if this probability applies\r
 541                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 542                 {\r
 543                         oldself = self;\r
 544                         self = target_predator_predator;\r
 545                         if(Swallow_condition_check(oldself))\r
 546                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 547                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 548                                 Vore_Swallow(oldself);\r
 549                         self = oldself;\r
 550                 }\r
 551         }\r
 552 \r
 553         // apply delays and skip the vore system under some circumstances\r
 554         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 555         {\r
 556                 Vore_Disconnect();\r
 557                 return;\r
 558         }\r
 559         if(self.spectatee_status)\r
 560                 return;\r
 561         if(time < self.system_delay)\r
 562                 return;\r
 563 \r
 564 // --------------------------------\r
 565 // Code that addresses predators:\r
 566 // --------------------------------\r
 567 \r
 568         entity prey;\r
 569         prey = Swallow_player_check();\r
 570 \r
 571         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 572         self.stat_canswallow = 0;\r
 573         if(Swallow_condition_check(prey))\r
 574         {\r
 575                 // canswallow stat, used by the HUD\r
 576                 if(teams_matter && prey.team == self.team)\r
 577                         self.stat_canswallow = 2;\r
 578                 else\r
 579                         self.stat_canswallow = 1;\r
 580 \r
 581                 if(self.BUTTON_ATCK)\r
 582                         Vore_Swallow(prey);\r
 583         }\r
 584         else if(prey != world)\r
 585                 self.stat_canswallow = -1;\r
 586 \r
 587         // toggle digestion, if the player has someone in their stomach\r
 588         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 589         {\r
 590                 if(self.stomach_load)\r
 591                 {\r
 592                         if(time > self.digest_button_delay_time)\r
 593                         {\r
 594                                 self.digesting = !self.digesting;\r
 595                                 self.digest_button_delay_time = time + button_delay_time;\r
 596                         }\r
 597                 }\r
 598                 else if(time > self.complain_vore)\r
 599                 {\r
 600                         play2(self, "misc/forbidden.wav");\r
 601                         sprint(self, "There is nothing to digest\n");\r
 602                         self.complain_vore = time + complain_delay_time;\r
 603                 }\r
 604         }\r
 605         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 606                 self.digesting = FALSE;\r
 607 \r
 608         // predator wishes to regurgitate his prey\r
 609         if(self.BUTTON_REGURGITATE)\r
 610         {\r
 611                 if(self.stomach_load)\r
 612                 {\r
 613                         if(time > self.regurgitate_button_delay_time)\r
 614                         {\r
 615                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 616                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 617                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 618                         }\r
 619                 }\r
 620                 else if(time > self.complain_vore)\r
 621                 {\r
 622                         play2(self, "misc/forbidden.wav");\r
 623                         sprint(self, "There is nothing to regurgitate\n");\r
 624                         self.complain_vore = time + complain_delay_time;\r
 625                 }\r
 626         }\r
 627 \r
 628         if(cvar("g_vore_gurglesound"))\r
 629                 Vore_GurgleSound();\r
 630 \r
 631 // --------------------------------\r
 632 // Code that addresses the prey:\r
 633 // --------------------------------\r
 634 \r
 635         Vore_CameraEffect_Apply();\r
 636 \r
 637         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 638         if(self.fakepredator.classname == "player")\r
 639         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 640                 Vore_DeadPrey_Detach(self);\r
 641 \r
 642         if(self.predator.classname != "player")\r
 643                 return;\r
 644 \r
 645         if(self.deadflag != DEAD_NO)\r
 646         {\r
 647                 Vore_PreyRelease(self, FALSE);\r
 648                 return;\r
 649         }\r
 650 \r
 651         if(self.predator.deadflag != DEAD_NO)\r
 652                 Vore_Regurgitate(self);\r
 653         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 654                 Vore_Regurgitate(self);\r
 655 \r
 656         // apply delayed regurgitating if it was scheduled\r
 657         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 658         {\r
 659                 self.predator.regurgitate_prepare = 0;\r
 660                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 661                 Vore_Regurgitate(self);\r
 662         }\r
 663 \r
 664         // execute digesting and team healing\r
 665         if(self.predator.digesting == TRUE)\r
 666                 Vore_Digest();\r
 667         if(teams_matter && self.team == self.predator.team)\r
 668         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 669                 Vore_Teamheal();\r
 670 \r
 671         // execute prey commands\r
 672         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 673                 Vore_StomachKick();\r
 674         if(self.BUTTON_JUMP)\r
 675                 Vore_StomachLeave();\r
 676 \r
 677         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 678         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 679         kh_Key_DropAll(self, FALSE);\r
 680 }