qcsrc/common/monsters/monster/spider.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SPIDER,
   4 /* functions  */ M_Spider, M_Spider_Attack,
   5 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-18 -18 -25', '18 18 30',
   7 /* model      */ "spider.dpm",
   8 /* netname    */ "spider",
   9 /* fullname   */ _("Spider")
  10 );
  11
  12 #else
  13 #ifdef SVQC
  14 float autocvar_g_monster_spider_health;
  15 float autocvar_g_monster_spider_damageforcescale = 0.6;
  16 float autocvar_g_monster_spider_attack_bite_damage;
  17 float autocvar_g_monster_spider_attack_bite_delay;
  18 float autocvar_g_monster_spider_attack_web_damagetime;
  19 float autocvar_g_monster_spider_attack_web_speed;
  20 float autocvar_g_monster_spider_attack_web_speed_up;
  21 float autocvar_g_monster_spider_attack_web_delay;
  22 float autocvar_g_monster_spider_speed_stop;
  23 float autocvar_g_monster_spider_speed_run;
  24 float autocvar_g_monster_spider_speed_walk;
  25
  26 /*
  27 const float spider_anim_idle            = 0;
  28 const float spider_anim_walk            = 1;
  29 const float spider_anim_attack          = 2;
  30 const float spider_anim_attack2         = 3;
  31 */
  32
  33 .float spider_web_delay;
  34
  35 void M_Spider_Attack_Web_Explode()
  36 {
  37         entity e;
  38         if(self)
  39         {
  40                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
  41                 RadiusDamage(self, self.realowner, 0, 0, 25, world, world, 25, self.projectiledeathtype, world);
  42
  43                 for(e = findradius(self.origin, 25); e; e = e.chain) if(e != self) if(e.takedamage && e.deadflag == DEAD_NO) if(e.health > 0) if(e.monsterid != self.realowner.monsterid)
  44                         e.spider_slowness = time + (autocvar_g_monster_spider_attack_web_damagetime);
  45
  46                 remove(self);
  47         }
  48 }
  49
  50 void M_Spider_Attack_Web_Touch()
  51 {
  52         PROJECTILE_TOUCH;
  53
  54         M_Spider_Attack_Web_Explode();
  55 }
  56
  57 void M_Spider_Attack_Web()
  58 {
  59         monster_makevectors(self.enemy);
  60
  61         sound(self, CH_SHOTS, "weapons/electro_fire2.wav", VOL_BASE, ATTEN_NORM);
  62
  63         entity proj = spawn ();
  64         proj.classname = "plasma";
  65         proj.owner = proj.realowner = self;
  66         proj.use = M_Spider_Attack_Web_Explode;
  67         proj.think = adaptor_think2use_hittype_splash;
  68         proj.bot_dodge = true;
  69         proj.bot_dodgerating = 0;
  70         proj.nextthink = time + 5;
  71         PROJECTILE_MAKETRIGGER(proj);
  72         proj.projectiledeathtype = DEATH_MONSTER_SPIDER;
  73         setorigin(proj, CENTER_OR_VIEWOFS(self));
  74
  75         //proj.glow_size = 50;
  76         //proj.glow_color = 45;
  77         proj.movetype = MOVETYPE_BOUNCE;
  78         W_SetupProjVelocity_Explicit(proj, v_forward, v_up, (autocvar_g_monster_spider_attack_web_speed), (autocvar_g_monster_spider_attack_web_speed_up), 0, 0, false);
  79         proj.touch = M_Spider_Attack_Web_Touch;
  80         setsize(proj, '-4 -4 -4', '4 4 4');
  81         proj.takedamage = DAMAGE_NO;
  82         proj.damageforcescale = 0;
  83         proj.health = 500;
  84         proj.event_damage = func_null;
  85         proj.flags = FL_PROJECTILE;
  86         proj.damagedbycontents = true;
  87
  88         proj.bouncefactor = 0.3;
  89         proj.bouncestop = 0.05;
  90         proj.missile_flags = MIF_SPLASH | MIF_ARC;
  91
  92         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, true);
  93 }
  94
  95 float M_Spider_Attack(float attack_type)
  96 {
  97         switch(attack_type)
  98         {
  99                 case MONSTER_ATTACK_MELEE:
 100                 {
 101                         return Monster_Attack_Melee(self.enemy, (autocvar_g_monster_spider_attack_bite_damage), ((random() > 0.5) ? self.anim_melee : self.anim_shoot), self.attack_range, (autocvar_g_monster_spider_attack_bite_delay), DEATH_MONSTER_SPIDER, true);
 102                 }
 103                 case MONSTER_ATTACK_RANGED:
 104                 {
 105                         if(time >= self.spider_web_delay)
 106                         {
 107                                 setanim(self, self.anim_shoot, true, true, true);
 108                                 self.attack_finished_single = time + (autocvar_g_monster_spider_attack_web_delay);
 109                                 self.anim_finished = time + 1;
 110                                 M_Spider_Attack_Web();
 111                                 self.spider_web_delay = time + 3;
 112                                 return true;
 113                         }
 114
 115                         return false;
 116                 }
 117         }
 118
 119         return false;
 120 }
 121
 122 void spawnfunc_monster_spider() { Monster_Spawn(MON_SPIDER); }
 123 #endif // SVQC
 124
 125 bool M_Spider(int req)
 126 {
 127         switch(req)
 128         {
 129                 #ifdef SVQC
 130                 case MR_THINK:
 131                 {
 132                         return true;
 133                 }
 134                 case MR_PAIN:
 135                 {
 136                         return true;
 137                 }
 138                 case MR_DEATH:
 139                 {
 140                         setanim(self, self.anim_melee, false, true, true);
 141                         self.angles_x = 180;
 142                         return true;
 143                 }
 144                 #endif
 145                 #ifndef MENUQC
 146                 case MR_ANIM:
 147                 {
 148                         vector none = '0 0 0';
 149                         self.anim_walk = animfixfps(self, '1 1 1', none);
 150                         self.anim_idle = animfixfps(self, '0 1 1', none);
 151                         self.anim_melee = animfixfps(self, '2 1 5', none); // analyze models and set framerate
 152                         self.anim_shoot = animfixfps(self, '3 1 5', none); // analyze models and set framerate
 153                         self.anim_run = animfixfps(self, '1 1 1', none);
 154
 155                         return true;
 156                 }
 157                 #endif
 158                 #ifdef SVQC
 159                 case MR_SETUP:
 160                 {
 161                         if(!self.health) self.health = (autocvar_g_monster_spider_health);
 162                         if(!self.speed) { self.speed = (autocvar_g_monster_spider_speed_walk); }
 163                         if(!self.speed2) { self.speed2 = (autocvar_g_monster_spider_speed_run); }
 164                         if(!self.stopspeed) { self.stopspeed = (autocvar_g_monster_spider_speed_stop); }
 165                         if(!self.damageforcescale) { self.damageforcescale = (autocvar_g_monster_spider_damageforcescale); }
 166
 167                         self.monster_loot = spawnfunc_item_health_medium;
 168
 169                         return true;
 170                 }
 171                 case MR_PRECACHE:
 172                 {
 173                         precache_model("models/monsters/spider.dpm");
 174                         precache_sound ("weapons/electro_fire2.wav");
 175                         return true;
 176                 }
 177                 #endif
 178         }
 179
 180         return true;
 181 }
 182
 183 #endif // REGISTER_MONSTER