qcsrc/common/weapons/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SHOTGUN,
   4 /* function  */ W_Shotgun,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 2,
   7 /* flags     */ WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN | WEP_FLAG_MUTATORBLOCKED,
   8 /* rating    */ BOT_PICKUP_RATING_LOW,
   9 /* color     */ '0.5 0.25 0',
  10 /* modelname */ "shotgun",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairshotgun 0.65",
  13 /* wepimg    */ "weaponshotgun",
  14 /* refname   */ "shotgun",
  15 /* wepname   */ _("Shotgun")
  16 );
  17
  18 #define SHOTGUN_SETTINGS(w_cvar,w_prop) SHOTGUN_SETTINGS_LIST(w_cvar, w_prop, SHOTGUN, shotgun)
  19 #define SHOTGUN_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, PRI,  ammo) \
  21         w_cvar(id, sn, BOTH, animtime) \
  22         w_cvar(id, sn, BOTH, refire) \
  23         w_cvar(id, sn, PRI,  bullets) \
  24         w_cvar(id, sn, BOTH, damage) \
  25         w_cvar(id, sn, BOTH, force) \
  26         w_cvar(id, sn, PRI,  solidpenetration) \
  27         w_cvar(id, sn, PRI,  spread) \
  28         w_cvar(id, sn, NONE, secondary) \
  29         w_cvar(id, sn, SEC,  melee_time) \
  30         w_cvar(id, sn, SEC,  melee_no_doubleslap) \
  31         w_cvar(id, sn, SEC,  melee_traces) \
  32         w_cvar(id, sn, SEC,  melee_swing_up) \
  33         w_cvar(id, sn, SEC,  melee_swing_side) \
  34         w_cvar(id, sn, SEC,  melee_nonplayerdamage) \
  35         w_cvar(id, sn, SEC,  melee_multihit) \
  36         w_cvar(id, sn, SEC,  melee_delay) \
  37         w_cvar(id, sn, SEC,  melee_range) \
  38         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  39         w_prop(id, sn, float,  reloading_time, reload_time) \
  40         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  41         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  42         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  43         w_prop(id, sn, float,  weaponstart, weaponstart) \
  44         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  45
  46 #ifdef SVQC
  47 SHOTGUN_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  48 #endif
  49 #else
  50 #ifdef SVQC
  51 void spawnfunc_weapon_shotgun(void) { weapon_defaultspawnfunc(WEP_SHOTGUN); }
  52
  53 void W_Shotgun_Attack (void)
  54 {
  55         float   sc;
  56         entity flash;
  57
  58         W_DecreaseAmmo(WEP_CVAR_PRI(shotgun, ammo));
  59
  60         W_SetupShot (self, TRUE, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, WEP_CVAR_PRI(shotgun, damage) * WEP_CVAR_PRI(shotgun, bullets));
  61         for (sc = 0;sc < WEP_CVAR_PRI(shotgun, bullets);sc = sc + 1)
  62                 fireBullet(w_shotorg, w_shotdir, WEP_CVAR_PRI(shotgun, spread), WEP_CVAR_PRI(shotgun, solidpenetration), WEP_CVAR_PRI(shotgun, damage), WEP_CVAR_PRI(shotgun, force), WEP_SHOTGUN, 0);
  63
  64         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, WEP_CVAR_PRI(shotgun, ammo));
  65
  66         // casing code
  67         if (autocvar_g_casings >= 1)
  68                 for (sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  69                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  70
  71         // muzzle flash for 1st person view
  72         flash = spawn();
  73         setmodel(flash, "models/uziflash.md3"); // precision set below
  74         flash.think = SUB_Remove;
  75         flash.nextthink = time + 0.06;
  76         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  77         W_AttachToShotorg(flash, '5 0 0');
  78 }
  79
  80 .float swing_prev;
  81 .entity swing_alreadyhit;
  82 void W_Shotgun_Melee_Think()
  83 {
  84         // declarations
  85         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  86         entity target_victim;
  87         vector targpos;
  88
  89         if(!self.cnt) // set start time of melee
  90         {
  91                 self.cnt = time;
  92                 W_PlayStrengthSound(self.realowner);
  93         }
  94
  95         makevectors(self.realowner.v_angle); // update values for v_* vectors
  96
  97         // calculate swing percentage based on time
  98         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor();
  99         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 100         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
 101
 102         // check to see if we can still continue, otherwise give up now
 103         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
 104         {
 105                 remove(self);
 106                 return;
 107         }
 108
 109         // if okay, perform the traces needed for this frame
 110         for(i=self.swing_prev; i < f; ++i)
 111         {
 112                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
 113
 114                 targpos = (self.realowner.origin + self.realowner.view_ofs
 115                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
 116                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
 117                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
 118
 119                 WarpZone_traceline_antilag(self, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self, ANTILAG_LATENCY(self.realowner));
 120
 121                 // draw lightning beams for debugging
 122                 //te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 123                 //te_customflash(targpos, 40,  2, '1 1 1');
 124
 125                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body");
 126
 127                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 128                         && (trace_ent.takedamage == DAMAGE_AIM)
 129                         && (trace_ent != self.swing_alreadyhit)
 130                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
 131                 {
 132                         target_victim = trace_ent; // so it persists through other calls
 133
 134                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 135                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
 136                         else
 137                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
 138
 139                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 140
 141                         Damage(target_victim, self.realowner, self.realowner,
 142                                 swing_damage, WEP_SHOTGUN | HITTYPE_SECONDARY,
 143                                 self.realowner.origin + self.realowner.view_ofs,
 144                                 v_forward * WEP_CVAR_SEC(shotgun, force));
 145
 146                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOTGUN, 0, swing_damage); }
 147
 148                         // draw large red flash for debugging
 149                         //te_customflash(targpos, 200, 2, '15 0 0');
 150
 151                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 152                         {
 153                                 self.swing_alreadyhit = target_victim;
 154                                 continue; // move along to next trace
 155                         }
 156                         else
 157                         {
 158                                 remove(self);
 159                                 return;
 160                         }
 161                 }
 162         }
 163
 164         if(time >= self.cnt + meleetime)
 165         {
 166                 // melee is finished
 167                 remove(self);
 168                 return;
 169         }
 170         else
 171         {
 172                 // set up next frame
 173                 self.swing_prev = i;
 174                 self.nextthink = time;
 175         }
 176 }
 177
 178 void W_Shotgun_Attack2 (void)
 179 {
 180         sound (self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTEN_NORM);
 181         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 182
 183         entity meleetemp;
 184         meleetemp = spawn();
 185         meleetemp.realowner = self;
 186         meleetemp.think = W_Shotgun_Melee_Think;
 187         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor();
 188         W_SetupShot_Range(self, TRUE, 0, "", 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range));
 189 }
 190
 191 .float shotgun_primarytime;
 192
 193 float W_Shotgun(float req)
 194 {
 195         switch(req)
 196         {
 197                 case WR_AIM:
 198                 {
 199                         if(vlen(self.origin-self.enemy.origin) <= WEP_CVAR_SEC(shotgun, melee_range))
 200                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 201                         else
 202                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 203
 204                         return TRUE;
 205                 }
 206                 case WR_THINK:
 207                 {
 208                         if(WEP_CVAR(shotgun, reload_ammo) && self.clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 209                         {
 210                                 // don't force reload an empty shotgun if its melee attack is active
 211                                 if (!WEP_CVAR(shotgun, secondary))
 212                                         WEP_ACTION(self.weapon, WR_RELOAD);
 213                         }
 214                         else
 215                         {
 216                                 if (self.BUTTON_ATCK)
 217                                 {
 218                                         if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 219                                         {
 220                                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(shotgun, animtime)))
 221                                                 {
 222                                                         W_Shotgun_Attack();
 223                                                         self.shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor();
 224                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 225                                                 }
 226                                         }
 227                                 }
 228                         }
 229                         if (self.clip_load >= 0) // we are not currently reloading
 230                         if (!self.crouch) // no crouchmelee please
 231                         if (self.BUTTON_ATCK2 && WEP_CVAR(shotgun, secondary))
 232                         if (weapon_prepareattack(1, WEP_CVAR_SEC(shotgun, refire)))
 233                         {
 234                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 235                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 236                         }
 237
 238                         return TRUE;
 239                 }
 240                 case WR_INIT:
 241                 {
 242                         precache_model ("models/uziflash.md3");
 243                         precache_model ("models/weapons/g_shotgun.md3");
 244                         precache_model ("models/weapons/v_shotgun.md3");
 245                         precache_model ("models/weapons/h_shotgun.iqm");
 246                         precache_sound ("misc/itempickup.wav");
 247                         precache_sound ("weapons/shotgun_fire.wav");
 248                         precache_sound ("weapons/shotgun_melee.wav");
 249                         SHOTGUN_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 250                         return TRUE;
 251                 }
 252                 case WR_SETUP:
 253                 {
 254                         self.ammo_field = ammo_none;
 255                         return TRUE;
 256                 }
 257                 case WR_CHECKAMMO1:
 258                 case WR_CHECKAMMO2:
 259                 {
 260                         // shotgun has infinite ammo
 261                         return TRUE;
 262                 }
 263                 case WR_CONFIG:
 264                 {
 265                         SHOTGUN_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 266                         return TRUE;
 267                 }
 268                 case WR_RELOAD:
 269                 {
 270                         W_Reload(WEP_CVAR_PRI(shotgun, ammo), "weapons/reload.wav"); // WEAPONTODO
 271                         return TRUE;
 272                 }
 273                 case WR_SUICIDEMESSAGE:
 274                 {
 275                         return WEAPON_THINKING_WITH_PORTALS;
 276                 }
 277                 case WR_KILLMESSAGE:
 278                 {
 279                         if(w_deathtype & HITTYPE_SECONDARY)
 280                                 return WEAPON_SHOTGUN_MURDER_SLAP;
 281                         else
 282                                 return WEAPON_SHOTGUN_MURDER;
 283                 }
 284         }
 285         return FALSE;
 286 }
 287 #endif
 288 #ifdef CSQC
 289 .float prevric;
 290 float W_Shotgun(float req)
 291 {
 292         switch(req)
 293         {
 294                 case WR_IMPACTEFFECT:
 295                 {
 296                         vector org2;
 297                         org2 = w_org + w_backoff * 2;
 298                         pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 299                         if(!w_issilent && time - self.prevric > 0.25)
 300                         {
 301                                 if(w_random < 0.0165)
 302                                         sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTEN_NORM);
 303                                 else if(w_random < 0.033)
 304                                         sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTEN_NORM);
 305                                 else if(w_random < 0.05)
 306                                         sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTEN_NORM);
 307                                 self.prevric = time;
 308                         }
 309
 310                         return TRUE;
 311                 }
 312                 case WR_INIT:
 313                 {
 314                         precache_sound("weapons/ric1.wav");
 315                         precache_sound("weapons/ric2.wav");
 316                         precache_sound("weapons/ric3.wav");
 317                         return TRUE;
 318                 }
 319                 case WR_ZOOMRETICLE:
 320                 {
 321                         // no weapon specific image for this weapon
 322                         return FALSE;
 323                 }
 324         }
 325         return FALSE;
 326 }
 327 #endif
 328 #endif