qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float gamestart_sv_cheats;
  18
  19 #define CHIMPULSE_SPEEDRUN_INIT 30
  20 #define CHIMPULSE_GIVE_ALL 99
  21 #define CHIMPULSE_CLONE_MOVING 140
  22 #define CHIMPULSE_SPEEDRUN 141
  23 #define CHIMPULSE_CLONE_STANDING 142
  24 #define CHIMPULSE_TELEPORT 143
  25 #define CHIMPULSE_R00T 148
  26
  27 #define CHRAME_DRAG 8
  28
  29 void CheatInit()
  30 {
  31         gamestart_sv_cheats = autocvar_sv_cheats;
  32 }
  33
  34 void CheatShutdown()
  35 {
  36 }
  37
  38 void CheatInitClient()
  39 {
  40 }
  41
  42 void CheatShutdownClient()
  43 {
  44 }
  45
  46 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  47 {
  48         // dead people cannot cheat
  49         if(self.deadflag != DEAD_NO)
  50                 return 0;
  51         if(self.classname != "player")
  52                 return 0;
  53
  54         // sv_clones
  55         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  56                 if(self.lip < sv_clones)
  57                         return 1;
  58
  59         // haha
  60         if(self.maycheat)
  61                 return 1;
  62
  63         // sv_cheats
  64         if(gamestart_sv_cheats && autocvar_sv_cheats)
  65                 return 1;
  66
  67         // if we get here, player is not allowed to cheat. Log it.
  68         if(i)
  69                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  70         else if(argc)
  71                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  72         else if(fr)
  73                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  74         else
  75                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  76
  77         return 0;
  78 }
  79
  80 #define BEGIN_CHEAT_FUNCTION() \
  81         float cheating, attempting; \
  82         cheating = 0; attempting = 0
  83 #define DID_CHEAT() \
  84         ++cheating
  85 #define ADD_CHEATS(e,n) \
  86         cheatcount_total += n; \
  87         e.cheatcount += n
  88 #define END_CHEAT_FUNCTION() \
  89         ADD_CHEATS(self,cheating); \
  90         return attempting
  91 #define IS_CHEAT(i,argc,fr) \
  92         if((++attempting, !CheatsAllowed(i,argc,fr))) \
  93                 break
  94
  95 float num_autoscreenshot;
  96 void info_autoscreenshot_findtarget()
  97 {
  98         entity e;
  99         e = find(world, targetname, self.target);
 100         if(!e)
 101         {
 102                 objerror("Missing target. FAIL!");
 103                 return;
 104         }
 105         vector a = vectoangles(e.origin - self.origin);
 106         a_x = -a_x; // don't ask
 107         self.angles_x = a_x;
 108         self.angles_y = a_y;
 109         // we leave Rick Roll alone
 110 }
 111 void spawnfunc_info_autoscreenshot()
 112 {
 113         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 114         {
 115                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 116                 return;
 117         }
 118         if(self.target != "")
 119                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 120         // this one just has to exist
 121 }
 122
 123 float CheatImpulse(float i)
 124 {
 125         BEGIN_CHEAT_FUNCTION();
 126         switch(i)
 127         {
 128                 entity e, e2;
 129                 vector org;
 130
 131                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 132                         // shared with regular waypoint init, so this is not a cheat by itself
 133                         if(!self.personal)
 134                         {
 135                                 self.personal = spawn();
 136                                 self.personal.classname = "personal_wp";
 137                         }
 138                         self.personal.origin = self.origin;
 139                         self.personal.v_angle = self.v_angle;
 140                         self.personal.velocity = self.velocity;
 141                         self.personal.ammo_rockets = self.ammo_rockets;
 142                         self.personal.ammo_nails = self.ammo_nails;
 143                         self.personal.ammo_cells = self.ammo_cells;
 144                         self.personal.ammo_shells = self.ammo_shells;
 145                         self.personal.ammo_fuel = self.ammo_fuel;
 146                         self.personal.health = self.health;
 147                         self.personal.armorvalue = self.armorvalue;
 148                         WEPSET_COPY_EE(self.personal, self);
 149                         self.personal.items = self.items;
 150                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 151                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 152                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 153                         self.personal.pauseregen_finished = self.pauseregen_finished;
 154                         self.personal.strength_finished = self.strength_finished;
 155                         self.personal.invincible_finished = self.invincible_finished;
 156                         self.personal.teleport_time = time;
 157                         break; // this part itself doesn't cheat, so let's not count this
 158                 case CHIMPULSE_CLONE_MOVING:
 159                         IS_CHEAT(i, 0, 0);
 160                         makevectors (self.v_angle);
 161                         self.velocity = self.velocity + v_forward * 300;
 162                         CopyBody(1);
 163                         self.lip += 1;
 164                         self.velocity = self.velocity - v_forward * 300;
 165                         DID_CHEAT();
 166                         break;
 167                 case CHIMPULSE_CLONE_STANDING:
 168                         IS_CHEAT(i, 0, 0);
 169                         CopyBody(0);
 170                         self.lip += 1;
 171                         DID_CHEAT();
 172                         break;
 173                 case CHIMPULSE_GIVE_ALL:
 174                         IS_CHEAT(i, 0, 0);
 175                         CheatCommand(tokenize_console("give all"));
 176                         break; // already counted as cheat
 177                 case CHIMPULSE_SPEEDRUN:
 178                         IS_CHEAT(i, 0, 0);
 179                         if(self.personal)
 180                         {
 181                                 self.speedrunning = TRUE;
 182                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 183                                 if(trace_startsolid)
 184                                 {
 185                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 186                                 }
 187                                 else
 188                                 {
 189                                         // Abort speedrun, teleport back
 190                                         setorigin(self, self.personal.origin);
 191                                         self.oldvelocity = self.velocity = self.personal.velocity;
 192                                         self.angles = self.personal.v_angle;
 193                                         self.fixangle = TRUE;
 194
 195                                         MUTATOR_CALLHOOK(AbortSpeedrun);
 196                                 }
 197
 198                                 self.ammo_rockets = self.personal.ammo_rockets;
 199                                 self.ammo_nails = self.personal.ammo_nails;
 200                                 self.ammo_cells = self.personal.ammo_cells;
 201                                 self.ammo_shells = self.personal.ammo_shells;
 202                                 self.ammo_fuel = self.personal.ammo_fuel;
 203                                 self.health = self.personal.health;
 204                                 self.armorvalue = self.personal.armorvalue;
 205                                 WEPSET_COPY_EE(self, self.personal);
 206                                 self.items = self.personal.items;
 207                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 208                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 209                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 210                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 211                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 212                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 213
 214                                 DID_CHEAT();
 215                                 break;
 216                         }
 217                         if(self.deadflag != DEAD_NO)
 218                                 sprint(self, "UR DEAD AHAHAH))\n");
 219                         else
 220                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 221                         break;
 222                 case CHIMPULSE_TELEPORT:
 223                         IS_CHEAT(i, 0, 0);
 224                         if(self.movetype == MOVETYPE_NOCLIP)
 225                         {
 226                                 e = find(world, classname, "info_autoscreenshot");
 227                                 if(e)
 228                                 {
 229                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 230                                         setorigin(self, e.origin);
 231                                         self.angles = e.angles;
 232                                         remove(e);
 233                                         // should we? self.angles_x = -self.angles_x;
 234                                         self.fixangle = TRUE;
 235                                         self.velocity = '0 0 0';
 236                                         DID_CHEAT();
 237                                         break;
 238                                 }
 239                         }
 240                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 241                         {
 242                                 sprint(self, "Emergency teleport used random location\n");
 243                                 self.angles_x = -self.angles_x;
 244                                 self.fixangle = TRUE;
 245                                 self.velocity = '0 0 0';
 246                                 DID_CHEAT();
 247                                 break;
 248                         }
 249                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 250                         break;
 251                 case CHIMPULSE_R00T:
 252                         IS_CHEAT(i, 0, 0);
 253                         FOR_EACH_PLAYER(e)
 254                         {
 255                                 get_model_parameters(e.playermodel, e.skin);
 256                                 if(get_model_parameters_sex == "Female")
 257                                 {
 258                                         makevectors(e.angles);
 259                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 260                                 }
 261                                 else
 262                                 {
 263                                         org_x = random();
 264                                         org_y = random();
 265                                         org_z = 0;
 266                                         org = normalize(org);
 267                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 268                                 }
 269
 270                                 org = findbetterlocation(trace_endpos, 12);
 271
 272                                 e2 = spawn();
 273                                 setorigin(e2, org);
 274                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 275                                 sound(e2, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 276                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 277                                 remove(e2);
 278                         }
 279                         print("404 Sportsmanship not found.\n");
 280                         DID_CHEAT();
 281                         break;
 282         }
 283
 284         END_CHEAT_FUNCTION();
 285 }
 286
 287 void DragBox_Think();
 288 float drag_lastcnt;
 289 float CheatCommand(float argc)
 290 {
 291         BEGIN_CHEAT_FUNCTION();
 292         string cmd;
 293         cmd = argv(0);
 294         switch(cmd)
 295         {
 296                 entity e;
 297                 float effectnum, f;
 298                 vector start, end;
 299                 entity oldself;
 300
 301                 case "pointparticles":
 302                         IS_CHEAT(0, argc, 0);
 303                         if(argc == 5)
 304                         {
 305                                 // arguments:
 306                                 //   effectname
 307                                 //   origin (0..1, on crosshair line)
 308                                 //   velocity
 309                                 //   howmany
 310                                 effectnum = particleeffectnum(argv(1));
 311                                 f = stof(argv(2));
 312                                 crosshair_trace(self);
 313                                 start = (1-f) * self.origin + f * trace_endpos;
 314                                 end = stov(argv(3));
 315                                 f = stof(argv(4));
 316                                 pointparticles(effectnum, start, end, f);
 317                                 DID_CHEAT();
 318                                 break;
 319                         }
 320                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 321                         break;
 322                 case "trailparticles":
 323                         IS_CHEAT(0, argc, 0);
 324                         if(argc == 2)
 325                         {
 326                                 // arguments:
 327                                 //   effectname
 328                                 effectnum = particleeffectnum(argv(1));
 329                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 330                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 331                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 332                                 DID_CHEAT();
 333                                 break;
 334                         }
 335                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 336                         break;
 337                 case "make":
 338                         IS_CHEAT(0, argc, 0);
 339                         if(argc == 3)
 340                         {
 341                                 // arguments:
 342                                 //   modelname mode
 343                                 f = stof(argv(2));
 344                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 345                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 346                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 347                                 {
 348                                         sprint(self, "cannot make stuff there (bad surface)\n");
 349                                 }
 350                                 else
 351                                 {
 352                                         e = spawn();
 353                                         e.model = strzone(argv(1));
 354                                         e.mdl = "rocket_explode";
 355                                         e.health = 1000;
 356                                         setorigin(e, trace_endpos);
 357                                         e.effects = EF_NOMODELFLAGS;
 358                                         if(f == 1)
 359                                         {
 360                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 361                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 362                                         }
 363                                         oldself = self;
 364                                         self = e;
 365                                         spawnfunc_func_breakable();
 366                                         self = oldself;
 367                                         // now, is it valid?
 368                                         if(f == 0)
 369                                         {
 370                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 371                                                 if(trace_startsolid)
 372                                                 {
 373                                                         remove(e);
 374                                                         sprint(self, "cannot make stuff there (no space)\n");
 375                                                 }
 376                                                 else
 377                                                         DID_CHEAT();
 378                                         }
 379                                         else
 380                                                 DID_CHEAT();
 381                                 }
 382                         }
 383                         else
 384                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 385                         break;
 386                 case "penalty":
 387                         IS_CHEAT(0, argc, 0);
 388                         if(argc == 3)
 389                         {
 390                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 391                                 DID_CHEAT();
 392                                 break;
 393                         }
 394                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 395                         break;
 396                 case "dragbox_spawn":
 397                         IS_CHEAT(0, argc, 0);
 398                         e = spawn();
 399                         e.classname = "dragbox_box";
 400                         e.think = DragBox_Think;
 401                         e.nextthink = time;
 402                         e.solid = -1; // black
 403                         setmodel(e, "null"); // network it
 404                         if(argc == 4)
 405                                 e.cnt = stof(argv(1));
 406                         else
 407                                 e.cnt = max(0, drag_lastcnt);
 408
 409                         e.aiment = spawn();
 410                         e.aiment.classname = "dragbox_corner_1";
 411                         e.aiment.owner = e;
 412                         setmodel(e.aiment, "models/marker.md3");
 413                         e.aiment.skin = 0;
 414                         setsize(e.aiment, '0 0 0', '0 0 0');
 415                         if(argc == 4)
 416                                 setorigin(e.aiment, stov(argv(2)));
 417                         else
 418                         {
 419                                 crosshair_trace(self);
 420                                 setorigin(e.aiment, trace_endpos);
 421                         }
 422
 423                         e.enemy = spawn();
 424                         e.enemy.classname = "dragbox_corner_2";
 425                         e.enemy.owner = e;
 426                         setmodel(e.enemy, "models/marker.md3");
 427                         e.enemy.skin = 1;
 428                         setsize(e.enemy, '0 0 0', '0 0 0');
 429                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 430                         end_x = (end_x > 0) * 2 - 1;
 431                         end_y = (end_y > 0) * 2 - 1;
 432                         end_z = (end_z > 0) * 2 - 1;
 433                         if(argc == 4)
 434                                 setorigin(e.enemy, stov(argv(3)));
 435                         else
 436                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 437
 438                         e.killindicator = spawn();
 439                         e.killindicator.classname = "drag_digit";
 440                         e.killindicator.owner = e;
 441                         setattachment(e.killindicator, e, "");
 442                         setorigin(e.killindicator, '0 0 -8');
 443                         e.killindicator.killindicator = spawn();
 444                         e.killindicator.killindicator.classname = "drag_digit";
 445                         e.killindicator.killindicator.owner = e;
 446                         setattachment(e.killindicator.killindicator, e, "");
 447                         setorigin(e.killindicator.killindicator, '0 0 8');
 448                         DID_CHEAT();
 449                         break;
 450                 case "dragpoint_spawn":
 451                         IS_CHEAT(0, argc, 0);
 452                         e = spawn();
 453                         e.classname = "dragpoint";
 454                         e.think = DragBox_Think;
 455                         e.nextthink = time;
 456                         e.solid = 0; // nothing special
 457                         setmodel(e, "models/marker.md3");
 458                         setsize(e, PL_MIN, PL_MAX);
 459                         e.skin = 2;
 460                         if(argc == 3)
 461                                 e.cnt = stof(argv(1));
 462                         else
 463                                 e.cnt = drag_lastcnt;
 464                         if(argc == 3)
 465                                 setorigin(e, stov(argv(2)));
 466                         else
 467                         {
 468                                 crosshair_trace(self);
 469                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 470                                 move_out_of_solid(e);
 471                         }
 472
 473                         e.killindicator = spawn();
 474                         e.killindicator.classname = "drag_digit";
 475                         e.killindicator.owner = e;
 476                         setattachment(e.killindicator, e, "");
 477                         setorigin(e.killindicator, '0 0 40');
 478                         e.killindicator.killindicator = spawn();
 479                         e.killindicator.killindicator.classname = "drag_digit";
 480                         e.killindicator.killindicator.owner = e;
 481                         setattachment(e.killindicator.killindicator, e, "");
 482                         setorigin(e.killindicator.killindicator, '0 0 56');
 483                         DID_CHEAT();
 484                         break;
 485                 case "drag_remove":
 486                         IS_CHEAT(0, argc, 0);
 487                         RandomSelection_Init();
 488                         crosshair_trace(self);
 489                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 490                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 491                         for(e = world; (e = find(e, classname, "dragpoint")); )
 492                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 493                         if(RandomSelection_chosen_ent)
 494                         {
 495                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 496                                 remove(RandomSelection_chosen_ent.killindicator);
 497                                 if(RandomSelection_chosen_ent.aiment)
 498                                         remove(RandomSelection_chosen_ent.aiment);
 499                                 if(RandomSelection_chosen_ent.enemy)
 500                                         remove(RandomSelection_chosen_ent.enemy);
 501                                 remove(RandomSelection_chosen_ent);
 502                         }
 503                         DID_CHEAT();
 504                         break;
 505                 case "drag_setcnt":
 506                         IS_CHEAT(0, argc, 0);
 507                         if(argc == 2)
 508                         {
 509                                 RandomSelection_Init();
 510                                 crosshair_trace(self);
 511                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 512                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 513                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 514                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 515                                 if(RandomSelection_chosen_ent)
 516                                 {
 517                                         if(substring(argv(1), 0, 1) == "*")
 518                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 519                                         else
 520                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 521                                 }
 522                                 DID_CHEAT();
 523                                 break;
 524                         }
 525                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 526                         break;
 527                 case "drag_save":
 528                         IS_CHEAT(0, argc, 0);
 529                         if(argc == 2)
 530                         {
 531                                 f = fopen(argv(1), FILE_WRITE);
 532                                 fputs(f, "cmd drag_clear\n");
 533                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 534                                 {
 535                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 536                                 }
 537                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 538                                 {
 539                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 540                                 }
 541                                 fclose(f);
 542                                 DID_CHEAT();
 543                                 break;
 544                         }
 545                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 546                         break;
 547                 case "drag_saveraceent":
 548                         IS_CHEAT(0, argc, 0);
 549                         if(argc == 2)
 550                         {
 551                                 f = fopen(argv(1), FILE_WRITE);
 552                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 553                                 {
 554                                         fputs(f, "{\n");
 555                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 556                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 557                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 558                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 559                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 560                                         fputs(f, "}\n");
 561                                 }
 562                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 563                                 {
 564                                         start = '0 0 0';
 565                                         effectnum = 0;
 566                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 567                                         {
 568                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 569                                                 {
 570                                                         start = start + oldself.origin;
 571                                                         ++effectnum;
 572                                                 }
 573                                         }
 574                                         start *= 1 / effectnum;
 575                                         fputs(f, "{\n");
 576                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 577                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 578                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 579                                         if(e.cnt == -2)
 580                                         {
 581                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 582                                                 fputs(f, "\"race_place\" \"0\"\n");
 583                                         }
 584                                         else if(e.cnt == -1)
 585                                         {
 586                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 587                                                 fputs(f, "\"race_place\" \"-1\"\n");
 588                                         }
 589                                         else
 590                                         {
 591                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 592                                                 if(e.cnt == 0)
 593                                                 {
 594                                                         // these need race_place
 595                                                         // counting...
 596                                                         effectnum = 1;
 597                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 598                                                         if(oldself.cnt == 0)
 599                                                         {
 600                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 601                                                                         ++effectnum;
 602                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 603                                                                         ++effectnum;
 604                                                         }
 605                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 606                                                 }
 607                                         }
 608                                         fputs(f, "}\n");
 609                                 }
 610                                 fclose(f);
 611                                 DID_CHEAT();
 612                                 break;
 613                         }
 614                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 615                         break;
 616                 case "drag_clear":
 617                         IS_CHEAT(0, argc, 0);
 618                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 619                                 remove(e);
 620                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 621                                 remove(e);
 622                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 623                                 remove(e);
 624                         for(e = world; (e = find(e, classname, "dragpoint")); )
 625                                 remove(e);
 626                         for(e = world; (e = find(e, classname, "drag_digit")); )
 627                                 remove(e);
 628                         DID_CHEAT();
 629                         break;
 630                 case "god":
 631                         IS_CHEAT(0, argc, 0);
 632                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 633                         if(self.flags & FL_GODMODE)
 634                         {
 635                                 sprint(self, "godmode ON\n");
 636                                 DID_CHEAT();
 637                         }
 638                         else
 639                                 sprint(self, "godmode OFF\n");
 640                         break;
 641                 case "notarget":
 642                         IS_CHEAT(0, argc, 0);
 643                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 644                         if(self.flags & FL_NOTARGET)
 645                         {
 646                                 sprint(self, "notarget ON\n");
 647                                 DID_CHEAT();
 648                         }
 649                         else
 650                                 sprint(self, "notarget OFF\n");
 651                         break;
 652                 case "noclip":
 653                         IS_CHEAT(0, argc, 0);
 654                         if(self.movetype != MOVETYPE_NOCLIP)
 655                         {
 656                                 self.movetype = MOVETYPE_NOCLIP;
 657                                 sprint(self, "noclip ON\n");
 658                                 DID_CHEAT();
 659                         }
 660                         else
 661                         {
 662                                 self.movetype = MOVETYPE_WALK;
 663                                 sprint(self, "noclip OFF\n");
 664                         }
 665                         break;
 666                 case "fly":
 667                         IS_CHEAT(0, argc, 0);
 668                         if(self.movetype != MOVETYPE_FLY)
 669                         {
 670                                 self.movetype = MOVETYPE_FLY;
 671                                 sprint(self, "flymode ON\n");
 672                                 DID_CHEAT();
 673                         }
 674                         else
 675                         {
 676                                 self.movetype = MOVETYPE_WALK;
 677                                 sprint(self, "flymode OFF\n");
 678                         }
 679                         break;
 680                 case "give":
 681                         IS_CHEAT(0, argc, 0);
 682                         if(GiveItems(self, 1, argc))
 683                                 DID_CHEAT();
 684                         break;
 685         }
 686
 687         END_CHEAT_FUNCTION();
 688 }
 689
 690 float Drag(entity e, float grab, float ischeat);
 691 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 692 void Drag_Finish(entity dragger);
 693 float Drag_IsDraggable(entity draggee);
 694 float Drag_MayChangeAngles(entity draggee);
 695 void Drag_MoveForward(entity dragger);
 696 void Drag_SetSpeed(entity dragger, float s);
 697 void Drag_MoveBackward(entity dragger);
 698 void Drag_Update(entity dragger);
 699 float Drag_CanDrag(entity dragger);
 700 float Drag_IsDragging(entity dragger);
 701 void Drag_MoveDrag(entity from, entity to);
 702 .entity dragentity;
 703
 704 float CheatFrame()
 705 {
 706         BEGIN_CHEAT_FUNCTION();
 707
 708         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 709         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 710         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 711         // grabbing itself no longer being accounted as cheating.
 712
 713         switch(0)
 714         {
 715                 default:
 716                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 717                         {
 718                                 // use cheat dragging if cheats are enabled
 719                                 crosshair_trace_plusvisibletriggers(self);
 720                                 Drag(trace_ent, TRUE, TRUE);
 721                         }
 722                         else
 723                         {
 724                                 // drag is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 725                                 // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 726                                 // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 727                                 // it goes out of range while slinging it around.
 728
 729                                 float drag;
 730                                 crosshair_trace_plusvisibletriggers(self);
 731                                 if(vlen(self.origin - trace_ent.origin) <= autocvar_g_grab_range)
 732                                 {
 733                                         switch(trace_ent.grab)
 734                                         {
 735                                                 case 0: // can't grab
 736                                                         break;
 737                                                 case 1: // owner can grab
 738                                                         if(trace_ent.owner == self || trace_ent.realowner == self)
 739                                                                 drag = TRUE;
 740                                                         break;
 741                                                 case 2: // owner and team mates can grab
 742                                                         if(!IsDifferentTeam(trace_ent.owner, self) || !IsDifferentTeam(trace_ent.realowner, self) || trace_ent.team == self.team)
 743                                                                 drag = TRUE;
 744                                                         break;
 745                                                 case 3: // anyone can grab
 746                                                         drag = TRUE;
 747                                                         break;
 748                                                 default:
 749                                                         break;
 750                                         }
 751                                 }
 752                                 Drag(trace_ent, drag, FALSE); // execute dragging
 753                         }
 754                         break;
 755         }
 756
 757         END_CHEAT_FUNCTION();
 758 }
 759
 760
 761
 762
 763
 764 // ENTITY DRAGGING
 765
 766 float Drag(entity e, float pick, float ischeat)
 767 {
 768         BEGIN_CHEAT_FUNCTION();
 769
 770         // returns TRUE when an entity has been picked up
 771         // If pick is TRUE, the object can also be picked up if it's not being held already
 772         // If pick is FALSE, only keep dragging the object if it's already being held
 773
 774         switch(0)
 775         {
 776                 default:
 777                         if(Drag_IsDragging(self))
 778                         {
 779                                 if(self.BUTTON_DRAG)
 780                                 {
 781                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 782                                         {
 783                                                 Drag_MoveForward(self);
 784                                                 self.impulse = 0;
 785                                         }
 786                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 787                                         {
 788                                                 Drag_MoveBackward(self);
 789                                                 self.impulse = 0;
 790                                         }
 791                                         else if(self.impulse >= 1 && self.impulse <= 9)
 792                                         {
 793                                                 Drag_SetSpeed(self, self.impulse - 1);
 794                                         }
 795                                         else if(self.impulse == 14)
 796                                         {
 797                                                 Drag_SetSpeed(self, 9);
 798                                         }
 799
 800                                         if(frametime)
 801                                                 Drag_Update(self);
 802                                 }
 803                                 else
 804                                 {
 805                                         Drag_Finish(self);
 806                                 }
 807                         }
 808                         else
 809                         {
 810                                 if(Drag_CanDrag(self))
 811                                         if(self.BUTTON_DRAG && pick)
 812                                         {
 813                                                 if(e)
 814                                                         if(Drag_IsDraggable(e))
 815                                                         {
 816                                                                 if(ischeat)
 817                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 818                                                                 if(e.draggedby)
 819                                                                         Drag_Finish(e.draggedby);
 820                                                                 if(e.tag_entity)
 821                                                                         detach_sameorigin(e);
 822                                                                 Drag_Begin(self, e, trace_endpos);
 823                                                                 if(ischeat)
 824                                                                         DID_CHEAT();
 825                                                                 return TRUE;
 826                                                         }
 827                                         }
 828                         }
 829                         break;
 830         }
 831         return FALSE;
 832 }
 833
 834 // on dragger:
 835 .float draggravity;
 836 .float dragspeed; // speed of mouse wheel action
 837 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 838 .vector draglocalvector; // local attachment vector of the dragentity
 839 .float draglocalangle;
 840 // on draggee:
 841 .entity draggedby;
 842 .float dragmovetype;
 843 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 844 {
 845         float tagscale;
 846
 847         draggee.dragmovetype = draggee.movetype;
 848         draggee.draggravity = draggee.gravity;
 849         draggee.movetype = MOVETYPE_WALK;
 850         draggee.gravity = 0.00001;
 851         draggee.flags &~= FL_ONGROUND;
 852         draggee.draggedby = dragger;
 853
 854         dragger.dragentity = draggee;
 855
 856         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 857         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 858         touchpoint = touchpoint - gettaginfo(draggee, 0);
 859         tagscale = pow(vlen(v_forward), -2);
 860         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 861         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 862         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 863
 864         dragger.dragspeed = 64;
 865 }
 866
 867 void Drag_Finish(entity dragger)
 868 {
 869         entity draggee;
 870         draggee = dragger.dragentity;
 871         if(dragger)
 872                 dragger.dragentity = world;
 873         draggee.draggedby = world;
 874         draggee.movetype = draggee.dragmovetype;
 875         draggee.gravity = draggee.draggravity;
 876
 877         switch(draggee.movetype)
 878         {
 879                 case MOVETYPE_TOSS:
 880                 case MOVETYPE_WALK:
 881                 case MOVETYPE_STEP:
 882                 case MOVETYPE_FLYMISSILE:
 883                 case MOVETYPE_BOUNCE:
 884                 case MOVETYPE_BOUNCEMISSILE:
 885                 case MOVETYPE_PHYSICS:
 886                         break;
 887                 default:
 888                         draggee.velocity = '0 0 0';
 889                         break;
 890         }
 891
 892         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 893         {
 894                 draggee.velocity = '0 0 0';
 895                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 896         }
 897 }
 898
 899 float Drag_IsDraggable(entity draggee)
 900 {
 901         // TODO add more checks for bad stuff here
 902         if(draggee == world)
 903                 return FALSE;
 904         if(draggee.classname == "func_bobbing")
 905                 return FALSE;
 906         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 907                 return FALSE;
 908         if(draggee.classname == "plat")
 909                 return FALSE;
 910         if(draggee.classname == "func_button")
 911                 return FALSE;
 912 //      if(draggee.model == "")
 913 //              return FALSE;
 914         if(draggee.classname == "spectator")
 915                 return FALSE;
 916         if(draggee.classname == "observer")
 917                 return FALSE;
 918         if(draggee.classname == "exteriorweaponentity")
 919                 return FALSE;
 920         if(draggee.classname == "weaponentity")
 921                 return FALSE;
 922
 923         return TRUE;
 924 }
 925
 926 float Drag_MayChangeAngles(entity draggee)
 927 {
 928         // TODO add more checks for bad stuff here
 929         if(substring(draggee.model, 0, 1) == "*")
 930                 return FALSE;
 931         return TRUE;
 932 }
 933
 934 void Drag_MoveForward(entity dragger)
 935 {
 936         dragger.dragdistance += dragger.dragspeed;
 937 }
 938
 939 void Drag_SetSpeed(entity dragger, float s)
 940 {
 941         dragger.dragspeed = pow(2, s);
 942 }
 943
 944 void Drag_MoveBackward(entity dragger)
 945 {
 946         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 947 }
 948
 949 void Drag_Update(entity dragger)
 950 {
 951         vector curorigin, neworigin, goodvelocity;
 952         float f;
 953         entity draggee;
 954
 955         draggee = dragger.dragentity;
 956         draggee.flags &~= FL_ONGROUND;
 957
 958         curorigin = gettaginfo(draggee, 0);
 959         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 960         makevectors(dragger.v_angle);
 961         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 962         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 963
 964         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 965                 dragger.draglocalangle += 360;
 966         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 967                 dragger.draglocalangle -= 360;
 968
 969         f = min(frametime * 10, 1);
 970         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 971
 972         if(Drag_MayChangeAngles(draggee))
 973                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 974
 975         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 976
 977         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 978 }
 979
 980 float Drag_CanDrag(entity dragger)
 981 {
 982         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 983 }
 984
 985 float Drag_IsDragging(entity dragger)
 986 {
 987         if(!dragger.dragentity)
 988                 return FALSE;
 989         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 990         {
 991                 dragger.dragentity = world;
 992                 return FALSE;
 993         }
 994         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 995         {
 996                 Drag_Finish(dragger);
 997                 return FALSE;
 998         }
 999         return TRUE;
1000 }
1001
1002 void Drag_MoveDrag(entity from, entity to)
1003 {
1004         if(from.draggedby)
1005         {
1006                 to.draggedby = from.draggedby;
1007                 to.draggedby.dragentity = to;
1008                 from.draggedby = world;
1009         }
1010 }
1011
1012 void DragBox_Think()
1013 {
1014         if(self.aiment && self.enemy)
1015         {
1016                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
1017                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
1018                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
1019                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
1020                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
1021                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
1022                 self.mins = -1 * self.maxs;
1023                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1024         }
1025
1026         if(self.cnt == -1) // actually race_place -1
1027         {
1028                 // show "10 10" for qualifying spawns
1029                 setmodel(self.killindicator, "models/sprites/10.spr32");
1030                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1031         }
1032         else if(self.cnt == -2) // actually race_place 0
1033         {
1034                 // show "10 0" for loser spawns
1035                 setmodel(self.killindicator, "models/sprites/10.spr32");
1036                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1037         }
1038         else
1039         {
1040                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
1041                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1042         }
1043
1044         self.nextthink = time;
1045 }
1046
1047 #endif