qcsrc/common/monsters/monster/mage.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ MAGE,
   4 /* function   */ m_mage,
   5 /* spawnflags */ 0,
   6 /* mins,maxs  */ '-36 -36 -24', '36 36 50',
   7 /* model      */ "mage.dpm",
   8 /* netname    */ "mage",
   9 /* fullname   */ _("Mage")
  10 );
  11
  12 #define MAGE_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_spike_damage) \
  15         MON_ADD_CVAR(monster, attack_spike_radius) \
  16         MON_ADD_CVAR(monster, attack_spike_delay) \
  17         MON_ADD_CVAR(monster, attack_spike_accel) \
  18         MON_ADD_CVAR(monster, attack_spike_decel) \
  19         MON_ADD_CVAR(monster, attack_spike_turnrate) \
  20         MON_ADD_CVAR(monster, attack_spike_speed_max) \
  21         MON_ADD_CVAR(monster, attack_spike_smart) \
  22         MON_ADD_CVAR(monster, attack_spike_smart_trace_min) \
  23         MON_ADD_CVAR(monster, attack_spike_smart_trace_max) \
  24         MON_ADD_CVAR(monster, attack_spike_smart_mindist) \
  25         MON_ADD_CVAR(monster, attack_melee_damage) \
  26         MON_ADD_CVAR(monster, attack_melee_delay) \
  27         MON_ADD_CVAR(monster, attack_grenade_damage) \
  28         MON_ADD_CVAR(monster, attack_grenade_edgedamage) \
  29         MON_ADD_CVAR(monster, attack_grenade_force) \
  30         MON_ADD_CVAR(monster, attack_grenade_radius) \
  31         MON_ADD_CVAR(monster, attack_grenade_lifetime) \
  32         MON_ADD_CVAR(monster, attack_grenade_chance) \
  33         MON_ADD_CVAR(monster, attack_grenade_speed) \
  34         MON_ADD_CVAR(monster, attack_grenade_speed_up) \
  35         MON_ADD_CVAR(monster, heal_self) \
  36         MON_ADD_CVAR(monster, heal_allies) \
  37         MON_ADD_CVAR(monster, heal_minhealth) \
  38         MON_ADD_CVAR(monster, heal_range) \
  39         MON_ADD_CVAR(monster, heal_delay) \
  40         MON_ADD_CVAR(monster, shield_time) \
  41         MON_ADD_CVAR(monster, shield_delay) \
  42         MON_ADD_CVAR(monster, shield_blockpercent) \
  43         MON_ADD_CVAR(monster, speed_stop) \
  44         MON_ADD_CVAR(monster, speed_run) \
  45         MON_ADD_CVAR(monster, speed_walk)
  46
  47 #ifdef SVQC
  48 MAGE_SETTINGS(mage)
  49 #endif // SVQC
  50 #else
  51 #ifdef SVQC
  52 const float mage_anim_idle              = 0;
  53 const float mage_anim_walk              = 1;
  54 const float mage_anim_attack    = 2;
  55 const float mage_anim_pain              = 3;
  56 const float mage_anim_death     = 4;
  57 const float mage_anim_run               = 5;
  58
  59 void() mage_heal;
  60 void() mage_shield;
  61 void() mage_shield_die;
  62
  63 float friend_needshelp(entity e)
  64 {
  65         if(e == world)
  66                 return FALSE;
  67         if(e.health <= 0)
  68                 return FALSE;
  69         if(vlen(e.origin - self.origin) > MON_CVAR(mage, heal_range))
  70                 return FALSE;
  71         if(IsDifferentTeam(e, self))
  72                 return FALSE;
  73         if(e.frozen)
  74                 return FALSE;
  75         if(!IS_PLAYER(e))
  76                 return (e.health < e.max_health);
  77         if(e.items & IT_INVINCIBLE)
  78                 return FALSE;
  79
  80         switch(self.skin)
  81         {
  82                 case 0: return (e.health < autocvar_g_balance_health_regenstable);
  83                 case 1: return ((e.ammo_cells && e.ammo_cells < g_pickup_cells_max) || (e.ammo_rockets && e.ammo_rockets < g_pickup_rockets_max) || (e.ammo_nails && e.ammo_nails < g_pickup_nails_max) || (e.ammo_shells && e.ammo_shells < g_pickup_shells_max));
  84                 case 2: return (e.armorvalue < autocvar_g_balance_armor_regenstable);
  85                 case 3: return (e.health > 0);
  86         }
  87
  88         return FALSE;
  89 }
  90
  91 void mageattack_melee()
  92 {
  93         monster_melee(self.enemy, MON_CVAR(mage, attack_melee_damage), 0.3, DEATH_MONSTER_MAGE, TRUE);
  94 }
  95
  96 void mage_grenade_explode()
  97 {
  98         pointparticles(particleeffectnum("explosion_small"), self.origin, '0 0 0', 1);
  99
 100         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 101         RadiusDamage (self, self.realowner, MON_CVAR(mage, attack_grenade_damage), MON_CVAR(mage, attack_grenade_edgedamage), MON_CVAR(mage, attack_grenade_radius), world, MON_CVAR(mage, attack_grenade_force), DEATH_MONSTER_MAGE, other);
 102         remove(self);
 103 }
 104
 105 void mage_grenade_touch()
 106 {
 107         if(IS_PLAYER(other))
 108         {
 109                 PROJECTILE_TOUCH;
 110                 mage_grenade_explode();
 111                 return;
 112         }
 113 }
 114
 115 void mage_throw_itemgrenade()
 116 {
 117         makevectors(self.angles);
 118
 119         entity gren = spawn ();
 120         gren.owner = gren.realowner = self;
 121         gren.classname = "grenade";
 122         gren.bot_dodge = FALSE;
 123         gren.movetype = MOVETYPE_BOUNCE;
 124         gren.solid = SOLID_TRIGGER;
 125         gren.projectiledeathtype = DEATH_MONSTER_MAGE;
 126         setorigin(gren, CENTER_OR_VIEWOFS(self));
 127         setsize(gren, '-64 -64 -64', '64 64 64');
 128
 129         gren.nextthink = time + MON_CVAR(mage, attack_grenade_lifetime);
 130         gren.think = mage_grenade_explode;
 131         gren.use = mage_grenade_explode;
 132         gren.touch = mage_grenade_touch;
 133
 134         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 135         W_SetupProjectileVelocityEx(gren, v_forward, v_up, MON_CVAR(mage, attack_grenade_speed), MON_CVAR(mage, attack_grenade_speed_up), 0, 0, FALSE);
 136
 137         gren.flags = FL_PROJECTILE;
 138
 139         setmodel(gren, "models/items/g_h50.md3");
 140
 141         self.attack_finished_single = time + 1.5;
 142 }
 143
 144 void mage_spike_explode()
 145 {
 146         self.event_damage = func_null;
 147
 148         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 149
 150         pointparticles(particleeffectnum("explosion_small"), self.origin, '0 0 0', 1);
 151         RadiusDamage (self, self.realowner, MON_CVAR(mage, attack_spike_damage), MON_CVAR(mage, attack_spike_damage) * 0.5, MON_CVAR(mage, attack_spike_radius), world, 0, DEATH_MONSTER_MAGE, other);
 152
 153         remove (self);
 154 }
 155
 156 void mage_spike_touch()
 157 {
 158         PROJECTILE_TOUCH;
 159
 160         mage_spike_explode();
 161 }
 162
 163 // copied from W_Seeker_Think
 164 void mage_spike_think()
 165 {
 166         entity e;
 167         vector desireddir, olddir, newdir, eorg;
 168         float turnrate;
 169         float dist;
 170         float spd;
 171
 172         if (time > self.ltime || self.enemy.health <= 0 || self.owner.health <= 0)
 173         {
 174                 self.projectiledeathtype |= HITTYPE_SPLASH;
 175                 mage_spike_explode();
 176         }
 177
 178         spd = vlen(self.velocity);
 179         spd = bound(
 180                 spd - MON_CVAR(mage, attack_spike_decel) * frametime,
 181                 MON_CVAR(mage, attack_spike_speed_max),
 182                 spd + MON_CVAR(mage, attack_spike_accel) * frametime
 183         );
 184
 185         if (self.enemy != world)
 186                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 187                         self.enemy = world;
 188
 189         if (self.enemy != world)
 190         {
 191                 e               = self.enemy;
 192                 eorg            = 0.5 * (e.absmin + e.absmax);
 193                 turnrate        = MON_CVAR(mage, attack_spike_turnrate); // how fast to turn
 194                 desireddir      = normalize(eorg - self.origin);
 195                 olddir          = normalize(self.velocity); // get my current direction
 196                 dist            = vlen(eorg - self.origin);
 197
 198                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 199                 if (MON_CVAR(mage, attack_spike_smart) && (dist > MON_CVAR(mage, attack_spike_smart_mindist)))
 200                 {
 201                         // Is it a better idea (shorter distance) to trace to the target itself?
 202                         if ( vlen(self.origin + olddir * self.wait) < dist)
 203                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 204                         else
 205                                 traceline(self.origin, eorg, FALSE, self);
 206
 207                         // Setup adaptive tracelength
 208                         self.wait = bound(MON_CVAR(mage, attack_spike_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = MON_CVAR(mage, attack_spike_smart_trace_max));
 209
 210                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 211                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 212                 }
 213
 214                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 215                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 216         }
 217         else
 218                 dist = 0;
 219
 220         ///////////////
 221
 222         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 223         self.nextthink = time;// + 0.05; // csqc projectiles
 224         UpdateCSQCProjectile(self);
 225 }
 226
 227 void mage_spike()
 228 {
 229         entity missile;
 230         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
 231
 232         makevectors(self.angles);
 233
 234         missile = spawn ();
 235         missile.owner = missile.realowner = self;
 236         missile.think = mage_spike_think;
 237         missile.ltime = time + 7;
 238         missile.nextthink = time;
 239         missile.solid = SOLID_BBOX;
 240         missile.movetype = MOVETYPE_FLYMISSILE;
 241         missile.flags = FL_PROJECTILE;
 242         setorigin(missile, self.origin + v_forward * 14 + '0 0 30' + v_right * -14);
 243         setsize (missile, '0 0 0', '0 0 0');
 244         missile.velocity = dir * 400;
 245         missile.avelocity = '300 300 300';
 246         missile.enemy = self.enemy;
 247         missile.touch = mage_spike_touch;
 248
 249         CSQCProjectile(missile, TRUE, PROJECTILE_MAGE_SPIKE, TRUE);
 250 }
 251
 252 void mage_heal()
 253 {
 254         entity head;
 255         float washealed = FALSE;
 256
 257         for(head = world; (head = findfloat(head, monster_attack, TRUE)); ) if(friend_needshelp(head))
 258         {
 259                 washealed = TRUE;
 260                 string fx = "";
 261                 if(IS_PLAYER(head))
 262                 {
 263                         switch(self.skin)
 264                         {
 265                                 case 0:
 266                                         if(head.health < autocvar_g_balance_health_regenstable) head.health = bound(0, head.health + MON_CVAR(mage, heal_allies), autocvar_g_balance_health_regenstable);
 267                                         fx = "healing_fx";
 268                                         break;
 269                                 case 1:
 270                                         if(head.ammo_cells) head.ammo_cells = bound(head.ammo_cells, head.ammo_cells + 1, g_pickup_cells_max);
 271                                         if(head.ammo_rockets) head.ammo_rockets = bound(head.ammo_rockets, head.ammo_rockets + 1, g_pickup_rockets_max);
 272                                         if(head.ammo_shells) head.ammo_shells = bound(head.ammo_shells, head.ammo_shells + 2, g_pickup_shells_max);
 273                                         if(head.ammo_nails) head.ammo_nails = bound(head.ammo_nails, head.ammo_nails + 5, g_pickup_nails_max);
 274                                         fx = "ammoregen_fx";
 275                                         break;
 276                                 case 2:
 277                                         if(head.armorvalue < autocvar_g_balance_armor_regenstable)
 278                                         {
 279                                                 head.armorvalue = bound(0, head.armorvalue + MON_CVAR(mage, heal_allies), autocvar_g_balance_armor_regenstable);
 280                                                 fx = "armorrepair_fx";
 281                                         }
 282                                         break;
 283                                 case 3:
 284                                         head.health = bound(0, head.health - ((head == self)  ? MON_CVAR(mage, heal_self) : MON_CVAR(mage, heal_allies)), autocvar_g_balance_health_regenstable);
 285                                         fx = "rage";
 286                                         break;
 287                         }
 288
 289                         pointparticles(particleeffectnum(fx), head.origin, '0 0 0', 1);
 290                 }
 291                 else
 292                 {
 293                         pointparticles(particleeffectnum("healing_fx"), head.origin, '0 0 0', 1);
 294                         head.health = bound(0, head.health + MON_CVAR(mage, heal_allies), head.max_health);
 295                         WaypointSprite_UpdateHealth(head.sprite, head.health);
 296                 }
 297         }
 298
 299         if(washealed)
 300         {
 301                 monsters_setframe(mage_anim_attack);
 302                 self.attack_finished_single = time + MON_CVAR(mage, heal_delay);
 303         }
 304 }
 305
 306 void mage_shield_die()
 307 {
 308         if not(self.weaponentity)
 309                 return; // why would this be called without a shield?
 310
 311         self.armorvalue = 1;
 312
 313         remove(self.weaponentity);
 314
 315         self.weaponentity = world;
 316 }
 317
 318 void mage_shield()
 319 {
 320         if(self.weaponentity)
 321                 return; // already have a shield
 322
 323         entity shield = spawn();
 324
 325         shield.owner = self;
 326         shield.team = self.team;
 327         shield.ltime = time + MON_CVAR(mage, shield_time);
 328         shield.health = 70;
 329         shield.classname = "shield";
 330         shield.effects = EF_ADDITIVE;
 331         shield.movetype = MOVETYPE_NOCLIP;
 332         shield.solid = SOLID_TRIGGER;
 333         shield.avelocity = '7 0 11';
 334         shield.scale = self.scale * 0.6;
 335
 336         setattachment(shield, self, "");
 337         setmodel(shield, "models/ctf/shield.md3");
 338         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 339
 340         self.weaponentity = shield;
 341
 342         self.lastshielded = time + MON_CVAR(mage, shield_delay);
 343
 344         monsters_setframe(mage_anim_attack);
 345         self.attack_finished_single = time + 1;
 346
 347         self.armorvalue = MON_CVAR(mage, shield_blockpercent) / 100;
 348 }
 349
 350 float mage_attack(float attack_type)
 351 {
 352         switch(attack_type)
 353         {
 354                 case MONSTER_ATTACK_MELEE:
 355                 {
 356                         monsters_setframe(mage_anim_attack);
 357                         self.attack_finished_single = time + MON_CVAR(mage, attack_melee_delay);
 358                         defer(0.2, mageattack_melee);
 359
 360                         return TRUE;
 361                 }
 362                 case MONSTER_ATTACK_RANGED:
 363                 {
 364                         if(random() < MON_CVAR(mage, attack_grenade_chance) / 100)
 365                         {
 366                                 mage_throw_itemgrenade();
 367                                 return TRUE;
 368                         }
 369
 370                         monsters_setframe(mage_anim_attack);
 371                         self.attack_finished_single = time + MON_CVAR(mage, attack_spike_delay);
 372                         defer(0.2, mage_spike);
 373
 374                         return TRUE;
 375                 }
 376         }
 377
 378         return FALSE;
 379 }
 380
 381 void spawnfunc_monster_mage()
 382 {
 383         self.classname = "monster_mage";
 384
 385         self.monster_spawnfunc = spawnfunc_monster_mage;
 386
 387         if(Monster_CheckAppearFlags(self))
 388                 return;
 389
 390         if not(monster_initialize(MON_MAGE, FALSE)) { remove(self); return; }
 391 }
 392
 393 // compatibility with old spawns
 394 void spawnfunc_monster_shalrath() { spawnfunc_monster_mage(); }
 395
 396 float m_mage(float req)
 397 {
 398         switch(req)
 399         {
 400                 case MR_THINK:
 401                 {
 402                         entity head;
 403                         float need_help = FALSE;
 404
 405                         FOR_EACH_PLAYER(head)
 406                         if(friend_needshelp(head))
 407                         {
 408                                 need_help = TRUE;
 409                                 break; // found 1 player near us who is low on health
 410                         }
 411                         if(!need_help)
 412                         FOR_EACH_MONSTER(head)
 413                         if(head != self)
 414                         if(friend_needshelp(head))
 415                         {
 416                                 need_help = TRUE;
 417                                 break; // found 1 player near us who is low on health
 418                         }
 419
 420                         if(self.weaponentity)
 421                         if(time >= self.weaponentity.ltime)
 422                                 mage_shield_die();
 423
 424                         if(self.health < MON_CVAR(mage, heal_minhealth) || need_help)
 425                         if(time >= self.attack_finished_single)
 426                         if(random() < 0.5)
 427                                 mage_heal();
 428
 429                         if(self.enemy)
 430                         if(self.health < self.max_health)
 431                         if(time >= self.lastshielded)
 432                         if(random() < 0.5)
 433                                 mage_shield();
 434
 435                         monster_move(MON_CVAR(mage, speed_run), MON_CVAR(mage, speed_walk), MON_CVAR(mage, speed_stop), mage_anim_walk, mage_anim_run, mage_anim_idle);
 436                         return TRUE;
 437                 }
 438                 case MR_DEATH:
 439                 {
 440                         monsters_setframe(mage_anim_death);
 441                         return TRUE;
 442                 }
 443                 case MR_SETUP:
 444                 {
 445                         if not(self.health) self.health = MON_CVAR(mage, health);
 446
 447                         self.monster_loot = spawnfunc_item_health_large;
 448                         self.monster_attackfunc = mage_attack;
 449                         monsters_setframe(mage_anim_walk);
 450
 451                         return TRUE;
 452                 }
 453                 case MR_INIT:
 454                 {
 455                         // nothing
 456                         return TRUE;
 457                 }
 458                 case MR_CONFIG:
 459                 {
 460                         MON_CONFIG_SETTINGS(MAGE_SETTINGS(mage))
 461                         return TRUE;
 462                 }
 463         }
 464
 465         return TRUE;
 466 }
 467
 468 #endif // SVQC
 469 #ifdef CSQC
 470 float m_mage(float req)
 471 {
 472         switch(req)
 473         {
 474                 case MR_DEATH:
 475                 {
 476                         // nothing
 477                         return TRUE;
 478                 }
 479                 case MR_INIT:
 480                 {
 481                         precache_model ("models/monsters/mage.dpm");
 482                         return TRUE;
 483                 }
 484         }
 485
 486         return TRUE;
 487 }
 488
 489 #endif // CSQC
 490 #endif // REGISTER_MONSTER