qcsrc/common/weapons/weapon/minelayer.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MINE_LAYER,
   4 /* function  */ W_MineLayer,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 4,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.75 1 0',
  10 /* modelname */ "minelayer",
  11 /* model     */ MDL_MINELAYER_ITEM,
  12 /* simplemdl */ "foobar",
  13 /* crosshair */ "gfx/crosshairminelayer 0.9",
  14 /* wepimg    */ "weaponminelayer",
  15 /* refname   */ "minelayer",
  16 /* wepname   */ _("Mine Layer")
  17 );
  18
  19 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  20 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  21         w_cvar(id, sn, NONE, ammo) \
  22         w_cvar(id, sn, NONE, animtime) \
  23         w_cvar(id, sn, NONE, damage) \
  24         w_cvar(id, sn, NONE, damageforcescale) \
  25         w_cvar(id, sn, NONE, detonatedelay) \
  26         w_cvar(id, sn, NONE, edgedamage) \
  27         w_cvar(id, sn, NONE, force) \
  28         w_cvar(id, sn, NONE, health) \
  29         w_cvar(id, sn, NONE, lifetime) \
  30         w_cvar(id, sn, NONE, lifetime_countdown) \
  31         w_cvar(id, sn, NONE, limit) \
  32         w_cvar(id, sn, NONE, protection) \
  33         w_cvar(id, sn, NONE, proximityradius) \
  34         w_cvar(id, sn, NONE, radius) \
  35         w_cvar(id, sn, NONE, refire) \
  36         w_cvar(id, sn, NONE, remote_damage) \
  37         w_cvar(id, sn, NONE, remote_edgedamage) \
  38         w_cvar(id, sn, NONE, remote_force) \
  39         w_cvar(id, sn, NONE, remote_radius) \
  40         w_cvar(id, sn, NONE, speed) \
  41         w_cvar(id, sn, NONE, time) \
  42         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  43         w_prop(id, sn, float,  reloading_time, reload_time) \
  44         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  45         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  46         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  47         w_prop(id, sn, float,  weaponstart, weaponstart) \
  48         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  49         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  50
  51 #ifdef SVQC
  52 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  53 void W_MineLayer_Think(void);
  54 .float minelayer_detonate, mine_explodeanyway;
  55 .float mine_time;
  56 .vector mine_orientation;
  57 #endif
  58 #endif
  59 #ifdef IMPLEMENTATION
  60 #ifdef SVQC
  61 void spawnfunc_weapon_minelayer(void) { weapon_defaultspawnfunc(WEP_MINE_LAYER.m_id); }
  62
  63 void W_MineLayer_Stick(entity to)
  64 {SELFPARAM();
  65         spamsound(self, CH_SHOTS, SND(MINE_STICK), VOL_BASE, ATTN_NORM);
  66
  67         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  68
  69         entity newmine;
  70         newmine = spawn();
  71         newmine.classname = self.classname;
  72
  73         newmine.bot_dodge = self.bot_dodge;
  74         newmine.bot_dodgerating = self.bot_dodgerating;
  75
  76         newmine.owner = self.owner;
  77         newmine.realowner = self.realowner;
  78         setsize(newmine, '-4 -4 -4', '4 4 4');
  79         setorigin(newmine, self.origin);
  80         setmodel(newmine, MDL_MINELAYER_MINE);
  81         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  82
  83         newmine.mine_orientation = -trace_plane_normal;
  84
  85         newmine.takedamage = self.takedamage;
  86         newmine.damageforcescale = self.damageforcescale;
  87         newmine.health = self.health;
  88         newmine.event_damage = self.event_damage;
  89         newmine.spawnshieldtime = self.spawnshieldtime;
  90         newmine.damagedbycontents = true;
  91
  92         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  93         newmine.projectiledeathtype = self.projectiledeathtype;
  94
  95         newmine.mine_time = self.mine_time;
  96
  97         newmine.touch = func_null;
  98         newmine.think = W_MineLayer_Think;
  99         newmine.nextthink = time;
 100         newmine.cnt = self.cnt;
 101         newmine.flags = self.flags;
 102
 103         remove(self);
 104         setself(newmine);
 105
 106         if(to)
 107                 SetMovetypeFollow(self, to);
 108 }
 109
 110 void W_MineLayer_Explode(void)
 111 {SELFPARAM();
 112         if(other.takedamage == DAMAGE_AIM)
 113                 if(IS_PLAYER(other))
 114                         if(DIFF_TEAM(self.realowner, other))
 115                                 if(other.deadflag == DEAD_NO)
 116                                         if(IsFlying(other))
 117                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 118
 119         self.event_damage = func_null;
 120         self.takedamage = DAMAGE_NO;
 121
 122         RadiusDamage(self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 123
 124         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 125         {
 126                 setself(self.realowner);
 127                 if(!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 128                 {
 129                         self.cnt = WEP_MINE_LAYER.m_id;
 130                         ATTACK_FINISHED(self) = time;
 131                         self.switchweapon = w_getbestweapon(self);
 132                 }
 133                 setself(this);
 134         }
 135         self.realowner.minelayer_mines -= 1;
 136         remove(self);
 137 }
 138
 139 void W_MineLayer_DoRemoteExplode(void)
 140 {SELFPARAM();
 141         self.event_damage = func_null;
 142         self.takedamage = DAMAGE_NO;
 143
 144         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 145                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 146
 147         RadiusDamage(self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 148
 149         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 150         {
 151                 setself(self.realowner);
 152                 if(!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 153                 {
 154                         self.cnt = WEP_MINE_LAYER.m_id;
 155                         ATTACK_FINISHED(self) = time;
 156                         self.switchweapon = w_getbestweapon(self);
 157                 }
 158                 setself(this);
 159         }
 160         self.realowner.minelayer_mines -= 1;
 161         remove(self);
 162 }
 163
 164 void W_MineLayer_RemoteExplode(void)
 165 {SELFPARAM();
 166         if(self.realowner.deadflag == DEAD_NO)
 167                 if((self.spawnshieldtime >= 0)
 168                         ? (time >= self.spawnshieldtime) // timer
 169                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 170                 )
 171                 {
 172                         W_MineLayer_DoRemoteExplode();
 173                 }
 174 }
 175
 176 void W_MineLayer_ProximityExplode(void)
 177 {SELFPARAM();
 178         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 179         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 180         {
 181                 entity head;
 182                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 183                 while(head)
 184                 {
 185                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 186                                 return;
 187                         head = head.chain;
 188                 }
 189         }
 190
 191         self.mine_time = 0;
 192         W_MineLayer_Explode();
 193 }
 194
 195 int W_MineLayer_Count(entity e)
 196 {
 197         int minecount = 0;
 198         entity mine;
 199         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 200                 minecount += 1;
 201
 202         return minecount;
 203 }
 204
 205 void W_MineLayer_Think(void)
 206 {SELFPARAM();
 207         entity head;
 208
 209         self.nextthink = time;
 210
 211         if(self.movetype == MOVETYPE_FOLLOW)
 212         {
 213                 if(LostMovetypeFollow(self))
 214                 {
 215                         UnsetMovetypeFollow(self);
 216                         self.movetype = MOVETYPE_NONE;
 217                 }
 218         }
 219
 220         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 221         // TODO: replace this mine_trigger.wav sound with a real countdown
 222         if((time > self.cnt) && (!self.mine_time) && (self.cnt > 0))
 223         {
 224                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 225                         spamsound(self, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 226                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 227                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 228         }
 229
 230         // a player's mines shall explode if he disconnects or dies
 231         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 232         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO || self.realowner.frozen)
 233         {
 234                 other = world;
 235                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 236                 W_MineLayer_Explode();
 237                 return;
 238         }
 239
 240         // set the mine for detonation when a foe gets close enough
 241         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 242         while(head)
 243         {
 244                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO && !head.frozen)
 245                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 246                 if(!self.mine_time)
 247                 {
 248                         spamsound(self, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 249                         self.mine_time = time + WEP_CVAR(minelayer, time);
 250                 }
 251                 head = head.chain;
 252         }
 253
 254         // explode if it's time to
 255         if(self.mine_time && time >= self.mine_time)
 256         {
 257                 W_MineLayer_ProximityExplode();
 258                 return;
 259         }
 260
 261         // remote detonation
 262         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 263         if(self.realowner.deadflag == DEAD_NO)
 264         if(self.minelayer_detonate)
 265                 W_MineLayer_RemoteExplode();
 266 }
 267
 268 void W_MineLayer_Touch(void)
 269 {SELFPARAM();
 270         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 271                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 272
 273         if(WarpZone_Projectile_Touch())
 274         {
 275                 if(wasfreed(self))
 276                         self.realowner.minelayer_mines -= 1;
 277                 return;
 278         }
 279
 280         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 281         {
 282                 // hit a player
 283                 // don't stick
 284         }
 285         else
 286         {
 287                 W_MineLayer_Stick(other);
 288         }
 289 }
 290
 291 void W_MineLayer_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 292 {SELFPARAM();
 293         if(self.health <= 0)
 294                 return;
 295
 296         float is_from_enemy = (inflictor.realowner != self.realowner);
 297
 298         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 299                 return; // g_projectiles_damage says to halt
 300
 301         self.health = self.health - damage;
 302         self.angles = vectoangles(self.velocity);
 303
 304         if(self.health <= 0)
 305                 W_PrepareExplosionByDamage(attacker, W_MineLayer_Explode);
 306 }
 307
 308 void W_MineLayer_Attack(void)
 309 {SELFPARAM();
 310         entity mine;
 311         entity flash;
 312
 313         // scan how many mines we placed, and return if we reached our limit
 314         if(WEP_CVAR(minelayer, limit))
 315         {
 316                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 317                 {
 318                         // the refire delay keeps this message from being spammed
 319                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, WEAPON_MINELAYER_LIMIT, WEP_CVAR(minelayer, limit));
 320                         play2(self, SND(UNAVAILABLE));
 321                         return;
 322                 }
 323         }
 324
 325         W_DecreaseAmmo(WEP_CVAR(minelayer, ammo));
 326
 327         W_SetupShot_ProjectileSize(self, '-4 -4 -4', '4 4 4', false, 5, SND(MINE_FIRE), CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 328         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 329
 330         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 331         mine.owner = mine.realowner = self;
 332         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 333                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 334         else
 335                 mine.spawnshieldtime = -1;
 336         mine.classname = "mine";
 337         mine.bot_dodge = true;
 338         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 339
 340         mine.takedamage = DAMAGE_YES;
 341         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 342         mine.health = WEP_CVAR(minelayer, health);
 343         mine.event_damage = W_MineLayer_Damage;
 344         mine.damagedbycontents = true;
 345
 346         mine.movetype = MOVETYPE_TOSS;
 347         PROJECTILE_MAKETRIGGER(mine);
 348         mine.projectiledeathtype = WEP_MINE_LAYER.m_id;
 349         setsize(mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 350
 351         setorigin(mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 352         W_SetupProjVelocity_Basic(mine, WEP_CVAR(minelayer, speed), 0);
 353         mine.angles = vectoangles(mine.velocity);
 354
 355         mine.touch = W_MineLayer_Touch;
 356         mine.think = W_MineLayer_Think;
 357         mine.nextthink = time;
 358         mine.cnt = (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 359         mine.flags = FL_PROJECTILE;
 360         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 361
 362         if(mine.cnt > 0) { mine.cnt += time; }
 363
 364         CSQCProjectile(mine, true, PROJECTILE_MINE, true);
 365
 366         // muzzle flash for 1st person view
 367         flash = spawn();
 368         setmodel(flash, MDL_MINELAYER_MUZZLEFLASH); // precision set below
 369         SUB_SetFade(flash, time, 0.1);
 370         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 371         W_AttachToShotorg(flash, '5 0 0');
 372
 373         // common properties
 374
 375         MUTATOR_CALLHOOK(EditProjectile, self, mine);
 376
 377         self.minelayer_mines = W_MineLayer_Count(self);
 378 }
 379
 380 float W_MineLayer_PlacedMines(float detonate)
 381 {SELFPARAM();
 382         entity mine;
 383         float minfound = 0;
 384
 385         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 386         {
 387                 if(detonate)
 388                 {
 389                         if(!mine.minelayer_detonate)
 390                         {
 391                                 mine.minelayer_detonate = true;
 392                                 minfound = 1;
 393                         }
 394                 }
 395                 else
 396                         minfound = 1;
 397         }
 398         return minfound;
 399 }
 400
 401 bool W_MineLayer(entity thiswep, int req)
 402 {SELFPARAM();
 403         entity mine;
 404         float ammo_amount;
 405         switch(req)
 406         {
 407                 case WR_AIM:
 408                 {
 409                         // aim and decide to fire if appropriate
 410                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 411                                 self.BUTTON_ATCK = false;
 412                         else
 413                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), false);
 414                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 415                         {
 416                                 // decide whether to detonate mines
 417                                 entity targetlist, targ;
 418                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 419                                 float selfdamage, teamdamage, enemydamage;
 420                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 421                                 coredamage = WEP_CVAR(minelayer, damage);
 422                                 edgeradius = WEP_CVAR(minelayer, radius);
 423                                 recipricoledgeradius = 1 / edgeradius;
 424                                 selfdamage = 0;
 425                                 teamdamage = 0;
 426                                 enemydamage = 0;
 427                                 targetlist = findchainfloat(bot_attack, true);
 428                                 mine = find(world, classname, "mine");
 429                                 while(mine)
 430                                 {
 431                                         if(mine.realowner != self)
 432                                         {
 433                                                 mine = find(mine, classname, "mine");
 434                                                 continue;
 435                                         }
 436                                         targ = targetlist;
 437                                         while(targ)
 438                                         {
 439                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 440                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 441                                                 // count potential damage according to type of target
 442                                                 if(targ == self)
 443                                                         selfdamage = selfdamage + d;
 444                                                 else if(targ.team == self.team && teamplay)
 445                                                         teamdamage = teamdamage + d;
 446                                                 else if(bot_shouldattack(targ))
 447                                                         enemydamage = enemydamage + d;
 448                                                 targ = targ.chain;
 449                                         }
 450                                         mine = find(mine, classname, "mine");
 451                                 }
 452                                 float desirabledamage;
 453                                 desirabledamage = enemydamage;
 454                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 455                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 456                                 if(teamplay && self.team)
 457                                         desirabledamage = desirabledamage - teamdamage;
 458
 459                                 mine = find(world, classname, "mine");
 460                                 while(mine)
 461                                 {
 462                                         if(mine.realowner != self)
 463                                         {
 464                                                 mine = find(mine, classname, "mine");
 465                                                 continue;
 466                                         }
 467                                         makevectors(mine.v_angle);
 468                                         targ = targetlist;
 469                                         if(skill > 9) // normal players only do this for the target they are tracking
 470                                         {
 471                                                 targ = targetlist;
 472                                                 while(targ)
 473                                                 {
 474                                                         if(
 475                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 476                                                                 && desirabledamage > 0.1*coredamage
 477                                                         )self.BUTTON_ATCK2 = true;
 478                                                         targ = targ.chain;
 479                                                 }
 480                                         }else{
 481                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 482                                                 //As the distance gets larger, a correct detonation gets near imposible
 483                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 484                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 485                                                         if(IS_PLAYER(self.enemy))
 486                                                                 if(desirabledamage >= 0.1*coredamage)
 487                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 488                                                                                 self.BUTTON_ATCK2 = true;
 489                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 490                                         }
 491
 492                                         mine = find(mine, classname, "mine");
 493                                 }
 494                                 // if we would be doing at X percent of the core damage, detonate it
 495                                 // but don't fire a new shot at the same time!
 496                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 497                                         self.BUTTON_ATCK2 = true;
 498                                 if((skill > 6.5) && (selfdamage > self.health))
 499                                         self.BUTTON_ATCK2 = false;
 500                                 //if(self.BUTTON_ATCK2 == true)
 501                                 //      dprint(ftos(desirabledamage),"\n");
 502                                 if(self.BUTTON_ATCK2 == true) self.BUTTON_ATCK = false;
 503                         }
 504
 505                         return true;
 506                 }
 507                 case WR_THINK:
 508                 {
 509                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 510                         {
 511                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 512                                 if(!(W_MineLayer_PlacedMines(false) && self.WEP_AMMO(MINE_LAYER) < WEP_CVAR(minelayer, ammo)))
 513                                         _WEP_ACTION(self.weapon, WR_RELOAD);
 514                         }
 515                         else if(self.BUTTON_ATCK)
 516                         {
 517                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 518                                 {
 519                                         W_MineLayer_Attack();
 520                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 521                                 }
 522                         }
 523
 524                         if(self.BUTTON_ATCK2)
 525                         {
 526                                 if(W_MineLayer_PlacedMines(true))
 527                                         sound(self, CH_WEAPON_B, SND_MINE_DET, VOL_BASE, ATTN_NORM);
 528                         }
 529
 530                         return true;
 531                 }
 532                 case WR_INIT:
 533                 {
 534                         MINELAYER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 535                         return true;
 536                 }
 537                 case WR_CHECKAMMO1:
 538                 {
 539                         // don't switch while placing a mine
 540                         if(ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER.m_id)
 541                         {
 542                                 ammo_amount = self.WEP_AMMO(MINE_LAYER) >= WEP_CVAR(minelayer, ammo);
 543                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER.m_id]) >= WEP_CVAR(minelayer, ammo);
 544                                 return ammo_amount;
 545                         }
 546                         return true;
 547                 }
 548                 case WR_CHECKAMMO2:
 549                 {
 550                         if(W_MineLayer_PlacedMines(false))
 551                                 return true;
 552                         else
 553                                 return false;
 554                 }
 555                 case WR_CONFIG:
 556                 {
 557                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 558                         return true;
 559                 }
 560                 case WR_RESETPLAYER:
 561                 {
 562                         self.minelayer_mines = 0;
 563                         return true;
 564                 }
 565                 case WR_RELOAD:
 566                 {
 567                         W_Reload(WEP_CVAR(minelayer, ammo), SND(RELOAD));
 568                         return true;
 569                 }
 570                 case WR_SUICIDEMESSAGE:
 571                 {
 572                         return WEAPON_MINELAYER_SUICIDE;
 573                 }
 574                 case WR_KILLMESSAGE:
 575                 {
 576                         return WEAPON_MINELAYER_MURDER;
 577                 }
 578         }
 579         return false;
 580 }
 581 #endif
 582 #ifdef CSQC
 583 bool W_MineLayer(entity thiswep, int req)
 584 {SELFPARAM();
 585         switch(req)
 586         {
 587                 case WR_IMPACTEFFECT:
 588                 {
 589                         vector org2;
 590                         org2 = w_org + w_backoff * 12;
 591                         pointparticles(particleeffectnum(EFFECT_ROCKET_EXPLODE), org2, '0 0 0', 1);
 592                         if(!w_issilent)
 593                                 sound(self, CH_SHOTS, SND_MINE_EXP, VOL_BASE, ATTN_NORM);
 594
 595                         return true;
 596                 }
 597                 case WR_INIT:
 598                 {
 599                         return true;
 600                 }
 601                 case WR_ZOOMRETICLE:
 602                 {
 603                         // no weapon specific image for this weapon
 604                         return false;
 605                 }
 606         }
 607         return false;
 608 }
 609 #endif
 610 #endif