qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_setupmodel(entity wp);
 288 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 289 {
 290         if (!(wp_from && wp_to))
 291                 return;
 292
 293         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 294         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 295         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 296         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 297         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 298         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 299         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 300         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 301
 302         return;
 303 }
 304
 305 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 306 {
 307         if (!(wp_from && wp_to))
 308                 return;
 309
 310         int removed = -1;
 311         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 312         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 313         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 314         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 315         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 316         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 317         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 318         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 319
 320         if (removed >= 0)
 321         {
 322                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 323                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 324                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 325                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 326                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 327                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 328                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 329                 if (removed <= 7) wp_from.wphw07 = NULL;
 330                 if (!wp_from.wphw00)
 331                         waypoint_setupmodel(wp_from);
 332         }
 333
 334         return;
 335 }
 336
 337 void waypoint_setupmodel(entity wp)
 338 {
 339         if (autocvar_g_waypointeditor)
 340         {
 341                 // TODO: add some sort of visible box in edit mode for box waypoints
 342                 vector m1 = wp.mins;
 343                 vector m2 = wp.maxs;
 344                 setmodel(wp, MDL_WAYPOINT);
 345                 setsize(wp, m1, m2);
 346                 wp.effects = EF_LOWPRECISION;
 347                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 348                         wp.colormod = '1 0 0'; // red
 349                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 350                         wp.colormod = '1 1 0'; // yellow
 351                 else if (wp.wpflags & WAYPOINTFLAG_SUPPORT)
 352                         wp.colormod = '0 1 0'; // green
 353                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 354                         wp.colormod = '1 0.5 0'; // orange
 355                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 356                         wp.colormod = '0 1 1'; // cyan
 357                 else if (waypoint_has_hardwiredlinks(wp))
 358                         wp.colormod = '0.5 0 1'; // purple
 359                 else
 360                         wp.colormod = '1 1 1';
 361         }
 362         else
 363                 wp.model = "";
 364 }
 365
 366 entity waypoint_get(vector m1, vector m2)
 367 {
 368         if (m1 == m2)
 369         {
 370                 m1 -= '8 8 8';
 371                 m2 += '8 8 8';
 372         }
 373         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 374
 375         return NULL;
 376 }
 377
 378 .float createdtime;
 379 entity waypoint_spawn(vector m1, vector m2, float f)
 380 {
 381         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 382         {
 383                 entity wp_found = waypoint_get(m1, m2);
 384                 if (wp_found)
 385                         return wp_found;
 386         }
 387         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 388         // otherwise links loaded from file would be applied only to the first destination
 389         // waypoint since link format doesn't specify waypoint entities but just positions
 390         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 391         {
 392                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 393                 {
 394                         return it;
 395                 });
 396         }
 397
 398         entity w = new(waypoint);
 399         IL_PUSH(g_waypoints, w);
 400         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 401         w.wpflags = f;
 402         w.solid = SOLID_TRIGGER;
 403         w.createdtime = time;
 404         setorigin(w, (m1 + m2) * 0.5);
 405         setsize(w, m1 - w.origin, m2 - w.origin);
 406         if (w.size)
 407                 w.wpisbox = true;
 408
 409         if(!w.wpisbox)
 410         {
 411                 if (f & WAYPOINTFLAG_CROUCH)
 412                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 413                 else
 414                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 415                 if(!move_out_of_solid(w))
 416                 {
 417                         if(!(f & WAYPOINTFLAG_GENERATED))
 418                         {
 419                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 420                                 delete(w);
 421                                 return NULL;
 422                         }
 423                         else
 424                         {
 425                                 if(autocvar_developer)
 426                                 {
 427                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 428                                         backtrace("Waypoint stuck");
 429                                 }
 430                         }
 431                 }
 432                 setsize(w, '0 0 0', '0 0 0');
 433         }
 434
 435         waypoint_clearlinks(w);
 436         //waypoint_schedulerelink(w);
 437
 438         waypoint_setupmodel(w);
 439
 440         return w;
 441 }
 442
 443 float trigger_push_get_push_time(entity this, vector endpos);
 444 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 445 {
 446         entity jp = NULL;
 447         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 448         {
 449                 jp = it;
 450                 break;
 451         });
 452         if (!jp)
 453                 return;
 454
 455         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 456         wp_from.wp00 = wp_to;
 457         wp_from.wp00mincost = cost;
 458         jp.nearestwaypoint = wp_from;
 459         jp.nearestwaypointtimeout = -1;
 460 }
 461
 462 bool start_wp_is_spawned;
 463 vector start_wp_origin;
 464 bool start_wp_is_hardwired;
 465 bool start_wp_is_support;
 466
 467 void waypoint_clear_start_wp_globals(entity pl, bool warn)
 468 {
 469         start_wp_is_spawned = false;
 470         start_wp_origin = '0 0 0';
 471         pl.wp_locked = NULL;
 472         start_wp_is_hardwired = false;
 473         start_wp_is_support = false;
 474         if (warn)
 475                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 476 }
 477
 478 void waypoint_start_hardwiredlink(entity pl)
 479 {
 480         entity wp = pl.nearestwaypoint;
 481         if ((!start_wp_is_spawned || start_wp_is_hardwired) && wp && !(wp.wpflags & WAYPOINTFLAG_NORELINK))
 482         {
 483                 start_wp_is_hardwired = true;
 484                 start_wp_is_spawned = true;
 485                 start_wp_origin = wp.origin;
 486                 pl.wp_locked = wp;
 487                 LOG_INFOF("^x80fNearest waypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 488         }
 489         else
 490                 start_wp_is_hardwired = false;
 491 }
 492
 493 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp, bool is_support_wp)
 494 {
 495         if (WAYPOINT_VERSION < waypoint_version_loaded)
 496         {
 497                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 498                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 499                 return;
 500         }
 501
 502         entity e = NULL, jp = NULL;
 503         vector org = pl.origin;
 504         if (at_crosshair)
 505         {
 506                 crosshair_trace(pl);
 507                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 508                 if (!(start_wp_is_hardwired || start_wp_is_support))
 509                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 510                         {
 511                                 jp = it;
 512                                 break;
 513                         });
 514         }
 515         if (jp || is_jump_wp || is_support_wp)
 516         {
 517                 if (start_wp_is_spawned)
 518                         start_wp_is_spawned = false;
 519                 LOG_INFO("^xf80Spawning start waypoint...\n");
 520         }
 521         int ctf_flags = havocbot_symmetry_origin_order;
 522         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 523                    || (autocvar_g_waypointeditor_symmetrical < 0));
 524         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 525                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 526         if (sym && ctf_flags < 2)
 527                 ctf_flags = 2;
 528         int wp_num = ctf_flags;
 529
 530         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp && !is_support_wp)
 531         {
 532                 // snap waypoint to item's origin if close enough
 533                 IL_EACH(g_items, true,
 534                 {
 535                         vector item_org = (it.absmin + it.absmax) * 0.5;
 536                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 537                         if (vlen(item_org - org) < 20)
 538                         {
 539                                 org = item_org;
 540                                 break;
 541                         }
 542                 });
 543         }
 544
 545         vector start_org = '0 0 0';
 546         if (start_wp_is_spawned)
 547         {
 548                 if (!start_wp_is_hardwired)
 549                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 550                 start_org = start_wp_origin;
 551         }
 552
 553         // save org as it can be modified spawning symmetrycal waypoints
 554         vector initial_origin = '0 0 0';
 555         bool initial_origin_is_set = false;
 556
 557         LABEL(add_wp);
 558
 559         if (jp)
 560         {
 561                 e = NULL;
 562                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 563                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 564                 {
 565                         e = it; break;
 566                 });
 567                 if (!e)
 568                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 569                 if (!pl.wp_locked)
 570                         pl.wp_locked = e;
 571         }
 572         else if (is_jump_wp)
 573         {
 574                 entity wp_found = waypoint_get(org, org);
 575                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_JUMP))
 576                 {
 577                         LOG_INFO("Error: can't spawn a jump waypoint over an existent waypoint of a different type\n");
 578                         return;
 579                 }
 580                 e = waypoint_spawn(org, org, WAYPOINTFLAG_JUMP | WAYPOINTFLAG_NORELINK);
 581                 if (!pl.wp_locked)
 582                         pl.wp_locked = e;
 583         }
 584         else if (is_support_wp)
 585         {
 586                 entity wp_found = waypoint_get(org, org);
 587                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_SUPPORT))
 588                 {
 589                         LOG_INFO("Error: can't spawn a support waypoint over an existent waypoint of a different type\n");
 590                         return;
 591                 }
 592                 e = waypoint_spawn(org, org, WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_NORELINK);
 593                 if (!pl.wp_locked)
 594                         pl.wp_locked = e;
 595         }
 596         else
 597                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 598         if(!e)
 599         {
 600                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 601                 if (start_wp_is_spawned)
 602                         waypoint_clear_start_wp_globals(pl, true);
 603                 return;
 604         }
 605
 606         if (!initial_origin_is_set)
 607         {
 608                 initial_origin = e.origin;
 609                 initial_origin_is_set = true;
 610         }
 611
 612         entity start_wp = NULL;
 613         if (start_wp_is_spawned)
 614         {
 615                 IL_EACH(g_waypoints, (start_wp_is_hardwired || it.wpflags & WAYPOINTFLAG_NORELINK)
 616                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 617                 {
 618                         start_wp = it; break;
 619                 });
 620                 if(!start_wp)
 621                 {
 622                         // should not happen
 623                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 624                         waypoint_clear_start_wp_globals(pl, true);
 625                         return;
 626                 }
 627                 if (start_wp_is_hardwired)
 628                 {
 629                         if (waypoint_is_hardwiredlink(start_wp, e))
 630                         {
 631                                 waypoint_unmark_hardwiredlink(start_wp, e);
 632                                 waypoint_removelink(start_wp, e);
 633                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 634                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 635                         }
 636                         else
 637                         {
 638                                 if (e.createdtime == time)
 639                                 {
 640                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 641                                         waypoint_remove(e);
 642                                         waypoint_clear_start_wp_globals(pl, true);
 643                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp, is_support_wp);
 644                                         return;
 645                                 }
 646                                 if (start_wp == e)
 647                                 {
 648                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 649                                         waypoint_clear_start_wp_globals(pl, true);
 650                                         return;
 651                                 }
 652                                 if (waypoint_islinked(start_wp, e))
 653                                 {
 654                                         LOG_INFO("Error: waypoints are already linked.\n");
 655                                         waypoint_clear_start_wp_globals(pl, true);
 656                                         return;
 657                                 }
 658                                 waypoint_addlink(start_wp, e);
 659                                 waypoint_mark_hardwiredlink(start_wp, e);
 660                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 661                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 662                         }
 663                 }
 664                 else
 665                 {
 666                         if (start_wp_is_support)
 667                         {
 668                                 if (e.SUPPORT_WP)
 669                                 {
 670                                         LOG_INFOF("Waypoint %v has already a support waypoint, delete it first.\n", e.origin);
 671                                         waypoint_clear_start_wp_globals(pl, true);
 672                                         return;
 673                                 }
 674                                 // clear all links to e
 675                                 IL_EACH(g_waypoints, it != e,
 676                                 {
 677                                         if (waypoint_islinked(it, e) && !waypoint_is_hardwiredlink(it, e))
 678                                                 waypoint_removelink(it, e);
 679                                 });
 680                         }
 681                         waypoint_addlink(start_wp, e);
 682                 }
 683         }
 684
 685         if (!(jp || is_jump_wp || is_support_wp || start_wp_is_hardwired))
 686                 waypoint_schedulerelink(e);
 687
 688         string wp_type_str = "Waypoint";
 689         if (is_crouch_wp)               wp_type_str = "Crouch waypoint";
 690         else if (is_jump_wp)    wp_type_str = "Jump waypoint";
 691         else if (is_support_wp) wp_type_str = "Support waypoint";
 692         else if (jp)                    wp_type_str = "Custom jumppad waypoint";
 693
 694         bprint(strcat(wp_type_str, " spawned at ", vtos(e.origin), "\n"));
 695
 696         if (start_wp_is_spawned)
 697         {
 698                 pl.wp_locked = NULL;
 699                 if (!start_wp_is_hardwired)
 700                         waypoint_schedulerelink(start_wp);
 701                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 702                 {
 703                         if (start_wp.wp00_original == start_wp.wp00)
 704                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 705                         else
 706                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 707                 }
 708         }
 709
 710         if (sym)
 711         {
 712                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 713                 if (jp)
 714                 {
 715                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 716                         {
 717                                 jp = it; break;
 718                         });
 719                 }
 720                 if (start_wp_is_spawned)
 721                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 722                 if (vdist(org - pl.origin, >, 32))
 723                 {
 724                         if(wp_num > 2)
 725                                 wp_num--;
 726                         else
 727                                 sym = false;
 728                         goto add_wp;
 729                 }
 730         }
 731         if (jp || is_jump_wp || is_support_wp)
 732         {
 733                 if (!start_wp_is_spawned)
 734                 {
 735                         // we've just created a custom jumppad waypoint
 736                         // the next one created by the user will be the destination waypoint
 737                         start_wp_is_spawned = true;
 738                         start_wp_origin = initial_origin;
 739                         if (is_support_wp)
 740                                 start_wp_is_support = true;
 741                 }
 742         }
 743         else if (start_wp_is_spawned)
 744         {
 745                 waypoint_clear_start_wp_globals(pl, false);
 746         }
 747 }
 748
 749 void waypoint_remove(entity wp)
 750 {
 751         if (wp.SUPPORT_WP)
 752                 waypoint_remove(wp.SUPPORT_WP); // remove support waypoint too
 753
 754         IL_EACH(g_waypoints, it != wp,
 755         {
 756                 if (it.SUPPORT_WP == wp)
 757                 {
 758                         it.SUPPORT_WP = NULL;
 759                         waypoint_schedulerelink(it); // restore incoming links
 760                 }
 761                 if (waypoint_islinked(it, wp))
 762                 {
 763                         if (waypoint_is_hardwiredlink(it, wp))
 764                                 waypoint_unmark_hardwiredlink(it, wp);
 765                         waypoint_removelink(it, wp);
 766                 }
 767         });
 768         delete(wp);
 769 }
 770
 771 void waypoint_remove_fromeditor(entity pl)
 772 {
 773         if (WAYPOINT_VERSION < waypoint_version_loaded)
 774         {
 775                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 776                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 777                 return;
 778         }
 779
 780         entity e = navigation_findnearestwaypoint(pl, false);
 781
 782         int ctf_flags = havocbot_symmetry_origin_order;
 783         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 784                    || (autocvar_g_waypointeditor_symmetrical < 0));
 785         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 786                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 787         if (sym && ctf_flags < 2)
 788                 ctf_flags = 2;
 789         int wp_num = ctf_flags;
 790
 791         LABEL(remove_wp);
 792         if (!e) return;
 793
 794         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 795         {
 796                 if (start_wp_is_spawned)
 797                         waypoint_clear_start_wp_globals(pl, true);
 798                 return;
 799         }
 800
 801         if (waypoint_has_hardwiredlinks(e))
 802         {
 803                 LOG_INFO("Can't remove a waypoint with hardwired links, remove them with \"wpeditor hardwire\" first\n");
 804                 return;
 805         }
 806
 807         entity wp_sym = NULL;
 808         if (sym)
 809         {
 810                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 811                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 812                         if(vdist(org - it.origin, <, 3))
 813                         {
 814                                 wp_sym = it;
 815                                 break;
 816                         }
 817                 });
 818         }
 819
 820         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 821         waypoint_remove(e);
 822
 823         if (sym && wp_sym)
 824         {
 825                 e = wp_sym;
 826                 if(wp_num > 2)
 827                         wp_num--;
 828                 else
 829                         sym = false;
 830                 goto remove_wp;
 831         }
 832
 833         if (start_wp_is_spawned)
 834                 waypoint_clear_start_wp_globals(pl, true);
 835 }
 836
 837 void waypoint_removelink(entity from, entity to)
 838 {
 839         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))))
 840                 return;
 841
 842         entity fromwp31_prev = from.wp31;
 843
 844         switch (waypoint_getlinknum(from, to))
 845         {
 846                 // fallthrough all the way
 847                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 848                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 849                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 850                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 851                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 852                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 853                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 854                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 855                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 856                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 857                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 858                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 859                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 860                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 861                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 862                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 863                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 864                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 865                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 866                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 867                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 868                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 869                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 870                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 871                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 872                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 873                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 874                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 875                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 876                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 877                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 878                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 879         }
 880
 881         if (fromwp31_prev && !from.wp31)
 882                 waypoint_schedulerelink(from);
 883 }
 884
 885 int waypoint_getlinknum(entity from, entity to)
 886 {
 887         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 888         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 889         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 890         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 891         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 892         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 893         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 894         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 895         return -1;
 896 }
 897
 898 bool waypoint_islinked(entity from, entity to)
 899 {
 900         return (waypoint_getlinknum(from, to) >= 0);
 901 }
 902
 903 void waypoint_updatecost_foralllinks()
 904 {
 905         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 906         {
 907                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 908                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 909                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 910                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 911                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 912                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 913                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 914                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 915                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 916                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 917                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 918                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 919                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 920                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 921                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 922                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 923                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 924                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 925                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 926                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 927                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 928                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 929                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 930                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 931                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 932                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 933                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 934                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 935                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 936                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 937                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 938                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 939         });
 940 }
 941
 942 float waypoint_getlinearcost(float dist)
 943 {
 944         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 945                 return dist / (autocvar_sv_maxspeed * 1.25);
 946         return dist / autocvar_sv_maxspeed;
 947 }
 948
 949 float waypoint_getlinearcost_underwater(float dist)
 950 {
 951         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 952         return dist / (autocvar_sv_maxspeed * 0.7);
 953 }
 954
 955 float waypoint_getlinearcost_crouched(float dist)
 956 {
 957         return dist / (autocvar_sv_maxspeed * 0.5);
 958 }
 959
 960 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 961 {
 962         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 963         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 964
 965         if (submerged_from && submerged_to)
 966                 return waypoint_getlinearcost_underwater(vlen(to - from));
 967
 968         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH && to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 969                 return waypoint_getlinearcost_crouched(vlen(to - from));
 970
 971         float c = waypoint_getlinearcost(vlen(to - from));
 972
 973         float height = from.z - to.z;
 974         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 975         {
 976                 float height_cost; // fall cost
 977                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 978                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 979                 else
 980                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 981                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 982                 if(height_cost > c)
 983                         c = height_cost;
 984         }
 985
 986         // consider half path underwater
 987         if (submerged_from || submerged_to)
 988                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 989
 990         // consider half path crouched
 991         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH || to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 992                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
 993
 994         return c;
 995 }
 996
 997 float waypoint_getlinkcost(entity from, entity to)
 998 {
 999         vector v1 = from.origin;
1000         vector v2 = to.origin;
1001         if (from.wpisbox)
1002         {
1003                 vector m1 = from.absmin, m2 = from.absmax;
1004                 v1.x = bound(m1.x, v2.x, m2.x);
1005                 v1.y = bound(m1.y, v2.y, m2.y);
1006                 v1.z = bound(m1.z, v2.z, m2.z);
1007         }
1008         if (to.wpisbox)
1009         {
1010                 vector m1 = to.absmin, m2 = to.absmax;
1011                 v2.x = bound(m1.x, v1.x, m2.x);
1012                 v2.y = bound(m1.y, v1.y, m2.y);
1013                 v2.z = bound(m1.z, v1.z, m2.z);
1014         }
1015         return waypoint_gettravelcost(v1, v2, from, to);
1016 }
1017
1018 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
1019 // if c == -1 automatically determine cost of the link
1020 void waypoint_addlink_customcost(entity from, entity to, float c)
1021 {
1022         if (from == to || waypoint_islinked(from, to))
1023                 return;
1024         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1025                 return;
1026
1027         if(c == -1)
1028                 c = waypoint_getlinkcost(from, to);
1029
1030         if (from.wp31mincost < c) return;
1031         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
1032         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
1033         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
1034         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
1035         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
1036         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
1037         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
1038         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
1039         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
1040         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
1041         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
1042         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
1043         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
1044         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1045         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1046         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1047         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1048         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1049         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1050         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1051         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1052         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1053         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1054         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1055         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1056         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1057         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1058         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1059         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1060         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1061         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1062         from.wp00 = to;from.wp00mincost = c;return;
1063 }
1064
1065 void waypoint_addlink(entity from, entity to)
1066 {
1067         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1068                 waypoint_addlink_for_custom_jumppad(from, to);
1069         else
1070                 waypoint_addlink_customcost(from, to, -1);
1071
1072         if (from.wpflags & WAYPOINTFLAG_SUPPORT)
1073                 to.SUPPORT_WP = from;
1074 }
1075
1076 // relink this spawnfunc_waypoint
1077 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1078 // (SLOW!)
1079 void waypoint_think(entity this)
1080 {
1081         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1082         float sv2_height = 0, ev2_height = 0;
1083
1084         bot_calculate_stepheightvec();
1085
1086         int dphitcontentsmask_save = this.dphitcontentsmask;
1087         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1088
1089         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1090
1091         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1092         IL_EACH(g_waypoints, this != it,
1093         {
1094                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1095                 {
1096                         if (!(this.wpflags & WAYPOINTFLAG_NORELINK))
1097                                 waypoint_addlink(this, it);
1098                         if (!(it.wpflags & WAYPOINTFLAG_NORELINK))
1099                                 waypoint_addlink(it, this);
1100                 }
1101                 else
1102                 {
1103                         ++relink_total;
1104                         if(!checkpvs(this.origin, it))
1105                         {
1106                                 ++relink_pvsculled;
1107                                 continue;
1108                         }
1109
1110                         sv = set_tracewalk_dest_2(this, it.origin);
1111                         sv2 = tracewalk_dest;
1112                         sv2_height = tracewalk_dest_height;
1113                         ev = set_tracewalk_dest_2(it, this.origin);
1114                         ev2 = tracewalk_dest;
1115                         ev2_height = tracewalk_dest_height;
1116
1117                         dv = ev - sv;
1118                         dv.z = 0;
1119                         int maxdist = 1050;
1120                         vector m1 = PL_MIN_CONST;
1121                         vector m2 = PL_MAX_CONST;
1122
1123                         if (this.wpflags & WAYPOINTFLAG_CROUCH || it.wpflags & WAYPOINTFLAG_CROUCH)
1124                         {
1125                                 m1 = PL_CROUCH_MIN_CONST;
1126                                 m2 = PL_CROUCH_MAX_CONST;
1127                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1128                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1129                                 // links from crouch wp to crouch wp can be as long as normal links
1130                                 if (!(this.wpflags & WAYPOINTFLAG_CROUCH && it.wpflags & WAYPOINTFLAG_CROUCH))
1131                                         maxdist = 100;
1132                         }
1133
1134                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1135                         {
1136                                 ++relink_lengthculled;
1137                                 continue;
1138                         }
1139
1140                         navigation_testtracewalk = 0;
1141
1142                         //traceline(this.origin, it.origin, false, NULL);
1143                         //if (trace_fraction == 1)
1144                         if (this.wpisbox || this.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT) // forbid outgoing links
1145                                 || it.SUPPORT_WP) // forbid incoming links
1146                         {
1147                                 relink_walkculled += 0.5;
1148                         }
1149                         else
1150                         {
1151                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1152                                         waypoint_addlink(this, it);
1153                                 else
1154                                         relink_walkculled += 0.5;
1155                         }
1156
1157                         // reverse direction
1158                         if (it.wpisbox || it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT) // forbid incoming links
1159                                 || this.SUPPORT_WP) // forbid outgoing links
1160                         {
1161                                 relink_walkculled += 0.5;
1162                         }
1163                         else
1164                         {
1165                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1166                                         waypoint_addlink(it, this);
1167                                 else
1168                                         relink_walkculled += 0.5;
1169                         }
1170                 }
1171         });
1172         navigation_testtracewalk = 0;
1173         this.wplinked = true;
1174         this.dphitcontentsmask = dphitcontentsmask_save;
1175
1176         setthink(this, func_null);
1177         this.nextthink = 0;
1178 }
1179
1180 void waypoint_clearlinks(entity wp)
1181 {
1182         // clear links to other waypoints
1183         float f = 10000000;
1184         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1185         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1186         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1187         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1188
1189         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1190         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1191         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1192         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1193
1194         wp.wplinked = false;
1195 }
1196
1197 // tell a spawnfunc_waypoint to relink
1198 void waypoint_schedulerelink(entity wp)
1199 {
1200         if (wp == NULL)
1201                 return;
1202
1203         waypoint_setupmodel(wp);
1204         wp.wpisbox = vdist(wp.size, >, 0);
1205         wp.enemy = NULL;
1206         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1207                 wp.owner = NULL;
1208         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
1209                 waypoint_clearlinks(wp);
1210         // schedule an actual relink on next frame
1211         setthink(wp, waypoint_think);
1212         wp.nextthink = time;
1213         wp.effects = EF_LOWPRECISION;
1214 }
1215
1216 // spawnfunc_waypoint map entity
1217 spawnfunc(waypoint)
1218 {
1219         IL_PUSH(g_waypoints, this);
1220
1221         setorigin(this, this.origin);
1222         // schedule a relink after other waypoints have had a chance to spawn
1223         waypoint_clearlinks(this);
1224         //waypoint_schedulerelink(this);
1225 }
1226
1227 // tell all waypoints to relink
1228 // actually this is useful only to update relink_* stats
1229 void waypoint_schedulerelinkall()
1230 {
1231         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1232         IL_EACH(g_waypoints, true,
1233         {
1234                 waypoint_schedulerelink(it);
1235         });
1236         waypoint_load_hardwiredlinks();
1237 }
1238
1239 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1240
1241 // Load waypoint links from file
1242 bool waypoint_load_links()
1243 {
1244         string s;
1245         float file, tokens, c = 0, found;
1246         entity wp_from = NULL, wp_to;
1247         vector wp_to_pos, wp_from_pos;
1248
1249         string gt_ext = GET_GAMETYPE_EXTENSION();
1250
1251         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1252         file = fopen(filename, FILE_READ);
1253
1254         if (gt_ext != "" && file < 0)
1255         {
1256                 // if race waypoint file doesn't exist load the default one
1257                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1258                 file = fopen(filename, FILE_READ);
1259         }
1260
1261         if (file < 0)
1262         {
1263                 LOG_TRACE("waypoint links load from ", filename, " failed");
1264                 waypoint_schedulerelinkall();
1265                 return false;
1266         }
1267
1268         bool parse_comments = true;
1269         float ver = 0;
1270         string links_time = string_null;
1271
1272         while ((s = fgets(file)))
1273         {
1274                 if(parse_comments)
1275                 {
1276                         if(substring(s, 0, 2) == "//")
1277                         {
1278                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1279                                         ver = stof(substring(s, 19, -1));
1280                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1281                                         links_time = substring(s, 16, -1);
1282                                 continue;
1283                         }
1284                         else
1285                         {
1286                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1287                                 {
1288                                         if (links_time != waypoint_time)
1289                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1290                                         else
1291                                                 LOG_TRACE("waypoint links for this map are outdated.");
1292                                         if (g_assault)
1293                                         {
1294                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1295                                         }
1296                                         else
1297                                         {
1298                                                 LOG_TRACE("automatically updating...");
1299                                                 waypoint_schedulerelinkall();
1300                                                 fclose(file);
1301                                                 return false;
1302                                         }
1303                                 }
1304                                 parse_comments = false;
1305                         }
1306                 }
1307
1308                 tokens = tokenizebyseparator(s, "*");
1309
1310                 if (tokens!=2)
1311                 {
1312                         // bad file format
1313                         fclose(file);
1314                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1315                         return false;
1316                 }
1317
1318                 wp_from_pos     = stov(argv(0));
1319                 wp_to_pos       = stov(argv(1));
1320
1321                 // Search "from" waypoint
1322                 if(!wp_from || wp_from.origin!=wp_from_pos)
1323                 {
1324                         wp_from = findradius(wp_from_pos, 1);
1325                         found = false;
1326                         while(wp_from)
1327                         {
1328                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1329                                 if(wp_from.classname == "waypoint")
1330                                 {
1331                                         found = true;
1332                                         break;
1333                                 }
1334                                 wp_from = wp_from.chain;
1335                         }
1336
1337                         if(!found)
1338                         {
1339                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1340                                 continue;
1341                         }
1342                 }
1343
1344                 // Search "to" waypoint
1345                 wp_to = findradius(wp_to_pos, 1);
1346                 found = false;
1347                 while(wp_to)
1348                 {
1349                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1350                         if(wp_to.classname == "waypoint")
1351                         {
1352                                 found = true;
1353                                 break;
1354                         }
1355                         wp_to = wp_to.chain;
1356                 }
1357
1358                 if(!found)
1359                 {
1360                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1361                         continue;
1362                 }
1363
1364                 ++c;
1365                 waypoint_addlink(wp_from, wp_to);
1366                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1367                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1368         }
1369
1370         fclose(file);
1371
1372         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1373
1374         bool scheduled = false;
1375         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1376         {
1377                 if (!it.wp00)
1378                 {
1379                         waypoint_schedulerelink(it);
1380                         scheduled = true;
1381                 }
1382         });
1383         if (scheduled)
1384                 return false;
1385
1386         botframe_cachedwaypointlinks = true;
1387         return true;
1388 }
1389
1390 void waypoint_load_hardwiredlinks()
1391 {
1392         string s;
1393         float file, tokens, c = 0, found;
1394         entity wp_from = NULL, wp_to;
1395         vector wp_to_pos, wp_from_pos;
1396
1397         string gt_ext = GET_GAMETYPE_EXTENSION();
1398
1399         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1400         file = fopen(filename, FILE_READ);
1401
1402         if (gt_ext != "" && file < 0)
1403         {
1404                 // if race waypoint file doesn't exist load the default one
1405                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1406                 file = fopen(filename, FILE_READ);
1407         }
1408
1409         botframe_loadedforcedlinks = true;
1410
1411         if (file < 0)
1412         {
1413                 LOG_TRACE("waypoint links load from ", filename, " failed");
1414                 return;
1415         }
1416
1417         bool is_special = false;
1418         while ((s = fgets(file)))
1419         {
1420                 if(substring(s, 0, 2)=="//")
1421                         continue;
1422
1423                 if(substring(s, 0, 1)=="#")
1424                         continue;
1425
1426                 // special links start with *, so old xonotic versions don't load them
1427                 is_special = false;
1428                 if (substring(s, 0, 1) == "*")
1429                 {
1430                         is_special = true;
1431                         s = substring(s, 1, -1);
1432                 }
1433
1434                 tokens = tokenizebyseparator(s, "*");
1435
1436                 if (tokens!=2)
1437                         continue;
1438
1439                 wp_from_pos     = stov(argv(0));
1440                 wp_to_pos       = stov(argv(1));
1441
1442                 // Search "from" waypoint
1443                 if(!wp_from || wp_from.origin!=wp_from_pos)
1444                 {
1445                         wp_from = findradius(wp_from_pos, 5);
1446                         found = false;
1447                         while(wp_from)
1448                         {
1449                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1450                                 if(wp_from.classname == "waypoint")
1451                                 {
1452                                         found = true;
1453                                         break;
1454                                 }
1455                                 wp_from = wp_from.chain;
1456                         }
1457
1458                         if(!found)
1459                         {
1460                                 LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1461                                 continue;
1462                         }
1463                 }
1464
1465                 // Search "to" waypoint
1466                 wp_to = findradius(wp_to_pos, 5);
1467                 found = false;
1468                 while(wp_to)
1469                 {
1470                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1471                         if(wp_to.classname == "waypoint")
1472                         {
1473                                 found = true;
1474                                 break;
1475                         }
1476                         wp_to = wp_to.chain;
1477                 }
1478
1479                 if(!found)
1480                 {
1481                         LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1482                         continue;
1483                 }
1484
1485                 ++c;
1486
1487                 if (!is_special)
1488                 {
1489                         waypoint_addlink(wp_from, wp_to);
1490                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1491                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1492                         && (wp_from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)
1493                                 || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1494                 {
1495                         waypoint_addlink(wp_from, wp_to);
1496                 }
1497         }
1498
1499         fclose(file);
1500
1501         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1502 }
1503
1504 entity waypoint_get_link(entity w, float i)
1505 {
1506         switch(i)
1507         {
1508                 case  0:return w.wp00;
1509                 case  1:return w.wp01;
1510                 case  2:return w.wp02;
1511                 case  3:return w.wp03;
1512                 case  4:return w.wp04;
1513                 case  5:return w.wp05;
1514                 case  6:return w.wp06;
1515                 case  7:return w.wp07;
1516                 case  8:return w.wp08;
1517                 case  9:return w.wp09;
1518                 case 10:return w.wp10;
1519                 case 11:return w.wp11;
1520                 case 12:return w.wp12;
1521                 case 13:return w.wp13;
1522                 case 14:return w.wp14;
1523                 case 15:return w.wp15;
1524                 case 16:return w.wp16;
1525                 case 17:return w.wp17;
1526                 case 18:return w.wp18;
1527                 case 19:return w.wp19;
1528                 case 20:return w.wp20;
1529                 case 21:return w.wp21;
1530                 case 22:return w.wp22;
1531                 case 23:return w.wp23;
1532                 case 24:return w.wp24;
1533                 case 25:return w.wp25;
1534                 case 26:return w.wp26;
1535                 case 27:return w.wp27;
1536                 case 28:return w.wp28;
1537                 case 29:return w.wp29;
1538                 case 30:return w.wp30;
1539                 case 31:return w.wp31;
1540                 default:return NULL;
1541         }
1542 }
1543
1544 // Save all hardwired waypoint links to a file
1545 void waypoint_save_hardwiredlinks()
1546 {
1547         string gt_ext = GET_GAMETYPE_EXTENSION();
1548
1549         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1550         int file = fopen(filename, FILE_WRITE);
1551         if (file < 0)
1552         {
1553                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1554                 return;
1555         }
1556
1557         // write hardwired links to file
1558         int count = 0;
1559         fputs(file, "// HARDWIRED LINKS\n");
1560         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1561         {
1562                 for (int j = 0; j < 32; ++j)
1563                 {
1564                         entity link = waypoint_get_link(it, j);
1565                         if (waypoint_is_hardwiredlink(it, link))
1566                         {
1567                                 // NOTE: vtos rounds vector components to 1 decimal place
1568                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1569                                 fputs(file, s);
1570                                 ++count;
1571                         }
1572                 }
1573         });
1574
1575         // write special links to file
1576         int count2 = 0;
1577         fputs(file, "\n// SPECIAL LINKS\n");
1578         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP),
1579         {
1580                 for (int j = 0; j < 32; ++j)
1581                 {
1582                         entity link = waypoint_get_link(it, j);
1583                         if (link)
1584                         {
1585                                 // NOTE: vtos rounds vector components to 1 decimal place
1586                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1587                                 fputs(file, s);
1588                                 ++count2;
1589                         }
1590                 }
1591         });
1592
1593         fclose(file);
1594
1595         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1596 }
1597
1598 // Save all waypoint links to a file
1599 void waypoint_save_links()
1600 {
1601         string gt_ext = GET_GAMETYPE_EXTENSION();
1602
1603         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1604         int file = fopen(filename, FILE_WRITE);
1605         if (file < 0)
1606         {
1607                 LOG_INFOF("waypoint link save to %s failed", filename);
1608                 return;
1609         }
1610
1611         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1612         if (waypoint_time != "")
1613                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1614
1615         int c = 0;
1616         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)),
1617         {
1618                 for(int j = 0; j < 32; ++j)
1619                 {
1620                         entity link = waypoint_get_link(it, j);
1621                         if (link && !waypoint_is_hardwiredlink(it, link))
1622                         {
1623                                 // NOTE: vtos rounds vector components to 1 decimal place
1624                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1625                                 fputs(file, s);
1626                                 ++c;
1627                         }
1628                 }
1629         });
1630         fclose(file);
1631
1632         botframe_cachedwaypointlinks = true;
1633
1634         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1635 }
1636
1637 // save waypoints to gamedir/data/maps/mapname.waypoints
1638 void waypoint_saveall()
1639 {
1640         if (WAYPOINT_VERSION < waypoint_version_loaded)
1641         {
1642                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1643                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1644                 return;
1645         }
1646         string gt_ext = GET_GAMETYPE_EXTENSION();
1647
1648         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1649         int file = fopen(filename, FILE_WRITE);
1650         if (file < 0)
1651         {
1652                 waypoint_save_links(); // save anyway?
1653                 botframe_loadedforcedlinks = false;
1654
1655                 LOG_INFOF("waypoint links: save to %s failed", filename);
1656                 return;
1657         }
1658
1659         float sym = autocvar_g_waypointeditor_symmetrical;
1660         string sym_str = ftos(sym);
1661         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1662         {
1663                 if (sym == 1)
1664                 {
1665                         sym_str = cons(sym_str, "-");
1666                         sym_str = cons(sym_str, "-");
1667                 }
1668                 else
1669                 {
1670                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1671                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1672                 }
1673                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1674                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1675         }
1676         else if (autocvar_g_waypointeditor_symmetrical == -2)
1677         {
1678                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1679                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1680         }
1681
1682         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1683         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1684         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1685         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1686
1687         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1688         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1689         //fputs(file, strcat("//", "\n"));
1690         //fputs(file, strcat("//", "\n"));
1691         //fputs(file, strcat("//", "\n"));
1692
1693         int c = 0;
1694         IL_EACH(g_waypoints, true,
1695         {
1696                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1697                         continue;
1698
1699                 string s;
1700                 // NOTE: vtos rounds vector components to 1 decimal place
1701                 s = strcat(vtos(it.origin + it.mins), "\n");
1702                 s = strcat(s, vtos(it.origin + it.maxs));
1703                 s = strcat(s, "\n");
1704                 s = strcat(s, ftos(it.wpflags));
1705                 s = strcat(s, "\n");
1706                 fputs(file, s);
1707                 c++;
1708         });
1709         fclose(file);
1710         waypoint_save_links();
1711         waypoint_save_hardwiredlinks();
1712
1713         botframe_loadedforcedlinks = false;
1714
1715         waypoint_version_loaded = WAYPOINT_VERSION;
1716         LOG_INFOF("saved %d waypoints to %s", c, filename);
1717 }
1718
1719 // load waypoints from file
1720 float waypoint_loadall()
1721 {
1722         string s;
1723         float file, cwp, cwb, fl;
1724         vector m1, m2;
1725         cwp = 0;
1726         cwb = 0;
1727
1728         string gt_ext = GET_GAMETYPE_EXTENSION();
1729
1730         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1731         file = fopen(filename, FILE_READ);
1732
1733         if (gt_ext != "" && file < 0)
1734         {
1735                 // if race waypoint file doesn't exist load the default one
1736                 filename = sprintf("maps/%s.waypoints", mapname);
1737                 file = fopen(filename, FILE_READ);
1738         }
1739
1740         if (file < 0)
1741         {
1742                 LOG_TRACE("waypoint load from ", filename, " failed");
1743                 return 0;
1744         }
1745
1746         bool parse_comments = true;
1747         float ver = 0;
1748         float sym = 0;
1749         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1750
1751         while ((s = fgets(file)))
1752         {
1753                 if(parse_comments)
1754                 {
1755                         if(substring(s, 0, 2) == "//")
1756                         {
1757                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1758                                         ver = stof(substring(s, 19, -1));
1759                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1760                                 {
1761                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1762                                         if (tokens) { sym = stof(argv(0)); }
1763                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1764                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1765                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1766                                 }
1767                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1768                                         strcpy(waypoint_time, substring(s, 16, -1));
1769                                 continue;
1770                         }
1771                         else
1772                         {
1773                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1774                                 {
1775                                         LOG_TRACE("waypoints for this map are outdated");
1776                                         LOG_TRACE("please update them in the editor");
1777                                 }
1778                                 parse_comments = false;
1779                         }
1780                 }
1781                 m1 = stov(s);
1782                 s = fgets(file);
1783                 if (!s)
1784                         break;
1785                 m2 = stov(s);
1786                 s = fgets(file);
1787                 if (!s)
1788                         break;
1789                 fl = stof(s);
1790                 waypoint_spawn(m1, m2, fl);
1791                 if (m1 == m2)
1792                         cwp = cwp + 1;
1793                 else
1794                         cwb = cwb + 1;
1795         }
1796         fclose(file);
1797         waypoint_version_loaded = ver;
1798         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1799
1800         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1801         {
1802                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1803                 if (sym == 1 && sym_param3 < 2)
1804                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1805                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1806                 {
1807                         string params;
1808                         if (sym == 1)
1809                                 params = cons("-", "-");
1810                         else
1811                         {
1812                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1813                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1814                         }
1815                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1816                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1817                 }
1818                 else if (sym == -2)
1819                 {
1820                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1821                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1822                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1823                 }
1824                 else
1825                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1826                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1827         }
1828
1829         if (WAYPOINT_VERSION < waypoint_version_loaded)
1830                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1831                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1832
1833         return cwp + cwb;
1834 }
1835
1836 #define waypoint_fixorigin(position, tracetest_ent) \
1837         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1838
1839 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1840 {
1841         vector endpos = position + down_dir * 3000;
1842         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1843         if(trace_startsolid)
1844                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1845         if(trace_startsolid)
1846                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1847         if(trace_fraction < 1)
1848                 position = trace_endpos;
1849         return position;
1850 }
1851
1852 void waypoint_spawnforitem_force(entity e, vector org)
1853 {
1854         // Fix the waypoint altitude if necessary
1855         org = waypoint_fixorigin(org, NULL);
1856
1857         // don't spawn an item spawnfunc_waypoint if it already exists
1858         IL_EACH(g_waypoints, true,
1859         {
1860                 if(it.wpisbox)
1861                 {
1862                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1863                         {
1864                                 e.nearestwaypoint = it;
1865                                 return;
1866                         }
1867                 }
1868                 else
1869                 {
1870                         if(vdist(it.origin - org, <, 16))
1871                         {
1872                                 e.nearestwaypoint = it;
1873                                 return;
1874                         }
1875                 }
1876         });
1877
1878         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1879 }
1880
1881 void waypoint_spawnforitem(entity e)
1882 {
1883         if(!bot_waypoints_for_items)
1884                 return;
1885
1886         waypoint_spawnforitem_force(e, e.origin);
1887 }
1888
1889 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1890 {
1891         entity w;
1892         entity dw;
1893         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1894         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1895         // one way link to the destination
1896         w.wp00_original = dw;
1897         w.wp00 = dw;
1898         w.wp00mincost = timetaken; // this is just for jump pads
1899         // the teleporter's nearest spawnfunc_waypoint is this one
1900         // (teleporters are not goals, so this is probably useless)
1901         e.nearestwaypoint = w;
1902         e.nearestwaypointtimeout = -1;
1903 }
1904
1905 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1906 {
1907         float src_angle = e.warpzone_angles.x;
1908         while (src_angle < -180) src_angle += 360;
1909         while (src_angle > 180) src_angle -= 360;
1910
1911         float dest_angle = e.enemy.warpzone_angles.x;
1912         while (dest_angle < -180) dest_angle += 360;
1913         while (dest_angle > 180) dest_angle -= 360;
1914
1915         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1916         if (src_angle == -90 || dest_angle == -90)
1917                 return;
1918
1919         makevectors(e.warpzone_angles);
1920         vector src = (e.absmin + e.absmax) * 0.5;
1921         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1922         vector down_dir_src = -v_up;
1923
1924         makevectors(e.enemy.warpzone_angles);
1925         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1926         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1927         vector down_dir_dest = -v_up;
1928
1929         int extra_flag = 0;
1930         // don't snap to the ground waypoints for source warpzones pointing downwards
1931         if (src_angle != 90)
1932         {
1933                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1934                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1935                 // oblique warpzones need a jump otherwise bots gets stuck
1936                 if (src_angle != 0)
1937                         extra_flag = WAYPOINTFLAG_JUMP;
1938         }
1939
1940         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1941 }
1942
1943 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1944 {
1945         destination = waypoint_fixorigin(destination, tracetest_ent);
1946         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1947 }
1948
1949 entity waypoint_spawnpersonal(entity this, vector position)
1950 {
1951         entity w;
1952
1953         // drop the waypoint to a proper location:
1954         //   first move it up by a player height
1955         //   then move it down to hit the floor with player bbox size
1956         position = waypoint_fixorigin(position, this);
1957
1958         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1959         w.nearestwaypoint = NULL;
1960         w.nearestwaypointtimeout = 0;
1961         w.owner = this;
1962
1963         waypoint_schedulerelink(w);
1964
1965         return w;
1966 }
1967
1968 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1969 {
1970         if (!(wp1 && wp2))
1971                 return;
1972
1973         if (waypoint_is_hardwiredlink(wp1, wp2) || wp1.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP))
1974                 te_beam(NULL, wp1.origin, wp2.origin);
1975         else if (display_type == 1)
1976                 te_lightning2(NULL, wp1.origin, wp2.origin);
1977 }
1978
1979 void waypoint_showlinks_to(entity wp, int display_type)
1980 {
1981         IL_EACH(g_waypoints, it != wp,
1982         {
1983                 if (waypoint_islinked(it, wp))
1984                         waypoint_showlink(it, wp, display_type);
1985         });
1986 }
1987
1988 void waypoint_showlinks_from(entity wp, int display_type)
1989 {
1990         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
1991         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
1992         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
1993         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
1994         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
1995         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
1996         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
1997         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
1998         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
1999         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
2000         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
2001         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
2002         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
2003         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
2004         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
2005         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
2006 }
2007
2008 void crosshair_trace_waypoints(entity pl)
2009 {
2010         IL_EACH(g_waypoints, true, {
2011                 it.solid = SOLID_BSP;
2012                 if (!it.wpisbox)
2013                         setsize(it, '-16 -16 -16', '16 16 16');
2014         });
2015
2016         crosshair_trace(pl);
2017
2018         IL_EACH(g_waypoints, true, {
2019                 it.solid = SOLID_TRIGGER;
2020                 if (!it.wpisbox)
2021                         setsize(it, '0 0 0', '0 0 0');
2022         });
2023         if (trace_ent.classname != "waypoint")
2024                 trace_ent = NULL;
2025 }
2026
2027 void botframe_showwaypointlinks()
2028 {
2029         if (time < botframe_waypointeditorlightningtime)
2030                 return;
2031         botframe_waypointeditorlightningtime = time + 0.5;
2032         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
2033         {
2034                 int display_type = 0;
2035                 if (wasfreed(it.wp_aimed))
2036                         it.wp_aimed = NULL;
2037                 if (wasfreed(it.wp_locked))
2038                         it.wp_locked = NULL;
2039                 if (PHYS_INPUT_BUTTON_USE(it))
2040                         it.wp_locked = it.wp_aimed;
2041                 entity head = it.wp_locked;
2042                 if (!head)
2043                         head = navigation_findnearestwaypoint(it, false);
2044                 it.nearestwaypoint = head; // mainly useful for debug
2045                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
2046                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
2047                         display_type = 1; // default
2048                 else if(waypoint_has_hardwiredlinks(head))
2049                         display_type = 2; // only hardwired
2050
2051                 if (display_type)
2052                 {
2053                         //navigation_testtracewalk = true;
2054                         //print("currently selected WP is ", etos(head), "\n");
2055                         //navigation_testtracewalk = false;
2056                         if (head)
2057                         {
2058                                 te_lightning2(NULL, head.origin, it.origin);
2059                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2060                                         waypoint_showlinks_to(head, display_type);
2061                                 else
2062                                         waypoint_showlinks_from(head, display_type);
2063                         }
2064                 }
2065                 string str;
2066                 entity wp = NULL;
2067                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2068                 {
2069                         crosshair_trace_waypoints(it);
2070                         if (trace_ent)
2071                         {
2072                                 wp = trace_ent;
2073                                 if (wp != it.wp_aimed)
2074                                 {
2075                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: %s\n", etof(wp), wp.wpflags, vtos(wp.origin));
2076                                         if (wp.wpisbox)
2077                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2078                                         stuffcmd(it, str);
2079                                         str = sprintf("entity: %d\nflags: %d\norigin: %s", etof(wp), wp.wpflags, vtos(wp.origin));
2080                                         if (wp.wpisbox)
2081                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2082                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2083                                 }
2084                         }
2085                 }
2086                 if (it.wp_aimed != wp)
2087                         it.wp_aimed = wp;
2088         });
2089 }
2090
2091 float botframe_autowaypoints_fixdown(vector v)
2092 {
2093         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2094         if(trace_fraction >= 1)
2095                 return 0;
2096         return 1;
2097 }
2098
2099 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2100 {
2101         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2102         {
2103                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2104                 return 0;
2105         });
2106
2107         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2108         return 1;
2109 }
2110
2111 // return value:
2112 //    1 = WP created
2113 //    0 = no action needed
2114 //   -1 = temp fail, try from world too
2115 //   -2 = permanent fail, do not retry
2116 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2117 {
2118         // make it possible to go from p to wp, if we can
2119         // if wp is NULL, nearest is chosen
2120
2121         entity w;
2122         vector porg;
2123         float t, tmin, tmax;
2124         vector o;
2125         vector save;
2126
2127         if(!botframe_autowaypoints_fixdown(p.origin))
2128                 return -2;
2129         porg = trace_endpos;
2130
2131         if(wp)
2132         {
2133                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2134
2135                 // if wp -> porg, then OK
2136                 float maxdist;
2137                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2138                 {
2139                         // we may find a better one
2140                         maxdist = vlen(wp.origin - porg);
2141                 }
2142                 else
2143                 {
2144                         // accept any "good"
2145                         maxdist = 2100;
2146                 }
2147
2148                 float bestdist = maxdist;
2149                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
2150                 {
2151                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2152                         if(d < bestdist)
2153                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2154                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2155                         {
2156                                 bestdist = d;
2157                                 p.(fld) = it;
2158                         }
2159                 });
2160                 if(bestdist < maxdist)
2161                 {
2162                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2163                         return 0;
2164                 }
2165
2166                 if(bestdist < 2100)
2167                 {
2168                         // we know maxdist < 2100
2169                         // so wp -> porg is still valid
2170                         // all is good
2171                         p.(fld) = wp;
2172                         return 0;
2173                 }
2174
2175                 // otherwise, no existing WP can fix our issues
2176         }
2177         else
2178         {
2179                 save = p.origin;
2180                 setorigin(p, porg);
2181                 w = navigation_findnearestwaypoint(p, walkfromwp);
2182                 setorigin(p, save);
2183                 if(w)
2184                 {
2185                         p.(fld) = w;
2186                         return 0;
2187                 }
2188         }
2189
2190         tmin = 0;
2191         tmax = 1;
2192         for (;;)
2193         {
2194                 if(tmax - tmin < 0.001)
2195                 {
2196                         // did not get a good candidate
2197                         return -1;
2198                 }
2199
2200                 t = (tmin + tmax) * 0.5;
2201                 o = antilag_takebackorigin(p, CS(p), time - t);
2202                 if(!botframe_autowaypoints_fixdown(o))
2203                         return -2;
2204                 o = trace_endpos;
2205
2206                 if(wp)
2207                 {
2208                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2209                         {
2210                                 // we cannot walk from wp.origin to o
2211                                 // get closer to tmax
2212                                 tmin = t;
2213                                 continue;
2214                         }
2215                 }
2216                 else
2217                 {
2218                         save = p.origin;
2219                         setorigin(p, o);
2220                         w = navigation_findnearestwaypoint(p, walkfromwp);
2221                         setorigin(p, save);
2222                         if(!w)
2223                         {
2224                                 // we cannot walk from any WP to o
2225                                 // get closer to tmax
2226                                 tmin = t;
2227                                 continue;
2228                         }
2229                 }
2230
2231                 // if we get here, o is valid regarding waypoints
2232                 // check if o is connected right to the player
2233                 // we break if it succeeds, as that means o is a good waypoint location
2234                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2235                         break;
2236
2237                 // o is no good, we need to get closer to the player
2238                 tmax = t;
2239         }
2240
2241         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2242         botframe_autowaypoints_createwp(o, p, fld, 0);
2243         return 1;
2244 }
2245
2246 // automatically create missing waypoints
2247 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2248 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2249 {
2250         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2251         if(r != -1)
2252                 return;
2253         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2254         if(r != -1)
2255                 return;
2256
2257         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2258         if(!botframe_autowaypoints_fixdown(p.origin))
2259                 return; // shouldn't happen, caught above
2260         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2261 }
2262
2263 void botframe_deleteuselesswaypoints()
2264 {
2265         IL_EACH(g_items, it.bot_pickup,
2266         {
2267                 // NOTE: this protects waypoints if they're the ONLY nearest
2268                 // waypoint. That's the intention.
2269                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2270                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2271         });
2272         IL_EACH(g_waypoints, true,
2273         {
2274                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2275                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2276                 // WP is useful if:
2277                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2278                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2279                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2280                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2281                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2282                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2283                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2284                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2285                 // b) WP is closest WP for an item/spawnpoint/other entity
2286                 //    This has been done above by protecting these WPs.
2287         });
2288         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2289         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2290         {
2291                 for (int m = 0; m < 32; ++m)
2292                 {
2293                         entity w = waypoint_get_link(it, m);
2294                         if (!w)
2295                                 break;
2296                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2297                                 continue;
2298                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2299                                 continue;
2300                         for (int j = 0; j < 32; ++j)
2301                         {
2302                                 entity w2 = waypoint_get_link(w, j);
2303                                 if (!w2)
2304                                         break;
2305                                 if (it == w2)
2306                                         continue;
2307                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2308                                         continue;
2309                                 // If we got here, it != w2 exist with it -> w
2310                                 // and w -> w2. That means the waypoint is not
2311                                 // a dead end.
2312                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2313                                 for (int k = 0; k < 32; ++k)
2314                                 {
2315                                         if (waypoint_get_link(it, k) == w2)
2316                                                 continue;
2317                                         // IF WE GET HERE, w is proven useful
2318                                         // to get from it to w2!
2319                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2320                                         goto next;
2321                                 }
2322                         }
2323 LABEL(next)
2324                 }
2325         });
2326         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2327         //     they are needed to complete routes while autowaypointing.
2328
2329         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2330         {
2331                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2332                 te_explosion(it.origin);
2333                 waypoint_remove(it);
2334                 break;
2335         });
2336
2337         IL_EACH(g_waypoints, true,
2338         {
2339                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2340         });
2341 }
2342
2343 void botframe_autowaypoints()
2344 {
2345         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2346                 // going back is broken, so only fix waypoints to walk TO the player
2347                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2348                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2349                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2350         });
2351
2352         if (autocvar_g_waypointeditor_auto >= 2) {
2353                 botframe_deleteuselesswaypoints();
2354         }
2355 }
2356