qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(targ == ent)
  64                 return FALSE; // don't attack ourselves
  65
  66         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  67
  68         if(trace_ent != targ)
  69         {
  70                 if(trace_ent != world)
  71                         targ = trace_ent;
  72                 else
  73                         return FALSE;
  74         }
  75
  76         if(targ.vehicle_flags & VHF_ISVEHICLE)
  77         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  78                 return FALSE; // melee attacks are useless against vehicles
  79
  80         if(time < game_starttime)
  81                 return FALSE; // monsters do nothing before the match has started
  82
  83         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  84                 return FALSE; // enemy is too far away
  85
  86         if(targ.takedamage == DAMAGE_NO)
  87                 return FALSE; // enemy can't be damaged
  88
  89         if(targ.items & IT_INVISIBILITY)
  90                 return FALSE; // enemy is invisible
  91
  92         if(substring(targ.classname, 0, 10) == "onslaught_")
  93                 return FALSE; // don't attack onslaught targets
  94
  95         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  96                 return FALSE; // enemy is a spectator
  97
  98         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  99         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 100                 return FALSE; // enemy/self is dead
 101
 102         if(ent.monster_owner == targ)
 103                 return FALSE; // don't attack our master
 104
 105         if(targ.monster_owner == ent)
 106                 return FALSE; // don't attack our pet
 107
 108         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 109         if(targ.flags & FL_NOTARGET)
 110                 return FALSE; // enemy can't be targeted
 111
 112         if not(autocvar_g_monsters_typefrag)
 113         if(targ.BUTTON_CHAT)
 114                 return FALSE; // no typefragging!
 115
 116         if not(IsDifferentTeam(targ, ent))
 117                 return FALSE; // enemy is on our team
 118
 119         if(autocvar_g_monsters_target_infront)
 120         if(ent.enemy != targ)
 121         {
 122                 float dot;
 123
 124                 makevectors (ent.angles);
 125                 dot = normalize (targ.origin - ent.origin) * v_forward;
 126
 127                 if(dot <= 0.3)
 128                         return FALSE;
 129         }
 130
 131         return TRUE;
 132 }
 133
 134 entity FindTarget (entity ent)
 135 {
 136         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 137
 138         entity head, closest_target = world;
 139         head = findradius(ent.origin, ent.target_range);
 140
 141         while(head) // find the closest acceptable target to pass to
 142         {
 143                 if(monster_isvalidtarget(head, ent))
 144                 {
 145                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 146                         vector head_center = CENTER_OR_VIEWOFS(head);
 147                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 148
 149                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 150                         if(closest_target)
 151                         {
 152                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 153                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 154                                         { closest_target = head; }
 155                         }
 156                         else { closest_target = head; }
 157                 }
 158
 159                 head = head.chain;
 160         }
 161
 162         return closest_target;
 163 }
 164
 165 void MonsterTouch ()
 166 {
 167         if(other == world)
 168                 return;
 169
 170         if(self.enemy != other)
 171         if not(other.flags & FL_MONSTER)
 172         if(monster_isvalidtarget(other, self))
 173                 self.enemy = other;
 174 }
 175
 176 void monster_sound(string msound, float sound_delay, float delaytoo)
 177 {
 178         if(delaytoo && time < self.msound_delay)
 179                 return; // too early
 180
 181         if(msound == "")
 182                 return; // sound doesn't exist
 183
 184         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTEN_NORM);
 185
 186         self.msound_delay = time + sound_delay;
 187 }
 188
 189 void monster_precachesounds(entity e)
 190 {
 191         precache_sound(e.msound_idle);
 192         precache_sound(e.msound_death);
 193         precache_sound(e.msound_attack_melee);
 194         precache_sound(e.msound_attack_ranged);
 195         precache_sound(e.msound_sight);
 196         precache_sound(e.msound_pain);
 197 }
 198
 199 void monster_setupsounds(string mon)
 200 {
 201         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 202         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 203         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 204         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 205         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 206         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 207 }
 208
 209 void monster_makevectors(entity e)
 210 {
 211         vector v;
 212
 213         v = CENTER_OR_VIEWOFS(e);
 214         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 215         self.v_angle_x = -self.v_angle_x;
 216
 217         makevectors(self.v_angle);
 218 }
 219
 220 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 221 {
 222         float rdmg = damg * random();
 223
 224         if (self.health <= 0)
 225                 return FALSE; // attacking while dead?!
 226
 227         if(dostop)
 228         {
 229                 self.velocity_x = 0;
 230                 self.velocity_y = 0;
 231                 self.state = MONSTER_STATE_ATTACK_MELEE;
 232                 self.SendFlags |= MSF_MOVE;
 233         }
 234
 235         monsters_setframe(anim);
 236
 237         if(anim_finished != 0)
 238                 self.attack_finished_single = time + anim_finished;
 239
 240         monster_makevectors(targ);
 241
 242         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 243
 244         if(trace_ent.takedamage)
 245                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 246
 247         return TRUE;
 248 }
 249
 250 void Monster_CheckMinibossFlag ()
 251 {
 252         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 253                 return;
 254
 255         float chance = random() * 100;
 256
 257         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 258         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 259         {
 260                 self.health += autocvar_g_monsters_miniboss_healthboost;
 261                 if not(self.weapon)
 262                         self.weapon = WEP_NEX;
 263         }
 264 }
 265
 266 float Monster_CanRespawn(entity ent)
 267 {
 268         other = ent;
 269         if(MUTATOR_CALLHOOK(MonsterRespawn))
 270                 return TRUE; // enabled by a mutator
 271
 272         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 273                 return FALSE;
 274
 275         if not(autocvar_g_monsters_respawn)
 276                 return FALSE;
 277
 278         return TRUE;
 279 }
 280
 281 void Monster_Fade ()
 282 {
 283         if(Monster_CanRespawn(self))
 284         {
 285                 self.monster_respawned = TRUE;
 286                 self.think = self.monster_spawnfunc;
 287                 self.nextthink = time + self.respawntime;
 288                 self.deadflag = DEAD_RESPAWNING;
 289                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 290                 {
 291                         self.pos1 = self.origin;
 292                         self.pos2 = self.angles;
 293                 }
 294                 self.event_damage = func_null;
 295                 self.takedamage = DAMAGE_NO;
 296                 setorigin(self, self.pos1);
 297                 self.angles = self.pos2;
 298                 self.health = self.max_health;
 299
 300                 self.SendFlags |= MSF_MOVE;
 301                 self.SendFlags |= MSF_STATUS;
 302         }
 303         else
 304                 SUB_SetFade(self, time + 3, 1);
 305 }
 306
 307 float Monster_CanJump (vector vel)
 308 {
 309         if(self.state)
 310                 return FALSE; // already attacking
 311         if not(self.flags & FL_ONGROUND)
 312                 return FALSE; // not on the ground
 313         if(self.health <= 0)
 314                 return FALSE; // called when dead?
 315         if(time < self.attack_finished_single)
 316                 return FALSE; // still attacking
 317
 318         vector old = self.velocity;
 319
 320         self.velocity = vel;
 321         tracetoss(self, self);
 322         self.velocity = old;
 323         if (trace_ent != self.enemy)
 324                 return FALSE;
 325
 326         return TRUE;
 327 }
 328
 329 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 330 {
 331         if(!Monster_CanJump(vel))
 332                 return FALSE;
 333
 334         monsters_setframe(anm);
 335         self.state = MONSTER_STATE_ATTACK_LEAP;
 336         self.touch = touchfunc;
 337         self.origin_z += 1;
 338         self.velocity = vel;
 339         self.flags &= ~FL_ONGROUND;
 340
 341         self.attack_finished_single = time + anim_finished;
 342
 343         return TRUE;
 344 }
 345
 346 void monster_checkattack(entity e, entity targ)
 347 {
 348         if(e == world)
 349                 return;
 350         if(targ == world)
 351                 return;
 352
 353         if not(e.monster_attackfunc)
 354                 return;
 355
 356         if(time < e.attack_finished_single)
 357                 return;
 358
 359         if(vlen(targ.origin - e.origin) <= e.attack_range)
 360         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 361         {
 362                 monster_sound(e.msound_attack_melee, 0, FALSE);
 363                 return;
 364         }
 365
 366         if(vlen(targ.origin - e.origin) > e.attack_range)
 367         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 368         {
 369                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 370                 return;
 371         }
 372 }
 373
 374 void monster_use ()
 375 {
 376         if (self.enemy)
 377                 return;
 378         if (self.health <= 0)
 379                 return;
 380
 381         if(!monster_isvalidtarget(activator, self))
 382                 return;
 383
 384         self.enemy = activator;
 385 }
 386
 387 .float last_trace;
 388 .float last_enemycheck; // for checking enemy
 389 vector monster_pickmovetarget(entity targ)
 390 {
 391         // enemy is always preferred target
 392         if(self.enemy)
 393         {
 394                 makevectors(self.angles);
 395                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 396                 self.last_trace = time + 1.2;
 397                 return self.enemy.origin * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 398         }
 399
 400         switch(self.monster_moveflags)
 401         {
 402                 case MONSTER_MOVE_OWNER:
 403                 {
 404                         self.monster_movestate = MONSTER_MOVE_OWNER;
 405                         self.last_trace = time + 0.3;
 406                         if(self.monster_owner && self.monster_owner.classname != "td_spawnpoint")
 407                                 return self.monster_owner.origin;
 408                 }
 409                 case MONSTER_MOVE_SPAWNLOC:
 410                 {
 411                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 412                         self.last_trace = time + 2;
 413                         return self.pos1;
 414                 }
 415                 case MONSTER_MOVE_NOMOVE:
 416                 {
 417                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 418                         self.last_trace = time + 2;
 419                         return self.origin;
 420                 }
 421                 default:
 422                 case MONSTER_MOVE_WANDER:
 423                 {
 424                         vector pos;
 425                         self.monster_movestate = MONSTER_MOVE_WANDER;
 426                         self.last_trace = time + 2;
 427
 428                         self.angles_y = random() * 500;
 429                         makevectors(self.angles);
 430                         pos = self.origin + v_forward * 600;
 431
 432                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 433                         {
 434                                 pos_z = random() * 200;
 435                                 if(random() >= 0.5)
 436                                         pos_z *= -1;
 437                         }
 438
 439                         if(targ)
 440                         {
 441                                 self.last_trace = time + 0.5;
 442                                 pos = targ.origin;
 443                         }
 444
 445                         return pos;
 446                 }
 447         }
 448 }
 449
 450 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 451 {
 452         fixedmakevectors(self.angles);
 453
 454         if(self.target2)
 455                 self.goalentity = find(world, targetname, self.target2);
 456
 457         entity targ;
 458
 459         if(self.frozen)
 460         {
 461                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 462                 self.health = max(1, self.max_health * self.revive_progress);
 463
 464                 self.SendFlags |= MSF_STATUS;
 465
 466                 movelib_beak_simple(stopspeed);
 467
 468                 self.velocity = '0 0 0';
 469                 self.enemy = world;
 470                 self.nextthink = time + 0.1;
 471
 472                 if(self.revive_progress >= 1)
 473                         Unfreeze(self); // wait for next think before attacking
 474
 475                 // don't bother updating angles here?
 476                 if(self.origin != self.oldorigin)
 477                 {
 478                         self.oldorigin = self.origin;
 479                         self.SendFlags |= MSF_MOVE;
 480                 }
 481
 482                 return; // no moving while frozen
 483         }
 484
 485         if(self.flags & FL_SWIM)
 486         {
 487                 if(self.waterlevel < WATERLEVEL_WETFEET)
 488                 {
 489                         if(time >= self.last_trace)
 490                         {
 491                                 self.last_trace = time + 0.4;
 492
 493                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 494                                 self.angles = '90 90 0';
 495                                 if(random() < 0.5)
 496                                 {
 497                                         self.velocity_y += random() * 50;
 498                                         self.velocity_x -= random() * 50;
 499                                 }
 500                                 else
 501                                 {
 502                                         self.velocity_y -= random() * 50;
 503                                         self.velocity_x += random() * 50;
 504                                 }
 505                                 self.velocity_z += random() * 150;
 506                         }
 507
 508
 509                         self.movetype = MOVETYPE_BOUNCE;
 510                         //self.velocity_z = -200;
 511
 512                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 513
 514                         return;
 515                 }
 516                 else
 517                 {
 518                         self.angles = '0 0 0';
 519                         self.movetype = MOVETYPE_WALK;
 520                 }
 521         }
 522
 523         targ = self.goalentity;
 524
 525         monster_target = targ;
 526         monster_speed_run = runspeed;
 527         monster_speed_walk = walkspeed;
 528
 529         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 530         {
 531                 runspeed = walkspeed = 0;
 532                 if(time >= self.spawn_time)
 533                         monsters_setframe(manim_idle);
 534                 movelib_beak_simple(stopspeed);
 535                 self.SendFlags |= MSF_MOVE;
 536                 return;
 537         }
 538
 539         targ = monster_target;
 540         runspeed = monster_speed_run;
 541         walkspeed = monster_speed_walk;
 542
 543         if(teamplay)
 544         if(autocvar_g_monsters_teams)
 545         if(IsDifferentTeam(self.monster_owner, self))
 546                 self.monster_owner = world;
 547
 548         if(self.enemy && self.enemy.health < 1)
 549                 self.enemy = world; // enough!
 550
 551         if(time >= self.last_enemycheck)
 552         {
 553                 if not(monster_isvalidtarget(self.enemy, self))
 554                         self.enemy = world;
 555
 556                 if not(self.enemy)
 557                 {
 558                         self.enemy = FindTarget(self);
 559                         if(self.enemy)
 560                                 monster_sound(self.msound_sight, 0, FALSE);
 561                 }
 562
 563                 self.last_enemycheck = time + 2;
 564         }
 565
 566         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 567                 self.state = 0;
 568
 569         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 570         if(time >= self.last_trace || self.enemy) // update enemy instantly
 571                 self.moveto = monster_pickmovetarget(targ);
 572
 573         if not(self.enemy)
 574                 monster_sound(self.msound_idle, 5, TRUE);
 575
 576         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 577                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 578
 579         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 580         {
 581                 self.state = 0;
 582                 self.touch = MonsterTouch;
 583         }
 584
 585         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 586
 587         float turny = 0;
 588         vector real_angle = vectoangles(self.steerto) - self.angles;
 589
 590         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 591                 turny = 20;
 592
 593         if(self.flags & FL_SWIM)
 594                 turny = vlen(self.angles - self.moveto);
 595
 596         if(turny)
 597         {
 598                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 599                 self.angles_y += turny;
 600         }
 601
 602         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 603                 self.moveto = self.origin;
 604
 605         if(self.enemy && self.enemy.vehicle)
 606                 runspeed = 0;
 607
 608         if not(self.flags & FL_FLY || self.flags & FL_SWIM)
 609                 self.moveto_z = self.origin_z;
 610
 611         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 612                 v_forward = normalize(self.moveto - self.origin);
 613
 614         if(vlen(self.origin - self.moveto) > 64)
 615         {
 616                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 617                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 618                 else
 619                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 620                 if(time > self.pain_finished)
 621                 if(time > self.attack_finished_single)
 622                 if(vlen(self.velocity) > 0)
 623                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 624                 else
 625                         monsters_setframe(manim_idle);
 626         }
 627         else
 628         {
 629                 entity e = find(world, targetname, self.target2);
 630                 if(e.target2)
 631                         self.target2 = e.target2;
 632                 else if(e.target)
 633                         self.target2 = e.target;
 634
 635                 movelib_beak_simple(stopspeed);
 636                 if(time > self.attack_finished_single)
 637                 if(time > self.pain_finished)
 638                 if (vlen(self.velocity) <= 30)
 639                         monsters_setframe(manim_idle);
 640         }
 641
 642         monster_checkattack(self, self.enemy);
 643
 644         if(self.angles != self.oldangles)
 645         {
 646                 self.oldangles = self.angles;
 647                 self.SendFlags |= MSF_ANG;
 648         }
 649
 650         if(self.origin != self.oldorigin)
 651         {
 652                 self.oldorigin = self.origin;
 653                 self.SendFlags |= MSF_MOVE;
 654         }
 655 }
 656
 657 void monster_dead_think()
 658 {
 659         self.think = monster_dead_think;
 660         self.nextthink = time + 0.3; // don't need to update so often now
 661
 662         self.deadflag = DEAD_DEAD;
 663
 664         if(time >= self.ltime)
 665         {
 666                 Monster_Fade();
 667                 return;
 668         }
 669
 670         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 671 }
 672
 673 void monsters_setstatus()
 674 {
 675         self.stat_monsters_total = monsters_total;
 676         self.stat_monsters_killed = monsters_killed;
 677 }
 678
 679 void Monster_Appear()
 680 {
 681         self.enemy = activator;
 682         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 683         self.monster_spawnfunc();
 684 }
 685
 686 float Monster_CheckAppearFlags(entity ent)
 687 {
 688         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 689                 return FALSE;
 690
 691         ent.think = func_null;
 692         ent.nextthink = 0;
 693         ent.use = Monster_Appear;
 694         ent.flags = FL_MONSTER; // set so this monster can get butchered
 695
 696         return TRUE;
 697 }
 698
 699 void monsters_reset()
 700 {
 701         setorigin(self, self.pos1);
 702         self.angles = self.pos2;
 703
 704         self.health = self.max_health;
 705         self.velocity = '0 0 0';
 706         self.enemy = world;
 707         self.goalentity = world;
 708         self.attack_finished_single = 0;
 709         self.moveto = self.origin;
 710
 711         self.SendFlags |= MSF_STATUS;
 712 }
 713
 714 float monster_send(entity to, float sf)
 715 {
 716         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 717         WriteByte(MSG_ENTITY, sf);
 718         if(sf & MSF_SETUP)
 719         {
 720             WriteByte(MSG_ENTITY, self.monsterid);
 721
 722             WriteCoord(MSG_ENTITY, self.origin_x);
 723             WriteCoord(MSG_ENTITY, self.origin_y);
 724             WriteCoord(MSG_ENTITY, self.origin_z);
 725
 726             WriteAngle(MSG_ENTITY, self.angles_x);
 727             WriteAngle(MSG_ENTITY, self.angles_y);
 728
 729                 WriteByte(MSG_ENTITY, self.skin);
 730                 WriteByte(MSG_ENTITY, self.team);
 731     }
 732
 733     if(sf & MSF_ANG)
 734     {
 735         WriteShort(MSG_ENTITY, rint(self.angles_x));
 736         WriteShort(MSG_ENTITY, rint(self.angles_y));
 737     }
 738
 739     if(sf & MSF_MOVE)
 740     {
 741         WriteShort(MSG_ENTITY, rint(self.origin_x));
 742         WriteShort(MSG_ENTITY, rint(self.origin_y));
 743         WriteShort(MSG_ENTITY, rint(self.origin_z));
 744
 745         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 746         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 747         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 748
 749         WriteShort(MSG_ENTITY, rint(self.angles_y));
 750     }
 751
 752     if(sf & MSF_ANIM)
 753     {
 754         WriteCoord(MSG_ENTITY, self.anim_start_time);
 755         WriteByte(MSG_ENTITY, self.frame);
 756     }
 757
 758     if(sf & MSF_STATUS)
 759     {
 760                 WriteByte(MSG_ENTITY, self.skin);
 761
 762         WriteByte(MSG_ENTITY, self.team);
 763
 764                 WriteByte(MSG_ENTITY, self.deadflag);
 765
 766         if(self.health <= 0)
 767             WriteByte(MSG_ENTITY, 0);
 768         else
 769             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 770     }
 771
 772         return TRUE;
 773 }
 774
 775 void monster_link(void() spawnproc)
 776 {
 777     Net_LinkEntity(self, TRUE, 0, monster_send);
 778     self.think      = spawnproc;
 779     self.nextthink  = time;
 780 }
 781
 782 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 783 {
 784         self.health -= damage;
 785
 786         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 787
 788         if(self.health <= -100) // 100 health until gone?
 789         {
 790                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 791
 792                 self.think = SUB_Remove;
 793                 self.nextthink = time + 0.1;
 794         }
 795 }
 796
 797 void monster_die()
 798 {
 799         self.think = monster_dead_think;
 800         self.nextthink = self.ticrate;
 801         self.ltime = time + 5;
 802
 803         monster_dropitem();
 804
 805         if(self.weaponentity)
 806         {
 807                 remove(self.weaponentity);
 808                 self.weaponentity = world;
 809         }
 810
 811         monster_sound(self.msound_death, 0, FALSE);
 812
 813         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 814                 monsters_killed += 1;
 815
 816         if(self.candrop && self.weapon)
 817                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 818
 819         if(IS_CLIENT(self.realowner))
 820                 self.realowner.monstercount -= 1;
 821
 822         self.event_damage       = monsters_corpse_damage;
 823         self.solid                      = SOLID_CORPSE;
 824         self.takedamage         = DAMAGE_AIM;
 825         self.enemy                      = world;
 826         self.movetype           = MOVETYPE_TOSS;
 827         self.moveto                     = self.origin;
 828         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 829
 830         if not(self.flags & FL_FLY)
 831                 self.velocity = '0 0 0';
 832
 833         self.SendFlags |= MSF_MOVE;
 834
 835         // number of monsters spawned with mobspawn command
 836         totalspawned -= 1;
 837
 838         MON_ACTION(self.monsterid, MR_DEATH);
 839 }
 840
 841 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 842 {
 843         if(self.frozen && deathtype != DEATH_KILL)
 844                 return;
 845
 846         if(time < self.pain_finished && deathtype != DEATH_KILL)
 847                 return;
 848
 849         if(time < self.spawnshieldtime)
 850                 return;
 851
 852         if(deathtype != DEATH_KILL)
 853                 damage *= self.armorvalue;
 854
 855         if(self.weaponentity && self.weaponentity.classname == "shield")
 856                 self.weaponentity.health -= damage;
 857
 858         self.health -= damage;
 859
 860         self.dmg_time = time;
 861
 862         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 863                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 864
 865         self.velocity += force * self.damageforcescale;
 866
 867         if(deathtype != DEATH_DROWN)
 868         {
 869                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 870                 if (damage > 50)
 871                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 872                 if (damage > 100)
 873                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 874         }
 875
 876         if(self.health <= 0)
 877         {
 878                 if(deathtype == DEATH_KILL)
 879                         self.candrop = FALSE; // killed by mobkill command
 880
 881                 // TODO: fix this?
 882                 activator = attacker;
 883                 other = self.enemy;
 884                 SUB_UseTargets();
 885                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 886
 887                 monster_die();
 888
 889                 frag_attacker = attacker;
 890                 frag_target = self;
 891                 MUTATOR_CALLHOOK(MonsterDies);
 892
 893                 if(self.health <= -100) // check if we're already gibbed
 894                 {
 895                         Violence_GibSplash(self, 1, 0.5, attacker);
 896
 897                         self.think = SUB_Remove;
 898                         self.nextthink = time + 0.1;
 899                 }
 900         }
 901
 902         self.SendFlags |= MSF_STATUS;
 903 }
 904
 905 void monster_think()
 906 {
 907         self.think = monster_think;
 908         self.nextthink = self.ticrate;
 909
 910         MON_ACTION(self.monsterid, MR_THINK);
 911 }
 912
 913 void monster_spawn()
 914 {
 915         MON_ACTION(self.monsterid, MR_SETUP);
 916
 917         if not(self.monster_respawned)
 918                 Monster_CheckMinibossFlag();
 919
 920         self.max_health = self.health;
 921         self.pain_finished = self.nextthink;
 922         self.anim_start_time = time;
 923
 924         if not(self.noalign)
 925         {
 926                 setorigin(self, self.origin + '0 0 20');
 927                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 928                 setorigin(self, trace_endpos);
 929         }
 930
 931         if not(self.monster_respawned)
 932         if not(self.skin)
 933                 self.skin = rint(random() * 4);
 934
 935         if not(self.attack_range)
 936                 self.attack_range = autocvar_g_monsters_attack_range;
 937
 938         self.pos1 = self.origin;
 939
 940         monster_setupsounds(self.netname);
 941
 942         monster_precachesounds(self);
 943
 944         if(teamplay)
 945                 self.monster_attack = TRUE; // we can have monster enemies in team games
 946
 947         monster_sound(self.msound_spawn, 0, FALSE);
 948
 949         MUTATOR_CALLHOOK(MonsterSpawn);
 950
 951         self.think = monster_think;
 952         self.nextthink = time + self.ticrate;
 953
 954         self.SendFlags |= MSF_SETUP;
 955 }
 956
 957 float monster_initialize(float mon_id, float nodrop)
 958 {
 959         if not(autocvar_g_monsters)
 960                 return FALSE;
 961
 962         vector min_s, max_s;
 963         entity mon = get_monsterinfo(mon_id);
 964
 965         // support for quake style removing monsters based on skill
 966         switch(monster_skill)
 967         {
 968                 case 1: if(self.spawnflags & MONSTERSKILL_NOTEASY)              return FALSE; break;
 969                 case 2: if(self.spawnflags & MONSTERSKILL_NOTMEDIUM)    return FALSE; break;
 970                 case 3: if(self.spawnflags & MONSTERSKILL_NOTHARD)              return FALSE; break;
 971                 case 4: if(self.spawnflags & MONSTERSKILL_NOTINSANE)    return FALSE; break;
 972                 case 5: if(self.spawnflags & MONSTERSKILL_NOTNIGHTMARE) return FALSE; break;
 973         }
 974
 975         if(self.monster_name == "")
 976                 self.monster_name = M_NAME(mon_id);
 977
 978         if(self.team && !teamplay)
 979                 self.team = 0;
 980
 981         self.flags = FL_MONSTER;
 982
 983         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 984         if not(self.monster_respawned)
 985                 monsters_total += 1;
 986
 987         min_s = mon.mins;
 988         max_s = mon.maxs;
 989
 990         self.netname = mon.netname;
 991
 992         setsize(self, min_s, max_s);
 993         self.takedamage                 = DAMAGE_AIM;
 994         self.bot_attack                 = TRUE;
 995         self.iscreature                 = TRUE;
 996         self.teleportable               = TRUE;
 997         self.damagedbycontents  = TRUE;
 998         self.monsterid                  = mon_id;
 999         self.damageforcescale   = 0;
1000         self.event_damage               = monsters_damage;
1001         self.touch                              = MonsterTouch;
1002         self.use                                = monster_use;
1003         self.solid                              = SOLID_BBOX;
1004         self.movetype                   = MOVETYPE_WALK;
1005         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1006         monsters_spawned           += 1;
1007         self.enemy                              = world;
1008         self.velocity                   = '0 0 0';
1009         self.moveto                             = self.origin;
1010         self.pos2                               = self.angles;
1011         self.reset                              = monsters_reset;
1012         self.candrop                    = TRUE;
1013         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1014         self.oldtarget2                 = self.target2;
1015         self.deadflag                   = DEAD_NO;
1016         self.noalign                    = nodrop;
1017         self.spawn_time                 = time;
1018         self.gravity                    = 1;
1019         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1020
1021         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1022                 self.flags |= FL_SWIM;
1023
1024         if(mon.spawnflags & MONSTER_TYPE_FLY)
1025         {
1026                 self.flags |= FL_FLY;
1027                 self.movetype = MOVETYPE_FLY;
1028         }
1029
1030         if not(self.scale)
1031                 self.scale = 1;
1032
1033         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1034                 self.scale = 1.3;
1035
1036         if not(self.ticrate)
1037                 self.ticrate = autocvar_g_monsters_think_delay;
1038
1039         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1040
1041         if not(self.armorvalue)
1042                 self.armorvalue = 1; // multiplier
1043
1044         if not(self.target_range)
1045                 self.target_range = autocvar_g_monsters_target_range;
1046
1047         if not(self.respawntime)
1048                 self.respawntime = autocvar_g_monsters_respawn_delay;
1049
1050         if not(self.monster_moveflags)
1051                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1052
1053         monster_link(monster_spawn);
1054
1055         return TRUE;
1056 }