data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 .entity swallow_model;\r
 203 void Vore_SwallowModel_Think()\r
 204 {\r
 205         //update the necessary angles to match our view\r
 206         //self.angles_x = self.owner.angles_x;\r
 207         //self.view_ofs = self.owner.view_ofs;\r
 208 \r
 209         self.view_ofs = '-1 0 0' * (0.5 - self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 210 \r
 211         // if our swallow progress is gone, the swallow model must also go\r
 212         if(!self.owner.swallow_progress_prey)\r
 213         {\r
 214                 remove(self.owner.swallow_model);\r
 215                 self.owner.swallow_model = world;\r
 216                 return;\r
 217         }\r
 218 \r
 219         self.nextthink = time;\r
 220 }\r
 221 \r
 222 void Vore_SwallowModel_Update(entity prey)\r
 223 {\r
 224         // if we don't have a swallow model already, spawn one\r
 225         if(!prey.swallow_model)\r
 226         {\r
 227                 prey.swallow_model = spawn();\r
 228                 \r
 229                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 230                 prey.swallow_model.solid = SOLID_NOT;\r
 231 \r
 232                 prey.swallow_model.skin = self.skin;\r
 233                 //prey.swallow_model.scale = self.scale; // FIX LATER\r
 234 \r
 235                 // apply the properties of the prey\r
 236                 prey.swallow_model.viewmodelforclient = prey;\r
 237                 prey.swallow_model.effects |= EF_NOGUNBOB;\r
 238                 prey.swallow_model.alpha = prey.cvar_cl_vore_stomachmodel;\r
 239                 prey.swallow_model.colormap = prey.colormap;\r
 240                 prey.swallow_model.glowmod = prey.glowmod;\r
 241 \r
 242                 prey.swallow_model.owner = prey; // owned by the prey\r
 243                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 244                 prey.swallow_model.nextthink = time;\r
 245         }\r
 246 \r
 247         // if predator has changed, update the swallow model\r
 248         if(prey.swallow_model.enemy != self)\r
 249         {\r
 250                 setmodel(prey.swallow_model, strcat(substring(self.playermodel, 0, strlen(self.playermodel) - 4), "_swallow.md3")); // 4 is the extension length\r
 251                 prey.swallow_model.skin = self.skin;\r
 252                 prey.swallow_model.enemy = self; // enemy is the predator\r
 253         }\r
 254 }\r
 255 \r
 256 .entity pusher;\r
 257 .float pushltime;\r
 258 void Vore_Swallow(entity e)\r
 259 {\r
 260         // this player is being swallowed by another player, apply the proper changes\r
 261 \r
 262         e.vore_oldmovetype = e.movetype;\r
 263         e.vore_oldsolid = e.solid;\r
 264 \r
 265         e.predator = self;\r
 266         setorigin(e, e.predator.origin);\r
 267         e.velocity = '0 0 0';\r
 268         e.movetype = MOVETYPE_FOLLOW;\r
 269         e.solid = SOLID_NOT;\r
 270         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 271 \r
 272         // drop keys (KH) and flags (CTF) when we get swallowed\r
 273         kh_Key_DropAll(e, FALSE);\r
 274         if(e.flagcarried)\r
 275                 DropFlag(e.flagcarried, world, e.predator);\r
 276 \r
 277         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 278                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 279 \r
 280         if(teams_matter && e.team == e.predator.team)\r
 281         {\r
 282                 if(cvar("g_vore_kick"))\r
 283                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 284                 if(cvar("g_vore_digestion"))\r
 285                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 286         }\r
 287 \r
 288         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 289         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 290         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 291         e.predator.stomach_load += 1;\r
 292         e.predator.regurgitate_prepare = 0;\r
 293         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 294         Vore_WeightApply(e.predator);\r
 295         Vore_AutoDigest(e.predator);\r
 296 \r
 297         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 298         e.predator.weapon_delay = time + button_delay_time;\r
 299         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 300         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 301         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 302 }\r
 303 \r
 304 void Vore_SwallowStep(entity e)\r
 305 {\r
 306         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 307         {\r
 308                 Vore_Swallow(e);\r
 309                 return;\r
 310         }\r
 311 \r
 312         Vore_SwallowModel_Update(e);\r
 313 \r
 314         // increase the progress value until it reaches 1, then swallow the player\r
 315         if(e.swallow_progress_prey < 1)\r
 316         {\r
 317                 float fill;\r
 318                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 319                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 320                         fill *= (self.scale / e.scale);\r
 321                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 322                         fill /= e.stomach_load;\r
 323 \r
 324                 e.swallow_progress_prey += fill;\r
 325         }\r
 326         else\r
 327         {\r
 328                 Vore_Swallow(e);\r
 329                 e.swallow_progress_prey = 0;\r
 330         }\r
 331 \r
 332         // the predator's progress is how much the prey got swallowed\r
 333         self.swallow_progress_pred = e.swallow_progress_prey;\r
 334 }\r
 335 \r
 336 void Vore_Regurgitate(entity e)\r
 337 {\r
 338         // this player is being regurgitated by their predator, apply the proper changes\r
 339 \r
 340         e.movetype = e.vore_oldmovetype;\r
 341         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 342                 e.solid = e.vore_oldsolid;\r
 343         e.view_ofs_z = PL_VIEW_OFS_z;\r
 344 \r
 345         // apply velocities\r
 346         local vector oldforward, oldright, oldup;\r
 347         oldforward = v_forward;\r
 348         oldright = v_right;\r
 349         oldup = v_up;\r
 350         makevectors(e.predator.v_angle);\r
 351         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 352         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 353         v_forward = oldforward;\r
 354         v_right = oldright;\r
 355         v_up = oldup;\r
 356 \r
 357         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 358         e.pushltime = time + cvar("g_maxpushtime");\r
 359 \r
 360         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 361         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 362                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 363 \r
 364         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 365         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 366         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 367         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 368         e.predator.stomach_load -= 1;\r
 369         e.predator.regurgitate_prepare = 0;\r
 370         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 371         Vore_WeightApply(e.predator);\r
 372 \r
 373         // block firing for a small amount of time, or we'll be firing the next frame\r
 374         e.weapon_delay = time + button_delay_time;\r
 375         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 376         e.predator = world;\r
 377 }\r
 378 \r
 379 void Vore_DeadPrey_Configure(entity e)\r
 380 {\r
 381         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 382 \r
 383         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 384                 return;\r
 385 \r
 386         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 387         e.fakepredator = e.predator;\r
 388         e.fakeprey = TRUE;\r
 389 \r
 390         // first release the prey from the predator, as dead prey needs to be attached differently\r
 391         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 392         e.predator.stomach_load -= 1;\r
 393         Vore_WeightApply(e.predator);\r
 394         e.predator = world;\r
 395 \r
 396         // now put our dead prey inside the predator's stomach, but only as an effect\r
 397         e.movetype = MOVETYPE_FOLLOW;\r
 398         e.takedamage = DAMAGE_NO;\r
 399         e.solid = SOLID_NOT;\r
 400         e.aiment = e.fakepredator;\r
 401 }\r
 402 \r
 403 void Vore_DeadPrey_Detach(entity e)\r
 404 {\r
 405         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 406         // should only execute after Vore_DeadPrey_Configure has ran first\r
 407 \r
 408         if not(cvar("g_vore_keepdeadprey"))\r
 409                 return;\r
 410 \r
 411         e.fakepredator = world;\r
 412         e.fakeprey = TRUE; // keep fakeprey status\r
 413         e.stat_eaten = 0;\r
 414         e.aiment = world;\r
 415         e.movetype = MOVETYPE_TOSS;\r
 416 }\r
 417 \r
 418 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 419 {\r
 420         if(pred_disconnect)\r
 421         {\r
 422                 if(e.fakeprey)\r
 423                         Vore_DeadPrey_Detach(e);\r
 424                 else\r
 425                         Vore_Regurgitate(e);\r
 426         }\r
 427         else if(self.stat_eaten && !self.fakeprey)\r
 428         {\r
 429                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 430                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 431                         Vore_DeadPrey_Configure(e);\r
 432                 else\r
 433                         Vore_Regurgitate(e);\r
 434         }\r
 435 }\r
 436 \r
 437 void Vore_Disconnect()\r
 438 {\r
 439         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 440 \r
 441         // prey disconnects or goes spectating while inside someone's belly\r
 442         if(self.stat_eaten)\r
 443                 Vore_PreyRelease(self, TRUE);\r
 444 \r
 445         // pred disconnects or goes spectating with players in their belly\r
 446         entity head;\r
 447         FOR_EACH_PLAYER(head)\r
 448         {\r
 449                 if(head.predator == self || head.fakepredator == self)\r
 450                         Vore_PreyRelease(head, TRUE);\r
 451         }\r
 452         Vore_GurgleSound(); // stop the gurgling sound\r
 453 \r
 454         self.stomach_load = self.gravity = 0; // prevents a bug\r
 455 }\r
 456 \r
 457 .float digestion_step;\r
 458 void Vore_Digest()\r
 459 {\r
 460         // apply digestion to prey\r
 461 \r
 462         if(time > self.digestion_step)\r
 463         {\r
 464                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 465                 float reduce;\r
 466                 if(cvar("g_balance_vore_digestion_distribute"))\r
 467                         reduce = self.predator.stomach_load;\r
 468                 else\r
 469                         reduce = 1;\r
 470 \r
 471                 float damage;\r
 472                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 473 \r
 474                 // apply player scale to digestion damage\r
 475                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 476                         damage *= (self.predator.scale / self.scale);\r
 477 \r
 478                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 479                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 480                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 481 \r
 482                 if (self.predator.digestsound_finished < time)\r
 483                 {\r
 484                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 485                         self.predator.digestsound_finished = time + 0.5;\r
 486                 }\r
 487                 self.digestion_step = time + steptime;\r
 488         }\r
 489 \r
 490         if(self.deadflag != DEAD_NO)\r
 491         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 492                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 493 }\r
 494 \r
 495 .float teamheal_step;\r
 496 void Vore_Teamheal()\r
 497 {\r
 498         // apply teamheal\r
 499 \r
 500         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 501         if(time > self.teamheal_step)\r
 502         {\r
 503                 self.health += cvar("g_balance_vore_teamheal");\r
 504                 self.teamheal_step = time + steptime;\r
 505 \r
 506                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 507                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 508                 {\r
 509                         play2(self, "misc/beep.wav");\r
 510                         play2(self.predator, "misc/beep.wav");\r
 511                 }\r
 512         }\r
 513 }\r
 514 \r
 515 void Vore_StomachKick()\r
 516 {\r
 517         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 518 \r
 519         if(time > self.stomachkick_delay)\r
 520         {\r
 521                 float damage;\r
 522                 vector force;\r
 523                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 524                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 525 \r
 526                 // apply player scale to the damage / force of the kick\r
 527                 if(cvar("g_balance_vore_kick_scalediff"))\r
 528                 {\r
 529                         damage *= (self.scale / self.predator.scale);\r
 530                         force *= (self.scale / self.predator.scale);\r
 531                 }\r
 532 \r
 533                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 534                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 535                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 536                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 537 \r
 538                 // abort the predator's scheduled regurgitation\r
 539                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 540                         self.predator.regurgitate_prepare = 0;\r
 541 \r
 542                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 543         }\r
 544 }\r
 545 \r
 546 void Vore_StomachLeave()\r
 547 {\r
 548         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 549 \r
 550         if(Vore_CanLeave())\r
 551                 Vore_Regurgitate(self);\r
 552         else if(time > self.complain_vore)\r
 553         {\r
 554                 play2(self, "misc/forbidden.wav");\r
 555                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 556                 self.complain_vore = time + complain_delay_time;\r
 557         }\r
 558 }\r
 559 \r
 560 void Vore_AutoTaunt()\r
 561 {\r
 562         // triggers ambient vore taunts, for both pred and prey\r
 563 \r
 564         float taunt_time;\r
 565 \r
 566         // predator taunts\r
 567         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 568         {\r
 569                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 570                 {\r
 571                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 572                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 573                 }\r
 574         }\r
 575         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 576         {\r
 577                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 578                 SetAutoTaunt(self, 0, 0);\r
 579         }\r
 580 \r
 581         // prey taunts\r
 582         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 583         {\r
 584                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 585                 {\r
 586                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 587                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 588                 }\r
 589         }\r
 590         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 591         {\r
 592                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 593                 SetAutoTaunt(self, 0, 0);\r
 594         }\r
 595 }\r
 596 \r
 597 void Vore_SetSbarRings()\r
 598 {\r
 599         // first clear the ring stats, then configure them if needed\r
 600         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 601         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 602 \r
 603         if(self.stat_eaten)\r
 604         {\r
 605                 if(time <= self.stomachkick_delay)\r
 606                 {\r
 607                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 608                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 609                 }\r
 610         }\r
 611         else\r
 612         {\r
 613                 if(self.swallow_progress_pred)\r
 614                 {\r
 615                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 616                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 617                 }\r
 618                 else if(time <= self.action_delay)\r
 619                 {\r
 620                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 621                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 622                 }\r
 623 \r
 624                 if(self.swallow_progress_prey)\r
 625                 {\r
 626                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 627                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 628                 }\r
 629                 else if(time <= self.regurgitate_prepare)\r
 630                 {\r
 631                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 632                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 633                 }\r
 634         }\r
 635 }\r
 636 \r
 637 void Vore()\r
 638 {\r
 639         // main vore code, this is where it all happens\r
 640 \r
 641         if(!cvar("g_vore")) // the vore system is disabled\r
 642         {\r
 643                 Vore_Disconnect();\r
 644                 return;\r
 645         }\r
 646 \r
 647         Vore_AutoTaunt();\r
 648 \r
 649         // wash the goo away from players once they leave the stomach\r
 650         if(!self.stat_eaten)\r
 651         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 652         if(self.colormod)\r
 653         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 654         {\r
 655                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 656                 if(self.colormod_x > 1)\r
 657                         self.colormod_x = 1;\r
 658                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 659                 if(self.colormod_y > 1)\r
 660                         self.colormod_y = 1;\r
 661                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 662                 if(self.colormod_z > 1)\r
 663                         self.colormod_z = 1;\r
 664         }\r
 665 \r
 666         // set all vore stats\r
 667         Vore_SetSbarRings();\r
 668         if(self.fakepredator.classname == "player")\r
 669                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 670         else if(self.predator.classname == "player")\r
 671         {\r
 672                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 673                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 674                 self.stat_eaten = num_for_edict(self.predator);\r
 675         }\r
 676         else\r
 677         {\r
 678                 self.stat_stomachload = self.stomach_load;\r
 679                 self.stat_digesting = self.digesting;\r
 680                 self.stat_eaten = 0;\r
 681         }\r
 682         self.stat_canleave = Vore_CanLeave();\r
 683 \r
 684         // don't allow a player inside a player inside another player :)\r
 685         // prevent this by checking if such has happened, and taking the proper measures\r
 686         // this code has a high priority and must not be stopped by any delay, so run it here\r
 687         if(self.predator.stat_eaten)\r
 688         {\r
 689                 entity target_predator, target_predator_predator, oldself;\r
 690                 target_predator = self.predator;\r
 691                 target_predator_predator = self.predator.predator;\r
 692 \r
 693                 Vore_Regurgitate(self);\r
 694 \r
 695                 // now steal our prey's prey if this probability applies\r
 696                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 697                 {\r
 698                         oldself = self;\r
 699                         self = target_predator_predator;\r
 700                         if(Swallow_condition_check(oldself))\r
 701                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 702                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 703                                 Vore_Swallow(oldself);\r
 704                         self = oldself;\r
 705                 }\r
 706         }\r
 707 \r
 708         // the swallow progress of prey and preds idly decrease by this amount\r
 709         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 710         {\r
 711                 if(self.swallow_progress_pred)\r
 712                 {\r
 713                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 714                         if(self.swallow_progress_pred < 0)\r
 715                                 self.swallow_progress_pred = 0;\r
 716                 }\r
 717                 if(self.swallow_progress_prey)\r
 718                 {\r
 719                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 720                         if(self.swallow_progress_prey < 0)\r
 721                                 self.swallow_progress_prey = 0;\r
 722                 }\r
 723         }\r
 724 \r
 725         // apply delays and skip the vore system under some circumstances\r
 726         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 727         {\r
 728                 Vore_Disconnect();\r
 729                 return;\r
 730         }\r
 731         if(self.spectatee_status)\r
 732                 return;\r
 733         if(time < self.system_delay)\r
 734                 return;\r
 735 \r
 736 // --------------------------------\r
 737 // Code that addresses predators:\r
 738 // --------------------------------\r
 739 \r
 740         entity prey;\r
 741         prey = Swallow_player_check();\r
 742 \r
 743         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 744         self.stat_canswallow = 0;\r
 745         if(Swallow_condition_check(prey))\r
 746         {\r
 747                 // canswallow stat, used by the HUD\r
 748                 if(teams_matter && prey.team == self.team)\r
 749                         self.stat_canswallow = 2;\r
 750                 else\r
 751                         self.stat_canswallow = 1;\r
 752 \r
 753                 if(self.BUTTON_ATCK)\r
 754                         Vore_SwallowStep(prey);\r
 755         }\r
 756         else if(prey != world)\r
 757                 self.stat_canswallow = -1;\r
 758 \r
 759         // toggle digestion, if the player has someone in their stomach\r
 760         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 761         {\r
 762                 if(self.stomach_load)\r
 763                 {\r
 764                         if(time > self.digest_button_delay_time)\r
 765                         {\r
 766                                 self.digesting = !self.digesting;\r
 767                                 self.digest_button_delay_time = time + button_delay_time;\r
 768                         }\r
 769                 }\r
 770                 else if(time > self.complain_vore)\r
 771                 {\r
 772                         play2(self, "misc/forbidden.wav");\r
 773                         sprint(self, "There is nothing to digest\n");\r
 774                         self.complain_vore = time + complain_delay_time;\r
 775                 }\r
 776         }\r
 777         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 778                 self.digesting = FALSE;\r
 779 \r
 780         // predator wishes to regurgitate his prey\r
 781         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 782         {\r
 783                 if(self.stomach_load)\r
 784                 {\r
 785                         if(time > self.regurgitate_button_delay_time)\r
 786                         {\r
 787                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 788                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 789                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 790                         }\r
 791                 }\r
 792                 else if(time > self.complain_vore)\r
 793                 {\r
 794                         play2(self, "misc/forbidden.wav");\r
 795                         sprint(self, "There is nothing to regurgitate\n");\r
 796                         self.complain_vore = time + complain_delay_time;\r
 797                 }\r
 798         }\r
 799 \r
 800         if(cvar("g_vore_gurglesound"))\r
 801                 Vore_GurgleSound();\r
 802 \r
 803 // --------------------------------\r
 804 // Code that addresses the prey:\r
 805 // --------------------------------\r
 806 \r
 807         Vore_SetPreyPositions();\r
 808 \r
 809         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 810         if(self.fakeprey)\r
 811         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 812                 Vore_DeadPrey_Detach(self);\r
 813 \r
 814         if(!self.stat_eaten)\r
 815                 return;\r
 816 \r
 817         if(self.deadflag != DEAD_NO)\r
 818         {\r
 819                 Vore_PreyRelease(self, FALSE);\r
 820                 return;\r
 821         }\r
 822 \r
 823         if(self.predator.deadflag != DEAD_NO)\r
 824                 Vore_Regurgitate(self);\r
 825         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 826                 Vore_Regurgitate(self);\r
 827 \r
 828         // apply delayed regurgitating if it was scheduled\r
 829         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 830         {\r
 831                 self.predator.regurgitate_prepare = 0;\r
 832                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 833                 Vore_Regurgitate(self);\r
 834         }\r
 835 \r
 836         // execute digesting and team healing\r
 837         if(self.predator.digesting == TRUE)\r
 838                 Vore_Digest();\r
 839         if(teams_matter && self.team == self.predator.team)\r
 840         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 841                 Vore_Teamheal();\r
 842 \r
 843         // execute prey commands\r
 844         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 845                 Vore_StomachKick();\r
 846         if(self.BUTTON_JUMP)\r
 847                 Vore_StomachLeave();\r
 848 \r
 849         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 850         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 851         kh_Key_DropAll(self, FALSE);\r
 852 }