qcsrc/common/notifications.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "constants.qh"
   7     #include "teams.qh"
   8     #include "counting.qh"
   9     #include "../server/autocvars.qh"
  10     #include "../server/constants.qh"
  11     #include "../server/defs.qh"
  12     #include "notifications.qh"
  13     #include "../server/mutators/mutators_include.qh"
  14 #endif
  15
  16 // ================================================
  17 //  Unified notification system, written by Samual
  18 //  Last updated: August, 2013
  19 // ================================================
  20
  21 string Get_Notif_TypeName(int net_type)
  22 {
  23         switch(net_type)
  24         {
  25                 case MSG_ANNCE: return "MSG_ANNCE";
  26                 case MSG_INFO: return "MSG_INFO";
  27                 case MSG_CENTER: return "MSG_CENTER";
  28                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
  29                 case MSG_MULTI: return "MSG_MULTI";
  30                 case MSG_CHOICE: return "MSG_CHOICE";
  31         }
  32         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
  33         return "";
  34 }
  35
  36 entity Get_Notif_Ent(int net_type, int net_name)
  37 {
  38         switch(net_type)
  39         {
  40                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
  41                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  42                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  43                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
  44                 case MSG_CHOICE: return msg_choice_notifs[net_name - 1];
  45         }
  46         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  47         return world;
  48 }
  49
  50 #ifdef SVQC
  51 #ifdef NOTIFICATIONS_DEBUG
  52 string Get_Notif_BroadcastName(float broadcast)
  53 {
  54         switch(broadcast)
  55         {
  56                 case NOTIF_ONE: return "NOTIF_ONE";
  57                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
  58                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
  59                 case NOTIF_ALL: return "NOTIF_ALL";
  60                 case NOTIF_TEAM: return "NOTIF_TEAM";
  61                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
  62         }
  63         backtrace(sprintf("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast));
  64         return "";
  65 }
  66 #endif
  67 #endif
  68
  69 string Notification_CheckArgs_TypeName(float net_type, float net_name)
  70 {
  71         // check supplied type and name for errors
  72         string checkargs = "";
  73         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
  74                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
  75                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
  76         switch(net_type)
  77         {
  78                 CHECKARG_TYPENAME(ANNCE)
  79                 CHECKARG_TYPENAME(INFO)
  80                 CHECKARG_TYPENAME(CENTER)
  81                 CHECKARG_TYPENAME(MULTI)
  82                 CHECKARG_TYPENAME(CHOICE)
  83                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
  84         }
  85         #undef CHECKARG_TYPENAME
  86         return checkargs;
  87 }
  88
  89 #ifdef SVQC
  90 string Notification_CheckArgs(
  91         float broadcast, entity client,
  92         float net_type, float net_name)
  93 {
  94         // check supplied broadcast, target, type, and name for errors
  95         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
  96         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
  97         switch(broadcast)
  98         {
  99                 case NOTIF_ONE:
 100                 case NOTIF_ONE_ONLY:
 101                 {
 102                         if(IS_NOT_A_CLIENT(client))
 103                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
 104                         break;
 105                 }
 106
 107                 case NOTIF_ALL_EXCEPT:
 108                 {
 109                         if(IS_NOT_A_CLIENT(client))
 110                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 111                         break;
 112                 }
 113
 114                 case NOTIF_ALL:
 115                 {
 116                         if(client)
 117                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
 118                         break;
 119                 }
 120
 121                 case NOTIF_TEAM:
 122                 {
 123                         if (!teamplay)
 124                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 125                         //else if (!client.team) { checkargs = sprintf("%sNo team provided!", checkargs); }
 126                         break;
 127                 }
 128
 129                 case NOTIF_TEAM_EXCEPT:
 130                 {
 131                         if (!teamplay)
 132                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 133                         else if(IS_NOT_A_CLIENT(client))
 134                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 135                         break;
 136                 }
 137
 138                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 139         }
 140         return checkargs;
 141 }
 142
 143 float Notification_ShouldSend(float broadcast, entity to_client, entity other_client)
 144 {
 145         switch(broadcast)
 146         {
 147                 case NOTIF_ONE: // send to one client and their spectator
 148                 {
 149                         if(
 150                                 (to_client == other_client)
 151                                 ||
 152                                 (
 153                                         IS_SPEC(to_client)
 154                                         &&
 155                                         (to_client.enemy == other_client)
 156                                 )
 157                         ) { return true; }
 158                         break;
 159                 }
 160                 case NOTIF_ONE_ONLY: // send ONLY to one client
 161                 {
 162                         if(to_client == other_client) { return true; }
 163                         break;
 164                 }
 165                 case NOTIF_TEAM: // send only to X team and their spectators
 166                 {
 167                         if(
 168                                 (to_client.team == other_client.team)
 169                                 ||
 170                                 (
 171                                         IS_SPEC(to_client)
 172                                         &&
 173                                         (to_client.enemy.team == other_client.team)
 174                                 )
 175                         ) { return true; }
 176                         break;
 177                 }
 178                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
 179                 {
 180                         if(
 181                                 (to_client != other_client)
 182                                 &&
 183                                 (
 184                                         (to_client.team == other_client.team)
 185                                         ||
 186                                         (
 187                                                 IS_SPEC(to_client)
 188                                                 &&
 189                                                 (
 190                                                         (to_client.enemy != other_client)
 191                                                         &&
 192                                                         (to_client.enemy.team == other_client.team)
 193                                                 )
 194                                         )
 195                                 )
 196                         ) { return true; }
 197                         break;
 198                 }
 199                 case NOTIF_ALL: // send to everyone
 200                 {
 201                         return true;
 202                 }
 203                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
 204                 {
 205                         if(
 206                                 (to_client != other_client)
 207                                 &&
 208                                 !(
 209                                         IS_SPEC(to_client)
 210                                         &&
 211                                         (to_client.enemy == other_client)
 212                                 )
 213                         ) { return true; }
 214                         break;
 215                 }
 216         }
 217         return false;
 218 }
 219
 220 #endif
 221
 222 // ===============================
 223 //  Initialization Core Functions
 224 // ===============================
 225
 226 // used by restartnotifs command to initialize notifications
 227 void Destroy_Notification_Entity(entity notif)
 228 {
 229         if(notif.nent_name != "") { strunzone(notif.nent_name); }
 230         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
 231         if(notif.nent_args != "") { strunzone(notif.nent_args); }
 232         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
 233         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
 234         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
 235         if(notif.nent_string != "") { strunzone(notif.nent_string); }
 236         remove(notif);
 237 }
 238
 239 void Destroy_All_Notifications(void)
 240 {
 241         entity notif;
 242         int i;
 243
 244         #define DESTROY_LOOP(type,count) do { \
 245                 for(i = 1; i <= count; ++i) \
 246                 { \
 247                         notif = Get_Notif_Ent(type, i); \
 248                         if (!notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
 249                         Destroy_Notification_Entity(notif); \
 250                 } \
 251         } while(0)
 252
 253         // kill all networked notifications and centerprints
 254         #ifdef SVQC
 255         Kill_Notification(NOTIF_ALL, world, 0, 0);
 256         #else
 257         reset_centerprint_messages();
 258         #endif
 259
 260         // kill all real notification entities
 261         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT);
 262         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT);
 263         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT);
 264         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT);
 265         DESTROY_LOOP(MSG_CHOICE, NOTIF_CHOICE_COUNT);
 266         #undef DESTROY_LOOP
 267 }
 268
 269 string Process_Notif_Line(
 270         int typeId,
 271         bool chat,
 272         string input,
 273         string notiftype,
 274         string notifname,
 275         string stringtype)
 276 {
 277         #ifdef CSQC
 278         if(typeId == MSG_INFO)
 279         {
 280                 if((chat && autocvar_notification_allow_chatboxprint)
 281                         || (autocvar_notification_allow_chatboxprint == 2))
 282                 {
 283                         // pass 1: add ETX char at beginning of line
 284                         input = strcat("\{3}", input);
 285
 286                         // pass 2: add ETX char at end of each new line (so that
 287                         // messages with multiple lines are put through chatbox too)
 288                         input = strreplace("\n", "\n\{3}", input);
 289
 290                         // pass 3: strip trailing ETX char
 291                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 292                                 { input = substring(input, 0, (strlen(input) - 1)); }
 293                 }
 294         }
 295         #endif
 296
 297         // done to both MSG_INFO and MSG_CENTER
 298         if(substring(input, (strlen(input) - 1), 1) == "\n")
 299         {
 300                 printf(
 301                         strcat(
 302                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: ",
 303                                 "^7net_type = %s, net_name = %s, string = %s.\n"
 304                         ),
 305                         notiftype,
 306                         notifname,
 307                         stringtype
 308                 );
 309                 notif_error = true;
 310                 input = substring(input, 1, (strlen(input) - 1));
 311         }
 312
 313         return input;
 314 }
 315
 316 string Process_Notif_Args(
 317         float arg_type,
 318         string args,
 319         string notiftype,
 320         string notifname)
 321 {
 322         string selected, remaining = args;
 323         float sel_num = 0;
 324
 325         for (;(remaining != "");)
 326         {
 327                 selected = car(remaining); remaining = cdr(remaining);
 328
 329                 switch(arg_type)
 330                 {
 331                         case 1: // normal args
 332                         {
 333                                 if(sel_num == NOTIF_MAX_ARGS)
 334                                 {
 335                                         printf(
 336                                                 strcat(
 337                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 338                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
 339                                                 ),
 340                                                 notiftype,
 341                                                 notifname,
 342                                                 NOTIF_MAX_ARGS
 343                                         );
 344                                         notif_error = true;
 345                                         break;
 346                                 }
 347
 348                                 switch(strtolower(selected))
 349                                 {
 350                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
 351                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
 352                                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { ++sel_num; break; }
 353                                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { ++sel_num; break; }
 354                                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { ++sel_num; break; }
 355                                         #define ARG_CASE_ARG_DC(selected,result)
 356                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 357                                         NOTIF_ARGUMENT_LIST
 358                                         #undef ARG_CASE
 359                                         #undef ARG_CASE_ARG_DC
 360                                         #undef ARG_CASE_ARG_SV
 361                                         #undef ARG_CASE_ARG_CS
 362                                         #undef ARG_CASE_ARG_CS_SV
 363                                         #undef ARG_CASE_ARG_CS_SV_DC
 364                                         #undef ARG_CASE_ARG_CS_SV_HA
 365                                         default:
 366                                         {
 367                                                 printf(
 368                                                         strcat(
 369                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 370                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
 371                                                         ),
 372                                                         notiftype,
 373                                                         notifname,
 374                                                         selected
 375                                                 );
 376                                                 notif_error = true;
 377                                                 break;
 378                                         }
 379                                 }
 380                                 break;
 381                         }
 382                         case 2: // hudargs
 383                         {
 384                                 if(sel_num == NOTIF_MAX_HUDARGS)
 385                                 {
 386                                         printf(
 387                                                 strcat(
 388                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 389                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
 390                                                 ),
 391                                                 notiftype,
 392                                                 notifname,
 393                                                 NOTIF_MAX_HUDARGS
 394                                         );
 395                                         notif_error = true;
 396                                         break;
 397                                 }
 398
 399                                 switch(strtolower(selected))
 400                                 {
 401                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
 402                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
 403                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 404                                         #define ARG_CASE_ARG_CS(selected,result)
 405                                         #define ARG_CASE_ARG_SV(selected,result)
 406                                         #define ARG_CASE_ARG_DC(selected,result)
 407                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 408                                         NOTIF_ARGUMENT_LIST
 409                                         #undef ARG_CASE
 410                                         #undef ARG_CASE_ARG_DC
 411                                         #undef ARG_CASE_ARG_SV
 412                                         #undef ARG_CASE_ARG_CS
 413                                         #undef ARG_CASE_ARG_CS_SV
 414                                         #undef ARG_CASE_ARG_CS_SV_DC
 415                                         #undef ARG_CASE_ARG_CS_SV_HA
 416                                         default:
 417                                         {
 418                                                 printf(
 419                                                         strcat(
 420                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 421                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
 422                                                         ),
 423                                                         notiftype,
 424                                                         notifname,
 425                                                         selected
 426                                                 );
 427                                                 notif_error = true;
 428                                                 break;
 429                                         }
 430                                 }
 431                                 break;
 432                         }
 433                         case 3: // durcnt
 434                         {
 435                                 if(sel_num == NOTIF_MAX_DURCNT)
 436                                 {
 437                                         printf(
 438                                                 strcat(
 439                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 440                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
 441                                                 ),
 442                                                 notiftype,
 443                                                 notifname,
 444                                                 NOTIF_MAX_DURCNT
 445                                         );
 446                                         notif_error = true;
 447                                         break;
 448                                 }
 449
 450                                 switch(strtolower(selected))
 451                                 {
 452                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
 453                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
 454                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 455                                         #define ARG_CASE_ARG_CS(selected,result)
 456                                         #define ARG_CASE_ARG_SV(selected,result)
 457                                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { ++sel_num; break; }
 458                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 459                                         NOTIF_ARGUMENT_LIST
 460                                         #undef ARG_CASE
 461                                         #undef ARG_CASE_ARG_DC
 462                                         #undef ARG_CASE_ARG_SV
 463                                         #undef ARG_CASE_ARG_CS
 464                                         #undef ARG_CASE_ARG_CS_SV
 465                                         #undef ARG_CASE_ARG_CS_SV_DC
 466                                         #undef ARG_CASE_ARG_CS_SV_HA
 467                                         default:
 468                                         {
 469                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 470                                                 else
 471                                                 {
 472                                                         printf(
 473                                                                 strcat(
 474                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 475                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
 476                                                                 ),
 477                                                                 notiftype,
 478                                                                 notifname,
 479                                                                 selected
 480                                                         );
 481                                                         notif_error = true;
 482                                                 }
 483                                                 break;
 484                                         }
 485                                 }
 486                                 break;
 487                         }
 488                 }
 489         }
 490         return args;
 491 }
 492
 493 void Create_Notification_Entity(
 494         float var_default,
 495         float var_cvar,
 496         int typeId,
 497         int nameid,
 498         string namestring,
 499         int strnum,
 500         int flnum,
 501         /* MSG_ANNCE */
 502         float channel,
 503         string snd,
 504         float vol,
 505         float position,
 506         /* MSG_INFO & MSG_CENTER */
 507         string args,
 508         string hudargs,
 509         string icon,
 510         float cpid,
 511         string durcnt,
 512         string normal,
 513         string gentle,
 514         /* MSG_MULTI */
 515         int anncename,
 516         int infoname,
 517         int centername,
 518         /* MSG_CHOICE */
 519         float challow_def,
 520         float challow_var,
 521         int chtype,
 522         int optiona,
 523         int optionb)
 524 {
 525         // =====================
 526         //  Global Entity Setup
 527         // =====================
 528         entity notif = spawn();
 529         switch(typeId)
 530         {
 531                 case MSG_ANNCE:
 532                 {
 533                         msg_annce_notifs[nameid - 1] = notif;
 534                         notif.classname = "msg_annce_notification";
 535                         break;
 536                 }
 537                 case MSG_INFO:
 538                 {
 539                         msg_info_notifs[nameid - 1] = notif;
 540                         notif.classname = "msg_info_notification";
 541                         break;
 542                 }
 543                 case MSG_CENTER:
 544                 {
 545                         msg_center_notifs[nameid - 1] = notif;
 546                         notif.classname = "msg_center_notification";
 547                         break;
 548                 }
 549                 case MSG_MULTI:
 550                 {
 551                         msg_multi_notifs[nameid - 1] = notif;
 552                         notif.classname = "msg_multi_notification";
 553                         break;
 554                 }
 555                 case MSG_CHOICE:
 556                 {
 557                         msg_choice_notifs[nameid - 1] = notif;
 558                         notif.classname = "msg_choice_notification";
 559                         break;
 560                 }
 561
 562                 default:
 563                 {
 564                         error(sprintf(
 565                                 strcat(
 566                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 567                                         "^7net_type = %d, net_name = %s.\n"
 568                                 ),
 569                                 typeId,
 570                                 namestring
 571                         ));
 572                         return; // It's not possible to recover from this one
 573                 }
 574         }
 575         notif.nent_default = var_default;
 576         notif.nent_enabled = (1 <= var_cvar);
 577         notif.nent_type = typeId;
 578         notif.nent_id = nameid;
 579         notif.nent_name = strzone(namestring);
 580
 581         string typestring = Get_Notif_TypeName(typeId);
 582
 583         // Other pre-notif-setup requisites
 584         notif_error = false;
 585
 586         // ====================
 587         //  Notification Setup
 588         // ====================
 589         switch(typeId)
 590         {
 591                 case MSG_ANNCE:
 592                 {
 593                         // Set MSG_ANNCE information and handle precaching
 594                         #ifdef CSQC
 595                         if (!(GENTLE && (var_cvar == 1)))
 596                         {
 597                                 if(snd != "")
 598                                 {
 599                                         if(notif.nent_enabled)
 600                                         {
 601                                                 precache_sound(sprintf("announcer/%s/%s.wav", autocvar_cl_announcer, snd));
 602                                                 notif.nent_channel = channel;
 603                                                 notif.nent_snd = strzone(snd);
 604                                                 notif.nent_vol = vol;
 605                                                 notif.nent_position = position;
 606                                         }
 607                                 }
 608                                 else
 609                                 {
 610                                         printf(
 611                                                 strcat(
 612                                                         "^1NOTIFICATION WITH NO SOUND: ",
 613                                                         "^7net_type = %s, net_name = %s.\n"
 614                                                 ),
 615                                                 typestring,
 616                                                 namestring
 617                                         );
 618                                         notif_error = true;
 619                                 }
 620                         }
 621                         else { notif.nent_enabled = false; }
 622                         #else
 623                         notif.nent_enabled = false;
 624                         #endif
 625
 626                         break;
 627                 }
 628
 629                 case MSG_INFO:
 630                 case MSG_CENTER:
 631                 {
 632                         // Set MSG_INFO and MSG_CENTER string/float counts
 633                         notif.nent_stringcount = strnum;
 634                         notif.nent_floatcount = flnum;
 635
 636                         // Only initialize arguments if we're either a client or on a dedicated server
 637                         #ifdef SVQC
 638                         float should_process_args = server_is_dedicated;
 639                         #else
 640                         float should_process_args = true;
 641                         #endif
 642
 643                         if(should_process_args)
 644                         {
 645                                 // ========================
 646                                 //  Process Main Arguments
 647                                 // ========================
 648                                 if(strnum + flnum)
 649                                 {
 650                                         if(args != "")
 651                                         {
 652                                                 notif.nent_args = strzone(
 653                                                         Process_Notif_Args(1, args, typestring, namestring));
 654                                         }
 655                                         else if((hudargs == "") && (durcnt ==""))
 656                                         {
 657                                                 printf(
 658                                                         strcat(
 659                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
 660                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
 661                                                         ),
 662                                                         typestring,
 663                                                         namestring,
 664                                                         strnum,
 665                                                         flnum
 666                                                 );
 667                                                 notif_error = true;
 668                                         }
 669                                 }
 670                                 else if(args != "")
 671                                 {
 672                                         notif.nent_args = strzone(
 673                                                 Process_Notif_Args(1, args, typestring, namestring));
 674                                 }
 675
 676
 677                                 // =======================================
 678                                 //  Process HUD and Centerprint Arguments
 679                                 //    Only processed on CSQC, as these
 680                                 //    args are only for HUD features.
 681                                 // =======================================
 682                                 #ifdef CSQC
 683                                 if(hudargs != "")
 684                                 {
 685                                         notif.nent_hudargs = strzone(
 686                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
 687
 688                                         if(icon != "") { notif.nent_icon = strzone(icon); }
 689                                         else
 690                                         {
 691                                                 printf(
 692                                                         strcat(
 693                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
 694                                                                 "^7net_type = %s, net_name = %s.\n"
 695                                                         ),
 696                                                         typestring,
 697                                                         namestring
 698                                                 );
 699                                                 notif_error = true;
 700                                         }
 701                                 }
 702                                 else if(icon != "")
 703                                 {
 704                                         printf(
 705                                                 strcat(
 706                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
 707                                                         "^7net_type = %s, net_name = %s.\n"
 708                                                 ),
 709                                                 typestring,
 710                                                 namestring
 711                                         );
 712                                         notif_error = true;
 713                                 }
 714
 715                                 if(durcnt != "")
 716                                 {
 717                                         notif.nent_durcnt = strzone(
 718                                                 Process_Notif_Args(3, durcnt, typestring, namestring));
 719
 720                                         if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 721                                         else
 722                                         {
 723                                                 printf(
 724                                                         strcat(
 725                                                                 "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
 726                                                                 "^7net_type = %s, net_name = %s.\n"
 727                                                         ),
 728                                                         typestring,
 729                                                         namestring
 730                                                 );
 731                                                 notif_error = true;
 732                                         }
 733                                 }
 734                                 else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 735                                 #endif
 736
 737
 738                                 // ======================
 739                                 //  Process Notif String
 740                                 // ======================
 741                                 #define SET_NOTIF_STRING(string,stringname) do { \
 742                                         notif.nent_string = strzone(CCR( \
 743                                                 Process_Notif_Line( \
 744                                                         typeId, \
 745                                                         (var_cvar > 1), \
 746                                                         string, \
 747                                                         typestring, \
 748                                                         namestring, \
 749                                                         stringname \
 750                                                 )) \
 751                                         ); \
 752                                 } while(0)
 753
 754                                 if(GENTLE)
 755                                 {
 756                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE"); }
 757                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 758                                 }
 759                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 760                                 #undef SET_NOTIF_STRING
 761
 762                                 // Check to make sure a string was chosen
 763                                 if(notif.nent_string == "")
 764                                 {
 765                                         printf(
 766                                                 strcat(
 767                                                         "^1EMPTY NOTIFICATION: ",
 768                                                         "^7net_type = %s, net_name = %s.\n"
 769                                                 ),
 770                                                 typestring,
 771                                                 namestring
 772                                         );
 773                                         notif_error = true;
 774                                 }
 775                         }
 776
 777                         break;
 778                 }
 779
 780                 case MSG_MULTI:
 781                 {
 782                         // Set MSG_MULTI string/float counts
 783                         if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
 784                         {
 785                                 printf(
 786                                         strcat(
 787                                                 "^1NOTIFICATION WITH NO SUBCALLS: ",
 788                                                 "^7net_type = %s, net_name = %s.\n"
 789                                         ),
 790                                         typestring,
 791                                         namestring
 792                                 );
 793                                 notif_error = true;
 794                         }
 795                         else
 796                         {
 797                                 // announcements don't actually need any arguments, so lets not even count them.
 798                                 if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
 799
 800                                 float infoname_stringcount = 0, infoname_floatcount = 0;
 801                                 float centername_stringcount = 0, centername_floatcount = 0;
 802
 803                                 if(infoname != NO_MSG)
 804                                 {
 805                                         notif.nent_msginfo = msg_info_notifs[infoname - 1];
 806                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 807                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 808                                 }
 809
 810                                 if(centername != NO_MSG)
 811                                 {
 812                                         notif.nent_msgcenter = msg_center_notifs[centername - 1];
 813                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 814                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 815                                 }
 816
 817                                 // set the requirements of THIS notification to the totals of its subcalls
 818                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 819                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 820                         }
 821
 822                         break;
 823                 }
 824
 825                 case MSG_CHOICE:
 826                 {
 827                         if((chtype == NO_MSG) || (optiona == NO_MSG) || (optionb == NO_MSG))
 828                         {
 829                                 printf(
 830                                         strcat(
 831                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: ",
 832                                                 "^7net_type = %s, net_name = %s.\n"
 833                                         ),
 834                                         typestring,
 835                                         namestring
 836                                 );
 837                                 notif_error = true;
 838                         }
 839                         else
 840                         {
 841                                 switch(chtype)
 842                                 {
 843                                         case MSG_ANNCE:
 844                                         {
 845                                                 notif.nent_optiona = msg_annce_notifs[optiona - 1];
 846                                                 notif.nent_optionb = msg_annce_notifs[optionb - 1];
 847                                                 break;
 848                                         }
 849                                         case MSG_INFO:
 850                                         {
 851                                                 notif.nent_optiona = msg_info_notifs[optiona - 1];
 852                                                 notif.nent_optionb = msg_info_notifs[optionb - 1];
 853                                                 break;
 854                                         }
 855                                         case MSG_CENTER:
 856                                         {
 857                                                 notif.nent_optiona = msg_center_notifs[optiona - 1];
 858                                                 notif.nent_optionb = msg_center_notifs[optionb - 1];
 859                                                 break;
 860                                         }
 861                                         case MSG_MULTI:
 862                                         {
 863                                                 notif.nent_optiona = msg_multi_notifs[optiona - 1];
 864                                                 notif.nent_optionb = msg_multi_notifs[optionb - 1];
 865                                                 break;
 866                                         }
 867                                         case MSG_CHOICE: // should we REALLY allow nested options?...
 868                                         {
 869                                                 notif.nent_optiona = msg_choice_notifs[optiona - 1];
 870                                                 notif.nent_optionb = msg_choice_notifs[optionb - 1];
 871                                                 break;
 872                                         }
 873
 874                                         default:
 875                                         {
 876                                                 printf(
 877                                                         strcat(
 878                                                                 "^1NOTIFICATION WITH IMPROPER TYPE: ",
 879                                                                 "^7net_type = %d, net_name = %s.\n"
 880                                                         ),
 881                                                         typeId,
 882                                                         namestring
 883                                                 );
 884                                                 notif_error = true;
 885                                                 break;
 886                                         }
 887                                 }
 888                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 889                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 890                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
 891                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
 892
 893                                 /*#ifdef NOTIFICATIONS_DEBUG
 894                                 Debug_Notification(sprintf(
 895                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
 896                                         notif.nent_name,
 897                                         sprintf(
 898                                                 "^ optiona: %s %s : %d %d",
 899                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
 900                                                 notif.nent_optiona.nent_name,
 901                                                 notif.nent_optiona.nent_stringcount,
 902                                                 notif.nent_optiona.nent_floatcount
 903                                         ),
 904                                         sprintf(
 905                                                 "^ optionb: %s %s : %d %d",
 906                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
 907                                                 notif.nent_optionb.nent_name,
 908                                                 notif.nent_optionb.nent_stringcount,
 909                                                 notif.nent_optionb.nent_floatcount
 910                                         )
 911                                 ));
 912                                 #endif*/
 913                         }
 914                         break;
 915                 }
 916
 917                 default:
 918                 {
 919                         printf(
 920                                 strcat(
 921                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 922                                         "^7net_type = %d, net_name = %s.\n"
 923                                 ),
 924                                 typeId,
 925                                 namestring
 926                         );
 927                         notif_error = true;
 928                         break;
 929                 }
 930         }
 931
 932         // now check to see if any errors happened
 933         if(notif_error)
 934         {
 935                 notif.nent_enabled = false; // disable the notification so it can't cause trouble
 936                 notif_global_error = true; // throw the red flag that an error happened on init
 937         }
 938 }
 939
 940
 941 // ===============
 942 //  Cvar Handling
 943 // ===============
 944
 945 // used by MSG_CHOICE to build list of choices
 946 #ifdef SVQC
 947 void Notification_GetCvars(void)
 948 {
 949         for(int i = 0; i <= NOTIF_CHOICE_COUNT; ++i)
 950         {
 951                 GetCvars_handleFloat(
 952                         get_cvars_s,
 953                         get_cvars_f,
 954                         msg_choice_choices[i],
 955                         sprintf("notification_%s", msg_choice_notifs[i].nent_name)
 956                 );
 957         }
 958 }
 959 #endif
 960
 961 // used to output notifications.cfg file
 962 void Dump_Notifications(float fh, float alsoprint)
 963 {
 964         #define NOTIF_WRITE(a) { \
 965                 fputs(fh, a); \
 966                 if(alsoprint) { print(a); } }
 967         #define NOTIF_WRITE_ENTITY(description) { \
 968                 notif_msg = \
 969                         sprintf( \
 970                                 "seta notification_%s \"%d\" \"%s\"\n", \
 971                                 e.nent_name, e.nent_default, description \
 972                         ); \
 973                 NOTIF_WRITE(notif_msg) }
 974         #define NOTIF_WRITE_ENTITY_CHOICE(descriptiona,descriptionb) { \
 975                 notif_msg = \
 976                         sprintf( \
 977                                 "seta notification_%s \"%d\" \"%s\"\n" \
 978                                 "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
 979                                 e.nent_name, e.nent_default, descriptiona, \
 980                                 e.nent_name, e.nent_challow_def, descriptionb \
 981                         ); \
 982                 NOTIF_WRITE(notif_msg) }
 983         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
 984                 notif_msg = \
 985                         sprintf( \
 986                                 "seta notification_%s \"%s\" \"%s\"\n", \
 987                                 cvar, default, description \
 988                         ); \
 989                 NOTIF_WRITE(notif_msg) }
 990
 991         string notif_msg;
 992         int i;
 993         entity e;
 994
 995         // Note: This warning only applies to the notifications.cfg file that is output...
 996
 997         // You ARE supposed to manually edit this function to add i.e. hard coded
 998         // notification variables for mutators or game modes or such and then
 999         // regenerate the notifications.cfg file from the new code.
