qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "damage.qh"
   6 #include "effects.qh"
   7 #include "generator.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "scoreboard.qh"
  17 #include "shownames.qh"
  18 #include "tuba.qh"
  19 #include "t_items.qh"
  20 #include "wall.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23
  24 #include "mutators/events.qh"
  25
  26 #include "weapons/projectile.qh"
  27
  28 #include "../common/buffs.qh"
  29 #include "../common/deathtypes.qh"
  30 #include "../common/effects/effects.qh"
  31 #include "../common/mapinfo.qh"
  32 #include "../common/monsters/all.qh"
  33 #include "../common/nades.qh"
  34 #include "../common/net_notice.qh"
  35 #include "../common/notifications.qh"
  36 #include "../common/stats.qh"
  37 #include "../common/teams.qh"
  38
  39 #include "../common/items/all.qh"
  40
  41 #include "../common/mutators/base.qh"
  42
  43 #include "../common/weapons/all.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../common/triggers/include.qh"
  49
  50 #include "../common/turrets/cl_turrets.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 string forcefog;
  85 void ConsoleCommand_macro_init();
  86 void CSQC_Init(void)
  87 {
  88         prvm_language = strzone(cvar_string("prvm_language"));
  89
  90 #ifdef WATERMARK
  91         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  92 #endif
  93
  94         int i;
  95
  96         binddb = db_create();
  97         tempdb = db_create();
  98         ClientProgsDB = db_load("client.db");
  99         compressShortVector_init();
 100
 101         draw_endBoldFont();
 102         menu_visible = false;
 103         menu_show = menu_show_error;
 104         menu_action = func_null;
 105
 106         for(i = 0; i < 255; ++i)
 107                 if(getplayerkeyvalue(i, "viewentity") == "")
 108                         break;
 109         maxclients = i;
 110
 111         //registercommand("hud_configure");
 112         //registercommand("hud_save");
 113         //registercommand("menu_action");
 114
 115         ConsoleCommand_macro_init();
 116
 117         registercvar("hud_usecsqc", "1");
 118         registercvar("scoreboard_columns", "default");
 119
 120         registercvar("cl_nade_type", "3");
 121         registercvar("cl_pokenade_type", "zombie");
 122
 123         registercvar("cl_jumpspeedcap_min", "");
 124         registercvar("cl_jumpspeedcap_max", "");
 125
 126         registercvar("cl_multijump", "0");
 127
 128         registercvar("cl_spawn_near_teammate", "1");
 129
 130         gametype = 0;
 131
 132         // hud_fields uses strunzone on the titles!
 133         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 134                 hud_title[i] = strzone("(null)");
 135
 136         Cmd_HUD_SetFields(0);
 137
 138         postinit = false;
 139
 140         calledhooks = 0;
 141
 142         teams = Sort_Spawn();
 143         players = Sort_Spawn();
 144
 145         GetTeam(NUM_SPECTATOR, true); // add specs first
 146
 147         // needs to be done so early because of the constants they create
 148         static_init();
 149         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 150         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 151         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 152         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 153
 154         initialize_minigames();
 155
 156         // precaches
 157
 158         Projectile_Precache();
 159         Tuba_Precache();
 160
 161         if(autocvar_cl_reticle)
 162         {
 163                 precache_pic("gfx/reticle_normal");
 164                 // weapon reticles are precached in weapon files
 165         }
 166
 167         get_mi_min_max_texcoords(1); // try the CLEVER way first
 168         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 169         shortmapname = mi_shortname;
 170
 171         if(precache_pic(minimapname) == "")
 172         {
 173                 // but maybe we have a non-clever minimap
 174                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 175                 if(precache_pic(minimapname) == "")
 176                         minimapname = ""; // FAIL
 177                 else
 178                         get_mi_min_max_texcoords(0); // load new texcoords
 179         }
 180
 181         mi_center = (mi_min + mi_max) * 0.5;
 182         mi_scale = mi_max - mi_min;
 183         minimapname = strzone(minimapname);
 184
 185         WarpZone_Init();
 186
 187         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 188         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 189 }
 190
 191 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 192 void Shutdown(void)
 193 {
 194         WarpZone_Shutdown();
 195
 196         remove(teams);
 197         remove(players);
 198         db_close(binddb);
 199         db_close(tempdb);
 200         if(autocvar_cl_db_saveasdump)
 201                 db_dump(ClientProgsDB, "client.db");
 202         else
 203                 db_save(ClientProgsDB, "client.db");
 204         db_close(ClientProgsDB);
 205
 206         if(camera_active)
 207                 cvar_set("chase_active",ftos(chase_active_backup));
 208
 209         // unset the event chasecam's chase_active
 210         if(autocvar_chase_active < 0)
 211                 cvar_set("chase_active", "0");
 212
 213         if (!isdemo())
 214         {
 215                 if (!(calledhooks & HOOK_START))
 216                         localcmd("\n_cl_hook_gamestart nop\n");
 217                 if (!(calledhooks & HOOK_END))
 218                         localcmd("\ncl_hook_gameend\n");
 219         }
 220
 221         deactivate_minigame();
 222         HUD_MinigameMenu_Close();
 223 }
 224
 225 .float has_team;
 226 float SetTeam(entity o, int Team)
 227 {
 228         entity tm;
 229         if(teamplay)
 230         {
 231                 switch(Team)
 232                 {
 233                         case -1:
 234                         case NUM_TEAM_1:
 235                         case NUM_TEAM_2:
 236                         case NUM_TEAM_3:
 237                         case NUM_TEAM_4:
 238                                 break;
 239                         default:
 240                                 if(GetTeam(Team, false) == world)
 241                                 {
 242                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 243                                         Team = NUM_SPECTATOR;
 244                                 }
 245                                 break;
 246                 }
 247         }
 248         else
 249         {
 250                 switch(Team)
 251                 {
 252                         case -1:
 253                         case 0:
 254                                 break;
 255                         default:
 256                                 if(GetTeam(Team, false) == world)
 257                                 {
 258                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 259                                         Team = NUM_SPECTATOR;
 260                                 }
 261                                 break;
 262                 }
 263         }
 264         if(Team == -1) // leave
 265         {
 266                 if(o.has_team)
 267                 {
 268                         tm = GetTeam(o.team, false);
 269                         tm.team_size -= 1;
 270                         o.has_team = 0;
 271                         return true;
 272                 }
 273         }
 274         else
 275         {
 276                 if (!o.has_team)
 277                 {
 278                         o.team = Team;
 279                         tm = GetTeam(Team, true);
 280                         tm.team_size += 1;
 281                         o.has_team = 1;
 282                         return true;
 283                 }
 284                 else if(Team != o.team)
 285                 {
 286                         tm = GetTeam(o.team, false);
 287                         tm.team_size -= 1;
 288                         o.team = Team;
 289                         tm = GetTeam(Team, true);
 290                         tm.team_size += 1;
 291                         return true;
 292                 }
 293         }
 294         return false;
 295 }
 296
 297 void Playerchecker_Think()
 298 {SELFPARAM();
 299     int i;
 300         entity e;
 301         for(i = 0; i < maxclients; ++i)
 302         {
 303                 e = playerslots[i];
 304                 if(GetPlayerName(i) == "")
 305                 {
 306                         if(e.sort_prev)
 307                         {
 308                                 // player disconnected
 309                                 SetTeam(e, -1);
 310                                 RemovePlayer(e);
 311                                 e.sort_prev = world;
 312                                 //e.gotscores = 0;
 313                         }
 314                 }
 315                 else
 316                 {
 317                         if (!e.sort_prev)
 318                         {
 319                                 // player connected
 320                                 if (!e)
 321                                         playerslots[i] = e = spawn();
 322                                 e.sv_entnum = i;
 323                                 e.ping = 0;
 324                                 e.ping_packetloss = 0;
 325                                 e.ping_movementloss = 0;
 326                                 //e.gotscores = 0; // we might already have the scores...
 327                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 328                                 RegisterPlayer(e);
 329                                 HUD_UpdatePlayerPos(e);
 330                         }
 331                 }
 332         }
 333         self.nextthink = time + 0.2;
 334 }
 335
 336 void Porto_Init();
 337 void TrueAim_Init();
 338 void PostInit(void)
 339 {
 340         entity playerchecker;
 341         playerchecker = spawn();
 342         playerchecker.think = Playerchecker_Think;
 343         playerchecker.nextthink = time + 0.2;
 344
 345         Porto_Init();
 346         TrueAim_Init();
 347
 348         postinit = true;
 349 }
 350
 351 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 352 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 353 // All keys are in ascii.
 354 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 355 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 356 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 357 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 358 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 359 {
 360         float bSkipKey;
 361         bSkipKey = false;
 362
 363         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 370                 return true;
 371
 372         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 376                 return true;
 377
 378         if(menu_visible && menu_action)
 379                 if(menu_action(bInputType, nPrimary, nSecondary))
 380                         return true;
 381
 382         return bSkipKey;
 383 }
 384
 385 // END REQUIRED CSQC FUNCTIONS
 386 // --------------------------------------------------------------------------
 387
 388 // --------------------------------------------------------------------------
 389 // BEGIN OPTIONAL CSQC FUNCTIONS
 390
 391 void Ent_RemoveEntCS()
 392 {SELFPARAM();
 393         entcs_receiver[self.sv_entnum] = world;
 394 }
 395 void Ent_ReadEntCS()
 396 {SELFPARAM();
 397     int sf;
 398         InterpolateOrigin_Undo();
 399
 400         self.classname = "entcs_receiver";
 401         sf = ReadByte();
 402
 403         if(sf & 1)
 404                 self.sv_entnum = ReadByte();
 405         if(sf & 2)
 406         {
 407                 self.origin_x = ReadShort();
 408                 self.origin_y = ReadShort();
 409                 self.origin_z = ReadShort();
 410                 setorigin(self, self.origin);
 411         }
 412         if(sf & 4)
 413         {
 414                 self.angles_y = ReadByte() * 360.0 / 256;
 415                 self.angles_x = self.angles_z = 0;
 416         }
 417         if(sf & 8)
 418                 self.healthvalue = ReadByte() * 10;
 419         if(sf & 16)
 420                 self.armorvalue = ReadByte() * 10;
 421
 422         entcs_receiver[self.sv_entnum] = self;
 423         self.entremove = Ent_RemoveEntCS;
 424         self.iflags |= IFLAG_ORIGIN;
 425
 426         InterpolateOrigin_Note();
 427 }
 428
 429 void Ent_Remove();
 430
 431 void Ent_RemovePlayerScore()
 432 {SELFPARAM();
 433         if(self.owner) {
 434                 SetTeam(self.owner, -1);
 435                 self.owner.gotscores = 0;
 436                 for(int i = 0; i < MAX_SCORE; ++i) {
 437                         self.owner.(scores[i]) = 0; // clear all scores
 438                 }
 439         }
 440 }
 441
 442 void Ent_ReadPlayerScore()
 443 {SELFPARAM();
 444         int i, n;
 445         bool isNew;
 446         entity o;
 447
 448         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 449         // (no I've never heard of M-x replace-string, sed, or anything like that)
 450         isNew = !self.owner; // workaround for DP bug
 451         n = ReadByte()-1;
 452
 453 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 454         if(!isNew && n != self.sv_entnum)
 455         {
 456                 //print("A CSQC entity changed its owner!\n");
 457                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 458                 isNew = true;
 459                 Ent_Remove();
 460                 self.enttype = ENT_CLIENT_SCORES;
 461         }
 462 #endif
 463
 464         self.sv_entnum = n;
 465
 466         if (!(playerslots[self.sv_entnum]))
 467                 playerslots[self.sv_entnum] = spawn();
 468         o = self.owner = playerslots[self.sv_entnum];
 469         o.sv_entnum = self.sv_entnum;
 470         o.gotscores = 1;
 471
 472         //if (!o.sort_prev)
 473         //      RegisterPlayer(o);
 474         //playerchecker will do this for us later, if it has not already done so
 475
 476     int sf, lf;
 477 #if MAX_SCORE <= 8
 478         sf = ReadByte();
 479         lf = ReadByte();
 480 #else
 481         sf = ReadShort();
 482         lf = ReadShort();
 483 #endif
 484     int p;
 485         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 486                 if(sf & p)
 487                 {
 488                         if(lf & p)
 489                                 o.(scores[i]) = ReadInt24_t();
 490                         else
 491                                 o.(scores[i]) = ReadChar();
 492                 }
 493
 494         if(o.sort_prev)
 495                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 496
 497         self.entremove = Ent_RemovePlayerScore;
 498 }
 499
 500 void Ent_ReadTeamScore()
 501 {SELFPARAM();
 502         int i;
 503         entity o;
 504
 505         self.team = ReadByte();
 506         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 507
 508     int sf, lf;
 509 #if MAX_TEAMSCORE <= 8
 510         sf = ReadByte();
 511         lf = ReadByte();
 512 #else
 513         sf = ReadShort();
 514         lf = ReadShort();
 515 #endif
 516         int p;
 517         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 518                 if(sf & p)
 519                 {
 520                         if(lf & p)
 521                                 o.(teamscores[i]) = ReadInt24_t();
 522                         else
 523                                 o.(teamscores[i]) = ReadChar();
 524                 }
 525
 526         HUD_UpdateTeamPos(o);
 527 }
 528
 529 void Ent_ClientData()
 530 {
 531         float newspectatee_status;
 532
 533     int f = ReadByte();
 534
 535         scoreboard_showscores_force = (f & 1);
 536
 537         if(f & 2)
 538         {
 539                 newspectatee_status = ReadByte();
 540                 if(newspectatee_status == player_localnum + 1)
 541                         newspectatee_status = -1; // observing
 542         }
 543         else
 544                 newspectatee_status = 0;
 545
 546         spectatorbutton_zoom = (f & 4);
 547
 548         if(f & 8)
 549         {
 550                 angles_held_status = 1;
 551                 angles_held.x = ReadAngle();
 552                 angles_held.y = ReadAngle();
 553                 angles_held.z = 0;
 554         }
 555         else
 556                 angles_held_status = 0;
 557
 558         if(newspectatee_status != spectatee_status)
 559         {
 560                 // clear race stuff
 561                 race_laptime = 0;
 562                 race_checkpointtime = 0;
 563         }
 564         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 565         {
 566                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 567                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 568                 )
 569                         prev_p_health = -1;
 570                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 571                         prev_health = -1;
 572         }
 573         spectatee_status = newspectatee_status;
 574
 575         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 576 }
 577
 578 void Ent_Nagger()
 579 {
 580     int i, j, b, f;
 581
 582     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 583
 584         if(!(nags & 4))
 585         {
 586                 if(vote_called_vote)
 587                         strunzone(vote_called_vote);
 588                 vote_called_vote = string_null;
 589                 vote_active = 0;
 590         }
 591         else
 592         {
 593                 vote_active = 1;
 594         }
 595
 596         if(nags & 64)
 597         {
 598                 vote_yescount = ReadByte();
 599                 vote_nocount = ReadByte();
 600                 vote_needed = ReadByte();
 601                 vote_highlighted = ReadChar();
 602         }
 603
 604         if(nags & 128)
 605         {
 606                 if(vote_called_vote)
 607                         strunzone(vote_called_vote);
 608                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 609         }
 610
 611         if(nags & 1)
 612         {
 613                 for(j = 0; j < maxclients; ++j)
 614                         if(playerslots[j])
 615                                 playerslots[j].ready = 1;
 616                 for(i = 1; i <= maxclients; i += 8)
 617                 {
 618                         f = ReadByte();
 619                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 620                                 if (!(f & b))
 621                                         if(playerslots[j])
 622                                                 playerslots[j].ready = 0;
 623                 }
 624         }
 625
 626         ready_waiting = (nags & 1);
 627         ready_waiting_for_me = (nags & 2);
 628         vote_waiting = (nags & 4);
 629         vote_waiting_for_me = (nags & 8);
 630         warmup_stage = (nags & 16);
 631 }
 632
 633 void Ent_EliminatedPlayers()
 634 {
 635     int i, j, b, f;
 636
 637     int sf = ReadByte();
 638         if(sf & 1)
 639         {
 640                 for(j = 0; j < maxclients; ++j)
 641                         if(playerslots[j])
 642                                 playerslots[j].eliminated = 1;
 643                 for(i = 1; i <= maxclients; i += 8)
 644                 {
 645                         f = ReadByte();
 646                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 647                                 if (!(f & b))
 648                                         if(playerslots[j])
 649                                                 playerslots[j].eliminated = 0;
 650                 }
 651         }
 652 }
 653
 654 void Ent_RandomSeed()
 655 {
 656         float s;
 657         prandom_debug();
 658         s = ReadShort();
 659         psrandom(s);
 660 }
 661
 662 void Ent_ReadAccuracy(void)
 663 {
 664     int f, w;
 665     int sf = ReadInt24_t();
 666         if(sf == 0)
 667         {
 668                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 669                         weapon_accuracy[w] = -1;
 670                 return;
 671         }
 672
 673         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 674         {
 675                 if(sf & f)
 676                 {
 677             int b = ReadByte();
 678                         if(b == 0)
 679                                 weapon_accuracy[w] = -1;
 680                         else if(b == 255)
 681                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 682                         else
 683                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 684                 }
 685                 if(f == 0x800000)
 686                         f = 1;
 687                 else
 688                         f *= 2;
 689         }
 690 }
 691
 692 void Spawn_Draw(void)
 693 {SELFPARAM();
 694         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 695 }
 696
 697 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 698 {SELFPARAM();
 699         float teamnum = (ReadByte() - 1);
 700         vector spn_origin;
 701         spn_origin.x = ReadShort();
 702         spn_origin.y = ReadShort();
 703         spn_origin.z = ReadShort();
 704
 705         if(is_new)
 706         {
 707                 self.origin = spn_origin;
 708                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 709                 droptofloor();
 710
 711                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 712                 {
 713                         self.mdl = "models/spawnpoint.md3";
 714                         self.colormod = Team_ColorRGB(teamnum);
 715                         precache_model(self.mdl);
 716                         setmodel(self, self.mdl);
 717                         self.drawmask = MASK_NORMAL;
 718                         //self.movetype = MOVETYPE_NOCLIP;
 719                         //self.draw = Spawn_Draw;
 720                 }*/
 721                 if(autocvar_cl_spawn_point_particles)
 722                 {
 723                         if((serverflags & SERVERFLAG_TEAMPLAY))
 724                         {
 725                                 switch(teamnum)
 726                                 {
 727                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 728                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 729                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 730                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 731                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 732                                 }
 733                         }
 734                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 735
 736                         self.draw = Spawn_Draw;
 737                 }
 738         }
 739
 740         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 741 }
 742
 743 void Ent_ReadSpawnEvent(float is_new)
 744 {SELFPARAM();
 745         // If entnum is 0, ONLY do the local spawn actions
 746         // this way the server can disable the sending of
 747         // spawn origin or such to clients if wanted.
 748         float entnum = ReadByte();
 749
 750         if(entnum)
 751         {
 752                 self.origin_x = ReadShort();
 753                 self.origin_y = ReadShort();
 754                 self.origin_z = ReadShort();
 755
 756                 if(is_new)
 757                 {
 758                         float teamnum = GetPlayerColor(entnum - 1);
 759
 760                         if(autocvar_cl_spawn_event_particles)
 761                         {
 762                                 switch(teamnum)
 763                                 {
 764                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 765                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 766                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 767                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 768                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 769                                 }
 770                         }
 771                         if(autocvar_cl_spawn_event_sound)
 772                         {
 773                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 774                         }
 775                 }
 776         }
 777
 778         // local spawn actions
 779         if(is_new && (!entnum || (entnum == player_localentnum)))
 780         {
 781                 zoomin_effect = 1;
 782                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 783
 784                 if(autocvar_cl_unpress_zoom_on_spawn)
 785                 {
 786                         localcmd("-zoom\n");
 787                         button_zoom = false;
 788                 }
 789         }
 790         HUD_Radar_Hide_Maximized();
 791         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 792 }
 793
 794 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 795 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 796 void Ent_RadarLink();
 797 void Ent_Init();
 798 void Ent_ScoresInfo();
 799 void CSQC_Ent_Update(float bIsNewEntity)
 800 {SELFPARAM();
 801         float t;
 802         float savetime;
 803         t = ReadByte();
 804
 805         if(autocvar_developer_csqcentities)
 806                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 807
 808         // set up the "time" global for received entities to be correct for interpolation purposes
 809         savetime = time;
 810         if(servertime)
 811         {
 812                 time = servertime;
 813         }
 814         else
 815         {
 816                 serverprevtime = time;
 817                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 818                 time = serverprevtime + serverdeltatime;
 819         }
 820
 821 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 822         if(self.enttype)
 823         {
 824                 if(t != self.enttype || bIsNewEntity)
 825                 {
 826                         //print("A CSQC entity changed its type!\n");
 827                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 828                         Ent_Remove();
 829                         clearentity(self);
 830                         bIsNewEntity = 1;
 831                 }
 832         }
 833         else
 834         {
 835                 if(!bIsNewEntity)
 836                 {
 837                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 838                         bIsNewEntity = 1;
 839                 }
 840         }
 841 #endif
 842         self.enttype = t;
 843         switch(t)
 844         {
 845                 case ENT_CLIENT_MUTATOR: {
 846                         int mutID = ReadMutator();
 847                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 848                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 849                         break;
 850                 }
 851                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 852                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 853                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 854                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 855                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 856                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 857                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 858                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 859                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 860                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 861                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 862                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 863                 case ENT_CLIENT_INIT: Ent_Init(); break;
 864                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 865                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 866                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 867                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 868                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 869                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 870                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 871                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 872                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 873                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 874                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 875                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 876                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 877                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 878                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 879                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 880                 case ENT_CLIENT_TURRET: ent_turret(); break;
 881                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 882                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 883                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 884                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 885                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 886                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 887                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 888                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 889                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 890                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 891                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 892                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 893                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 894                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 895                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 896                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 897                 case ENT_CLIENT_DOOR: ent_door(); break;
 898                 case ENT_CLIENT_PLAT: ent_plat(); break;
 899                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 900                 case ENT_CLIENT_CORNER: ent_corner(); break;
 901                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 902                 case ENT_CLIENT_TRAIN: ent_train(); break;
 903                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 904                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 905
 906                 default:
 907                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 908                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 909                         break;
 910         }
 911
 912         time = savetime;
 913 }
 914 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 915 // used when an entity changes its type. For an entity that someone interacts
 916 // with others, make sure it can no longer do so.
 917 void Ent_Remove()
 918 {SELFPARAM();
 919         if(self.entremove)
 920                 self.entremove();
 921
 922         if(self.skeletonindex)
 923         {
 924                 skel_delete(self.skeletonindex);
 925                 self.skeletonindex = 0;
 926         }
 927
 928         if(self.snd_looping > 0)
 929         {
 930                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 931                 self.snd_looping = 0;
 932         }
 933
 934         self.enttype = 0;
 935         self.classname = "";
 936         self.draw = menu_sub_null;
 937         self.entremove = menu_sub_null;
 938         // TODO possibly set more stuff to defaults
 939 }
 940 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 941 void CSQC_Ent_Remove()
 942 {SELFPARAM();
 943         if(autocvar_developer_csqcentities)
 944                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 945
 946         if(wasfreed(self))
 947         {
 948                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 949                 return;
 950         }
 951         if(self.enttype)
 952                 Ent_Remove();
 953         remove(self);
 954 }
 955
 956 void Gamemode_Init()
 957 {
 958         if (!isdemo())
 959         {
 960                 if(!(calledhooks & HOOK_START))
 961                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 962                 calledhooks |= HOOK_START;
 963         }
 964 }
 965 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 966 void CSQC_Parse_StuffCmd(string strMessage)
 967 {
 968         if(autocvar_developer_csqcentities)
 969                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 970
 971         localcmd(strMessage);
 972 }
 973 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 974 void CSQC_Parse_Print(string strMessage)
 975 {
 976         if(autocvar_developer_csqcentities)
 977                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 978
 979         print(ColorTranslateRGB(strMessage));
 980 }
 981
 982 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 983 void CSQC_Parse_CenterPrint(string strMessage)
 984 {
 985         if(autocvar_developer_csqcentities)
 986                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 987
 988         centerprint_hud(strMessage);
 989 }
 990
 991 string notranslate_fogcmd1 = "\nfog ";
 992 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 993 void Fog_Force()
 994 {
 995         // TODO somehow thwart prvm_globalset client ...
 996
 997         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 998                 { localcmd("\nr_drawfog 0\n"); }
 999         else if(forcefog != "")
1000                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1001 }
1002
1003 void Gamemode_Init();
1004 void Ent_ScoresInfo()
1005 {SELFPARAM();
1006     int i;
1007         self.classname = "ent_client_scores_info";
1008         gametype = ReadInt24_t();
1009         HUD_ModIcons_SetFunc();
1010         for(i = 0; i < MAX_SCORE; ++i)
1011         {
1012                 if(scores_label[i])
1013                         strunzone(scores_label[i]);
1014                 scores_label[i] = strzone(ReadString());
1015                 scores_flags[i] = ReadByte();
1016         }
1017         for(i = 0; i < MAX_TEAMSCORE; ++i)
1018         {
1019                 if(teamscores_label[i])
1020                         strunzone(teamscores_label[i]);
1021                 teamscores_label[i] = strzone(ReadString());
1022                 teamscores_flags[i] = ReadByte();
1023         }
1024         HUD_InitScores();
1025         Gamemode_Init();
1026 }
1027
1028 void Ent_Init()
1029 {SELFPARAM();
1030         self.classname = "ent_client_init";
1031
1032         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1033
1034         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1035         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1036         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1037         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1042
1043         if(forcefog)
1044                 strunzone(forcefog);
1045         forcefog = strzone(ReadString());
1046
1047         armorblockpercent = ReadByte() / 255.0;
1048
1049         g_balance_mortar_bouncefactor = ReadCoord();
1050         g_balance_mortar_bouncestop = ReadCoord();
1051         g_balance_electro_secondary_bouncefactor = ReadCoord();
1052         g_balance_electro_secondary_bouncestop = ReadCoord();
1053
1054         vortex_scope = !ReadByte();
1055         rifle_scope = !ReadByte();
1056
1057         serverflags = ReadByte();
1058
1059         minelayer_maxmines = ReadByte();
1060
1061         hagar_maxrockets = ReadByte();
1062
1063         g_trueaim_minrange = ReadCoord();
1064         g_balance_porto_secondary = ReadByte();
1065
1066         if(!postinit)
1067                 PostInit();
1068 }
1069
1070 void Net_ReadRace()
1071 {
1072         float b;
1073
1074         b = ReadByte();
1075
1076         switch(b)
1077         {
1078                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1079                         race_checkpoint = ReadByte();
1080                         race_time = ReadInt24_t();
1081                         race_previousbesttime = ReadInt24_t();
1082                         if(race_previousbestname)
1083                                 strunzone(race_previousbestname);
1084                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1085
1086                         race_checkpointtime = time;
1087
1088                         if(race_checkpoint == 0 || race_checkpoint == 254)
1089                         {
1090                                 race_penaltyaccumulator = 0;
1091                                 race_laptime = time; // valid
1092                         }
1093
1094                         break;
1095
1096                 case RACE_NET_CHECKPOINT_CLEAR:
1097                         race_laptime = 0;
1098                         race_checkpointtime = 0;
1099                         break;
1100
1101                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1102                         race_laptime = ReadCoord();
1103                         race_checkpointtime = -99999;
1104                         // fall through
1105                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1106                         race_nextcheckpoint = ReadByte();
1107
1108                         race_nextbesttime = ReadInt24_t();
1109                         if(race_nextbestname)
1110                                 strunzone(race_nextbestname);
1111                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1112                         break;
1113
1114                 case RACE_NET_CHECKPOINT_HIT_RACE:
1115                         race_mycheckpoint = ReadByte();
1116                         race_mycheckpointtime = time;
1117                         race_mycheckpointdelta = ReadInt24_t();
1118                         race_mycheckpointlapsdelta = ReadByte();
1119                         if(race_mycheckpointlapsdelta >= 128)
1120                                 race_mycheckpointlapsdelta -= 256;
1121                         if(race_mycheckpointenemy)
1122                                 strunzone(race_mycheckpointenemy);
1123                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1124                         break;
1125
1126                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1127                         race_othercheckpoint = ReadByte();
1128                         race_othercheckpointtime = time;
1129                         race_othercheckpointdelta = ReadInt24_t();
1130                         race_othercheckpointlapsdelta = ReadByte();
1131                         if(race_othercheckpointlapsdelta >= 128)
1132                                 race_othercheckpointlapsdelta -= 256;
1133                         if(race_othercheckpointenemy)
1134                                 strunzone(race_othercheckpointenemy);
1135                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1136                         break;
1137
1138                 case RACE_NET_PENALTY_RACE:
1139                         race_penaltyeventtime = time;
1140                         race_penaltytime = ReadShort();
1141                         //race_penaltyaccumulator += race_penaltytime;
1142                         if(race_penaltyreason)
1143                                 strunzone(race_penaltyreason);
1144                         race_penaltyreason = strzone(ReadString());
1145                         break;
1146
1147                 case RACE_NET_PENALTY_QUALIFYING:
1148                         race_penaltyeventtime = time;
1149                         race_penaltytime = ReadShort();
1150                         race_penaltyaccumulator += race_penaltytime;
1151                         if(race_penaltyreason)
1152                                 strunzone(race_penaltyreason);
1153                         race_penaltyreason = strzone(ReadString());
1154                         break;
1155
1156                 case RACE_NET_SERVER_RECORD:
1157                         race_server_record = ReadInt24_t();
1158                         break;
1159                 case RACE_NET_SPEED_AWARD:
1160                         race_speedaward = ReadInt24_t();
1161                         if(race_speedaward_holder)
1162                                 strunzone(race_speedaward_holder);
1163                         race_speedaward_holder = strzone(ReadString());
1164                         break;
1165                 case RACE_NET_SPEED_AWARD_BEST:
1166                         race_speedaward_alltimebest = ReadInt24_t();
1167                         if(race_speedaward_alltimebest_holder)
1168                                 strunzone(race_speedaward_alltimebest_holder);
1169                         race_speedaward_alltimebest_holder = strzone(ReadString());
1170                         break;
1171                 case RACE_NET_SERVER_RANKINGS:
1172                         float prevpos, del;
1173             int pos = ReadShort();
1174                         prevpos = ReadShort();
1175                         del = ReadShort();
1176
1177                         // move other rankings out of the way
1178             int i;
1179                         if (prevpos) {
1180                                 for (i=prevpos-1;i>pos-1;--i) {
1181                                         grecordtime[i] = grecordtime[i-1];
1182                                         if(grecordholder[i])
1183                                                 strunzone(grecordholder[i]);
1184                                         grecordholder[i] = strzone(grecordholder[i-1]);
1185                                 }
1186                         } else if (del) { // a record has been deleted by the admin
1187                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1188                                         if (i == RANKINGS_CNT-1) { // clear out last record
1189                                                 grecordtime[i] = 0;
1190                                                 if (grecordholder[i])
1191                                                         strunzone(grecordholder[i]);
1192                                                 grecordholder[i] = string_null;
1193                                         }
1194                                         else {
1195                                                 grecordtime[i] = grecordtime[i+1];
1196                                                 if (grecordholder[i])
1197                                                         strunzone(grecordholder[i]);
1198                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1199                                         }
1200                                 }
1201                         } else { // player has no ranked record yet
1202                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1203                                         grecordtime[i] = grecordtime[i-1];
1204                                         if(grecordholder[i])
1205                                                 strunzone(grecordholder[i]);
1206                                         grecordholder[i] = strzone(grecordholder[i-1]);
1207                                 }
1208                         }
1209
1210                         // store new ranking
1211                         if(grecordholder[pos-1] != "")
1212                                 strunzone(grecordholder[pos-1]);
1213                         grecordholder[pos-1] = strzone(ReadString());
1214                         grecordtime[pos-1] = ReadInt24_t();
1215                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1216                                 race_myrank = pos;
1217                         break;
1218                 case RACE_NET_SERVER_STATUS:
1219                         race_status = ReadShort();
1220                         if(race_status_name)
1221                                 strunzone(race_status_name);
1222                         race_status_name = strzone(ReadString());
1223         }
1224 }
1225
1226 void Net_TeamNagger()
1227 {
1228         teamnagger = 1;
1229 }
1230
1231 void Net_ReadPingPLReport()
1232 {
1233         int e, pi, pl, ml;
1234         e = ReadByte();
1235         pi = ReadShort();
1236         pl = ReadByte();
1237         ml = ReadByte();
1238         if (!(playerslots[e]))
1239                 return;
1240         playerslots[e].ping = pi;
1241         playerslots[e].ping_packetloss = pl / 255.0;
1242         playerslots[e].ping_movementloss = ml / 255.0;
1243 }
1244
1245 void Net_WeaponComplain()
1246 {
1247         complain_weapon = ReadByte();
1248
1249         if(complain_weapon_name)
1250                 strunzone(complain_weapon_name);
1251         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1252
1253         complain_weapon_type = ReadByte();
1254
1255         complain_weapon_time = time;
1256         weapontime = time; // ping the weapon panel
1257
1258         switch(complain_weapon_type)
1259         {
1260                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1261                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1262                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1263         }
1264 }
1265
1266 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1267 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1268 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1269 float CSQC_Parse_TempEntity()
1270 {
1271         // Acquire TE ID
1272         int nTEID = ReadByte();
1273
1274         if (autocvar_developer_csqcentities)
1275                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1276
1277         switch (nTEID)
1278         {
1279                 case TE_CSQC_MUTATOR:
1280                         int mutID = ReadMutator();
1281                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1282                         return true;
1283                 case TE_CSQC_TARGET_MUSIC:
1284                         Net_TargetMusic();
1285                         return true;
1286                 case TE_CSQC_PICTURE:
1287                         Net_MapVote_Picture();
1288                         return true;
1289                 case TE_CSQC_RACE:
1290                         Net_ReadRace();
1291                         return true;
1292                 case TE_CSQC_VORTEXBEAMPARTICLE:
1293                         Net_ReadVortexBeamParticle();
1294                         return true;
1295                 case TE_CSQC_TEAMNAGGER:
1296                         Net_TeamNagger();
1297                         return true;
1298                 case TE_CSQC_ARC:
1299                         Net_ReadArc();
1300                         return true;
1301                 case TE_CSQC_PINGPLREPORT:
1302                         Net_ReadPingPLReport();
1303                         return true;
1304                 case TE_CSQC_WEAPONCOMPLAIN:
1305                         Net_WeaponComplain();
1306                         return true;
1307                 case TE_CSQC_VEHICLESETUP:
1308                         Net_VehicleSetup();
1309                         return true;
1310                 case TE_CSQC_SVNOTICE:
1311                         cl_notice_read();
1312                         return true;
1313                 case TE_CSQC_SHOCKWAVEPARTICLE:
1314                         Net_ReadShockwaveParticle();
1315                         return true;
1316                 default:
1317                         // No special logic for this temporary entity; return 0 so the engine can handle it
1318                         return false;
1319         }
1320 }
1321
1322 string getcommandkey(string text, string command)
1323 {
1324         string keys;
1325         float n, j, k, l = 0;
1326
1327         if (!autocvar_hud_showbinds)
1328                 return text;
1329
1330         keys = db_get(binddb, command);
1331         if (keys == "")
1332         {
1333                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1334                 for(j = 0; j < n; ++j)
1335                 {
1336                         k = stof(argv(j));
1337                         if(k != -1)
1338                         {
1339                                 if ("" == keys)
1340                                         keys = keynumtostring(k);
1341                                 else
1342                                         keys = strcat(keys, ", ", keynumtostring(k));
1343
1344                                 ++l;
1345                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1346                                         break;
1347                         }
1348
1349                 }
1350                 if (keys == "")
1351                         keys = "NO_KEY";
1352                 db_put(binddb, command, keys);
1353         }
1354
1355         if (keys == "NO_KEY") {
1356                 if (autocvar_hud_showbinds > 1)
1357                         return sprintf(_("%s (not bound)"), text);
1358                 else
1359                         return text;
1360         }
1361         else if (autocvar_hud_showbinds > 1)
1362                 return sprintf("%s (%s)", text, keys);
1363         else
1364                 return keys;
1365 }