qcsrc/common/monsters/monster/spider.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SPIDER,
   4 /* function   */ m_spider,
   5 /* spawnflags */ 0,
   6 /* mins,maxs  */ '-18 -18 -25', '18 18 30',
   7 /* model      */ "spider.dpm",
   8 /* netname    */ "spider",
   9 /* fullname   */ _("Spider")
  10 );
  11
  12 #define SPIDER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_bite_damage) \
  15         MON_ADD_CVAR(monster, attack_bite_delay) \
  16         MON_ADD_CVAR(monster, attack_web_damagetime) \
  17         MON_ADD_CVAR(monster, attack_web_speed) \
  18         MON_ADD_CVAR(monster, attack_web_speed_up) \
  19         MON_ADD_CVAR(monster, attack_web_delay) \
  20         MON_ADD_CVAR(monster, attack_type) \
  21         MON_ADD_CVAR(monster, speed_stop) \
  22         MON_ADD_CVAR(monster, speed_run) \
  23         MON_ADD_CVAR(monster, speed_walk)
  24
  25 #ifdef SVQC
  26 SPIDER_SETTINGS(spider)
  27 #endif // SVQC
  28 #else
  29 #ifdef SVQC
  30 const float spider_anim_idle            = 0;
  31 const float spider_anim_walk            = 1;
  32 const float spider_anim_attack          = 2;
  33 const float spider_anim_attack2         = 3;
  34
  35 .float spider_type; // used to switch between fire & ice attacks
  36 const float SPIDER_TYPE_ICE             = 0;
  37 const float SPIDER_TYPE_FIRE    = 1;
  38
  39 void spider_web_explode()
  40 {
  41         entity e;
  42         if(self)
  43         {
  44                 float damg = 0, edamg = 0, rad = 1;
  45                 switch(self.realowner.spider_type)
  46                 {
  47                         case SPIDER_TYPE_ICE:
  48                                 rad = 25;
  49                                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
  50                                 break;
  51                         case SPIDER_TYPE_FIRE:
  52                                 pointparticles(particleeffectnum("fireball_explode"), self.origin, '0 0 0', 1);
  53                                 damg = 15;
  54                                 rad = 25;
  55                                 edamg = 6;
  56                                 break;
  57                 }
  58
  59                 RadiusDamage(self, self.realowner, damg, edamg, 0, world, rad, DEATH_MONSTER_SPIDER_FIRE, world); // ice deals no damage anyway
  60
  61                 for(e = findradius(self.origin, rad); e; e = e.chain) if(e != self) if(e.takedamage && e.deadflag == DEAD_NO) if(e.health > 0)
  62                 {
  63                         switch(self.realowner.spider_type)
  64                         {
  65                                 case SPIDER_TYPE_ICE:
  66                                         Freeze(e, 0.3, 2, FALSE);
  67                                         break;
  68                                 case SPIDER_TYPE_FIRE:
  69                                         Fire_AddDamage(e, self.realowner, 5 * monster_skill, MON_CVAR(spider, attack_web_damagetime), DEATH_MONSTER_SPIDER_FIRE);
  70                                         break;
  71                         }
  72                 }
  73
  74                 remove(self);
  75         }
  76 }
  77
  78 void spider_web_touch()
  79 {
  80         PROJECTILE_TOUCH;
  81
  82         spider_web_explode();
  83 }
  84
  85 void spider_shootweb(float ptype)
  86 {
  87         float p = 0;
  88         string snd = "";
  89         switch(ptype)
  90         {
  91                 case SPIDER_TYPE_ICE:
  92                         p = PROJECTILE_ELECTRO;
  93                         snd = "weapons/electro_fire2.wav";
  94                         break;
  95                 case SPIDER_TYPE_FIRE:
  96                         p = PROJECTILE_FIREMINE;
  97                         snd = "weapons/fireball_fire.wav";
  98                         break;
  99         }
 100
 101         vector fmins = '-4 -4 -4', fmaxs = '4 4 4';
 102
 103         monster_makevectors(self.enemy);
 104
 105         sound(self, CH_SHOTS, snd, VOL_BASE, ATTEN_NORM);
 106
 107         entity proj = spawn ();
 108         proj.classname = "plasma";
 109         proj.owner = proj.realowner = self;
 110         proj.use = spider_web_touch;
 111         proj.think = adaptor_think2use_hittype_splash;
 112         proj.bot_dodge = TRUE;
 113         proj.bot_dodgerating = 0;
 114         proj.nextthink = time + 5;
 115         PROJECTILE_MAKETRIGGER(proj);
 116         proj.projectiledeathtype = DEATH_MONSTER_SPIDER_FIRE;
 117         setorigin(proj, CENTER_OR_VIEWOFS(self));
 118
 119         //proj.glow_size = 50;
 120         //proj.glow_color = 45;
 121         proj.movetype = MOVETYPE_BOUNCE;
 122         W_SetupProjectileVelocityEx(proj, v_forward, v_up, MON_CVAR(spider, attack_web_speed), MON_CVAR(spider, attack_web_speed_up), 0, 0, FALSE);
 123         proj.touch = spider_web_touch;
 124         setsize(proj, fmins, fmaxs);
 125         proj.takedamage = DAMAGE_NO;
 126         proj.damageforcescale = 0;
 127         proj.health = 500;
 128         proj.event_damage = func_null;
 129         proj.flags = FL_PROJECTILE;
 130         proj.damagedbycontents = TRUE;
 131
 132         proj.bouncefactor = 0.3;
 133         proj.bouncestop = 0.05;
 134         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 135
 136         CSQCProjectile(proj, TRUE, p, TRUE);
 137 }
 138
 139 float spider_attack(float attack_type)
 140 {
 141         switch(attack_type)
 142         {
 143                 case MONSTER_ATTACK_MELEE:
 144                 {
 145                         if(monster_melee(self.enemy, MON_CVAR(spider, attack_bite_damage), ((random() > 0.5) ? spider_anim_attack : spider_anim_attack2), self.attack_range, MON_CVAR(spider, attack_bite_delay), DEATH_MONSTER_SPIDER, TRUE))
 146                                 return TRUE;
 147
 148                         return FALSE;
 149                 }
 150                 case MONSTER_ATTACK_RANGED:
 151                 {
 152                         if(self.enemy.frozen)
 153                                 return FALSE;
 154
 155                         monsters_setframe(spider_anim_attack2);
 156                         self.attack_finished_single = time + MON_CVAR(spider, attack_web_delay);
 157                         spider_shootweb(self.spider_type);
 158
 159                         return TRUE;
 160                 }
 161         }
 162
 163         return FALSE;
 164 }
 165
 166 void spawnfunc_monster_spider()
 167 {
 168         self.classname = "monster_spider";
 169
 170         self.monster_spawnfunc = spawnfunc_monster_spider;
 171
 172         if(Monster_CheckAppearFlags(self))
 173                 return;
 174
 175         if not(monster_initialize(MON_SPIDER, FALSE)) { remove(self); return; }
 176 }
 177
 178 float m_spider(float req)
 179 {
 180         switch(req)
 181         {
 182                 case MR_THINK:
 183                 {
 184                         monster_move(MON_CVAR(spider, speed_run), MON_CVAR(spider, speed_walk), MON_CVAR(spider, speed_stop), spider_anim_walk, spider_anim_walk, spider_anim_idle);
 185                         return TRUE;
 186                 }
 187                 case MR_DEATH:
 188                 {
 189                         monsters_setframe(spider_anim_attack);
 190                         self.angles += '180 0 0';
 191                         self.SendFlags |= MSF_ANG;
 192                         return TRUE;
 193                 }
 194                 case MR_SETUP:
 195                 {
 196                         if not(self.health) self.health = MON_CVAR(spider, health);
 197                         if not(self.spider_type) self.spider_type = MON_CVAR(spider, attack_type);
 198
 199                         self.monster_loot = spawnfunc_item_health_medium;
 200                         self.monster_attackfunc = spider_attack;
 201                         monsters_setframe(spider_anim_idle);
 202
 203                         return TRUE;
 204                 }
 205                 case MR_INIT:
 206                 {
 207                         // nothing
 208                         return TRUE;
 209                 }
 210                 case MR_CONFIG:
 211                 {
 212                         MON_CONFIG_SETTINGS(SPIDER_SETTINGS(spider))
 213                         return TRUE;
 214                 }
 215         }
 216
 217         return TRUE;
 218 }
 219
 220 #endif // SVQC
 221 #ifdef CSQC
 222 float m_spider(float req)
 223 {
 224         switch(req)
 225         {
 226                 case MR_DEATH:
 227                 {
 228                         // nothing
 229                         return TRUE;
 230                 }
 231                 case MR_INIT:
 232                 {
 233                         precache_model ("models/monsters/spider.dpm");
 234                         return TRUE;
 235                 }
 236         }
 237
 238         return TRUE;
 239 }
 240
 241 #endif // CSQC
 242 #endif // REGISTER_MONSTER