qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/teleporters.qh>
  22 #include <common/mapobjects/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107
 108         this.bot_aimdir_executed = false;
 109
 110         if (this.bot_aimtarg)
 111         {
 112                 this.aistatus |= AI_STATUS_ATTACKING;
 113                 this.aistatus &= ~AI_STATUS_ROAMING;
 114
 115                 if(STAT(WEAPONS, this))
 116                 {
 117                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 118                         {
 119                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 120                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 121                         }
 122                         else
 123                         {
 124                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 125                                 {
 126                                         .entity weaponentity = weaponentities[slot];
 127                                         Weapon w = this.(weaponentity).m_weapon;
 128                                         if(w == WEP_Null && slot != 0)
 129                                                 continue;
 130                                         w.wr_aim(w, this, weaponentity);
 131                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 132                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 133                                 }
 134                         }
 135                 }
 136                 else
 137                 {
 138                         if(IS_PLAYER(this.bot_aimtarg))
 139                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 140                 }
 141         }
 142         else if (this.goalcurrent)
 143         {
 144                 this.aistatus |= AI_STATUS_ROAMING;
 145                 this.aistatus &= ~AI_STATUS_ATTACKING;
 146         }
 147
 148         havocbot_movetogoal(this);
 149         if (!this.bot_aimdir_executed && this.goalcurrent)
 150         {
 151                 // Heading
 152                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 153                 dir -= this.origin + this.view_ofs;
 154                 dir.z = 0;
 155                 bot_aimdir(this, dir, -1);
 156         }
 157
 158         // if the bot is not attacking, consider reloading weapons
 159         if (!(this.aistatus & AI_STATUS_ATTACKING))
 160         {
 161                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 162                 {
 163                         .entity weaponentity = weaponentities[slot];
 164
 165                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 166                                 continue;
 167
 168                         // we are currently holding a weapon that's not fully loaded, reload it
 169                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 170                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 171                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 172
 173                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 174                         // the code above executes next frame, starting the reloading then
 175                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 176                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 177                         {
 178                                 FOREACH(Weapons, it != WEP_Null, {
 179                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 180                                         {
 181                                                 this.(weaponentity).m_switchweapon = it;
 182                                                 break;
 183                                         }
 184                                 });
 185                         }
 186                 }
 187         }
 188 }
 189
 190 void havocbot_keyboard_movement(entity this, vector destorg)
 191 {
 192         vector keyboard;
 193
 194         if (time > this.havocbot_keyboardtime)
 195         {
 196                 float sk = skill + this.bot_moveskill;
 197                 this.havocbot_keyboardtime =
 198                         max(
 199                                 this.havocbot_keyboardtime
 200                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 201                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 202                         , time);
 203                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 204
 205                 float trigger = autocvar_bot_ai_keyboard_threshold;
 206                 float trigger1 = -trigger;
 207
 208                 // categorize forward movement
 209                 // at skill < 1.5 only forward
 210                 // at skill < 2.5 only individual directions
 211                 // at skill < 4.5 only individual directions, and forward diagonals
 212                 // at skill >= 4.5, all cases allowed
 213                 if (keyboard.x > trigger)
 214                 {
 215                         keyboard.x = 1;
 216                         if (sk < 2.5)
 217                                 keyboard.y = 0;
 218                 }
 219                 else if (keyboard.x < trigger1 && sk > 1.5)
 220                 {
 221                         keyboard.x = -1;
 222                         if (sk < 4.5)
 223                                 keyboard.y = 0;
 224                 }
 225                 else
 226                 {
 227                         keyboard.x = 0;
 228                         if (sk < 1.5)
 229                                 keyboard.y = 0;
 230                 }
 231                 if (sk < 4.5)
 232                         keyboard.z = 0;
 233
 234                 if (keyboard.y > trigger)
 235                         keyboard.y = 1;
 236                 else if (keyboard.y < trigger1)
 237                         keyboard.y = -1;
 238                 else
 239                         keyboard.y = 0;
 240
 241                 if (keyboard.z > trigger)
 242                         keyboard.z = 1;
 243                 else if (keyboard.z < trigger1)
 244                         keyboard.z = -1;
 245                 else
 246                         keyboard.z = 0;
 247
 248                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 249                 if (this.havocbot_ducktime > time)
 250                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 251         }
 252
 253         keyboard = this.havocbot_keyboard;
 254         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 255         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 256         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 257 }
 258
 259 void havocbot_bunnyhop(entity this, vector dir)
 260 {
 261         float bunnyhopdistance;
 262         vector deviation;
 263         float maxspeed;
 264
 265         // Don't jump when attacking
 266         if(this.aistatus & AI_STATUS_ATTACKING)
 267                 return;
 268
 269         if(IS_PLAYER(this.goalcurrent))
 270                 return;
 271
 272         maxspeed = autocvar_sv_maxspeed;
 273
 274         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 275                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 276         {
 277                 this.aistatus &= ~AI_STATUS_RUNNING;
 278                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 279                 this.bot_canruntogoal = 0;
 280                 this.bot_timelastseengoal = 0;
 281                 return;
 282         }
 283
 284         if(this.waterlevel > WATERLEVEL_WETFEET)
 285         {
 286                 this.aistatus &= ~AI_STATUS_RUNNING;
 287                 return;
 288         }
 289
 290         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 291         {
 292                 this.bot_canruntogoal = 0;
 293                 this.bot_timelastseengoal = 0;
 294         }
 295
 296         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 297         bunnyhopdistance = vlen(this.origin - gco);
 298
 299         // Run only to visible goals
 300         if(IS_ONGROUND(this))
 301         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 302         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 303         {
 304                         this.bot_lastseengoal = this.goalcurrent;
 305
 306                         // seen it before
 307                         if(this.bot_timelastseengoal)
 308                         {
 309                                 // for a period of time
 310                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 311                                 {
 312                                         float checkdistance;
 313                                         checkdistance = true;
 314
 315                                         // don't run if it is too close
 316                                         if(this.bot_canruntogoal==0)
 317                                         {
 318                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 319                                                         this.bot_canruntogoal = 1;
 320                                                 else
 321                                                         this.bot_canruntogoal = -1;
 322                                         }
 323
 324                                         if(this.bot_canruntogoal != 1)
 325                                                 return;
 326
 327                                         if(this.aistatus & AI_STATUS_ROAMING)
 328                                         if(this.goalcurrent.classname=="waypoint")
 329                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 330                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 331                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 332                                         {
 333                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 334                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 335                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 336                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 337
 338                                                 if(fabs(deviation.y) < 20)
 339                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 340                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 341                                                 {
 342                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 343                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 344                                                         {
 345                                                                 checkdistance = false;
 346                                                         }
 347                                                 }
 348                                         }
 349
 350                                         if(checkdistance)
 351                                         {
 352                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 353                                                 // increase stop distance in case the goal is on a slope or a lower platform
 354                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 355                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 356                                         }
 357                                         else
 358                                         {
 359                                                 this.aistatus |= AI_STATUS_RUNNING;
 360                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 361                                         }
 362                                 }
 363                         }
 364                         else
 365                         {
 366                                 this.bot_timelastseengoal = time;
 367                         }
 368         }
 369         else
 370         {
 371                 this.bot_timelastseengoal = 0;
 372         }
 373
 374 #if 0
 375         // Release jump button
 376         if(!cvar("sv_pogostick"))
 377         if((IS_ONGROUND(this)) == 0)
 378         {
 379                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 380                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 381
 382                 // Strafe
 383                 if(this.aistatus & AI_STATUS_RUNNING)
 384                 if(vlen(this.velocity)>maxspeed)
 385                 {
 386                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 387                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 388                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 389
 390                         if(fabs(deviation.y)>10)
 391                                 CS(this).movement_x = 0;
 392
 393                         if(deviation.y>10)
 394                                 CS(this).movement_y = maxspeed * -1;
 395                         else if(deviation.y<10)
 396                                 CS(this).movement_y = maxspeed;
 397
 398                 }
 399         }
 400 #endif
 401 }
 402
 403 // return true when bot isn't getting closer to the current goal
 404 bool havocbot_checkgoaldistance(entity this, vector gco)
 405 {
 406         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 407         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 408         float distance_time = this.goalcurrent_distance_time;
 409         if(distance_time < 0)
 410                 distance_time = -distance_time;
 411         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 412         {
 413                 if(!distance_time)
 414                         this.goalcurrent_distance_time = time;
 415                 else if (time - distance_time > 0.5)
 416                         return true;
 417         }
 418         else
 419         {
 420                 // reduce it a little bit so it works even with very small approaches to the goal
 421                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 422                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 423                 this.goalcurrent_distance_time = 0;
 424         }
 425         return false;
 426 }
 427
 428 entity havocbot_select_an_item_of_group(entity this, int gr)
 429 {
 430         entity selected = NULL;
 431         float selected_dist2 = 0;
 432         // select farthest item of this group from bot's position
 433         IL_EACH(g_items, it.item_group == gr && it.solid,
 434         {
 435                 float dist2 = vlen2(this.origin - it.origin);
 436                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 437                 {
 438                         selected = it;
 439                         selected_dist2 = vlen2(this.origin - selected.origin);
 440                 }
 441         });
 442
 443         if (!selected)
 444                 return NULL;
 445
 446         set_tracewalk_dest(selected, this.origin, false);
 447         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 448                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 449         {
 450                 return NULL;
 451         }
 452
 453         return selected;
 454 }
 455
 456 void havocbot_movetogoal(entity this)
 457 {
 458         vector diff;
 459         vector dir;
 460         vector flatdir;
 461         vector evadeobstacle;
 462         vector evadelava;
 463         float dodge_enemy_factor = 1;
 464         float maxspeed;
 465         //float dist;
 466         vector dodge;
 467         //if (this.goalentity)
 468         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 469         CS(this).movement = '0 0 0';
 470         maxspeed = autocvar_sv_maxspeed;
 471
 472         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 473         // Jetpack navigation
 474         if(this.navigation_jetpack_goal)
 475         if(this.goalcurrent==this.navigation_jetpack_goal)
 476         if(GetResourceAmount(this, RESOURCE_FUEL))
 477         {
 478                 if(autocvar_bot_debug_goalstack)
 479                 {
 480                         debuggoalstack(this);
 481                         te_wizspike(this.navigation_jetpack_point);
 482                 }
 483
 484                 // Take off
 485                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 486                 {
 487                         // Brake almost completely so it can get a good direction
 488                         if(vdist(this.velocity, >, 10))
 489                                 return;
 490                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 491                 }
 492
 493                 makevectors(this.v_angle.y * '0 1 0');
 494                 dir = normalize(this.navigation_jetpack_point - this.origin);
 495
 496                 // Landing
 497                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 498                 {
 499                         // Calculate brake distance in xy
 500                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 501                         float v = vlen(vec2(this.velocity));
 502                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 503                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 504                         if(d < db || d < 500)
 505                         {
 506                                 // Brake
 507                                 if(v > maxspeed * 0.3)
 508                                 {
 509                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 510                                         return;
 511                                 }
 512                                 // Switch to normal mode
 513                                 this.navigation_jetpack_goal = NULL;
 514                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 515                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 516                                 return;
 517                         }
 518                 }
 519                 else if(checkpvs(this.origin,this.goalcurrent))
 520                 {
 521                         // If I can see the goal switch to landing code
 522                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 523                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 524                         return;
 525                 }
 526
 527                 // Flying
 528                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 529                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 530                 {
 531                         CS(this).movement_x = dir * v_forward * maxspeed;
 532                         CS(this).movement_y = dir * v_right * maxspeed;
 533                 }
 534                 return;
 535         }
 536
 537         // Handling of jump pads
 538         if(this.jumppadcount)
 539         {
 540                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 541                 {
 542                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 543                         if(navigation_poptouchedgoals(this))
 544                                 return;
 545                 }
 546                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 547                 {
 548                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 549                         // but with some randomness so it can try out different paths
 550                         if(!this.goalcurrent)
 551                         {
 552                                 entity newgoal = NULL;
 553                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 554                                 {
 555                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 556                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 557                                                 continue;
 558
 559                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 560
 561                                         if(trace_fraction < 1)
 562                                                 continue;
 563
 564                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 565                                                 newgoal = it;
 566                                 });
 567
 568                                 if(newgoal)
 569                                 {
 570                                         this.ignoregoal = this.goalcurrent;
 571                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 572                                         navigation_clearroute(this);
 573                                         navigation_routetogoal(this, newgoal, this.origin);
 574                                         if(autocvar_bot_debug_goalstack)
 575                                                 debuggoalstack(this);
 576                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 577                                 }
 578                         }
 579                         else
 580                         {
 581                                 if (this.goalcurrent.bot_pickup)
 582                                 {
 583                                         entity jumppad_wp = this.goalcurrent_prev;
 584                                         navigation_poptouchedgoals(this);
 585                                         if(!this.goalcurrent && jumppad_wp.wp00)
 586                                         {
 587                                                 // head to the jumppad destination once bot reaches the goal item
 588                                                 navigation_pushroute(this, jumppad_wp.wp00);
 589                                         }
 590                                 }
 591                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 592                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 593                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 594                                 else if(havocbot_checkgoaldistance(this, gco))
 595                                 {
 596                                         navigation_clearroute(this);
 597                                         navigation_goalrating_timeout_force(this);
 598                                 }
 599                                 else
 600                                         return;
 601                         }
 602                 }
 603                 else
 604                 {
 605                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 606                         {
 607                                 vector velxy = this.velocity; velxy_z = 0;
 608                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 609                                 {
 610                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 611                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 612                                 }
 613                                 return;
 614                         }
 615
 616                         // Don't chase players while using a jump pad
 617                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 618                                 return;
 619                 }
 620         }
 621         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 622                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 623
 624         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 625         if (skill > 6 && !(IS_ONGROUND(this)))
 626         {
 627                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 628                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 629                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 630
 631                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 632                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 633                 if(this.items & IT_JETPACK)
 634                 {
 635                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 636                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 637                         {
 638                                 if(this.velocity.z<0)
 639                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 640                         }
 641                         else
 642                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 643
 644                         // If there is no goal try to move forward
 645
 646                         if(this.goalcurrent==NULL)
 647                                 dir = v_forward;
 648                         else
 649                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 650
 651                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 652                         float xyspeed = xyvelocity * dir;
 653
 654                         if(xyspeed < (maxspeed / 2))
 655                         {
 656                                 makevectors(this.v_angle.y * '0 1 0');
 657                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 658                                 if(trace_fraction==1)
 659                                 {
 660                                         CS(this).movement_x = dir * v_forward * maxspeed;
 661                                         CS(this).movement_y = dir * v_right * maxspeed;
 662                                         if (skill < 10)
 663                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 664                                 }
 665                         }
 666
 667                         this.havocbot_blockhead = true;
 668
 669                         return;
 670                 }
 671                 else if(GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR) > ROCKETJUMP_DAMAGE())
 672                 {
 673                         if(this.velocity.z < 0)
 674                         {
 675                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 676                                 {
 677                                         .entity weaponentity = weaponentities[slot];
 678
 679                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 680                                                 continue;
 681
 682                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 683                                         {
 684                                                 CS(this).movement_x = maxspeed;
 685
 686                                                 if(this.rocketjumptime)
 687                                                 {
 688                                                         if(time > this.rocketjumptime)
 689                                                         {
 690                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 691                                                                 this.rocketjumptime = 0;
 692                                                         }
 693                                                         return;
 694                                                 }
 695
 696                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 697                                                 this.v_angle_x = 90;
 698                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 699                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 700                                                 return;
 701                                         }
 702                                 }
 703                         }
 704                 }
 705                 else
 706                 {
 707                         // If there is no goal try to move forward
 708                         if(this.goalcurrent==NULL)
 709                                 CS(this).movement_x = maxspeed;
 710                 }
 711         }
 712
 713         // If we are under water with no goals, swim up
 714         if(this.waterlevel && !this.goalcurrent)
 715         {
 716                 dir = '0 0 0';
 717                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 718                         dir.z = 1;
 719                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 720                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 721                 else
 722                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 723                 makevectors(this.v_angle.y * '0 1 0');
 724                 CS(this).movement_x = dir * v_forward * maxspeed;
 725                 CS(this).movement_y = dir * v_right * maxspeed;
 726                 CS(this).movement_z = dir * v_up * maxspeed;
 727         }
 728
 729         // if there is nowhere to go, exit
 730         if (this.goalcurrent == NULL)
 731                 return;
 732
 733
 734         bool locked_goal = false;
 735         if((this.goalentity && wasfreed(this.goalentity))
 736                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 737         {
 738                 navigation_clearroute(this);
 739                 navigation_goalrating_timeout_force(this);
 740                 return;
 741         }
 742         else if(this.goalentity.tag_entity)
 743         {
 744                 navigation_goalrating_timeout_expire(this, 2);
 745         }
 746         else if(this.goalentity.bot_pickup)
 747         {
 748                 if(this.goalentity.bot_pickup_respawning)
 749                 {
 750                         if(this.goalentity.solid) // item respawned
 751                                 this.goalentity.bot_pickup_respawning = false;
 752                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 753                         {
 754                                 if(checkpvs(this.origin, this.goalentity))
 755                                 {
 756                                         this.goalentity.bot_pickup_respawning = false;
 757                                         navigation_goalrating_timeout_expire(this, random());
 758                                 }
 759                                 locked_goal = true; // wait for item to respawn
 760                         }
 761                         else if(this.goalentity == this.goalcurrent)
 762                                 locked_goal = true; // wait for item to respawn
 763                 }
 764                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 765                 {
 766                         if(checkpvs(this.origin, this.goalentity))
 767                         {
 768                                 navigation_goalrating_timeout_expire(this, random());
 769                         }
 770                 }
 771         }
 772         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 773                 locked_goal = true;
 774
 775         if (navigation_shortenpath(this))
 776         {
 777                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 778                         && navigation_goalrating_timeout_can_be_anticipated(this))
 779                         navigation_goalrating_timeout_force(this);
 780         }
 781
 782         bool goalcurrent_can_be_removed = false;
 783         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 784         {
 785                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 786                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 787                 {
 788                         goalcurrent_can_be_removed = true;
 789                         // don't remove if not visible
 790                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 791                         {
 792                                 navigation_goalrating_timeout_force(this);
 793                                 return;
 794                         }
 795                 }
 796                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 797                 {
 798                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 799                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 800                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 801                         {
 802                                 navigation_goalrating_timeout_force(this);
 803                                 return;
 804                         }
 805                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 806                 }
 807         }
 808
 809         if(!locked_goal)
 810         {
 811                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 812                 // in this case path finding can start directly from a waypoint instead of
 813                 // looking for all the reachable waypoints up to a certain distance
 814                 if (navigation_poptouchedgoals(this))
 815                 {
 816                         if (this.goalcurrent)
 817                         {
 818                                 if (goalcurrent_can_be_removed)
 819                                 {
 820                                         // remove even if not visible
 821                                         navigation_goalrating_timeout_force(this);
 822                                         return;
 823                                 }
 824                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 825                                         navigation_goalrating_timeout_force(this);
 826                         }
 827                         else
 828                         {
 829                                 entity old_goal = this.goalcurrent_prev;
 830                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 831                                 {
 832                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 833                                         // item of the group by telling the bot to head directly to the farthest item.
 834                                         // Next time we let the bot select a goal as usual which can be another item
 835                                         // of this group (the closest one) and so on
 836                                         this.item_group = old_goal.item_group;
 837                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 838                                         if (new_goal)
 839                                                 navigation_pushroute(this, new_goal);
 840                                 }
 841                         }
 842                 }
 843         }
 844
 845         // if ran out of goals try to use an alternative goal or get a new strategy asap
 846         if(this.goalcurrent == NULL)
 847         {
 848                 navigation_goalrating_timeout_force(this);
 849                 return;
 850         }
 851
 852
 853         if(autocvar_bot_debug_goalstack)
 854                 debuggoalstack(this);
 855
 856         bool bunnyhop_forbidden = false;
 857         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 858         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 859         {
 860                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 861                 destorg = this.goalcurrent.origin;
 862         }
 863         else if (this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 864         {
 865                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 866                 bunnyhop_forbidden = true;
 867                 destorg = this.goalcurrent.origin;
 868                 if(destorg.z > this.origin.z)
 869                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 870         }
 871
 872         diff = destorg - this.origin;
 873
 874         // 1. stop if too close to target player (even if frozen)
 875         // 2. stop if the locked goal has been reached
 876         if ((IS_PLAYER(this.goalcurrent) && vdist(diff, <, 80))
 877                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 878         {
 879                 destorg = this.origin;
 880                 diff = '0 0 0';
 881         }
 882
 883         dir = normalize(diff);
 884         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 885
 886         //if (this.bot_dodgevector_time < time)
 887         {
 888                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 889                 //this.bot_dodgevector_jumpbutton = 1;
 890                 evadeobstacle = '0 0 0';
 891                 evadelava = '0 0 0';
 892
 893                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 894                 makevectors(this.v_angle.y * '0 1 0');
 895                 if (this.waterlevel > WATERLEVEL_WETFEET)
 896                 {
 897                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 898                         {
 899                                 if(!this.goalcurrent)
 900                                         this.aistatus |= AI_STATUS_OUT_WATER;
 901                                 else if(destorg.z > this.origin.z)
 902                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 903                         }
 904                         else
 905                         {
 906                                 dir = flatdir;
 907                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 908                                         (this.aistatus & AI_STATUS_OUT_WATER))
 909                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 910                                 else
 911                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 912                         }
 913                 }
 914                 else
 915                 {
 916                         float s;
 917                         vector offset;
 918                         if(this.aistatus & AI_STATUS_OUT_WATER)
 919                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 920
 921                         // jump if going toward an obstacle that doesn't look like stairs we
 922                         // can walk up directly
 923                         vector deviation = '0 0 0';
 924                         float current_speed = vlen(vec2(this.velocity));
 925                         if (current_speed < maxspeed * 0.2)
 926                                 current_speed = maxspeed * 0.2;
 927                         else
 928                         {
 929                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 930                                 while (deviation.y < -180) deviation.y += 360;
 931                                 while (deviation.y > 180) deviation.y -= 360;
 932                         }
 933                         float turning = false;
 934                         vector flat_diff = vec2(diff);
 935                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 936                         vector actual_destorg = this.origin + offset;
 937                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 938                         {
 939                                 if (vlen2(flat_diff) < vlen2(offset))
 940                                 {
 941                                         actual_destorg.x = destorg.x;
 942                                         actual_destorg.y = destorg.y;
 943                                 }
 944                         }
 945                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 946                         {
 947                                 actual_destorg.x = destorg.x;
 948                                 actual_destorg.y = destorg.y;
 949                         }
 950                         else if (vlen2(flat_diff) < vlen2(offset))
 951                         {
 952                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 953                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 954                                 float dist = vlen(vec2(this.origin + offset - destorg));
 955                                 // if current and next goal are close to each other make sure
 956                                 // actual_destorg isn't set beyond next_goal_org
 957                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 958                                         actual_destorg = next_goal_org;
 959                                 else
 960                                         actual_destorg = vec2(destorg) + dist * next_dir;
 961                                 actual_destorg.z = this.origin.z;
 962                                 turning = true;
 963                         }
 964
 965                         LABEL(jump_check);
 966                         dir = flatdir = normalize(actual_destorg - this.origin);
 967
 968                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
 969                         {
 970                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
 971                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
 972                                 {
 973                                         s = trace_fraction;
 974                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
 975                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
 976                                         {
 977                                                 // found an obstacle
 978                                                 if (turning && fabs(deviation.y) > 5)
 979                                                 {
 980                                                         // check if the obstacle is still there without turning
 981                                                         actual_destorg = destorg;
 982                                                         turning = false;
 983                                                         this.bot_tracewalk_time = time + 0.25;
 984                                                         goto jump_check;
 985                                                 }
 986                                                 s = trace_fraction;
 987                                                 // don't artificially reduce max jump height in real-time
 988                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
 989                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
 990                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
 991                                                 if (trace_fraction > s)
 992                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 993                                                 else
 994                                                 {
 995                                                         jump_height = stepheightvec + jumpheight_vec / 2;
 996                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
 997                                                         if (trace_fraction > s)
 998                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 999                                                 }
1000                                         }
1001                                 }
1002                         }
1003
1004                         // if bot for some reason doesn't get close to the current goal find another one
1005                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1006                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1007                         if(havocbot_checkgoaldistance(this, destorg))
1008                         {
1009                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1010                                 {
1011                                         navigation_clearroute(this);
1012                                         navigation_goalrating_timeout_force(this);
1013                                         return;
1014                                 }
1015
1016                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1017                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1018                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1019                                 {
1020                                         navigation_clearroute(this);
1021                                         navigation_goalrating_timeout_force(this);
1022                                         return;
1023                                 }
1024
1025                                 // give bot only another chance to prevent bot getting stuck
1026                                 // in case it thinks it can walk but actually can't
1027                                 this.goalcurrent_distance_z = FLOAT_MAX;
1028                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1029                                 this.goalcurrent_distance_time = -time; // mark second try
1030                         }
1031
1032                         // Check for water/slime/lava and dangerous edges
1033                         // (only when the bot is on the ground or jumping intentionally)
1034
1035                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1036                         vector dst_ahead = this.origin + this.view_ofs + offset;
1037                         vector dst_down = dst_ahead - '0 0 3000';
1038                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1039
1040                         bool unreachable = false;
1041                         s = CONTENT_SOLID;
1042                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1043                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1044                         {
1045                                 // Look downwards
1046                                 traceline(dst_ahead , dst_down, true, NULL);
1047                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1048                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1049                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1050                                 {
1051                                         s = pointcontents(trace_endpos + '0 0 1');
1052                                         if (s != CONTENT_SOLID)
1053                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1054                                                 evadelava = normalize(this.velocity) * -1;
1055                                         else if (s == CONTENT_SKY)
1056                                                 evadeobstacle = normalize(this.velocity) * -1;
1057                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1058                                         {
1059                                                 // the traceline check isn't enough but is good as optimization,
1060                                                 // when not true (most of the time) this tracebox call is avoided
1061                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1062                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1063                                                 {
1064                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1065                                                         {
1066                                                                 // the goal is probably on an upper platform, assume bot can't get there
1067                                                                 unreachable = true;
1068                                                         }
1069                                                         else
1070                                                                 evadelava = normalize(this.velocity) * -1;
1071                                                 }
1072                                         }
1073                                 }
1074                         }
1075
1076                         dir = flatdir;
1077                         evadeobstacle.z = 0;
1078                         evadelava.z = 0;
1079                         makevectors(this.v_angle.y * '0 1 0');
1080
1081                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1082                         {
1083                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1084                                 if(IS_PLAYER(this.goalcurrent))
1085                                         unreachable = true;
1086                         }
1087
1088                         // slow down if bot is in the air and goal is under it
1089                         if (!this.goalcurrent.wphardwired
1090                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1091                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1092                         {
1093                                 // tracebox wouldn't work when bot is still on the ledge
1094                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1095                                 if (this.origin.z - trace_endpos.z > 120)
1096                                         evadeobstacle = normalize(this.velocity) * -1;
1097                         }
1098
1099                         if(unreachable)
1100                         {
1101                                 navigation_clearroute(this);
1102                                 navigation_goalrating_timeout_force(this);
1103                                 this.ignoregoal = this.goalcurrent;
1104                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1105                         }
1106                 }
1107
1108                 dodge = havocbot_dodge(this);
1109                 if (dodge)
1110                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1111                 dodge += evadeobstacle + evadelava;
1112                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1113                 if (this.enemy)
1114                 {
1115                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1116                         if (IS_PLAYER(trace_ent))
1117                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1118                 }
1119         //      this.bot_dodgevector = dir;
1120         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1121         }
1122
1123         float ladder_zdir = 0;
1124         if(time < this.ladder_time)
1125         {
1126                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1127                 {
1128                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1129                                 ladder_zdir = 1;
1130                 }
1131                 else
1132                 {
1133                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1134                                 ladder_zdir = -1;
1135                 }
1136                 if (ladder_zdir)
1137                 {
1138                         dir.z = ladder_zdir * 1.3;
1139                         dir = normalize(dir);
1140                 }
1141         }
1142
1143         if (this.goalcurrent.wpisbox
1144                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1145         {
1146                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1147                 // head to teleport origin
1148                 dir = (this.goalcurrent.origin - this.origin);
1149                 dir.z = 0;
1150                 dir = normalize(dir);
1151         }
1152
1153         if (!this.bot_aimdir_executed)
1154                 bot_aimdir(this, dir, -1);
1155
1156         if (!ladder_zdir)
1157         {
1158                 dir *= dodge_enemy_factor;
1159                 dir = normalize(dir + dodge);
1160         }
1161
1162         //dir = this.bot_dodgevector;
1163         //if (this.bot_dodgevector_jumpbutton)
1164         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1165         CS(this).movement_x = dir * v_forward * maxspeed;
1166         CS(this).movement_y = dir * v_right * maxspeed;
1167         CS(this).movement_z = dir * v_up * maxspeed;
1168
1169         // Emulate keyboard interface
1170         if (skill < 10)
1171                 havocbot_keyboard_movement(this, destorg);
1172
1173         // Bunnyhop!
1174         //if(this.aistatus & AI_STATUS_ROAMING)
1175         if(!bunnyhop_forbidden && this.goalcurrent)
1176         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1177                 havocbot_bunnyhop(this, dir);
1178
1179         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1180         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1181         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1182 }
1183
1184 entity havocbot_gettarget(entity this, bool secondary)
1185 {
1186         entity best = NULL;
1187         vector eye = CENTER_OR_VIEWOFS(this);
1188         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1189         {
1190                 vector v = CENTER_OR_VIEWOFS(it);
1191                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1192                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1193                 if(bot_shouldattack(this, it))
1194                 {
1195                         traceline(eye, v, true, this);
1196                         if (trace_ent == it || trace_fraction >= 1)
1197                                 best = it;
1198                 }
1199         });
1200
1201         return best;
1202 }
1203
1204 void havocbot_chooseenemy(entity this)
1205 {
1206         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1207         {
1208                 this.enemy = NULL;
1209                 return;
1210         }
1211         if (this.enemy)
1212         {
1213                 if (!bot_shouldattack(this, this.enemy))
1214                 {
1215                         // enemy died or something, find a new target
1216                         this.enemy = NULL;
1217                         this.havocbot_chooseenemy_finished = time;
1218                 }
1219                 else if (this.havocbot_stickenemy)
1220                 {
1221                         // tracking last chosen enemy
1222                         // if enemy is visible
1223                         // and not really really far away
1224                         // and we're not severely injured
1225                         // then keep tracking for a half second into the future
1226                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1227                         if (trace_ent == this.enemy || trace_fraction == 1)
1228                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1229                         if (GetResourceAmount(this, RESOURCE_HEALTH) > 30)
1230                         {
1231                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1232                                 this.havocbot_chooseenemy_finished = time + 0.5;
1233                                 return;
1234                         }
1235                         // enemy isn't visible, or is far away, or we're injured severely
1236                         // so stop preferring this enemy
1237                         // (it will still take a half second until a new one is chosen)
1238                         this.havocbot_stickenemy = 0;
1239                 }
1240         }
1241         if (time < this.havocbot_chooseenemy_finished)
1242                 return;
1243         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1244         vector eye = this.origin + this.view_ofs;
1245         entity best = NULL;
1246         float bestrating = 100000000;
1247
1248         // Backup hit flags
1249         int hf = this.dphitcontentsmask;
1250
1251         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1252
1253         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1254
1255         bool scan_transparent = false;
1256         bool scan_secondary_targets = false;
1257         bool have_secondary_targets = false;
1258         while(true)
1259         {
1260                 scan_secondary_targets = false;
1261 LABEL(scan_targets)
1262                 IL_EACH(g_bot_targets, it.bot_attack,
1263                 {
1264                         if(!scan_secondary_targets)
1265                         {
1266                                 if(it.classname == "misc_breakablemodel")
1267                                 {
1268                                         have_secondary_targets = true;
1269                                         continue;
1270                                 }
1271                         }
1272                         else if(it.classname != "misc_breakablemodel")
1273                                 continue;
1274
1275                         vector v = (it.absmin + it.absmax) * 0.5;
1276                         float rating = vlen2(v - eye);
1277                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1278                         if (bestrating > rating)
1279                         if (bot_shouldattack(this, it))
1280                         {
1281                                 traceline(eye, v, true, this);
1282                                 if (trace_ent == it || trace_fraction >= 1)
1283                                 {
1284                                         best = it;
1285                                         bestrating = rating;
1286                                 }
1287                         }
1288                 });
1289
1290                 if(!best && have_secondary_targets && !scan_secondary_targets)
1291                 {
1292                         scan_secondary_targets = true;
1293                         // restart the loop
1294                         bestrating = 100000000;
1295                         goto scan_targets;
1296                 }
1297
1298                 // I want to do a second scan if no enemy was found or I don't have weapons
1299                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1300                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1301                         break;
1302                 if(scan_transparent)
1303                         break;
1304
1305                 // Set flags to see through transparent objects
1306                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1307
1308                 scan_transparent = true;
1309         }
1310
1311         // Restore hit flags
1312         this.dphitcontentsmask = hf;
1313
1314         this.enemy = best;
1315         this.havocbot_stickenemy = true;
1316         if(best && best.classname == "misc_breakablemodel")
1317                 this.havocbot_stickenemy = false;
1318 }
1319
1320 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1321 {
1322         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1323         // so skip this for them, or they'll never get to reload their weapons at all.
1324         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1325         if(skill < 5)
1326                 return false;
1327
1328         // if this weapon is scheduled for reloading, don't switch to it during combat
1329         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1330         {
1331                 FOREACH(Weapons, it != WEP_Null, {
1332                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1333                                 return true; // other weapon available
1334                 });
1335         }
1336
1337         return false;
1338 }
1339
1340 void havocbot_chooseweapon(entity this, .entity weaponentity)
1341 {
1342         int i;
1343
1344         // ;)
1345         if(g_weaponarena_weapons == WEPSET(TUBA))
1346         {
1347                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1348                 return;
1349         }
1350
1351         // TODO: clean this up by moving it to weapon code
1352         if(this.enemy==NULL)
1353         {
1354                 // If no weapon was chosen get the first available weapon
1355                 if(this.(weaponentity).m_weapon==WEP_Null)
1356                 FOREACH(Weapons, it != WEP_Null, {
1357                         if(client_hasweapon(this, it, weaponentity, true, false))
1358                         {
1359                                 this.(weaponentity).m_switchweapon = it;
1360                                 return;
1361                         }
1362                 });
1363                 return;
1364         }
1365
1366         // Do not change weapon during the next second after a combo
1367         float f = time - this.lastcombotime;
1368         if(f < 1)
1369                 return;
1370
1371         float w;
1372         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1373
1374         // Should it do a weapon combo?
1375         float af, ct, combo_time, combo;
1376
1377         af = ATTACK_FINISHED(this, 0);
1378         ct = autocvar_bot_ai_weapon_combo_threshold;
1379
1380         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1381         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1382         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1383
1384         combo = false;
1385
1386         if(autocvar_bot_ai_weapon_combo)
1387         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1388         if(af > combo_time)
1389         {
1390                 combo = true;
1391                 this.lastcombotime = time;
1392         }
1393
1394         distance *= (2 ** this.bot_rangepreference);
1395
1396         // Custom weapon list based on distance to the enemy
1397         if(bot_custom_weapon){
1398
1399                 // Choose weapons for far distance
1400                 if ( distance > bot_distance_far ) {
1401                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1402                                 w = bot_weapons_far[i];
1403                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1404                                 {
1405                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1406                                                 continue;
1407                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1408                                         return;
1409                                 }
1410                         }
1411                 }
1412
1413                 // Choose weapons for mid distance
1414                 if ( distance > bot_distance_close) {
1415                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1416                                 w = bot_weapons_mid[i];
1417                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1418                                 {
1419                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1420                                                 continue;
1421                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1422                                         return;
1423                                 }
1424                         }
1425                 }
1426
1427                 // Choose weapons for close distance
1428                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1429                         w = bot_weapons_close[i];
1430                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1431                         {
1432                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1433                                         continue;
1434                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1435                                 return;
1436                         }
1437                 }
1438         }
1439 }
1440
1441 void havocbot_aim(entity this)
1442 {
1443         if (time < this.nextaim)
1444                 return;
1445         this.nextaim = time + 0.1;
1446         vector myvel = this.velocity;
1447         if (!this.waterlevel)
1448                 myvel.z = 0;
1449         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1450         else if (this.enemy)
1451         {
1452                 vector enemyvel = this.enemy.velocity;
1453                 if (!this.enemy.waterlevel)
1454                         enemyvel.z = 0;
1455                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1456         }
1457         else
1458                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1459 }
1460
1461 bool havocbot_moveto_refresh_route(entity this)
1462 {
1463         // Refresh path to goal if necessary
1464         entity wp;
1465         wp = this.havocbot_personal_waypoint;
1466         navigation_goalrating_start(this);
1467         navigation_routerating(this, wp, 10000, 10000);
1468         navigation_goalrating_end(this);
1469         return (this.goalentity != NULL);
1470 }
1471
1472 float havocbot_moveto(entity this, vector pos)
1473 {
1474         entity wp;
1475
1476         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1477         {
1478                 // Step 4: Move to waypoint
1479                 if(this.havocbot_personal_waypoint==NULL)
1480                 {
1481                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1482                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1483                         return CMD_STATUS_ERROR;
1484                 }
1485
1486                 if (!bot_strategytoken_taken)
1487                 if(this.havocbot_personal_waypoint_searchtime<time)
1488                 {
1489                         bot_strategytoken_taken = true;
1490                         if(havocbot_moveto_refresh_route(this))
1491                         {
1492                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1493                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1494                                 this.havocbot_personal_waypoint_failcounter = 0;
1495                         }
1496                         else
1497                         {
1498                                 this.havocbot_personal_waypoint_failcounter += 1;
1499                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1500                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1501                                 {
1502                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1503                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1504                                         delete(this.havocbot_personal_waypoint);
1505                                         return CMD_STATUS_ERROR;
1506                                 }
1507                                 else
1508                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1509                         }
1510                 }
1511
1512                 if(autocvar_bot_debug_goalstack)
1513                         debuggoalstack(this);
1514
1515
1516                 // Go!
1517                 havocbot_movetogoal(this);
1518
1519                 if (!this.bot_aimdir_executed && this.goalcurrent)
1520                 {
1521                         // Heading
1522                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1523                         dir -= this.origin + this.view_ofs;
1524                         dir.z = 0;
1525                         bot_aimdir(this, dir, -1);
1526                 }
1527
1528                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1529                 {
1530                         // Step 5: Waypoint reached
1531                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1532                         delete(this.havocbot_personal_waypoint);
1533                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1534                         return CMD_STATUS_FINISHED;
1535                 }
1536
1537                 return CMD_STATUS_EXECUTING;
1538         }
1539
1540         // Step 2: Linking waypoint
1541         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1542         {
1543                 // Wait until it is linked
1544                 if(!this.havocbot_personal_waypoint.wplinked)
1545                 {
1546                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1547                         return CMD_STATUS_EXECUTING;
1548                 }
1549
1550                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1551                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1552                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1553
1554                 // Step 3: Route to waypoint
1555                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1556
1557                 return CMD_STATUS_EXECUTING;
1558         }
1559
1560         // Step 1: Spawning waypoint
1561         wp = waypoint_spawnpersonal(this, pos);
1562         if(wp==NULL)
1563         {
1564                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1565                 return CMD_STATUS_ERROR;
1566         }
1567
1568         this.havocbot_personal_waypoint = wp;
1569         this.havocbot_personal_waypoint_failcounter = 0;
1570         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1571
1572         // if pos is inside a teleport, then let's mark it as teleport waypoint
1573         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1574         {
1575                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1576                 this.lastteleporttime = 0;
1577         });
1578
1579 /*
1580         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1581                 print("routing to a teleporter\n");
1582         else
1583                 print("routing to a non-teleporter\n");
1584 */
1585
1586         return CMD_STATUS_EXECUTING;
1587 }
1588
1589 float havocbot_resetgoal(entity this)
1590 {
1591         navigation_clearroute(this);
1592         return CMD_STATUS_FINISHED;
1593 }
1594
1595 void havocbot_setupbot(entity this)
1596 {
1597         this.bot_ai = havocbot_ai;
1598         this.cmd_moveto = havocbot_moveto;
1599         this.cmd_resetgoal = havocbot_resetgoal;
1600
1601         // NOTE: bot is not player yet
1602         havocbot_chooserole(this);
1603 }
1604
1605 vector havocbot_dodge(entity this)
1606 {
1607         // LordHavoc: disabled because this is too expensive
1608         return '0 0 0';
1609 #if 0
1610         entity head;
1611         vector dodge, v, n;
1612         float danger, bestdanger, vl, d;
1613         dodge = '0 0 0';
1614         bestdanger = -20;
1615         // check for dangerous objects near bot or approaching bot
1616         head = findchainfloat(bot_dodge, true);
1617         while(head)
1618         {
1619                 if (head.owner != this)
1620                 {
1621                         vl = vlen(head.velocity);
1622                         if (vl > autocvar_sv_maxspeed * 0.3)
1623                         {
1624                                 n = normalize(head.velocity);
1625                                 v = this.origin - head.origin;
1626                                 d = v * n;
1627                                 if (d > (0 - head.bot_dodgerating))
1628                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1629                                 {
1630                                         // calculate direction and distance from the flight path, by removing the forward axis
1631                                         v = v - (n * (v * n));
1632                                         danger = head.bot_dodgerating - vlen(v);
1633                                         if (bestdanger < danger)
1634                                         {
1635                                                 bestdanger = danger;
1636                                                 // dodge to the side of the object
1637                                                 dodge = normalize(v);
1638                                         }
1639                                 }
1640                         }
1641                         else
1642                         {
1643                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1644                                 if (bestdanger < danger)
1645                                 {
1646                                         bestdanger = danger;
1647                                         dodge = normalize(this.origin - head.origin);
1648                                 }
1649                         }
1650                 }
1651                 head = head.chain;
1652         }
1653         return dodge;
1654 #endif
1655 }