qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12 float ca_teams_ok;
  13 .float caplayer;
  14
  15 void PutObserverInServer();
  16 void PutClientInServer();
  17 void(entity e) ReturnFlag;
  18 void dom_controlpoint_setup();
  19 void onslaught_generator_reset();
  20 void onslaught_controlpoint_reset();
  21 void func_breakable_reset();
  22 void assault_objective_reset();
  23 void target_assault_roundend_reset();
  24
  25 float next_round;
  26 float stopalivecheck;
  27 float redalive, bluealive, yellowalive, pinkalive;
  28 float totalalive;
  29 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
  30 float red_players, blue_players, yellow_players, pink_players;
  31 float total_players;
  32
  33 /**
  34  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
  35  * Sets the 'warmup' global variable.
  36  */
  37 void reset_map(float dorespawn)
  38 {
  39         entity oldself;
  40         oldself = self;
  41
  42         if(g_arena && autocvar_g_arena_warmup)
  43                 warmup = time + autocvar_g_arena_warmup;
  44         else if(g_ca) {
  45                 warmup = time + autocvar_g_ca_warmup;
  46                 allowed_to_spawn = 1;
  47         }
  48         else if(g_freezetag)
  49         {
  50                 warmup = time + autocvar_g_freezetag_warmup;
  51         }
  52
  53         lms_lowest_lives = 999;
  54         lms_next_place = player_count;
  55
  56         race_ReadyRestart();
  57
  58         for(self = world; (self = nextent(self)); )
  59         if(clienttype(self) == CLIENTTYPE_NOTACLIENT && self.items != IT_STRENGTH && self.items != IT_INVINCIBLE) // don't respawn strength or shield, that will only lead to them spawning very early each match
  60         {
  61                 if(self.reset)
  62                 {
  63                         self.reset();
  64                         continue;
  65                 }
  66
  67                 if(self.team_saved)
  68                         self.team = self.team_saved;
  69
  70                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
  71                         remove(self);
  72         }
  73
  74         // Waypoints and assault start come LAST
  75         for(self = world; (self = nextent(self)); )
  76         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
  77         {
  78                 if(self.reset2)
  79                 {
  80                         self.reset2();
  81                         continue;
  82                 }
  83         }
  84
  85         // Moving the player reset code here since the player-reset depends
  86         // on spawnpoint entities which have to be reset first --blub
  87         if(dorespawn)
  88         FOR_EACH_CLIENT(self) {
  89                 if(self.flags & FL_CLIENT)                              // reset all players
  90                 {
  91                         if(g_arena)
  92                         {
  93                                 if(self.spawned)
  94                                         PutClientInServer();
  95                                 else
  96                                         PutObserverInServer();
  97                         }
  98                         else if(g_ca && self.caplayer) {
  99                                 self.classname = "player";
 100                                 PutClientInServer();
 101                         }
 102                         else if(g_freezetag)
 103                         {
 104                                 if(self.classname == "player")
 105                                         PutClientInServer();
 106                         }
 107                         else
 108                         {
 109                                 /*
 110                                 only reset players if a restart countdown is active
 111                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 112                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 113                                 sv_ready_restart_after_countdown is not used and countdown is still running
 114                                 */
 115                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 116                                 {
 117                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 118                                         if (self.classname == "player") {
 119                                                 //PlayerScore_Clear(self);
 120                                                 if(g_lms)
 121                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 122                                                 self.killcount = 0;
 123                                                 //stop the player from moving so that he stands still once he gets respawned
 124                                                 self.velocity = '0 0 0';
 125                                                 self.avelocity = '0 0 0';
 126                                                 self.movement = '0 0 0';
 127                                                 PutClientInServer();
 128                                         }
 129                                 }
 130                         }
 131                 }
 132         }
 133
 134         if(g_keyhunt)
 135                 kh_Controller_SetThink_NoMsg(autocvar_g_balance_keyhunt_delay_round+(game_starttime - time), kh_StartRound);
 136
 137         if(g_arena)
 138         if(champion && champion.classname == "player" && player_count > 1)
 139                 UpdateFrags(champion, +1);
 140
 141         self = oldself;
 142 }
 143
 144 void Spawnqueue_Insert(entity e)
 145 {
 146         if(e.spawnqueue_in)
 147                 return;
 148         dprint(strcat("Into queue: ", e.netname, "\n"));
 149         e.spawnqueue_in = TRUE;
 150         e.spawnqueue_prev = spawnqueue_last;
 151         e.spawnqueue_next = world;
 152         if(spawnqueue_last)
 153                 spawnqueue_last.spawnqueue_next = e;
 154         spawnqueue_last = e;
 155         if(!spawnqueue_first)
 156                 spawnqueue_first = e;
 157 }
 158
 159 void Spawnqueue_Remove(entity e)
 160 {
 161         if(!e.spawnqueue_in)
 162                 return;
 163         dprint(strcat("Out of queue: ", e.netname, "\n"));
 164         e.spawnqueue_in = FALSE;
 165         if(e == spawnqueue_first)
 166                 spawnqueue_first = e.spawnqueue_next;
 167         if(e == spawnqueue_last)
 168                 spawnqueue_last = e.spawnqueue_prev;
 169         if(e.spawnqueue_prev)
 170                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 171         if(e.spawnqueue_next)
 172                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 173         e.spawnqueue_next = world;
 174         e.spawnqueue_prev = world;
 175 }
 176
 177 void Spawnqueue_Unmark(entity e)
 178 {
 179         if(!e.spawned)
 180                 return;
 181         e.spawned = FALSE;
 182         numspawned = numspawned - 1;
 183 }
 184
 185 void Spawnqueue_Mark(entity e)
 186 {
 187         if(e.spawned)
 188                 return;
 189         e.spawned = TRUE;
 190         numspawned = numspawned + 1;
 191 }
 192
 193 /**
 194  * If roundbased arena game mode is active, it centerprints the texts for the
 195  * player when player is waiting for the countdown to finish.
 196  * Blocks the players movement while countdown is active.
 197  * Unblocks the player once the countdown is over.
 198  *
 199  * Called in StartFrame()
 200  */
 201 float roundStartTime_prev; // prevent networkspam
 202 void Arena_Warmup()
 203 {
 204         float f;
 205         entity e;
 206
 207         if(gameover)
 208         {
 209                 if(champion && g_arena)
 210                 {
 211                         FOR_EACH_CLIENT(e)
 212                                 centerprint(e, strcat("The Champion is ", champion.netname));
 213                         champion = world;
 214                 }
 215                 return;
 216         }
 217         if((!g_arena && !g_ca && !g_freezetag) || (g_arena && !arena_roundbased) || (time < game_starttime))
 218                 return;
 219
 220         f = ceil(warmup - time);
 221
 222         allowed_to_spawn = 0;
 223
 224         if(inWarmupStage)
 225                 allowed_to_spawn = 1;
 226         if(g_ca && !ca_teams_ok)
 227                 allowed_to_spawn = 1;
 228
 229         if(time < warmup && !inWarmupStage)
 230         {
 231                 if (g_ca)
 232                         allowed_to_spawn = 1;
 233                 if(champion && g_arena)
 234                 {
 235                         FOR_EACH_PLAYER(e)
 236                                 centerprint(e, strcat("The Champion is ", champion.netname));
 237                 }
 238
 239                 if(f != roundStartTime_prev) {
 240                         roundStartTime_prev = f;
 241                         if(f == 5)
 242                                 Announce("prepareforbattle");
 243                         else if(f == 3)
 244                                 Announce("3");
 245                         else if(f == 2)
 246                                 Announce("2");
 247                         else if(f == 1)
 248                                 Announce("1");
 249
 250                         FOR_EACH_PLAYER(e)
 251                                 Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "Round will start in %d", 1, f);
 252                 }
 253
 254                 if (g_arena) {
 255                         FOR_EACH_CLIENT(e)
 256                         {
 257                                 if(e.spawned && e.classname == "player")
 258                                         e.movetype = MOVETYPE_NONE;
 259                                 e.velocity = '0 0 0';
 260                                 e.avelocity = '0 0 0';
 261                                 e.movement = '0 0 0';
 262                         }
 263                 }
 264         }
 265         else if(f > -1 && f != roundStartTime_prev)
 266         {
 267                 roundStartTime_prev = f;
 268                 Announce("begin");
 269                 FOR_EACH_PLAYER(e)
 270                         Send_CSQC_Centerprint_Generic(e, CPID_ROUND_STARTING, "^1Begin!", 1, 0);
 271
 272                 if(g_ca)
 273                         ca_teams_ok = (red_players && blue_players); // teams are ok if there's at least 1 player in each team
 274
 275                 FOR_EACH_PLAYER(e)
 276                 {
 277                         if(e.health > 0 && e.movetype == MOVETYPE_NONE)
 278                                 e.movetype = MOVETYPE_WALK;
 279                 }
 280         }
 281
 282         // clear champion to avoid centerprinting again the champion msg
 283         if (champion)
 284                 champion = world;
 285 }
 286
 287 void count_players()
 288 {
 289         // count amount of players in each team
 290         total_players = red_players = blue_players = yellow_players = pink_players = 0;
 291         FOR_EACH_PLAYER(self) {
 292                 if (self.team == COLOR_TEAM1)
 293                 {
 294                         red_players += 1;
 295                         total_players += 1;
 296                 }
 297                 else if (self.team == COLOR_TEAM2)
 298                 {
 299                         blue_players += 1;
 300                         total_players += 1;
 301                 }
 302                 else if (self.team == COLOR_TEAM3)
 303                 {
 304                         yellow_players += 1;
 305                         total_players += 1;
 306                 }
 307                 else if (self.team == COLOR_TEAM4)
 308                 {
 309                         pink_players += 1;
 310                         total_players += 1;
 311                 }
 312         }
 313 }
 314
 315 void count_alive_players()
 316 {
 317         totalalive = redalive = bluealive = yellowalive = pinkalive = 0;
 318         if(g_ca)
 319         {
 320                 FOR_EACH_PLAYER(self) {
 321                         if (self.team == COLOR_TEAM1 && self.health >= 1)
 322                         {
 323                                 redalive += 1;
 324                                 totalalive += 1;
 325                         }
 326                         else if (self.team == COLOR_TEAM2 && self.health >= 1)
 327                         {
 328                                 bluealive += 1;
 329                                 totalalive += 1;
 330                         }
 331                 }
 332                 FOR_EACH_REALCLIENT(self) {
 333                         self.redalive_stat = redalive;
 334                         self.bluealive_stat = bluealive;
 335                 }
 336         }
 337         else if(g_freezetag)
 338         {
 339                 // count amount of alive players in each team
 340                 FOR_EACH_PLAYER(self) {
 341                         if (self.team == COLOR_TEAM1 && self.freezetag_frozen == 0 && self.health >= 1)
 342                         {
 343                                 redalive += 1;
 344                                 totalalive += 1;
 345                         }
 346                         else if (self.team == COLOR_TEAM2 && self.freezetag_frozen == 0 && self.health >= 1)
 347                         {
 348                                 bluealive += 1;
 349                                 totalalive += 1;
 350                         }
 351                         else if (self.team == COLOR_TEAM3 && self.freezetag_frozen == 0 && self.health >= 1)
 352                         {
 353                                 yellowalive += 1;
 354                                 totalalive += 1;
 355                         }
 356                         else if (self.team == COLOR_TEAM4 && self.freezetag_frozen == 0 && self.health >= 1)
 357                         {
 358                                 pinkalive += 1;
 359                                 totalalive += 1;
 360                         }
 361                 }
 362                 FOR_EACH_REALCLIENT(self) {
 363                         self.redalive_stat = redalive;
 364                         self.bluealive_stat = bluealive;
 365                         self.yellowalive_stat = yellowalive;
 366                         self.pinkalive_stat = pinkalive;
 367                 }
 368         }
 369
 370 }
 371
 372 /**
 373  * This function finds out whether an arena round is over 1 player is left.
 374  * It determines the last player who's still alive and saves it's entity reference
 375  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
 376  *
 377  * Gets called in StartFrame()
 378  */
 379 float warntime;
 380 void Spawnqueue_Check()
 381 {
 382         if(time < warmup + 1 || inWarmupStage || intermission_running)
 383                 return;
 384
 385         if(g_ca) {
 386                 if(!ca_teams_ok && (red_players && blue_players)) {
 387                         reset_map(TRUE);
 388                 }
 389                 else if(!ca_teams_ok) {
 390                         if (time > warntime)
 391                         {
 392                                 FOR_EACH_PLAYER(self)
 393                                         Send_CSQC_Centerprint_Generic(self, CPID_ROUND_STARTING, "^1Need at least 1 player in each team to play CA", 2, 0);
 394                                 warntime = time + 1;
 395                         }
 396                         return;
 397                 }
 398                 else if(!next_round) {
 399                         if((red_players && !blue_players) || (blue_players && !red_players)) {
 400                                 next_round = time + 5;
 401                         }
 402                         else if((!red_players && !blue_players) || time - warmup > autocvar_g_ca_round_timelimit) {
 403                                 FOR_EACH_CLIENT(self) centerprint(self, "^7Round tied");
 404                                 next_round = time + 5;
 405                         }
 406
 407                 }
 408                 if(!stopalivecheck)
 409                 {
 410                         if(redalive && !bluealive)
 411                         {
 412                                 play2all("ctf/red_capture.wav");
 413                                 FOR_EACH_CLIENT(self) centerprint(self, "^1RED ^7team wins the round");
 414                                 TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, +1);
 415                                 stopalivecheck = TRUE;
 416                         }
 417                         else if(bluealive && !redalive)
 418                         {
 419                                 play2all("ctf/blue_capture.wav");
 420                                 FOR_EACH_CLIENT(self) centerprint(self, "^4BLUE ^7team wins the round");
 421                                 TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, +1);
 422                                 stopalivecheck = TRUE;
 423                         }
 424                 }
 425
 426                 if((next_round && next_round < time))
 427                 {
 428                         stopalivecheck = FALSE;
 429                         next_round = 0;
 430                         reset_map(TRUE);
 431                 }
 432         } else if(g_freezetag) {
 433                 if((next_round && next_round < time))
 434                 {
 435                         next_round = 0;
 436                         reset_map(TRUE);
 437                 }
 438         } else { // arena
 439                 //extend next_round if it isn't set yet and only 1 player is spawned
 440                 if(!next_round)
 441                 if(numspawned < 2)
 442                         next_round = time + 3;
 443
 444                 if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 445                 {
 446                         next_round = 0;
 447
 448                         if(arena_roundbased)
 449                         {
 450                                 champion = find(world, classname, "player");
 451                                 while(champion && champion.deadflag)
 452                                         champion = find(champion, classname, "player");
 453                                 reset_map(TRUE);
 454                         }
 455
 456                         while(numspawned < maxspawned && spawnqueue_first)
 457                         {
 458                                 self = spawnqueue_first;
 459
 460                                 bprint ("^4", self.netname, "^4 is the next challenger\n");
 461
 462                                 Spawnqueue_Remove(self);
 463                                 Spawnqueue_Mark(self);
 464
 465                                 self.classname = "player";
 466                                 PutClientInServer();
 467                         }
 468                 }
 469         }
 470 }