1000
1001         NOTIF_WRITE("// ********************************************** //\n");
1002         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
1003         NOTIF_WRITE("// **                                          ** //\n");
1004         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
1005         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
1006         NOTIF_WRITE("// **                                          ** //\n");
1007         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
1008         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
1009         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
1010         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
1011         NOTIF_WRITE("// **                                          ** //\n");
1012         NOTIF_WRITE("// ********************************************** //\n");
1013
1014         // These notifications will also append their string as a comment...
1015         // This is not necessary, and does not matter if they vary between config versions,
1016         // it is just a semi-helpful tool for those who want to manually change their user settings.
1017
1018         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
1019         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
1020         {
1021                 e = Get_Notif_Ent(MSG_ANNCE, i);
1022                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1023
1024                 NOTIF_WRITE_ENTITY(
1025                         "0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled"
1026                 );
1027         }
1028
1029         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
1030         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
1031         {
1032                 e = Get_Notif_Ent(MSG_INFO, i);
1033                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1034
1035                 NOTIF_WRITE_ENTITY(
1036                         "0 = off, 1 = print to console, "
1037                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
1038                 );
1039         }
1040
1041         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
1042         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
1043         {
1044                 e = Get_Notif_Ent(MSG_CENTER, i);
1045                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1046
1047                 NOTIF_WRITE_ENTITY(
1048                         "0 = off, 1 = centerprint"
1049                 );
1050         }
1051
1052         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
1053         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
1054         {
1055                 e = Get_Notif_Ent(MSG_MULTI, i);
1056                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1057
1058                 NOTIF_WRITE_ENTITY(
1059                         "Enable this multiple notification"
1060                 );
1061         }
1062
1063         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
1064         for(i = 1; i <= NOTIF_CHOICE_COUNT; ++i)
1065         {
1066                 e = Get_Notif_Ent(MSG_CHOICE, i);
1067                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1068
1069                 NOTIF_WRITE_ENTITY_CHOICE(
1070                         "Choice for this notification 0 = off, 1 = default message, 2 = verbose message",
1071                         "Allow choice for this notification 0 = off, 1 = only in warmup mode, 2 = always"
1072                 );
1073         }
1074
1075         // edit these to match whichever cvars are used for specific notification options
1076         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
1077
1078         NOTIF_WRITE_HARDCODED(
1079                 "allow_chatboxprint", "1",
1080                 "Allow INFO notifications to be printed to chat box"
1081                 "0 = do not allow, "
1082                 "1 = allow only if allowed by individual notification_INFO* cvars, "
1083                 "2 = force all INFO notifications to be printed to the chatbox"
1084         );
1085
1086         NOTIF_WRITE_HARDCODED(
1087                 "debug", "0",
1088                 "Print extra debug information on all notification function calls "
1089                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
1090                 "0 = disabled, 1 = dprint, 2 = print"
1091         );
1092
1093         NOTIF_WRITE_HARDCODED(
1094                 "errors_are_fatal", "1",
1095                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
1096         );
1097
1098         NOTIF_WRITE_HARDCODED(
1099                 "item_centerprinttime", "1.5",
1100                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
1101         );
1102
1103         NOTIF_WRITE_HARDCODED(
1104                 "lifetime_mapload", "10",
1105                 "Amount of time that notification entities last immediately at mapload (in seconds) "
1106                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
1107         );
1108
1109         NOTIF_WRITE_HARDCODED(
1110                 "lifetime_runtime", "0.5",
1111                 "Amount of time that notification entities last on the server during runtime (In seconds)"
1112         );
1113
1114         NOTIF_WRITE_HARDCODED(
1115                 "server_allows_location", "1",
1116                 "Server side cvar for allowing death messages to show location information too"
1117         );
1118
1119         NOTIF_WRITE_HARDCODED(
1120                 "show_location", "0",
1121                 "Append location information to MSG_INFO death/kill messages"
1122         );
1123
1124         NOTIF_WRITE_HARDCODED(
1125                 "show_location_string", "",
1126                 "Replacement string piped into sprintf, "
1127                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
1128         );
1129
1130         NOTIF_WRITE_HARDCODED(
1131                 "show_sprees", "1",
1132                 "Print information about sprees in death/kill messages"
1133         );
1134
1135         NOTIF_WRITE_HARDCODED(
1136                 "show_sprees_center", "1",
1137                 "Show spree information in MSG_CENTER messages... "
1138                 "0 = off, 1 = target (but only for first victim) and attacker"
1139         );
1140
1141         NOTIF_WRITE_HARDCODED(
1142                 "show_sprees_center_specialonly", "1",
1143                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
1144         );
1145
1146         NOTIF_WRITE_HARDCODED(
1147                 "show_sprees_info", "3",
1148                 "Show spree information in MSG_INFO messages... "
1149                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
1150         );
1151
1152         NOTIF_WRITE_HARDCODED(
1153                 "show_sprees_info_newline", "1",
1154                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
1155         );
1156
1157         NOTIF_WRITE_HARDCODED(
1158                 "show_sprees_info_specialonly", "1",
1159                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
1160         );
1161
1162         NOTIF_WRITE(sprintf(
1163                 strcat(
1164                         "\n// Notification counts (total = %d): ",
1165                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
1166                 ),
1167                 (
1168                         NOTIF_ANNCE_COUNT +
1169                         NOTIF_INFO_COUNT +
1170                         NOTIF_CENTER_COUNT +
1171                         NOTIF_MULTI_COUNT +
1172                         NOTIF_CHOICE_COUNT
1173                 ),
1174                 NOTIF_ANNCE_COUNT,
1175                 NOTIF_INFO_COUNT,
1176                 NOTIF_CENTER_COUNT,
1177                 NOTIF_MULTI_COUNT,
1178                 NOTIF_CHOICE_COUNT
1179         ));
1180
1181         return;
1182         #undef NOTIF_WRITE_HARDCODED
1183         #undef NOTIF_WRITE_ENTITY
1184         #undef NOTIF_WRITE
1185 }
1186
1187
1188 // ===============================
1189 //  Frontend Notification Pushing
1190 // ===============================
1191
1192 #ifdef NOTIFICATIONS_DEBUG
1193 void Debug_Notification(string input)
1194 {
1195         switch(autocvar_notification_debug)
1196         {
1197                 case 1: { dprint(input); break; }
1198                 case 2: { print(input); break; }
1199         }
1200 }
1201 #endif
1202
1203 string Local_Notification_sprintf(
1204         string input, string args,
1205         string s1, string s2, string s3, string s4,
1206         int f1, float f2, float f3, float f4)
1207 {
1208         #ifdef NOTIFICATIONS_DEBUG
1209         Debug_Notification(sprintf(
1210                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
1211                 MakeConsoleSafe(input),
1212                 args,
1213                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1214                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1215         ));
1216         #endif
1217
1218         string selected;
1219         int sel_num;
1220         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1221
1222         string tmp_s;
1223
1224         for(sel_num = 0;(args != "");)
1225         {
1226                 selected = car(args); args = cdr(args);
1227                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf");
1228                 switch(strtolower(selected))
1229                 {
1230                         #ifdef CSQC
1231                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1232                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1233                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1234                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1235                         #define ARG_CASE_ARG_SV(selected,result)
1236                         #define ARG_CASE_ARG_DC(selected,result)
1237                         #else
1238                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1239                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1240                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1241                         #define ARG_CASE_ARG_CS(selected,result)
1242                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1243                         #define ARG_CASE_ARG_DC(selected,result)
1244                         #endif
1245                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1246                         NOTIF_ARGUMENT_LIST
1247                         #undef ARG_CASE
1248                         #undef ARG_CASE_ARG_DC
1249                         #undef ARG_CASE_ARG_SV
1250                         #undef ARG_CASE_ARG_CS
1251                         #undef ARG_CASE_ARG_CS_SV
1252                         #undef ARG_CASE_ARG_CS_SV_DC
1253                         #undef ARG_CASE_ARG_CS_SV_HA
1254                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1255                 }
1256         }
1257         return sprintf(
1258                 strcat(input, "\n"),
1259                 arg_slot[0],
1260                 arg_slot[1],
1261                 arg_slot[2],
1262                 arg_slot[3],
1263                 arg_slot[4],
1264                 arg_slot[5],
1265                 arg_slot[6]
1266         );
1267 }
1268
1269 #ifdef CSQC
1270 void Local_Notification_sound(
1271         float soundchannel, string soundfile,
1272         float soundvolume, float soundposition)
1273 {
1274         if((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1275         {
1276                 #ifdef NOTIFICATIONS_DEBUG
1277                 Debug_Notification(sprintf(
1278                         "Local_Notification_sound(world, %f, '%s', %f, %f);\n",
1279                         soundchannel,
1280                         sprintf(
1281                                 "announcer/%s/%s.wav",
1282                                 autocvar_cl_announcer,
1283                                 soundfile
1284                         ),
1285                         soundvolume,
1286                         soundposition
1287                 ));
1288                 #endif
1289
1290                 sound(
1291                         world,
1292                         soundchannel,
1293                         sprintf(
1294                                 "announcer/%s/%s.wav",
1295                                 autocvar_cl_announcer,
1296                                 soundfile
1297                         ),
1298                         soundvolume,
1299                         soundposition
1300                 );
1301
1302                 if(prev_soundfile) { strunzone(prev_soundfile); }
1303                 prev_soundfile = strzone(soundfile);
1304                 prev_soundtime = time;
1305         }
1306         else
1307         {
1308                 #ifdef NOTIFICATIONS_DEBUG
1309                 Debug_Notification(sprintf(
1310                         strcat(
1311                                 "Local_Notification_sound(world, %f, '%s', %f, %f) ",
1312                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1313                          ),
1314                         soundchannel,
1315                         sprintf(
1316                                 "announcer/%s/%s.wav",
1317                                 autocvar_cl_announcer,
1318                                 soundfile
1319                         ),
1320                         soundvolume,
1321                         soundposition,
1322                         prev_soundfile,
1323                         (time - prev_soundtime),
1324                         autocvar_cl_announcer_antispam
1325                 ));
1326                 #endif
1327         }
1328 }
1329
1330 void Local_Notification_HUD_Notify_Push(
1331         string icon, string hudargs,
1332         string s1, string s2, string s3, string s4,
1333         float f1, float f2, float f3, float f4)
1334 {
1335         string selected;
1336         arg_slot[0] = ""; arg_slot[1] = "";
1337
1338         int sel_num;
1339         for(sel_num = 0;(hudargs != "");)
1340         {
1341                 selected = car(hudargs); hudargs = cdr(hudargs);
1342                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push");
1343                 switch(strtolower(selected))
1344                 {
1345                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1346                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
1347                         #define ARG_CASE_ARG_CS_SV(selected,result)
1348                         #define ARG_CASE_ARG_CS(selected,result)
1349                         #define ARG_CASE_ARG_SV(selected,result)
1350                         #define ARG_CASE_ARG_DC(selected,result)
1351                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1352                         NOTIF_ARGUMENT_LIST
1353                         #undef ARG_CASE
1354                         #undef ARG_CASE_ARG_DC
1355                         #undef ARG_CASE_ARG_SV
1356                         #undef ARG_CASE_ARG_CS
1357                         #undef ARG_CASE_ARG_CS_SV
1358                         #undef ARG_CASE_ARG_CS_SV_DC
1359                         #undef ARG_CASE_ARG_CS_SV_HA
1360                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1361                 }
1362         }
1363         #ifdef NOTIFICATIONS_DEBUG
1364         Debug_Notification(sprintf(
1365                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s, %s);\n",
1366                 icon,
1367                 hudargs,
1368                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1369                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4),
1370                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1371         ));
1372         #endif
1373         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1374 }
1375
1376 void Local_Notification_centerprint_generic(
1377         string input, string durcnt,
1378         int cpid, float f1, float f2)
1379 {
1380         arg_slot[0] = ""; arg_slot[1] = "";
1381
1382         for(int sel_num = 0;(durcnt != "");)
1383         {
1384                 string selected = car(durcnt); durcnt = cdr(durcnt);
1385                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic");
1386                 switch(strtolower(selected))
1387                 {
1388                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
1389                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1390                         #define ARG_CASE_ARG_CS_SV(selected,result)
1391                         #define ARG_CASE_ARG_CS(selected,result)
1392                         #define ARG_CASE_ARG_SV(selected,result)
1393                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1394                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1395                         NOTIF_ARGUMENT_LIST
1396                         #undef ARG_CASE
1397                         #undef ARG_CASE_ARG_DC
1398                         #undef ARG_CASE_ARG_SV
1399                         #undef ARG_CASE_ARG_CS
1400                         #undef ARG_CASE_ARG_CS_SV
1401                         #undef ARG_CASE_ARG_CS_SV_DC
1402                         #undef ARG_CASE_ARG_CS_SV_HA
1403                         default:
1404                         {
1405                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
1406                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
1407                                 break;
1408                         }
1409                 }
1410         }
1411         #ifdef NOTIFICATIONS_DEBUG
1412         Debug_Notification(sprintf(
1413                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
1414                 MakeConsoleSafe(input),
1415                 durcnt,
1416                 f1, f2,
1417                 stof(arg_slot[0]),
1418                 stof(arg_slot[1])
1419         ));
1420         #endif
1421         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
1422 }
1423 #endif
1424
1425 void Local_Notification(int net_type, int net_name, ...count)
1426 {
1427         // check if this should be aborted
1428         if(net_name == NOTIF_ABORT)
1429         {
1430                 #ifdef NOTIFICATIONS_DEBUG
1431                 Debug_Notification(sprintf(
1432                         "Local_Notification(%s, %s, ...);\n",
1433                         Get_Notif_TypeName(net_type),
1434                         "NOTIF_ABORT"
1435                 ));
1436                 #endif
1437                 return;
1438         }
1439
1440         // check supplied type and name for errors
1441         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
1442         if(checkargs != "")
1443         {
1444                 #ifdef NOTIFICATIONS_DEBUG
1445                 Debug_Notification(sprintf(
1446                         "Local_Notification(%s, %d, ...);\n",
1447                         Get_Notif_TypeName(net_type),
1448                         Get_Notif_Ent(net_type, net_name).nent_name
1449                 ));
1450                 #endif
1451                 backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs));
1452                 return;
1453         }
1454
1455         // retreive entity of this notification
1456         entity notif = Get_Notif_Ent(net_type, net_name);
1457         if (!notif)
1458         {
1459                 #ifdef NOTIFICATIONS_DEBUG
1460                 Debug_Notification(sprintf(
1461                         "Local_Notification(%s, %d, ...);\n",
1462                         Get_Notif_TypeName(net_type),
1463                         net_name
1464                 ));
1465                 #endif
1466                 backtrace("Local_Notification: Could not find notification entity!\n");
1467                 return;
1468         }
1469
1470         // check if the notification is enabled
1471         if (!notif.nent_enabled)
1472         {
1473                 #ifdef NOTIFICATIONS_DEBUG
1474                 Debug_Notification(sprintf(
1475                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1476                         Get_Notif_TypeName(net_type),
1477                         notif.nent_name
1478                 ));
1479                 #endif
1480                 return;
1481         }
1482
1483         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1484         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1485         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1486         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1487         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1488         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1489         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1490         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1491
1492         #ifdef NOTIFICATIONS_DEBUG
1493         Debug_Notification(sprintf(
1494                 "Local_Notification(%s, %s, %s, %s);\n",
1495                 Get_Notif_TypeName(net_type),
1496                 notif.nent_name,
1497                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1498                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1499         ));
1500         #endif
1501
1502         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1503         {
1504                 backtrace(sprintf(
1505                         strcat(
1506                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
1507                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1508                                 "Check the definition and function call for accuracy...?\n"
1509                         ),
1510                         Get_Notif_TypeName(net_type),
1511                         notif.nent_name,
1512                         notif.nent_stringcount,
1513                         notif.nent_floatcount,
1514                         count
1515                 ));
1516                 return;
1517         }
1518         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1519         {
1520                 backtrace(sprintf(
1521                         strcat(
1522                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
1523                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1524                                 "Check the definition and function call for accuracy...?\n"
1525                         ),
1526                         Get_Notif_TypeName(net_type),
1527                         notif.nent_name,
1528                         notif.nent_stringcount,
1529                         notif.nent_floatcount,
1530                         count
1531                 ));
1532                 return;
1533         }
1534
1535         switch(net_type)
1536         {
1537                 case MSG_ANNCE:
1538                 {
1539                         #ifdef CSQC
1540                         Local_Notification_sound(
1541                                 notif.nent_channel,
1542                                 notif.nent_snd,
1543                                 notif.nent_vol,
1544                                 notif.nent_position
1545                         );
1546                         #else
1547                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1548                         #endif
1549                         break;
1550                 }
1551
1552                 case MSG_INFO:
1553                 {
1554                         print(
1555                                 Local_Notification_sprintf(
1556                                         notif.nent_string,
1557                                         notif.nent_args,
1558                                         s1, s2, s3, s4,
1559                                         f1, f2, f3, f4)
1560                         );
1561                         #ifdef CSQC
1562                         if(notif.nent_icon != "")
1563                         {
1564                                 if ( notif.nent_iconargs != "" )
1565                                 {
1566                                         notif.nent_icon = Local_Notification_sprintf(
1567                                                 notif.nent_icon,notif.nent_iconargs,
1568                                                 s1, s2, s3, s4, f1, f2, f3, f4);
1569                                         // remove the newline added by Local_Notification_sprintf
1570                                         notif.nent_icon = strzone(substring(notif.nent_icon,0,strlen(notif.nent_icon)-1));
1571                                 }
1572                                 Local_Notification_HUD_Notify_Push(
1573                                         notif.nent_icon,
1574                                         notif.nent_hudargs,
1575                                         s1, s2, s3, s4,
1576                                         f1, f2, f3, f4);
1577                         }
1578                         #endif
1579                         break;
1580                 }
1581
1582                 #ifdef CSQC
1583                 case MSG_CENTER:
1584                 {
1585                         Local_Notification_centerprint_generic(
1586                                 Local_Notification_sprintf(
1587                                         notif.nent_string,
1588                                         notif.nent_args,
1589                                         s1, s2, s3, s4,
1590                                         f1, f2, f3, f4),
1591                                 notif.nent_durcnt,
1592                                 notif.nent_cpid,
1593                                 f1, f2);
1594                         break;
1595                 }
1596                 #endif
1597
1598                 case MSG_MULTI:
1599                 {
1600                         if(notif.nent_msginfo)
1601                         if(notif.nent_msginfo.nent_enabled)
1602                         {
1603                                 Local_Notification_WOVA(
1604                                         MSG_INFO,
1605                                         notif.nent_msginfo.nent_id,
1606                                         notif.nent_msginfo.nent_stringcount,
1607                                         notif.nent_msginfo.nent_floatcount,
1608                                         s1, s2, s3, s4,
1609                                         f1, f2, f3, f4);
1610                         }
1611                         #ifdef CSQC
1612                         if(notif.nent_msgannce)
1613                         if(notif.nent_msgannce.nent_enabled)
1614                         {
1615                                 Local_Notification_WOVA(
1616                                         MSG_ANNCE,
1617                                         notif.nent_msgannce.nent_id,
1618                                         0, 0,
1619                                         "", "", "", "",
1620                                         0, 0, 0, 0);
1621                         }
1622                         if(notif.nent_msgcenter)
1623                         if(notif.nent_msgcenter.nent_enabled)
1624                         {
1625                                 Local_Notification_WOVA(
1626                                         MSG_CENTER,
1627                                         notif.nent_msgcenter.nent_id,
1628                                         notif.nent_msgcenter.nent_stringcount,
1629                                         notif.nent_msgcenter.nent_floatcount,
1630                                         s1, s2, s3, s4,
1631                                         f1, f2, f3, f4);
1632                         }
1633                         #endif
1634                         break;
1635                 }
1636
1637                 case MSG_CHOICE:
1638                 {
1639                         entity found_choice;
1640
1641                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2)))
1642                         {
1643                                 switch(cvar(sprintf("notification_%s", notif.nent_name)))
1644                                 {
1645                                         case 1: found_choice = notif.nent_optiona; break;
1646                                         case 2: found_choice = notif.nent_optionb; break;
1647                                         default: return; // not enabled anyway
1648                                 }
1649                         }
1650                         else { found_choice = notif.nent_optiona; }
1651
1652                         Local_Notification_WOVA(
1653                                 found_choice.nent_type,
1654                                 found_choice.nent_id,
1655                                 found_choice.nent_stringcount,
1656                                 found_choice.nent_floatcount,
1657                                 s1, s2, s3, s4,
1658                                 f1, f2, f3, f4);
1659                 }
1660         }
1661 }
1662
1663 // WOVA = Without Variable Arguments
1664 void Local_Notification_WOVA(
1665         int net_type, float net_name,
1666         float stringcount, float floatcount,
1667         string s1, string s2, string s3, string s4,
1668         float f1, float f2, float f3, float f4)
1669 {
1670         #define VARITEM(stringc,floatc,args) \
1671                 if((stringcount == stringc) && (floatcount == floatc)) \
1672                         { Local_Notification(net_type, net_name, args); return; }
1673         EIGHT_VARS_TO_VARARGS_VARLIST
1674         #undef VARITEM
1675         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1676 }
1677
1678
1679 // =========================
1680 //  Notification Networking
1681 // =========================
1682
1683 #ifdef CSQC
1684 void Read_Notification(float is_new)
1685 {
1686         int net_type = ReadByte();
1687         int net_name = ReadShort();
1688
1689         entity notif;
1690
1691         if(net_type == MSG_CENTER_CPID)
1692         {
1693                 #ifdef NOTIFICATIONS_DEBUG
1694                 Debug_Notification(sprintf(
1695                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1696                         is_new,
1697                         time,
1698                         Get_Notif_TypeName(net_type),
1699                         net_name
1700                 ));
1701                 #endif
1702
1703                 if(is_new)
1704                 {
1705                         if(net_name == 0) { reset_centerprint_messages(); }
1706                         else if(net_name != NO_CPID)
1707                         {
1708                                 // in this case, net_name IS the cpid we want to kill
1709                                 centerprint_generic(net_name, "", 0, 0);
1710                         }
1711                         else
1712                         {
1713                                 backtrace(sprintf(
1714                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1715                                         is_new,
1716                                         time
1717                                 ));
1718                         }
1719                 }
1720         }
1721         else
1722         {
1723                 notif = Get_Notif_Ent(net_type, net_name);
1724                 if (!notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1725
1726                 #ifdef NOTIFICATIONS_DEBUG
1727                 Debug_Notification(sprintf(
1728                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1729                         is_new,
1730                         time,
1731                         Get_Notif_TypeName(net_type),
1732                         notif.nent_name
1733                 ));
1734                 #endif
1735
1736                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1737                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1738                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1739                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1740                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1741                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1742                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1743                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1744
1745                 if(is_new)
1746                 {
1747                         Local_Notification_WOVA(
1748                                 net_type, net_name,
1749                                 notif.nent_stringcount,
1750                                 notif.nent_floatcount,
1751                                 s1, s2, s3, s4,
1752                                 f1, f2, f3, f4);
1753                 }
1754         }
1755 }
1756 #endif
1757
1758 #ifdef SVQC
1759 void Net_Notification_Remove()
1760 {
1761         if (!self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1762
1763         #ifdef NOTIFICATIONS_DEBUG
1764         Debug_Notification(sprintf(
1765                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1766                 time,
1767                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1768                 Get_Notif_TypeName(self.nent_net_type),
1769                 self.owner.nent_name
1770         ));
1771         #endif
1772
1773         for(int i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1774         remove(self);
1775 }
1776
1777 float Net_Write_Notification(entity client, int sf)
1778 {
1779         if(Notification_ShouldSend(self.nent_broadcast, client, self.nent_client))
1780         {
1781                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1782                 WriteByte(MSG_ENTITY, self.nent_net_type);
1783                 WriteShort(MSG_ENTITY, self.nent_net_name);
1784                 for(int i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
1785                 for(int i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1786                 return true;
1787         }
1788         else { return false; }
1789 }
1790
1791 void Kill_Notification(
1792         float broadcast, entity client,
1793         float net_type, float net_name)
1794 {
1795         #ifdef NOTIFICATIONS_DEBUG
1796         Debug_Notification(sprintf(
1797                 "Kill_Notification(%s, '%s', %s, %d);\n",
1798                 Get_Notif_BroadcastName(broadcast),
1799                 client.netname,
1800                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1801                 net_name
1802         ));
1803         #endif
1804
1805         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1806         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1807
1808         entity notif, net_notif;
1809         float killed_cpid = NO_CPID;
1810
1811         switch(net_type)
1812         {
1813                 case 0:
1814                 {
1815                         killed_cpid = 0; // kill ALL centerprints
1816                         break;
1817                 }
1818
1819                 case MSG_CENTER:
1820                 {
1821                         if(net_name)
1822                         {
1823                                 entity notif = Get_Notif_Ent(net_type, net_name);
1824                                 if (!notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1825
1826                                 if(notif.nent_cpid)
1827                                         killed_cpid = notif.nent_cpid;
1828                                 else
1829                                         killed_cpid = NO_CPID;
1830                         }
1831                         else
1832                         {
1833                                 killed_cpid = 0; // kill ALL centerprints
1834                         }
1835                         break;
1836                 }
1837
1838                 case MSG_CENTER_CPID:
1839                 {
1840                         killed_cpid = net_name;
1841                         break;
1842                 }
1843         }
1844
1845         if(killed_cpid != NO_CPID)
1846         {
1847                 net_notif = spawn();
1848                 net_notif.classname = "net_kill_notification";
1849                 net_notif.nent_broadcast = broadcast;
1850                 net_notif.nent_client = client;
1851                 net_notif.nent_net_type = MSG_CENTER_CPID;
1852                 net_notif.nent_net_name = killed_cpid;
1853                 Net_LinkEntity(net_notif, false, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1854         }
1855
1856         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1857         {
1858                 if(net_type)
1859                 {
1860                         if((killed_cpid != NO_CPID) && (notif.nent_net_type == MSG_CENTER))
1861                         {
1862                                 if(notif.owner.nent_cpid == killed_cpid)
1863                                 {
1864                                         notif.nent_net_name = -1;
1865                                         notif.nextthink = time;
1866                                 }
1867                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1868                         }
1869                         else if(notif.nent_net_type == net_type)
1870                         {
1871                                 if(net_name)
1872                                 {
1873                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1874                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1875                                 }
1876                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1877                         }
1878                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1879                 }
1880                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1881         }
1882 }
1883
1884 void Send_Notification(
1885         float broadcast, entity client,
1886         float net_type, float net_name,
1887         ...count)
1888 {
1889         // check if this should be aborted
1890         if(net_name == NOTIF_ABORT)
1891         {
1892                 #ifdef NOTIFICATIONS_DEBUG
1893                 Debug_Notification(sprintf(
1894                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1895                         Get_Notif_BroadcastName(broadcast),
1896                         client.classname,
1897                         Get_Notif_TypeName(net_type),
1898                         "NOTIF_ABORT"
1899                 ));
1900                 #endif
1901                 return;
1902         }
1903
1904         // check supplied broadcast, target, type, and name for errors
1905         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1906         if(checkargs != "")
1907         {
1908                 #ifdef NOTIFICATIONS_DEBUG
1909                 Debug_Notification(sprintf(
1910                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1911                         Get_Notif_BroadcastName(broadcast),
1912                         client.classname,
1913                         Get_Notif_TypeName(net_type),
1914                         Get_Notif_Ent(net_type, net_name).nent_name
1915                 ));
1916                 #endif
1917                 backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs));
1918                 return;
1919         }
1920
1921         // retreive entity of this notification
1922         entity notif = Get_Notif_Ent(net_type, net_name);
1923         if (!notif)
1924         {
1925                 #ifdef NOTIFICATIONS_DEBUG
1926                 Debug_Notification(sprintf(
1927                         "Send_Notification(%s, '%s', %s, %d, ...);\n",
1928                         Get_Notif_BroadcastName(broadcast),
1929                         client.classname,
1930                         Get_Notif_TypeName(net_type),
1931                         net_name
1932                 ));
1933                 #endif
1934                 backtrace("Send_Notification: Could not find notification entity!\n");
1935                 return;
1936         }
1937
1938         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1939         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1940         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1941         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1942         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1943         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1944         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1945         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1946
1947         #ifdef NOTIFICATIONS_DEBUG
1948         Debug_Notification(sprintf(
1949                 "Send_Notification(%s, %s, %s);\n",
1950                 sprintf(
1951                         "%s, '%s', %s, %s",
1952                         Get_Notif_BroadcastName(broadcast),
1953                         client.classname,
1954                         Get_Notif_TypeName(net_type),
1955                         notif.nent_name
1956                 ),
1957                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1958                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1959         ));
1960         #endif
1961
1962         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1963         {
1964                 backtrace(sprintf(
1965                         strcat(
1966                                 "Not enough arguments for Send_Notification(%s, ...)! ",
1967                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1968                                 "Check the definition and function call for accuracy...?\n"
1969                         ),
1970                         sprintf(
1971                                 #ifdef NOTIFICATIONS_DEBUG
1972                                 "%s, '%s', %s, %s",
1973                                 Get_Notif_BroadcastName(broadcast),
1974                                 #else
1975                                 "%d, '%s', %s, %s",
1976                                 broadcast,
1977                                 #endif
1978                                 client.classname,
1979                                 Get_Notif_TypeName(net_type),
1980                                 notif.nent_name
1981                         ),
1982                         notif.nent_stringcount,
1983                         notif.nent_floatcount,
1984                         count
1985                 ));
1986                 return;
1987         }
1988         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1989         {
1990                 backtrace(sprintf(
1991                         strcat(
1992                                 "Too many arguments for Send_Notification(%s, ...)! ",
1993                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1994                                 "Check the definition and function call for accuracy...?\n"
1995                         ),
1996                         sprintf(
1997                                 #ifdef NOTIFICATIONS_DEBUG
1998                                 "%s, '%s', %s, %s",
1999                                 Get_Notif_BroadcastName(broadcast),
2000                                 #else
2001                                 "%d, '%s', %s, %s",
2002                                 broadcast,
2003                                 #endif
2004                                 client.classname,
2005                                 Get_Notif_TypeName(net_type),
2006                                 notif.nent_name
2007                         ),
2008                         notif.nent_stringcount,
2009                         notif.nent_floatcount,
2010                         count
2011                 ));
2012                 return;
2013         }
2014
2015         if(
2016                 server_is_dedicated
2017                 &&
2018                 (
2019                         broadcast == NOTIF_ALL
2020                         ||
2021                         broadcast == NOTIF_ALL_EXCEPT
2022                 )
2023                 &&
2024                 !(
2025                         net_type == MSG_ANNCE
2026                         ||
2027                         net_type == MSG_CENTER
2028                 )
2029         )
2030         {
2031                 Local_Notification_WOVA(
2032                         net_type, net_name,
2033                         notif.nent_stringcount,
2034                         notif.nent_floatcount,
2035                         s1, s2, s3, s4,
2036                         f1, f2, f3, f4);
2037         }
2038
2039         if(net_type == MSG_CHOICE)
2040         {
2041                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
2042                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
2043                 // It's slow, but it's better than the alternatives:
2044                 //   1. Constantly networking all info and letting client decide
2045                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
2046                 entity found_choice;
2047
2048                 #define RECURSE_FROM_CHOICE(ent,action) do { \
2049                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) \
2050                         { \
2051                                 switch(ent.msg_choice_choices[net_name - 1]) \
2052                                 { \
2053                                         case 1: found_choice = notif.nent_optiona; break; \
2054                                         case 2: found_choice = notif.nent_optionb; break; \
2055                                         default: action; \
2056                                 } \
2057                         } \
2058                         else { found_choice = notif.nent_optiona; } \
2059                         Send_Notification_WOVA( \
2060                                 NOTIF_ONE_ONLY, \
2061                                 ent, \
2062                                 found_choice.nent_type, \
2063                                 found_choice.nent_id, \
2064                                 found_choice.nent_stringcount, \
2065                                 found_choice.nent_floatcount, \
2066                                 s1, s2, s3, s4, \
2067                                 f1, f2, f3, f4); \
2068                 } while(0)
2069
2070                 switch(broadcast)
2071                 {
2072                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
2073                         {
2074                                 if(IS_REAL_CLIENT(client))
2075                                 {
2076                                         RECURSE_FROM_CHOICE(client, return);
2077                                 }
2078                                 break;
2079                         }
2080                         default:
2081                         {
2082                                 entity to;
2083                                 FOR_EACH_REALCLIENT(to)
2084                                 {
2085                                         if(Notification_ShouldSend(broadcast, to, client))
2086                                         {
2087                                                 RECURSE_FROM_CHOICE(to, continue);
2088                                         }
2089                                 }
2090                                 break;
2091                         }
2092                 }
2093         }
2094         else
2095         {
2096                 entity net_notif = spawn();
2097                 net_notif.owner = notif;
2098                 net_notif.classname = "net_notification";
2099                 net_notif.nent_broadcast = broadcast;
2100                 net_notif.nent_client = client;
2101                 net_notif.nent_net_type = net_type;
2102                 net_notif.nent_net_name = net_name;
2103                 net_notif.nent_stringcount = notif.nent_stringcount;
2104                 net_notif.nent_floatcount = notif.nent_floatcount;
2105
2106                 for(int i = 0; i < net_notif.nent_stringcount; ++i)
2107                         { net_notif.nent_strings[i] = strzone(...(i, string)); }
2108                 for(int i = 0; i < net_notif.nent_floatcount; ++i)
2109                         { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
2110
2111                 net_notif.think = Net_Notification_Remove;
2112                 net_notif.nextthink =
2113                         ((time > autocvar_notification_lifetime_mapload)
2114                         ?
2115                                 (time + autocvar_notification_lifetime_runtime)
2116                                 :
2117                                 autocvar_notification_lifetime_mapload
2118                         );
2119
2120                 Net_LinkEntity(net_notif, false, 0, Net_Write_Notification);
2121         }
2122 }
2123
2124 // WOVA = Without Variable Arguments
2125 void Send_Notification_WOVA(
2126         float broadcast, entity client,
2127         float net_type, float net_name,
2128         float stringcount, float floatcount,
2129         string s1, string s2, string s3, string s4,
2130         float f1, float f2, float f3, float f4)
2131 {
2132         #ifdef NOTIFICATIONS_DEBUG
2133         entity notif = Get_Notif_Ent(net_type, net_name);
2134         Debug_Notification(sprintf(
2135                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
2136                 sprintf(
2137                         "%s, '%s', %s, %s",
2138                         Get_Notif_BroadcastName(broadcast),
2139                         client.classname,
2140                         Get_Notif_TypeName(net_type),
2141                         notif.nent_name
2142                 ),
2143                 stringcount,
2144                 floatcount,
2145                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2146                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2147         ));
2148         #endif
2149
2150         #define VARITEM(stringc,floatc,args) \
2151                 if((stringcount == stringc) && (floatcount == floatc)) \
2152                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2153         EIGHT_VARS_TO_VARARGS_VARLIST
2154         #undef VARITEM
2155         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2156 }
2157
2158 // WOCOVA = Without Counts Or Variable Arguments
2159 void Send_Notification_WOCOVA(
2160         float broadcast, entity client,
2161         float net_type, float net_name,
2162         string s1, string s2, string s3, string s4,
2163         float f1, float f2, float f3, float f4)
2164 {
2165         entity notif = Get_Notif_Ent(net_type, net_name);
2166
2167         #ifdef NOTIFICATIONS_DEBUG
2168         Debug_Notification(sprintf(
2169                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
2170                 sprintf(
2171                         "%s, '%s', %s, %s",
2172                         Get_Notif_BroadcastName(broadcast),
2173                         client.classname,
2174                         Get_Notif_TypeName(net_type),
2175                         notif.nent_name
2176                 ),
2177                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2178                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2179         ));
2180         #endif
2181
2182         #define VARITEM(stringc,floatc,args) \
2183                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
2184                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2185         EIGHT_VARS_TO_VARARGS_VARLIST
2186         #undef VARITEM
2187         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2188 }
2189 #endif // ifdef SVQC