qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ MINE_LAYER,
   4 /* function */ w_minelayer,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 4,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "minelayer",
  10 /* netname  */ "minelayer",
  11 /* fullname */ _("Mine Layer")
  12 );
  13
  14 #define MINELAYER_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, ammo) \
  16         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, animtime) \
  17         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, damage) \
  18         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, damageforcescale) \
  19         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, detonatedelay) \
  20         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, edgedamage) \
  21         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, force) \
  22         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, health) \
  23         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, lifetime) \
  24         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, lifetime_countdown) \
  25         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, limit) \
  26         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, protection) \
  27         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, proximityradius) \
  28         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, radius) \
  29         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, refire) \
  30         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, remote_damage) \
  31         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, remote_edgedamage) \
  32         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, remote_force) \
  33         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, remote_radius) \
  34         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, speed) \
  35         w_cvar(WEP_MINE_LAYER, minelayer, MO_NONE, time) \
  36         w_prop(WEP_MINE_LAYER, minelayer, float,  reloading_ammo, reload_ammo) \
  37         w_prop(WEP_MINE_LAYER, minelayer, float,  reloading_time, reload_time) \
  38         w_prop(WEP_MINE_LAYER, minelayer, float,  switchdelay_raise, switchdelay_raise) \
  39         w_prop(WEP_MINE_LAYER, minelayer, float,  switchdelay_drop, switchdelay_drop) \
  40         w_prop(WEP_MINE_LAYER, minelayer, string, weaponreplace, weaponreplace) \
  41         w_prop(WEP_MINE_LAYER, minelayer, float,  weaponstart, weaponstart)
  42
  43 #ifdef SVQC
  44 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  45 void W_Mine_Think (void);
  46 .float minelayer_detonate, mine_explodeanyway;
  47 .float mine_time;
  48 .vector mine_orientation;
  49 #endif
  50 #else
  51 #ifdef SVQC
  52 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  53
  54 void W_Mine_Stick (entity to)
  55 {
  56         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  57
  58         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  59
  60         entity newmine;
  61         newmine = spawn();
  62         newmine.classname = self.classname;
  63
  64         newmine.bot_dodge = self.bot_dodge;
  65         newmine.bot_dodgerating = self.bot_dodgerating;
  66
  67         newmine.owner = self.owner;
  68         newmine.realowner = self.realowner;
  69         setsize(newmine, '-4 -4 -4', '4 4 4');
  70         setorigin(newmine, self.origin);
  71         setmodel(newmine, "models/mine.md3");
  72         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  73
  74         newmine.mine_orientation = -trace_plane_normal;
  75
  76         newmine.takedamage = self.takedamage;
  77         newmine.damageforcescale = self.damageforcescale;
  78         newmine.health = self.health;
  79         newmine.event_damage = self.event_damage;
  80         newmine.spawnshieldtime = self.spawnshieldtime;
  81         newmine.damagedbycontents = TRUE;
  82
  83         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  84         newmine.projectiledeathtype = self.projectiledeathtype;
  85
  86         newmine.mine_time = self.mine_time;
  87
  88         newmine.touch = func_null;
  89         newmine.think = W_Mine_Think;
  90         newmine.nextthink = time;
  91         newmine.cnt = self.cnt;
  92         newmine.flags = self.flags;
  93
  94         remove(self);
  95         self = newmine;
  96
  97         if(to)
  98                 SetMovetypeFollow(self, to);
  99 }
 100
 101 void W_Mine_Explode ()
 102 {
 103         if(other.takedamage == DAMAGE_AIM)
 104                 if(IS_PLAYER(other))
 105                         if(DIFF_TEAM(self.realowner, other))
 106                                 if(other.deadflag == DEAD_NO)
 107                                         if(IsFlying(other))
 108                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 109
 110         self.event_damage = func_null;
 111         self.takedamage = DAMAGE_NO;
 112
 113         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 114
 115         if (self.realowner.weapon == WEP_MINE_LAYER)
 116         {
 117                 entity oldself;
 118                 oldself = self;
 119                 self = self.realowner;
 120                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 121                 {
 122                         self.cnt = WEP_MINE_LAYER;
 123                         ATTACK_FINISHED(self) = time;
 124                         self.switchweapon = w_getbestweapon(self);
 125                 }
 126                 self = oldself;
 127         }
 128         self.realowner.minelayer_mines -= 1;
 129         remove (self);
 130 }
 131
 132 void W_Mine_DoRemoteExplode ()
 133 {
 134         self.event_damage = func_null;
 135         self.takedamage = DAMAGE_NO;
 136
 137         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 138                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 139
 140         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 141
 142         if (self.realowner.weapon == WEP_MINE_LAYER)
 143         {
 144                 entity oldself;
 145                 oldself = self;
 146                 self = self.realowner;
 147                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 148                 {
 149                         self.cnt = WEP_MINE_LAYER;
 150                         ATTACK_FINISHED(self) = time;
 151                         self.switchweapon = w_getbestweapon(self);
 152                 }
 153                 self = oldself;
 154         }
 155         self.realowner.minelayer_mines -= 1;
 156         remove (self);
 157 }
 158
 159 void W_Mine_RemoteExplode ()
 160 {
 161         if(self.realowner.deadflag == DEAD_NO)
 162                 if((self.spawnshieldtime >= 0)
 163                         ? (time >= self.spawnshieldtime) // timer
 164                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 165                 )
 166                 {
 167                         W_Mine_DoRemoteExplode();
 168                 }
 169 }
 170
 171 void W_Mine_ProximityExplode ()
 172 {
 173         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 174         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 175         {
 176                 entity head;
 177                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 178                 while(head)
 179                 {
 180                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 181                                 return;
 182                         head = head.chain;
 183                 }
 184         }
 185
 186         self.mine_time = 0;
 187         W_Mine_Explode();
 188 }
 189
 190 float W_Mine_Count(entity e)
 191 {
 192         float minecount = 0;
 193         entity mine;
 194         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 195                 minecount += 1;
 196
 197         return minecount;
 198 }
 199
 200 void W_Mine_Think (void)
 201 {
 202         entity head;
 203
 204         self.nextthink = time;
 205
 206         if(self.movetype == MOVETYPE_FOLLOW)
 207         {
 208                 if(LostMovetypeFollow(self))
 209                 {
 210                         UnsetMovetypeFollow(self);
 211                         self.movetype = MOVETYPE_NONE;
 212                 }
 213         }
 214
 215         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 216         // TODO: replace this mine_trigger.wav sound with a real countdown
 217         if ((time > self.cnt) && (!self.mine_time))
 218         {
 219                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 220                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 221                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 222                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 223         }
 224
 225         // a player's mines shall explode if he disconnects or dies
 226         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 227         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 228         {
 229                 other = world;
 230                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 231                 W_Mine_Explode();
 232                 return;
 233         }
 234
 235         // set the mine for detonation when a foe gets close enough
 236         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 237         while(head)
 238         {
 239                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 240                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 241                 if(!self.mine_time)
 242                 {
 243                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 244                         self.mine_time = time + WEP_CVAR(minelayer, time);
 245                 }
 246                 head = head.chain;
 247         }
 248
 249         // explode if it's time to
 250         if(self.mine_time && time >= self.mine_time)
 251         {
 252                 W_Mine_ProximityExplode();
 253                 return;
 254         }
 255
 256         // remote detonation
 257         if (self.realowner.weapon == WEP_MINE_LAYER)
 258         if (self.realowner.deadflag == DEAD_NO)
 259         if (self.minelayer_detonate)
 260                 W_Mine_RemoteExplode();
 261 }
 262
 263 void W_Mine_Touch (void)
 264 {
 265         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 266                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 267
 268         if(WarpZone_Projectile_Touch())
 269         {
 270                 if(wasfreed(self))
 271                         self.realowner.minelayer_mines -= 1;
 272                 return;
 273         }
 274
 275         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 276         {
 277                 // hit a player
 278                 // don't stick
 279         }
 280         else
 281         {
 282                 W_Mine_Stick(other);
 283         }
 284 }
 285
 286 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 287 {
 288         if (self.health <= 0)
 289                 return;
 290
 291         float is_from_enemy = (inflictor.realowner != self.realowner);
 292
 293         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 294                 return; // g_projectiles_damage says to halt
 295
 296         self.health = self.health - damage;
 297         self.angles = vectoangles(self.velocity);
 298
 299         if (self.health <= 0)
 300                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 301 }
 302
 303 void W_Mine_Attack (void)
 304 {
 305         entity mine;
 306         entity flash;
 307
 308         // scan how many mines we placed, and return if we reached our limit
 309         if(WEP_CVAR(minelayer, limit))
 310         {
 311                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 312                 {
 313                         // the refire delay keeps this message from being spammed
 314                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 315                         play2(self, "weapons/unavailable.wav");
 316                         return;
 317                 }
 318         }
 319
 320         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(minelayer, ammo), autocvar_g_balance_minelayer_reload_ammo);
 321
 322         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 323         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 324
 325         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 326         mine.owner = mine.realowner = self;
 327         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 328                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 329         else
 330                 mine.spawnshieldtime = -1;
 331         mine.classname = "mine";
 332         mine.bot_dodge = TRUE;
 333         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 334
 335         mine.takedamage = DAMAGE_YES;
 336         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 337         mine.health = WEP_CVAR(minelayer, health);
 338         mine.event_damage = W_Mine_Damage;
 339         mine.damagedbycontents = TRUE;
 340
 341         mine.movetype = MOVETYPE_TOSS;
 342         PROJECTILE_MAKETRIGGER(mine);
 343         mine.projectiledeathtype = WEP_MINE_LAYER;
 344         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 345
 346         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 347         W_SetupProjectileVelocity(mine, WEP_CVAR(minelayer, speed), 0);
 348         mine.angles = vectoangles (mine.velocity);
 349
 350         mine.touch = W_Mine_Touch;
 351         mine.think = W_Mine_Think;
 352         mine.nextthink = time;
 353         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 354         mine.flags = FL_PROJECTILE;
 355         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 356
 357         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 358
 359         // muzzle flash for 1st person view
 360         flash = spawn ();
 361         setmodel (flash, "models/flash.md3"); // precision set below
 362         SUB_SetFade (flash, time, 0.1);
 363         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 364         W_AttachToShotorg(flash, '5 0 0');
 365
 366         // common properties
 367
 368         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 369
 370         self.minelayer_mines = W_Mine_Count(self);
 371 }
 372
 373 float W_PlacedMines(float detonate)
 374 {
 375         entity mine;
 376         float minfound = 0;
 377
 378         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 379         {
 380                 if(detonate)
 381                 {
 382                         if(!mine.minelayer_detonate)
 383                         {
 384                                 mine.minelayer_detonate = TRUE;
 385                                 minfound = 1;
 386                         }
 387                 }
 388                 else
 389                         minfound = 1;
 390         }
 391         return minfound;
 392 }
 393
 394 float w_minelayer(float req)
 395 {
 396         entity mine;
 397         float ammo_amount;
 398         switch(req)
 399         {
 400                 case WR_AIM:
 401                 {
 402                         // aim and decide to fire if appropriate
 403                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 404                                 self.BUTTON_ATCK = FALSE;
 405                         else
 406                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 407                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 408                         {
 409                                 // decide whether to detonate mines
 410                                 entity targetlist, targ;
 411                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 412                                 float selfdamage, teamdamage, enemydamage;
 413                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 414                                 coredamage = WEP_CVAR(minelayer, damage);
 415                                 edgeradius = WEP_CVAR(minelayer, radius);
 416                                 recipricoledgeradius = 1 / edgeradius;
 417                                 selfdamage = 0;
 418                                 teamdamage = 0;
 419                                 enemydamage = 0;
 420                                 targetlist = findchainfloat(bot_attack, TRUE);
 421                                 mine = find(world, classname, "mine");
 422                                 while (mine)
 423                                 {
 424                                         if (mine.realowner != self)
 425                                         {
 426                                                 mine = find(mine, classname, "mine");
 427                                                 continue;
 428                                         }
 429                                         targ = targetlist;
 430                                         while (targ)
 431                                         {
 432                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 433                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 434                                                 // count potential damage according to type of target
 435                                                 if (targ == self)
 436                                                         selfdamage = selfdamage + d;
 437                                                 else if (targ.team == self.team && teamplay)
 438                                                         teamdamage = teamdamage + d;
 439                                                 else if (bot_shouldattack(targ))
 440                                                         enemydamage = enemydamage + d;
 441                                                 targ = targ.chain;
 442                                         }
 443                                         mine = find(mine, classname, "mine");
 444                                 }
 445                                 float desirabledamage;
 446                                 desirabledamage = enemydamage;
 447                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 448                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 449                                 if (teamplay && self.team)
 450                                         desirabledamage = desirabledamage - teamdamage;
 451
 452                                 mine = find(world, classname, "mine");
 453                                 while (mine)
 454                                 {
 455                                         if (mine.realowner != self)
 456                                         {
 457                                                 mine = find(mine, classname, "mine");
 458                                                 continue;
 459                                         }
 460                                         makevectors(mine.v_angle);
 461                                         targ = targetlist;
 462                                         if (skill > 9) // normal players only do this for the target they are tracking
 463                                         {
 464                                                 targ = targetlist;
 465                                                 while (targ)
 466                                                 {
 467                                                         if (
 468                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 469                                                                 && desirabledamage > 0.1*coredamage
 470                                                         )self.BUTTON_ATCK2 = TRUE;
 471                                                         targ = targ.chain;
 472                                                 }
 473                                         }else{
 474                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 475                                                 //As the distance gets larger, a correct detonation gets near imposible
 476                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 477                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 478                                                         if(IS_PLAYER(self.enemy))
 479                                                                 if(desirabledamage >= 0.1*coredamage)
 480                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 481                                                                                 self.BUTTON_ATCK2 = TRUE;
 482                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 483                                         }
 484
 485                                         mine = find(mine, classname, "mine");
 486                                 }
 487                                 // if we would be doing at X percent of the core damage, detonate it
 488                                 // but don't fire a new shot at the same time!
 489                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 490                                         self.BUTTON_ATCK2 = TRUE;
 491                                 if ((skill > 6.5) && (selfdamage > self.health))
 492                                         self.BUTTON_ATCK2 = FALSE;
 493                                 //if(self.BUTTON_ATCK2 == TRUE)
 494                                 //      dprint(ftos(desirabledamage),"\n");
 495                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 496                         }
 497
 498                         return TRUE;
 499                 }
 500                 case WR_THINK:
 501                 {
 502                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 503                         {
 504                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 505                                 if(!(W_PlacedMines(FALSE) && self.ammo_rockets < WEP_CVAR(minelayer, ammo)))
 506                                         WEP_ACTION(self.weapon, WR_RELOAD);
 507                         }
 508                         else if (self.BUTTON_ATCK)
 509                         {
 510                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 511                                 {
 512                                         W_Mine_Attack();
 513                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 514                                 }
 515                         }
 516
 517                         if (self.BUTTON_ATCK2)
 518                         {
 519                                 if(W_PlacedMines(TRUE))
 520                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 521                         }
 522
 523                         return TRUE;
 524                 }
 525                 case WR_INIT:
 526                 {
 527                         precache_model ("models/flash.md3");
 528                         precache_model ("models/mine.md3");
 529                         precache_model ("models/weapons/g_minelayer.md3");
 530                         precache_model ("models/weapons/v_minelayer.md3");
 531                         precache_model ("models/weapons/h_minelayer.iqm");
 532                         precache_sound ("weapons/mine_det.wav");
 533                         precache_sound ("weapons/mine_fire.wav");
 534                         precache_sound ("weapons/mine_stick.wav");
 535                         precache_sound ("weapons/mine_trigger.wav");
 536                         MINELAYER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 537                         return TRUE;
 538                 }
 539                 case WR_SETUP:
 540                 {
 541                         self.current_ammo = ammo_rockets;
 542                         return TRUE;
 543                 }
 544                 case WR_CHECKAMMO1:
 545                 {
 546                         // don't switch while placing a mine
 547                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 548                         {
 549                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(minelayer, ammo);
 550                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 551                                 return ammo_amount;
 552                         }
 553                         return TRUE;
 554                 }
 555                 case WR_CHECKAMMO2:
 556                 {
 557                         if (W_PlacedMines(FALSE))
 558                                 return TRUE;
 559                         else
 560                                 return FALSE;
 561                 }
 562                 case WR_CONFIG:
 563                 {
 564                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 565                         return TRUE;
 566                 }
 567                 case WR_RESETPLAYER:
 568                 {
 569                         self.minelayer_mines = 0;
 570                         return TRUE;
 571                 }
 572                 case WR_RELOAD:
 573                 {
 574                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 575                         return TRUE;
 576                 }
 577                 case WR_SUICIDEMESSAGE:
 578                 {
 579                         return WEAPON_MINELAYER_SUICIDE;
 580                 }
 581                 case WR_KILLMESSAGE:
 582                 {
 583                         return WEAPON_MINELAYER_MURDER;
 584                 }
 585         }
 586         return TRUE;
 587 }
 588 #endif
 589 #ifdef CSQC
 590 float w_minelayer(float req)
 591 {
 592         switch(req)
 593         {
 594                 case WR_IMPACTEFFECT:
 595                 {
 596                         vector org2;
 597                         org2 = w_org + w_backoff * 12;
 598                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 599                         if(!w_issilent)
 600                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 601
 602                         return TRUE;
 603                 }
 604                 case WR_INIT:
 605                 {
 606                         precache_sound("weapons/mine_exp.wav");
 607                         return TRUE;
 608                 }
 609         }
 610         return TRUE;
 611 }
 612 #endif
 613 #endif