qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ DEVASTATOR,
   4 /* function */ W_Devastator,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 9,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "rl",
  10 /* netname  */ "devastator",
  11 /* fullname */ _("Devastator")
  12 );
  13
  14 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, ammo) \
  16         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, animtime) \
  17         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, damage) \
  18         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, damageforcescale) \
  19         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, detonatedelay) \
  20         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, edgedamage) \
  21         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, force) \
  22         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guidedelay) \
  23         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guidegoal) \
  24         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guiderate) \
  25         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guideratedelay) \
  26         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guidestop) \
  27         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, health) \
  28         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, lifetime) \
  29         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, radius) \
  30         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, refire) \
  31         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_damage) \
  32         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_edgedamage) \
  33         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_force) \
  34         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_radius) \
  35         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, speed) \
  36         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, speedaccel) \
  37         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, speedstart) \
  38         w_prop(WEP_DEVASTATOR, devastator, float,  reloading_ammo, reload_ammo) \
  39         w_prop(WEP_DEVASTATOR, devastator, float,  reloading_time, reload_time) \
  40         w_prop(WEP_DEVASTATOR, devastator, float,  switchdelay_raise, switchdelay_raise) \
  41         w_prop(WEP_DEVASTATOR, devastator, float,  switchdelay_drop, switchdelay_drop) \
  42         w_prop(WEP_DEVASTATOR, devastator, string, weaponreplace, weaponreplace) \
  43         w_prop(WEP_DEVASTATOR, devastator, float,  weaponstart, weaponstart)
  44
  45 #ifdef SVQC
  46 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  47 .float rl_release;
  48 .float rl_detonate_later;
  49 #endif
  50 #else
  51 #ifdef SVQC
  52 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  53 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  54
  55 void W_Devastator_Unregister()
  56 {
  57         if(self.realowner && self.realowner.lastrocket == self)
  58         {
  59                 self.realowner.lastrocket = world;
  60                 // self.realowner.rl_release = 1;
  61         }
  62 }
  63
  64 void W_Devastator_Explode()
  65 {
  66         W_Devastator_Unregister();
  67
  68         if(other.takedamage == DAMAGE_AIM)
  69                 if(IS_PLAYER(other))
  70                         if(DIFF_TEAM(self.realowner, other))
  71                                 if(other.deadflag == DEAD_NO)
  72                                         if(IsFlying(other))
  73                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  74
  75         self.event_damage = func_null;
  76         self.takedamage = DAMAGE_NO;
  77
  78         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  79
  80         if (self.realowner.weapon == WEP_DEVASTATOR)
  81         {
  82                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  83                 {
  84                         self.realowner.cnt = WEP_DEVASTATOR;
  85                         ATTACK_FINISHED(self.realowner) = time;
  86                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  87                 }
  88         }
  89         remove (self);
  90 }
  91
  92 void W_Devastator_DoRemoteExplode()
  93 {
  94         W_Devastator_Unregister();
  95
  96         self.event_damage = func_null;
  97         self.takedamage = DAMAGE_NO;
  98
  99         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 100
 101         if (self.realowner.weapon == WEP_DEVASTATOR)
 102         {
 103                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
 104                 {
 105                         self.realowner.cnt = WEP_DEVASTATOR;
 106                         ATTACK_FINISHED(self.realowner) = time;
 107                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 108                 }
 109         }
 110         remove (self);
 111 }
 112
 113 void W_Devastator_RemoteExplode()
 114 {
 115         if(self.realowner.deadflag == DEAD_NO)
 116         if(self.realowner.lastrocket)
 117         {
 118                 if((self.spawnshieldtime >= 0)
 119                         ? (time >= self.spawnshieldtime) // timer
 120                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 121                 )
 122                 {
 123                         W_Devastator_DoRemoteExplode();
 124                 }
 125         }
 126 }
 127
 128 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 129 {
 130         if(thisdir * goaldir > maxturn_cos)
 131                 return goaldir;
 132         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 133                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 134         float f, m2;
 135         vector v;
 136         // solve:
 137         //   g = normalize(thisdir + goaldir * X)
 138         //   thisdir * g = maxturn
 139         //
 140         //   gg = thisdir + goaldir * X
 141         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 142         //
 143         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 144         f = thisdir * goaldir;
 145         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 146         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 147         m2 = maxturn_cos * maxturn_cos;
 148         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 149         return normalize(thisdir + goaldir * v_y); // the larger solution!
 150 }
 151 // assume thisdir == -goaldir:
 152 //   f == -1
 153 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 154 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 155 //   x^2 - 2 * x + 1 = 0
 156 //   (x - 1)^2 = 0
 157 //   x = 1
 158 //   normalize(thisdir + goaldir)
 159 //   normalize(0)
 160
 161 void W_Devastator_Think (void)
 162 {
 163         vector desireddir, olddir, newdir, desiredorigin, goal;
 164 #if 0
 165         float cosminang, cosmaxang, cosang;
 166 #endif
 167         float velspeed, f;
 168         self.nextthink = time;
 169         if (time > self.cnt)
 170         {
 171                 other = world;
 172                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 173                 W_Devastator_Explode ();
 174                 return;
 175         }
 176
 177         // accelerate
 178         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 179         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 180         if (velspeed > 0)
 181                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 182
 183         // laser guided, or remote detonation
 184         if (self.realowner.weapon == WEP_DEVASTATOR)
 185         {
 186                 if(self == self.realowner.lastrocket)
 187                 if(!self.realowner.rl_release)
 188                 if(!self.BUTTON_ATCK2)
 189                 if(WEP_CVAR(devastator, guiderate))
 190                 if(time > self.pushltime)
 191                 if(self.realowner.deadflag == DEAD_NO)
 192                 {
 193                         f = WEP_CVAR(devastator, guideratedelay);
 194                         if(f)
 195                                 f = bound(0, (time - self.pushltime) / f, 1);
 196                         else
 197                                 f = 1;
 198
 199                         velspeed = vlen(self.velocity);
 200
 201                         makevectors(self.realowner.v_angle);
 202                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 203                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 204                         olddir = normalize(self.velocity);
 205
 206                         // now it gets tricky... we want to move like some curve to approximate the target direction
 207                         // but we are limiting the rate at which we can turn!
 208                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 209                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 210
 211                         self.velocity = newdir * velspeed;
 212                         self.angles = vectoangles(self.velocity);
 213
 214                         if(!self.count)
 215                         {
 216                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 217                                 // TODO add a better sound here
 218                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 219                                 self.count = 1;
 220                         }
 221                 }
 222
 223                 if(self.rl_detonate_later)
 224                         W_Devastator_RemoteExplode();
 225         }
 226
 227         if(self.csqcprojectile_clientanimate == 0)
 228                 UpdateCSQCProjectile(self);
 229 }
 230
 231 void W_Devastator_Touch (void)
 232 {
 233         if(WarpZone_Projectile_Touch())
 234         {
 235                 if(wasfreed(self))
 236                         W_Devastator_Unregister();
 237                 return;
 238         }
 239         W_Devastator_Unregister();
 240         W_Devastator_Explode ();
 241 }
 242
 243 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 244 {
 245         if (self.health <= 0)
 246                 return;
 247
 248         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 249                 return; // g_projectiles_damage says to halt
 250
 251         self.health = self.health - damage;
 252         self.angles = vectoangles(self.velocity);
 253
 254         if (self.health <= 0)
 255                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 256 }
 257
 258 void W_Devastator_Attack (void)
 259 {
 260         entity missile;
 261         entity flash;
 262
 263         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo));
 264
 265         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 266         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 267
 268         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 269         missile.owner = missile.realowner = self;
 270         self.lastrocket = missile;
 271         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 272                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 273         else
 274                 missile.spawnshieldtime = -1;
 275         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 276         missile.classname = "rocket";
 277         missile.bot_dodge = TRUE;
 278         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 279
 280         missile.takedamage = DAMAGE_YES;
 281         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 282         missile.health = WEP_CVAR(devastator, health);
 283         missile.event_damage = W_Devastator_Damage;
 284         missile.damagedbycontents = TRUE;
 285
 286         missile.movetype = MOVETYPE_FLY;
 287         PROJECTILE_MAKETRIGGER(missile);
 288         missile.projectiledeathtype = WEP_DEVASTATOR;
 289         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 290
 291         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 292         W_SetupProjectileVelocity(missile, WEP_CVAR(devastator, speedstart), 0);
 293         missile.angles = vectoangles (missile.velocity);
 294
 295         missile.touch = W_Devastator_Touch;
 296         missile.think = W_Devastator_Think;
 297         missile.nextthink = time;
 298         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 299         missile.flags = FL_PROJECTILE;
 300         missile.missile_flags = MIF_SPLASH;
 301
 302         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 303
 304         // muzzle flash for 1st person view
 305         flash = spawn ();
 306         setmodel (flash, "models/flash.md3"); // precision set below
 307         SUB_SetFade (flash, time, 0.1);
 308         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 309         W_AttachToShotorg(flash, '5 0 0');
 310
 311         // common properties
 312         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 313 }
 314
 315 float W_Devastator(float req)
 316 {
 317         entity rock;
 318         float rockfound;
 319         float ammo_amount;
 320         switch(req)
 321         {
 322                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 323                 {
 324                         // aim and decide to fire if appropriate
 325                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 326                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 327                         {
 328                                 // decide whether to detonate rockets
 329                                 entity missile, targetlist, targ;
 330                                 targetlist = findchainfloat(bot_attack, TRUE);
 331                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 332                                 {
 333                                         targ = targetlist;
 334                                         while(targ)
 335                                         {
 336                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 337                                                 {
 338                                                         self.BUTTON_ATCK2 = TRUE;
 339                                                         break;
 340                                                 }
 341                                                 targ = targ.chain;
 342                                         }
 343                                 }
 344
 345                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 346                         }
 347
 348                         return TRUE;
 349                 }
 350                 case WR_THINK:
 351                 {
 352                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 353                                 WEP_ACTION(self.weapon, WR_RELOAD);
 354                         else
 355                         {
 356                                 if(self.BUTTON_ATCK)
 357                                 {
 358                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 359                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 360                                         {
 361                                                 W_Devastator_Attack();
 362                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 363                                                 self.rl_release = 0;
 364                                         }
 365                                 }
 366                                 else
 367                                         self.rl_release = 1;
 368
 369                                 if(self.BUTTON_ATCK2)
 370                                 {
 371                                         rockfound = 0;
 372                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 373                                         {
 374                                                 if(!rock.rl_detonate_later)
 375                                                 {
 376                                                         rock.rl_detonate_later = TRUE;
 377                                                         rockfound = 1;
 378                                                 }
 379                                         }
 380                                         if(rockfound)
 381                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 382                                 }
 383                         }
 384
 385                         return TRUE;
 386                 }
 387                 case WR_INIT:
 388                 {
 389                         if(autocvar_sv_precacheweapons)
 390                         {
 391                                 precache_model("models/flash.md3");
 392                                 precache_model("models/weapons/g_rl.md3");
 393                                 precache_model("models/weapons/v_rl.md3");
 394                                 precache_model("models/weapons/h_rl.iqm");
 395                                 precache_sound("weapons/rocket_det.wav");
 396                                 precache_sound("weapons/rocket_fire.wav");
 397                                 precache_sound("weapons/rocket_mode.wav");
 398                         }
 399                         DEVASTATOR_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 400                         return TRUE;
 401                 }
 402                 case WR_SETUP:
 403                 {
 404                         self.current_ammo = ammo_rockets;
 405                         self.rl_release = 1;
 406                         return TRUE;
 407                 }
 408                 case WR_CHECKAMMO1:
 409                 {
 410                         // don't switch while guiding a missile
 411                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 412                         {
 413                                 ammo_amount = FALSE;
 414                                 if(WEP_CVAR(devastator, reload_ammo))
 415                                 {
 416                                         if(self.ammo_rockets < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 417                                                 ammo_amount = TRUE;
 418                                 }
 419                                 else if(self.ammo_rockets < WEP_CVAR(devastator, ammo))
 420                                         ammo_amount = TRUE;
 421                                 return !ammo_amount;
 422                         }
 423
 424                         return TRUE;
 425                 }
 426                 case WR_CHECKAMMO2:
 427                 {
 428                         return FALSE;
 429                 }
 430                 case WR_CONFIG:
 431                 {
 432                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 433                         return TRUE;
 434                 }
 435                 case WR_RESETPLAYER:
 436                 {
 437                         self.rl_release = 0;
 438                         return TRUE;
 439                 }
 440                 case WR_RELOAD:
 441                 {
 442                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 443                         return TRUE;
 444                 }
 445                 case WR_SUICIDEMESSAGE:
 446                 {
 447                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 448                 }
 449                 case WR_KILLMESSAGE:
 450                 {
 451                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 452                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 453                         else
 454                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 455                 }
 456         }
 457         return TRUE;
 458 }
 459 #endif
 460 #ifdef CSQC
 461 float W_Devastator(float req)
 462 {
 463         switch(req)
 464         {
 465                 case WR_IMPACTEFFECT:
 466                 {
 467                         vector org2;
 468                         org2 = w_org + w_backoff * 12;
 469                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 470                         if(!w_issilent)
 471                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 472
 473                         return TRUE;
 474                 }
 475                 case WR_INIT:
 476                 {
 477                         precache_sound("weapons/rocket_impact.wav");
 478                         return TRUE;
 479                 }
 480         }
 481         return TRUE;
 482 }
 483 #endif
 484 #endif