qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!warmup_stage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         self.weapons = '0 0 0';
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                 {
 301                         defaultmodel = argv(floor(n * self.model_randomizer));
 302                         // However, do NOT randomize if the player-selected model is in the list.
 303                         for (i = 0; i < n; ++i)
 304                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 305                                         defaultmodel = argv(i);
 306                 }
 307
 308                 i = strstrofs(defaultmodel, ":", 0);
 309                 if(i >= 0)
 310                 {
 311                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 312                         defaultmodel = substring(defaultmodel, 0, i);
 313                 }
 314         }
 315
 316         if(defaultmodel != "")
 317         {
 318                 if (defaultmodel != self.model)
 319                 {
 320                         m1 = self.mins;
 321                         m2 = self.maxs;
 322                         setplayermodel (self, defaultmodel);
 323                         setsize (self, m1, m2);
 324                         chmdl = TRUE;
 325                 }
 326
 327                 oldskin = self.skin;
 328                 self.skin = defaultskin;
 329         } else {
 330                 if (self.playermodel != self.model || self.playermodel == "")
 331                 {
 332                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 333                         m1 = self.mins;
 334                         m2 = self.maxs;
 335                         setplayermodel (self, self.playermodel);
 336                         setsize (self, m1, m2);
 337                         chmdl = TRUE;
 338                 }
 339
 340                 oldskin = self.skin;
 341                 self.skin = stof(self.playerskin);
 342         }
 343
 344         if(chmdl || oldskin != self.skin) // model or skin has changed
 345         {
 346                 self.species = player_getspecies(); // update species
 347                 UpdatePlayerSounds(); // update skin sounds
 348         }
 349
 350         if(!teamplay)
 351                 if(strlen(autocvar_sv_defaultplayercolors))
 352                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 353                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 354 }
 355
 356 /*
 357 =============
 358 PutClientInServer
 359
 360 Called when a client spawns in the server
 361 =============
 362 */
 363 void PutClientInServer (void)
 364 {
 365         if(IS_BOT_CLIENT(self))
 366                 self.classname = "player";
 367         else if(IS_REAL_CLIENT(self))
 368         {
 369                 msg_entity = self;
 370                 WriteByte(MSG_ONE, SVC_SETVIEW);
 371                 WriteEntity(MSG_ONE, self);
 372         }
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 race_PreSpawn();
 393
 394                 spot = SelectSpawnPoint (FALSE);
 395                 if(!spot)
 396                 {
 397                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 398                         return; // spawn failed
 399                 }
 400
 401                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 402
 403                 if(self.vehicle)
 404                         vehicles_exit(VHEF_RELESE);
 405
 406                 self.classname = "player";
 407                 self.wasplayer = TRUE;
 408                 self.iscreature = TRUE;
 409                 self.teleportable = TELEPORT_NORMAL;
 410                 self.damagedbycontents = TRUE;
 411                 self.movetype = MOVETYPE_WALK;
 412                 self.solid = SOLID_SLIDEBOX;
 413                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 414                 if(autocvar_g_playerclip_collisions)
 415                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 416                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 417                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 418                 self.frags = FRAGS_PLAYER;
 419                 if(INDEPENDENT_PLAYERS)
 420                         MAKE_INDEPENDENT_PLAYER(self);
 421                 self.flags = FL_CLIENT;
 422                 if(autocvar__notarget)
 423                         self.flags |= FL_NOTARGET;
 424                 self.takedamage = DAMAGE_AIM;
 425                 self.effects = 0;
 426                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 427                 self.air_finished = time + 12;
 428                 self.dmg = 2;
 429                 if(autocvar_g_balance_nex_charge)
 430                 {
 431                         if(autocvar_g_balance_nex_secondary_chargepool)
 432                                 self.nex_chargepool_ammo = 1;
 433                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 434                 }
 435
 436                 if(warmup_stage)
 437                 {
 438                         self.ammo_shells = warmup_start_ammo_shells;
 439                         self.ammo_nails = warmup_start_ammo_nails;
 440                         self.ammo_rockets = warmup_start_ammo_rockets;
 441                         self.ammo_cells = warmup_start_ammo_cells;
 442                         self.ammo_fuel = warmup_start_ammo_fuel;
 443                         self.health = warmup_start_health;
 444                         self.armorvalue = warmup_start_armorvalue;
 445                         self.weapons = WARMUP_START_WEAPONS;
 446                 }
 447                 else
 448                 {
 449                         self.ammo_shells = start_ammo_shells;
 450                         self.ammo_nails = start_ammo_nails;
 451                         self.ammo_rockets = start_ammo_rockets;
 452                         self.ammo_cells = start_ammo_cells;
 453                         self.ammo_fuel = start_ammo_fuel;
 454                         self.health = start_health;
 455                         self.armorvalue = start_armorvalue;
 456                         self.weapons = start_weapons;
 457                 }
 458
 459                 if(self.weapons & WEPSET_SUPERWEAPONS)
 460                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 461                 else
 462                         self.superweapons_finished = 0;
 463
 464                 if(g_weaponarena_random)
 465                 {
 466                         if(g_weaponarena_random_with_laser)
 467                                 self.weapons &= ~WEPSET_LASER;
 468                         W_RandomWeapons(self, g_weaponarena_random);
 469                         if(g_weaponarena_random_with_laser)
 470                                 self.weapons |= WEPSET_LASER;
 471                 }
 472
 473                 self.items = start_items;
 474
 475                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 476                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 477                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 478                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 479                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 480                 //extend the pause of rotting if client was reset at the beginning of the countdown
 481                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 482                         self.spawnshieldtime += game_starttime - time;
 483                         self.pauserotarmor_finished += game_starttime - time;
 484                         self.pauserothealth_finished += game_starttime - time;
 485                         self.pauseregen_finished += game_starttime - time;
 486                 }
 487                 self.damageforcescale = 2;
 488                 self.death_time = 0;
 489                 self.respawn_flags = 0;
 490                 self.respawn_time = 0;
 491                 self.stat_respawn_time = 0;
 492                 self.scale = 0;
 493                 self.fade_time = 0;
 494                 self.pain_frame = 0;
 495                 self.pain_finished = 0;
 496                 self.strength_finished = 0;
 497                 self.invincible_finished = 0;
 498                 self.pushltime = 0;
 499                 // players have no think function
 500                 self.think = func_null;
 501                 self.nextthink = 0;
 502                 self.hook_time = 0;
 503                 self.dmg_team = 0;
 504                 self.ballistics_density = autocvar_g_ballistics_density_player;
 505
 506                 self.metertime = 0;
 507
 508                 self.deadflag = DEAD_NO;
 509
 510                 self.angles = spot.angles;
 511
 512                 self.angles_z = 0; // never spawn tilted even if the spot says to
 513                 self.fixangle = TRUE; // turn this way immediately
 514                 self.velocity = '0 0 0';
 515                 self.avelocity = '0 0 0';
 516                 self.punchangle = '0 0 0';
 517                 self.punchvector = '0 0 0';
 518                 self.oldvelocity = self.velocity;
 519                 self.fire_endtime = -1;
 520
 521                 entity spawnevent = spawn();
 522                 spawnevent.owner = self;
 523                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 524
 525                 self.model = "";
 526                 FixPlayermodel();
 527                 self.drawonlytoclient = world;
 528
 529                 self.crouch = FALSE;
 530                 self.view_ofs = PL_VIEW_OFS;
 531                 setsize (self, PL_MIN, PL_MAX);
 532                 self.spawnorigin = spot.origin;
 533                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 534                 // don't reset back to last position, even if new position is stuck in solid
 535                 self.oldorigin = self.origin;
 536                 self.prevorigin = self.origin;
 537                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 538                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 539         self.hud = HUD_NORMAL;
 540
 541                 self.event_damage = PlayerDamage;
 542
 543                 self.bot_attack = TRUE;
 544                 self.monster_attack = TRUE;
 545
 546                 self.spider_slowness = 0;
 547
 548                 self.statdraintime = time + 5;
 549                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 550
 551                 if(self.killcount == -666) {
 552                         PlayerScore_Clear(self);
 553                         self.killcount = 0;
 554                 }
 555
 556                 CL_SpawnWeaponentity();
 557                 self.alpha = default_player_alpha;
 558                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 559                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 560
 561                 self.speedrunning = FALSE;
 562
 563                 race_PostSpawn(spot);
 564
 565                 //stuffcmd(self, "chase_active 0");
 566                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 567
 568                 target_voicescript_clear(self);
 569
 570                 // reset fields the weapons may use
 571                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 572                 {
 573                         weapon_action(j, WR_RESETPLAYER);
 574
 575                         // all weapons must be fully loaded when we spawn
 576                         entity e;
 577                         e = get_weaponinfo(j);
 578                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 579                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 580                 }
 581
 582                 oldself = self;
 583                 self = spot;
 584                         activator = oldself;
 585                                 string s;
 586                                 s = self.target;
 587                                 self.target = string_null;
 588                                 SUB_UseTargets();
 589                                 self.target = s;
 590                         activator = world;
 591                 self = oldself;
 592
 593                 spawn_spot = spot;
 594                 MUTATOR_CALLHOOK(PlayerSpawn);
 595
 596                 if(autocvar_spawn_debug)
 597                 {
 598                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 599                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 600                 }
 601
 602                 self.switchweapon = w_getbestweapon(self);
 603                 self.cnt = -1; // W_LastWeapon will not complain
 604                 self.weapon = 0;
 605                 self.weaponname = "";
 606                 self.switchingweapon = 0;
 607
 608                 if(!warmup_stage)
 609                         if(!self.alivetime)
 610                                 self.alivetime = time;
 611
 612                 antilag_clear(self);
 613         }
 614         else if(IS_OBSERVER(self))
 615         {
 616                 PutObserverInServer ();
 617         }
 618 }
 619
 620 .float ebouncefactor, ebouncestop; // electro's values
 621 // TODO do we need all these fields, or should we stop autodetecting runtime
 622 // changes and just have a console command to update this?
 623 float ClientInit_SendEntity(entity to, float sf)
 624 {
 625         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 626         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 639         if(sv_foginterval && world.fog != "")
 640                 WriteString(MSG_ENTITY, world.fog);
 641         else
 642                 WriteString(MSG_ENTITY, "");
 643         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 644         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 645         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 646         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 647         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 650         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 651         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 652         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 653         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 654         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 655         return TRUE;
 656 }
 657
 658 void ClientInit_CheckUpdate()
 659 {
 660         self.nextthink = time;
 661         if(self.count != autocvar_g_balance_armor_blockpercent)
 662         {
 663                 self.count = autocvar_g_balance_armor_blockpercent;
 664                 self.SendFlags |= 1;
 665         }
 666         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 667         {
 668                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 669                 self.SendFlags |= 1;
 670         }
 671         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 672         {
 673                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 674                 self.SendFlags |= 1;
 675         }
 676         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 677         {
 678                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 679                 self.SendFlags |= 1;
 680         }
 681         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 682         {
 683                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 684                 self.SendFlags |= 1;
 685         }
 686 }
 687
 688 void ClientInit_Spawn()
 689 {
 690         entity o;
 691         entity e;
 692         e = spawn();
 693         e.classname = "clientinit";
 694         e.think = ClientInit_CheckUpdate;
 695         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 696
 697         o = self;
 698         self = e;
 699         ClientInit_CheckUpdate();
 700         self = o;
 701 }
 702
 703 /*
 704 =============
 705 SetNewParms
 706 =============
 707 */
 708 void SetNewParms (void)
 709 {
 710         // initialize parms for a new player
 711         parm1 = -(86400 * 366);
 712 }
 713
 714 /*
 715 =============
 716 SetChangeParms
 717 =============
 718 */
 719 void SetChangeParms (void)
 720 {
 721         // save parms for level change
 722         parm1 = self.parm_idlesince - time;
 723 }
 724
 725 /*
 726 =============
 727 DecodeLevelParms
 728 =============
 729 */
 730 void DecodeLevelParms (void)
 731 {
 732         // load parms
 733         self.parm_idlesince = parm1;
 734         if(self.parm_idlesince == -(86400 * 366))
 735                 self.parm_idlesince = time;
 736
 737         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 738         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 739 }
 740
 741 /*
 742 =============
 743 ClientKill
 744
 745 Called when a client types 'kill' in the console
 746 =============
 747 */
 748
 749 .float clientkill_nexttime;
 750 void ClientKill_Now_TeamChange()
 751 {
 752         if(self.killindicator_teamchange == -1)
 753         {
 754                 JoinBestTeam( self, FALSE, TRUE );
 755         }
 756         else if(self.killindicator_teamchange == -2)
 757         {
 758                 if(blockSpectators)
 759                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 760                 PutObserverInServer();
 761         }
 762         else
 763                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 764         self.killindicator_teamchange = 0;
 765 }
 766
 767 void ClientKill_Now()
 768 {
 769         if(self.vehicle)
 770         {
 771             vehicles_exit(VHEF_RELESE);
 772             if(!self.killindicator_teamchange)
 773             {
 774             self.vehicle_health = -1;
 775             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 776             }
 777         }
 778
 779         if(self.killindicator && !wasfreed(self.killindicator))
 780                 remove(self.killindicator);
 781
 782         self.killindicator = world;
 783
 784         if(self.killindicator_teamchange)
 785                 ClientKill_Now_TeamChange();
 786
 787         // in any case:
 788         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 789
 790         // now I am sure the player IS dead
 791 }
 792 void KillIndicator_Think()
 793 {
 794         if (gameover)
 795         {
 796                 self.owner.killindicator = world;
 797                 remove(self);
 798                 return;
 799         }
 800
 801         if (self.owner.alpha < 0 && !self.owner.vehicle)
 802         {
 803                 self.owner.killindicator = world;
 804                 remove(self);
 805                 return;
 806         }
 807
 808         if(self.cnt <= 0)
 809         {
 810                 self = self.owner;
 811                 ClientKill_Now(); // no oldself needed
 812                 return;
 813         }
 814     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 815     {
 816         self.nextthink = time + 1;
 817         self.cnt -= 1;
 818     }
 819         else
 820         {
 821                 if(self.cnt <= 10)
 822                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 823                 if(IS_REAL_CLIENT(self.owner))
 824                 {
 825                         if(self.cnt <= 10)
 826                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 827                 }
 828                 self.nextthink = time + 1;
 829                 self.cnt -= 1;
 830         }
 831 }
 832
 833 float clientkilltime;
 834 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 835 {
 836         float killtime;
 837         float starttime;
 838         entity e;
 839
 840         if (gameover)
 841                 return;
 842
 843         killtime = autocvar_g_balance_kill_delay;
 844
 845         if(g_race_qualifying || g_cts)
 846                 killtime = 0;
 847
 848     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 849     {
 850                 remove(self.killindicator);
 851                 self.killindicator = world;
 852
 853         ClientKill_Now(); // allow instant kill in this case
 854         return;
 855     }
 856
 857         self.killindicator_teamchange = targetteam;
 858
 859     if(!self.killindicator)
 860         {
 861                 if(self.deadflag == DEAD_NO)
 862                 {
 863                         killtime = max(killtime, self.clientkill_nexttime - time);
 864                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 865                 }
 866
 867                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 868                 {
 869                         ClientKill_Now();
 870                 }
 871                 else
 872                 {
 873                         starttime = max(time, clientkilltime);
 874
 875                         self.killindicator = spawn();
 876                         self.killindicator.owner = self;
 877                         self.killindicator.scale = 0.5;
 878                         setattachment(self.killindicator, self, "");
 879                         setorigin(self.killindicator, '0 0 52');
 880                         self.killindicator.think = KillIndicator_Think;
 881                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 882                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 883                         self.killindicator.cnt = ceil(killtime);
 884                         self.killindicator.count = bound(0, ceil(killtime), 10);
 885                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 886
 887                         for(e = world; (e = find(e, classname, "body")) != world; )
 888                         {
 889                                 if(e.enemy != self)
 890                                         continue;
 891                                 e.killindicator = spawn();
 892                                 e.killindicator.owner = e;
 893                                 e.killindicator.scale = 0.5;
 894                                 setattachment(e.killindicator, e, "");
 895                                 setorigin(e.killindicator, '0 0 52');
 896                                 e.killindicator.think = KillIndicator_Think;
 897                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 898                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 899                                 e.killindicator.cnt = ceil(killtime);
 900                         }
 901                         self.lip = 0;
 902                 }
 903         }
 904         if(self.killindicator)
 905         {
 906                 if(targetteam == 0) // just die
 907                 {
 908                         self.killindicator.colormod = '0 0 0';
 909                         if(IS_REAL_CLIENT(self))
 910                         if(self.killindicator.cnt > 0)
 911                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 912                 }
 913                 else if(targetteam == -1) // auto
 914                 {
 915                         self.killindicator.colormod = '0 1 0';
 916                         if(IS_REAL_CLIENT(self))
 917                         if(self.killindicator.cnt > 0)
 918                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 919                 }
 920                 else if(targetteam == -2) // spectate
 921                 {
 922                         self.killindicator.colormod = '0.5 0.5 0.5';
 923                         if(IS_REAL_CLIENT(self))
 924                         if(self.killindicator.cnt > 0)
 925                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 926                 }
 927                 else
 928                 {
 929                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 930                         if(IS_REAL_CLIENT(self))
 931                         if(self.killindicator.cnt > 0)
 932                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 933                 }
 934         }
 935
 936 }
 937
 938 void ClientKill (void)
 939 {
 940         if(gameover) return;
 941         if(self.player_blocked) return;
 942         if(self.freezetag_frozen) return;
 943
 944         ClientKill_TeamChange(0);
 945 }
 946
 947 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 948 {
 949     e.killindicator = spawn();
 950     e.killindicator.owner = e;
 951     e.killindicator.think = KillIndicator_Think;
 952     e.killindicator.nextthink = time + (e.lip) * 0.05;
 953     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 954     e.killindicator.health = 1; // this is used to indicate that it should be silent
 955     e.lip = 0;
 956 }
 957
 958 void FixClientCvars(entity e)
 959 {
 960         // send prediction settings to the client
 961         stuffcmd(e, "\nin_bindmap 0 0\n");
 962         if(g_race || g_cts)
 963                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 964         if(autocvar_g_antilag == 3) // client side hitscan
 965                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 966         if(autocvar_sv_gentle)
 967                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 968         /*
 969          * we no longer need to stuff this. Remove this comment block if you feel
 970          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 971         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 972         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 973         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 974         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 975         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 976         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 978         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 979         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 983         stuffcmd(e, "cl_movement_edgefriction 1\n");
 984          */
 985 }
 986
 987 float PlayerInIDList(entity p, string idlist)
 988 {
 989         float n, i;
 990         string s;
 991
 992         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 993         if (!p.crypto_idfp)
 994                 return 0;
 995
 996         // this function allows abbreviated player IDs too!
 997         n = tokenize_console(idlist);
 998         for(i = 0; i < n; ++i)
 999         {
1000                 s = argv(i);
1001                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1002                         return 1;
1003         }
1004
1005         return 0;
1006 }
1007
1008 /*
1009 =============
1010 ClientConnect
1011
1012 Called when a client connects to the server
1013 =============
1014 */
1015 void DecodeLevelParms (void);
1016 //void dom_player_join_team(entity pl);
1017 void set_dom_state(entity e);
1018 void ClientConnect (void)
1019 {
1020         float t;
1021
1022         if(IS_CLIENT(self))
1023         {
1024                 print("Warning: ClientConnect, but already connected!\n");
1025                 return;
1026         }
1027
1028         if(Ban_MaybeEnforceBanOnce(self))
1029                 return;
1030
1031         DecodeLevelParms();
1032
1033 #ifdef WATERMARK
1034         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1035 #endif
1036
1037         self.classname = "player_joining";
1038
1039         self.flags = FL_CLIENT;
1040         self.version_nagtime = time + 10 + random() * 10;
1041
1042         if(player_count<0)
1043         {
1044                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1045                 player_count = 0;
1046         }
1047
1048         PlayerScore_Attach(self);
1049         ClientData_Attach();
1050         accuracy_init(self);
1051
1052         bot_clientconnect();
1053
1054         playerdemo_init();
1055
1056         anticheat_init();
1057
1058         race_PreSpawnObserver();
1059
1060         // identify the right forced team
1061         if(autocvar_g_campaign)
1062         {
1063                 if(IS_REAL_CLIENT(self)) // only players, not bots
1064                 {
1065                         switch(autocvar_g_campaign_forceteam)
1066                         {
1067                                 case 1: self.team_forced = NUM_TEAM_1; break;
1068                                 case 2: self.team_forced = NUM_TEAM_2; break;
1069                                 case 3: self.team_forced = NUM_TEAM_3; break;
1070                                 case 4: self.team_forced = NUM_TEAM_4; break;
1071                                 default: self.team_forced = 0;
1072                         }
1073                 }
1074         }
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1076                 self.team_forced = NUM_TEAM_1;
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1078                 self.team_forced = NUM_TEAM_2;
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1080                 self.team_forced = NUM_TEAM_3;
1081         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1082                 self.team_forced = NUM_TEAM_4;
1083         else if(autocvar_g_forced_team_otherwise == "red")
1084                 self.team_forced = NUM_TEAM_1;
1085         else if(autocvar_g_forced_team_otherwise == "blue")
1086                 self.team_forced = NUM_TEAM_2;
1087         else if(autocvar_g_forced_team_otherwise == "yellow")
1088                 self.team_forced = NUM_TEAM_3;
1089         else if(autocvar_g_forced_team_otherwise == "pink")
1090                 self.team_forced = NUM_TEAM_4;
1091         else if(autocvar_g_forced_team_otherwise == "spectate")
1092                 self.team_forced = -1;
1093         else if(autocvar_g_forced_team_otherwise == "spectator")
1094                 self.team_forced = -1;
1095         else
1096                 self.team_forced = 0;
1097
1098         if(!teamplay)
1099                 if(self.team_forced > 0)
1100                         self.team_forced = 0;
1101
1102         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1103
1104         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1105                 self.classname = "observer";
1106         } else {
1107                 if(teamplay)
1108                 {
1109                         if(autocvar_g_balance_teams)
1110                         {
1111                                 self.classname = "player";
1112                                 campaign_bots_may_start = 1;
1113                         }
1114                         else
1115                         {
1116                                 self.classname = "observer"; // do it anyway
1117                         }
1118                 }
1119                 else
1120                 {
1121                         self.classname = "player";
1122                         campaign_bots_may_start = 1;
1123                 }
1124         }
1125
1126         self.playerid = (playerid_last = playerid_last + 1);
1127
1128         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1129
1130     if(IS_BOT_CLIENT(self))
1131         PlayerStats_AddPlayer(self);
1132
1133         if(autocvar_sv_eventlog)
1134                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1135
1136         LogTeamchange(self.playerid, self.team, 1);
1137
1138         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1139
1140         self.netname_previous = strzone(self.netname);
1141
1142         if(IS_PLAYER(self) && teamplay)
1143                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1144         else
1145                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1146
1147         stuffcmd(self, strcat(clientstuff, "\n"));
1148         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1149
1150         FixClientCvars(self);
1151
1152         // spawnfunc_waypoint sprites
1153         WaypointSprite_InitClient(self);
1154
1155         // Wazat's grappling hook
1156         SetGrappleHookBindings();
1157
1158         // get version info from player
1159         stuffcmd(self, "cmd clientversion $gameversion\n");
1160
1161         // get other cvars from player
1162         GetCvars(0);
1163
1164         // notify about available teams
1165         if(teamplay)
1166         {
1167                 CheckAllowedTeams(self);
1168                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1169                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1170         }
1171         else
1172                 stuffcmd(self, "set _teams_available 0\n");
1173
1174         attach_entcs();
1175
1176         bot_relinkplayerlist();
1177
1178         self.spectatortime = time;
1179         if(blockSpectators)
1180         {
1181                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1182         }
1183
1184         if(IS_SPEC(self) || IS_OBSERVER(self))
1185         if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
1186                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
1187
1188         self.jointime = time;
1189         self.allowed_timeouts = autocvar_sv_timeout_number;
1190
1191         if(IS_REAL_CLIENT(self))
1192         {
1193                 if(!autocvar_g_campaign)
1194                 {
1195                         self.motd_actived_time = -1;
1196                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1197                 }
1198
1199                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1200                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1201         }
1202
1203         if(!sv_foginterval && world.fog != "")
1204                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1205
1206         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1207         {
1208                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1209                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1210         }
1211         else
1212                 self.hitplotfh = -1;
1213
1214         if(g_race || g_cts) {
1215                 string rr;
1216                 if(g_cts)
1217                         rr = CTS_RECORD;
1218                 else
1219                         rr = RACE_RECORD;
1220
1221                 msg_entity = self;
1222                 race_send_recordtime(MSG_ONE);
1223                 race_send_speedaward(MSG_ONE);
1224
1225                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1226                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1227                 race_send_speedaward_alltimebest(MSG_ONE);
1228
1229                 float i;
1230                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1231                         race_SendRankings(i, 0, 0, MSG_ONE);
1232                 }
1233         }
1234         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1235                 send_CSQC_teamnagger();
1236
1237         CheatInitClient();
1238
1239         CSQCMODEL_AUTOINIT();
1240
1241         self.model_randomizer = random();
1242
1243         if(IS_REAL_CLIENT(self))
1244                 sv_notice_join();
1245
1246         MUTATOR_CALLHOOK(ClientConnect);
1247 }
1248 /*
1249 =============
1250 ClientDisconnect
1251
1252 Called when a client disconnects from the server
1253 =============
1254 */
1255 .entity chatbubbleentity;
1256 void ReadyCount();
1257 void ClientDisconnect (void)
1258 {
1259         if(self.vehicle)
1260             vehicles_exit(VHEF_RELESE);
1261
1262         if (!IS_CLIENT(self))
1263         {
1264                 print("Warning: ClientDisconnect without ClientConnect\n");
1265                 return;
1266         }
1267
1268         PlayerStats_AddGlobalInfo(self);
1269
1270         CheatShutdownClient();
1271
1272         if(self.hitplotfh >= 0)
1273         {
1274                 fclose(self.hitplotfh);
1275                 self.hitplotfh = -1;
1276         }
1277
1278         anticheat_report();
1279         anticheat_shutdown();
1280
1281         playerdemo_shutdown();
1282
1283         bot_clientdisconnect();
1284
1285         if(self.entcs)
1286                 detach_entcs();
1287
1288         if(autocvar_sv_eventlog)
1289                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1290
1291         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1292
1293         MUTATOR_CALLHOOK(ClientDisconnect);
1294
1295         Portal_ClearAll(self);
1296
1297         RemoveGrapplingHook(self);
1298
1299         // Here, everything has been done that requires this player to be a client.
1300
1301         self.flags &= ~FL_CLIENT;
1302
1303         if (self.chatbubbleentity)
1304                 remove (self.chatbubbleentity);
1305
1306         if (self.killindicator)
1307                 remove (self.killindicator);
1308
1309         WaypointSprite_PlayerGone();
1310
1311         bot_relinkplayerlist();
1312
1313         accuracy_free(self);
1314         ClientData_Detach();
1315         PlayerScore_Detach(self);
1316
1317         if(self.netname_previous)
1318                 strunzone(self.netname_previous);
1319         if(self.clientstatus)
1320                 strunzone(self.clientstatus);
1321         if(self.weaponorder_byimpulse)
1322                 strunzone(self.weaponorder_byimpulse);
1323
1324         ClearPlayerSounds();
1325
1326         if(self.personal)
1327                 remove(self.personal);
1328
1329         self.playerid = 0;
1330         ReadyCount();
1331
1332         // free cvars
1333         GetCvars(-1);
1334 }
1335
1336 .float BUTTON_CHAT;
1337 void ChatBubbleThink()
1338 {
1339         self.nextthink = time;
1340         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1341         {
1342                 if(self.owner) // but why can that ever be world?
1343                         self.owner.chatbubbleentity = world;
1344                 remove(self);
1345                 return;
1346         }
1347         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1348 #ifdef TETRIS
1349                 || self.owner.tetris_on
1350 #endif
1351         )
1352                 self.model = self.mdl;
1353         else
1354                 self.model = "";
1355 }
1356
1357 void UpdateChatBubble()
1358 {
1359         if (self.alpha < 0)
1360                 return;
1361         // spawn a chatbubble entity if needed
1362         if (!self.chatbubbleentity)
1363         {
1364                 self.chatbubbleentity = spawn();
1365                 self.chatbubbleentity.owner = self;
1366                 self.chatbubbleentity.exteriormodeltoclient = self;
1367                 self.chatbubbleentity.think = ChatBubbleThink;
1368                 self.chatbubbleentity.nextthink = time;
1369                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1370                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1371                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1372                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1373                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1374                 self.chatbubbleentity.model = "";
1375                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1376         }
1377 }
1378
1379
1380 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1381 // added to the model skins
1382 /*void UpdateColorModHack()
1383 {
1384         float c;
1385         c = self.clientcolors & 15;
1386         // LordHavoc: only bothering to support white, green, red, yellow, blue
1387              if (!teamplay) self.colormod = '0 0 0';
1388         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1389         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1390         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1391         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1392         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1393         else self.colormod = '1 1 1';
1394 }*/
1395
1396 void respawn(void)
1397 {
1398         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1399         {
1400                 self.solid = SOLID_NOT;
1401                 self.takedamage = DAMAGE_NO;
1402                 self.movetype = MOVETYPE_FLY;
1403                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1404                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1405                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1406                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1407                 if(autocvar_g_respawn_ghosts_maxtime)
1408                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1409         }
1410
1411         CopyBody(1);
1412
1413         self.effects |= EF_NODRAW; // prevent another CopyBody
1414         PutClientInServer();
1415 }
1416
1417 void play_countdown(float finished, string samp)
1418 {
1419         if(IS_REAL_CLIENT(self))
1420                 if(floor(finished - time - frametime) != floor(finished - time))
1421                         if(finished - time < 6)
1422                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1423 }
1424
1425 void player_powerups (void)
1426 {
1427         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1428         olditems = self.items;
1429
1430         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1431                 self.modelflags |= MF_ROCKET;
1432         else
1433                 self.modelflags &= ~MF_ROCKET;
1434
1435         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1436
1437         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1438                 return;
1439
1440         Fire_ApplyDamage(self);
1441         Fire_ApplyEffect(self);
1442
1443         if (!g_minstagib)
1444         {
1445                 if (self.items & IT_STRENGTH)
1446                 {
1447                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1448                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1449                         if (time > self.strength_finished)
1450                         {
1451                                 self.items = self.items - (self.items & IT_STRENGTH);
1452                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1453                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1454                         }
1455                 }
1456                 else
1457                 {
1458                         if (time < self.strength_finished)
1459                         {
1460                                 self.items = self.items | IT_STRENGTH;
1461                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1462                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1463                         }
1464                 }
1465                 if (self.items & IT_INVINCIBLE)
1466                 {
1467                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1468                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1469                         if (time > self.invincible_finished)
1470                         {
1471                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1472                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1473                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1474                         }
1475                 }
1476                 else
1477                 {
1478                         if (time < self.invincible_finished)
1479                         {
1480                                 self.items = self.items | IT_INVINCIBLE;
1481                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1482                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1483                         }
1484                 }
1485                 if (self.items & IT_SUPERWEAPON)
1486                 {
1487                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1488                         {
1489                                 self.superweapons_finished = 0;
1490                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1491                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1492                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1493                         }
1494                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1495                         {
1496                                 // don't let them run out
1497                         }
1498                         else
1499                         {
1500                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1501                                 if (time > self.superweapons_finished)
1502                                 {
1503                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1504                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1505                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1506                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1507                                 }
1508                         }
1509                 }
1510                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1511                 {
1512                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1513                         {
1514                                 self.items = self.items | IT_SUPERWEAPON;
1515                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1516                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1517                         }
1518                         else
1519                         {
1520                                 self.superweapons_finished = 0;
1521                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1522                         }
1523                 }
1524                 else
1525                 {
1526                         self.superweapons_finished = 0;
1527                 }
1528         }
1529
1530         if(autocvar_g_nodepthtestplayers)
1531                 self.effects = self.effects | EF_NODEPTHTEST;
1532
1533         if(autocvar_g_fullbrightplayers)
1534                 self.effects = self.effects | EF_FULLBRIGHT;
1535
1536         if (time >= game_starttime)
1537         if (time < self.spawnshieldtime)
1538                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1539
1540         MUTATOR_CALLHOOK(PlayerPowerups);
1541 }
1542
1543 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1544 {
1545         if(current > stable)
1546                 return current;
1547         else if(current > stable - 0.25) // when close enough, "snap"
1548                 return stable;
1549         else
1550                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1551 }
1552
1553 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1554 {
1555         if(current < stable)
1556                 return current;
1557         else if(current < stable + 0.25) // when close enough, "snap"
1558                 return stable;
1559         else
1560                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1561 }
1562
1563 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1564 {
1565         if(current > rotstable)
1566         {
1567                 if(rotframetime > 0)
1568                 {
1569                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1570                         current = max(rotstable, current - rotlinear * rotframetime);
1571                 }
1572         }
1573         else if(current < regenstable)
1574         {
1575                 if(regenframetime > 0)
1576                 {
1577                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1578                         current = min(regenstable, current + regenlinear * regenframetime);
1579                 }
1580         }
1581
1582         if(current > limit)
1583                 current = limit;
1584
1585         return current;
1586 }
1587
1588 void player_regen (void)
1589 {
1590         if(!MUTATOR_CALLHOOK(PlayerRegen))
1591         {
1592                 float minh, mina, maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1593                 maxh = autocvar_g_balance_health_rotstable;
1594                 maxa = autocvar_g_balance_armor_rotstable;
1595                 minh = autocvar_g_balance_health_regenstable;
1596                 mina = autocvar_g_balance_armor_regenstable;
1597                 limith = autocvar_g_balance_health_limit;
1598                 limita = autocvar_g_balance_armor_limit;
1599
1600                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1601
1602                 maxh = maxh * max_mod;
1603                 minh = minh * max_mod;
1604                 limith = limith * limit_mod;
1605                 limita = limita * limit_mod;
1606
1607                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1608                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1609         }
1610
1611         // if player rotted to death...  die!
1612         // check this outside above checks, as player may still be able to rot to death
1613         if(self.health < 1)
1614                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1615
1616         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1617         {
1618                 float minf, maxf, limitf;
1619
1620                 maxf = autocvar_g_balance_fuel_rotstable;
1621                 minf = autocvar_g_balance_fuel_regenstable;
1622                 limitf = autocvar_g_balance_fuel_limit;
1623
1624                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1625         }
1626 }
1627
1628 float zoomstate_set;
1629 void SetZoomState(float z)
1630 {
1631         if(z != self.zoomstate)
1632         {
1633                 self.zoomstate = z;
1634                 ClientData_Touch(self);
1635         }
1636         zoomstate_set = 1;
1637 }
1638
1639 void GetPressedKeys(void) {
1640         MUTATOR_CALLHOOK(GetPressedKeys);
1641         if (self.movement_x > 0) // get if movement keys are pressed
1642         {       // forward key pressed
1643                 self.pressedkeys |= KEY_FORWARD;
1644                 self.pressedkeys &= ~KEY_BACKWARD;
1645         }
1646         else if (self.movement_x < 0)
1647         {       // backward key pressed
1648                 self.pressedkeys |= KEY_BACKWARD;
1649                 self.pressedkeys &= ~KEY_FORWARD;
1650         }
1651         else
1652         {       // no x input
1653                 self.pressedkeys &= ~KEY_FORWARD;
1654                 self.pressedkeys &= ~KEY_BACKWARD;
1655         }
1656
1657         if (self.movement_y > 0)
1658         {       // right key pressed
1659                 self.pressedkeys |= KEY_RIGHT;
1660                 self.pressedkeys &= ~KEY_LEFT;
1661         }
1662         else if (self.movement_y < 0)
1663         {       // left key pressed
1664                 self.pressedkeys |= KEY_LEFT;
1665                 self.pressedkeys &= ~KEY_RIGHT;
1666         }
1667         else
1668         {       // no y input
1669                 self.pressedkeys &= ~KEY_RIGHT;
1670                 self.pressedkeys &= ~KEY_LEFT;
1671         }
1672
1673         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1674                 self.pressedkeys |= KEY_JUMP;
1675         else
1676                 self.pressedkeys &= ~KEY_JUMP;
1677         if (self.BUTTON_CROUCH)
1678                 self.pressedkeys |= KEY_CROUCH;
1679         else
1680                 self.pressedkeys &= ~KEY_CROUCH;
1681
1682         if (self.BUTTON_ATCK)
1683                 self.pressedkeys |= KEY_ATCK;
1684         else
1685                 self.pressedkeys &= ~KEY_ATCK;
1686         if (self.BUTTON_ATCK2)
1687                 self.pressedkeys |= KEY_ATCK2;
1688         else
1689                 self.pressedkeys &= ~KEY_ATCK2;
1690 }
1691
1692 /*
1693 ======================
1694 spectate mode routines
1695 ======================
1696 */
1697
1698 void SpectateCopy(entity spectatee) {
1699         other = spectatee;
1700         MUTATOR_CALLHOOK(SpectateCopy);
1701         self.armortype = spectatee.armortype;
1702         self.armorvalue = spectatee.armorvalue;
1703         self.ammo_cells = spectatee.ammo_cells;
1704         self.ammo_shells = spectatee.ammo_shells;
1705         self.ammo_nails = spectatee.ammo_nails;
1706         self.ammo_rockets = spectatee.ammo_rockets;
1707         self.ammo_fuel = spectatee.ammo_fuel;
1708         self.clip_load = spectatee.clip_load;
1709         self.clip_size = spectatee.clip_size;
1710         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1711         self.health = spectatee.health;
1712         self.impulse = 0;
1713         self.items = spectatee.items;
1714         self.last_pickup = spectatee.last_pickup;
1715         self.hit_time = spectatee.hit_time;
1716         self.metertime = spectatee.metertime;
1717         self.strength_finished = spectatee.strength_finished;
1718         self.invincible_finished = spectatee.invincible_finished;
1719         self.pressedkeys = spectatee.pressedkeys;
1720         self.weapons = spectatee.weapons;
1721         self.switchweapon = spectatee.switchweapon;
1722         self.switchingweapon = spectatee.switchingweapon;
1723         self.weapon = spectatee.weapon;
1724         self.nex_charge = spectatee.nex_charge;
1725         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1726         self.hagar_load = spectatee.hagar_load;
1727         self.minelayer_mines = spectatee.minelayer_mines;
1728         self.punchangle = spectatee.punchangle;
1729         self.view_ofs = spectatee.view_ofs;
1730         self.velocity = spectatee.velocity;
1731         self.dmg_take = spectatee.dmg_take;
1732         self.dmg_save = spectatee.dmg_save;
1733         self.dmg_inflictor = spectatee.dmg_inflictor;
1734         self.v_angle = spectatee.v_angle;
1735         self.angles = spectatee.v_angle;
1736         if(!self.BUTTON_USE)
1737                 self.fixangle = TRUE;
1738         setorigin(self, spectatee.origin);
1739         setsize(self, spectatee.mins, spectatee.maxs);
1740         SetZoomState(spectatee.zoomstate);
1741
1742     anticheat_spectatecopy(spectatee);
1743         self.hud = spectatee.hud;
1744         if(spectatee.vehicle)
1745     {
1746         self.fixangle = FALSE;
1747         //self.velocity = spectatee.vehicle.velocity;
1748         self.vehicle_health = spectatee.vehicle_health;
1749         self.vehicle_shield = spectatee.vehicle_shield;
1750         self.vehicle_energy = spectatee.vehicle_energy;
1751         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1752         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1753         self.vehicle_reload1 = spectatee.vehicle_reload1;
1754         self.vehicle_reload2 = spectatee.vehicle_reload2;
1755
1756         msg_entity = self;
1757
1758         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1759             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1760             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1761             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1762
1763         //WriteByte (MSG_ONE, SVC_SETVIEW);
1764         //    WriteEntity(MSG_ONE, self);
1765         //makevectors(spectatee.v_angle);
1766         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1767     }
1768 }
1769
1770 float SpectateUpdate() {
1771         if(!self.enemy)
1772             return 0;
1773
1774         if (self == self.enemy)
1775                 return 0;
1776
1777         if (!IS_PLAYER(self.enemy))
1778                 return 0;
1779
1780         SpectateCopy(self.enemy);
1781
1782         return 1;
1783 }
1784
1785
1786 float SpectateSet()
1787 {
1788         if(self.enemy.classname != "player")
1789                 return FALSE;
1790         /*if(self.enemy.vehicle)
1791         {
1792
1793                 msg_entity = self;
1794                 WriteByte(MSG_ONE, SVC_SETVIEW);
1795                 WriteEntity(MSG_ONE, self.enemy);
1796                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1797
1798                 self.movetype = MOVETYPE_NONE;
1799                 accuracy_resend(self);
1800         }
1801         else
1802         {*/
1803                 msg_entity = self;
1804                 WriteByte(MSG_ONE, SVC_SETVIEW);
1805                 WriteEntity(MSG_ONE, self.enemy);
1806                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1807                 self.movetype = MOVETYPE_NONE;
1808                 accuracy_resend(self);
1809
1810                 if(!SpectateUpdate())
1811                         PutObserverInServer();
1812         //}
1813         return TRUE;
1814 }
1815
1816 float Spectate(entity pl)
1817 {
1818         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1819         if(pl.team != self.team)
1820                 return 0;
1821
1822         self.enemy = pl;
1823         return SpectateSet();
1824 }
1825
1826 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1827 entity CA_SpectateNext(entity start) {
1828         if (start.team == self.team) {
1829                 return start;
1830         }
1831
1832         other = start;
1833         // continue from current player
1834         while(other && other.team != self.team) {
1835                 other = find(other, classname, "player");
1836         }
1837
1838         if (!other) {
1839                 // restart from begining
1840                 other = find(other, classname, "player");
1841                 while(other && other.team != self.team) {
1842                         other = find(other, classname, "player");
1843                 }
1844         }
1845
1846         return other;
1847 }
1848
1849 float SpectateNext()
1850 {
1851         other = find(self.enemy, classname, "player");
1852
1853         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1854                 // CA and ca players when spectating enemies is forbidden
1855                 other = CA_SpectateNext(other);
1856         } else {
1857                 // other modes and ca spectators or spectating enemies is allowed
1858                 if (!other)
1859                         other = find(other, classname, "player");
1860         }
1861
1862         if (other)
1863                 self.enemy = other;
1864
1865         return SpectateSet();
1866 }
1867
1868 float SpectatePrev()
1869 {
1870         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1871         other = findchain(classname, "player");
1872         if (!other) // no player
1873                 return FALSE;
1874
1875         entity first = other;
1876         // skip players until current spectated player
1877         if(self.enemy)
1878         while(other && other != self.enemy)
1879                 other = other.chain;
1880
1881         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1882         {
1883                 do { other = other.chain; }
1884                 while(other && other.team != self.team);
1885
1886                 if (!other)
1887                 {
1888                         other = first;
1889                         while(other.team != self.team)
1890                                 other = other.chain;
1891                         if(other == self.enemy)
1892                                 return TRUE;
1893                 }
1894         }
1895         else
1896         {
1897                 if(other.chain)
1898                         other = other.chain;
1899                 else
1900                         other = first;
1901         }
1902         self.enemy = other;
1903         return SpectateSet();
1904 }
1905
1906 /*
1907 =============
1908 ShowRespawnCountdown()
1909
1910 Update a respawn countdown display.
1911 =============
1912 */
1913 void ShowRespawnCountdown()
1914 {
1915         float number;
1916         if(self.deadflag == DEAD_NO) // just respawned?
1917                 return;
1918         else
1919         {
1920                 number = ceil(self.respawn_time - time);
1921                 if(number <= 0)
1922                         return;
1923                 if(number <= self.respawn_countdown)
1924                 {
1925                         self.respawn_countdown = number - 1;
1926                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1927                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1928                 }
1929         }
1930 }
1931
1932 void LeaveSpectatorMode()
1933 {
1934         if(self.caplayer)
1935                 return;
1936         if(nJoinAllowed(self))
1937         {
1938                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1939                 {
1940                         self.classname = "player";
1941
1942                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1943                                 { JoinBestTeam(self, FALSE, TRUE); }
1944
1945                         if(autocvar_g_campaign)
1946                                 { campaign_bots_may_start = 1; }
1947
1948                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1949
1950                         PutClientInServer();
1951
1952                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1953                 }
1954                 else
1955                         stuffcmd(self, "menu_showteamselect\n");
1956         }
1957         else
1958         {
1959                 // Player may not join because g_maxplayers is set
1960                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1961         }
1962 }
1963
1964 /**
1965  * Determines whether the player is allowed to join. This depends on cvar
1966  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1967  * it checks whether the number of currently playing players exceeds g_maxplayers.
1968  * @return int number of free slots for players, 0 if none
1969  */
1970 float nJoinAllowed(entity ignore) {
1971         if(!ignore)
1972         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1973         // so report 0 free slots if restricted
1974         {
1975                 if(autocvar_g_forced_team_otherwise == "spectate")
1976                         return 0;
1977                 if(autocvar_g_forced_team_otherwise == "spectator")
1978                         return 0;
1979         }
1980
1981         if(self.team_forced < 0)
1982                 return 0; // forced spectators can never join
1983
1984         // TODO simplify this
1985         entity e;
1986         float totalClients = 0;
1987         FOR_EACH_CLIENT(e)
1988                 if(e != ignore)
1989                         totalClients += 1;
1990
1991         if (!autocvar_g_maxplayers)
1992                 return maxclients - totalClients;
1993
1994         float currentlyPlaying = 0;
1995         FOR_EACH_REALCLIENT(e)
1996                 if(IS_PLAYER(e) || e.caplayer == 1)
1997                         currentlyPlaying += 1;
1998
1999         if(currentlyPlaying < autocvar_g_maxplayers)
2000                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2001
2002         return 0;
2003 }
2004
2005 /**
2006  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2007  * g_maxplayers_spectator_blocktime seconds
2008  */
2009 void checkSpectatorBlock() {
2010         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2011                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2012                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2013                         dropclient(self);
2014                 }
2015         }
2016 }
2017
2018 void PrintWelcomeMessage()
2019 {
2020         if(self.motd_actived_time == 0)
2021         {
2022                 if (autocvar_g_campaign) {
2023                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2024                                 self.motd_actived_time = time;
2025                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2026                         }
2027                 } else {
2028                         if (self.BUTTON_INFO) {
2029                                 self.motd_actived_time = time;
2030                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2031                         }
2032                 }
2033         }
2034         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2035         {
2036                 if (autocvar_g_campaign) {
2037                         if (self.BUTTON_INFO)
2038                                 self.motd_actived_time = time;
2039                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2040                                 self.motd_actived_time = 0;
2041                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2042                         }
2043                 } else {
2044                         if (self.BUTTON_INFO)
2045                                 self.motd_actived_time = time;
2046                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2047                                 self.motd_actived_time = 0;
2048                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2049                         }
2050                 }
2051         }
2052         else //if(self.motd_actived_time < 0) // just connected, motd is active
2053         {
2054                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2055                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2056                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2057                 {
2058                         // instanctly hide MOTD
2059                         self.motd_actived_time = 0;
2060                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2061                 }
2062         }
2063 }
2064
2065 void ObserverThink()
2066 {
2067         float prefered_movetype;
2068         if (self.flags & FL_JUMPRELEASED) {
2069                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2070                         self.flags &= ~FL_JUMPRELEASED;
2071                         self.flags |= FL_SPAWNING;
2072                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2073                         self.flags &= ~FL_JUMPRELEASED;
2074                         if(SpectateNext()) {
2075                                 self.classname = "spectator";
2076                         }
2077                 } else {
2078                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2079                         if (self.movetype != prefered_movetype)
2080                                 self.movetype = prefered_movetype;
2081                 }
2082         } else {
2083                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2084                         self.flags |= FL_JUMPRELEASED;
2085                         if(self.flags & FL_SPAWNING)
2086                         {
2087                                 self.flags &= ~FL_SPAWNING;
2088                                 LeaveSpectatorMode();
2089                                 return;
2090                         }
2091                 }
2092         }
2093 }
2094
2095 void SpectatorThink()
2096 {
2097         if (self.flags & FL_JUMPRELEASED) {
2098                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2099                         self.flags &= ~FL_JUMPRELEASED;
2100                         self.flags |= FL_SPAWNING;
2101                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2102                         self.flags &= ~FL_JUMPRELEASED;
2103                         if(SpectateNext()) {
2104                                 self.classname = "spectator";
2105                         } else {
2106                                 self.classname = "observer";
2107                                 PutClientInServer();
2108                         }
2109                         self.impulse = 0;
2110                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2111                         self.flags &= ~FL_JUMPRELEASED;
2112                         if(SpectatePrev()) {
2113                                 self.classname = "spectator";
2114                         } else {
2115                                 self.classname = "observer";
2116                                 PutClientInServer();
2117                         }
2118                         self.impulse = 0;
2119                 } else if (self.BUTTON_ATCK2) {
2120                         self.flags &= ~FL_JUMPRELEASED;
2121                         self.classname = "observer";
2122                         PutClientInServer();
2123                 } else {
2124                         if(!SpectateUpdate())
2125                                 PutObserverInServer();
2126                 }
2127         } else {
2128                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2129                         self.flags |= FL_JUMPRELEASED;
2130                         if(self.flags & FL_SPAWNING)
2131                         {
2132                                 self.flags &= ~FL_SPAWNING;
2133                                 LeaveSpectatorMode();
2134                                 return;
2135                         }
2136                 }
2137                 if(!SpectateUpdate())
2138                         PutObserverInServer();
2139         }
2140
2141         self.flags |= FL_CLIENT | FL_NOTARGET;
2142 }
2143
2144 void PlayerUseKey()
2145 {
2146         if (!IS_PLAYER(self))
2147                 return;
2148
2149         if(self.vehicle)
2150         {
2151         vehicles_exit(VHEF_NORMAL);
2152         return;
2153         }
2154
2155         // a use key was pressed; call handlers
2156         MUTATOR_CALLHOOK(PlayerUseKey);
2157 }
2158
2159 /*
2160 =============
2161 PlayerPreThink
2162
2163 Called every frame for each client before the physics are run
2164 =============
2165 */
2166 .float usekeypressed;
2167 void() nexball_setstatus;
2168 .float items_added;
2169 void PlayerPreThink (void)
2170 {
2171         WarpZone_PlayerPhysics_FixVAngle();
2172
2173         self.stat_game_starttime = game_starttime;
2174         self.stat_round_starttime = round_starttime;
2175         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2176         self.stat_leadlimit = autocvar_leadlimit;
2177
2178         if(frametime)
2179         {
2180                 // physics frames: update anticheat stuff
2181                 anticheat_prethink();
2182         }
2183
2184         if(blockSpectators && frametime)
2185                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2186                 checkSpectatorBlock();
2187
2188         zoomstate_set = 0;
2189
2190         if(self.netname_previous != self.netname)
2191         {
2192                 if(autocvar_sv_eventlog)
2193                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2194                 if(self.netname_previous)
2195                         strunzone(self.netname_previous);
2196                 self.netname_previous = strzone(self.netname);
2197         }
2198
2199         // version nagging
2200         if(self.version_nagtime)
2201                 if(self.cvar_g_xonoticversion)
2202                         if(time > self.version_nagtime)
2203                         {
2204                                 // don't notify git users
2205                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2206                                 {
2207                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2208                                         {
2209                                                 // notify release users if connecting to git
2210                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2211                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2212                                         }
2213                                         else
2214                                         {
2215                                                 float r;
2216                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2217                                                 if(r < 0)
2218                                                 {
2219                                                         // give users new version
2220                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2221                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2222                                                 }
2223                                                 else if(r > 0)
2224                                                 {
2225                                                         // notify users about old server version
2226                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2227                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2228                                                 }
2229                                         }
2230                                 }
2231                                 self.version_nagtime = 0;
2232                         }
2233
2234         // GOD MODE info
2235         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2236         {
2237                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2238                 self.max_armorvalue = 0;
2239         }
2240
2241 #ifdef TETRIS
2242         if (TetrisPreFrame())
2243                 return;
2244 #endif
2245
2246         MUTATOR_CALLHOOK(PlayerPreThink);
2247
2248         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2249         {
2250                 if(self.BUTTON_USE && !self.usekeypressed)
2251                         PlayerUseKey();
2252                 self.usekeypressed = self.BUTTON_USE;
2253         }
2254
2255         if(IS_REAL_CLIENT(self))
2256                 PrintWelcomeMessage();
2257
2258         if(IS_PLAYER(self))
2259         {
2260
2261                 CheckRules_Player();
2262
2263                 if (intermission_running)
2264                 {
2265                         IntermissionThink ();   // otherwise a button could be missed between
2266                         return;                                 // the think tics
2267                 }
2268
2269                 //don't allow the player to turn around while game is paused!
2270                 if(timeout_status == TIMEOUT_ACTIVE) {
2271                         // FIXME turn this into CSQC stuff
2272                         self.v_angle = self.lastV_angle;
2273                         self.angles = self.lastV_angle;
2274                         self.fixangle = TRUE;
2275                 }
2276
2277                 if(frametime)
2278                 {
2279                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2280                         {
2281                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2282                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2283                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2284
2285                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2286                                 {
2287                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2288                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2289                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2290                                 }
2291                         }
2292                         else
2293                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2294
2295                         player_powerups();
2296                 }
2297
2298                 if (self.deadflag != DEAD_NO)
2299                 {
2300                         if(self.personal && g_race_qualifying)
2301                         {
2302                                 if(time > self.respawn_time)
2303                                 {
2304                                         self.respawn_time = time + 1; // only retry once a second
2305                                         self.stat_respawn_time = self.respawn_time;
2306                                         respawn();
2307                                         self.impulse = 141;
2308                                 }
2309                         }
2310                         else
2311                         {
2312                                 float button_pressed;
2313                                 if(frametime)
2314                                         player_anim();
2315                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2316
2317                                 if (self.deadflag == DEAD_DYING)
2318                                 {
2319                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2320                                                 self.deadflag = DEAD_RESPAWNING;
2321                                         else if(!button_pressed)
2322                                                 self.deadflag = DEAD_DEAD;
2323                                 }
2324                                 else if (self.deadflag == DEAD_DEAD)
2325                                 {
2326                                         if(button_pressed)
2327                                                 self.deadflag = DEAD_RESPAWNABLE;
2328                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2329                                                 self.deadflag = DEAD_RESPAWNING;
2330                                 }
2331                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2332                                 {
2333                                         if(!button_pressed)
2334                                                 self.deadflag = DEAD_RESPAWNING;
2335                                 }
2336                                 else if (self.deadflag == DEAD_RESPAWNING)
2337                                 {
2338                                         if(time > self.respawn_time)
2339                                         {
2340                                                 self.respawn_time = time + 1; // only retry once a second
2341                                                 self.respawn_time_max = self.respawn_time;
2342                                                 respawn();
2343                                         }
2344                                 }
2345
2346                                 ShowRespawnCountdown();
2347
2348                                 if(self.respawn_flags & RESPAWN_SILENT)
2349                                         self.stat_respawn_time = 0;
2350                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2351                                         self.stat_respawn_time = self.respawn_time_max;
2352                                 else
2353                                         self.stat_respawn_time = self.respawn_time;
2354                         }
2355
2356                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2357                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2358                                 self.stat_respawn_time *= -1;
2359
2360                         return;
2361                 }
2362
2363                 self.prevorigin = self.origin;
2364
2365                 float do_crouch = self.BUTTON_CROUCH;
2366                 if(self.hook.state)
2367                         do_crouch = 0;
2368                 if(self.vehicle)
2369                         do_crouch = 0;
2370                 if(self.freezetag_frozen)
2371                         do_crouch = 0;
2372                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2373                         do_crouch = 0;
2374
2375                 if (do_crouch)
2376                 {
2377                         if (!self.crouch)
2378                         {
2379                                 self.crouch = TRUE;
2380                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2381                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2382                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2383                         }
2384                 }
2385                 else
2386                 {
2387                         if (self.crouch)
2388                         {
2389                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2390                                 if (!trace_startsolid)
2391                                 {
2392                                         self.crouch = FALSE;
2393                                         self.view_ofs = PL_VIEW_OFS;
2394                                         setsize (self, PL_MIN, PL_MAX);
2395                                 }
2396                         }
2397                 }
2398
2399                 FixPlayermodel();
2400
2401                 GrapplingHookFrame();
2402
2403                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2404                 //if(frametime)
2405                 {
2406                         self.items &= ~self.items_added;
2407
2408                         W_WeaponFrame();
2409
2410                         self.items_added = 0;
2411                         if(self.items & IT_JETPACK)
2412                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2413                                         self.items_added |= IT_FUEL;
2414
2415                         self.items |= self.items_added;
2416                 }
2417
2418                 player_regen();
2419
2420                 // rot nex charge to the charge limit
2421                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2422                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2423
2424                 if(frametime)
2425                         player_anim();
2426
2427                 // secret status
2428                 secrets_setstatus();
2429
2430                 // monsters status
2431                 monsters_setstatus();
2432
2433                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2434
2435                 //self.angles_y=self.v_angle_y + 90;   // temp
2436         } else if(gameover) {
2437                 if (intermission_running)
2438                         IntermissionThink ();   // otherwise a button could be missed between
2439                 return;
2440         } else if(IS_OBSERVER(self)) {
2441                 ObserverThink();
2442         } else if(IS_SPEC(self)) {
2443                 SpectatorThink();
2444         }
2445
2446         if(!zoomstate_set)
2447                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2448
2449         float oldspectatee_status;
2450         oldspectatee_status = self.spectatee_status;
2451         if(IS_SPEC(self))
2452                 self.spectatee_status = num_for_edict(self.enemy);
2453         else if(IS_OBSERVER(self))
2454                 self.spectatee_status = num_for_edict(self);
2455         else
2456                 self.spectatee_status = 0;
2457         if(self.spectatee_status != oldspectatee_status)
2458         {
2459                 ClientData_Touch(self);
2460                 if(g_race || g_cts)
2461                         race_InitSpectator();
2462         }
2463
2464         if(self.teamkill_soundtime)
2465         if(time > self.teamkill_soundtime)
2466         {
2467                 self.teamkill_soundtime = 0;
2468
2469                 entity oldpusher, oldself;
2470
2471                 oldself = self; self = self.teamkill_soundsource;
2472                 oldpusher = self.pusher; self.pusher = oldself;
2473
2474                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2475
2476                 self.pusher = oldpusher;
2477                 self = oldself;
2478         }
2479
2480         if(self.taunt_soundtime)
2481         if(time > self.taunt_soundtime)
2482         {
2483                 self.taunt_soundtime = 0;
2484                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2485         }
2486
2487         target_voicescript_next(self);
2488
2489         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2490         if(!self.weapon)
2491                 self.clip_load = self.clip_size = 0;
2492 }
2493
2494 float isInvisibleString(string s)
2495 {
2496         float i, n, c;
2497         s = strdecolorize(s);
2498         for((i = 0), (n = strlen(s)); i < n; ++i)
2499         {
2500                 c = str2chr(s, i);
2501                 switch(c)
2502                 {
2503                         case 0:
2504                         case 32: // space
2505                                 break;
2506                         case 192: // charmap space
2507                                 if (!autocvar_utf8_enable)
2508                                         break;
2509                                 return FALSE;
2510                         case 160: // space in unicode fonts
2511                         case 0xE000 + 192: // utf8 charmap space
2512                                 if (autocvar_utf8_enable)
2513                                         break;
2514                         default:
2515                                 return FALSE;
2516                 }
2517         }
2518         return TRUE;
2519 }
2520
2521 /*
2522 =============
2523 PlayerPostThink
2524
2525 Called every frame for each client after the physics are run
2526 =============
2527 */
2528 .float idlekick_lasttimeleft;
2529 void PlayerPostThink (void)
2530 {
2531         // Savage: Check for nameless players
2532         if (isInvisibleString(self.netname)) {
2533                 self.netname = "Player";
2534                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2535         }
2536
2537         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2538         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2539         {
2540                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2541                 {
2542                         if(self.idlekick_lasttimeleft)
2543                         {
2544                                 self.idlekick_lasttimeleft = 0;
2545                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2546                         }
2547                 }
2548                 else
2549                 {
2550                         float timeleft;
2551                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2552                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2553                         {
2554                                 if(!self.idlekick_lasttimeleft)
2555                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2556                         }
2557                         if(timeleft <= 0)
2558                         {
2559                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2560                                 dropclient(self);
2561                                 return;
2562                         }
2563                         else if(timeleft <= 10)
2564                         {
2565                                 if(timeleft != self.idlekick_lasttimeleft)
2566                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2567                                 self.idlekick_lasttimeleft = timeleft;
2568                         }
2569                 }
2570         }
2571
2572 #ifdef TETRIS
2573         if(self.impulse == 100)
2574                 ImpulseCommands();
2575         if (!TetrisPostFrame())
2576         {
2577 #endif
2578
2579         CheatFrame();
2580
2581         //CheckPlayerJump();
2582
2583         if(IS_PLAYER(self)) {
2584                 CheckRules_Player();
2585                 UpdateChatBubble();
2586                 if (self.impulse)
2587                         ImpulseCommands();
2588                 if (intermission_running)
2589                         return;         // intermission or finale
2590                 GetPressedKeys();
2591         }
2592
2593 #ifdef TETRIS
2594         }
2595 #endif
2596
2597         /*
2598         float i;
2599         for(i = 0; i < 1000; ++i)
2600         {
2601                 vector end;
2602                 end = self.origin + '0 0 1024' + 512 * randomvec();
2603                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2604                 if(trace_fraction < 1)
2605                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2606                 {
2607                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2608                         break;
2609                 }
2610         }
2611         */
2612
2613         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2614
2615         if(self.waypointsprite_attachedforcarrier)
2616                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2617
2618         playerdemo_write();
2619
2620         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2621         {
2622                 if (!self.stored_netname)
2623                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2624                 if(self.stored_netname != self.netname)
2625                 {
2626                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2627                         strunzone(self.stored_netname);
2628                         self.stored_netname = strzone(self.netname);
2629                 }
2630         }
2631
2632         /*
2633         if(g_race)
2634                 dprintf("%f %.6f\n", time, race_GetFractionalLapCount(self));
2635         */
2636
2637         CSQCMODEL_AUTOUPDATE();
2638 }