qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 if (autocvar_cl_ghost_items_color)
  54                 {
  55                         this.alpha = autocvar_cl_ghost_items;
  56                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  57                 }
  58                 else
  59                         this.alpha = -1;
  60         }
  61
  62         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67
  68         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  69 }
  70
  71 void ItemDraw(entity this)
  72 {
  73     if(this.gravity)
  74     {
  75         Movetype_Physics_MatchServer(this, false);
  76         if(IS_ONGROUND(this))
  77         { // For some reason avelocity gets set to '0 0 0' here ...
  78             this.oldorigin = this.origin;
  79             this.gravity = 0;
  80
  81             if(autocvar_cl_animate_items)
  82             { // ... so reset it if animations are requested.
  83                 if(this.ItemStatus & ITS_ANIMATE1)
  84                     this.avelocity = '0 180 0';
  85
  86                 if(this.ItemStatus & ITS_ANIMATE2)
  87                     this.avelocity = '0 -90 0';
  88             }
  89
  90             // delay is for blocking item's position for a while;
  91             // it's a workaround for dropped weapons that receive the position
  92             // another time right after they spawn overriding animation position
  93             this.onground_time = time + 0.5;
  94         }
  95     }
  96     else if (autocvar_cl_animate_items)
  97     {
  98         if(this.ItemStatus & ITS_ANIMATE1)
  99         {
 100                 if(!this.item_simple)
 101                 this.angles += this.avelocity * frametime;
 102             float fade_in = bound(0, time - this.onground_time, 1);
 103             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 104         }
 105
 106         if(this.ItemStatus & ITS_ANIMATE2)
 107         {
 108                 if(!this.item_simple)
 109                 this.angles += this.avelocity * frametime;
 110             float fade_in = bound(0, time - this.onground_time, 1);
 111             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 112         }
 113     }
 114
 115     Item_SetAlpha(this);
 116 }
 117
 118 void Item_PreDraw(entity this)
 119 {
 120         if(warpzone_warpzones_exist)
 121         {
 122                 setpredraw(this, func_null); // no need to keep running this
 123                 return;
 124         }
 125         float alph;
 126         vector org = getpropertyvec(VF_ORIGIN);
 127         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 128                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 129         if(this.fade_start)
 130         {
 131                 if(vdist(org - this.origin, >, this.fade_end))
 132                         alph = 0; // save on some processing
 133                 else if(vdist(org - this.origin, <, this.fade_start))
 134                         alph = 1; // more processing saved
 135                 else
 136                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 137         }
 138         else
 139                 alph = 1;
 140         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 141         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 142                 this.alpha = alph;
 143         if(alph <= 0)
 144                 this.drawmask = 0;
 145         //else
 146                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 147 }
 148
 149 void ItemRemove(entity this)
 150 {
 151         if(this.mdl)
 152                 strunzone(this.mdl);
 153 }
 154
 155 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 156 {
 157     int sf = ReadByte();
 158
 159     if(sf & ISF_LOCATION)
 160     {
 161         this.origin = ReadVector();
 162         setorigin(this, this.origin);
 163         this.oldorigin = this.origin;
 164     }
 165
 166     if(sf & ISF_ANGLES)
 167     {
 168         this.angles_x = ReadAngle();
 169         this.angles_y = ReadAngle();
 170         this.angles_z = ReadAngle();
 171     }
 172
 173     if(sf & ISF_SIZE)
 174     {
 175         float use_bigsize = ReadByte();
 176         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 177     }
 178
 179     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 180     {
 181         this.ItemStatus = ReadByte();
 182
 183         Item_SetAlpha(this);
 184
 185         if(autocvar_cl_fullbright_items)
 186             if(this.ItemStatus & ITS_ALLOWFB)
 187                 this.effects |= EF_FULLBRIGHT;
 188
 189         if(this.ItemStatus & ITS_GLOW)
 190         {
 191             if(this.ItemStatus & ITS_AVAILABLE)
 192                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 193             else
 194                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 195         }
 196     }
 197
 198     if(sf & ISF_MODEL)
 199     {
 200         this.drawmask  = MASK_NORMAL;
 201                 set_movetype(this, MOVETYPE_TOSS);
 202                 if (isnew) IL_PUSH(g_drawables, this);
 203         this.draw       = ItemDraw;
 204         this.solid = SOLID_TRIGGER;
 205         //this.flags |= FL_ITEM;
 206
 207         bool use_bigsize = ReadByte();
 208
 209         this.fade_end = ReadShort();
 210         this.fade_start = ReadShort();
 211         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 212                 setpredraw(this, Item_PreDraw);
 213
 214         if(this.mdl)
 215             strunzone(this.mdl);
 216
 217         this.mdl = "";
 218         string _fn = ReadString();
 219         this.item_simple = false; // reset it!
 220
 221         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 222         {
 223             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 224             this.item_simple = true;
 225
 226             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 227                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 228             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 229                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 230             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 231                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 232             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 233                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 234             else
 235             {
 236                 this.item_simple = false;
 237                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 238             }
 239         }
 240
 241         if(!this.item_simple)
 242             this.mdl = strzone(_fn);
 243
 244
 245         if(this.mdl == "")
 246             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 247
 248         precache_model(this.mdl);
 249         _setmodel(this, this.mdl);
 250
 251         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 252     }
 253
 254     if(sf & ISF_COLORMAP)
 255     {
 256         this.colormap = ReadShort();
 257         this.item_glowmod_x = ReadByte() / 255.0;
 258         this.item_glowmod_y = ReadByte() / 255.0;
 259         this.item_glowmod_z = ReadByte() / 255.0;
 260     }
 261
 262     if(sf & ISF_DROP)
 263     {
 264         this.gravity = 1;
 265         this.pushable = true;
 266         //this.angles = '0 0 0';
 267         set_movetype(this, MOVETYPE_TOSS);
 268         this.velocity = ReadVector();
 269         setorigin(this, this.oldorigin);
 270
 271         if(!this.move_time)
 272         {
 273             this.move_time = time;
 274             this.spawntime = time;
 275         }
 276         else
 277             this.move_time = max(this.move_time, time);
 278     }
 279
 280     if(autocvar_cl_animate_items)
 281     {
 282         if(this.ItemStatus & ITS_ANIMATE1)
 283             this.avelocity = '0 180 0';
 284
 285         if(this.ItemStatus & ITS_ANIMATE2)
 286             this.avelocity = '0 -90 0';
 287     }
 288
 289     this.entremove = ItemRemove;
 290
 291     return true;
 292 }
 293
 294 #endif
 295
 296 #ifdef SVQC
 297 bool ItemSend(entity this, entity to, int sf)
 298 {
 299         if(this.gravity)
 300                 sf |= ISF_DROP;
 301         else
 302                 sf &= ~ISF_DROP;
 303
 304         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 305         WriteByte(MSG_ENTITY, sf);
 306
 307         //WriteByte(MSG_ENTITY, this.cnt);
 308         if(sf & ISF_LOCATION)
 309         {
 310                 WriteVector(MSG_ENTITY, this.origin);
 311         }
 312
 313         if(sf & ISF_ANGLES)
 314         {
 315                 WriteAngle(MSG_ENTITY, this.angles_x);
 316                 WriteAngle(MSG_ENTITY, this.angles_y);
 317                 WriteAngle(MSG_ENTITY, this.angles_z);
 318         }
 319
 320         if(sf & ISF_SIZE)
 321         {
 322                 Pickup p = this.itemdef;
 323                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 324         }
 325
 326         if(sf & ISF_STATUS)
 327                 WriteByte(MSG_ENTITY, this.ItemStatus);
 328
 329         if(sf & ISF_MODEL)
 330         {
 331                 Pickup p = this.itemdef;
 332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 333                 WriteShort(MSG_ENTITY, this.fade_end);
 334                 WriteShort(MSG_ENTITY, this.fade_start);
 335
 336                 if(this.mdl == "")
 337                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 338
 339                 WriteString(MSG_ENTITY, this.mdl);
 340         }
 341
 342
 343         if(sf & ISF_COLORMAP)
 344         {
 345                 WriteShort(MSG_ENTITY, this.colormap);
 346                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 347         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 348         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 349         }
 350
 351         if(sf & ISF_DROP)
 352         {
 353                 WriteVector(MSG_ENTITY, this.velocity);
 354         }
 355
 356         return true;
 357 }
 358
 359 void ItemUpdate(entity this)
 360 {
 361         this.oldorigin = this.origin;
 362         this.SendFlags |= ISF_LOCATION;
 363 }
 364
 365 void UpdateItemAfterTeleport(entity this)
 366 {
 367         if(getSendEntity(this) == ItemSend)
 368                 ItemUpdate(this);
 369 }
 370
 371 bool have_pickup_item(entity this)
 372 {
 373         if(this.itemdef.instanceOfPowerup)
 374         {
 375                 if(autocvar_g_powerups > 0)
 376                         return true;
 377                 if(autocvar_g_powerups == 0)
 378                         return false;
 379         }
 380         else
 381         {
 382                 if(autocvar_g_pickup_items > 0)
 383                         return true;
 384                 if(autocvar_g_pickup_items == 0)
 385                         return false;
 386                 if(g_weaponarena)
 387                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 388                                 return false;
 389         }
 390         return true;
 391 }
 392
 393 /*
 394 float Item_Customize()
 395 {
 396         if(this.spawnshieldtime)
 397                 return true;
 398         if(this.weapons & ~other.weapons)
 399         {
 400                 this.colormod = '0 0 0';
 401                 this.glowmod = this.colormod;
 402                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 403                 return true;
 404         }
 405         else
 406         {
 407                 if(g_ghost_items)
 408                 {
 409                         this.colormod = stov(autocvar_g_ghost_items_color);
 410                         this.glowmod = this.colormod;
 411                         this.alpha = g_ghost_items;
 412                         return true;
 413                 }
 414                 else
 415                         return false;
 416         }
 417 }
 418 */
 419
 420 void Item_Show (entity e, float mode)
 421 {
 422         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 423         e.ItemStatus &= ~ITS_STAYWEP;
 424         entity def = e.itemdef;
 425         if (mode > 0)
 426         {
 427                 // make the item look normal, and be touchable
 428                 e.model = e.mdl;
 429                 e.solid = SOLID_TRIGGER;
 430                 e.spawnshieldtime = 1;
 431                 e.ItemStatus |= ITS_AVAILABLE;
 432         }
 433         else if (mode < 0)
 434         {
 435                 // hide the item completely
 436                 e.model = string_null;
 437                 e.solid = SOLID_NOT;
 438                 e.spawnshieldtime = 1;
 439                 e.ItemStatus &= ~ITS_AVAILABLE;
 440         }
 441         else
 442         {
 443                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 444                         || e.team // weapon stay isn't supported for teamed weapons
 445                         ;
 446                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 447                 {
 448                         // make the item translucent and not touchable
 449                         e.model = e.mdl;
 450                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 451                         e.effects |= EF_STARDUST;
 452                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 453                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 454                 }
 455                 else
 456                 {
 457                         //setmodel(e, "null");
 458                         e.solid = SOLID_NOT;
 459                         e.colormod = '0 0 0';
 460                         //e.glowmod = e.colormod;
 461                         e.spawnshieldtime = 1;
 462                         e.ItemStatus &= ~ITS_AVAILABLE;
 463                 }
 464         }
 465
 466         if (def.m_glow)
 467                 e.ItemStatus |= ITS_GLOW;
 468
 469         if (autocvar_g_nodepthtestitems)
 470                 e.effects |= EF_NODEPTHTEST;
 471
 472
 473         if (autocvar_g_fullbrightitems)
 474                 e.ItemStatus |= ITS_ALLOWFB;
 475
 476         if (autocvar_sv_simple_items)
 477                 e.ItemStatus |= ITS_ALLOWSI;
 478
 479         // relink entity (because solid may have changed)
 480         setorigin(e, e.origin);
 481         e.SendFlags |= ISF_STATUS;
 482 }
 483
 484 void Item_Think(entity this)
 485 {
 486         this.nextthink = time;
 487         if(this.origin != this.oldorigin)
 488                 ItemUpdate(this);
 489 }
 490
 491 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 492 bool Item_ItemsTime_Allow(GameItem it);
 493 float Item_ItemsTime_UpdateTime(entity e, float t);
 494 void Item_ItemsTime_SetTime(entity e, float t);
 495 void Item_ItemsTime_SetTimesForAllPlayers();
 496
 497 void Item_Respawn (entity this)
 498 {
 499         Item_Show(this, 1);
 500         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 501         setorigin(this, this.origin);
 502
 503     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 504         {
 505                 float t = Item_ItemsTime_UpdateTime(this, 0);
 506                 Item_ItemsTime_SetTime(this, t);
 507                 Item_ItemsTime_SetTimesForAllPlayers();
 508         }
 509
 510         setthink(this, Item_Think);
 511         this.nextthink = time;
 512
 513         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 514         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 515 }
 516
 517 void Item_RespawnCountdown (entity this)
 518 {
 519         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 520         {
 521                 if(this.waypointsprite_attached)
 522                         WaypointSprite_Kill(this.waypointsprite_attached);
 523                 Item_Respawn(this);
 524         }
 525         else
 526         {
 527                 this.nextthink = time + 1;
 528                 this.item_respawncounter += 1;
 529                 if(this.item_respawncounter == 1)
 530                 {
 531                         do {
 532                                 {
 533                                         entity wi = Weapons_from(this.weapon);
 534                                         if (wi != WEP_Null) {
 535                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 536                                                 wp.wp_extra = wi.m_id;
 537                                                 break;
 538                                         }
 539                                 }
 540                                 {
 541                                         entity ii = this.itemdef;
 542                                         if (ii != NULL) {
 543                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 544                                                 wp.wp_extra = ii.m_id;
 545                                                 break;
 546                                         }
 547                                 }
 548                         } while (0);
 549                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 550             if(this.waypointsprite_attached)
 551             {
 552                 GameItem def = this.itemdef;
 553                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 554                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 555                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 556             }
 557                 }
 558
 559                 if(this.waypointsprite_attached)
 560                 {
 561                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 562                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 563                                 {
 564                                         msg_entity = it;
 565                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 566                                 }
 567                         });
 568
 569                         WaypointSprite_Ping(this.waypointsprite_attached);
 570                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 571                 }
 572         }
 573 }
 574
 575 void Item_RespawnThink(entity this)
 576 {
 577         this.nextthink = time;
 578         if(this.origin != this.oldorigin)
 579                 ItemUpdate(this);
 580
 581         if(time >= this.wait)
 582                 Item_Respawn(this);
 583 }
 584
 585 void Item_ScheduleRespawnIn(entity e, float t)
 586 {
 587         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 588         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 589         {
 590                 setthink(e, Item_RespawnCountdown);
 591                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 592                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 593                 e.item_respawncounter = 0;
 594                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 595                 {
 596                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 597                         Item_ItemsTime_SetTime(e, t);
 598                         Item_ItemsTime_SetTimesForAllPlayers();
 599                 }
 600         }
 601         else
 602         {
 603                 setthink(e, Item_RespawnThink);
 604                 e.nextthink = time;
 605                 e.scheduledrespawntime = time + t;
 606                 e.wait = time + t;
 607
 608                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 609                 {
 610                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 611                         Item_ItemsTime_SetTime(e, t);
 612                         Item_ItemsTime_SetTimesForAllPlayers();
 613                 }
 614         }
 615 }
 616
 617 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 618 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 619 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 620
 621 /// Adjust respawn time according to the number of players.
 622 float adjust_respawntime(float normal_respawntime) {
 623         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 624         float o = autocvar_g_pickup_respawntime_scaling_offset;
 625         float l = autocvar_g_pickup_respawntime_scaling_linear;
 626
 627         if (r == 0 && l == 1) {
 628                 return normal_respawntime;
 629         }
 630
 631         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 632         TeamBalance_GetTeamCounts(balance, NULL);
 633         int players = 0;
 634         for (int i = 1; i <= NUM_TEAMS; ++i)
 635         {
 636                 if (TeamBalance_IsTeamAllowed(balance, i))
 637                 {
 638                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 639                 }
 640         }
 641         TeamBalance_Destroy(balance);
 642
 643         if (players >= 2) {
 644                 return normal_respawntime * (r / (players + o) + l);
 645         } else {
 646                 return normal_respawntime;
 647         }
 648 }
 649
 650 void Item_ScheduleRespawn(entity e)
 651 {
 652         if(e.respawntime > 0)
 653         {
 654                 Item_Show(e, 0);
 655
 656                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 657                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 658
 659                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 660                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 661                 Item_ScheduleRespawnIn(e, respawn_in);
 662         }
 663         else // if respawntime is -1, this item does not respawn
 664                 Item_Show(e, -1);
 665 }
 666
 667 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 668         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 669
 670 float shared_random;
 671 STATIC_INIT(shared_random) { shared_random = random(); }
 672 void Item_ScheduleInitialRespawn(entity e)
 673 {
 674         Item_Show(e, 0);
 675
 676         float spawn_in;
 677         if (autocvar_g_pickup_respawntime_initial_random == 0)
 678         {
 679                 // range: respawntime .. respawntime + respawntimejitter
 680                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 681         }
 682         else if (autocvar_g_pickup_respawntime_initial_random == 1)
 683         {
 684                 // range:
 685                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 686                 // else: 0 .. ITEM_RESPAWN_TICKS
 687                 // this is to prevent powerups spawning unexpectedly without waypoints
 688                 spawn_in = ITEM_RESPAWN_TICKS + shared_random * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 689         }
 690         else
 691         {
 692                 // range: same as 1
 693                 spawn_in = ITEM_RESPAWN_TICKS + random() * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 694         }
 695
 696         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 697 }
 698
 699 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 700         entity ammo_entity)
 701 {
 702         if (num_weapons == 0)
 703         {
 704                 return;
 705         }
 706         int num_potential_weapons = tokenize_console(weapon_names);
 707         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 708         {
 709                 RandomSelection_Init();
 710                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 711                         ++weapon_index)
 712                 {
 713                         string weapon = argv(weapon_index);
 714                         FOREACH(Weapons, it != WEP_Null,
 715                         {
 716                                 // Finding a weapon which player doesn't have.
 717                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 718                                 {
 719                                         RandomSelection_AddEnt(it, 1, 1);
 720                                         break;
 721                                 }
 722                         });
 723                 }
 724                 if (RandomSelection_chosen_ent == NULL)
 725                 {
 726                         return;
 727                 }
 728                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 729                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 730                 {
 731                         continue;
 732                 }
 733                 if (GetResourceAmount(receiver,
 734                         RandomSelection_chosen_ent.ammo_type) != 0)
 735                 {
 736                         continue;
 737                 }
 738                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 739                         GetResourceAmount(ammo_entity,
 740                         RandomSelection_chosen_ent.ammo_type));
 741         }
 742 }
 743
 744 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 745 {
 746         float amount = GetResourceAmount(item, resource_type);
 747         if (amount == 0)
 748         {
 749                 return false;
 750         }
 751         float player_amount = GetResourceAmount(player, resource_type);
 752         if (item.spawnshieldtime)
 753         {
 754                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 755                 {
 756                         return false;
 757                 }
 758                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 759                 return true;
 760         }
 761         if (g_weapon_stay != 2)
 762         {
 763                 return false;
 764         }
 765         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 766         return true;
 767 }
 768
 769 float Item_GiveTo(entity item, entity player)
 770 {
 771         float pickedup;
 772
 773         // if nothing happens to player, just return without taking the item
 774         pickedup = false;
 775         int _switchweapon = 0;
 776         // in case the player has autoswitch enabled do the following:
 777         // if the player is using their best weapon before items are given, they
 778         // probably want to switch to an even better weapon after items are given
 779
 780         if(CS(player).autoswitch)
 781         {
 782                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 783                 {
 784                         .entity weaponentity = weaponentities[slot];
 785                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 786                         {
 787                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 788                                         _switchweapon |= BIT(slot);
 789
 790                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 791                                         _switchweapon |= BIT(slot);
 792                         }
 793                 }
 794         }
 795         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 796         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 797         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 798         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 799         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 800         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 801         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 802         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 803         if (item.itemdef.instanceOfWeaponPickup)
 804         {
 805                 WepSet w;
 806                 w = item.weapons;
 807                 w &= ~player.weapons;
 808
 809                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 810                 {
 811                         pickedup = true;
 812                         FOREACH(Weapons, it != WEP_Null, {
 813                                 if(w & (it.m_wepset))
 814                                 {
 815                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 816                                         {
 817                                                 .entity weaponentity = weaponentities[slot];
 818                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 819                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 820                                         }
 821                                         W_GiveWeapon(player, it.m_id);
 822                                 }
 823                         });
 824                 }
 825         }
 826
 827         if (item.itemdef.instanceOfPowerup)
 828         {
 829                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 830                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 831                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 832                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 833         }
 834
 835         int its;
 836         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 837         {
 838                 pickedup = true;
 839                 player.items |= its;
 840                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 841         }
 842
 843         if (item.strength_finished)
 844         {
 845                 pickedup = true;
 846                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 847         }
 848         if (item.invincible_finished)
 849         {
 850                 pickedup = true;
 851                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 852         }
 853         if (item.superweapons_finished)
 854         {
 855                 pickedup = true;
 856                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 857         }
 858
 859         // always eat teamed entities
 860         if(item.team)
 861                 pickedup = true;
 862
 863         if (!pickedup)
 864                 return 0;
 865
 866         // crude hack to enforce switching weapons
 867         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 868         {
 869                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 870                 {
 871                         .entity weaponentity = weaponentities[slot];
 872                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 873                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 874                 }
 875                 return 1;
 876         }
 877
 878         if(_switchweapon)
 879         {
 880                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 881                 {
 882                         .entity weaponentity = weaponentities[slot];
 883                         if(_switchweapon & BIT(slot))
 884                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 885                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 886                 }
 887         }
 888
 889         return 1;
 890 }
 891
 892 void Item_Touch(entity this, entity toucher)
 893 {
 894         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 895         if (Item_IsLoot(this))
 896         {
 897                 if (ITEM_TOUCH_NEEDKILL())
 898                 {
 899                         delete(this);
 900                         return;
 901                 }
 902         }
 903
 904         if(!(toucher.flags & FL_PICKUPITEMS)
 905         || STAT(FROZEN, toucher)
 906         || IS_DEAD(toucher)
 907         || (this.solid != SOLID_TRIGGER)
 908         || (this.owner == toucher)
 909         || (time < this.item_spawnshieldtime)
 910         ) { return; }
 911
 912         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 913         {
 914                 case MUT_ITEMTOUCH_RETURN: { return; }
 915                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 916         }
 917
 918         toucher = M_ARGV(1, entity);
 919
 920         if (Item_IsExpiring(this))
 921         {
 922                 this.strength_finished = max(0, this.strength_finished - time);
 923                 this.invincible_finished = max(0, this.invincible_finished - time);
 924                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 925         }
 926         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 927         if (!gave)
 928         {
 929                 if (Item_IsExpiring(this))
 930                 {
 931                         // undo what we did above
 932                         this.strength_finished += time;
 933                         this.invincible_finished += time;
 934                         this.superweapons_finished += time;
 935                 }
 936                 return;
 937         }
 938
 939 LABEL(pickup)
 940
 941         STAT(LAST_PICKUP, toucher) = time;
 942
 943         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 944         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 945
 946         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 947         if (wasfreed(this))
 948         {
 949                 return;
 950         }
 951
 952         if (Item_IsLoot(this))
 953         {
 954                 delete(this);
 955                 return;
 956         }
 957         if (!this.spawnshieldtime)
 958         {
 959                 return;
 960         }
 961         entity e;
 962         if (this.team)
 963         {
 964                 RandomSelection_Init();
 965                 IL_EACH(g_items, it.team == this.team,
 966                 {
 967                         if (it.itemdef) // is a registered item
 968                         {
 969                                 Item_Show(it, -1);
 970                                 it.scheduledrespawntime = 0;
 971                                 RandomSelection_AddEnt(it, it.cnt, 0);
 972                         }
 973                 });
 974                 e = RandomSelection_chosen_ent;
 975                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 976         }
 977         else
 978                 e = this;
 979         Item_ScheduleRespawn(e);
 980 }
 981
 982 void Item_Reset(entity this)
 983 {
 984         Item_Show(this, !this.state);
 985         setorigin(this, this.origin);
 986
 987         if (Item_IsLoot(this))
 988         {
 989                 return;
 990         }
 991         setthink(this, Item_Think);
 992         this.nextthink = time;
 993         if (this.waypointsprite_attached)
 994         {
 995                 WaypointSprite_Kill(this.waypointsprite_attached);
 996         }
 997         if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 998         {
 999                 Item_ScheduleInitialRespawn(this);
1000         }
1001 }
1002
1003 void Item_FindTeam(entity this)
1004 {
1005         entity e;
1006
1007         if(this.effects & EF_NODRAW)
1008         {
1009                 // marker for item team search
1010                 LOG_TRACE("Initializing item team ", ftos(this.team));
1011                 RandomSelection_Init();
1012                 IL_EACH(g_items, it.team == this.team,
1013                 {
1014                         if(it.itemdef) // is a registered item
1015                                 RandomSelection_AddEnt(it, it.cnt, 0);
1016                 });
1017
1018                 e = RandomSelection_chosen_ent;
1019                 e.state = 0;
1020                 Item_Show(e, 1);
1021
1022                 IL_EACH(g_items, it.team == this.team,
1023                 {
1024                         if(it.itemdef) // is a registered item
1025                         {
1026                                 if(it != e)
1027                                 {
1028                                         // make it non-spawned
1029                                         Item_Show(it, -1);
1030                                         it.state = 1; // state 1 = initially hidden item, apparently
1031                                 }
1032                                 it.effects &= ~EF_NODRAW;
1033                         }
1034                 });
1035
1036                 Item_Reset(this);
1037         }
1038 }
1039
1040 // Savage: used for item garbage-collection
1041 void RemoveItem(entity this)
1042 {
1043         if(wasfreed(this) || !this) { return; }
1044         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1045         delete(this);
1046 }
1047
1048 // pickup evaluation functions
1049 // these functions decide how desirable an item is to the bots
1050
1051 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1052
1053 float weapon_pickupevalfunc(entity player, entity item)
1054 {
1055         // See if I have it already
1056         if(player.weapons & item.weapons)
1057         {
1058                 // If I can pick it up
1059                 if(!item.spawnshieldtime)
1060                         return 0;
1061                 return ammo_pickupevalfunc(player, item);
1062         }
1063
1064         // reduce weapon value if bot already got a good arsenal
1065         float c = 1;
1066         int weapons_value = 0;
1067         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1068                 weapons_value += it.bot_pickupbasevalue;
1069         });
1070         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1071
1072         return item.bot_pickupbasevalue * c;
1073 }
1074
1075 float ammo_pickupevalfunc(entity player, entity item)
1076 {
1077         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1078         entity wpn = NULL;
1079         float c = 0;
1080         float rating = 0;
1081
1082         // Detect needed ammo
1083         if(item.itemdef.instanceOfWeaponPickup)
1084         {
1085                 entity ammo = NULL;
1086                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1087                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1088                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1089                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1090                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1091                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1092
1093                 if(!ammo)
1094                         return 0;
1095                 wpn = item;
1096                 rating = ammo.m_botvalue;
1097         }
1098         else
1099         {
1100                 FOREACH(Weapons, it != WEP_Null, {
1101                         if(!(player.weapons & (it.m_wepset)))
1102                                 continue;
1103
1104                         switch(it.ammo_type)
1105                         {
1106                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1107                                 case RESOURCE_BULLETS: need_nails   = true; break;
1108                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1109                                 case RESOURCE_CELLS:   need_cells   = true; break;
1110                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1111                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1112                         }
1113                 });
1114                 rating = item.bot_pickupbasevalue;
1115         }
1116
1117         float noammorating = 0.5;
1118
1119         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1120                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1121
1122         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1123                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1124
1125         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1126                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1127
1128         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1129                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1130
1131         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1132                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1133
1134         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1135                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1136
1137         rating *= min(c, 2);
1138         if(wpn)
1139                 rating += wpn.bot_pickupbasevalue * 0.1;
1140         return rating;
1141 }
1142
1143 float healtharmor_pickupevalfunc(entity player, entity item)
1144 {
1145         float c = 0;
1146         float rating = item.bot_pickupbasevalue;
1147
1148         float itemarmor = item.armorvalue;
1149         float itemhealth = item.health;
1150
1151         if(item.item_group)
1152         {
1153                 itemarmor *= min(4, item.item_group_count);
1154                 itemhealth *= min(4, item.item_group_count);
1155         }
1156
1157         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1158                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1159
1160         if (itemhealth && (player.health < item.max_health))
1161                 c = itemhealth / max(1, player.health);
1162
1163         rating *= min(2, c);
1164         return rating;
1165 }
1166
1167 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1168 {
1169         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1170                 RemoveItem(this);
1171 }
1172
1173 void item_use(entity this, entity actor, entity trigger)
1174 {
1175         // use the touch function to handle collection
1176         gettouch(this)(this, actor);
1177 }
1178
1179 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1180 {
1181         string itemname = def.m_name;
1182         Model itemmodel = def.m_model;
1183     Sound pickupsound = def.m_sound;
1184         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1185         float pickupbasevalue = def.m_botvalue;
1186         int itemflags = def.m_itemflags;
1187
1188         startitem_failed = false;
1189
1190         this.item_model_ent = itemmodel;
1191     this.item_pickupsound_ent = pickupsound;
1192
1193     if(def.m_iteminit)
1194         def.m_iteminit(this);
1195
1196         if(!this.respawntime) // both need to be set
1197         {
1198                 this.respawntime = defaultrespawntime;
1199                 this.respawntimejitter = defaultrespawntimejitter;
1200         }
1201
1202         if(!this.pickup_anyway && def.m_pickupanyway)
1203                 this.pickup_anyway = def.m_pickupanyway();
1204
1205         int itemid = def.m_itemid;
1206         this.items = itemid;
1207         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1208         this.weapon = weaponid;
1209
1210         if(!this.fade_end)
1211         {
1212                 this.fade_start = autocvar_g_items_mindist;
1213                 this.fade_end = autocvar_g_items_maxdist;
1214         }
1215
1216         if(weaponid)
1217                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1218
1219         this.flags = FL_ITEM | itemflags;
1220         IL_PUSH(g_items, this);
1221
1222         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1223         {
1224                 startitem_failed = true;
1225                 delete(this);
1226                 return;
1227         }
1228
1229         if (Item_IsLoot(this))
1230         {
1231                 this.reset = SUB_Remove;
1232                 set_movetype(this, MOVETYPE_TOSS);
1233
1234                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1235                 setthink(this, RemoveItem);
1236                 this.nextthink = time + 20;
1237
1238                 this.takedamage = DAMAGE_YES;
1239                 this.event_damage = Item_Damage;
1240
1241                 if (Item_IsExpiring(this))
1242                 {
1243                         // if item is worthless after a timer, have it expire then
1244                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1245                 }
1246
1247                 // don't drop if in a NODROP zone (such as lava)
1248                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1249                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1250                 {
1251                         startitem_failed = true;
1252                         delete(this);
1253                         return;
1254                 }
1255         }
1256         else
1257         {
1258                 if(!have_pickup_item(this))
1259                 {
1260                         startitem_failed = true;
1261                         delete(this);
1262                         return;
1263                 }
1264
1265                 if(this.angles != '0 0 0')
1266                         this.SendFlags |= ISF_ANGLES;
1267
1268                 this.reset = Item_Reset;
1269                 // it's a level item
1270                 if(this.spawnflags & 1)
1271                         this.noalign = 1;
1272                 if (this.noalign > 0)
1273                         set_movetype(this, MOVETYPE_NONE);
1274                 else
1275                         set_movetype(this, MOVETYPE_TOSS);
1276                 // do item filtering according to game mode and other things
1277                 if (this.noalign <= 0)
1278                 {
1279                         // first nudge it off the floor a little bit to avoid math errors
1280                         setorigin(this, this.origin + '0 0 1');
1281                         // set item size before we spawn a spawnfunc_waypoint
1282                         setsize(this, def.m_mins, def.m_maxs);
1283                         this.SendFlags |= ISF_SIZE;
1284                         // note droptofloor returns false if stuck/or would fall too far
1285                         if (!this.noalign)
1286                                 droptofloor(this);
1287                         waypoint_spawnforitem(this);
1288                 }
1289
1290                 /*
1291                  * can't do it that way, as it would break maps
1292                  * TODO make a target_give like entity another way, that perhaps has
1293                  * the weapon name in a key
1294                 if(this.targetname)
1295                 {
1296                         // target_give not yet supported; maybe later
1297                         print("removed targeted ", this.classname, "\n");
1298                         startitem_failed = true;
1299                         delete(this);
1300                         return;
1301                 }
1302                 */
1303
1304                 if(this.targetname != "" && (this.spawnflags & 16))
1305                         this.use = item_use;
1306
1307                 if(autocvar_spawn_debug >= 2)
1308                 {
1309             // why not flags & fl_item?
1310                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1311                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1312                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1313                 error("Mapper sucks.");
1314             });
1315                         this.is_item = true;
1316                 }
1317
1318                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1319
1320                 precache_model(this.model);
1321                 precache_sound(this.item_pickupsound);
1322
1323                 if (   def.instanceOfPowerup
1324                         || def.instanceOfWeaponPickup
1325                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1326                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1327                         || (itemid & (IT_KEY1 | IT_KEY2))
1328                 ) this.target = "###item###"; // for finding the nearest item using find()
1329
1330                 Item_ItemsTime_SetTime(this, 0);
1331         }
1332
1333         this.bot_pickup = true;
1334         this.bot_pickupevalfunc = pickupevalfunc;
1335         this.bot_pickupbasevalue = pickupbasevalue;
1336         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1337         this.netname = itemname;
1338         settouch(this, Item_Touch);
1339         setmodel(this, MDL_Null); // precision set below
1340         //this.effects |= EF_LOWPRECISION;
1341
1342         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1343
1344         this.SendFlags |= ISF_SIZE;
1345
1346         if (!(this.spawnflags & 1024)) {
1347                 if(def.instanceOfPowerup)
1348                         this.ItemStatus |= ITS_ANIMATE1;
1349
1350                 if(this.armorvalue || this.health)
1351                         this.ItemStatus |= ITS_ANIMATE2;
1352         }
1353
1354         if(def.instanceOfWeaponPickup)
1355         {
1356                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1357                         this.colormap = 1024; // color shirt=0 pants=0 grey
1358                 else
1359                         this.gravity = 1;
1360                 if (!(this.spawnflags & 1024))
1361                         this.ItemStatus |= ITS_ANIMATE1;
1362                 this.SendFlags |= ISF_COLORMAP;
1363         }
1364
1365         this.state = 0;
1366         if(this.team) // broken, no idea why.
1367         {
1368                 if(!this.cnt)
1369                         this.cnt = 1; // item probability weight
1370
1371                 this.effects |= EF_NODRAW; // marker for item team search
1372                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1373         }
1374         else
1375                 Item_Reset(this);
1376
1377         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1378
1379         // call this hook after everything else has been done
1380         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1381         {
1382                 startitem_failed = true;
1383                 delete(this);
1384                 return;
1385         }
1386
1387         setItemGroup(this);
1388 }
1389
1390 void StartItem(entity this, GameItem def)
1391 {
1392     def = def.m_spawnfunc_hookreplace(def, this);
1393     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1394     {
1395         delete(this);
1396         return;
1397     }
1398     this.classname = def.m_canonical_spawnfunc;
1399     _StartItem(
1400         this,
1401         this.itemdef = def,
1402         def.m_respawntime(), // defaultrespawntime
1403         def.m_respawntimejitter() // defaultrespawntimejitter
1404         );
1405 }
1406
1407 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1408 int group_count = 1;
1409
1410 void setItemGroup(entity this)
1411 {
1412         if(!IS_SMALL(this.itemdef))
1413                 return;
1414
1415         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1416         {
1417                 if(!this.item_group)
1418                 {
1419                         if(!it.item_group)
1420                         {
1421                                 it.item_group = group_count;
1422                                 group_count++;
1423                         }
1424                         this.item_group = it.item_group;
1425                 }
1426                 else // spawning item is already part of a item_group X
1427                 {
1428                         if(!it.item_group)
1429                                 it.item_group = this.item_group;
1430                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1431                         {
1432                                 int grY = it.item_group;
1433                                 // move all items of item_group Y to item_group X
1434                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1435                                 {
1436                                         if(it.item_group == grY)
1437                                                 it.item_group = this.item_group;
1438                                 });
1439                         }
1440                 }
1441         });
1442 }
1443
1444 void setItemGroupCount()
1445 {
1446         for (int k = 1; k <= group_count; k++)
1447         {
1448                 int count = 0;
1449                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1450                 if (count)
1451                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1452         }
1453 }
1454
1455 void target_items_use(entity this, entity actor, entity trigger)
1456 {
1457         if(Item_IsLoot(actor))
1458         {
1459                 EXACTTRIGGER_TOUCH(this, trigger);
1460                 delete(actor);
1461                 return;
1462         }
1463
1464         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1465                 return;
1466
1467         if(trigger.solid == SOLID_TRIGGER)
1468         {
1469                 EXACTTRIGGER_TOUCH(this, trigger);
1470         }
1471
1472         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1473         {
1474                 delete(it);
1475         });
1476
1477         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1478                 centerprint(actor, this.message);
1479 }
1480
1481 spawnfunc(target_items)
1482 {
1483         int n;
1484         string s;
1485
1486         this.use = target_items_use;
1487         if(!this.strength_finished)
1488                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1489         if(!this.invincible_finished)
1490                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1491         if(!this.superweapons_finished)
1492                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1493
1494         n = tokenize_console(this.netname);
1495         if(argv(0) == "give")
1496         {
1497                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1498         }
1499         else
1500         {
1501                 for(int j = 0; j < n; ++j)
1502                 {
1503                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1504                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1505                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1506                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1507                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1508                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1509                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1510                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1511                         else
1512                         {
1513                                 FOREACH(Buffs, it != BUFF_Null,
1514                                 {
1515                                         s = Buff_UndeprecateName(argv(j));
1516                                         if(s == it.m_name)
1517                                         {
1518                                                 STAT(BUFFS, this) |= (it.m_itemid);
1519                                                 break;
1520                                         }
1521                                 });
1522                                 FOREACH(Weapons, it != WEP_Null, {
1523                                         s = W_UndeprecateName(argv(j));
1524                                         if(s == it.netname)
1525                                         {
1526                                                 this.weapons |= (it.m_wepset);
1527                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1528                                                         it.wr_init(it);
1529                                                 break;
1530                                         }
1531                                 });
1532                         }
1533                 }
1534
1535                 string itemprefix, valueprefix;
1536                 if(this.spawnflags == 0)
1537                 {
1538                         itemprefix = "";
1539                         valueprefix = "";
1540                 }
1541                 else if(this.spawnflags == 1)
1542                 {
1543                         itemprefix = "max ";
1544                         valueprefix = "max ";
1545                 }
1546                 else if(this.spawnflags == 2)
1547                 {
1548                         itemprefix = "min ";
1549                         valueprefix = "min ";
1550                 }
1551                 else if(this.spawnflags == 4)
1552                 {
1553                         itemprefix = "minus ";
1554                         valueprefix = "max ";
1555                 }
1556                 else
1557                 {
1558                         error("invalid spawnflags");
1559                         itemprefix = valueprefix = string_null;
1560                 }
1561
1562                 this.netname = "";
1563                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1564                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1565                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1566                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1567                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1568                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1569                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1570                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1571                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1572                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1573                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1574                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1575                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1576                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1577                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1578                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1579                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1580         }
1581         this.netname = strzone(this.netname);
1582         //print(this.netname, "\n");
1583
1584         n = tokenize_console(this.netname);
1585         for(int j = 0; j < n; ++j)
1586         {
1587                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1588             it.wr_init(it);
1589             break;
1590                 });
1591         }
1592 }
1593
1594 float GiveWeapon(entity e, float wpn, float op, float val)
1595 {
1596         WepSet v0, v1;
1597         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1598         v0 = (e.weapons & s);
1599         switch(op)
1600         {
1601                 case OP_SET:
1602                         if(val > 0)
1603                                 e.weapons |= s;
1604                         else
1605                                 e.weapons &= ~s;
1606                         break;
1607                 case OP_MIN:
1608                 case OP_PLUS:
1609                         if(val > 0)
1610                                 e.weapons |= s;
1611                         break;
1612                 case OP_MAX:
1613                         if(val <= 0)
1614                                 e.weapons &= ~s;
1615                         break;
1616                 case OP_MINUS:
1617                         if(val > 0)
1618                                 e.weapons &= ~s;
1619                         break;
1620         }
1621         v1 = (e.weapons & s);
1622         return (v0 != v1);
1623 }
1624
1625 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1626 {
1627         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1628         switch(op)
1629         {
1630                 case OP_SET:
1631                         if(val > 0)
1632                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1633                         else
1634                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1635                         break;
1636                 case OP_MIN:
1637                 case OP_PLUS:
1638                         if(val > 0)
1639                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1640                         break;
1641                 case OP_MAX:
1642                         if(val <= 0)
1643                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1644                         break;
1645                 case OP_MINUS:
1646                         if(val > 0)
1647                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1648                         break;
1649         }
1650         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1651         return (had_buff != have_buff);
1652 }
1653
1654 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1655 {
1656         if(v1 == v0)
1657                 return;
1658         if(v1 <= v0 - t)
1659         {
1660                 if(snd_decr != NULL)
1661                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1662         }
1663         else if(v0 >= v0 + t)
1664         {
1665                 if(snd_incr != NULL)
1666                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1667         }
1668 }
1669
1670 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1671 {
1672         if(v0 < v1)
1673                 e.(rotfield) = max(e.(rotfield), time + rottime);
1674         else if(v0 > v1)
1675                 e.(regenfield) = max(e.(regenfield), time + regentime);
1676 }
1677 float GiveItems(entity e, float beginarg, float endarg)
1678 {
1679         float got, i, val, op;
1680         string cmd;
1681
1682         val = 999;
1683         op = OP_SET;
1684
1685         got = 0;
1686
1687         int _switchweapon = 0;
1688
1689         if(CS(e).autoswitch)
1690         {
1691                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1692                 {
1693                         .entity weaponentity = weaponentities[slot];
1694                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1695                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1696                                 _switchweapon |= BIT(slot);
1697                 }
1698         }
1699
1700         e.strength_finished = max(0, e.strength_finished - time);
1701         e.invincible_finished = max(0, e.invincible_finished - time);
1702         e.superweapons_finished = max(0, e.superweapons_finished - time);
1703
1704         PREGIVE(e, items);
1705         PREGIVE_WEAPONS(e);
1706         PREGIVE(e, strength_finished);
1707         PREGIVE(e, invincible_finished);
1708         PREGIVE(e, superweapons_finished);
1709         PREGIVE(e, ammo_nails);
1710         PREGIVE(e, ammo_cells);
1711         PREGIVE(e, ammo_plasma);
1712         PREGIVE(e, ammo_shells);
1713         PREGIVE(e, ammo_rockets);
1714         PREGIVE(e, ammo_fuel);
1715         PREGIVE(e, armorvalue);
1716         PREGIVE(e, health);
1717
1718         for(i = beginarg; i < endarg; ++i)
1719         {
1720                 cmd = argv(i);
1721
1722                 if(cmd == "0" || stof(cmd))
1723                 {
1724                         val = stof(cmd);
1725                         continue;
1726                 }
1727                 switch(cmd)
1728                 {
1729                         case "no":
1730                                 op = OP_MAX;
1731                                 val = 0;
1732                                 continue;
1733                         case "max":
1734                                 op = OP_MAX;
1735                                 continue;
1736                         case "min":
1737                                 op = OP_MIN;
1738                                 continue;
1739                         case "plus":
1740                                 op = OP_PLUS;
1741                                 continue;
1742                         case "minus":
1743                                 op = OP_MINUS;
1744                                 continue;
1745                         case "ALL":
1746                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1747                                 got += GiveValue(e, strength_finished, op, val);
1748                                 got += GiveValue(e, invincible_finished, op, val);
1749                                 got += GiveValue(e, superweapons_finished, op, val);
1750                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1751                         case "all":
1752                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1753                                 got += GiveValue(e, health, op, val);
1754                                 got += GiveValue(e, armorvalue, op, val);
1755                         case "allweapons":
1756                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1757                         //case "allbuffs": // all buffs makes a player god, do not want!
1758                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1759                         case "allammo":
1760                                 got += GiveValue(e, ammo_cells, op, val);
1761                                 got += GiveValue(e, ammo_plasma, op, val);
1762                                 got += GiveValue(e, ammo_shells, op, val);
1763                                 got += GiveValue(e, ammo_nails, op, val);
1764                                 got += GiveValue(e, ammo_rockets, op, val);
1765                                 got += GiveValue(e, ammo_fuel, op, val);
1766                                 break;
1767                         case "unlimited_ammo":
1768                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1769                                 break;
1770                         case "unlimited_weapon_ammo":
1771                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1772                                 break;
1773                         case "unlimited_superweapons":
1774                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1775                                 break;
1776                         case "jetpack":
1777                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1778                                 break;
1779                         case "fuel_regen":
1780                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1781                                 break;
1782                         case "strength":
1783                                 got += GiveValue(e, strength_finished, op, val);
1784                                 break;
1785                         case "invincible":
1786                                 got += GiveValue(e, invincible_finished, op, val);
1787                                 break;
1788                         case "superweapons":
1789                                 got += GiveValue(e, superweapons_finished, op, val);
1790                                 break;
1791                         case "cells":
1792                                 got += GiveValue(e, ammo_cells, op, val);
1793                                 break;
1794                         case "plasma":
1795                                 got += GiveValue(e, ammo_plasma, op, val);
1796                                 break;
1797                         case "shells":
1798                                 got += GiveValue(e, ammo_shells, op, val);
1799                                 break;
1800                         case "nails":
1801                         case "bullets":
1802                                 got += GiveValue(e, ammo_nails, op, val);
1803                                 break;
1804                         case "rockets":
1805                                 got += GiveValue(e, ammo_rockets, op, val);
1806                                 break;
1807                         case "health":
1808                                 got += GiveValue(e, health, op, val);
1809                                 break;
1810                         case "armor":
1811                                 got += GiveValue(e, armorvalue, op, val);
1812                                 break;
1813                         case "fuel":
1814                                 got += GiveValue(e, ammo_fuel, op, val);
1815                                 break;
1816                         default:
1817                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1818                                 {
1819                                         got += GiveBuff(e, it, op, val);
1820                                         break;
1821                                 });
1822                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1823                     got += GiveWeapon(e, it.m_id, op, val);
1824                     break;
1825                                 });
1826                                 break;
1827                 }
1828                 val = 999;
1829                 op = OP_SET;
1830         }
1831
1832         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1833         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1834         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1835         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1836         FOREACH(Weapons, it != WEP_Null, {
1837                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1838                 if(!(save_weapons & (it.m_wepset)))
1839                         if(e.weapons & (it.m_wepset))
1840                                 it.wr_init(it);
1841         });
1842         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1843         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1844         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1845         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1846         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1847         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1848         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1849         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1850         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1851         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1852         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1853
1854         if(e.superweapons_finished <= 0)
1855                 if(e.weapons & WEPSET_SUPERWEAPONS)
1856                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1857
1858         if(e.strength_finished <= 0)
1859                 e.strength_finished = 0;
1860         else
1861                 e.strength_finished += time;
1862         if(e.invincible_finished <= 0)
1863                 e.invincible_finished = 0;
1864         else
1865                 e.invincible_finished += time;
1866         if(e.superweapons_finished <= 0)
1867                 e.superweapons_finished = 0;
1868         else
1869                 e.superweapons_finished += time;
1870
1871         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1872         {
1873                 .entity weaponentity = weaponentities[slot];
1874                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1875                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1876                         _switchweapon |= BIT(slot);
1877         }
1878
1879         if(_switchweapon)
1880         {
1881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1882                 {
1883                         .entity weaponentity = weaponentities[slot];
1884                         if(_switchweapon & BIT(slot))
1885                         {
1886                                 Weapon wep = w_getbestweapon(e, weaponentity);
1887                                 if(wep != e.(weaponentity).m_switchweapon)
1888                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1889                         }
1890                 }
1891         }
1892
1893         return got;
1894 }
1895 #endif