qcsrc/common/animdecide.qc

   1 // player animation data for this model
   2 // each vector is as follows:
   3 // _x = startframe
   4 // _y = numframes
   5 // _z = framerate
   6 .vector anim_die1; // player dies
   7 .vector anim_die2; // player dies differently
   8 .vector anim_draw; // player pulls out a weapon
   9 .vector anim_duckwalk; // player walking while crouching
  10 .vector anim_duckjump; // player jumping from a crouch
  11 .vector anim_duckidle; // player idling while crouching
  12 .vector anim_idle; // player standing
  13 .vector anim_jump; // player jump
  14 .vector anim_pain1; // player flinches from pain
  15 .vector anim_pain2; // player flinches from pain, differently
  16 .vector anim_shoot; // player shoots
  17 .vector anim_taunt; // player taunts others (FIXME: no code references this)
  18 .vector anim_run; // player running forward
  19 .vector anim_runbackwards; // player running backward
  20 .vector anim_strafeleft; // player shuffling left quickly
  21 .vector anim_straferight; // player shuffling right quickly
  22 .vector anim_forwardright; // player running forward and right
  23 .vector anim_forwardleft; // player running forward and left
  24 .vector anim_backright; // player running backward and right
  25 .vector anim_backleft; // player running back and left
  26 .vector anim_melee; // player doing the melee action
  27 .vector anim_duck; // player doing the melee action
  28 .vector anim_duckwalkbackwards;
  29 .vector anim_duckwalkstrafeleft;
  30 .vector anim_duckwalkstraferight;
  31 .vector anim_duckwalkforwardright;
  32 .vector anim_duckwalkforwardleft;
  33 .vector anim_duckwalkbackright;
  34 .vector anim_duckwalkbackleft;
  35
  36 void animdecide_init(entity e)
  37 {
  38         vector none = '0 0 0';
  39         e.anim_die1 = animfixfps(e, '0 1 0.5', none); // 2 seconds
  40         e.anim_die2 = animfixfps(e, '1 1 0.5', none); // 2 seconds
  41         e.anim_draw = animfixfps(e, '2 1 3', none);
  42         e.anim_duckwalk = animfixfps(e, '4 1 1', none);
  43         e.anim_duckjump = animfixfps(e, '5 1 10', none);
  44         e.anim_duckidle = animfixfps(e, '6 1 1', none);
  45         e.anim_idle = animfixfps(e, '7 1 1', none);
  46         e.anim_jump = animfixfps(e, '8 1 10', none);
  47         e.anim_pain1 = animfixfps(e, '9 1 2', none); // 0.5 seconds
  48         e.anim_pain2 = animfixfps(e, '10 1 2', none); // 0.5 seconds
  49         e.anim_shoot = animfixfps(e, '11 1 5', none); // analyze models and set framerate
  50         e.anim_taunt = animfixfps(e, '12 1 0.33', none);
  51         e.anim_run = animfixfps(e, '13 1 1', none);
  52         e.anim_runbackwards = animfixfps(e, '14 1 1', none);
  53         e.anim_strafeleft = animfixfps(e, '15 1 1', none);
  54         e.anim_straferight = animfixfps(e, '16 1 1', none);
  55         e.anim_forwardright = animfixfps(e, '19 1 1', '16 1 1');
  56         e.anim_forwardleft = animfixfps(e, '20 1 1', '15 1 1');
  57         e.anim_backright = animfixfps(e, '21 1 1', '16 1 1');
  58         e.anim_backleft  = animfixfps(e, '22 1 1', '15 1 1');
  59         e.anim_melee = animfixfps(e, '23 1 1', '11 1 1');
  60         e.anim_duckwalkbackwards = animfixfps(e, '24 1 1', '4 1 1');
  61         e.anim_duckwalkstrafeleft = animfixfps(e, '25 1 1', '4 1 1');
  62         e.anim_duckwalkstraferight = animfixfps(e, '26 1 1', '4 1 1');
  63         e.anim_duckwalkforwardright = animfixfps(e, '27 1 1', '4 1 1');
  64         e.anim_duckwalkforwardleft = animfixfps(e, '28 1 1', '4 1 1');
  65         e.anim_duckwalkbackright = animfixfps(e, '29 1 1', '4 1 1');
  66         e.anim_duckwalkbackleft  = animfixfps(e, '30 1 1', '4 1 1');
  67
  68         // these anims ought to stay until stopped explicitly by weaponsystem
  69         e.anim_shoot_z = 0.001;
  70         e.anim_melee_z = 0.001;
  71 }
  72
  73 #define ANIMPRIO_IDLE 0
  74 #define ANIMPRIO_ACTIVE 1
  75 #define ANIMPRIO_CROUCH 2
  76 #define ANIMPRIO_DEAD 3
  77
  78 vector animdecide_getupperanim(entity e)
  79 {
  80         // death etc.
  81         if(e.anim_state & ANIMSTATE_FROZEN)
  82                 return vec3(e.anim_idle_x, e.anim_time, ANIMPRIO_DEAD);
  83         if(e.anim_state & ANIMSTATE_DEAD1)
  84                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
  85         if(e.anim_state & ANIMSTATE_DEAD2)
  86                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
  87
  88         // is there an action?
  89         vector outframe = '-1 0 0';
  90         float t, a;
  91         if(e.anim_upper_time >= e.anim_upper_implicit_time)
  92         {
  93                 a = e.anim_upper_action;
  94                 t = e.anim_upper_time;
  95         }
  96         else
  97         {
  98                 a = e.anim_upper_implicit_action;
  99                 t = e.anim_upper_implicit_time;
 100         }
 101         switch(a)
 102         {
 103                 case ANIMACTION_DRAW: outframe = e.anim_draw; break;
 104                 case ANIMACTION_PAIN1: outframe = e.anim_pain1; break;
 105                 case ANIMACTION_PAIN2: outframe = e.anim_pain2; break;
 106                 case ANIMACTION_SHOOT: outframe = e.anim_shoot; break;
 107                 case ANIMACTION_TAUNT: outframe = e.anim_taunt; break;
 108                 case ANIMACTION_MELEE: outframe = e.anim_melee; break;
 109         }
 110         if(outframe_x >= 0)
 111         {
 112                 if(time <= t + outframe_y / outframe_z)
 113                 {
 114                         // animation is running!
 115                         return vec3(outframe_x, t, ANIMPRIO_ACTIVE);
 116                 }
 117         }
 118         // or, decide the anim by state
 119         t = max(e.anim_time, e.anim_implicit_time);
 120         // but all states are for lower body!
 121         return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 122 }
 123
 124 vector animdecide_getloweranim(entity e)
 125 {
 126         // death etc.
 127         if(e.anim_state & ANIMSTATE_FROZEN)
 128                 return vec3(e.anim_idle_x, e.anim_time, ANIMPRIO_DEAD);
 129         if(e.anim_state & ANIMSTATE_DEAD1)
 130                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 131         if(e.anim_state & ANIMSTATE_DEAD2)
 132                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 133
 134         // is there an action?
 135         vector outframe = '-1 0 0';
 136         float t, a;
 137         if(e.anim_lower_time >= e.anim_lower_implicit_time)
 138         {
 139                 a = e.anim_lower_action;
 140                 t = e.anim_lower_time;
 141         }
 142         else
 143         {
 144                 a = e.anim_lower_implicit_action;
 145                 t = e.anim_lower_implicit_time;
 146         }
 147         switch(a)
 148         {
 149                 case ANIMACTION_JUMP: if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) { if(e.anim_state & ANIMSTATE_DUCK) outframe = e.anim_duckjump; else outframe = e.anim_jump; } break;
 150         }
 151         if(outframe_x >= 0)
 152         {
 153                 if(time <= t + outframe_y / outframe_z)
 154                 {
 155                         // animation is running!
 156                         return vec3(outframe_x, t, ANIMPRIO_ACTIVE);
 157                 }
 158         }
 159         // or, decide the anim by state
 160         t = max(e.anim_time, e.anim_implicit_time);
 161         if(e.anim_state & ANIMSTATE_DUCK)
 162         {
 163                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 164                         return vec3(e.anim_duckjump_x, 0, ANIMPRIO_CROUCH); // play the END of the jump anim
 165                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 166                 {
 167                         case ANIMIMPLICITSTATE_FORWARD:
 168                                 return vec3(e.anim_duckwalk_x, t, ANIMPRIO_CROUCH);
 169                         case ANIMIMPLICITSTATE_BACKWARDS:
 170                                 return vec3(e.anim_duckwalkbackwards_x, t, ANIMPRIO_CROUCH);
 171                         case ANIMIMPLICITSTATE_RIGHT:
 172                                 return vec3(e.anim_duckwalkstraferight_x, t, ANIMPRIO_CROUCH);
 173                         case ANIMIMPLICITSTATE_LEFT:
 174                                 return vec3(e.anim_duckwalkstrafeleft_x, t, ANIMPRIO_CROUCH);
 175                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 176                                 return vec3(e.anim_duckwalkforwardright_x, t, ANIMPRIO_CROUCH);
 177                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 178                                 return vec3(e.anim_duckwalkforwardleft_x, t, ANIMPRIO_CROUCH);
 179                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 180                                 return vec3(e.anim_duckwalkbackright_x, t, ANIMPRIO_CROUCH);
 181                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 182                                 return vec3(e.anim_duckwalkbackleft_x, t, ANIMPRIO_CROUCH);
 183                         default:
 184                                 return vec3(e.anim_duckidle_x, t, ANIMPRIO_CROUCH);
 185                 }
 186         }
 187         else
 188         {
 189                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 190                         return vec3(e.anim_jump_x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 191                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 192                 {
 193                         case ANIMIMPLICITSTATE_FORWARD:
 194                                 return vec3(e.anim_run_x, t, ANIMPRIO_ACTIVE);
 195                         case ANIMIMPLICITSTATE_BACKWARDS:
 196                                 return vec3(e.anim_runbackwards_x, t, ANIMPRIO_ACTIVE);
 197                         case ANIMIMPLICITSTATE_RIGHT:
 198                                 return vec3(e.anim_straferight_x, t, ANIMPRIO_ACTIVE);
 199                         case ANIMIMPLICITSTATE_LEFT:
 200                                 return vec3(e.anim_strafeleft_x, t, ANIMPRIO_ACTIVE);
 201                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 202                                 return vec3(e.anim_forwardright_x, t, ANIMPRIO_ACTIVE);
 203                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 204                                 return vec3(e.anim_forwardleft_x, t, ANIMPRIO_ACTIVE);
 205                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 206                                 return vec3(e.anim_backright_x, t, ANIMPRIO_ACTIVE);
 207                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 208                                 return vec3(e.anim_backleft_x, t, ANIMPRIO_ACTIVE);
 209                         default:
 210                                 return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 211                 }
 212         }
 213         // can't get here
 214 #ifdef GMQCC
 215         return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 216 #endif
 217 }
 218
 219 void animdecide_setimplicitstate(entity e, float onground)
 220 {
 221         float s;
 222         s = 0;
 223
 224         makevectors(e.angles);
 225         vector v;
 226         v_x = e.velocity * v_forward;
 227         v_y = e.velocity * v_right;
 228
 229         // we want to match like this:
 230         // the 8 directions shall be "evenly spaced"
 231         // that means, the forward key includes anything from -67.5 to +67.5 degrees
 232         // which then means x > |y| * cot(3pi/8)
 233         //
 234         // BUT, the engine's clip-movement-to-keyboard function uses 0.5 here,
 235         // which would be an angle range from -63.43 to +63.43 degrees, making
 236         // it slightly less likely to "hit two keys at once", so let's do this
 237         // here too
 238
 239         if(vlen(v) > 10)
 240         {
 241                 if(v_x >  fabs(v_y) * 0.5)
 242                         s |= ANIMIMPLICITSTATE_FORWARD;
 243                 if(v_x < -fabs(v_y) * 0.5)
 244                         s |= ANIMIMPLICITSTATE_BACKWARDS;
 245                 if(v_y >  fabs(v_x) * 0.5)
 246                         s |= ANIMIMPLICITSTATE_RIGHT;
 247                 if(v_y < -fabs(v_x) * 0.5)
 248                         s |= ANIMIMPLICITSTATE_LEFT;
 249         }
 250         if(!onground)
 251                 s |= ANIMIMPLICITSTATE_INAIR;
 252
 253         // detect some kinds of otherwise misdetected jumps (ground to air transition)
 254         // NOTE: currently, in CSQC this is the only jump detection, as the explicit jump action is never called!
 255         if(!(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) && (s & ANIMIMPLICITSTATE_INAIR))
 256         {
 257                 e.anim_lower_implicit_action = ANIMACTION_JUMP;
 258                 e.anim_lower_implicit_time = time;
 259         }
 260
 261         if(s != e.anim_implicit_state)
 262         {
 263                 e.anim_implicit_state = s;
 264                 e.anim_implicit_time = time;
 265         }
 266 }
 267 void animdecide_setframes(entity e, float support_blending, .float fld_frame, .float fld_frame1time, .float fld_frame2, .float fld_frame2time)
 268 {
 269         // _x: frame
 270         // _y: start time
 271         // _z: priority
 272         vector upper = animdecide_getupperanim(e);
 273         vector lower = animdecide_getloweranim(e);
 274         //print("UPPER: ", vtos(upper), ", LOWER: ", vtos(lower), "\n");
 275         if(support_blending)
 276         {
 277                 if(upper_z && !lower_z)
 278                         lower = upper;
 279                 else if(lower_z && !upper_z)
 280                         upper = lower;
 281                 if(e.frame1time != upper_y || e.frame2time != lower_y)
 282                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 283                 e.fld_frame = upper_x;
 284                 e.fld_frame1time = upper_y;
 285                 e.fld_frame2 = lower_x;
 286                 e.fld_frame2time = lower_y;
 287         }
 288         else
 289         {
 290                 if(upper_z > lower_z)
 291                         lower = upper;
 292                 else if(lower_z > upper_z)
 293                         upper = lower;
 294                 if(e.frame1time != upper_y)
 295                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 296                 e.fld_frame = upper_x;
 297                 e.fld_frame1time = upper_y;
 298         }
 299 }
 300
 301 void animdecide_setstate(entity e, float newstate, float restart)
 302 {
 303         if(!restart)
 304                 if(newstate == e.anim_state)
 305                         return;
 306         e.anim_state = newstate;
 307         e.anim_time = time;
 308 }
 309 void animdecide_setaction(entity e, float action, float restart)
 310 {
 311         if(action < 0)
 312         {
 313                 if(!restart)
 314                         if(action == e.anim_lower_action)
 315                                 return;
 316                 e.anim_lower_action = action;
 317                 e.anim_lower_time = time;
 318         }
 319         else
 320         {
 321                 if(!restart)
 322                         if(action == e.anim_upper_action)
 323                                 return;
 324                 e.anim_upper_action = action;
 325                 e.anim_upper_time = time;
 326         }
 327 }