qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud.qh"
   5 #include "hud_config.qh"
   6 #include "mapvoting.qh"
   7 #include "scoreboard.qh"
   8 #include "shownames.qh"
   9 #include "quickmenu.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/anim.qh"
  14 #include "../common/constants.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/nades/all.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 void viewmodel_draw(entity this)
  34 {
  35         int mask = (intermission || (getstati(STAT_HEALTH) <= 0)) ? 0 : MASK_NORMAL;
  36         int c = stof(getplayerkeyvalue(current_player, "colors"));
  37         vector g = colormapPaletteColor(c & 0x0F, true) * 2;
  38         for (entity e = this; e; e = e.weaponchild)
  39         {
  40                 e.drawmask = mask;
  41                 e.colormap = c;
  42                 e.glowmod = g;
  43         }
  44 }
  45
  46 entity viewmodel;
  47 STATIC_INIT(viewmodel) {
  48     viewmodel = new(viewmodel);
  49         viewmodel.draw = viewmodel_draw;
  50 }
  51
  52 entity porto;
  53 vector polyline[16];
  54 void Porto_Draw(entity this)
  55 {
  56         vector p, dir, ang, q, nextdir;
  57         float portal_number, portal1_idx;
  58
  59         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  60                 return;
  61         if(g_balance_porto_secondary)
  62                 return;
  63         if(intermission == 1)
  64                 return;
  65         if(intermission == 2)
  66                 return;
  67         if (getstati(STAT_HEALTH) <= 0)
  68                 return;
  69
  70         dir = view_forward;
  71
  72         if(angles_held_status)
  73         {
  74                 makevectors(angles_held);
  75                 dir = v_forward;
  76         }
  77
  78         p = view_origin;
  79
  80         polyline[0] = p;
  81         int idx = 1;
  82         portal_number = 0;
  83         nextdir = dir;
  84
  85         for (;;)
  86         {
  87                 dir = nextdir;
  88                 traceline(p, p + 65536 * dir, true, porto);
  89                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  90                         return;
  91                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  92                 p = trace_endpos;
  93                 polyline[idx] = p;
  94                 ++idx;
  95                 if(idx >= 16)
  96                         return;
  97                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  98                         continue;
  99                 ++portal_number;
 100                 ang = vectoangles2(trace_plane_normal, dir);
 101                 ang.x = -ang.x;
 102                 makevectors(ang);
 103                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 104                         return;
 105                 if(portal_number == 1)
 106                 {
 107                         portal1_idx = idx;
 108                         if(portal_number >= 2)
 109                                 break;
 110                 }
 111         }
 112
 113         while(idx >= 2)
 114         {
 115                 p = polyline[idx-2];
 116                 q = polyline[idx-1];
 117                 if(idx == 2)
 118                         p = p - view_up * 16;
 119                 if(idx-1 >= portal1_idx)
 120                 {
 121                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 122                 }
 123                 else
 124                 {
 125                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 126                 }
 127                 --idx;
 128         }
 129 }
 130
 131 void Porto_Init()
 132 {
 133         porto = spawn();
 134         porto.classname = "porto";
 135         porto.draw = Porto_Draw;
 136         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 137 }
 138
 139 float drawtime;
 140 float avgspeed;
 141 vector GetCurrentFov(float fov)
 142 {
 143         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 144         float velocityzoom, curspeed;
 145         vector v;
 146
 147         zoomsensitivity = autocvar_cl_zoomsensitivity;
 148         zoomfactor = autocvar_cl_zoomfactor;
 149         if(zoomfactor < 1 || zoomfactor > 30)
 150                 zoomfactor = 2.5;
 151         zoomspeed = autocvar_cl_zoomspeed;
 152         if(zoomspeed >= 0)
 153         if(zoomspeed < 0.5 || zoomspeed > 16)
 154                         zoomspeed = 3.5;
 155
 156         zoomdir = button_zoom;
 157         if(hud == HUD_NORMAL)
 158         if(switchweapon == activeweapon)
 159         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 160                 zoomdir += button_attack2;
 161         if(spectatee_status > 0 || isdemo())
 162         {
 163                 if(spectatorbutton_zoom)
 164                 {
 165                         if(zoomdir)
 166                                 zoomdir = 0;
 167                         else
 168                                 zoomdir = 1;
 169                 }
 170                 // fteqcc failed twice here already, don't optimize this
 171         }
 172
 173         if(zoomdir) { zoomin_effect = 0; }
 174
 175         if(camera_active)
 176         {
 177                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 178         }
 179         else if(autocvar_cl_spawnzoom && zoomin_effect)
 180         {
 181                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 182
 183                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 184                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 185                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 186         }
 187         else
 188         {
 189                 if(zoomspeed < 0) // instant zoom
 190                 {
 191                         if(zoomdir)
 192                                 current_viewzoom = 1 / zoomfactor;
 193                         else
 194                                 current_viewzoom = 1;
 195                 }
 196                 else
 197                 {
 198                         if(zoomdir)
 199                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 200                         else
 201                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 202                 }
 203         }
 204
 205         if(almost_equals(current_viewzoom, 1))
 206                 current_zoomfraction = 0;
 207         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 208                 current_zoomfraction = 1;
 209         else
 210                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 211
 212         if(zoomsensitivity < 1)
 213                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 214         else
 215                 setsensitivityscale(1);
 216
 217         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 218         {
 219                 if(intermission) { curspeed = 0; }
 220                 else
 221                 {
 222
 223                         makevectors(view_angles);
 224                         v = pmove_vel;
 225                         if(csqcplayer)
 226                                 v = csqcplayer.velocity;
 227
 228                         switch(autocvar_cl_velocityzoom_type)
 229                         {
 230                                 case 3: curspeed = max(0, v_forward * v); break;
 231                                 case 2: curspeed = (v_forward * v); break;
 232                                 case 1: default: curspeed = vlen(v); break;
 233                         }
 234                 }
 235
 236                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 237                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 238                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 239
 240                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 241         }
 242         else
 243                 velocityzoom = 1;
 244
 245         float frustumx, frustumy, fovx, fovy;
 246         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 247         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 248         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 249         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 250
 251         return '1 0 0' * fovx + '0 1 0' * fovy;
 252 }
 253
 254 vector GetViewLocationFOV(float fov)
 255 {
 256         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 257         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 258         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 259         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 260         return '1 0 0' * fovx + '0 1 0' * fovy;
 261 }
 262
 263 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 264 {
 265         float fovx, fovy;
 266         float width = (ov_worldmax.x - ov_worldmin.x);
 267         float height = (ov_worldmax.y - ov_worldmin.y);
 268         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 269         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 270         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 271         return '1 0 0' * fovx + '0 1 0' * fovy;
 272 }
 273
 274 // this function must match W_SetupShot!
 275 float zoomscript_caught;
 276
 277 vector wcross_origin;
 278 float wcross_scale_prev, wcross_alpha_prev;
 279 vector wcross_color_prev;
 280 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 281 vector wcross_color_goal_prev;
 282 float wcross_changedonetime;
 283
 284 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 285 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 286 float wcross_name_changestarttime, wcross_name_changedonetime;
 287 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 288
 289 float wcross_ring_prev;
 290
 291 entity trueaim;
 292 entity trueaim_rifle;
 293
 294 const float SHOTTYPE_HITTEAM = 1;
 295 const float SHOTTYPE_HITOBSTRUCTION = 2;
 296 const float SHOTTYPE_HITWORLD = 3;
 297 const float SHOTTYPE_HITENEMY = 4;
 298
 299 void TrueAim_Init()
 300 {
 301         trueaim = spawn();
 302         trueaim.classname = "trueaim";
 303         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 304         trueaim_rifle = spawn();
 305         trueaim_rifle.classname = "trueaim_rifle";
 306         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 307 }
 308
 309 float EnemyHitCheck()
 310 {
 311         float t, n;
 312         wcross_origin = project_3d_to_2d(trace_endpos);
 313         wcross_origin.z = 0;
 314         if(trace_ent)
 315                 n = trace_ent.entnum;
 316         else
 317                 n = trace_networkentity;
 318         if(n < 1)
 319                 return SHOTTYPE_HITWORLD;
 320         if(n > maxclients)
 321                 return SHOTTYPE_HITWORLD;
 322         t = GetPlayerColor(n - 1);
 323         if(teamplay)
 324                 if(t == myteam)
 325                         return SHOTTYPE_HITTEAM;
 326         if(t == NUM_SPECTATOR)
 327                 return SHOTTYPE_HITWORLD;
 328         return SHOTTYPE_HITENEMY;
 329 }
 330
 331 float TrueAimCheck()
 332 {
 333         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 334         vector vecs, trueaimpoint, w_shotorg;
 335         vector mi, ma, dv;
 336         float shottype;
 337         entity ta;
 338         float mv;
 339
 340         mi = ma = '0 0 0';
 341         ta = trueaim;
 342         mv = MOVE_NOMONSTERS;
 343
 344         switch(activeweapon) // WEAPONTODO
 345         {
 346                 case WEP_TUBA.m_id: // no aim
 347                 case WEP_PORTO.m_id: // shoots from eye
 348                 case WEP_NEXBALL.m_id: // shoots from eye
 349                 case WEP_HOOK.m_id: // no trueaim
 350                 case WEP_MORTAR.m_id: // toss curve
 351                         return SHOTTYPE_HITWORLD;
 352                 case WEP_VORTEX.m_id:
 353                 case WEP_VAPORIZER.m_id:
 354                         mv = MOVE_NORMAL;
 355                         break;
 356                 case WEP_RIFLE.m_id:
 357                         ta = trueaim_rifle;
 358                         mv = MOVE_NORMAL;
 359                         if(zoomscript_caught)
 360                         {
 361                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 362                                 return EnemyHitCheck();
 363                         }
 364                         break;
 365                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 366                         mi = '-3 -3 -3';
 367                         ma = '3 3 3';
 368                         break;
 369                 case WEP_FIREBALL.m_id: // projectile has a size!
 370                         mi = '-16 -16 -16';
 371                         ma = '16 16 16';
 372                         break;
 373                 case WEP_SEEKER.m_id: // projectile has a size!
 374                         mi = '-2 -2 -2';
 375                         ma = '2 2 2';
 376                         break;
 377                 case WEP_ELECTRO.m_id: // projectile has a size!
 378                         mi = '0 0 -3';
 379                         ma = '0 0 -3';
 380                         break;
 381         }
 382
 383         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 384
 385         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 386
 387         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 388         trueaimpoint = trace_endpos;
 389
 390         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 391                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 392
 393         if(vecs.x > 0)
 394                 vecs.y = -vecs.y;
 395         else
 396                 vecs = '0 0 0';
 397
 398         dv = view_right * vecs.y + view_up * vecs.z;
 399         w_shotorg = traceorigin + dv;
 400
 401         // now move the vecs forward as much as requested if possible
 402         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 403         w_shotorg = trace_endpos - view_forward * nudge;
 404
 405         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 406         shottype = EnemyHitCheck();
 407         if(shottype != SHOTTYPE_HITWORLD)
 408                 return shottype;
 409
 410 #if 0
 411         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 412         // or rather, I know why, but see no fix
 413         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 414                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 415                 return SHOTTYPE_HITOBSTRUCTION;
 416 #endif
 417
 418         return SHOTTYPE_HITWORLD;
 419 }
 420
 421 void PostInit(void);
 422 void CSQC_Demo_Camera();
 423 float HUD_WouldDrawScoreboard();
 424 float camera_mode;
 425 const float CAMERA_FREE = 1;
 426 const float CAMERA_CHASE = 2;
 427 float reticle_type;
 428 string reticle_image;
 429 string NextFrameCommand;
 430
 431 vector freeze_org, freeze_ang;
 432 entity nightvision_noise, nightvision_noise2;
 433
 434 const float MAX_TIME_DIFF = 5;
 435 float pickup_crosshair_time, pickup_crosshair_size;
 436 float hitindication_crosshair_size;
 437 float use_vortex_chargepool;
 438
 439 float myhealth, myhealth_prev;
 440 float myhealth_flash;
 441
 442 float old_blurradius, old_bluralpha;
 443 float old_sharpen_intensity;
 444
 445 vector myhealth_gentlergb;
 446
 447 float contentavgalpha, liquidalpha_prev;
 448 vector liquidcolor_prev;
 449
 450 float eventchase_current_distance;
 451 float eventchase_running;
 452 bool WantEventchase()
 453 {SELFPARAM();
 454         if(autocvar_cl_orthoview)
 455                 return false;
 456         if(intermission)
 457                 return true;
 458         if(self.viewloc)
 459                 return true;
 460         if(spectatee_status >= 0)
 461         {
 462                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 463                         return true;
 464                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 465                         return true;
 466                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 467                         return true;
 468                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 469                 {
 470                         if(autocvar_cl_eventchase_death == 2)
 471                         {
 472                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 473                                 if(self.velocity == '0 0 0' || eventchase_running)
 474                                         return true;
 475                         }
 476                         else return true;
 477                 }
 478         }
 479         return false;
 480 }
 481
 482 void HUD_Crosshair_Vehicle()
 483 {
 484         if(hud != HUD_BUMBLEBEE_GUN)
 485         {
 486                 Vehicle info = get_vehicleinfo(hud);
 487                 info.vr_crosshair(info);
 488         }
 489 }
 490
 491 vector damage_blurpostprocess, content_blurpostprocess;
 492
 493 float unaccounted_damage = 0;
 494 void UpdateDamage()
 495 {
 496         // accumulate damage with each stat update
 497         static float damage_total_prev = 0;
 498         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 499         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 500         damage_total_prev = damage_total;
 501
 502         static float damage_dealt_time_prev = 0;
 503         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 504         if (damage_dealt_time != damage_dealt_time_prev)
 505         {
 506                 unaccounted_damage += unaccounted_damage_new;
 507                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 508         }
 509         damage_dealt_time_prev = damage_dealt_time;
 510
 511         // prevent hitsound when switching spectatee
 512         static float spectatee_status_prev = 0;
 513         if (spectatee_status != spectatee_status_prev)
 514                 unaccounted_damage = 0;
 515         spectatee_status_prev = spectatee_status;
 516 }
 517
 518 void HitSound()
 519 {
 520         // varying sound pitch
 521
 522         static float hitsound_time_prev = 0;
 523         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 524         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 525         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 526         {
 527                 if (autocvar_cl_hitsound && unaccounted_damage)
 528                 {
 529                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 530                         float a = autocvar_cl_hitsound_max_pitch;
 531                         float b = autocvar_cl_hitsound_min_pitch;
 532                         float c = autocvar_cl_hitsound_nom_damage;
 533                         float x = unaccounted_damage;
 534                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 535
 536                         // if sound variation is disabled, set pitch_shift to 1
 537                         if (autocvar_cl_hitsound == 1)
 538                                 pitch_shift = 1;
 539
 540                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 541                         if (autocvar_cl_hitsound == 3)
 542                         {
 543                                 float mirror_value = (a-b)/2 + b;
 544                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 545                         }
 546
 547                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 548
 549                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 550                         // todo: normalize sound pressure levels? seems unnecessary
 551
 552                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 553                 }
 554                 unaccounted_damage = 0;
 555                 hitsound_time_prev = time;
 556         }
 557
 558         static float typehit_time_prev = 0;
 559         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 560         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 561         {
 562                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 563                 typehit_time_prev = typehit_time;
 564         }
 565 }
 566
 567 void HUD_Crosshair()
 568 {SELFPARAM();
 569         static float rainbow_last_flicker;
 570         static vector rainbow_prev_color;
 571         entity e = self;
 572         float f, i, j;
 573         vector v;
 574         if(!scoreboard_active && !camera_active && intermission != 2 &&
 575                 spectatee_status != -1 && !csqcplayer.viewloc &&
 576                 !HUD_MinigameMenu_IsOpened() )
 577         {
 578                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 579                         return;
 580
 581                 if (hud != HUD_NORMAL)
 582                 {
 583                         HUD_Crosshair_Vehicle();
 584                         return;
 585                 }
 586
 587                 string wcross_style;
 588                 float wcross_alpha, wcross_resolution;
 589                 wcross_style = autocvar_crosshair;
 590                 if (wcross_style == "0")
 591                         return;
 592                 wcross_resolution = autocvar_crosshair_size;
 593                 if (wcross_resolution == 0)
 594                         return;
 595                 wcross_alpha = autocvar_crosshair_alpha;
 596                 if (wcross_alpha == 0)
 597                         return;
 598
 599                 // TrueAim check
 600                 float shottype;
 601
 602                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 603                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 604                 wcross_origin.z = 0;
 605                 if(autocvar_crosshair_hittest)
 606                 {
 607                         vector wcross_oldorigin;
 608                         wcross_oldorigin = wcross_origin;
 609                         shottype = TrueAimCheck();
 610                         if(shottype == SHOTTYPE_HITWORLD)
 611                         {
 612                                 v = wcross_origin - wcross_oldorigin;
 613                                 v.x /= vid_conwidth;
 614                                 v.y /= vid_conheight;
 615                                 if(vlen(v) > 0.01)
 616                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 617                         }
 618                         if(!autocvar_crosshair_hittest_showimpact)
 619                                 wcross_origin = wcross_oldorigin;
 620                 }
 621                 else
 622                         shottype = SHOTTYPE_HITWORLD;
 623
 624                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 625                 string wcross_name = "";
 626                 float wcross_scale, wcross_blur;
 627
 628                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 629                 {
 630                         e = get_weaponinfo(switchingweapon);
 631                         if(e)
 632                         {
 633                                 if(autocvar_crosshair_per_weapon)
 634                                 {
 635                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 636                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 637                                         //if (wcross_resolution == 0)
 638                                                 //return;
 639
 640                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 641                                         wcross_resolution *= e.w_crosshair_size;
 642                                         wcross_name = e.w_crosshair;
 643                                 }
 644                         }
 645                 }
 646
 647                 if(wcross_name == "")
 648                         wcross_name = strcat("gfx/crosshair", wcross_style);
 649
 650                 // MAIN CROSSHAIR COLOR DECISION
 651                 switch(autocvar_crosshair_color_special)
 652                 {
 653                         case 1: // crosshair_color_per_weapon
 654                         {
 655                                 if(e)
 656                                 {
 657                                         wcross_color = e.wpcolor;
 658                                         break;
 659                                 }
 660                                 else { goto normalcolor; }
 661                         }
 662
 663                         case 2: // crosshair_color_by_health
 664                         {
 665                                 float x = getstati(STAT_HEALTH);
 666
 667                                 //x = red
 668                                 //y = green
 669                                 //z = blue
 670
 671                                 wcross_color.z = 0;
 672
 673                                 if(x > 200)
 674                                 {
 675                                         wcross_color.x = 0;
 676                                         wcross_color.y = 1;
 677                                 }
 678                                 else if(x > 150)
 679                                 {
 680                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 681                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 682                                 }
 683                                 else if(x > 100)
 684                                 {
 685                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 686                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 687                                         wcross_color.z = 1 - (x-100)*0.02;
 688                                 }
 689                                 else if(x > 50)
 690                                 {
 691                                         wcross_color.x = 1;
 692                                         wcross_color.y = 1;
 693                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 694                                 }
 695                                 else if(x > 20)
 696                                 {
 697                                         wcross_color.x = 1;
 698                                         wcross_color.y = (x-20)*90/27/100;
 699                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 700                                 }
 701                                 else
 702                                 {
 703                                         wcross_color.x = 1;
 704                                         wcross_color.y = 0;
 705                                 }
 706                                 break;
 707                         }
 708
 709                         case 3: // crosshair_color_rainbow
 710                         {
 711                                 if(time >= rainbow_last_flicker)
 712                                 {
 713                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 714                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 715                                 }
 716                                 wcross_color = rainbow_prev_color;
 717                                 break;
 718                         }
 719                         :normalcolor
 720                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 721                 }
 722
 723                 if(autocvar_crosshair_effect_scalefade)
 724                 {
 725                         wcross_scale = wcross_resolution;
 726                         wcross_resolution = 1;
 727                 }
 728                 else
 729                 {
 730                         wcross_scale = 1;
 731                 }
 732
 733                 if(autocvar_crosshair_pickup)
 734                 {
 735                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 736
 737                         if(pickup_crosshair_time < stat_pickup_time)
 738                         {
 739                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 740                                         pickup_crosshair_size = 1;
 741
 742                                 pickup_crosshair_time = stat_pickup_time;
 743                         }
 744
 745                         if(pickup_crosshair_size > 0)
 746                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 747                         else
 748                                 pickup_crosshair_size = 0;
 749
 750                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 751                 }
 752
 753                 // todo: make crosshair hit indication dependent on damage dealt
 754                 if(autocvar_crosshair_hitindication)
 755                 {
 756                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 757
 758                         if(unaccounted_damage)
 759                         {
 760                                 hitindication_crosshair_size = 1;
 761                         }
 762
 763                         if(hitindication_crosshair_size > 0)
 764                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 765                         else
 766                                 hitindication_crosshair_size = 0;
 767
 768                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 769                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 770                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 771                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 772                 }
 773
 774                 if(shottype == SHOTTYPE_HITENEMY)
 775                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 776                 if(shottype == SHOTTYPE_HITTEAM)
 777                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 778
 779                 f = fabs(autocvar_crosshair_effect_time);
 780                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 781                 {
 782                         wcross_changedonetime = time + f;
 783                 }
 784                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 785                 {
 786                         wcross_name_changestarttime = time;
 787                         wcross_name_changedonetime = time + f;
 788                         if(wcross_name_goal_prev_prev)
 789                                 strunzone(wcross_name_goal_prev_prev);
 790                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 791                         wcross_name_goal_prev = strzone(wcross_name);
 792                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 793                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 794                         wcross_resolution_goal_prev = wcross_resolution;
 795                 }
 796
 797                 wcross_scale_goal_prev = wcross_scale;
 798                 wcross_alpha_goal_prev = wcross_alpha;
 799                 wcross_color_goal_prev = wcross_color;
 800
 801                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 802                 {
 803                         wcross_blur = 1;
 804                         wcross_alpha *= 0.75;
 805                 }
 806                 else
 807                         wcross_blur = 0;
 808                 // *_prev is at time-frametime
 809                 // * is at wcross_changedonetime+f
 810                 // what do we have at time?
 811                 if(time < wcross_changedonetime)
 812                 {
 813                         f = frametime / (wcross_changedonetime - time + frametime);
 814                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 815                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 816                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 817                 }
 818
 819                 wcross_scale_prev = wcross_scale;
 820                 wcross_alpha_prev = wcross_alpha;
 821                 wcross_color_prev = wcross_color;
 822
 823                 MUTATOR_CALLHOOK(UpdateCrosshair);
 824
 825                 wcross_scale *= 1 - autocvar__menu_alpha;
 826                 wcross_alpha *= 1 - autocvar__menu_alpha;
 827                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 828
 829                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 830                 {
 831                         // crosshair rings for weapon stats
 832                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 833                         {
 834                                 // declarations and stats
 835                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 836                                 string ring_image = string_null, ring_inner_image = string_null;
 837                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 838
 839                                 ring_scale = autocvar_crosshair_ring_size;
 840
 841                                 float weapon_clipload, weapon_clipsize;
 842                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 843                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 844
 845                                 float ok_ammo_charge, ok_ammo_chargepool;
 846                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 847                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 848
 849                                 float vortex_charge, vortex_chargepool;
 850                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 851                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 852
 853                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 854
 855                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 856                                         vortex_charge_movingavg = vortex_charge;
 857
 858
 859                                 // handle the values
 860                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 861                                 {
 862                                         if (vortex_chargepool || use_vortex_chargepool) {
 863                                                 use_vortex_chargepool = 1;
 864                                                 ring_inner_value = vortex_chargepool;
 865                                         } else {
 866                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 867                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 868                                         }
 869
 870                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 871                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 872                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 873
 874                                         // draw the outer ring to show the current charge of the weapon
 875                                         ring_value = vortex_charge;
 876                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 877                                         ring_rgb = wcross_color;
 878                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 879                                 }
 880                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 881                                 {
 882                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 883                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 884                                         ring_rgb = wcross_color;
 885                                         ring_image = "gfx/crosshair_ring.tga";
 886                                 }
 887                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 888                                 {
 889                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 890                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 891                                         ring_rgb = wcross_color;
 892                                         ring_image = "gfx/crosshair_ring.tga";
 893                                 }
 894                                 else if (ok_ammo_charge)
 895                                 {
 896                                         ring_value = ok_ammo_chargepool;
 897                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 898                                         ring_rgb = wcross_color;
 899                                         ring_image = "gfx/crosshair_ring.tga";
 900                                 }
 901                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 902                                 {
 903                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 904                                         ring_scale = autocvar_crosshair_ring_reload_size;
 905                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 906                                         ring_rgb = wcross_color;
 907
 908                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 909                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 910                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 911                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 912                                         else
 913                                                 ring_image = "gfx/crosshair_ring.tga";
 914                                 }
 915                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 916                                 {
 917                                         ring_value = arc_heat;
 918                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 919                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 920                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 921                                         ring_image = "gfx/crosshair_ring.tga";
 922                                 }
 923
 924                                 // if in weapon switch animation, fade ring out/in
 925                                 if(autocvar_crosshair_effect_time > 0)
 926                                 {
 927                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 928                                         if (f >= 1)
 929                                         {
 930                                                 wcross_ring_prev = ((ring_image) ? true : false);
 931                                         }
 932
 933                                         if(wcross_ring_prev)
 934                                         {
 935                                                 if(f < 1)
 936                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 937                                         }
 938                                         else
 939                                         {
 940                                                 if(f < 1)
 941                                                         ring_alpha *= bound(0, f, 1);
 942                                         }
 943                                 }
 944
 945                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 946                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 947
 948                                 if (ring_value)
 949                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 950                         }
 951
 952 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 953                         do \
 954                         { \
 955                                 if(wcross_blur > 0) \
 956                                 { \
 957                                         for(i = -2; i <= 2; ++i) \
 958                                         for(j = -2; j <= 2; ++j) \
 959                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 960                                 } \
 961                                 else \
 962                                 { \
 963                                         M(0,0,sz,wcross_name,wcross_alpha); \
 964                                 } \
 965                         } \
 966                         while(0)
 967
 968 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 969                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 970
 971 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 972                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 973
 974                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 975                         {
 976                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 977                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 978                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 979                                 f = 1 - f;
 980                         }
 981                         else
 982                         {
 983                                 f = 1;
 984                         }
 985                         wcross_name_alpha_goal_prev = f;
 986
 987                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 988                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 989
 990                         if(autocvar_crosshair_dot)
 991                         {
 992                                 vector wcross_color_old;
 993                                 wcross_color_old = wcross_color;
 994
 995                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 996                                         wcross_color = stov(autocvar_crosshair_dot_color);
 997
 998                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 999                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
1000                                 wcross_color = wcross_color_old;
1001                         }
1002                 }
1003         }
1004         else
1005         {
1006                 wcross_scale_prev = 0;
1007                 wcross_alpha_prev = 0;
1008                 wcross_scale_goal_prev = 0;
1009                 wcross_alpha_goal_prev = 0;
1010                 wcross_changedonetime = 0;
1011                 if(wcross_name_goal_prev)
1012                         strunzone(wcross_name_goal_prev);
1013                 wcross_name_goal_prev = string_null;
1014                 if(wcross_name_goal_prev_prev)
1015                         strunzone(wcross_name_goal_prev_prev);
1016                 wcross_name_goal_prev_prev = string_null;
1017                 wcross_name_changestarttime = 0;
1018                 wcross_name_changedonetime = 0;
1019                 wcross_name_alpha_goal_prev = 0;
1020                 wcross_name_alpha_goal_prev_prev = 0;
1021                 wcross_resolution_goal_prev = 0;
1022                 wcross_resolution_goal_prev_prev = 0;
1023         }
1024 }
1025
1026 void HUD_Draw()
1027 {
1028         if(getstati(STAT_FROZEN))
1029                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1030         else if (getstatf(STAT_HEALING_ORB)>time)
1031                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1032         if(!intermission)
1033         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1034         {
1035                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1036                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1037         }
1038         else if(getstatf(STAT_REVIVE_PROGRESS))
1039         {
1040                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1041                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1042         }
1043
1044         if(autocvar_r_letterbox == 0)
1045                 if(autocvar_viewsize < 120)
1046                 {
1047                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1048                                 Accuracy_LoadLevels();
1049
1050                         HUD_Main();
1051                         HUD_DrawScoreboard();
1052                 }
1053
1054         // crosshair goes VERY LAST
1055         UpdateDamage();
1056         HUD_Crosshair();
1057         HitSound();
1058 }
1059
1060 bool ov_enabled;
1061 float oldr_nearclip;
1062 float oldr_farclip_base;
1063 float oldr_farclip_world;
1064 float oldr_novis;
1065 float oldr_useportalculling;
1066 float oldr_useinfinitefarclip;
1067
1068 const int BUTTON_3 = 4;
1069 const int BUTTON_4 = 8;
1070 float cl_notice_run();
1071 float prev_myteam;
1072 int lasthud;
1073 float vh_notice_time;
1074 void WaypointSprite_Load();
1075 void CSQC_UpdateView(float w, float h)
1076 {SELFPARAM();
1077         entity e;
1078         float fov;
1079         float f;
1080         vector vf_size, vf_min;
1081         float a;
1082
1083         execute_next_frame();
1084
1085         ++framecount;
1086
1087         hud = getstati(STAT_HUD);
1088
1089         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1090                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1091
1092         lasthud = hud;
1093
1094         if(autocvar__hud_showbinds_reload) // menu can set this one
1095         {
1096                 db_close(binddb);
1097                 binddb = db_create();
1098                 cvar_set("_hud_showbinds_reload", "0");
1099         }
1100
1101         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1102                 view_quality = getproperty(VF_MINFPS_QUALITY);
1103         else
1104                 view_quality = 1;
1105
1106         button_attack2 = (input_buttons & BUTTON_3);
1107         button_zoom = (input_buttons & BUTTON_4);
1108
1109         vf_size = getpropertyvec(VF_SIZE);
1110         vf_min = getpropertyvec(VF_MIN);
1111         vid_width = vf_size.x;
1112         vid_height = vf_size.y;
1113
1114         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1115         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1116
1117         WaypointSprite_Load();
1118
1119         CSQCPlayer_SetCamera();
1120
1121         if(player_localentnum <= maxclients) // is it a client?
1122                 current_player = player_localentnum - 1;
1123         else // then player_localentnum is the vehicle I'm driving
1124                 current_player = player_localnum;
1125         myteam = GetPlayerColor(current_player);
1126
1127         if(myteam != prev_myteam)
1128         {
1129                 myteamcolors = colormapPaletteColor(myteam, 1);
1130                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1131                 prev_myteam = myteam;
1132         }
1133
1134         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1135
1136         float is_dead = (getstati(STAT_HEALTH) <= 0);
1137
1138         // FIXME do we need this hack?
1139         if(isdemo())
1140         {
1141                 // in demos, input_buttons do not work
1142                 button_zoom = (autocvar__togglezoom == "-");
1143         }
1144         else if(button_zoom
1145                 && autocvar_cl_unpress_zoom_on_death
1146                 && (spectatee_status >= 0)
1147                 && (is_dead || intermission))
1148         {
1149                 // no zoom while dead or in intermission please
1150                 localcmd("-zoom\n");
1151                 button_zoom = false;
1152         }
1153
1154         // event chase camera
1155         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1156         {
1157                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1158                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1159                 entity gen = world;
1160
1161                 if(ons_roundlost)
1162                 {
1163                         entity e;
1164                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1165                         {
1166                                 if(e.health <= 0)
1167                                 {
1168                                         gen = e;
1169                                         break;
1170                                 }
1171                         }
1172                         if(!gen)
1173                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1174                 }
1175                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1176                 {
1177                         eventchase_running = true;
1178
1179                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1180                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1181                         if(ons_roundlost) { current_view_origin = gen.origin; }
1182
1183                         // detect maximum viewoffset and use it
1184                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1185                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1186                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1187
1188                         if(view_offset)
1189                         {
1190                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1191                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1192                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1193                         }
1194
1195                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1196                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1197                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1198                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1199
1200                         // make the camera smooth back
1201                         float chase_distance = autocvar_cl_eventchase_distance;
1202                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1203                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1204
1205                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1206                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1207                         else if(eventchase_current_distance != chase_distance)
1208                                 eventchase_current_distance = chase_distance;
1209
1210                         makevectors(view_angles);
1211
1212                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1213                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1214
1215                         // If the boxtrace fails, revert back to line tracing.
1216                         if(!self.viewloc)
1217                         if(trace_startsolid)
1218                         {
1219                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1220                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1221                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1222                         }
1223                         else { setproperty(VF_ORIGIN, trace_endpos); }
1224
1225                         if(!self.viewloc)
1226                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1227                 }
1228                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1229                 {
1230                         eventchase_running = false;
1231                         cvar_set("chase_active", "0");
1232                         eventchase_current_distance = 0; // start from 0 next time
1233                 }
1234         }
1235         // workaround for camera stuck between player's legs when using chase_active 1
1236         // because the engine stops updating the chase_active camera when the game ends
1237         else if(intermission)
1238         {
1239                 cvar_settemp("chase_active", "-1");
1240                 eventchase_current_distance = 0;
1241         }
1242
1243         // do lockview after event chase camera so that it still applies whenever necessary.
1244         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1245         {
1246                 setproperty(VF_ORIGIN, freeze_org);
1247                 setproperty(VF_ANGLES, freeze_ang);
1248         }
1249         else
1250         {
1251                 freeze_org = getpropertyvec(VF_ORIGIN);
1252                 freeze_ang = getpropertyvec(VF_ANGLES);
1253         }
1254
1255         WarpZone_FixView();
1256         //WarpZone_FixPMove();
1257         {
1258                 static string name_last;
1259                 string name = get_weaponinfo(switchingweapon).mdl;
1260                 if (name != name_last)
1261                 {
1262                     name_last = name;
1263                         CL_WeaponEntity_SetModel(viewmodel, name);
1264                         updateanim(viewmodel);
1265                         if (!viewmodel.animstate_override)
1266                                 setanim(viewmodel, viewmodel.anim_idle, true, false, false);
1267                 }
1268         }
1269
1270         vector ov_org = '0 0 0';
1271         vector ov_mid = '0 0 0';
1272         vector ov_worldmin = '0 0 0';
1273         vector ov_worldmax = '0 0 0';
1274         if(autocvar_cl_orthoview)
1275         {
1276                 ov_worldmin = mi_picmin;
1277                 ov_worldmax = mi_picmax;
1278
1279                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1280                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1281                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1282
1283                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1284                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1285
1286                 float ov_nearest = vlen(ov_org - vec3(
1287                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1288                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1289                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1290                 ));
1291
1292                 float ov_furthest = 0;
1293                 float dist = 0;
1294
1295                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1296                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1297                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1298                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1299                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1300                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1301                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1302                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1303
1304                 if(!ov_enabled)
1305                 {
1306                         oldr_nearclip = cvar("r_nearclip");
1307                         oldr_farclip_base = cvar("r_farclip_base");
1308                         oldr_farclip_world = cvar("r_farclip_world");
1309                         oldr_novis = cvar("r_novis");
1310                         oldr_useportalculling = cvar("r_useportalculling");
1311                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1312                 }
1313
1314                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1315                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1316                 cvar_settemp("r_farclip_world", "0");
1317                 cvar_settemp("r_novis", "1");
1318                 cvar_settemp("r_useportalculling", "0");
1319                 cvar_settemp("r_useinfinitefarclip", "0");
1320
1321                 setproperty(VF_ORIGIN, ov_org);
1322                 setproperty(VF_ANGLES, '90 0 0');
1323
1324                 ov_enabled = true;
1325
1326                 #if 0
1327                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1328                         vtos(ov_org),
1329                         vtos(getpropertyvec(VF_ANGLES)),
1330                         ov_distance,
1331                         ov_nearest,
1332                         ov_furthest);
1333                 #endif
1334         }
1335         else
1336         {
1337                 if(ov_enabled)
1338                 {
1339                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1340                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1341                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1342                         cvar_set("r_novis", ftos(oldr_novis));
1343                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1344                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1345                 }
1346                 ov_enabled = false;
1347         }
1348
1349         // Render the Scene
1350         view_origin = getpropertyvec(VF_ORIGIN);
1351         view_angles = getpropertyvec(VF_ANGLES);
1352         makevectors(view_angles);
1353         view_forward = v_forward;
1354         view_right = v_right;
1355         view_up = v_up;
1356
1357 #ifdef BLURTEST
1358         if(time > blurtest_time0 && time < blurtest_time1)
1359         {
1360                 float r, t;
1361
1362                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1363                 r = t * blurtest_radius;
1364                 f = 1 / pow(t, blurtest_power) - 1;
1365
1366                 cvar_set("r_glsl_postprocess", "1");
1367                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1368         }
1369         else
1370         {
1371                 cvar_set("r_glsl_postprocess", "0");
1372                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1373         }
1374 #endif
1375
1376         TargetMusic_Advance();
1377         Fog_Force();
1378
1379         if(drawtime == 0)
1380                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1381         else
1382                 drawframetime = bound(0.000001, time - drawtime, 1);
1383         drawtime = time;
1384
1385         // watch for gametype changes here...
1386         // in ParseStuffCMD the cmd isn't executed yet :/
1387         // might even be better to add the gametype to TE_CSQC_INIT...?
1388         if(!postinit)
1389                 PostInit();
1390
1391         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1392         {
1393                 if(calledhooks & HOOK_START)
1394                 {
1395                         localcmd("\ncl_hook_gameend\n");
1396                         calledhooks |= HOOK_END;
1397                 }
1398         }
1399
1400         Announcer();
1401
1402         fov = autocvar_fov;
1403         if(fov <= 59.5)
1404         {
1405                 if(!zoomscript_caught)
1406                 {
1407                         localcmd("+button9\n");
1408                         zoomscript_caught = 1;
1409                 }
1410         }
1411         else
1412         {
1413                 if(zoomscript_caught)
1414                 {
1415                         localcmd("-button9\n");
1416                         zoomscript_caught = 0;
1417                 }
1418         }
1419
1420         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1421
1422         // next WANTED weapon (for HUD)
1423         switchweapon = getstati(STAT_SWITCHWEAPON);
1424
1425         // currently switching-to weapon (for crosshair)
1426         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1427
1428         // actually active weapon (for zoom)
1429         activeweapon = getstati(STAT_ACTIVEWEAPON);
1430
1431         f = (serverflags & SERVERFLAG_TEAMPLAY);
1432         if(f != teamplay)
1433         {
1434                 teamplay = f;
1435                 HUD_InitScores();
1436         }
1437
1438         if(last_switchweapon != switchweapon)
1439         {
1440                 weapontime = time;
1441                 last_switchweapon = switchweapon;
1442                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1443                 {
1444                         localcmd("-zoom\n");
1445                         button_zoom = false;
1446                 }
1447                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1448                 {
1449                         localcmd("-fire\n");
1450                         localcmd("-fire2\n");
1451                         button_attack2 = false;
1452                 }
1453         }
1454         if(last_activeweapon != activeweapon)
1455         {
1456                 last_activeweapon = activeweapon;
1457
1458                 e = get_weaponinfo(activeweapon);
1459                 if(e.netname != "")
1460                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1461                 else
1462                         localcmd("\ncl_hook_activeweapon none\n");
1463         }
1464
1465         // ALWAYS Clear Current Scene First
1466         clearscene();
1467
1468         setproperty(VF_ORIGIN, view_origin);
1469         setproperty(VF_ANGLES, view_angles);
1470
1471         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1472         setproperty(VF_SIZE, vf_size);
1473         setproperty(VF_MIN, vf_min);
1474
1475         // Assign Standard Viewflags
1476         // Draw the World (and sky)
1477         setproperty(VF_DRAWWORLD, 1);
1478
1479         // Set the console size vars
1480         vid_conwidth = autocvar_vid_conwidth;
1481         vid_conheight = autocvar_vid_conheight;
1482         vid_pixelheight = autocvar_vid_pixelheight;
1483
1484         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1485         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1486         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1487
1488         // Camera for demo playback
1489         if(camera_active)
1490         {
1491                 if(autocvar_camera_enable)
1492                         CSQC_Demo_Camera();
1493                 else
1494                 {
1495                         cvar_set("chase_active", ftos(chase_active_backup));
1496                         cvar_set("cl_demo_mousegrab", "0");
1497                         camera_active = false;
1498                 }
1499         }
1500         else
1501         {
1502 #ifdef CAMERATEST
1503                 if(autocvar_camera_enable)
1504 #else
1505                 if(autocvar_camera_enable && isdemo())
1506 #endif
1507                 {
1508                         // Enable required Darkplaces cvars
1509                         chase_active_backup = autocvar_chase_active;
1510                         cvar_set("chase_active", "2");
1511                         cvar_set("cl_demo_mousegrab", "1");
1512                         camera_active = true;
1513                         camera_mode = false;
1514                 }
1515         }
1516
1517         // Draw the Crosshair
1518         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1519
1520         // Draw the Engine Status Bar (the default Quake HUD)
1521         setproperty(VF_DRAWENGINESBAR, 0);
1522
1523         // Update the mouse position
1524         /*
1525            mousepos_x = vid_conwidth;
1526            mousepos_y = vid_conheight;
1527            mousepos = mousepos*0.5 + getmousepos();
1528          */
1529
1530         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1531                 WITH(entity, self, e, e.draw(e));
1532         }
1533
1534         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1535         renderscene();
1536
1537         // now switch to 2D drawing mode by calling a 2D drawing function
1538         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1539         // next R_RenderScene call
1540         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1541
1542         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1543         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1544         {
1545                 // apply night vision effect
1546                 vector tc_00, tc_01, tc_10, tc_11;
1547                 vector rgb = '0 0 0';
1548
1549                 if(!nightvision_noise)
1550                 {
1551                         nightvision_noise = spawn();
1552                         nightvision_noise.classname = "nightvision_noise";
1553                 }
1554                 if(!nightvision_noise2)
1555                 {
1556                         nightvision_noise2 = spawn();
1557                         nightvision_noise2.classname = "nightvision_noise2";
1558                 }
1559
1560                 // color tint in yellow
1561                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1562
1563                 // draw BG
1564                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1565                 rgb = '1 1 1';
1566                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1567                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1568                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1569                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1570                 tc_11 = tc_01 + tc_10 - tc_00;
1571                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1572                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1573                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1574                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1575                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1576                 R_EndPolygon();
1577
1578                 // draw FG
1579                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1580                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1581                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1582                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1583                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1584                 tc_11 = tc_01 + tc_10 - tc_00;
1585                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1586                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1587                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1588                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1589                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1590                 R_EndPolygon();
1591         }
1592
1593         if(autocvar_cl_reticle)
1594         {
1595                 Weapon wep = get_weaponinfo(activeweapon);
1596                 // Draw the aiming reticle for weapons that use it
1597                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1598                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1599                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1600                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1601                 {
1602                         // no zoom reticle while dead
1603                         reticle_type = 0;
1604                 }
1605                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1606                 {
1607                         if(reticle_image != "") { reticle_type = 2; }
1608                         else { reticle_type = 0; }
1609                 }
1610                 else if(button_zoom || zoomscript_caught)
1611                 {
1612                         // normal zoom
1613                         reticle_type = 1;
1614                 }
1615
1616                 if(reticle_type)
1617                 {
1618                         if(autocvar_cl_reticle_stretch)
1619                         {
1620                                 reticle_size.x = vid_conwidth;
1621                                 reticle_size.y = vid_conheight;
1622                                 reticle_pos.x = 0;
1623                                 reticle_pos.y = 0;
1624                         }
1625                         else
1626                         {
1627                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1628                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1629                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1630                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1631                         }
1632
1633                         if(zoomscript_caught)
1634                                 f = 1;
1635                         else
1636                                 f = current_zoomfraction;
1637
1638                         if(f)
1639                         {
1640                                 switch(reticle_type)
1641                                 {
1642                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1643                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1644                                 }
1645                         }
1646                 }
1647         }
1648         else
1649         {
1650                 if(reticle_type != 0) { reticle_type = 0; }
1651         }
1652
1653
1654         // improved polyblend
1655         if(autocvar_hud_contents)
1656         {
1657                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1658                 vector liquidcolor;
1659
1660                 switch(pointcontents(view_origin))
1661                 {
1662                         case CONTENT_WATER:
1663                                 liquidalpha = autocvar_hud_contents_water_alpha;
1664                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1665                                 incontent = 1;
1666                                 break;
1667
1668                         case CONTENT_LAVA:
1669                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1670                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1671                                 incontent = 1;
1672                                 break;
1673
1674                         case CONTENT_SLIME:
1675                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1676                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1677                                 incontent = 1;
1678                                 break;
1679
1680                         default:
1681                                 liquidalpha = 0;
1682                                 liquidcolor = '0 0 0';
1683                                 incontent = 0;
1684                                 break;
1685                 }
1686
1687                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1688                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1689                         contentfadetime = autocvar_hud_contents_fadeintime;
1690                         liquidalpha_prev = liquidalpha;
1691                         liquidcolor_prev = liquidcolor;
1692                 }
1693                 else
1694                         contentfadetime = autocvar_hud_contents_fadeouttime;
1695
1696                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1697                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1698
1699                 if(contentavgalpha)
1700                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1701
1702                 if(autocvar_hud_postprocessing)
1703                 {
1704                         if(autocvar_hud_contents_blur && contentavgalpha)
1705                         {
1706                                 content_blurpostprocess.x = 1;
1707                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1708                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1709                         }
1710                         else
1711                         {
1712                                 content_blurpostprocess.x = 0;
1713                                 content_blurpostprocess.y = 0;
1714                                 content_blurpostprocess.z = 0;
1715                         }
1716                 }
1717         }
1718
1719         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1720         {
1721                 splash_size.x = max(vid_conwidth, vid_conheight);
1722                 splash_size.y = max(vid_conwidth, vid_conheight);
1723                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1724                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1725
1726                 float myhealth_flash_temp;
1727                 myhealth = getstati(STAT_HEALTH);
1728
1729                 // fade out
1730                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1731                 // add new damage
1732                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1733
1734                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1735                 pain_threshold = autocvar_hud_damage_pain_threshold;
1736                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1737                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1738
1739                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1740                 {
1741                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1742                 }
1743
1744                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1745
1746                 if(myhealth_prev < 1)
1747                 {
1748                         if(myhealth >= 1)
1749                         {
1750                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1751                                 myhealth_flash_temp = 0;
1752                         }
1753                         else
1754                         {
1755                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1756                         }
1757                 }
1758
1759                 if(spectatee_status == -1 || intermission)
1760                 {
1761                         myhealth_flash = 0; // observing, or match ended
1762                         myhealth_flash_temp = 0;
1763                 }
1764
1765                 myhealth_prev = myhealth;
1766
1767                 // IDEA: change damage color/picture based on player model for robot/alien species?
1768                 // pro: matches model better
1769                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1770                 // maybe different reddish pics?
1771                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1772                 {
1773                         if(autocvar_cl_gentle_damage == 2)
1774                         {
1775                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1776                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1777                         }
1778                         else
1779                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1780
1781                         if(myhealth_flash_temp > 0)
1782                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1783                 }
1784                 else if(myhealth_flash_temp > 0)
1785                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1786
1787                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1788                 {
1789                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1790                         {
1791                                 damage_blurpostprocess.x = 1;
1792                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1793                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1794                         }
1795                         else
1796                         {
1797                                 damage_blurpostprocess.x = 0;
1798                                 damage_blurpostprocess.y = 0;
1799                                 damage_blurpostprocess.z = 0;
1800                         }
1801                 }
1802         }
1803
1804         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1805         float e2 = (autocvar_hud_powerup != 0);
1806         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1807         {
1808                 // enable or disable rendering types if they are used or not
1809                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1810                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1811
1812                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1813                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1814                 {
1815                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1816                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1817                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1818                         {
1819                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1820                                 old_blurradius = blurradius;
1821                                 old_bluralpha = bluralpha;
1822                         }
1823                 }
1824                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1825                 {
1826                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1827                         old_blurradius = 0;
1828                         old_bluralpha = 0;
1829                 }
1830
1831                 // edge detection postprocess handling done second (used by hud_powerup)
1832                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1833                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1834                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1835
1836                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1837
1838                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1839                 {
1840                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1841                         {
1842                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1843                                 old_sharpen_intensity = sharpen_intensity;
1844                         }
1845                 }
1846                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1847                 {
1848                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1849                         old_sharpen_intensity = 0;
1850                 }
1851
1852                 if(cvar("r_glsl_postprocess") == 0)
1853                         cvar_set("r_glsl_postprocess", "2");
1854         }
1855         else if(cvar("r_glsl_postprocess") == 2)
1856                 cvar_set("r_glsl_postprocess", "0");
1857
1858         if(menu_visible)
1859                 menu_show();
1860
1861         /*if(gametype == MAPINFO_TYPE_CTF)
1862           {
1863           ctf_view();
1864           } else */
1865
1866         // draw 2D entities
1867         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1868                 WITH(entity, self, e, e.draw2d(e));
1869         }
1870         Draw_ShowNames_All();
1871
1872         scoreboard_active = HUD_WouldDrawScoreboard();
1873
1874         HUD_Draw();
1875
1876         if(NextFrameCommand)
1877         {
1878                 localcmd("\n", NextFrameCommand, "\n");
1879                 NextFrameCommand = string_null;
1880         }
1881
1882         // we must do this check AFTER a frame was rendered, or it won't work
1883         if(cs_project_is_b0rked == 0)
1884         {
1885                 string w0, h0;
1886                 w0 = ftos(autocvar_vid_conwidth);
1887                 h0 = ftos(autocvar_vid_conheight);
1888                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1889                 //setproperty(VF_FOV, '90 90 0');
1890                 setproperty(VF_ORIGIN, '0 0 0');
1891                 setproperty(VF_ANGLES, '0 0 0');
1892                 setproperty(VF_PERSPECTIVE, 1);
1893                 makevectors('0 0 0');
1894                 vector v1, v2;
1895                 cvar_set("vid_conwidth", "800");
1896                 cvar_set("vid_conheight", "600");
1897                 v1 = cs_project(v_forward);
1898                 cvar_set("vid_conwidth", "640");
1899                 cvar_set("vid_conheight", "480");
1900                 v2 = cs_project(v_forward);
1901                 if(v1 == v2)
1902                         cs_project_is_b0rked = 1;
1903                 else
1904                         cs_project_is_b0rked = -1;
1905                 cvar_set("vid_conwidth", w0);
1906                 cvar_set("vid_conheight", h0);
1907         }
1908
1909         if(autocvar__hud_configure)
1910                 HUD_Panel_Mouse();
1911         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1912                 HUD_Minigame_Mouse();
1913         else if(QuickMenu_IsOpened())
1914                 QuickMenu_Mouse();
1915         else
1916                 HUD_Radar_Mouse();
1917
1918         cl_notice_run();
1919
1920         // let's reset the view back to normal for the end
1921         setproperty(VF_MIN, '0 0 0');
1922         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1923 }
1924
1925
1926 // following vectors must be global to allow seamless switching between camera modes
1927 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1928 void CSQC_Demo_Camera()
1929 {
1930         float speed, attenuation, dimensions;
1931         vector tmp, delta;
1932
1933         if( autocvar_camera_reset || !camera_mode )
1934         {
1935                 camera_offset = '0 0 0';
1936                 current_angles = '0 0 0';
1937                 camera_direction = '0 0 0';
1938                 camera_offset.z += 30;
1939                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1940                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1941                 current_origin = view_origin;
1942                 current_camera_offset  = camera_offset;
1943                 cvar_set("camera_reset", "0");
1944                 camera_mode = CAMERA_CHASE;
1945         }
1946
1947         // Camera angles
1948         if( camera_roll )
1949                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1950
1951         if(autocvar_camera_look_player)
1952         {
1953                 vector dir;
1954                 float n;
1955
1956                 dir = normalize(view_origin - current_position);
1957                 n = mouse_angles.z;
1958                 mouse_angles = vectoangles(dir);
1959                 mouse_angles.x = mouse_angles.x * -1;
1960                 mouse_angles.z = n;
1961         }
1962         else
1963         {
1964                 tmp = getmousepos() * 0.1;
1965                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1966                 {
1967                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1968                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1969                 }
1970         }
1971
1972         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1973         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1974         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1975         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1976
1977         // Fix difference when angles don't have the same sign
1978         delta = '0 0 0';
1979         if(mouse_angles.y < -60 && current_angles.y > 60)
1980                 delta = '0 360 0';
1981         if(mouse_angles.y > 60 && current_angles.y < -60)
1982                 delta = '0 -360 0';
1983
1984         if(autocvar_camera_look_player)
1985                 attenuation = autocvar_camera_look_attenuation;
1986         else
1987                 attenuation = autocvar_camera_speed_attenuation;
1988
1989         attenuation = 1 / max(1, attenuation);
1990         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1991
1992         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1993         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1994         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1995         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1996
1997         // Camera position
1998         tmp = '0 0 0';
1999         dimensions = 0;
2000
2001         if( camera_direction.x )
2002         {
2003                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2004                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2005                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2006                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2007                 ++dimensions;
2008         }
2009
2010         if( camera_direction.y )
2011         {
2012                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2013                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2014                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2015                 ++dimensions;
2016         }
2017
2018         if( camera_direction.z )
2019         {
2020                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2021                 ++dimensions;
2022         }
2023
2024         if(autocvar_camera_free)
2025                 speed = autocvar_camera_speed_free;
2026         else
2027                 speed = autocvar_camera_speed_chase;
2028
2029         if(dimensions)
2030         {
2031                 speed = speed * sqrt(1 / dimensions);
2032                 camera_offset += tmp * speed;
2033         }
2034
2035         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2036
2037         // Camera modes
2038         if( autocvar_camera_free )
2039         {
2040                 if ( camera_mode == CAMERA_CHASE )
2041                 {
2042                         current_camera_offset = current_origin + current_camera_offset;
2043                         camera_offset = current_origin + camera_offset;
2044                 }
2045
2046                 camera_mode = CAMERA_FREE;
2047                 current_position = current_camera_offset;
2048         }
2049         else
2050         {
2051                 if ( camera_mode == CAMERA_FREE )
2052                 {
2053                         current_origin = view_origin;
2054                         camera_offset = camera_offset - current_origin;
2055                         current_camera_offset = current_camera_offset - current_origin;
2056                 }
2057
2058                 camera_mode = CAMERA_CHASE;
2059
2060                 if(autocvar_camera_chase_smoothly)
2061                         current_origin += (view_origin - current_origin) * attenuation;
2062                 else
2063                         current_origin = view_origin;
2064
2065                 current_position = current_origin + current_camera_offset;
2066         }
2067
2068         setproperty(VF_ANGLES, current_angles);
2069         setproperty(VF_ORIGIN, current_position);
2070 }