qcsrc/client/hud.qh

   1 vector mousepos;
   2 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
   3 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
   4 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
   5 float highlightedPanel;
   6 float highlightedPanel_prev;
   7 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
   8
   9 const float BORDER_MULTIPLIER = 0.25;
  10 float hud_color_bg_team;
  11 float scoreboard_bottom;
  12 float weapon_hits[WEP_MAXCOUNT];
  13 float weapon_fired[WEP_MAXCOUNT];
  14 float weapon_number;
  15
  16 float complain_weapon;
  17 string complain_weapon_name;
  18 float complain_weapon_type;
  19 float complain_weapon_time;
  20
  21 float ps_primary, ps_secondary;
  22 float ts_primary, ts_secondary;
  23
  24 float last_weapon;
  25 float weapontime;
  26
  27 float teamnagger;
  28 float hud_fg_alpha;
  29 float hud_accuracy_hud;
  30 float hud_border_thickness;
  31 float hud_accuracy_border_thickness;
  32
  33 float hud_configure_checkcollisions;
  34 float hud_configure_prev;
  35
  36 float hudShiftState;
  37 const float S_SHIFT = 1;
  38 const float S_CTRL = 2;
  39 const float S_ALT = 4;
  40
  41 float disable_menu_alphacheck; // 0 = enable alpha check, 1 = disable for entire hud, 2 = disable for one panel
  42 float menu_fade_alpha;
  43
  44 string hud_skin_path;
  45
  46 var vector progressbar_color;
  47
  48 var float active_panel; // this panel has recently referred the UpdateCvars macro
  49 var string panel_name;
  50 var float panel_enabled;
  51 var vector panel_pos;
  52 var vector panel_size;
  53 var string panel_bg;
  54 var string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
  55 var vector panel_bg_color;
  56 var string panel_bg_color_str;
  57 var float panel_bg_color_team;
  58 var string panel_bg_color_team_str;
  59 var float panel_fg_alpha;
  60 var float panel_bg_alpha;
  61 var string panel_bg_alpha_str;
  62 var float panel_bg_border;
  63 var string panel_bg_border_str;
  64 var float panel_bg_padding;
  65 var string panel_bg_padding_str;
  66 var float panel_accuracy_yellow;
  67 var float panel_accuracy_onlycurrent;
  68 var float panel_accuracy_flip;
  69 var float panel_accuracy_iconalign;
  70 var float panel_accuracy_baralign;
  71 var float panel_accuracy_info_top;
  72 var float panel_accuracy_foreground_alpha;
  73 var float panel_accuracy_alreadyvoted_alpha;
  74
  75 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
  76 // ----------------------
  77 // MACRO HELL STARTS HERE
  78 // ----------------------
  79 // Little help for the poor people who have to make sense of this: Start from the bottom
  80
  81 // TODO: shirt, pants, team colors
  82 #define HUD_Panel_GetProgressBarColor(item) \
  83 switch(item) {\
  84         case "strength": progressbar_color = autocvar_hud_progressbar_strength_color; break;\
  85         case "shield": progressbar_color = autocvar_hud_progressbar_shield_color; break;\
  86         case "health": progressbar_color = autocvar_hud_progressbar_health_color; break;\
  87         case "armor": progressbar_color = autocvar_hud_progressbar_armor_color; break;\
  88         case "fuel": progressbar_color = autocvar_hud_progressbar_fuel_color; break;\
  89         case "nexball": progressbar_color = autocvar_hud_progressbar_nexball_color; break;\
  90 }
  91
  92 // Get value for panel_bg: if "" fetch default, else use panel_bg_str
  93 // comment on last line of macro: // we probably want to see a background in config mode at all times...
  94 #define HUD_Panel_GetBg()\
  95 if(!autocvar__hud_configure && panel_bg_str == "0") {\
  96         panel_bg = "0";\
  97 } else {\
  98         if(panel_bg_str == "") {\
  99                 panel_bg = autocvar_hud_bg;\
 100         } else if(panel_bg_str == "0" && autocvar__hud_configure) {\
 101                 panel_bg = "border";\
 102         } else {\
 103                 panel_bg = panel_bg_str;\
 104         }\
 105 }
 106
 107 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 108 #define HUD_Panel_GetColor()\
 109 if(teamplay && panel_bg_color_team) {\
 110         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkey(player_localentnum - 1, "colors")), 16), 1) * panel_bg_color_team;\
 111 } else {\
 112         if(panel_bg_color_str == "") {\
 113                 panel_bg_color = autocvar_hud_bg_color;\
 114         } else {\
 115                 if(panel_bg_color_str == "shirt") {\
 116                         panel_bg_color = colormapPaletteColor(floor(stof(getplayerkey(player_localentnum - 1, "colors")) / 16), 0);\
 117                 } else if(panel_bg_color_str == "pants") {\
 118                         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkey(player_localentnum - 1, "colors")), 16), 1);\
 119                 } else {\
 120                         panel_bg_color = stov(panel_bg_color_str);\
 121                 }\
 122         }\
 123 }
 124
 125 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 126 #define HUD_Panel_GetColorTeam()\
 127 if(panel_bg_color_team_str == "") {\
 128         panel_bg_color_team = autocvar_hud_bg_color_team;\
 129 } else {\
 130         panel_bg_color_team = stof(panel_bg_color_team_str);\
 131 }
 132
 133 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 134 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 135 #define HUD_Panel_GetBgAlpha()\
 136 if(panel_bg_alpha_str == "") {\
 137         panel_bg_alpha_str = ftos(autocvar_hud_bg_alpha);\
 138 }\
 139 panel_bg_alpha = stof(panel_bg_alpha_str);\
 140 if(autocvar__hud_configure && disable_menu_alphacheck == 2 && highlightedPanel == active_panel) {\
 141         panel_bg_alpha = (1 - autocvar__menu_alpha) * max(autocvar_hud_configure_bg_minalpha, panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 142 } else if(autocvar__hud_configure) {\
 143         panel_bg_alpha = max(autocvar_hud_configure_bg_minalpha, panel_bg_alpha);\
 144 } if(autocvar__hud_configure && !panel_enabled) {\
 145         panel_bg_alpha = 0.25;\
 146 } if(!(disable_menu_alphacheck == 2 && highlightedPanel == active_panel)) {\
 147         panel_bg_alpha *= menu_fade_alpha;\
 148 }
 149
 150 // Get value for panel_fg_alpha. Also do various minalpha checks
 151 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 152 // comment on line 4 of macro: // don't fade this panel when showing the panel-specific menu dialog
 153 #define HUD_Panel_GetFgAlpha()\
 154 panel_fg_alpha = autocvar_hud_fg_alpha;\
 155 if(autocvar__hud_configure && !panel_enabled)\
 156         panel_fg_alpha = 0.25;\
 157 if(!(disable_menu_alphacheck == 2 && highlightedPanel == active_panel))\
 158         panel_fg_alpha *= menu_fade_alpha;
 159
 160 // Get border. See comments above, it's similar.
 161 #define HUD_Panel_GetBorder()\
 162 if(panel_bg_border_str == "") {\
 163         panel_bg_border = autocvar_hud_bg_border;\
 164 } else {\
 165         panel_bg_border = stof(panel_bg_border_str);\
 166 }
 167
 168 // Scale the pos and size vectors to absolute coordinates
 169 #define HUD_Panel_GetScaledVectors()\
 170 panel_pos_x *= vid_conwidth;\
 171 panel_pos_y *= vid_conheight;\
 172 panel_size_x *= vid_conwidth;\
 173 panel_size_y *= vid_conheight;
 174
 175 // Get padding. See comments above, it's similar.
 176 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 177 #define HUD_Panel_GetPadding()\
 178 if(panel_bg_padding_str == "") {\
 179         panel_bg_padding = autocvar_hud_bg_padding;\
 180 } else {\
 181         panel_bg_padding = stof(panel_bg_padding_str);\
 182 }\
 183 panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);
 184
 185 // Point to the macros above (stupid max macro length)
 186 #define HUD_Panel_StringVars()\
 187 HUD_Panel_GetBg()\
 188 HUD_Panel_GetColorTeam()\
 189 HUD_Panel_GetColor()\
 190 HUD_Panel_GetBgAlpha()\
 191 HUD_Panel_GetFgAlpha()\
 192 HUD_Panel_GetBorder()\
 193 HUD_Panel_GetScaledVectors()\
 194 HUD_Panel_GetPadding()
 195
 196 // Update all common cvars of given panel name
 197 #define HUD_Panel_UpdateCvars(name) \
 198 panel_enabled = autocvar_hud_##name; \
 199 panel_pos = autocvar_hud_##name##_pos; \
 200 panel_size = autocvar_hud_##name##_size; \
 201 panel_bg_str = autocvar_hud_##name##_bg; \
 202 panel_bg_color_str = autocvar_hud_##name##_bg_color; \
 203 panel_bg_color_team_str = autocvar_hud_##name##_bg_color_team; \
 204 panel_bg_alpha_str = autocvar_hud_##name##_bg_alpha; \
 205 panel_bg_border_str = autocvar_hud_##name##_bg_border; \
 206 panel_bg_padding_str = autocvar_hud_##name##_bg_padding; \
 207 HUD_Panel_StringVars()
 208
 209 // Update all common cvars of given panel id
 210 #define HUD_Panel_UpdateCvarsForId(id) \
 211 active_panel = id; \
 212 switch(id) { \
 213         case HUD_PANEL_WEAPONICONS: HUD_Panel_UpdateCvars(weaponicons) break; \
 214         case HUD_PANEL_INVENTORY: HUD_Panel_UpdateCvars(inventory) break; \
 215         case HUD_PANEL_POWERUPS: HUD_Panel_UpdateCvars(powerups) break; \
 216         case HUD_PANEL_HEALTHARMOR: HUD_Panel_UpdateCvars(healtharmor) break; \
 217         case HUD_PANEL_NOTIFY: HUD_Panel_UpdateCvars(notify) break; \
 218         case HUD_PANEL_TIMER: HUD_Panel_UpdateCvars(timer) break; \
 219         case HUD_PANEL_RADAR: HUD_Panel_UpdateCvars(radar) break; \
 220         case HUD_PANEL_SCORE: HUD_Panel_UpdateCvars(score) break; \
 221         case HUD_PANEL_RACETIMER: HUD_Panel_UpdateCvars(racetimer) break; \
 222         case HUD_PANEL_VOTE: HUD_Panel_UpdateCvars(vote) break; \
 223         case HUD_PANEL_MODICONS: HUD_Panel_UpdateCvars(modicons) break; \
 224         case HUD_PANEL_PRESSEDKEYS: HUD_Panel_UpdateCvars(pressedkeys) break; \
 225         case HUD_PANEL_CHAT: HUD_Panel_UpdateCvars(chat) break; \
 226         case HUD_PANEL_ENGINEINFO: HUD_Panel_UpdateCvars(engineinfo) break; \
 227 }
 228
 229 #define HUD_Panel_UpdatePosSize(name) \
 230 panel_pos = autocvar_hud_##name##_pos; \
 231 panel_size = autocvar_hud_##name##_size; \
 232 HUD_Panel_GetScaledVectors()\
 233 panel_bg_border_str = autocvar_hud_##name##_bg_border; \
 234 HUD_Panel_GetBorder()
 235
 236 // Update pos and size of given panel id
 237 #define HUD_Panel_UpdatePosSizeForId(id) \
 238 switch(id) { \
 239         case HUD_PANEL_WEAPONICONS: HUD_Panel_UpdatePosSize(weaponicons) break; \
 240         case HUD_PANEL_INVENTORY: HUD_Panel_UpdatePosSize(inventory) break; \
 241         case HUD_PANEL_POWERUPS: HUD_Panel_UpdatePosSize(powerups) break; \
 242         case HUD_PANEL_HEALTHARMOR: HUD_Panel_UpdatePosSize(healtharmor) break; \
 243         case HUD_PANEL_NOTIFY: HUD_Panel_UpdatePosSize(notify) break; \
 244         case HUD_PANEL_TIMER: HUD_Panel_UpdatePosSize(timer) break; \
 245         case HUD_PANEL_RADAR: HUD_Panel_UpdatePosSize(radar) break; \
 246         case HUD_PANEL_SCORE: HUD_Panel_UpdatePosSize(score) break; \
 247         case HUD_PANEL_RACETIMER: HUD_Panel_UpdatePosSize(racetimer) break; \
 248         case HUD_PANEL_VOTE: HUD_Panel_UpdatePosSize(vote) break; \
 249         case HUD_PANEL_MODICONS: HUD_Panel_UpdatePosSize(modicons) break; \
 250         case HUD_PANEL_PRESSEDKEYS: HUD_Panel_UpdatePosSize(pressedkeys) break; \
 251         case HUD_PANEL_CHAT: HUD_Panel_UpdatePosSize(chat) break; \
 252         case HUD_PANEL_ENGINEINFO: HUD_Panel_UpdatePosSize(engineinfo) break; \
 253 }