qcsrc/client/weapons/projectile.qc

   1 #include "projectile.qh"
   2
   3 #include "../autocvars.qh"
   4 #include "../defs.qh"
   5 #include "../main.qh"
   6 #include "../movetypes.qh"
   7 #include "../../common/constants.qh"
   8 #include "../../common/nades.qh"
   9 #include "../../common/util.qh"
  10 #include "../../csqcmodellib/interpolate.qh"
  11 #include "../../warpzonelib/anglestransform.qh"
  12
  13 .float alpha;
  14 .float scale;
  15 .vector colormod;
  16
  17 void SUB_Stop()
  18 {
  19         self.move_velocity = self.move_avelocity = '0 0 0';
  20         self.move_movetype = MOVETYPE_NONE;
  21 }
  22
  23 void Projectile_ResetTrail(vector to)
  24 {
  25         self.trail_oldorigin = to;
  26         self.trail_oldtime = time;
  27 }
  28
  29 void Projectile_DrawTrail(vector to)
  30 {
  31         vector from;
  32         float t0;
  33
  34         from = self.trail_oldorigin;
  35         t0 = self.trail_oldtime;
  36         self.trail_oldorigin = to;
  37         self.trail_oldtime = time;
  38
  39         // force the effect even for stationary firemine
  40         if(self.cnt == PROJECTILE_FIREMINE)
  41                 if(from == to)
  42                         from.z += 1;
  43
  44         if (self.traileffect)
  45         {
  46                 particles_alphamin = particles_alphamax = particles_fade = sqrt(self.alpha);
  47                 boxparticles(self.traileffect, self, from, to, self.velocity, self.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  48         }
  49 }
  50
  51 void Projectile_Draw()
  52 {
  53         vector rot;
  54         vector trailorigin;
  55         int f;
  56         bool drawn;
  57         float t;
  58         float a;
  59
  60         f = self.move_flags;
  61
  62         if(self.count & 0x80)
  63         {
  64                 //self.move_flags &= ~FL_ONGROUND;
  65                 if(self.move_movetype == MOVETYPE_NONE || self.move_movetype == MOVETYPE_FLY)
  66                         Movetype_Physics_NoMatchServer();
  67                         // the trivial movetypes do not have to match the
  68                         // server's ticrate as they are ticrate independent
  69                         // NOTE: this assumption is only true if MOVETYPE_FLY
  70                         // projectiles detonate on impact. If they continue
  71                         // moving, we might still be ticrate dependent.
  72                 else
  73                         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74                 if(!(self.move_flags & FL_ONGROUND))
  75                         if(self.velocity != '0 0 0')
  76                                 self.move_angles = self.angles = vectoangles(self.velocity);
  77         }
  78         else
  79         {
  80                 InterpolateOrigin_Do();
  81         }
  82
  83         if(self.count & 0x80)
  84         {
  85                 drawn = (time >= self.spawntime - 0.02);
  86                 t = max(time, self.spawntime);
  87         }
  88         else
  89         {
  90                 drawn = (self.iflags & IFLAG_VALID);
  91                 t = time;
  92         }
  93
  94         if(!(f & FL_ONGROUND))
  95         {
  96                 rot = '0 0 0';
  97                 switch(self.cnt)
  98                 {
  99                         /*
 100                         case PROJECTILE_GRENADE:
 101                                 rot = '-2000 0 0'; // forward
 102                                 break;
 103                         */
 104                         case PROJECTILE_GRENADE_BOUNCING:
 105                                 rot = '0 -1000 0'; // sideways
 106                                 break;
 107                         case PROJECTILE_HOOKBOMB:
 108                                 rot = '1000 0 0'; // forward
 109                                 break;
 110                         default:
 111                                 break;
 112                 }
 113
 114                 if(Nade_IDFromProjectile(self.cnt) != 0)
 115                         rot = self.avelocity;
 116
 117                 self.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(self.angles), rot * (t - self.spawntime)));
 118         }
 119
 120         vector ang;
 121         ang = self.angles;
 122         ang.x = -ang.x;
 123         makevectors(ang);
 124
 125         a = 1 - (time - self.fade_time) * self.fade_rate;
 126         self.alpha = bound(0, self.alphamod * a, 1);
 127         if(self.alpha <= 0)
 128                 drawn = 0;
 129         self.renderflags = 0;
 130
 131         trailorigin = self.origin;
 132         switch(self.cnt)
 133         {
 134                 case PROJECTILE_GRENADE:
 135                 case PROJECTILE_GRENADE_BOUNCING:
 136                         trailorigin += v_right * 1 + v_forward * -10;
 137                         break;
 138                 default:
 139                         break;
 140         }
 141
 142         if(Nade_IDFromProjectile(self.cnt) != 0)
 143                 trailorigin += v_up * 4;
 144
 145         if(drawn)
 146                 Projectile_DrawTrail(trailorigin);
 147         else
 148                 Projectile_ResetTrail(trailorigin);
 149
 150         self.drawmask = 0;
 151
 152         if(!drawn)
 153                 return;
 154
 155         switch(self.cnt)
 156         {
 157                 // Possibly add dlights here.
 158                 default:
 159                         break;
 160         }
 161
 162         self.drawmask = MASK_NORMAL;
 163 }
 164
 165 void loopsound(entity e, int ch, string samp, float vol, float attn)
 166 {
 167         if(self.silent)
 168                 return;
 169
 170         sound(e, ch, samp, vol, attn);
 171         e.snd_looping = ch;
 172 }
 173
 174 void Ent_RemoveProjectile()
 175 {
 176         if(self.count & 0x80)
 177         {
 178                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 179                 Projectile_DrawTrail(trace_endpos);
 180         }
 181 }
 182
 183 void Ent_Projectile()
 184 {
 185         int f;
 186
 187         // projectile properties:
 188         //   kind (interpolated, or clientside)
 189         //
 190         //   modelindex
 191         //   origin
 192         //   scale
 193         //   if clientside:
 194         //     velocity
 195         //     gravity
 196         //   soundindex (hardcoded list)
 197         //   effects
 198         //
 199         // projectiles don't send angles, because they always follow the velocity
 200
 201         f = ReadByte();
 202         self.count = (f & 0x80);
 203         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 204         self.solid = SOLID_TRIGGER;
 205         //self.effects = EF_NOMODELFLAGS;
 206
 207         // this should make collisions with bmodels more exact, but it leads to
 208         // projectiles no longer being able to lie on a bmodel
 209         self.move_nomonsters = MOVE_WORLDONLY;
 210         if(f & 0x40)
 211                 self.move_flags |= FL_ONGROUND;
 212         else
 213                 self.move_flags &= ~FL_ONGROUND;
 214
 215         if(!self.move_time)
 216         {
 217                 // for some unknown reason, we don't need to care for
 218                 // sv_gameplayfix_delayprojectiles here.
 219                 self.move_time = time;
 220                 self.spawntime = time;
 221         }
 222         else
 223                 self.move_time = max(self.move_time, time);
 224
 225         if(!(self.count & 0x80))
 226                 InterpolateOrigin_Undo();
 227
 228         if(f & 1)
 229         {
 230                 self.origin_x = ReadCoord();
 231                 self.origin_y = ReadCoord();
 232                 self.origin_z = ReadCoord();
 233                 setorigin(self, self.origin);
 234                 if(self.count & 0x80)
 235                 {
 236                         self.velocity_x = ReadCoord();
 237                         self.velocity_y = ReadCoord();
 238                         self.velocity_z = ReadCoord();
 239                         if(f & 0x10)
 240                                 self.gravity = ReadCoord();
 241                         else
 242                                 self.gravity = 0; // none
 243                         self.move_origin = self.origin;
 244                         self.move_velocity = self.velocity;
 245                 }
 246
 247                 if(time == self.spawntime || (self.count & 0x80) || (f & 0x08))
 248                 {
 249                         self.trail_oldorigin = self.origin;
 250                         if(!(self.count & 0x80))
 251                                 InterpolateOrigin_Reset();
 252                 }
 253
 254                 if(f & 0x20)
 255                 {
 256                         self.fade_time = time + ReadByte() * ticrate;
 257                         self.fade_rate = 1 / (ReadByte() * ticrate);
 258                 }
 259                 else
 260                 {
 261                         self.fade_time = 0;
 262                         self.fade_rate = 0;
 263                 }
 264
 265                 self.team = ReadByte() - 1;
 266         }
 267
 268         if(f & 2)
 269         {
 270                 self.cnt = ReadByte();
 271
 272                 self.silent = (self.cnt & 0x80);
 273                 self.cnt = (self.cnt & 0x7F);
 274
 275                 self.scale = 1;
 276                 self.traileffect = 0;
 277                 switch(self.cnt)
 278                 {
 279                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 280                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); self.scale = 2; break;
 281                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 282                         case PROJECTILE_CRYLINK_BOUNCING: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 283                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 284                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 285                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 286                         case PROJECTILE_MINE: setmodel(self, "models/mine.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 287                         case PROJECTILE_BLASTER: setmodel(self, "models/laser.mdl");self.traileffect = particleeffectnum(""); break;
 288                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3");self.traileffect = particleeffectnum(""); break;
 289                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 290                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 291                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_KNIGHTSPIKE"); break;
 292                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 293                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 294                         case PROJECTILE_NAPALM_FOUNTAIN: //self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("torch_small"); break;
 295                         case PROJECTILE_FIREBALL: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("fireball"); break; // particle effect is good enough
 296                         case PROJECTILE_FIREMINE: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("firemine"); break; // particle effect is good enough
 297                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); self.traileffect = particleeffectnum("TR_ROCKET"); break;
 298                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; self.traileffect = particleeffectnum("TR_SEEKER"); break;
 299                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.traileffect = particleeffectnum("TR_SEEKER"); break;
 300
 301                         case PROJECTILE_MAGE_SPIKE: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_VORESPIKE"); break;
 302                         case PROJECTILE_SHAMBLER_LIGHTNING: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 303
 304                         case PROJECTILE_RAPTORBOMB:    setmodel(self, "models/vehicles/clusterbomb.md3"); self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 305                         case PROJECTILE_RAPTORBOMBLET: setmodel(self, "models/vehicles/bomblet.md3");     self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 306                         case PROJECTILE_RAPTORCANNON:  setmodel(self, "models/plasmatrail.mdl"); self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 307
 308                         case PROJECTILE_SPIDERROCKET: setmodel(self, "models/vehicles/rocket02.md3"); self.traileffect = particleeffectnum("spiderbot_rocket_thrust"); break;
 309                         case PROJECTILE_WAKIROCKET:   setmodel(self, "models/vehicles/rocket01.md3");  self.traileffect = particleeffectnum("wakizashi_rocket_thrust"); break;
 310                         case PROJECTILE_WAKICANNON:   setmodel(self, "models/laser.mdl");  self.traileffect = particleeffectnum(""); break;
 311
 312                         case PROJECTILE_BUMBLE_GUN: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 313                         case PROJECTILE_BUMBLE_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 314
 315                         case PROJECTILE_RPC: setmodel(self, "models/weapons/ok_rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); break;
 316
 317                         default:
 318                                 if(Nade_IDFromProjectile(self.cnt) != 0) { setmodel(self, "models/weapons/v_ok_grenade.md3");self.traileffect = particleeffectnum(Nade_TrailEffect(self.cnt, self.team)); break; }
 319                                 error("Received invalid CSQC projectile, can't work with this!");
 320                                 break;
 321                 }
 322
 323                 self.mins = '0 0 0';
 324                 self.maxs = '0 0 0';
 325                 self.colormod = '0 0 0';
 326                 self.move_touch = SUB_Stop;
 327                 self.move_movetype = MOVETYPE_TOSS;
 328                 self.alphamod = 1;
 329
 330                 switch(self.cnt)
 331                 {
 332                         case PROJECTILE_ELECTRO:
 333                                 // only new engines support sound moving with object
 334                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 335                                 self.mins = '0 0 -4';
 336                                 self.maxs = '0 0 -4';
 337                                 self.move_movetype = MOVETYPE_BOUNCE;
 338                                 self.move_touch = func_null;
 339                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 340                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 341                                 break;
 342                         case PROJECTILE_RPC:
 343                         case PROJECTILE_ROCKET:
 344                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 345                                 self.mins = '-3 -3 -3';
 346                                 self.maxs = '3 3 3';
 347                                 break;
 348                         case PROJECTILE_GRENADE:
 349                                 self.mins = '-3 -3 -3';
 350                                 self.maxs = '3 3 3';
 351                                 break;
 352                         case PROJECTILE_GRENADE_BOUNCING:
 353                                 self.mins = '-3 -3 -3';
 354                                 self.maxs = '3 3 3';
 355                                 self.move_movetype = MOVETYPE_BOUNCE;
 356                                 self.move_touch = func_null;
 357                                 self.move_bounce_factor = g_balance_mortar_bouncefactor;
 358                                 self.move_bounce_stopspeed = g_balance_mortar_bouncestop;
 359                                 break;
 360                         case PROJECTILE_SHAMBLER_LIGHTNING:
 361                                 self.mins = '-8 -8 -8';
 362                                 self.maxs = '8 8 8';
 363                                 self.scale = 2.5;
 364                                 self.avelocity = randomvec() * 720;
 365                                 break;
 366                         case PROJECTILE_MINE:
 367                                 self.mins = '-4 -4 -4';
 368                                 self.maxs = '4 4 4';
 369                                 break;
 370                         case PROJECTILE_PORTO_RED:
 371                                 self.colormod = '2 1 1';
 372                                 self.alphamod = 0.5;
 373                                 self.move_movetype = MOVETYPE_BOUNCE;
 374                                 self.move_touch = func_null;
 375                                 break;
 376                         case PROJECTILE_PORTO_BLUE:
 377                                 self.colormod = '1 1 2';
 378                                 self.alphamod = 0.5;
 379                                 self.move_movetype = MOVETYPE_BOUNCE;
 380                                 self.move_touch = func_null;
 381                                 break;
 382                         case PROJECTILE_HAGAR_BOUNCING:
 383                                 self.move_movetype = MOVETYPE_BOUNCE;
 384                                 self.move_touch = func_null;
 385                                 break;
 386                         case PROJECTILE_CRYLINK_BOUNCING:
 387                                 self.move_movetype = MOVETYPE_BOUNCE;
 388                                 self.move_touch = func_null;
 389                                 break;
 390                         case PROJECTILE_NAPALM_FOUNTAIN:
 391                         case PROJECTILE_FIREBALL:
 392                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly2.wav", VOL_BASE, ATTEN_NORM);
 393                                 self.mins = '-16 -16 -16';
 394                                 self.maxs = '16 16 16';
 395                                 break;
 396                         case PROJECTILE_FIREMINE:
 397                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly.wav", VOL_BASE, ATTEN_NORM);
 398                                 self.move_movetype = MOVETYPE_BOUNCE;
 399                                 self.move_touch = func_null;
 400                                 self.mins = '-4 -4 -4';
 401                                 self.maxs = '4 4 4';
 402                                 break;
 403                         case PROJECTILE_TAG:
 404                                 self.mins = '-2 -2 -2';
 405                                 self.maxs = '2 2 2';
 406                                 break;
 407                         case PROJECTILE_FLAC:
 408                                 self.mins = '-2 -2 -2';
 409                                 self.maxs = '2 2 2';
 410                                 break;
 411                         case PROJECTILE_SEEKER:
 412                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 413                                 self.mins = '-4 -4 -4';
 414                                 self.maxs = '4 4 4';
 415                                 break;
 416             case PROJECTILE_RAPTORBOMB:
 417                                 self.mins = '-3 -3 -3';
 418                                 self.maxs = '3 3 3';
 419                                 break;
 420             case PROJECTILE_RAPTORBOMBLET:
 421                                 break;
 422             case PROJECTILE_RAPTORCANNON:
 423                                 break;
 424             case PROJECTILE_SPIDERROCKET:
 425                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 426                                 break;
 427             case PROJECTILE_WAKIROCKET:
 428                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 429                                 break;
 430             /*
 431             case PROJECTILE_WAKICANNON:
 432                                 break;
 433                         case PROJECTILE_BUMBLE_GUN:
 434                                 // only new engines support sound moving with object
 435                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 436                                 self.mins = '0 0 -4';
 437                                 self.maxs = '0 0 -4';
 438                                 self.move_movetype = MOVETYPE_BOUNCE;
 439                                 self.move_touch = func_null;
 440                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 441                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 442                                 break;
 443                         */
 444                         default:
 445                                 break;
 446                 }
 447
 448                 if(Nade_IDFromProjectile(self.cnt) != 0)
 449                 {
 450                         int nade_type = Nade_IDFromProjectile(self.cnt);
 451                         self.mins = '-16 -16 -16';
 452                         self.maxs = '16 16 16';
 453                         self.colormod = Nade_Color(nade_type);
 454                         self.move_movetype = MOVETYPE_BOUNCE;
 455                         self.move_touch = func_null;
 456                         self.scale = 1.5;
 457                         self.avelocity = randomvec() * 720;
 458
 459                         if(nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 460                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 461                         else
 462                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 463                 }
 464
 465                 setsize(self, self.mins, self.maxs);
 466         }
 467
 468         if(self.gravity)
 469         {
 470                 if(self.move_movetype == MOVETYPE_FLY)
 471                         self.move_movetype = MOVETYPE_TOSS;
 472                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 473                         self.move_movetype = MOVETYPE_BOUNCE;
 474         }
 475         else
 476         {
 477                 if(self.move_movetype == MOVETYPE_TOSS)
 478                         self.move_movetype = MOVETYPE_FLY;
 479                 if(self.move_movetype == MOVETYPE_BOUNCE)
 480                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 481         }
 482
 483         if(!(self.count & 0x80))
 484                 InterpolateOrigin_Note();
 485
 486         self.draw = Projectile_Draw;
 487         self.entremove = Ent_RemoveProjectile;
 488 }
 489
 490 void Projectile_Precache()
 491 {
 492         precache_model("models/ebomb.mdl");
 493         precache_model("models/elaser.mdl");
 494         precache_model("models/grenademodel.md3");
 495         precache_model("models/mine.md3");
 496         precache_model("models/hagarmissile.mdl");
 497         precache_model("models/hlac_bullet.md3");
 498         precache_model("models/laser.mdl");
 499         precache_model("models/plasmatrail.mdl");
 500         precache_model("models/rocket.md3");
 501         precache_model("models/tagrocket.md3");
 502         precache_model("models/tracer.mdl");
 503         precache_model("models/sphere/sphere.md3");
 504
 505         precache_model("models/weapons/v_ok_grenade.md3");
 506         precache_model("models/weapons/ok_rocket.md3");
 507
 508         precache_sound("weapons/electro_fly.wav");
 509         precache_sound("weapons/rocket_fly.wav");
 510         precache_sound("weapons/fireball_fly.wav");
 511         precache_sound("weapons/fireball_fly2.wav");
 512         precache_sound("weapons/tag_rocket_fly.wav");
 513
 514 }