qcsrc/client/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "autocvars.qh"
   4 #include "defs.qh"
   5 #include "hud/_mod.qh"
   6
   7 #include <common/command/_mod.qh>
   8
   9 #include <common/teams.qh>
  10
  11 #include <lib/csqcmodel/cl_model.qh>
  12
  13
  14 void AuditLists()
  15 {
  16         entity e;
  17         entity prev;
  18
  19         prev = players;
  20         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
  21         {
  22                 if(prev != e.sort_prev)
  23                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
  24         }
  25
  26         prev = teams;
  27         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
  28         {
  29                 if(prev != e.sort_prev)
  30                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
  31         }
  32 }
  33
  34
  35 float RegisterPlayer(entity player)
  36 {
  37         entity pl;
  38         AuditLists();
  39         for(pl = players.sort_next; pl; pl = pl.sort_next)
  40                 if(pl == player)
  41                         error("Player already registered!");
  42         player.sort_next = players.sort_next;
  43         player.sort_prev = players;
  44         if(players.sort_next)
  45                 players.sort_next.sort_prev = player;
  46         players.sort_next = player;
  47         AuditLists();
  48         return true;
  49 }
  50
  51 void RemovePlayer(entity player)
  52 {
  53         entity pl, parent;
  54         AuditLists();
  55         parent = players;
  56         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
  57                 parent = pl;
  58
  59         if(!pl)
  60         {
  61                 error("Trying to remove a player which is not in the playerlist!");
  62                 return;
  63         }
  64         parent.sort_next = player.sort_next;
  65         if(player.sort_next)
  66                 player.sort_next.sort_prev = parent;
  67         AuditLists();
  68 }
  69
  70 void MoveToLast(entity e)
  71 {
  72         AuditLists();
  73         entity ent = e.sort_next;
  74         while(ent)
  75         {
  76                 SORT_SWAP(ent, e);
  77                 ent = e.sort_next;
  78         }
  79         AuditLists();
  80 }
  81
  82 float RegisterTeam(entity Team)
  83 {
  84         assert_once(Team.team, eprint(Team));
  85         entity tm;
  86         AuditLists();
  87         for(tm = teams.sort_next; tm; tm = tm.sort_next)
  88                 if(tm == Team)
  89                         error("Team already registered!");
  90         Team.sort_next = teams.sort_next;
  91         Team.sort_prev = teams;
  92         if(teams.sort_next)
  93                 teams.sort_next.sort_prev = Team;
  94         teams.sort_next = Team;
  95         if(Team.team && Team.team != NUM_SPECTATOR)
  96                 ++team_count;
  97         AuditLists();
  98         return true;
  99 }
 100
 101 void RemoveTeam(entity Team)
 102 {
 103         entity tm, parent;
 104         AuditLists();
 105         parent = teams;
 106         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 107                 parent = tm;
 108
 109         if(!tm)
 110         {
 111                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 112                 return;
 113         }
 114         parent.sort_next = Team.sort_next;
 115         if(Team.sort_next)
 116                 Team.sort_next.sort_prev = parent;
 117         if(Team.team && Team.team != NUM_SPECTATOR)
 118                 --team_count;
 119         AuditLists();
 120 }
 121
 122 entity GetTeam(int Team, bool add)
 123 {
 124     TC(int, Team); TC(bool, add);
 125         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 126         if(teamslots[num])
 127                 return teamslots[num];
 128         if (!add)
 129                 return NULL;
 130         entity tm = new_pure(team);
 131         tm.team = Team;
 132         teamslots[num] = tm;
 133         RegisterTeam(tm);
 134         return tm;
 135 }
 136
 137 vector HUD_GetFontsize(string cvarname)
 138 {
 139         vector v;
 140         v = stov(cvar_string(cvarname));
 141         if(v.x == 0)
 142                 v = '8 8 0';
 143         if(v.y == 0)
 144                 v.y = v.x;
 145         v.z = 0;
 146         return v;
 147 }
 148
 149 float PreviewExists(string name)
 150 {
 151         if(autocvar_cl_readpicture_force)
 152                 return false;
 153
 154         if (fexists(strcat(name, ".tga"))) return true;
 155         if (fexists(strcat(name, ".png"))) return true;
 156         if (fexists(strcat(name, ".jpg"))) return true;
 157         if (fexists(strcat(name, ".pcx"))) return true;
 158
 159         return false;
 160 }
 161
 162 // decolorizes and team colors the player name when needed
 163 string playername(string thename, float teamid)
 164 {
 165     TC(int, teamid);
 166     string t;
 167     if (teamplay)
 168     {
 169         t = Team_ColorCode(teamid);
 170         return strcat(t, strdecolorize(thename));
 171     }
 172     else
 173         return strdecolorize(thename);
 174 }
 175
 176 float cvar_or(string cv, float v)
 177 {
 178         string s;
 179         s = cvar_string(cv);
 180         if(s == "")
 181                 return v;
 182         else
 183                 return stof(s);
 184 }
 185
 186 vector project_3d_to_2d(vector vec)
 187 {
 188         vec = cs_project(vec);
 189         if(cs_project_is_b0rked > 0)
 190         {
 191                 vec.x *= vid_conwidth / vid_width;
 192                 vec.y *= vid_conheight / vid_height;
 193         }
 194         return vec;
 195 }
 196
 197 bool projected_on_screen(vector screen_pos)
 198 {
 199         return screen_pos.z >= 0
 200                 && screen_pos.x >= 0
 201                 && screen_pos.y >= 0
 202                 && screen_pos.x < vid_conwidth
 203                 && screen_pos.y < vid_conheight;
 204 }
 205
 206 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
 207 {
 208         return 1.2 / (1.2 - fadelerp);
 209 }
 210
 211 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
 212 {
 213         boxsize.x *= boxxsizefactor; // easier interface for text
 214         return boxsize * (0.5 * (1 - sz));
 215 }
 216
 217 void drawborderlines(float thickness, vector pos, vector dim, vector color, float theAlpha, float drawflag)
 218 {
 219         vector line_dim = '0 0 0';
 220
 221         // left and right lines
 222         pos.x -= thickness;
 223         line_dim.x = thickness;
 224         line_dim.y = dim.y;
 225         drawfill(pos, line_dim, color, theAlpha, drawflag);
 226         drawfill(pos + (dim.x + thickness) * '1 0 0', line_dim, color, theAlpha, drawflag);
 227
 228         // upper and lower lines
 229         pos.y -= thickness;
 230         line_dim.x = dim.x + thickness * 2; // make upper and lower lines longer
 231         line_dim.y = thickness;
 232         drawfill(pos, line_dim, color, theAlpha, drawflag);
 233         drawfill(pos + (dim.y + thickness) * '0 1 0', line_dim, color, theAlpha, drawflag);
 234 }
 235
 236 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float theAlpha, float drawflag)
 237 {
 238         pos = HUD_Shift(pos);
 239         sz = HUD_Scale(sz);
 240         area = HUD_Scale(area);
 241
 242         vector current_pos = '0 0 0', end_pos, new_size = '0 0 0', ratio = '0 0 0';
 243         end_pos = pos + area;
 244
 245         current_pos.y = pos.y;
 246         while (current_pos.y < end_pos.y)
 247         {
 248                 current_pos.x = pos.x;
 249                 while (current_pos.x < end_pos.x)
 250                 {
 251                         new_size.x = min(sz.x, end_pos.x - current_pos.x);
 252                         new_size.y = min(sz.y, end_pos.y - current_pos.y);
 253                         ratio.x = new_size.x / sz.x;
 254                         ratio.y = new_size.y / sz.y;
 255                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, theAlpha, drawflag);
 256                         current_pos.x += sz.x;
 257                 }
 258                 current_pos.y += sz.y;
 259         }
 260 }
 261
 262 void drawpic_aspect_skin_expanding(vector position, string pic, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 263 {
 264         float sz;
 265         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 266
 267         drawpic_aspect_skin(position + expandingbox_resize_centered_box_offset(sz, theScale, 1), pic, theScale * sz, rgb, theAlpha * (1 - fadelerp), flag);
 268 }
 269
 270 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 271 {
 272         drawpic_aspect_skin_expanding(position, pic, theScale, rgb, theAlpha, flag, fadelerp);
 273         drawpic_skin(position, pic, theScale, rgb, theAlpha * fadelerp, flag);
 274 }
 275
 276 void HUD_Scale_Disable()
 277 {
 278         hud_scale = '1 1 0';
 279         hud_shift = '0 0 0';
 280         drawfontscale = hud_scale;
 281 }
 282
 283 void HUD_Scale_Enable()
 284 {
 285         hud_scale = hud_scale_current;
 286         hud_shift = hud_shift_current;
 287         drawfontscale = hud_scale;
 288 }
 289
 290 vector HUD_Scale(vector v)
 291 {
 292         v.x = HUD_ScaleX(v.x);
 293         v.y = HUD_ScaleY(v.y);
 294         return v;
 295 }
 296
 297 vector HUD_Shift(vector v)
 298 {
 299         v.x = HUD_ShiftX(v.x);
 300         v.y = HUD_ShiftY(v.y);
 301         return v;
 302 }
 303
 304 float stringwidth(string text, float handleColors, vector sz)
 305 {
 306         vector dfs = drawfontscale;
 307         drawfontscale = '1 1 0';
 308         float r = stringwidth_builtin(text, handleColors, sz);
 309         drawfontscale = dfs;
 310         return r;
 311 }
 312
 313 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 314 void drawstring_aspect(vector pos, string text, vector sz, vector color, float theAlpha, float drawflag) {
 315         SET_POS_AND_SZ_Y_ASPECT(false);
 316         drawstring(pos, text, '1 1 0' * sz.y, color, theAlpha, drawflag);
 317 }
 318
 319 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
 320 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float theAlpha, float drawflag) {
 321         SET_POS_AND_SZ_Y_ASPECT(true);
 322         drawcolorcodedstring(pos, text, '1 1 0' * sz.y, theAlpha, drawflag);
 323 }
 324
 325 void drawstring_expanding(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 326 {
 327         float sz;
 328         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 329
 330         drawfontscale = hud_scale * sz;
 331         vector dfs = drawfontscale;
 332         drawfontscale = sz * '1 1 0';
 333         float textaspect = stringwidth_builtin(text, false, theScale * (sz / drawfontscale.x)) / (theScale.x * sz);
 334         drawfontscale = dfs;
 335         drawstring(position + expandingbox_resize_centered_box_offset(sz, theScale, textaspect), text, HUD_Scale(theScale * (sz / drawfontscale.x)), rgb, theAlpha * (1 - fadelerp), flag);
 336         // width parameter:
 337         //    (scale_x * sz / drawfontscale.x) * drawfontscale.x * SIZE1 / (scale_x * sz)
 338         //    SIZE1
 339         drawfontscale = hud_scale;
 340 }
 341
 342 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 343 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float theAlpha, float drawflag, float fadelerp) {
 344         SET_POS_AND_SZ_Y_ASPECT(false);
 345         drawstring_expanding(pos, text, '1 1 0' * sz.y, color, theAlpha, drawflag, fadelerp);
 346 }
 347
 348 void drawcolorcodedstring_expanding(vector position, string text, vector theScale, float theAlpha, float flag, float fadelerp)
 349 {
 350         float sz;
 351         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 352
 353         drawfontscale = hud_scale * sz;
 354         // eventually replace with drawcolorcodedstring
 355         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, theScale, stringwidth_builtin(text, true, theScale * (sz / drawfontscale.x)) / (theScale.x * sz)), text, theScale * (sz / drawfontscale.x), theAlpha * (1 - fadelerp), flag);
 356         drawfontscale = hud_scale;
 357 }
 358
 359 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float theAlpha, float drawflag, float fadelerp) {
 360         SET_POS_AND_SZ_Y_ASPECT(true);
 361         drawcolorcodedstring_expanding(pos, text, '1 1 0' * sz.y, theAlpha, drawflag, fadelerp);
 362 }
 363
 364 void update_mousepos()
 365 {
 366         mousepos += getmousepos() * autocvar_menu_mouse_speed;
 367         mousepos.x = bound(0, mousepos.x, vid_conwidth);
 368         mousepos.y = bound(0, mousepos.y, vid_conheight);
 369 }
 370
 371 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
 372 float PolyDrawModelSurface(entity e, float i_s)
 373 {
 374         float i_t;
 375         float n_t;
 376         vector tri;
 377         string tex;
 378         tex = getsurfacetexture(e, i_s);
 379         if (!tex)
 380                 return 0; // this is beyond the last one
 381         n_t = getsurfacenumtriangles(e, i_s);
 382         for(i_t = 0; i_t < n_t; ++i_t)
 383         {
 384                 tri = getsurfacetriangle(e, i_s, i_t);
 385                 R_BeginPolygon(tex, 0);
 386                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.x), getsurfacepointattribute(e, i_s, tri.x, SPA_TEXCOORDS0), '1 1 1', 1);
 387                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.y), getsurfacepointattribute(e, i_s, tri.y, SPA_TEXCOORDS0), '1 1 1', 1);
 388                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.z), getsurfacepointattribute(e, i_s, tri.z, SPA_TEXCOORDS0), '1 1 1', 1);
 389                 R_EndPolygon();
 390         }
 391         return 1;
 392 }
 393 void PolyDrawModel(entity e)
 394 {
 395         float i_s;
 396         for(i_s = 0; ; ++i_s)
 397                 if(!PolyDrawModelSurface(e, i_s))
 398                         break;
 399 }
 400
 401 void DrawCircleClippedPic(vector centre, float radi, string pic, float f, vector rgb, float a, float drawflag)
 402 {
 403         float d;
 404         vector ringsize, v, t;
 405         ringsize = radi * '1 1 0';
 406         centre = HUD_Shift(centre);
 407         ringsize = HUD_Scale(ringsize);
 408
 409         float co = cos(f * 2 * M_PI);
 410         float si = sin(f * 2 * M_PI);
 411         float q = fabs(co) + fabs(si);
 412         co /= q;
 413         si /= q;
 414
 415         if(f >= 1)
 416         {
 417                 // draw full rectangle
 418                 R_BeginPolygon(pic, drawflag);
 419                         v = centre;                     t = '0.5 0.5 0';
 420                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 421                         R_PolygonVertex(v, t, rgb, a);
 422
 423                         v = centre;                     t = '0.5 0.5 0';
 424                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 425                         R_PolygonVertex(v, t, rgb, a);
 426
 427                         v = centre;                     t = '0.5 0.5 0';
 428                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 429                         R_PolygonVertex(v, t, rgb, a);
 430
 431                         v = centre;                     t = '0.5 0.5 0';
 432                         v.y -= 0.5 * ringsize.y;        t -= '0.5 -0.5 0';
 433                         R_PolygonVertex(v, t, rgb, a);
 434                 R_EndPolygon();
 435
 436                 d = q - 1;
 437                 if(d > 0)
 438                 {
 439                         R_BeginPolygon(pic, drawflag);
 440                                 v = centre;                     t = '0.5 0.5 0';
 441                                 R_PolygonVertex(v, t, rgb, a);
 442
 443                                 v = centre;                     t = '0.5 0.5 0';
 444                                 v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 445                                 R_PolygonVertex(v, t, rgb, a);
 446                 }
 447         }
 448         else if(f > 0.75)
 449         {
 450                 // draw upper and first triangle
 451                 R_BeginPolygon(pic, drawflag);
 452                         v = centre;                     t = '0.5 0.5 0';
 453                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 454                         R_PolygonVertex(v, t, rgb, a);
 455
 456                         v = centre;                     t = '0.5 0.5 0';
 457                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 458                         R_PolygonVertex(v, t, rgb, a);
 459
 460                         v = centre;                     t = '0.5 0.5 0';
 461                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 462                         R_PolygonVertex(v, t, rgb, a);
 463                 R_EndPolygon();
 464                 R_BeginPolygon(pic, drawflag);
 465                         v = centre;                     t = '0.5 0.5 0';
 466                         R_PolygonVertex(v, t, rgb, a);
 467
 468                         v = centre;                     t = '0.5 0.5 0';
 469                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 470                         R_PolygonVertex(v, t, rgb, a);
 471
 472                         v = centre;                     t = '0.5 0.5 0';
 473                         v.y -= 0.5 * ringsize.y;        t -= '0.5 -0.5 0';
 474                         R_PolygonVertex(v, t, rgb, a);
 475
 476                 d = q - 0.75;
 477                 if(d <= 0)
 478                         R_EndPolygon();
 479         }
 480         else if(f > 0.5)
 481         {
 482                 // draw upper triangle
 483                 R_BeginPolygon(pic, drawflag);
 484                         v = centre;                     t = '0.5 0.5 0';
 485                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 486                         R_PolygonVertex(v, t, rgb, a);
 487
 488                         v = centre;                     t = '0.5 0.5 0';
 489                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 490                         R_PolygonVertex(v, t, rgb, a);
 491
 492                         v = centre;                     t = '0.5 0.5 0';
 493                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 494                         R_PolygonVertex(v, t, rgb, a);
 495                 R_EndPolygon();
 496
 497                 d = q - 0.5;
 498                 if(d > 0)
 499                 {
 500                         R_BeginPolygon(pic, drawflag);
 501                                 v = centre;                     t = '0.5 0.5 0';
 502                                 R_PolygonVertex(v, t, rgb, a);
 503
 504                                 v = centre;                     t = '0.5 0.5 0';
 505                                 v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 506                                 R_PolygonVertex(v, t, rgb, a);
 507                 }
 508         }
 509         else if(f > 0.25)
 510         {
 511                 // draw first triangle
 512                 R_BeginPolygon(pic, drawflag);
 513                         v = centre;                     t = '0.5 0.5 0';
 514                         R_PolygonVertex(v, t, rgb, a);
 515
 516                         v = centre;                     t = '0.5 0.5 0';
 517                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 518                         R_PolygonVertex(v, t, rgb, a);
 519
 520                         v = centre;                     t = '0.5 0.5 0';
 521                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 522                         R_PolygonVertex(v, t, rgb, a);
 523
 524                 d = q - 0.25;
 525                 if(d <= 0)
 526                         R_EndPolygon();
 527         }
 528         else
 529         {
 530                 d = q;
 531                 if(d > 0)
 532                 {
 533                         R_BeginPolygon(pic, drawflag);
 534                                 v = centre;                     t = '0.5 0.5 0';
 535                                 R_PolygonVertex(v, t, rgb, a);
 536
 537                                 v = centre;                     t = '0.5 0.5 0';
 538                                 v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 539                                 R_PolygonVertex(v, t, rgb, a);
 540                 }
 541         }
 542
 543         if(d > 0)
 544         {
 545                         v = centre;                     t = '0.5 0.5 0';
 546                         v.x += co * 0.5 * ringsize.x;   t += co * '0.5 0.5 0';
 547                         v.y += si * 0.5 * ringsize.y;   t += si * '0.5 -0.5 0';
 548                         R_PolygonVertex(v, t, rgb, a);
 549                 R_EndPolygon();
 550         }
 551 }
 552
 553 /** engine callback */
 554 void URI_Get_Callback(int id, int status, string data)
 555 {
 556     TC(int, id); TC(int, status);
 557         if(url_URI_Get_Callback(id, status, data))
 558         {
 559                 // handled
 560         }
 561         else if (id == URI_GET_DISCARD)
 562         {
 563                 // discard
 564         }
 565         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 566         {
 567                 // sv_cmd curl
 568                 Curl_URI_Get_Callback(id, status, data);
 569         }
 570         else
 571         {
 572                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
 573         }
 574 }
 575
 576 void Accuracy_LoadLevels()
 577 {
 578         if(autocvar_accuracy_color_levels != acc_color_levels)
 579         {
 580                 strcpy(acc_color_levels, autocvar_accuracy_color_levels);
 581                 acc_levels = tokenize_console(acc_color_levels);
 582                 if(acc_levels > MAX_ACCURACY_LEVELS)
 583                         acc_levels = MAX_ACCURACY_LEVELS;
 584                 if(acc_levels < 2)
 585                         LOG_INFO("Warning: accuracy_color_levels must contain at least 2 values");
 586
 587                 int i;
 588                 for(i = 0; i < acc_levels; ++i)
 589                         acc_lev[i] = stof(argv(i)) / 100.0;
 590         }
 591 }
 592
 593 void Accuracy_LoadColors()
 594 {
 595         if(time > acc_col_loadtime)
 596         if(acc_levels >= 2)
 597         {
 598                 int i;
 599                 for(i = 0; i < acc_levels; ++i)
 600                         acc_col[i] = stov(cvar_string(strcat("accuracy_color", ftos(i))));
 601                 acc_col_loadtime = time + 2;
 602         }
 603 }
 604
 605 vector Accuracy_GetColor(float accuracy)
 606 {
 607         float factor;
 608         vector color;
 609         if(acc_levels < 2)
 610                 return '0 0 0'; // return black, can't determine the right color
 611
 612         // find the max level lower than acc
 613         int j = acc_levels-1;
 614         while(j && accuracy < acc_lev[j])
 615                 --j;
 616
 617         // inject color j+1 in color j, how much depending on how much accuracy is higher than level j
 618         factor = (accuracy - acc_lev[j]) / (acc_lev[j+1] - acc_lev[j]);
 619         color = acc_col[j];
 620         color = color + factor * (acc_col[j+1] - color);
 621         return color;
 622 }