qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SEEKER,
   4 /* function */ w_seeker,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 8,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "seeker",
  10 /* netname  */ "seeker",
  11 /* fullname */ _("T.A.G. Seeker")
  12 );
  13
  14 #define SEEKER_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, type) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, flac_ammo) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, flac_animtime) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, flac_damage) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, flac_edgedamage) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, flac_force) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, flac_lifetime) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, flac_lifetime_rand) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, flac_radius) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, flac_refire) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, missile_accel) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, missile_ammo) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, missile_animtime) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, missile_count) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, missile_damage) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, missile_damageforcescale) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, missile_decel) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, missile_delay) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, missile_edgedamage) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, missile_force) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, missile_health) \
  36         WEP_ADD_CVAR(weapon, MO_NONE, missile_lifetime) \
  37         WEP_ADD_CVAR(weapon, MO_NONE, missile_proxy) \
  38         WEP_ADD_CVAR(weapon, MO_NONE, missile_proxy_delay) \
  39         WEP_ADD_CVAR(weapon, MO_NONE, missile_proxy_maxrange) \
  40         WEP_ADD_CVAR(weapon, MO_NONE, missile_radius) \
  41         WEP_ADD_CVAR(weapon, MO_NONE, missile_refire) \
  42         WEP_ADD_CVAR(weapon, MO_NONE, missile_smart) \
  43         WEP_ADD_CVAR(weapon, MO_NONE, missile_smart_mindist) \
  44         WEP_ADD_CVAR(weapon, MO_NONE, missile_smart_trace_max) \
  45         WEP_ADD_CVAR(weapon, MO_NONE, missile_smart_trace_min) \
  46         WEP_ADD_CVAR(weapon, MO_NONE, missile_speed_max) \
  47         WEP_ADD_CVAR(weapon, MO_NONE, missile_turnrate) \
  48         WEP_ADD_CVAR(weapon, MO_NONE, tag_ammo) \
  49         WEP_ADD_CVAR(weapon, MO_NONE, tag_animtime) \
  50         WEP_ADD_CVAR(weapon, MO_NONE, tag_damageforcescale) \
  51         WEP_ADD_CVAR(weapon, MO_NONE, tag_health) \
  52         WEP_ADD_CVAR(weapon, MO_NONE, tag_lifetime) \
  53         WEP_ADD_CVAR(weapon, MO_NONE, tag_refire) \
  54         WEP_ADD_CVAR(weapon, MO_NONE, tag_speed) \
  55         WEP_ADD_CVAR(weapon, MO_NONE, tag_tracker_lifetime) \
  56         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  57         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  58         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  59         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  60
  61 #ifdef SVQC
  62 SEEKER_SETTINGS(seeker)
  63 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  64
  65 .entity tag_target, wps_tag_tracker;
  66 .float tag_time;
  67 #endif
  68 #else
  69 #ifdef SVQC
  70
  71 // ============================
  72 // Begin: Missile functions, these are general functions to be manipulated by other code
  73 // ============================
  74 void Seeker_Missile_Explode ()
  75 {
  76         self.event_damage = func_null;
  77         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  78
  79         remove (self);
  80 }
  81
  82 void Seeker_Missile_Touch()
  83 {
  84         PROJECTILE_TOUCH;
  85
  86         Seeker_Missile_Explode();
  87 }
  88
  89 void Seeker_Missile_Think()
  90 {
  91         entity e;
  92         vector desireddir, olddir, newdir, eorg;
  93         float turnrate;
  94         float dist;
  95         float spd;
  96
  97         if (time > self.cnt)
  98         {
  99                 self.projectiledeathtype |= HITTYPE_SPLASH;
 100                 Seeker_Missile_Explode();
 101         }
 102
 103         spd = vlen(self.velocity);
 104         spd = bound(
 105                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 106                 WEP_CVAR(seeker, missile_speed_max),
 107                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 108         );
 109
 110         if (self.enemy != world)
 111                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 112                         self.enemy = world;
 113
 114         if (self.enemy != world)
 115         {
 116                 e               = self.enemy;
 117                 eorg            = 0.5 * (e.absmin + e.absmax);
 118                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 119                 desireddir      = normalize(eorg - self.origin);
 120                 olddir          = normalize(self.velocity); // get my current direction
 121                 dist            = vlen(eorg - self.origin);
 122
 123                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 124                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 125                 {
 126                         // Is it a better idea (shorter distance) to trace to the target itself?
 127                         if ( vlen(self.origin + olddir * self.wait) < dist)
 128                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 129                         else
 130                                 traceline(self.origin, eorg, FALSE, self);
 131
 132                         // Setup adaptive tracelength
 133                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 134
 135                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 136                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 137                 }
 138
 139                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 140                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 141         }
 142         else
 143                 dist = 0;
 144
 145         // Proxy
 146         if (WEP_CVAR(seeker, missile_proxy))
 147         {
 148                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 149                 {
 150                         if (self.autoswitch == 0)
 151                         {
 152                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 153                         }
 154                         else
 155                         {
 156                                 if (self.autoswitch <= time)
 157                                 {
 158                                         Seeker_Missile_Explode();
 159                                         self.autoswitch = 0;
 160                                 }
 161                         }
 162                 }
 163                 else
 164                 {
 165                         if (self.autoswitch != 0)
 166                                 self.autoswitch = 0;
 167                 }
 168         }
 169         ///////////////
 170
 171         if (self.enemy.deadflag != DEAD_NO)
 172         {
 173                 self.enemy = world;
 174                 self.cnt = time + 1 + (random() * 4);
 175                 self.nextthink = self.cnt;
 176                 return;
 177         }
 178
 179         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 180         self.nextthink = time;// + 0.05; // csqc projectiles
 181         UpdateCSQCProjectile(self);
 182 }
 183
 184
 185
 186 void Seeker_Missile_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 187 {
 188         if (self.health <= 0)
 189                 return;
 190
 191         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 192                 return; // g_projectiles_damage says to halt
 193
 194         if (self.realowner == attacker)
 195                 self.health = self.health - (damage * 0.25);
 196         else
 197                 self.health = self.health - damage;
 198
 199         if (self.health <= 0)
 200                 W_PrepareExplosionByDamage(attacker, Seeker_Missile_Explode);
 201 }
 202
 203 /*
 204 void Seeker_Missile_Animate()
 205 {
 206         self.frame = self.frame +1;
 207         self.nextthink = time + 0.05;
 208
 209         if (self.enemy != world)
 210                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 211                         self.enemy = world;
 212
 213         if(self.frame == 5)
 214         {
 215                 self.think           = Seeker_Missile_Think;
 216                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 217
 218                 if (autocvar_g_balance_seeker_missile_proxy)
 219                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 220                 else
 221                         self.movetype    = MOVETYPE_FLYMISSILE;
 222         }
 223
 224         UpdateCSQCProjectile(self);
 225 }
 226 */
 227
 228 void Seeker_Fire_Missile(vector f_diff, entity m_target)
 229 {
 230         entity missile;
 231
 232         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, missile_ammo), autocvar_g_balance_seeker_reload_ammo);
 233
 234         makevectors(self.v_angle);
 235         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 236         w_shotorg += f_diff;
 237         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 238
 239         //self.detornator         = FALSE;
 240
 241         missile                 = spawn();
 242         missile.owner           = missile.realowner = self;
 243         missile.classname       = "seeker_missile";
 244         missile.bot_dodge       = TRUE;
 245         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 246
 247         missile.think           = Seeker_Missile_Think;
 248         missile.touch           = Seeker_Missile_Touch;
 249         missile.event_damage    = Seeker_Missile_Damage;
 250         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 251         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 252         missile.enemy           = m_target;
 253         missile.solid           = SOLID_BBOX;
 254         missile.scale           = 2;
 255         missile.takedamage      = DAMAGE_YES;
 256         missile.health          = WEP_CVAR(seeker, missile_health);
 257         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 258         missile.damagedbycontents = TRUE;
 259         //missile.think           = Seeker_Missile_Animate; // csqc projectiles.
 260
 261         if (missile.enemy != world)
 262                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 263         else
 264                 missile.projectiledeathtype = WEP_SEEKER;
 265
 266
 267         setorigin (missile, w_shotorg);
 268         setsize (missile, '-4 -4 -4', '4 4 4');
 269         missile.movetype    = MOVETYPE_FLYMISSILE;
 270         missile.flags       = FL_PROJECTILE;
 271         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 272
 273         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_missile);
 274
 275         missile.angles = vectoangles (missile.velocity);
 276
 277         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 278
 279         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 280 }
 281
 282 // ============================
 283 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 284 // ============================
 285 void Seeker_Flac_Explode ()
 286 {
 287         self.event_damage = func_null;
 288
 289         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 290
 291         remove (self);
 292 }
 293
 294 void Seeker_Flac_Touch()
 295 {
 296         PROJECTILE_TOUCH;
 297
 298         Seeker_Flac_Explode();
 299 }
 300
 301 void Seeker_Fire_Flac()
 302 {
 303         entity missile;
 304         vector f_diff;
 305         float c;
 306
 307         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, flac_ammo), autocvar_g_balance_seeker_reload_ammo);
 308
 309         c = mod(self.bulletcounter, 4);
 310         switch(c)
 311         {
 312                 case 0:
 313                         f_diff = '-1.25 -3.75 0';
 314                         break;
 315                 case 1:
 316                         f_diff = '+1.25 -3.75 0';
 317                         break;
 318                 case 2:
 319                         f_diff = '-1.25 +3.75 0';
 320                         break;
 321                 case 3:
 322                 default:
 323                         f_diff = '+1.25 +3.75 0';
 324                         break;
 325         }
 326         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 327         w_shotorg += f_diff;
 328
 329         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 330
 331         missile                                 = spawn ();
 332         missile.owner                   = missile.realowner = self;
 333         missile.classname               = "missile";
 334         missile.bot_dodge               = TRUE;
 335         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 336         missile.touch                   = Seeker_Flac_Explode;
 337         missile.use                     = Seeker_Flac_Explode;
 338         missile.think                   = adaptor_think2use_hittype_splash;
 339         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 340         missile.solid                   = SOLID_BBOX;
 341         missile.movetype                = MOVETYPE_FLY;
 342         missile.projectiledeathtype = WEP_SEEKER;
 343         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 344         missile.flags                           = FL_PROJECTILE;
 345         missile.missile_flags       = MIF_SPLASH;
 346
 347         // csqc projectiles
 348         //missile.angles                                = vectoangles (missile.velocity);
 349         //missile.scale = 0.4; // BUG: the model is too big
 350
 351         setorigin (missile, w_shotorg);
 352         setsize (missile, '-2 -2 -2', '2 2 2');
 353
 354         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_flac);
 355         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 356
 357         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 358 }
 359
 360 // ============================
 361 // Begin: Tag and rocket controllers
 362 // ============================
 363 entity Seeker_Tagged_Info(entity isowner, entity istarget)
 364 {
 365         entity tag;
 366         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 367                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 368                         return tag;
 369
 370         return world;
 371 }
 372
 373 void Seeker_Attack()
 374 {
 375         entity tracker, closest_target;
 376
 377         closest_target = world;
 378         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 379         {
 380                 if (closest_target)
 381                 {
 382                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 383                                 closest_target = tracker.tag_target;
 384                 }
 385                 else
 386                         closest_target = tracker.tag_target;
 387         }
 388
 389         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 390         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 391                 closest_target = world;
 392
 393         Seeker_Fire_Missile('0 0 0', closest_target);
 394 }
 395
 396 void Seeker_Vollycontroller_Think() // TODO: Merge this with Seeker_Attack
 397 {
 398         float c;
 399         entity oldself,oldenemy;
 400         self.cnt = self.cnt - 1;
 401
 402         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.ammo_rockets < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 403         {
 404                 remove(self);
 405                 return;
 406         }
 407
 408         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 409
 410         oldself = self;
 411         self = self.realowner;
 412
 413         oldenemy = self.enemy;
 414         self.enemy = oldself.enemy;
 415
 416         c = mod(self.cnt, 4);
 417         switch(c)
 418         {
 419                 case 0:
 420                         Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 421                         break;
 422                 case 1:
 423                         Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 424                         break;
 425                 case 2:
 426                         Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 427                         break;
 428                 case 3:
 429                 default:
 430                         Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 431                         break;
 432         }
 433
 434         self.enemy = oldenemy;
 435         self = oldself;
 436 }
 437
 438 void Seeker_Tracker_Think()
 439 {
 440         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 441         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 442         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 443         {
 444                 if (self)
 445                 {
 446                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 447                         remove(self);
 448                 }
 449                 return;
 450         }
 451
 452         // Update the think method information
 453         self.nextthink = time;
 454 }
 455
 456 // ============================
 457 // Begin: Tag projectile
 458 // ============================
 459 void Seeker_Tag_Explode ()
 460 {
 461         //if(other==self.realowner)
 462         //    return;
 463         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 464
 465         remove (self);
 466 }
 467
 468 void Seeker_Tag_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 469 {
 470         if (self.health <= 0)
 471                 return;
 472         self.health = self.health - damage;
 473         if (self.health <= 0)
 474                 Seeker_Tag_Explode();
 475 }
 476
 477 void Seeker_Tag_Touch()
 478 {
 479         vector dir;
 480         vector org2;
 481         entity e;
 482
 483         PROJECTILE_TOUCH;
 484
 485         dir     = normalize (self.realowner.origin - self.origin);
 486         org2    = findbetterlocation (self.origin, 8);
 487
 488         te_knightspike(org2);
 489
 490         self.event_damage = func_null;
 491         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 492
 493         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 494         {
 495                 // check to see if this person is already tagged by me
 496                 entity tag = Seeker_Tagged_Info(self.realowner, other);
 497
 498                 if (tag != world)
 499                 {
 500                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 501                                 WaypointSprite_Kill(other.wps_tag_tracker);
 502
 503                         tag.tag_time = time;
 504                 }
 505                 else
 506                 {
 507                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 508                         e             = spawn();
 509                         e.cnt         = WEP_CVAR(seeker, missile_count);
 510                         e.classname   = "tag_tracker";
 511                         e.owner       = self.owner;
 512                         e.realowner   = self.realowner;
 513
 514                         if      (WEP_CVAR(seeker, type) == 1)
 515                         {
 516                                 e.tag_target  = other;
 517                                 e.tag_time    = time;
 518                                 e.think       = Seeker_Tracker_Think;
 519                         }
 520                         else
 521                         {
 522                                 e.enemy     = other;
 523                                 e.think     = Seeker_Vollycontroller_Think;
 524                         }
 525
 526                         e.nextthink   = time;
 527                 }
 528
 529                 if      (WEP_CVAR(seeker, type) == 1)
 530                 {
 531                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 532                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 533                 }
 534         }
 535
 536         remove(self);
 537         return;
 538 }
 539
 540 void Seeker_Fire_Tag()
 541 {
 542         entity missile;
 543         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, tag_ammo), autocvar_g_balance_seeker_reload_ammo);
 544
 545         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 546
 547         missile                 = spawn();
 548         missile.owner           = missile.realowner = self;
 549         missile.classname       = "seeker_tag";
 550         missile.bot_dodge       = TRUE;
 551         missile.bot_dodgerating = 50;
 552         missile.touch           = Seeker_Tag_Touch;
 553         missile.think           = SUB_Remove;
 554         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 555         missile.movetype        = MOVETYPE_FLY;
 556         missile.solid           = SOLID_BBOX;
 557
 558         missile.takedamage       = DAMAGE_YES;
 559         missile.event_damage     = Seeker_Tag_Damage;
 560         missile.health           = WEP_CVAR(seeker, tag_health);
 561         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 562
 563         setorigin (missile, w_shotorg);
 564         setsize (missile, '-2 -2 -2', '2 2 2');
 565
 566         missile.flags       = FL_PROJECTILE;
 567         //missile.missile_flags = MIF_..?;
 568
 569         missile.movetype    = MOVETYPE_FLY;
 570         W_SETUPPROJECTILEVELOCITY(missile, g_balance_seeker_tag);
 571         missile.angles = vectoangles (missile.velocity);
 572
 573         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 574
 575         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 576 }
 577
 578 // ============================
 579 // Begin: Genereal weapon functions
 580 // ============================
 581 void spawnfunc_weapon_seeker (void)
 582 {
 583         weapon_defaultspawnfunc(WEP_SEEKER);
 584 }
 585
 586 float w_seeker(float req)
 587 {
 588         float ammo_amount;
 589
 590         switch(req)
 591         {
 592                 case WR_AIM:
 593                 {
 594                         if (WEP_CVAR(seeker, type) == 1)
 595                                 if (Seeker_Tagged_Info(self, self.enemy) != world)
 596                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 597                                 else
 598                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 599                         else
 600                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 601
 602                         return TRUE;
 603                 }
 604                 case WR_THINK:
 605                 {
 606                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 607                                 WEP_ACTION(self.weapon, WR_RELOAD);
 608
 609                         else if (self.BUTTON_ATCK)
 610                         {
 611                                 if (WEP_CVAR(seeker, type) == 1)
 612                                 {
 613                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 614                                         {
 615                                                 Seeker_Attack();
 616                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 617                                         }
 618                                 }
 619                                 else
 620                                 {
 621                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 622                                         {
 623                                                 Seeker_Fire_Tag();
 624                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 625                                         }
 626                                 }
 627                         }
 628
 629                         else if (self.BUTTON_ATCK2)
 630                         {
 631                                 if (WEP_CVAR(seeker, type) == 1)
 632                                 {
 633                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 634                                         {
 635                                                 Seeker_Fire_Tag();
 636                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 637                                         }
 638                                 }
 639                                 else
 640                                 {
 641                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 642                                         {
 643                                                 Seeker_Fire_Flac();
 644                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 645                                         }
 646                                 }
 647                         }
 648
 649                         return TRUE;
 650                 }
 651                 case WR_INIT:
 652                 {
 653                         precache_model ("models/weapons/g_seeker.md3");
 654                         precache_model ("models/weapons/v_seeker.md3");
 655                         precache_model ("models/weapons/h_seeker.iqm");
 656                         precache_sound ("weapons/tag_fire.wav");
 657                         precache_sound ("weapons/flac_fire.wav");
 658                         precache_sound ("weapons/seeker_fire.wav");
 659                         WEP_SET_PROPS(SEEKER_SETTINGS(seeker), WEP_SEEKER)
 660                         return TRUE;
 661                 }
 662                 case WR_SETUP:
 663                 {
 664                         self.current_ammo = ammo_rockets;
 665                         return TRUE;
 666                 }
 667                 case WR_CHECKAMMO1:
 668                 {
 669                         if (WEP_CVAR(seeker, type) == 1)
 670                         {
 671                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, missile_ammo);
 672                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 673                         }
 674                         else
 675                         {
 676                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 677                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 678                         }
 679
 680                         return ammo_amount;
 681                 }
 682                 case WR_CHECKAMMO2:
 683                 {
 684                         if (WEP_CVAR(seeker, type) == 1)
 685                         {
 686                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 687                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 688                         }
 689                         else
 690                         {
 691                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, flac_ammo);
 692                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 693                         }
 694
 695                         return ammo_amount;
 696                 }
 697                 case WR_CONFIG:
 698                 {
 699                         WEP_CONFIG_SETTINGS(SEEKER_SETTINGS(seeker))
 700                         return TRUE;
 701                 }
 702                 case WR_RELOAD:
 703                 {
 704                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), autocvar_g_balance_seeker_reload_ammo, autocvar_g_balance_seeker_reload_time, "weapons/reload.wav");
 705                         return TRUE;
 706                 }
 707                 case WR_SUICIDEMESSAGE:
 708                 {
 709                         return WEAPON_SEEKER_SUICIDE;
 710                 }
 711                 case WR_KILLMESSAGE:
 712                 {
 713                         if(w_deathtype & HITTYPE_SECONDARY)
 714                                 return WEAPON_SEEKER_MURDER_TAG;
 715                         else
 716                                 return WEAPON_SEEKER_MURDER_SPRAY;
 717                 }
 718         }
 719         return TRUE;
 720 }
 721 #endif
 722 #ifdef CSQC
 723 float w_seeker(float req)
 724 {
 725         switch(req)
 726         {
 727                 case WR_IMPACTEFFECT:
 728                 {
 729                         vector org2;
 730                         org2 = w_org + w_backoff * 6;
 731                         if(w_deathtype & HITTYPE_BOUNCE)
 732                         {
 733                                 if(w_deathtype & HITTYPE_SECONDARY)
 734                                 {
 735                                         if(!w_issilent)
 736                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTN_NORM);
 737                                 }
 738                                 else
 739                                 {
 740                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 741                                         if(!w_issilent)
 742                                         {
 743                                                 if (w_random<0.15)
 744                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTN_NORM);
 745                                                 else if (w_random<0.7)
 746                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTN_NORM);
 747                                                 else
 748                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTN_NORM);
 749                                         }
 750                                 }
 751                         }
 752                         else
 753                         {
 754                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 755                                 if(!w_issilent)
 756                                 {
 757                                         if (w_random<0.15)
 758                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTN_NORM);
 759                                         else if (w_random<0.7)
 760                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTN_NORM);
 761                                         else
 762                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTN_NORM);
 763                                 }
 764                         }
 765
 766                         return TRUE;
 767                 }
 768                 case WR_INIT:
 769                 {
 770                         precache_sound("weapons/seekerexp1.wav");
 771                         precache_sound("weapons/seekerexp2.wav");
 772                         precache_sound("weapons/seekerexp3.wav");
 773                         precache_sound("weapons/tagexp1.wav");
 774                         precache_sound("weapons/tagexp2.wav");
 775                         precache_sound("weapons/tagexp3.wav");
 776                         precache_sound("weapons/tag_impact.wav");
 777                         return TRUE;
 778                 }
 779         }
 780
 781         return TRUE;
 782 }
 783 #endif
 784 #endif