qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27
  28         entity e2 = navigation_findnearestwaypoint(pl, false);
  29         if(!e2)
  30         {
  31                 LOG_INFOF("Can't find any waypoint nearby\n");
  32                 return;
  33         }
  34
  35         navigation_markroutes(pl, e2);
  36
  37         int j = 0;
  38         int m = 0;
  39         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  40         {
  41                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  42                 it.colormod_z = 8;
  43                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  44                 j++;
  45                 m++;
  46         });
  47         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  48         navigation_markroutes_inverted(e2);
  49
  50         j = 0;
  51         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  52         {
  53                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  54                 it.colormod_x = 8;
  55                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  56                         m++;
  57                 it.effects |= EF_NODEPTHTEST | EF_RED;
  58                 j++;
  59         });
  60         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  61         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  62
  63         j = 0;
  64         IL_EACH(g_spawnpoints, true,
  65         {
  66                 if (navigation_findnearestwaypoint(it, false))
  67                 {
  68                         if(it.spawnpointmodel)
  69                         {
  70                                 delete(it.spawnpointmodel);
  71                                 it.spawnpointmodel = NULL;
  72                         }
  73                 }
  74                 else
  75                 {
  76                         if(!it.spawnpointmodel)
  77                         {
  78                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  79                                 entity e = new(spawnpointmodel);
  80                                 vector org = trace_endpos + eZ;
  81                                 setorigin(e, org);
  82                                 e.solid = SOLID_TRIGGER;
  83                                 it.spawnpointmodel = e;
  84                         }
  85                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  86                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  87                         _setmodel(it.spawnpointmodel, pl.model);
  88                         it.spawnpointmodel.frame = pl.frame;
  89                         it.spawnpointmodel.skin = pl.skin;
  90                         it.spawnpointmodel.colormap = pl.colormap;
  91                         it.spawnpointmodel.colormod = pl.colormod;
  92                         it.spawnpointmodel.glowmod = pl.glowmod;
  93                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  94                         j++;
  95                 }
  96         });
  97         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  98
  99         j = 0;
 100         IL_EACH(g_items, true,
 101         {
 102                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 103                 it.colormod = '0.5 0.5 0.5';
 104         });
 105         IL_EACH(g_items, true,
 106         {
 107                 if (navigation_findnearestwaypoint(it, false))
 108                         continue;
 109                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 110                 it.effects |= EF_NODEPTHTEST | EF_RED;
 111                 it.colormod_x = 8;
 112                 j++;
 113         });
 114         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 115
 116         j = 0;
 117         IL_EACH(g_items, true,
 118         {
 119                 if (navigation_findnearestwaypoint(it, true))
 120                         continue;
 121                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 122                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 123                 it.colormod_z = 8;
 124                 j++;
 125         });
 126         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 127 }
 128
 129 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 130 {
 131         vector new_org = org;
 132         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 133         {
 134                 vector map_center = havocbot_middlepoint;
 135                 if (autocvar_g_waypointeditor_symmetrical == -1)
 136                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 137
 138                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 139         }
 140         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 141         {
 142                 float m = havocbot_symmetryaxis_equation.x;
 143                 float q = havocbot_symmetryaxis_equation.y;
 144                 if (autocvar_g_waypointeditor_symmetrical == -2)
 145                 {
 146                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 147                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 148                 }
 149
 150                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 151                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 152         }
 153         new_org.z = org.z;
 154         return new_org;
 155 }
 156
 157 void waypoint_setupmodel(entity wp)
 158 {
 159         if (autocvar_g_waypointeditor)
 160         {
 161                 // TODO: add some sort of visible box in edit mode for box waypoints
 162                 vector m1 = wp.mins;
 163                 vector m2 = wp.maxs;
 164                 setmodel(wp, MDL_WAYPOINT);
 165                 setsize(wp, m1, m2);
 166                 wp.effects = EF_LOWPRECISION;
 167                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 168                         wp.colormod = '1 0 0';
 169                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 170                         wp.colormod = '1 1 0';
 171                 else if (wp.wphardwired)
 172                         wp.colormod = '0.5 0 1';
 173                 else
 174                         wp.colormod = '1 1 1';
 175         }
 176         else
 177                 wp.model = "";
 178 }
 179
 180 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 181 // them back to it as well
 182 // (suitable for spawnfunc_waypoint editor)
 183 entity waypoint_spawn(vector m1, vector m2, float f)
 184 {
 185         if(!(f & WAYPOINTFLAG_PERSONAL))
 186         {
 187                 vector em1 = m1, em2 = m2;
 188                 if (!(f & WAYPOINTFLAG_GENERATED) && m1 == m2)
 189                 {
 190                         em1 = m1 - '8 8 8';
 191                         em2 = m2 + '8 8 8';
 192                 }
 193                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 194                 {
 195                         return it;
 196                 });
 197         }
 198
 199         entity w = new(waypoint);
 200         IL_PUSH(g_waypoints, w);
 201         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 202         w.wpflags = f;
 203         w.solid = SOLID_TRIGGER;
 204         setorigin(w, (m1 + m2) * 0.5);
 205         setsize(w, m1 - w.origin, m2 - w.origin);
 206         if (w.size)
 207                 w.wpisbox = true;
 208
 209         if(!w.wpisbox)
 210         {
 211                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 212                 if(!move_out_of_solid(w))
 213                 {
 214                         if(!(f & WAYPOINTFLAG_GENERATED))
 215                         {
 216                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 217                                 delete(w);
 218                                 return NULL;
 219                         }
 220                         else
 221                         {
 222                                 if(autocvar_developer)
 223                                 {
 224                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 225                                         backtrace("Waypoint stuck");
 226                                 }
 227                         }
 228                 }
 229                 setsize(w, '0 0 0', '0 0 0');
 230         }
 231
 232         waypoint_clearlinks(w);
 233         //waypoint_schedulerelink(w);
 234
 235         waypoint_setupmodel(w);
 236
 237         return w;
 238 }
 239
 240 void waypoint_spawn_fromeditor(entity pl)
 241 {
 242         entity e;
 243         vector org = pl.origin;
 244         int ctf_flags = havocbot_symmetryaxis_equation.z;
 245         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 246                    || (autocvar_g_waypointeditor_symmetrical < 0));
 247         int order = ctf_flags;
 248         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 249         {
 250                 order = autocvar_g_waypointeditor_symmetrical_order;
 251                 ctf_flags = order;
 252         }
 253
 254         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 255         {
 256                 // snap waypoint to item's origin if close enough
 257                 IL_EACH(g_items, true,
 258                 {
 259                         vector item_org = (it.absmin + it.absmax) * 0.5;
 260                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 261                         if(vlen(item_org - org) < 30)
 262                         {
 263                                 org = item_org;
 264                                 break;
 265                         }
 266                 });
 267         }
 268
 269         LABEL(add_wp);
 270         e = waypoint_spawn(org, org, 0);
 271         if(!e)
 272         {
 273                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 274                 return;
 275         }
 276         waypoint_schedulerelink(e);
 277         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 278         if(sym)
 279         {
 280                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 281                 if (vdist(org - pl.origin, >, 32))
 282                 {
 283                         if(order > 2)
 284                                 order--;
 285                         else
 286                                 sym = false;
 287                         goto add_wp;
 288                 }
 289         }
 290 }
 291
 292 void waypoint_remove(entity wp)
 293 {
 294         // tell all waypoints linked to wp that they need to relink
 295         IL_EACH(g_waypoints, it != wp,
 296         {
 297                 if (waypoint_islinked(it, wp))
 298                         waypoint_removelink(it, wp);
 299         });
 300         delete(wp);
 301 }
 302
 303 void waypoint_remove_fromeditor(entity pl)
 304 {
 305         entity e = navigation_findnearestwaypoint(pl, false);
 306
 307         int ctf_flags = havocbot_symmetryaxis_equation.z;
 308         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 309                    || (autocvar_g_waypointeditor_symmetrical < 0));
 310         int order = ctf_flags;
 311         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 312         {
 313                 order = autocvar_g_waypointeditor_symmetrical_order;
 314                 ctf_flags = order;
 315         }
 316
 317         LABEL(remove_wp);
 318         if (!e) return;
 319         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 320
 321         if (e.wphardwired)
 322         {
 323                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 324                 return;
 325         }
 326
 327         entity wp_sym = NULL;
 328         if (sym)
 329         {
 330                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 331                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 332                         if(vdist(org - it.origin, <, 3))
 333                         {
 334                                 wp_sym = it;
 335                                 break;
 336                         }
 337                 });
 338         }
 339
 340         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 341         waypoint_remove(e);
 342
 343         if (sym && wp_sym)
 344         {
 345                 e = wp_sym;
 346                 if(order > 2)
 347                         order--;
 348                 else
 349                         sym = false;
 350                 goto remove_wp;
 351         }
 352 }
 353
 354 void waypoint_removelink(entity from, entity to)
 355 {
 356         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 357                 return;
 358
 359         bool found = false;
 360         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 361         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 362         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 363         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 364         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 365         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 366         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 367         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 368         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 369         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 370         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 371         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 372         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 373         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 374         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 375         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 376         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 377         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 378         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 379         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 380         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 381         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 382         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 383         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 384         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 385         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 386         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 387         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 388         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 389         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 390         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 391         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 392 }
 393
 394 bool waypoint_islinked(entity from, entity to)
 395 {
 396         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 397         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 398         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 399         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 400         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 401         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 402         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 403         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 404         return false;
 405 }
 406
 407 void waypoint_updatecost_foralllinks()
 408 {
 409         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 410         {
 411                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 412                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 413                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 414                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 415                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 416                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 417                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 418                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 419                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 420                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 421                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 422                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 423                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 424                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 425                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 426                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 427                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 428                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 429                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 430                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 431                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 432                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 433                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 434                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 435                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 436                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 437                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 438                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 439                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 440                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 441                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 442                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 443         });
 444 }
 445
 446 float waypoint_getlinearcost(float dist)
 447 {
 448         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 449                 return dist / (autocvar_sv_maxspeed * 1.25);
 450         return dist / autocvar_sv_maxspeed;
 451 }
 452 float waypoint_getlinearcost_underwater(float dist)
 453 {
 454         // NOTE: this value is hardcoded on the engine too, see SV_WaterMove
 455         return dist / (autocvar_sv_maxspeed * 0.7);
 456 }
 457
 458 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 459 {
 460         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 461         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 462
 463         if (submerged_from && submerged_to)
 464                 return waypoint_getlinearcost_underwater(vlen(to - from));
 465
 466         float c = waypoint_getlinearcost(vlen(to - from));
 467
 468         float height = from.z - to.z;
 469         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 470         {
 471                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 472                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 473                 if(height_cost > c)
 474                         c = height_cost;
 475         }
 476
 477         if (submerged_from || submerged_to)
 478                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 479         return c;
 480 }
 481
 482 float waypoint_getlinkcost(entity from, entity to)
 483 {
 484         vector v1 = from.origin;
 485         vector v2 = to.origin;
 486         if (from.wpisbox)
 487         {
 488                 vector m1 = from.absmin, m2 = from.absmax;
 489                 v1.x = bound(m1.x, v2.x, m2.x);
 490                 v1.y = bound(m1.y, v2.y, m2.y);
 491                 v1.z = bound(m1.z, v2.z, m2.z);
 492         }
 493         if (to.wpisbox)
 494         {
 495                 vector m1 = to.absmin, m2 = to.absmax;
 496                 v2.x = bound(m1.x, v1.x, m2.x);
 497                 v2.y = bound(m1.y, v1.y, m2.y);
 498                 v2.z = bound(m1.z, v1.z, m2.z);
 499         }
 500         return waypoint_gettravelcost(v1, v2, from, to);
 501 }
 502
 503 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 504 // if c == -1 automatically determine cost of the link
 505 void waypoint_addlink_customcost(entity from, entity to, float c)
 506 {
 507         if (from == to || waypoint_islinked(from, to))
 508                 return;
 509         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 510                 return;
 511
 512         if(c == -1)
 513                 c = waypoint_getlinkcost(from, to);
 514
 515         if (from.wp31mincost < c) return;
 516         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 517         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 518         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 519         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 520         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 521         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 522         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 523         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 524         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 525         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 526         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 527         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 528         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 529         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 530         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 531         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 532         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 533         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 534         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 535         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 536         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 537         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 538         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 539         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 540         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 541         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 542         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 543         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 544         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 545         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 546         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 547         from.wp00 = to;from.wp00mincost = c;return;
 548 }
 549
 550 void waypoint_addlink(entity from, entity to)
 551 {
 552         waypoint_addlink_customcost(from, to, -1);
 553 }
 554
 555 // relink this spawnfunc_waypoint
 556 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 557 // (SLOW!)
 558 void waypoint_think(entity this)
 559 {
 560         vector sv, sv2, ev, ev2, dv;
 561         float sv2_height, ev2_height;
 562
 563         bot_calculate_stepheightvec();
 564
 565         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 566
 567         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 568         IL_EACH(g_waypoints, this != it,
 569         {
 570                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 571                 {
 572                         waypoint_addlink(this, it);
 573                         waypoint_addlink(it, this);
 574                 }
 575                 else
 576                 {
 577                         ++relink_total;
 578                         if(!checkpvs(this.origin, it))
 579                         {
 580                                 ++relink_pvsculled;
 581                                 continue;
 582                         }
 583
 584                         SET_TRACEWALK_DESTCOORDS_2(this, it.origin, sv, sv2, sv2_height);
 585                         SET_TRACEWALK_DESTCOORDS_2(it, this.origin, ev, ev2, ev2_height);
 586
 587                         dv = ev - sv;
 588                         dv.z = 0;
 589                         if(vdist(dv, >=, 1050)) // max search distance in XY
 590                         {
 591                                 ++relink_lengthculled;
 592                                 continue;
 593                         }
 594
 595                         navigation_testtracewalk = 0;
 596
 597                         //traceline(this.origin, it.origin, false, NULL);
 598                         //if (trace_fraction == 1)
 599                         if (this.wpisbox)
 600                                 relink_walkculled += 0.5;
 601                         else
 602                         {
 603                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 604                                         waypoint_addlink(this, it);
 605                                 else
 606                                         relink_walkculled += 0.5;
 607                         }
 608
 609                         if (it.wpisbox)
 610                                 relink_walkculled += 0.5;
 611                         else
 612                         {
 613                                 if (tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 614                                         waypoint_addlink(it, this);
 615                                 else
 616                                         relink_walkculled += 0.5;
 617                         }
 618                 }
 619         });
 620         navigation_testtracewalk = 0;
 621         this.wplinked = true;
 622 }
 623
 624 void waypoint_clearlinks(entity wp)
 625 {
 626         // clear links to other waypoints
 627         float f = 10000000;
 628         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 629         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 630         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 631         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 632
 633         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 634         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 635         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 636         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 637
 638         wp.wplinked = false;
 639 }
 640
 641 // tell a spawnfunc_waypoint to relink
 642 void waypoint_schedulerelink(entity wp)
 643 {
 644         if (wp == NULL)
 645                 return;
 646
 647         waypoint_setupmodel(wp);
 648         wp.wpisbox = vdist(wp.size, >, 0);
 649         wp.enemy = NULL;
 650         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 651                 wp.owner = NULL;
 652         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 653                 waypoint_clearlinks(wp);
 654         // schedule an actual relink on next frame
 655         setthink(wp, waypoint_think);
 656         wp.nextthink = time;
 657         wp.effects = EF_LOWPRECISION;
 658 }
 659
 660 // spawnfunc_waypoint map entity
 661 spawnfunc(waypoint)
 662 {
 663         IL_PUSH(g_waypoints, this);
 664
 665         setorigin(this, this.origin);
 666         // schedule a relink after other waypoints have had a chance to spawn
 667         waypoint_clearlinks(this);
 668         //waypoint_schedulerelink(this);
 669 }
 670
 671 // tell all waypoints to relink
 672 // actually this is useful only to update relink_* stats
 673 void waypoint_schedulerelinkall()
 674 {
 675         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 676         IL_EACH(g_waypoints, true,
 677         {
 678                 waypoint_schedulerelink(it);
 679         });
 680         waypoint_load_links_hardwired();
 681 }
 682
 683 // Load waypoint links from file
 684 bool waypoint_load_links()
 685 {
 686         string filename, s;
 687         float file, tokens, c = 0, found;
 688         entity wp_from = NULL, wp_to;
 689         vector wp_to_pos, wp_from_pos;
 690         filename = strcat("maps/", mapname);
 691         filename = strcat(filename, ".waypoints.cache");
 692         file = fopen(filename, FILE_READ);
 693
 694         if (file < 0)
 695         {
 696                 LOG_TRACE("waypoint links load from ");
 697                 LOG_TRACE(filename);
 698                 LOG_TRACE(" failed");
 699                 return false;
 700         }
 701
 702         while ((s = fgets(file)))
 703         {
 704                 tokens = tokenizebyseparator(s, "*");
 705
 706                 if (tokens!=2)
 707                 {
 708                         // bad file format
 709                         fclose(file);
 710                         return false;
 711                 }
 712
 713                 wp_from_pos     = stov(argv(0));
 714                 wp_to_pos       = stov(argv(1));
 715
 716                 // Search "from" waypoint
 717                 if(!wp_from || wp_from.origin!=wp_from_pos)
 718                 {
 719                         wp_from = findradius(wp_from_pos, 1);
 720                         found = false;
 721                         while(wp_from)
 722                         {
 723                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 724                                 if(wp_from.classname == "waypoint")
 725                                 {
 726                                         found = true;
 727                                         break;
 728                                 }
 729                                 wp_from = wp_from.chain;
 730                         }
 731
 732                         if(!found)
 733                         {
 734                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 735                                 continue;
 736                         }
 737
 738                 }
 739
 740                 // Search "to" waypoint
 741                 wp_to = findradius(wp_to_pos, 1);
 742                 found = false;
 743                 while(wp_to)
 744                 {
 745                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 746                         if(wp_to.classname == "waypoint")
 747                         {
 748                                 found = true;
 749                                 break;
 750                         }
 751                         wp_to = wp_to.chain;
 752                 }
 753
 754                 if(!found)
 755                 {
 756                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 757                         continue;
 758                 }
 759
 760                 ++c;
 761                 waypoint_addlink(wp_from, wp_to);
 762         }
 763
 764         fclose(file);
 765
 766         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 767
 768         botframe_cachedwaypointlinks = true;
 769         return true;
 770 }
 771
 772 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 773 {
 774         string filename, s;
 775         float file, tokens, c = 0, found;
 776         entity wp_from = NULL, wp_to;
 777         vector wp_to_pos, wp_from_pos;
 778         filename = strcat("maps/", mapname);
 779         filename = strcat(filename, ".waypoints.hardwired");
 780         file = fopen(filename, FILE_READ);
 781
 782         botframe_loadedforcedlinks = true;
 783
 784         if (file < 0)
 785         {
 786                 if(!removal_mode)
 787                         LOG_TRACE("waypoint links load from ", filename, " failed");
 788                 return;
 789         }
 790
 791         while ((s = fgets(file)))
 792         {
 793                 if(substring(s, 0, 2)=="//")
 794                         continue;
 795
 796                 if(substring(s, 0, 1)=="#")
 797                         continue;
 798
 799                 tokens = tokenizebyseparator(s, "*");
 800
 801                 if (tokens!=2)
 802                         continue;
 803
 804                 wp_from_pos     = stov(argv(0));
 805                 wp_to_pos       = stov(argv(1));
 806
 807                 // Search "from" waypoint
 808                 if(!wp_from || wp_from.origin!=wp_from_pos)
 809                 {
 810                         wp_from = findradius(wp_from_pos, 5);
 811                         found = false;
 812                         while(wp_from)
 813                         {
 814                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 815                                 if(wp_from.classname == "waypoint")
 816                                 {
 817                                         found = true;
 818                                         break;
 819                                 }
 820                                 wp_from = wp_from.chain;
 821                         }
 822
 823                         if(!found)
 824                         {
 825                                 if(!removal_mode)
 826                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 827                                 continue;
 828                         }
 829                 }
 830
 831                 // Search "to" waypoint
 832                 wp_to = findradius(wp_to_pos, 5);
 833                 found = false;
 834                 while(wp_to)
 835                 {
 836                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 837                         if(wp_to.classname == "waypoint")
 838                         {
 839                                 found = true;
 840                                 break;
 841                         }
 842                         wp_to = wp_to.chain;
 843                 }
 844
 845                 if(!found)
 846                 {
 847                         if(!removal_mode)
 848                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 849                         continue;
 850                 }
 851
 852                 ++c;
 853                 if(removal_mode)
 854                 {
 855                         waypoint_removelink(wp_from, wp_to);
 856                         continue;
 857                 }
 858
 859                 waypoint_addlink(wp_from, wp_to);
 860                 wp_from.wphardwired = true;
 861                 wp_to.wphardwired = true;
 862                 waypoint_setupmodel(wp_from);
 863                 waypoint_setupmodel(wp_to);
 864         }
 865
 866         fclose(file);
 867
 868         if(!removal_mode)
 869                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 870 }
 871
 872 entity waypoint_get_link(entity w, float i)
 873 {
 874         switch(i)
 875         {
 876                 case  0:return w.wp00;
 877                 case  1:return w.wp01;
 878                 case  2:return w.wp02;
 879                 case  3:return w.wp03;
 880                 case  4:return w.wp04;
 881                 case  5:return w.wp05;
 882                 case  6:return w.wp06;
 883                 case  7:return w.wp07;
 884                 case  8:return w.wp08;
 885                 case  9:return w.wp09;
 886                 case 10:return w.wp10;
 887                 case 11:return w.wp11;
 888                 case 12:return w.wp12;
 889                 case 13:return w.wp13;
 890                 case 14:return w.wp14;
 891                 case 15:return w.wp15;
 892                 case 16:return w.wp16;
 893                 case 17:return w.wp17;
 894                 case 18:return w.wp18;
 895                 case 19:return w.wp19;
 896                 case 20:return w.wp20;
 897                 case 21:return w.wp21;
 898                 case 22:return w.wp22;
 899                 case 23:return w.wp23;
 900                 case 24:return w.wp24;
 901                 case 25:return w.wp25;
 902                 case 26:return w.wp26;
 903                 case 27:return w.wp27;
 904                 case 28:return w.wp28;
 905                 case 29:return w.wp29;
 906                 case 30:return w.wp30;
 907                 case 31:return w.wp31;
 908                 default:return NULL;
 909         }
 910 }
 911
 912 // Save all waypoint links to a file
 913 void waypoint_save_links()
 914 {
 915         // temporarily remove hardwired links so they don't get saved among normal links
 916         waypoint_remove_links_hardwired();
 917
 918         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 919         int file = fopen(filename, FILE_WRITE);
 920         if (file < 0)
 921         {
 922                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 923                 return;
 924         }
 925
 926         int c = 0;
 927         IL_EACH(g_waypoints, true,
 928         {
 929                 for(int j = 0; j < 32; ++j)
 930                 {
 931                         entity link = waypoint_get_link(it, j);
 932                         if(link)
 933                         {
 934                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 935                                 fputs(file, s);
 936                                 ++c;
 937                         }
 938                 }
 939         });
 940         fclose(file);
 941         botframe_cachedwaypointlinks = true;
 942
 943         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 944
 945         waypoint_load_links_hardwired();
 946 }
 947
 948 // save waypoints to gamedir/data/maps/mapname.waypoints
 949 void waypoint_saveall()
 950 {
 951         string filename = sprintf("maps/%s.waypoints", mapname);
 952         int file = fopen(filename, FILE_WRITE);
 953         if (file < 0)
 954         {
 955                 waypoint_save_links(); // save anyway?
 956                 botframe_loadedforcedlinks = false;
 957
 958                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 959                 return;
 960         }
 961
 962         int c = 0;
 963         IL_EACH(g_waypoints, true,
 964         {
 965                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 966                         continue;
 967
 968                 string s;
 969                 s = strcat(vtos(it.origin + it.mins), "\n");
 970                 s = strcat(s, vtos(it.origin + it.maxs));
 971                 s = strcat(s, "\n");
 972                 s = strcat(s, ftos(it.wpflags));
 973                 s = strcat(s, "\n");
 974                 fputs(file, s);
 975                 c++;
 976         });
 977         fclose(file);
 978         waypoint_save_links();
 979         botframe_loadedforcedlinks = false;
 980
 981         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 982 }
 983
 984 // load waypoints from file
 985 float waypoint_loadall()
 986 {
 987         string filename, s;
 988         float file, cwp, cwb, fl;
 989         vector m1, m2;
 990         cwp = 0;
 991         cwb = 0;
 992         filename = strcat("maps/", mapname);
 993         filename = strcat(filename, ".waypoints");
 994         file = fopen(filename, FILE_READ);
 995         if (file >= 0)
 996         {
 997                 while ((s = fgets(file)))
 998                 {
 999                         m1 = stov(s);
1000                         s = fgets(file);
1001                         if (!s)
1002                                 break;
1003                         m2 = stov(s);
1004                         s = fgets(file);
1005                         if (!s)
1006                                 break;
1007                         fl = stof(s);
1008                         waypoint_spawn(m1, m2, fl);
1009                         if (m1 == m2)
1010                                 cwp = cwp + 1;
1011                         else
1012                                 cwb = cwb + 1;
1013                 }
1014                 fclose(file);
1015                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1016         }
1017         else
1018         {
1019                 LOG_TRACE("waypoint load from ", filename, " failed");
1020         }
1021         return cwp + cwb;
1022 }
1023
1024 vector waypoint_fixorigin(vector position, entity tracetest_ent)
1025 {
1026         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, tracetest_ent);
1027         if(trace_fraction < 1)
1028                 position = trace_endpos;
1029         return position;
1030 }
1031
1032 void waypoint_spawnforitem_force(entity e, vector org)
1033 {
1034         // Fix the waypoint altitude if necessary
1035         org = waypoint_fixorigin(org, NULL);
1036
1037         // don't spawn an item spawnfunc_waypoint if it already exists
1038         IL_EACH(g_waypoints, true,
1039         {
1040                 if(it.wpisbox)
1041                 {
1042                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1043                         {
1044                                 e.nearestwaypoint = it;
1045                                 return;
1046                         }
1047                 }
1048                 else
1049                 {
1050                         if(vdist(it.origin - org, <, 16))
1051                         {
1052                                 e.nearestwaypoint = it;
1053                                 return;
1054                         }
1055                 }
1056         });
1057
1058         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1059 }
1060
1061 void waypoint_spawnforitem(entity e)
1062 {
1063         if(!bot_waypoints_for_items)
1064                 return;
1065
1066         waypoint_spawnforitem_force(e, e.origin);
1067 }
1068
1069 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1070 {
1071         entity w;
1072         entity dw;
1073         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1074         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1075         // one way link to the destination
1076         w.wp00 = dw;
1077         w.wp00mincost = timetaken; // this is just for jump pads
1078         // the teleporter's nearest spawnfunc_waypoint is this one
1079         // (teleporters are not goals, so this is probably useless)
1080         e.nearestwaypoint = w;
1081         e.nearestwaypointtimeout = -1;
1082 }
1083
1084 void waypoint_spawnforteleporter_wz(entity e, vector org, vector destination, float timetaken, entity tracetest_ent)
1085 {
1086         org = waypoint_fixorigin(org, tracetest_ent);
1087         destination = waypoint_fixorigin(destination, tracetest_ent);
1088         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1089 }
1090
1091 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1092 {
1093         destination = waypoint_fixorigin(destination, tracetest_ent);
1094         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1095 }
1096
1097 entity waypoint_spawnpersonal(entity this, vector position)
1098 {
1099         entity w;
1100
1101         // drop the waypoint to a proper location:
1102         //   first move it up by a player height
1103         //   then move it down to hit the floor with player bbox size
1104         position = waypoint_fixorigin(position, this);
1105
1106         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1107         w.nearestwaypoint = NULL;
1108         w.nearestwaypointtimeout = 0;
1109         w.owner = this;
1110
1111         waypoint_schedulerelink(w);
1112
1113         return w;
1114 }
1115
1116 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1117 {
1118         if (!(wp1 && wp2))
1119                 return;
1120
1121         if (wp1.wphardwired && wp2.wphardwired)
1122                 te_beam(NULL, wp1.origin, wp2.origin);
1123         else if (display_type == 1)
1124                 te_lightning2(NULL, wp1.origin, wp2.origin);
1125 }
1126
1127 void waypoint_showlinks_to(entity wp, int display_type)
1128 {
1129         IL_EACH(g_waypoints, it != wp,
1130         {
1131                 if (waypoint_islinked(it, wp))
1132                         waypoint_showlink(it, wp, display_type);
1133         });
1134 }
1135
1136 void waypoint_showlinks_from(entity wp, int display_type)
1137 {
1138         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1139         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1140         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1141         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1142         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1143         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1144         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1145         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1146         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1147         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1148         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1149         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1150         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1151         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1152         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1153         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1154 }
1155
1156 void botframe_showwaypointlinks()
1157 {
1158         if (time < botframe_waypointeditorlightningtime)
1159                 return;
1160         botframe_waypointeditorlightningtime = time + 0.5;
1161         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1162         {
1163                 int display_type = 0;
1164                 entity head = navigation_findnearestwaypoint(it, false);
1165                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1166                         display_type = 1; // default
1167                 else if(head && (head.wphardwired))
1168                         display_type = 2; // only hardwired
1169
1170                 if (display_type)
1171                 {
1172                         //navigation_testtracewalk = true;
1173                         //print("currently selected WP is ", etos(head), "\n");
1174                         //navigation_testtracewalk = false;
1175                         if (head)
1176                         {
1177                                 te_lightning2(NULL, head.origin, it.origin);
1178                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1179                                         waypoint_showlinks_to(head, display_type);
1180                                 else
1181                                         waypoint_showlinks_from(head, display_type);
1182                         }
1183                 }
1184         });
1185 }
1186
1187 float botframe_autowaypoints_fixdown(vector v)
1188 {
1189         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1190         if(trace_fraction >= 1)
1191                 return 0;
1192         return 1;
1193 }
1194
1195 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1196 {
1197         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1198         {
1199                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1200                 return 0;
1201         });
1202
1203         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1204         return 1;
1205 }
1206
1207 // return value:
1208 //    1 = WP created
1209 //    0 = no action needed
1210 //   -1 = temp fail, try from world too
1211 //   -2 = permanent fail, do not retry
1212 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1213 {
1214         // make it possible to go from p to wp, if we can
1215         // if wp is NULL, nearest is chosen
1216
1217         entity w;
1218         vector porg;
1219         float t, tmin, tmax;
1220         vector o;
1221         vector save;
1222
1223         if(!botframe_autowaypoints_fixdown(p.origin))
1224                 return -2;
1225         porg = trace_endpos;
1226
1227         if(wp)
1228         {
1229                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1230
1231                 // if wp -> porg, then OK
1232                 float maxdist;
1233                 if(navigation_waypoint_will_link(wp.origin, porg, p, wp.origin, 0, walkfromwp, 1050))
1234                 {
1235                         // we may find a better one
1236                         maxdist = vlen(wp.origin - porg);
1237                 }
1238                 else
1239                 {
1240                         // accept any "good"
1241                         maxdist = 2100;
1242                 }
1243
1244                 float bestdist = maxdist;
1245                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1246                 {
1247                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1248                         if(d < bestdist)
1249                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, wp.origin, 0, walkfromwp, 1050))
1250                         if(navigation_waypoint_will_link(it.origin, porg, p, it.origin, 0, walkfromwp, 1050))
1251                         {
1252                                 bestdist = d;
1253                                 p.(fld) = it;
1254                         }
1255                 });
1256                 if(bestdist < maxdist)
1257                 {
1258                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1259                         return 0;
1260                 }
1261
1262                 if(bestdist < 2100)
1263                 {
1264                         // we know maxdist < 2100
1265                         // so wp -> porg is still valid
1266                         // all is good
1267                         p.(fld) = wp;
1268                         return 0;
1269                 }
1270
1271                 // otherwise, no existing WP can fix our issues
1272         }
1273         else
1274         {
1275                 save = p.origin;
1276                 setorigin(p, porg);
1277                 w = navigation_findnearestwaypoint(p, walkfromwp);
1278                 setorigin(p, save);
1279                 if(w)
1280                 {
1281                         p.(fld) = w;
1282                         return 0;
1283                 }
1284         }
1285
1286         tmin = 0;
1287         tmax = 1;
1288         for (;;)
1289         {
1290                 if(tmax - tmin < 0.001)
1291                 {
1292                         // did not get a good candidate
1293                         return -1;
1294                 }
1295
1296                 t = (tmin + tmax) * 0.5;
1297                 o = antilag_takebackorigin(p, CS(p), time - t);
1298                 if(!botframe_autowaypoints_fixdown(o))
1299                         return -2;
1300                 o = trace_endpos;
1301
1302                 if(wp)
1303                 {
1304                         if(!navigation_waypoint_will_link(wp.origin, o, p, wp.origin, 0, walkfromwp, 1050))
1305                         {
1306                                 // we cannot walk from wp.origin to o
1307                                 // get closer to tmax
1308                                 tmin = t;
1309                                 continue;
1310                         }
1311                 }
1312                 else
1313                 {
1314                         save = p.origin;
1315                         setorigin(p, o);
1316                         w = navigation_findnearestwaypoint(p, walkfromwp);
1317                         setorigin(p, save);
1318                         if(!w)
1319                         {
1320                                 // we cannot walk from any WP to o
1321                                 // get closer to tmax
1322                                 tmin = t;
1323                                 continue;
1324                         }
1325                 }
1326
1327                 // if we get here, o is valid regarding waypoints
1328                 // check if o is connected right to the player
1329                 // we break if it succeeds, as that means o is a good waypoint location
1330                 if(navigation_waypoint_will_link(o, porg, p, o, 0, walkfromwp, 1050))
1331                         break;
1332
1333                 // o is no good, we need to get closer to the player
1334                 tmax = t;
1335         }
1336
1337         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1338         botframe_autowaypoints_createwp(o, p, fld, 0);
1339         return 1;
1340 }
1341
1342 // automatically create missing waypoints
1343 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1344 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1345 {
1346         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1347         if(r != -1)
1348                 return;
1349         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1350         if(r != -1)
1351                 return;
1352
1353         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1354         if(!botframe_autowaypoints_fixdown(p.origin))
1355                 return; // shouldn't happen, caught above
1356         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1357 }
1358
1359 void botframe_deleteuselesswaypoints()
1360 {
1361         IL_EACH(g_items, it.bot_pickup,
1362         {
1363                 // NOTE: this protects waypoints if they're the ONLY nearest
1364                 // waypoint. That's the intention.
1365                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1366                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1367         });
1368         IL_EACH(g_waypoints, true,
1369         {
1370                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1371                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1372                 // WP is useful if:
1373                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1374                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1375                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1376                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1377                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1378                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1379                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1380                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1381                 // b) WP is closest WP for an item/spawnpoint/other entity
1382                 //    This has been done above by protecting these WPs.
1383         });
1384         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1385         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1386         {
1387                 for (int m = 0; m < 32; ++m)
1388                 {
1389                         entity w = waypoint_get_link(it, m);
1390                         if (!w)
1391                                 break;
1392                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1393                                 continue;
1394                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1395                                 continue;
1396                         for (int j = 0; j < 32; ++j)
1397                         {
1398                                 entity w2 = waypoint_get_link(w, j);
1399                                 if (!w2)
1400                                         break;
1401                                 if (it == w2)
1402                                         continue;
1403                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1404                                         continue;
1405                                 // If we got here, it != w2 exist with it -> w
1406                                 // and w -> w2. That means the waypoint is not
1407                                 // a dead end.
1408                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1409                                 for (int k = 0; k < 32; ++k)
1410                                 {
1411                                         if (waypoint_get_link(it, k) == w2)
1412                                                 continue;
1413                                         // IF WE GET HERE, w is proven useful
1414                                         // to get from it to w2!
1415                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1416                                         goto next;
1417                                 }
1418                         }
1419 LABEL(next)
1420                 }
1421         });
1422         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1423         //     they are needed to complete routes while autowaypointing.
1424
1425         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1426         {
1427                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1428                 te_explosion(it.origin);
1429                 waypoint_remove(it);
1430                 break;
1431         });
1432
1433         IL_EACH(g_waypoints, true,
1434         {
1435                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1436         });
1437 }
1438
1439 void botframe_autowaypoints()
1440 {
1441         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1442                 // going back is broken, so only fix waypoints to walk TO the player
1443                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1444                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1445                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1446         ));
1447
1448         if (autocvar_g_waypointeditor_auto >= 2) {
1449                 botframe_deleteuselesswaypoints();
1450         }
1451 }
1452