qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "controlpoint.qh"
   6 #include "csqcmodel_hooks.qh"
   7 #include "damage.qh"
   8 #include "effects.qh"
   9 #include "generator.qh"
  10 #include "gibs.qh"
  11 #include "hook.qh"
  12 #include "hud.qh"
  13 #include "hud_config.qh"
  14 #include "laser.qh"
  15 #include "mapvoting.qh"
  16 #include "modeleffects.qh"
  17 #include "particles.qh"
  18 #include "prandom.qh"
  19 #include "scoreboard.qh"
  20 #include "shownames.qh"
  21 #include "sortlist.qh"
  22 #include "tuba.qh"
  23 #include "t_items.qh"
  24 #include "wall.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27
  28 #include "mutators/events.qh"
  29
  30 #include "weapons/projectile.qh"
  31
  32 #include "../common/buffs.qh"
  33 #include "../common/deathtypes.qh"
  34 #include "../common/effects.qh"
  35 #include "../common/mapinfo.qh"
  36 #include "../common/monsters/all.qh"
  37 #include "../common/nades.qh"
  38 #include "../common/net_notice.qh"
  39 #include "../common/notifications.qh"
  40 #include "../common/stats.qh"
  41 #include "../common/teams.qh"
  42
  43 #include "../common/items/all.qh"
  44
  45 #include "../common/mutators/base.qh"
  46
  47 #include "../common/weapons/all.qh"
  48
  49 #include "../csqcmodellib/cl_model.qh"
  50 #include "../csqcmodellib/interpolate.qh"
  51
  52 #include "../common/triggers/include.qh"
  53
  54 #include "../common/turrets/cl_turrets.qh"
  55 #include "../common/turrets/turrets.qh"
  56
  57 #include "../warpzonelib/client.qh"
  58
  59 // --------------------------------------------------------------------------
  60 // BEGIN REQUIRED CSQC FUNCTIONS
  61 //include "main.qh"
  62
  63 entity clearentity_ent;
  64 void clearentity(entity e)
  65 {
  66         if (!clearentity_ent)
  67         {
  68                 clearentity_ent = spawn();
  69                 clearentity_ent.classname = "clearentity";
  70         }
  71         int n = e.entnum;
  72         copyentity(clearentity_ent, e);
  73         e.entnum = n;
  74 }
  75
  76 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  77 void menu_show_error()
  78 {
  79         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  80 }
  81
  82 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  83 // Useful for precaching things
  84
  85 void menu_sub_null()
  86 {
  87 }
  88
  89 string forcefog;
  90 void ConsoleCommand_macro_init();
  91 void CSQC_Init(void)
  92 {
  93         prvm_language = strzone(cvar_string("prvm_language"));
  94
  95 #ifdef WATERMARK
  96         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  97 #endif
  98
  99         int i;
 100
 101         binddb = db_create();
 102         tempdb = db_create();
 103         ClientProgsDB = db_load("client.db");
 104         compressShortVector_init();
 105
 106         draw_endBoldFont();
 107         menu_visible = false;
 108         menu_show = menu_show_error;
 109         menu_action = func_null;
 110
 111         for(i = 0; i < 255; ++i)
 112                 if(getplayerkeyvalue(i, "viewentity") == "")
 113                         break;
 114         maxclients = i;
 115
 116         //registercommand("hud_configure");
 117         //registercommand("hud_save");
 118         //registercommand("menu_action");
 119
 120         ConsoleCommand_macro_init();
 121
 122         registercvar("hud_usecsqc", "1");
 123         registercvar("scoreboard_columns", "default");
 124
 125         registercvar("cl_nade_type", "3");
 126         registercvar("cl_pokenade_type", "zombie");
 127
 128         registercvar("cl_jumpspeedcap_min", "");
 129         registercvar("cl_jumpspeedcap_max", "");
 130
 131         gametype = 0;
 132
 133         // hud_fields uses strunzone on the titles!
 134         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 135                 hud_title[i] = strzone("(null)");
 136
 137         Cmd_HUD_SetFields(0);
 138
 139         postinit = false;
 140
 141         calledhooks = 0;
 142
 143         teams = Sort_Spawn();
 144         players = Sort_Spawn();
 145
 146         GetTeam(NUM_SPECTATOR, true); // add specs first
 147
 148         // needs to be done so early because of the constants they create
 149         static_init();
 150         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 151         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 152         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 153         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 154         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 155
 156         initialize_minigames();
 157
 158         // precaches
 159         precache_model("null");
 160         precache_sound("misc/hit.wav");
 161         precache_sound("misc/typehit.wav");
 162
 163         generator_precache();
 164         Projectile_Precache();
 165         Hook_Precache();
 166         GibSplash_Precache();
 167         Casings_Precache();
 168         Tuba_Precache();
 169         CSQCPlayer_Precache();
 170
 171         if(autocvar_cl_reticle)
 172         {
 173                 precache_pic("gfx/reticle_normal");
 174                 // weapon reticles are precached in weapon files
 175         }
 176
 177         get_mi_min_max_texcoords(1); // try the CLEVER way first
 178         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 179         shortmapname = mi_shortname;
 180
 181         if(precache_pic(minimapname) == "")
 182         {
 183                 // but maybe we have a non-clever minimap
 184                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 185                 if(precache_pic(minimapname) == "")
 186                         minimapname = ""; // FAIL
 187                 else
 188                         get_mi_min_max_texcoords(0); // load new texcoords
 189         }
 190
 191         mi_center = (mi_min + mi_max) * 0.5;
 192         mi_scale = mi_max - mi_min;
 193         minimapname = strzone(minimapname);
 194
 195         WarpZone_Init();
 196
 197         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 198         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 199 }
 200
 201 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 202 void Shutdown(void)
 203 {
 204         WarpZone_Shutdown();
 205
 206         remove(teams);
 207         remove(players);
 208         db_close(binddb);
 209         db_close(tempdb);
 210         if(autocvar_cl_db_saveasdump)
 211                 db_dump(ClientProgsDB, "client.db");
 212         else
 213                 db_save(ClientProgsDB, "client.db");
 214         db_close(ClientProgsDB);
 215
 216         if(camera_active)
 217                 cvar_set("chase_active",ftos(chase_active_backup));
 218
 219         // unset the event chasecam's chase_active
 220         if(autocvar_chase_active < 0)
 221                 cvar_set("chase_active", "0");
 222
 223         if (!isdemo())
 224         {
 225                 if (!(calledhooks & HOOK_START))
 226                         localcmd("\n_cl_hook_gamestart nop\n");
 227                 if (!(calledhooks & HOOK_END))
 228                         localcmd("\ncl_hook_gameend\n");
 229         }
 230
 231         deactivate_minigame();
 232         HUD_MinigameMenu_Close();
 233 }
 234
 235 .float has_team;
 236 float SetTeam(entity o, int Team)
 237 {
 238         entity tm;
 239         if(teamplay)
 240         {
 241                 switch(Team)
 242                 {
 243                         case -1:
 244                         case NUM_TEAM_1:
 245                         case NUM_TEAM_2:
 246                         case NUM_TEAM_3:
 247                         case NUM_TEAM_4:
 248                                 break;
 249                         default:
 250                                 if(GetTeam(Team, false) == world)
 251                                 {
 252                                         dprintf("trying to switch to unsupported team %d\n", Team);
 253                                         Team = NUM_SPECTATOR;
 254                                 }
 255                                 break;
 256                 }
 257         }
 258         else
 259         {
 260                 switch(Team)
 261                 {
 262                         case -1:
 263                         case 0:
 264                                 break;
 265                         default:
 266                                 if(GetTeam(Team, false) == world)
 267                                 {
 268                                         dprintf("trying to switch to unsupported team %d\n", Team);
 269                                         Team = NUM_SPECTATOR;
 270                                 }
 271                                 break;
 272                 }
 273         }
 274         if(Team == -1) // leave
 275         {
 276                 if(o.has_team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.has_team = 0;
 281                         return true;
 282                 }
 283         }
 284         else
 285         {
 286                 if (!o.has_team)
 287                 {
 288                         o.team = Team;
 289                         tm = GetTeam(Team, true);
 290                         tm.team_size += 1;
 291                         o.has_team = 1;
 292                         return true;
 293                 }
 294                 else if(Team != o.team)
 295                 {
 296                         tm = GetTeam(o.team, false);
 297                         tm.team_size -= 1;
 298                         o.team = Team;
 299                         tm = GetTeam(Team, true);
 300                         tm.team_size += 1;
 301                         return true;
 302                 }
 303         }
 304         return false;
 305 }
 306
 307 void Playerchecker_Think()
 308 {
 309     int i;
 310         entity e;
 311         for(i = 0; i < maxclients; ++i)
 312         {
 313                 e = playerslots[i];
 314                 if(GetPlayerName(i) == "")
 315                 {
 316                         if(e.sort_prev)
 317                         {
 318                                 // player disconnected
 319                                 SetTeam(e, -1);
 320                                 RemovePlayer(e);
 321                                 e.sort_prev = world;
 322                                 //e.gotscores = 0;
 323                         }
 324                 }
 325                 else
 326                 {
 327                         if (!e.sort_prev)
 328                         {
 329                                 // player connected
 330                                 if (!e)
 331                                         playerslots[i] = e = spawn();
 332                                 e.sv_entnum = i;
 333                                 e.ping = 0;
 334                                 e.ping_packetloss = 0;
 335                                 e.ping_movementloss = 0;
 336                                 //e.gotscores = 0; // we might already have the scores...
 337                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 338                                 RegisterPlayer(e);
 339                                 HUD_UpdatePlayerPos(e);
 340                         }
 341                 }
 342         }
 343         self.nextthink = time + 0.2;
 344 }
 345
 346 void Porto_Init();
 347 void TrueAim_Init();
 348 void PostInit(void)
 349 {
 350         entity playerchecker;
 351         playerchecker = spawn();
 352         playerchecker.think = Playerchecker_Think;
 353         playerchecker.nextthink = time + 0.2;
 354
 355         Porto_Init();
 356         TrueAim_Init();
 357
 358         postinit = true;
 359 }
 360
 361 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 362 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 363 // All keys are in ascii.
 364 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 365 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 366 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 367 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 368 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 369 {
 370         float bSkipKey;
 371         bSkipKey = false;
 372
 373         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 374                 return true;
 375
 376         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 377                 return true;
 378
 379         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 380                 return true;
 381
 382         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 383                 return true;
 384
 385         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 386                 return true;
 387
 388         if(menu_visible && menu_action)
 389                 if(menu_action(bInputType, nPrimary, nSecondary))
 390                         return true;
 391
 392         return bSkipKey;
 393 }
 394
 395 // END REQUIRED CSQC FUNCTIONS
 396 // --------------------------------------------------------------------------
 397
 398 // --------------------------------------------------------------------------
 399 // BEGIN OPTIONAL CSQC FUNCTIONS
 400
 401 void Ent_RemoveEntCS()
 402 {
 403         entcs_receiver[self.sv_entnum] = world;
 404 }
 405 void Ent_ReadEntCS()
 406 {
 407     int sf;
 408         InterpolateOrigin_Undo();
 409
 410         self.classname = "entcs_receiver";
 411         sf = ReadByte();
 412
 413         if(sf & 1)
 414                 self.sv_entnum = ReadByte();
 415         if(sf & 2)
 416         {
 417                 self.origin_x = ReadShort();
 418                 self.origin_y = ReadShort();
 419                 self.origin_z = ReadShort();
 420                 setorigin(self, self.origin);
 421         }
 422         if(sf & 4)
 423         {
 424                 self.angles_y = ReadByte() * 360.0 / 256;
 425                 self.angles_x = self.angles_z = 0;
 426         }
 427         if(sf & 8)
 428                 self.healthvalue = ReadByte() * 10;
 429         if(sf & 16)
 430                 self.armorvalue = ReadByte() * 10;
 431
 432         entcs_receiver[self.sv_entnum] = self;
 433         self.entremove = Ent_RemoveEntCS;
 434         self.iflags |= IFLAG_ORIGIN;
 435
 436         InterpolateOrigin_Note();
 437 }
 438
 439 void Ent_Remove();
 440
 441 void Ent_RemovePlayerScore()
 442 {
 443         if(self.owner) {
 444                 SetTeam(self.owner, -1);
 445                 self.owner.gotscores = 0;
 446                 for(int i = 0; i < MAX_SCORE; ++i) {
 447                         self.owner.(scores[i]) = 0; // clear all scores
 448                 }
 449         }
 450 }
 451
 452 void Ent_ReadPlayerScore()
 453 {
 454         int i, n;
 455         bool isNew;
 456         entity o;
 457
 458         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 459         // (no I've never heard of M-x replace-string, sed, or anything like that)
 460         isNew = !self.owner; // workaround for DP bug
 461         n = ReadByte()-1;
 462
 463 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 464         if(!isNew && n != self.sv_entnum)
 465         {
 466                 //print("A CSQC entity changed its owner!\n");
 467                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 468                 isNew = true;
 469                 Ent_Remove();
 470                 self.enttype = ENT_CLIENT_SCORES;
 471         }
 472 #endif
 473
 474         self.sv_entnum = n;
 475
 476         if (!(playerslots[self.sv_entnum]))
 477                 playerslots[self.sv_entnum] = spawn();
 478         o = self.owner = playerslots[self.sv_entnum];
 479         o.sv_entnum = self.sv_entnum;
 480         o.gotscores = 1;
 481
 482         //if (!o.sort_prev)
 483         //      RegisterPlayer(o);
 484         //playerchecker will do this for us later, if it has not already done so
 485
 486     int sf, lf;
 487 #if MAX_SCORE <= 8
 488         sf = ReadByte();
 489         lf = ReadByte();
 490 #else
 491         sf = ReadShort();
 492         lf = ReadShort();
 493 #endif
 494     int p;
 495         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 496                 if(sf & p)
 497                 {
 498                         if(lf & p)
 499                                 o.(scores[i]) = ReadInt24_t();
 500                         else
 501                                 o.(scores[i]) = ReadChar();
 502                 }
 503
 504         if(o.sort_prev)
 505                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 506
 507         self.entremove = Ent_RemovePlayerScore;
 508 }
 509
 510 void Ent_ReadTeamScore()
 511 {
 512         int i;
 513         entity o;
 514
 515         self.team = ReadByte();
 516         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 517
 518     int sf, lf;
 519 #if MAX_TEAMSCORE <= 8
 520         sf = ReadByte();
 521         lf = ReadByte();
 522 #else
 523         sf = ReadShort();
 524         lf = ReadShort();
 525 #endif
 526         int p;
 527         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 528                 if(sf & p)
 529                 {
 530                         if(lf & p)
 531                                 o.(teamscores[i]) = ReadInt24_t();
 532                         else
 533                                 o.(teamscores[i]) = ReadChar();
 534                 }
 535
 536         HUD_UpdateTeamPos(o);
 537 }
 538
 539 void Ent_ClientData()
 540 {
 541         float newspectatee_status;
 542
 543     int f = ReadByte();
 544
 545         scoreboard_showscores_force = (f & 1);
 546
 547         if(f & 2)
 548         {
 549                 newspectatee_status = ReadByte();
 550                 if(newspectatee_status == player_localnum + 1)
 551                         newspectatee_status = -1; // observing
 552         }
 553         else
 554                 newspectatee_status = 0;
 555
 556         spectatorbutton_zoom = (f & 4);
 557
 558         if(f & 8)
 559         {
 560                 angles_held_status = 1;
 561                 angles_held.x = ReadAngle();
 562                 angles_held.y = ReadAngle();
 563                 angles_held.z = 0;
 564         }
 565         else
 566                 angles_held_status = 0;
 567
 568         if(newspectatee_status != spectatee_status)
 569         {
 570                 // clear race stuff
 571                 race_laptime = 0;
 572                 race_checkpointtime = 0;
 573         }
 574         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 575         {
 576                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 577                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 578                 )
 579                         prev_p_health = -1;
 580                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 581                         prev_health = -1;
 582         }
 583         spectatee_status = newspectatee_status;
 584
 585         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 586 }
 587
 588 void Ent_Nagger()
 589 {
 590     int i, j, b, f;
 591
 592     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 593
 594         if(!(nags & 4))
 595         {
 596                 if(vote_called_vote)
 597                         strunzone(vote_called_vote);
 598                 vote_called_vote = string_null;
 599                 vote_active = 0;
 600         }
 601         else
 602         {
 603                 vote_active = 1;
 604         }
 605
 606         if(nags & 64)
 607         {
 608                 vote_yescount = ReadByte();
 609                 vote_nocount = ReadByte();
 610                 vote_needed = ReadByte();
 611                 vote_highlighted = ReadChar();
 612         }
 613
 614         if(nags & 128)
 615         {
 616                 if(vote_called_vote)
 617                         strunzone(vote_called_vote);
 618                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 619         }
 620
 621         if(nags & 1)
 622         {
 623                 for(j = 0; j < maxclients; ++j)
 624                         if(playerslots[j])
 625                                 playerslots[j].ready = 1;
 626                 for(i = 1; i <= maxclients; i += 8)
 627                 {
 628                         f = ReadByte();
 629                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 630                                 if (!(f & b))
 631                                         if(playerslots[j])
 632                                                 playerslots[j].ready = 0;
 633                 }
 634         }
 635
 636         ready_waiting = (nags & 1);
 637         ready_waiting_for_me = (nags & 2);
 638         vote_waiting = (nags & 4);
 639         vote_waiting_for_me = (nags & 8);
 640         warmup_stage = (nags & 16);
 641 }
 642
 643 void Ent_EliminatedPlayers()
 644 {
 645     int i, j, b, f;
 646
 647     int sf = ReadByte();
 648         if(sf & 1)
 649         {
 650                 for(j = 0; j < maxclients; ++j)
 651                         if(playerslots[j])
 652                                 playerslots[j].eliminated = 1;
 653                 for(i = 1; i <= maxclients; i += 8)
 654                 {
 655                         f = ReadByte();
 656                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 657                                 if (!(f & b))
 658                                         if(playerslots[j])
 659                                                 playerslots[j].eliminated = 0;
 660                 }
 661         }
 662 }
 663
 664 void Ent_RandomSeed()
 665 {
 666         float s;
 667         prandom_debug();
 668         s = ReadShort();
 669         psrandom(s);
 670 }
 671
 672 void Ent_ReadAccuracy(void)
 673 {
 674     int f, w;
 675     int sf = ReadInt24_t();
 676         if(sf == 0)
 677         {
 678                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 679                         weapon_accuracy[w] = -1;
 680                 return;
 681         }
 682
 683         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 684         {
 685                 if(sf & f)
 686                 {
 687             int b = ReadByte();
 688                         if(b == 0)
 689                                 weapon_accuracy[w] = -1;
 690                         else if(b == 255)
 691                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 692                         else
 693                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 694                 }
 695                 if(f == 0x800000)
 696                         f = 1;
 697                 else
 698                         f *= 2;
 699         }
 700 }
 701
 702 void Spawn_Draw(void)
 703 {
 704         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 705 }
 706
 707 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 708 {
 709         float teamnum = (ReadByte() - 1);
 710         vector spn_origin;
 711         spn_origin.x = ReadShort();
 712         spn_origin.y = ReadShort();
 713         spn_origin.z = ReadShort();
 714
 715         if(is_new)
 716         {
 717                 self.origin = spn_origin;
 718                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 719                 droptofloor();
 720
 721                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 722                 {
 723                         self.mdl = "models/spawnpoint.md3";
 724                         self.colormod = Team_ColorRGB(teamnum);
 725                         precache_model(self.mdl);
 726                         setmodel(self, self.mdl);
 727                         self.drawmask = MASK_NORMAL;
 728                         //self.movetype = MOVETYPE_NOCLIP;
 729                         //self.draw = Spawn_Draw;
 730                 }*/
 731                 if(autocvar_cl_spawn_point_particles)
 732                 {
 733                         if((serverflags & SERVERFLAG_TEAMPLAY))
 734                         {
 735                                 switch(teamnum)
 736                                 {
 737                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 738                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 739                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 740                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 741                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 742                                 }
 743                         }
 744                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 745
 746                         self.draw = Spawn_Draw;
 747                 }
 748         }
 749
 750         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 751 }
 752
 753 void Ent_ReadSpawnEvent(float is_new)
 754 {
 755         // If entnum is 0, ONLY do the local spawn actions
 756         // this way the server can disable the sending of
 757         // spawn origin or such to clients if wanted.
 758         float entnum = ReadByte();
 759
 760         if(entnum)
 761         {
 762                 self.origin_x = ReadShort();
 763                 self.origin_y = ReadShort();
 764                 self.origin_z = ReadShort();
 765
 766                 if(is_new)
 767                 {
 768                         float teamnum = GetPlayerColor(entnum - 1);
 769
 770                         if(autocvar_cl_spawn_event_particles)
 771                         {
 772                                 switch(teamnum)
 773                                 {
 774                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 775                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 776                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 777                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 778                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 779                                 }
 780                         }
 781                         if(autocvar_cl_spawn_event_sound)
 782                         {
 783                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 784                         }
 785                 }
 786         }
 787
 788         // local spawn actions
 789         if(is_new && (!entnum || (entnum == player_localentnum)))
 790         {
 791                 zoomin_effect = 1;
 792                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 793
 794                 if(autocvar_cl_unpress_zoom_on_spawn)
 795                 {
 796                         localcmd("-zoom\n");
 797                         button_zoom = false;
 798                 }
 799         }
 800         HUD_Radar_Hide_Maximized();
 801         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 802 }
 803
 804 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 805 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 806 void Ent_RadarLink();
 807 void Ent_Init();
 808 void Ent_ScoresInfo();
 809 void CSQC_Ent_Update(float bIsNewEntity)
 810 {
 811         float t;
 812         float savetime;
 813         t = ReadByte();
 814
 815         if(autocvar_developer_csqcentities)
 816                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 817
 818         // set up the "time" global for received entities to be correct for interpolation purposes
 819         savetime = time;
 820         if(servertime)
 821         {
 822                 time = servertime;
 823         }
 824         else
 825         {
 826                 serverprevtime = time;
 827                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 828                 time = serverprevtime + serverdeltatime;
 829         }
 830
 831 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 832         if(self.enttype)
 833         {
 834                 if(t != self.enttype || bIsNewEntity)
 835                 {
 836                         //print("A CSQC entity changed its type!\n");
 837                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 838                         Ent_Remove();
 839                         clearentity(self);
 840                         bIsNewEntity = 1;
 841                 }
 842         }
 843         else
 844         {
 845                 if(!bIsNewEntity)
 846                 {
 847                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 848                         bIsNewEntity = 1;
 849                 }
 850         }
 851 #endif
 852         self.enttype = t;
 853         switch(t)
 854         {
 855                 case ENT_CLIENT_MUTATOR: {
 856                         int mutID = ReadMutator();
 857                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 858                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 859                         break;
 860                 }
 861                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 862                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 863                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 864                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 865                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 866                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 867                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 868                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 869                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 870                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 871                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 872                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 873                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 874                 case ENT_CLIENT_INIT: Ent_Init(); break;
 875                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 876                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 877                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 878                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 879                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 880                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 881                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 882                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 883                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 884                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 885                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 886                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 887                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 888                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 889                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 890                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 891                 case ENT_CLIENT_TURRET: ent_turret(); break;
 892                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 893                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 894                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 895                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 896                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 897                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 898                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 899                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 900                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 901                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 902                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 903                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 904                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 905                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 906                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 907                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 908                 case ENT_CLIENT_DOOR: ent_door(); break;
 909                 case ENT_CLIENT_PLAT: ent_plat(); break;
 910                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 911                 case ENT_CLIENT_CORNER: ent_corner(); break;
 912                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 913                 case ENT_CLIENT_TRAIN: ent_train(); break;
 914                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 915                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 916
 917                 default:
 918                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 919                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 920                         break;
 921         }
 922
 923         time = savetime;
 924 }
 925 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 926 // used when an entity changes its type. For an entity that someone interacts
 927 // with others, make sure it can no longer do so.
 928 void Ent_Remove()
 929 {
 930         if(self.entremove)
 931                 self.entremove();
 932
 933         if(self.skeletonindex)
 934         {
 935                 skel_delete(self.skeletonindex);
 936                 self.skeletonindex = 0;
 937         }
 938
 939         if(self.snd_looping > 0)
 940         {
 941                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 942                 self.snd_looping = 0;
 943         }
 944
 945         self.enttype = 0;
 946         self.classname = "";
 947         self.draw = menu_sub_null;
 948         self.entremove = menu_sub_null;
 949         // TODO possibly set more stuff to defaults
 950 }
 951 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 952 void CSQC_Ent_Remove()
 953 {
 954         if(autocvar_developer_csqcentities)
 955                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 956
 957         if(wasfreed(self))
 958         {
 959                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 960                 return;
 961         }
 962         if(self.enttype)
 963                 Ent_Remove();
 964         remove(self);
 965 }
 966
 967 void Gamemode_Init()
 968 {
 969         if (!isdemo())
 970         {
 971                 if(!(calledhooks & HOOK_START))
 972                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 973                 calledhooks |= HOOK_START;
 974         }
 975 }
 976 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 977 void CSQC_Parse_StuffCmd(string strMessage)
 978 {
 979         if(autocvar_developer_csqcentities)
 980                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 981
 982         localcmd(strMessage);
 983 }
 984 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 985 void CSQC_Parse_Print(string strMessage)
 986 {
 987         if(autocvar_developer_csqcentities)
 988                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 989
 990         print(ColorTranslateRGB(strMessage));
 991 }
 992
 993 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 994 void CSQC_Parse_CenterPrint(string strMessage)
 995 {
 996         if(autocvar_developer_csqcentities)
 997                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 998
 999         centerprint_hud(strMessage);
1000 }
1001
1002 string notranslate_fogcmd1 = "\nfog ";
1003 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1004 void Fog_Force()
1005 {
1006         // TODO somehow thwart prvm_globalset client ...
1007
1008         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1009                 { localcmd("\nr_drawfog 0\n"); }
1010         else if(forcefog != "")
1011                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1012 }
1013
1014 void Gamemode_Init();
1015 void Ent_ScoresInfo()
1016 {
1017     int i;
1018         self.classname = "ent_client_scores_info";
1019         gametype = ReadInt24_t();
1020         HUD_ModIcons_SetFunc();
1021         for(i = 0; i < MAX_SCORE; ++i)
1022         {
1023                 if(scores_label[i])
1024                         strunzone(scores_label[i]);
1025                 scores_label[i] = strzone(ReadString());
1026                 scores_flags[i] = ReadByte();
1027         }
1028         for(i = 0; i < MAX_TEAMSCORE; ++i)
1029         {
1030                 if(teamscores_label[i])
1031                         strunzone(teamscores_label[i]);
1032                 teamscores_label[i] = strzone(ReadString());
1033                 teamscores_flags[i] = ReadByte();
1034         }
1035         HUD_InitScores();
1036         Gamemode_Init();
1037 }
1038
1039 void Ent_Init()
1040 {
1041         self.classname = "ent_client_init";
1042
1043         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1044
1045         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1046         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1047         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1048         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1049         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1050         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1051         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1052         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1053
1054         if(forcefog)
1055                 strunzone(forcefog);
1056         forcefog = strzone(ReadString());
1057
1058         armorblockpercent = ReadByte() / 255.0;
1059
1060         g_balance_mortar_bouncefactor = ReadCoord();
1061         g_balance_mortar_bouncestop = ReadCoord();
1062         g_balance_electro_secondary_bouncefactor = ReadCoord();
1063         g_balance_electro_secondary_bouncestop = ReadCoord();
1064
1065         vortex_scope = !ReadByte();
1066         rifle_scope = !ReadByte();
1067
1068         serverflags = ReadByte();
1069
1070         minelayer_maxmines = ReadByte();
1071
1072         hagar_maxrockets = ReadByte();
1073
1074         g_trueaim_minrange = ReadCoord();
1075         g_balance_porto_secondary = ReadByte();
1076
1077         if(!postinit)
1078                 PostInit();
1079 }
1080
1081 void Net_ReadRace()
1082 {
1083         float b;
1084
1085         b = ReadByte();
1086
1087         switch(b)
1088         {
1089                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1090                         race_checkpoint = ReadByte();
1091                         race_time = ReadInt24_t();
1092                         race_previousbesttime = ReadInt24_t();
1093                         if(race_previousbestname)
1094                                 strunzone(race_previousbestname);
1095                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1096
1097                         race_checkpointtime = time;
1098
1099                         if(race_checkpoint == 0 || race_checkpoint == 254)
1100                         {
1101                                 race_penaltyaccumulator = 0;
1102                                 race_laptime = time; // valid
1103                         }
1104
1105                         break;
1106
1107                 case RACE_NET_CHECKPOINT_CLEAR:
1108                         race_laptime = 0;
1109                         race_checkpointtime = 0;
1110                         break;
1111
1112                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1113                         race_laptime = ReadCoord();
1114                         race_checkpointtime = -99999;
1115                         // fall through
1116                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1117                         race_nextcheckpoint = ReadByte();
1118
1119                         race_nextbesttime = ReadInt24_t();
1120                         if(race_nextbestname)
1121                                 strunzone(race_nextbestname);
1122                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1123                         break;
1124
1125                 case RACE_NET_CHECKPOINT_HIT_RACE:
1126                         race_mycheckpoint = ReadByte();
1127                         race_mycheckpointtime = time;
1128                         race_mycheckpointdelta = ReadInt24_t();
1129                         race_mycheckpointlapsdelta = ReadByte();
1130                         if(race_mycheckpointlapsdelta >= 128)
1131                                 race_mycheckpointlapsdelta -= 256;
1132                         if(race_mycheckpointenemy)
1133                                 strunzone(race_mycheckpointenemy);
1134                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1135                         break;
1136
1137                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1138                         race_othercheckpoint = ReadByte();
1139                         race_othercheckpointtime = time;
1140                         race_othercheckpointdelta = ReadInt24_t();
1141                         race_othercheckpointlapsdelta = ReadByte();
1142                         if(race_othercheckpointlapsdelta >= 128)
1143                                 race_othercheckpointlapsdelta -= 256;
1144                         if(race_othercheckpointenemy)
1145                                 strunzone(race_othercheckpointenemy);
1146                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1147                         break;
1148
1149                 case RACE_NET_PENALTY_RACE:
1150                         race_penaltyeventtime = time;
1151                         race_penaltytime = ReadShort();
1152                         //race_penaltyaccumulator += race_penaltytime;
1153                         if(race_penaltyreason)
1154                                 strunzone(race_penaltyreason);
1155                         race_penaltyreason = strzone(ReadString());
1156                         break;
1157
1158                 case RACE_NET_PENALTY_QUALIFYING:
1159                         race_penaltyeventtime = time;
1160                         race_penaltytime = ReadShort();
1161                         race_penaltyaccumulator += race_penaltytime;
1162                         if(race_penaltyreason)
1163                                 strunzone(race_penaltyreason);
1164                         race_penaltyreason = strzone(ReadString());
1165                         break;
1166
1167                 case RACE_NET_SERVER_RECORD:
1168                         race_server_record = ReadInt24_t();
1169                         break;
1170                 case RACE_NET_SPEED_AWARD:
1171                         race_speedaward = ReadInt24_t();
1172                         if(race_speedaward_holder)
1173                                 strunzone(race_speedaward_holder);
1174                         race_speedaward_holder = strzone(ReadString());
1175                         break;
1176                 case RACE_NET_SPEED_AWARD_BEST:
1177                         race_speedaward_alltimebest = ReadInt24_t();
1178                         if(race_speedaward_alltimebest_holder)
1179                                 strunzone(race_speedaward_alltimebest_holder);
1180                         race_speedaward_alltimebest_holder = strzone(ReadString());
1181                         break;
1182                 case RACE_NET_SERVER_RANKINGS:
1183                         float prevpos, del;
1184             int pos = ReadShort();
1185                         prevpos = ReadShort();
1186                         del = ReadShort();
1187
1188                         // move other rankings out of the way
1189             int i;
1190                         if (prevpos) {
1191                                 for (i=prevpos-1;i>pos-1;--i) {
1192                                         grecordtime[i] = grecordtime[i-1];
1193                                         if(grecordholder[i])
1194                                                 strunzone(grecordholder[i]);
1195                                         grecordholder[i] = strzone(grecordholder[i-1]);
1196                                 }
1197                         } else if (del) { // a record has been deleted by the admin
1198                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1199                                         if (i == RANKINGS_CNT-1) { // clear out last record
1200                                                 grecordtime[i] = 0;
1201                                                 if (grecordholder[i])
1202                                                         strunzone(grecordholder[i]);
1203                                                 grecordholder[i] = string_null;
1204                                         }
1205                                         else {
1206                                                 grecordtime[i] = grecordtime[i+1];
1207                                                 if (grecordholder[i])
1208                                                         strunzone(grecordholder[i]);
1209                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1210                                         }
1211                                 }
1212                         } else { // player has no ranked record yet
1213                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1214                                         grecordtime[i] = grecordtime[i-1];
1215                                         if(grecordholder[i])
1216                                                 strunzone(grecordholder[i]);
1217                                         grecordholder[i] = strzone(grecordholder[i-1]);
1218                                 }
1219                         }
1220
1221                         // store new ranking
1222                         if(grecordholder[pos-1] != "")
1223                                 strunzone(grecordholder[pos-1]);
1224                         grecordholder[pos-1] = strzone(ReadString());
1225                         grecordtime[pos-1] = ReadInt24_t();
1226                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1227                                 race_myrank = pos;
1228                         break;
1229                 case RACE_NET_SERVER_STATUS:
1230                         race_status = ReadShort();
1231                         if(race_status_name)
1232                                 strunzone(race_status_name);
1233                         race_status_name = strzone(ReadString());
1234         }
1235 }
1236
1237 void Net_TeamNagger()
1238 {
1239         teamnagger = 1;
1240 }
1241
1242 void Net_ReadPingPLReport()
1243 {
1244         int e, pi, pl, ml;
1245         e = ReadByte();
1246         pi = ReadShort();
1247         pl = ReadByte();
1248         ml = ReadByte();
1249         if (!(playerslots[e]))
1250                 return;
1251         playerslots[e].ping = pi;
1252         playerslots[e].ping_packetloss = pl / 255.0;
1253         playerslots[e].ping_movementloss = ml / 255.0;
1254 }
1255
1256 void Net_WeaponComplain()
1257 {
1258         complain_weapon = ReadByte();
1259
1260         if(complain_weapon_name)
1261                 strunzone(complain_weapon_name);
1262         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1263
1264         complain_weapon_type = ReadByte();
1265
1266         complain_weapon_time = time;
1267         weapontime = time; // ping the weapon panel
1268
1269         switch(complain_weapon_type)
1270         {
1271                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1272                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1273                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1274         }
1275 }
1276
1277 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1278 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1279 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1280 float CSQC_Parse_TempEntity()
1281 {
1282         // Acquire TE ID
1283         int nTEID = ReadByte();
1284
1285         if (autocvar_developer_csqcentities)
1286                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1287
1288         switch (nTEID)
1289         {
1290                 case TE_CSQC_MUTATOR:
1291                         int mutID = ReadMutator();
1292                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1293                         return true;
1294                 case TE_CSQC_TARGET_MUSIC:
1295                         Net_TargetMusic();
1296                         return true;
1297                 case TE_CSQC_PICTURE:
1298                         Net_MapVote_Picture();
1299                         return true;
1300                 case TE_CSQC_RACE:
1301                         Net_ReadRace();
1302                         return true;
1303                 case TE_CSQC_VORTEXBEAMPARTICLE:
1304                         Net_ReadVortexBeamParticle();
1305                         return true;
1306                 case TE_CSQC_TEAMNAGGER:
1307                         Net_TeamNagger();
1308                         return true;
1309                 case TE_CSQC_ARC:
1310                         Net_ReadArc();
1311                         return true;
1312                 case TE_CSQC_PINGPLREPORT:
1313                         Net_ReadPingPLReport();
1314                         return true;
1315                 case TE_CSQC_WEAPONCOMPLAIN:
1316                         Net_WeaponComplain();
1317                         return true;
1318                 case TE_CSQC_VEHICLESETUP:
1319                         Net_VehicleSetup();
1320                         return true;
1321                 case TE_CSQC_SVNOTICE:
1322                         cl_notice_read();
1323                         return true;
1324                 case TE_CSQC_SHOCKWAVEPARTICLE:
1325                         Net_ReadShockwaveParticle();
1326                         return true;
1327                 default:
1328                         // No special logic for this temporary entity; return 0 so the engine can handle it
1329                         return false;
1330         }
1331 }
1332
1333 string getcommandkey(string text, string command)
1334 {
1335         string keys;
1336         float n, j, k, l = 0;
1337
1338         if (!autocvar_hud_showbinds)
1339                 return text;
1340
1341         keys = db_get(binddb, command);
1342         if (keys == "")
1343         {
1344                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1345                 for(j = 0; j < n; ++j)
1346                 {
1347                         k = stof(argv(j));
1348                         if(k != -1)
1349                         {
1350                                 if ("" == keys)
1351                                         keys = keynumtostring(k);
1352                                 else
1353                                         keys = strcat(keys, ", ", keynumtostring(k));
1354
1355                                 ++l;
1356                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1357                                         break;
1358                         }
1359
1360                 }
1361                 if (keys == "")
1362                         keys = "NO_KEY";
1363                 db_put(binddb, command, keys);
1364         }
1365
1366         if (keys == "NO_KEY") {
1367                 if (autocvar_hud_showbinds > 1)
1368                         return sprintf(_("%s (not bound)"), text);
1369                 else
1370                         return text;
1371         }
1372         else if (autocvar_hud_showbinds > 1)
1373                 return sprintf("%s (%s)", text, keys);
1374         else
1375                 return keys;
1376 }