qcsrc/common/weapons/weapon/porto.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(PortoLaunch, Weapon)
   3 /* ammotype  */ ATTRIB(PortoLaunch, ammo_field, .int, ammo_none)
   4 /* impulse   */ ATTRIB(PortoLaunch, impulse, int, 0)
   5 /* flags     */ ATTRIB(PortoLaunch, spawnflags, int, WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON);
   6 /* rating    */ ATTRIB(PortoLaunch, bot_pickupbasevalue, float, 0);
   7 /* color     */ ATTRIB(PortoLaunch, wpcolor, vector, '0.5 0.5 0.5');
   8 /* modelname */ ATTRIB(PortoLaunch, mdl, string, "porto");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(PortoLaunch, m_model, Model, MDL_PORTO_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair, string, "gfx/crosshairporto");
  13 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(PortoLaunch, model2, string, "weaponporto");
  15 /* refname   */ ATTRIB(PortoLaunch, netname, string, "porto");
  16 /* wepname   */ ATTRIB(PortoLaunch, m_name, string, _("Port-O-Launch"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, animtime, float, BOTH) \
  21                 P(class, prefix, lifetime, float, BOTH) \
  22                 P(class, prefix, refire, float, BOTH) \
  23                 P(class, prefix, secondary, float, NONE) \
  24                 P(class, prefix, speed, float, BOTH) \
  25         P(class, prefix, switchdelay_drop, float, NONE) \
  26                 P(class, prefix, switchdelay_raise, float, NONE) \
  27         P(class, prefix, weaponreplace, string,NONE) \
  28         P(class, prefix, weaponstartoverride, float, NONE) \
  29         P(class, prefix, weaponstart, float, NONE) \
  30         P(class, prefix, weaponthrowable, float, NONE) \
  31         END()
  32     W_PROPS(X, PortoLaunch, porto)
  33 #undef X
  34 ENDCLASS(PortoLaunch)
  35 REGISTER_WEAPON(PORTO, porto, NEW(PortoLaunch));
  36
  37 #ifdef SVQC
  38 .entity porto_current;
  39 .vector porto_v_angle; // holds "held" view angles
  40 .float porto_v_angle_held;
  41 .vector right_vector;
  42 .float porto_forbidden;
  43 #endif
  44 #endif
  45 #ifdef IMPLEMENTATION
  46 #ifdef SVQC
  47 #include "../../triggers/trigger/jumppads.qh"
  48
  49 spawnfunc(weapon_porto) { weapon_defaultspawnfunc(this, WEP_PORTO); }
  50
  51 REGISTER_MUTATOR(porto_ticker, true);
  52 MUTATOR_HOOKFUNCTION(porto_ticker, SV_StartFrame) {
  53         entity e;
  54         FOR_EACH_PLAYER(e)
  55                 e.porto_forbidden = max(0, e.porto_forbidden - 1);
  56 }
  57
  58 void W_Porto_Success()
  59 {SELFPARAM();
  60         if(self.realowner == world)
  61         {
  62                 objerror("Cannot succeed successfully: no owner\n");
  63                 return;
  64         }
  65
  66         self.realowner.porto_current = world;
  67         remove(self);
  68 }
  69
  70 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  71 void W_Porto_Fail(float failhard)
  72 {SELFPARAM();
  73         if(self.realowner == world)
  74         {
  75                 objerror("Cannot fail successfully: no owner\n");
  76                 return;
  77         }
  78
  79         // no portals here!
  80         if(self.cnt < 0)
  81         {
  82                 Portal_ClearWithID(self.realowner, self.portal_id);
  83         }
  84
  85         self.realowner.porto_current = world;
  86
  87         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET(PORTO)))
  88         {
  89                 setsize(self, '-16 -16 0', '16 16 32');
  90                 setorigin(self, self.origin + trace_plane_normal);
  91                 if(move_out_of_solid(self))
  92                 {
  93                         self.flags = FL_ITEM;
  94                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  95                         tracetoss(self, self);
  96                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  97                         {
  98                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO.m_id, 0, self.origin, self.velocity);
  99                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_FAILED);
 100                         }
 101                 }
 102         }
 103         remove(self);
 104 }
 105
 106 void W_Porto_Remove(entity p)
 107 {SELFPARAM();
 108         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
 109         {
 110                 WITH(entity, self, p.porto_current, W_Porto_Fail(1));
 111         }
 112 }
 113
 114 void W_Porto_Think()
 115 {SELFPARAM();
 116         trace_plane_normal = '0 0 0';
 117         if(self.realowner.playerid != self.playerid)
 118                 remove(self);
 119         else
 120                 W_Porto_Fail(0);
 121 }
 122
 123 void W_Porto_Touch()
 124 {SELFPARAM();
 125         vector norm;
 126
 127         // do not use PROJECTILE_TOUCH here
 128         // FIXME but DO handle warpzones!
 129
 130         if(other.classname == "portal")
 131                 return; // handled by the portal
 132
 133         norm = trace_plane_normal;
 134         if(trace_ent.iscreature)
 135         {
 136                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN.z, MOVE_WORLDONLY, self);
 137                 if(trace_fraction >= 1)
 138                         return;
 139                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 140                         return;
 141                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 142                         return;
 143         }
 144
 145         if(self.realowner.playerid != self.playerid)
 146         {
 147                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 148                 remove(self);
 149         }
 150         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 151         {
 152                 spamsound(self, CH_SHOTS, SND(PORTO_BOUNCE), VOL_BASE, ATTEN_NORM);
 153                 // just reflect
 154                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 155                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 156         }
 157         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 158         {
 159                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 160                 W_Porto_Fail(0);
 161                 if(self.cnt < 0)
 162                         Portal_ClearAll_PortalsOnly(self.realowner);
 163         }
 164         else if(self.cnt == 0)
 165         {
 166                 // in-portal only
 167                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 168                 {
 169                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 170                         trace_plane_normal = norm;
 171                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 172                         W_Porto_Success();
 173                 }
 174                 else
 175                 {
 176                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 177                         trace_plane_normal = norm;
 178                         W_Porto_Fail(0);
 179                 }
 180         }
 181         else if(self.cnt == 1)
 182         {
 183                 // out-portal only
 184                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 185                 {
 186                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 187                         trace_plane_normal = norm;
 188                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 189                         W_Porto_Success();
 190                 }
 191                 else
 192                 {
 193                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 194                         trace_plane_normal = norm;
 195                         W_Porto_Fail(0);
 196                 }
 197         }
 198         else if(self.effects & EF_RED)
 199         {
 200                 self.effects += EF_BLUE - EF_RED;
 201                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 202                 {
 203                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 204                         trace_plane_normal = norm;
 205                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 206                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 207                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 208                         CSQCProjectile(self, true, PROJECTILE_PORTO_BLUE, true); // change type
 209                 }
 210                 else
 211                 {
 212                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 213                         trace_plane_normal = norm;
 214                         Portal_ClearAll_PortalsOnly(self.realowner);
 215                         W_Porto_Fail(0);
 216                 }
 217         }
 218         else
 219         {
 220                 if(self.realowner.portal_in.portal_id == self.portal_id)
 221                 {
 222                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 223                         {
 224                                 sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 225                                 trace_plane_normal = norm;
 226                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 227                                 W_Porto_Success();
 228                         }
 229                         else
 230                         {
 231                                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 232                                 Portal_ClearAll_PortalsOnly(self.realowner);
 233                                 W_Porto_Fail(0);
 234                         }
 235                 }
 236                 else
 237                 {
 238                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 239                         Portal_ClearAll_PortalsOnly(self.realowner);
 240                         W_Porto_Fail(0);
 241                 }
 242         }
 243 }
 244
 245 void W_Porto_Attack(float type)
 246 {SELFPARAM();
 247         entity gren;
 248
 249         W_SetupShot(self, false, 4, SND(PORTO_FIRE), CH_WEAPON_A, 0);
 250         // always shoot from the eye
 251         w_shotdir = v_forward;
 252         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 253
 254         //Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 255
 256         gren = new(porto);
 257         gren.cnt = type;
 258         gren.owner = gren.realowner = self;
 259         gren.playerid = self.playerid;
 260         gren.bot_dodge = true;
 261         gren.bot_dodgerating = 200;
 262         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 263         PROJECTILE_MAKETRIGGER(gren);
 264         gren.effects = EF_RED;
 265         gren.scale = 4;
 266         setorigin(gren, w_shotorg);
 267         setsize(gren, '0 0 0', '0 0 0');
 268
 269         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 270         gren.think = W_Porto_Think;
 271         gren.touch = W_Porto_Touch;
 272
 273         if(self.items & ITEM_Strength.m_itemid)
 274                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 275         else
 276                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 277
 278         gren.angles = vectoangles(gren.velocity);
 279         gren.flags = FL_PROJECTILE;
 280
 281         gren.portal_id = time;
 282         self.porto_current = gren;
 283         gren.playerid = self.playerid;
 284         fixedmakevectors(fixedvectoangles(gren.velocity));
 285         gren.right_vector = v_right;
 286
 287         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 288
 289         if(type > 0)
 290                 CSQCProjectile(gren, true, PROJECTILE_PORTO_BLUE, true);
 291         else
 292                 CSQCProjectile(gren, true, PROJECTILE_PORTO_RED, true);
 293
 294         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 295 }
 296
 297                 METHOD(PortoLaunch, wr_aim, void(entity thiswep))
 298                 {
 299                         SELFPARAM();
 300                         self.BUTTON_ATCK = false;
 301                         self.BUTTON_ATCK2 = false;
 302                         if(!WEP_CVAR(porto, secondary))
 303                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), false))
 304                                         self.BUTTON_ATCK = true;
 305                 }
 306                 METHOD(PortoLaunch, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 307                 {
 308                         if(WEP_CVAR(porto, secondary))
 309                         {
 310                                 if(fire & 1)
 311                                 if(!actor.porto_current)
 312                                 if(!actor.porto_forbidden)
 313                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(porto, refire)))
 314                                 {
 315                                         W_Porto_Attack(0);
 316                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 317                                 }
 318
 319                                 if(fire & 2)
 320                                 if(!actor.porto_current)
 321                                 if(!actor.porto_forbidden)
 322                                 if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(porto, refire)))
 323                                 {
 324                                         W_Porto_Attack(1);
 325                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 326                                 }
 327                         }
 328                         else
 329                         {
 330                                 if(actor.porto_v_angle_held)
 331                                 {
 332                                         if(!(fire & 2))
 333                                         {
 334                                                 actor.porto_v_angle_held = 0;
 335
 336                                                 ClientData_Touch(actor);
 337                                         }
 338                                 }
 339                                 else
 340                                 {
 341                                         if(fire & 2)
 342                                         {
 343                                                 actor.porto_v_angle = actor.v_angle;
 344                                                 actor.porto_v_angle_held = 1;
 345
 346                                                 ClientData_Touch(actor);
 347                                         }
 348                                 }
 349                                 if(actor.porto_v_angle_held)
 350                                         makevectors(actor.porto_v_angle); // override the previously set angles
 351
 352                                 if(fire & 1)
 353                                 if(!actor.porto_current)
 354                                 if(!actor.porto_forbidden)
 355                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(porto, refire)))
 356                                 {
 357                                         W_Porto_Attack(-1);
 358                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 359                                 }
 360                         }
 361                 }
 362                 METHOD(PortoLaunch, wr_checkammo1, bool(entity this))
 363                 {
 364                         // always allow infinite ammo
 365                         return true;
 366                 }
 367                 METHOD(PortoLaunch, wr_checkammo2, bool(entity this))
 368                 {
 369                         // always allow infinite ammo
 370                         return true;
 371                 }
 372                 METHOD(PortoLaunch, wr_setup, void(entity thiswep))
 373                 {
 374                         SELFPARAM();
 375                         self.ammo_field = ammo_none;
 376                 }
 377                 METHOD(PortoLaunch, wr_resetplayer, void(entity thiswep))
 378                 {
 379                         SELFPARAM();
 380                         self.porto_current = world;
 381                 }
 382 #endif
 383 #ifdef CSQC
 384                 METHOD(PortoLaunch, wr_impacteffect, void(entity this)) {
 385                         LOG_WARNING("Since when does Porto send DamageInfo?\n");
 386                 }
 387 #endif
 388 #endif