qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143
 144         spot = SelectSpawnPoint (TRUE);
 145         if(!spot)
 146                 error("No spawnpoints for observers?!?\n");
 147         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 148
 149         if(IS_REAL_CLIENT(self))
 150         {
 151                 msg_entity = self;
 152                 WriteByte(MSG_ONE, SVC_SETVIEW);
 153                 WriteEntity(MSG_ONE, self);
 154         }
 155
 156         self.frags = FRAGS_SPECTATOR;
 157
 158         MUTATOR_CALLHOOK(MakePlayerObserver);
 159
 160         Portal_ClearAll(self);
 161
 162         if(self.alivetime)
 163         {
 164                 if(!warmup_stage)
 165                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 166                 self.alivetime = 0;
 167         }
 168
 169         if(self.vehicle)
 170                 vehicles_exit(VHEF_RELESE);
 171
 172         WaypointSprite_PlayerDead();
 173
 174         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 175                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 176
 177         if(self.killcount != -666)
 178         {
 179                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 180                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 181                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 182
 183                 if(self.just_joined == FALSE) {
 184                         LogTeamchange(self.playerid, -1, 4);
 185                 } else
 186                         self.just_joined = FALSE;
 187         }
 188
 189         PlayerScore_Clear(self); // clear scores when needed
 190
 191         accuracy_resend(self);
 192
 193         self.spectatortime = time;
 194
 195         self.classname = "observer";
 196         self.iscreature = FALSE;
 197         self.teleportable = TELEPORT_SIMPLE;
 198         self.damagedbycontents = FALSE;
 199         self.health = -666;
 200         self.takedamage = DAMAGE_NO;
 201         self.solid = SOLID_NOT;
 202         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 203         self.flags = FL_CLIENT | FL_NOTARGET;
 204         self.armorvalue = 666;
 205         self.effects = 0;
 206         self.armorvalue = autocvar_g_balance_armor_start;
 207         self.pauserotarmor_finished = 0;
 208         self.pauserothealth_finished = 0;
 209         self.pauseregen_finished = 0;
 210         self.damageforcescale = 0;
 211         self.death_time = 0;
 212         self.respawn_flags = 0;
 213         self.respawn_time = 0;
 214         self.stat_respawn_time = 0;
 215         self.alpha = 0;
 216         self.scale = 0;
 217         self.fade_time = 0;
 218         self.pain_frame = 0;
 219         self.pain_finished = 0;
 220         self.strength_finished = 0;
 221         self.invincible_finished = 0;
 222         self.superweapons_finished = 0;
 223         self.pushltime = 0;
 224         self.istypefrag = 0;
 225         self.think = func_null;
 226         self.nextthink = 0;
 227         self.hook_time = 0;
 228         self.deadflag = DEAD_NO;
 229         self.angles = spot.angles;
 230         self.angles_z = 0;
 231         self.fixangle = TRUE;
 232         self.crouch = FALSE;
 233
 234         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 235         self.prevorigin = self.origin;
 236         self.items = 0;
 237         self.weapons = '0 0 0';
 238         self.model = "";
 239         FixPlayermodel();
 240         setmodel(self, "null");
 241         self.drawonlytoclient = self;
 242
 243         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 244         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 245
 246         self.weapon = 0;
 247         self.weaponname = "";
 248         self.switchingweapon = 0;
 249         self.weaponmodel = "";
 250         self.weaponentity = world;
 251         self.exteriorweaponentity = world;
 252         self.killcount = -666;
 253         self.velocity = '0 0 0';
 254         self.avelocity = '0 0 0';
 255         self.punchangle = '0 0 0';
 256         self.punchvector = '0 0 0';
 257         self.oldvelocity = self.velocity;
 258         self.fire_endtime = -1;
 259 }
 260
 261 .float model_randomizer;
 262 void FixPlayermodel()
 263 {
 264         string defaultmodel;
 265         float defaultskin, chmdl, oldskin, n, i;
 266         vector m1, m2;
 267
 268         defaultmodel = "";
 269         defaultskin = 0;
 270         chmdl = FALSE;
 271
 272         if(autocvar_sv_defaultcharacter == 1)
 273         {
 274                 if(teamplay)
 275                 {
 276                         string s;
 277                         s = Team_ColorName_Lower(self.team);
 278                         if(s != "neutral")
 279                         {
 280                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 281                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 282                         }
 283                 }
 284
 285                 if(defaultmodel == "")
 286                 {
 287                         defaultmodel = autocvar_sv_defaultplayermodel;
 288                         defaultskin = autocvar_sv_defaultplayerskin;
 289                 }
 290
 291                 n = tokenize_console(defaultmodel);
 292                 if(n > 0)
 293                 {
 294                         defaultmodel = argv(floor(n * self.model_randomizer));
 295                         // However, do NOT randomize if the player-selected model is in the list.
 296                         for (i = 0; i < n; ++i)
 297                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 298                                         defaultmodel = argv(i);
 299                 }
 300
 301                 i = strstrofs(defaultmodel, ":", 0);
 302                 if(i >= 0)
 303                 {
 304                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 305                         defaultmodel = substring(defaultmodel, 0, i);
 306                 }
 307         }
 308
 309         if(defaultmodel != "")
 310         {
 311                 if (defaultmodel != self.model)
 312                 {
 313                         m1 = self.mins;
 314                         m2 = self.maxs;
 315                         setplayermodel (self, defaultmodel);
 316                         setsize (self, m1, m2);
 317                         chmdl = TRUE;
 318                 }
 319
 320                 oldskin = self.skin;
 321                 self.skin = defaultskin;
 322         } else {
 323                 if (self.playermodel != self.model || self.playermodel == "")
 324                 {
 325                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 326                         m1 = self.mins;
 327                         m2 = self.maxs;
 328                         setplayermodel (self, self.playermodel);
 329                         setsize (self, m1, m2);
 330                         chmdl = TRUE;
 331                 }
 332
 333                 oldskin = self.skin;
 334                 self.skin = stof(self.playerskin);
 335         }
 336
 337         if(chmdl || oldskin != self.skin) // model or skin has changed
 338         {
 339                 self.species = player_getspecies(); // update species
 340                 UpdatePlayerSounds(); // update skin sounds
 341         }
 342
 343         if(!teamplay)
 344                 if(strlen(autocvar_sv_defaultplayercolors))
 345                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 346                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 347 }
 348
 349 /*
 350 =============
 351 PutClientInServer
 352
 353 Called when a client spawns in the server
 354 =============
 355 */
 356 void PutClientInServer (void)
 357 {
 358         if(IS_BOT_CLIENT(self))
 359                 self.classname = "player";
 360         else if(IS_REAL_CLIENT(self))
 361         {
 362                 msg_entity = self;
 363                 WriteByte(MSG_ONE, SVC_SETVIEW);
 364                 WriteEntity(MSG_ONE, self);
 365         }
 366
 367         // reset player keys
 368         self.itemkeys = 0;
 369
 370         MUTATOR_CALLHOOK(PutClientInServer);
 371
 372         if(gameover)
 373                 self.classname = "observer";
 374
 375         if(IS_PLAYER(self))
 376         {
 377                 entity spot, oldself;
 378                 float j;
 379
 380                 accuracy_resend(self);
 381
 382                 if(self.team < 0)
 383                         JoinBestTeam(self, FALSE, TRUE);
 384
 385                 spot = SelectSpawnPoint (FALSE);
 386                 if(!spot)
 387                 {
 388                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 389                         return; // spawn failed
 390                 }
 391
 392                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394                 if(self.vehicle)
 395                         vehicles_exit(VHEF_RELESE);
 396
 397                 self.classname = "player";
 398                 self.wasplayer = TRUE;
 399                 self.iscreature = TRUE;
 400                 self.teleportable = TELEPORT_NORMAL;
 401                 self.damagedbycontents = TRUE;
 402                 self.movetype = MOVETYPE_WALK;
 403                 self.solid = SOLID_SLIDEBOX;
 404                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 405                 if(autocvar_g_playerclip_collisions)
 406                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 407                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 409                 self.frags = FRAGS_PLAYER;
 410                 if(INDEPENDENT_PLAYERS)
 411                         MAKE_INDEPENDENT_PLAYER(self);
 412                 self.flags = FL_CLIENT;
 413                 if(autocvar__notarget)
 414                         self.flags |= FL_NOTARGET;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 if(autocvar_g_balance_nex_charge)
 421                 {
 422                         if(autocvar_g_balance_nex_secondary_chargepool)
 423                                 self.nex_chargepool_ammo = 1;
 424                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 425                 }
 426
 427                 if(warmup_stage)
 428                 {
 429                         self.ammo_shells = warmup_start_ammo_shells;
 430                         self.ammo_nails = warmup_start_ammo_nails;
 431                         self.ammo_rockets = warmup_start_ammo_rockets;
 432                         self.ammo_cells = warmup_start_ammo_cells;
 433                         self.ammo_fuel = warmup_start_ammo_fuel;
 434                         self.health = warmup_start_health;
 435                         self.armorvalue = warmup_start_armorvalue;
 436                         self.weapons = WARMUP_START_WEAPONS;
 437                 }
 438                 else
 439                 {
 440                         self.ammo_shells = start_ammo_shells;
 441                         self.ammo_nails = start_ammo_nails;
 442                         self.ammo_rockets = start_ammo_rockets;
 443                         self.ammo_cells = start_ammo_cells;
 444                         self.ammo_fuel = start_ammo_fuel;
 445                         self.health = start_health;
 446                         self.armorvalue = start_armorvalue;
 447                         self.weapons = start_weapons;
 448                 }
 449
 450                 if(self.weapons & WEPSET_SUPERWEAPONS)
 451                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 452                 else
 453                         self.superweapons_finished = 0;
 454
 455                 if(g_weaponarena_random)
 456                 {
 457                         if(g_weaponarena_random_with_laser)
 458                                 self.weapons &= ~WEPSET_LASER;
 459                         W_RandomWeapons(self, g_weaponarena_random);
 460                         if(g_weaponarena_random_with_laser)
 461                                 self.weapons |= WEPSET_LASER;
 462                 }
 463
 464                 self.items = start_items;
 465
 466                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 467                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 468                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 469                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 470                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 471                 //extend the pause of rotting if client was reset at the beginning of the countdown
 472                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 473                         self.spawnshieldtime += game_starttime - time;
 474                         self.pauserotarmor_finished += game_starttime - time;
 475                         self.pauserothealth_finished += game_starttime - time;
 476                         self.pauseregen_finished += game_starttime - time;
 477                 }
 478                 self.damageforcescale = 2;
 479                 self.death_time = 0;
 480                 self.respawn_flags = 0;
 481                 self.respawn_time = 0;
 482                 self.stat_respawn_time = 0;
 483                 self.scale = 0;
 484                 self.fade_time = 0;
 485                 self.pain_frame = 0;
 486                 self.pain_finished = 0;
 487                 self.strength_finished = 0;
 488                 self.invincible_finished = 0;
 489                 self.pushltime = 0;
 490                 // players have no think function
 491                 self.think = func_null;
 492                 self.nextthink = 0;
 493                 self.hook_time = 0;
 494                 self.dmg_team = 0;
 495                 self.ballistics_density = autocvar_g_ballistics_density_player;
 496
 497                 self.metertime = 0;
 498
 499                 self.deadflag = DEAD_NO;
 500
 501                 self.angles = spot.angles;
 502
 503                 self.angles_z = 0; // never spawn tilted even if the spot says to
 504                 self.fixangle = TRUE; // turn this way immediately
 505                 self.velocity = '0 0 0';
 506                 self.avelocity = '0 0 0';
 507                 self.punchangle = '0 0 0';
 508                 self.punchvector = '0 0 0';
 509                 self.oldvelocity = self.velocity;
 510                 self.fire_endtime = -1;
 511
 512                 entity spawnevent = spawn();
 513                 spawnevent.owner = self;
 514                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 515
 516                 self.model = "";
 517                 FixPlayermodel();
 518                 self.drawonlytoclient = world;
 519
 520                 self.crouch = FALSE;
 521                 self.view_ofs = PL_VIEW_OFS;
 522                 setsize (self, PL_MIN, PL_MAX);
 523                 self.spawnorigin = spot.origin;
 524                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 525                 // don't reset back to last position, even if new position is stuck in solid
 526                 self.oldorigin = self.origin;
 527                 self.prevorigin = self.origin;
 528                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 529                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 530         self.hud = HUD_NORMAL;
 531
 532                 self.event_damage = PlayerDamage;
 533
 534                 self.bot_attack = TRUE;
 535                 self.monster_attack = TRUE;
 536
 537                 self.spider_slowness = 0;
 538
 539                 self.statdraintime = time + 5;
 540                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 541
 542                 if(self.killcount == -666) {
 543                         PlayerScore_Clear(self);
 544                         self.killcount = 0;
 545                 }
 546
 547                 CL_SpawnWeaponentity();
 548                 self.alpha = default_player_alpha;
 549                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 550                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 551
 552                 self.speedrunning = FALSE;
 553
 554                 //stuffcmd(self, "chase_active 0");
 555                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 556
 557                 target_voicescript_clear(self);
 558
 559                 // reset fields the weapons may use
 560                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 561                 {
 562                         weapon_action(j, WR_RESETPLAYER);
 563
 564                         // all weapons must be fully loaded when we spawn
 565                         entity e;
 566                         e = get_weaponinfo(j);
 567                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 568                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 569                 }
 570
 571                 oldself = self;
 572                 self = spot;
 573                         activator = oldself;
 574                                 string s;
 575                                 s = self.target;
 576                                 self.target = string_null;
 577                                 SUB_UseTargets();
 578                                 self.target = s;
 579                         activator = world;
 580                 self = oldself;
 581
 582                 spawn_spot = spot;
 583                 MUTATOR_CALLHOOK(PlayerSpawn);
 584
 585                 if(autocvar_spawn_debug)
 586                 {
 587                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 588                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 589                 }
 590
 591                 self.switchweapon = w_getbestweapon(self);
 592                 self.cnt = -1; // W_LastWeapon will not complain
 593                 self.weapon = 0;
 594                 self.weaponname = "";
 595                 self.switchingweapon = 0;
 596
 597                 if(!warmup_stage)
 598                         if(!self.alivetime)
 599                                 self.alivetime = time;
 600
 601                 antilag_clear(self);
 602         }
 603         else if(IS_OBSERVER(self))
 604         {
 605                 PutObserverInServer ();
 606         }
 607 }
 608
 609 .float ebouncefactor, ebouncestop; // electro's values
 610 // TODO do we need all these fields, or should we stop autodetecting runtime
 611 // changes and just have a console command to update this?
 612 float ClientInit_SendEntity(entity to, float sf)
 613 {
 614         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 615         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 628         if(sv_foginterval && world.fog != "")
 629                 WriteString(MSG_ENTITY, world.fog);
 630         else
 631                 WriteString(MSG_ENTITY, "");
 632         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 633         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 634         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 635         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 636         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 637         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 638         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 639         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 641         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 642         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 644         return TRUE;
 645 }
 646
 647 void ClientInit_CheckUpdate()
 648 {
 649         self.nextthink = time;
 650         if(self.count != autocvar_g_balance_armor_blockpercent)
 651         {
 652                 self.count = autocvar_g_balance_armor_blockpercent;
 653                 self.SendFlags |= 1;
 654         }
 655         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 656         {
 657                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 658                 self.SendFlags |= 1;
 659         }
 660         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 661         {
 662                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 666         {
 667                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 671         {
 672                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 673                 self.SendFlags |= 1;
 674         }
 675 }
 676
 677 void ClientInit_Spawn()
 678 {
 679         entity o;
 680         entity e;
 681         e = spawn();
 682         e.classname = "clientinit";
 683         e.think = ClientInit_CheckUpdate;
 684         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 685
 686         o = self;
 687         self = e;
 688         ClientInit_CheckUpdate();
 689         self = o;
 690 }
 691
 692 /*
 693 =============
 694 SetNewParms
 695 =============
 696 */
 697 void SetNewParms (void)
 698 {
 699         // initialize parms for a new player
 700         parm1 = -(86400 * 366);
 701 }
 702
 703 /*
 704 =============
 705 SetChangeParms
 706 =============
 707 */
 708 void SetChangeParms (void)
 709 {
 710         // save parms for level change
 711         parm1 = self.parm_idlesince - time;
 712 }
 713
 714 /*
 715 =============
 716 DecodeLevelParms
 717 =============
 718 */
 719 void DecodeLevelParms (void)
 720 {
 721         // load parms
 722         self.parm_idlesince = parm1;
 723         if(self.parm_idlesince == -(86400 * 366))
 724                 self.parm_idlesince = time;
 725
 726         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 727         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 728 }
 729
 730 /*
 731 =============
 732 ClientKill
 733
 734 Called when a client types 'kill' in the console
 735 =============
 736 */
 737
 738 .float clientkill_nexttime;
 739 void ClientKill_Now_TeamChange()
 740 {
 741         if(self.killindicator_teamchange == -1)
 742         {
 743                 JoinBestTeam( self, FALSE, TRUE );
 744         }
 745         else if(self.killindicator_teamchange == -2)
 746         {
 747                 if(blockSpectators)
 748                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 749                 PutObserverInServer();
 750         }
 751         else
 752                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 753         self.killindicator_teamchange = 0;
 754 }
 755
 756 void ClientKill_Now()
 757 {
 758         if(self.vehicle)
 759         {
 760             vehicles_exit(VHEF_RELESE);
 761             if(!self.killindicator_teamchange)
 762             {
 763             self.vehicle_health = -1;
 764             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 765             }
 766         }
 767
 768         if(self.killindicator && !wasfreed(self.killindicator))
 769                 remove(self.killindicator);
 770
 771         self.killindicator = world;
 772
 773         if(self.killindicator_teamchange)
 774                 ClientKill_Now_TeamChange();
 775
 776         // in any case:
 777         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 778
 779         // now I am sure the player IS dead
 780 }
 781 void KillIndicator_Think()
 782 {
 783         if (gameover)
 784         {
 785                 self.owner.killindicator = world;
 786                 remove(self);
 787                 return;
 788         }
 789
 790         if (self.owner.alpha < 0 && !self.owner.vehicle)
 791         {
 792                 self.owner.killindicator = world;
 793                 remove(self);
 794                 return;
 795         }
 796
 797         if(self.cnt <= 0)
 798         {
 799                 self = self.owner;
 800                 ClientKill_Now(); // no oldself needed
 801                 return;
 802         }
 803     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 804     {
 805         self.nextthink = time + 1;
 806         self.cnt -= 1;
 807     }
 808         else
 809         {
 810                 if(self.cnt <= 10)
 811                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 812                 if(IS_REAL_CLIENT(self.owner))
 813                 {
 814                         if(self.cnt <= 10)
 815                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 816                 }
 817                 self.nextthink = time + 1;
 818                 self.cnt -= 1;
 819         }
 820 }
 821
 822 float clientkilltime;
 823 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 824 {
 825         float killtime;
 826         float starttime;
 827         entity e;
 828
 829         if (gameover)
 830                 return;
 831
 832         killtime = autocvar_g_balance_kill_delay;
 833
 834         if(g_race_qualifying || g_cts)
 835                 killtime = 0;
 836
 837     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 838     {
 839                 remove(self.killindicator);
 840                 self.killindicator = world;
 841
 842         ClientKill_Now(); // allow instant kill in this case
 843         return;
 844     }
 845
 846         self.killindicator_teamchange = targetteam;
 847
 848     if(!self.killindicator)
 849         {
 850                 if(self.deadflag == DEAD_NO)
 851                 {
 852                         killtime = max(killtime, self.clientkill_nexttime - time);
 853                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 854                 }
 855
 856                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 857                 {
 858                         ClientKill_Now();
 859                 }
 860                 else
 861                 {
 862                         starttime = max(time, clientkilltime);
 863
 864                         self.killindicator = spawn();
 865                         self.killindicator.owner = self;
 866                         self.killindicator.scale = 0.5;
 867                         setattachment(self.killindicator, self, "");
 868                         setorigin(self.killindicator, '0 0 52');
 869                         self.killindicator.think = KillIndicator_Think;
 870                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 871                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 872                         self.killindicator.cnt = ceil(killtime);
 873                         self.killindicator.count = bound(0, ceil(killtime), 10);
 874                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 875
 876                         for(e = world; (e = find(e, classname, "body")) != world; )
 877                         {
 878                                 if(e.enemy != self)
 879                                         continue;
 880                                 e.killindicator = spawn();
 881                                 e.killindicator.owner = e;
 882                                 e.killindicator.scale = 0.5;
 883                                 setattachment(e.killindicator, e, "");
 884                                 setorigin(e.killindicator, '0 0 52');
 885                                 e.killindicator.think = KillIndicator_Think;
 886                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 887                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 888                                 e.killindicator.cnt = ceil(killtime);
 889                         }
 890                         self.lip = 0;
 891                 }
 892         }
 893         if(self.killindicator)
 894         {
 895                 if(targetteam == 0) // just die
 896                 {
 897                         self.killindicator.colormod = '0 0 0';
 898                         if(IS_REAL_CLIENT(self))
 899                         if(self.killindicator.cnt > 0)
 900                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 901                 }
 902                 else if(targetteam == -1) // auto
 903                 {
 904                         self.killindicator.colormod = '0 1 0';
 905                         if(IS_REAL_CLIENT(self))
 906                         if(self.killindicator.cnt > 0)
 907                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 908                 }
 909                 else if(targetteam == -2) // spectate
 910                 {
 911                         self.killindicator.colormod = '0.5 0.5 0.5';
 912                         if(IS_REAL_CLIENT(self))
 913                         if(self.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 915                 }
 916                 else
 917                 {
 918                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 919                         if(IS_REAL_CLIENT(self))
 920                         if(self.killindicator.cnt > 0)
 921                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 922                 }
 923         }
 924
 925 }
 926
 927 void ClientKill (void)
 928 {
 929         if(gameover) return;
 930         if(self.player_blocked) return;
 931         if(self.freezetag_frozen) return;
 932
 933         ClientKill_TeamChange(0);
 934 }
 935
 936 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 937 {
 938     e.killindicator = spawn();
 939     e.killindicator.owner = e;
 940     e.killindicator.think = KillIndicator_Think;
 941     e.killindicator.nextthink = time + (e.lip) * 0.05;
 942     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 943     e.killindicator.health = 1; // this is used to indicate that it should be silent
 944     e.lip = 0;
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         stuffcmd(e, "\nin_bindmap 0 0\n");
 951         if(g_race || g_cts)
 952                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 953         if(autocvar_g_antilag == 3) // client side hitscan
 954                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 955         if(autocvar_sv_gentle)
 956                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 957         /*
 958          * we no longer need to stuff this. Remove this comment block if you feel
 959          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 960         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 961         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 962         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 963         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 964         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 965         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 966         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 967         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 968         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 969         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 970         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 972         stuffcmd(e, "cl_movement_edgefriction 1\n");
 973          */
 974 }
 975
 976 float PlayerInIDList(entity p, string idlist)
 977 {
 978         float n, i;
 979         string s;
 980
 981         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 982         if (!p.crypto_idfp)
 983                 return 0;
 984
 985         // this function allows abbreviated player IDs too!
 986         n = tokenize_console(idlist);
 987         for(i = 0; i < n; ++i)
 988         {
 989                 s = argv(i);
 990                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 991                         return 1;
 992         }
 993
 994         return 0;
 995 }
 996
 997 /*
 998 =============
 999 ClientConnect
1000
1001 Called when a client connects to the server
1002 =============
1003 */
1004 void DecodeLevelParms (void);
1005 //void dom_player_join_team(entity pl);
1006 void set_dom_state(entity e);
1007 void ClientConnect (void)
1008 {
1009         float t;
1010
1011         if(IS_CLIENT(self))
1012         {
1013                 print("Warning: ClientConnect, but already connected!\n");
1014                 return;
1015         }
1016
1017         if(Ban_MaybeEnforceBanOnce(self))
1018                 return;
1019
1020         DecodeLevelParms();
1021
1022 #ifdef WATERMARK
1023         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1024 #endif
1025
1026         self.classname = "player_joining";
1027
1028         self.flags = FL_CLIENT;
1029         self.version_nagtime = time + 10 + random() * 10;
1030
1031         if(player_count<0)
1032         {
1033                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1034                 player_count = 0;
1035         }
1036
1037         PlayerScore_Attach(self);
1038         ClientData_Attach();
1039         accuracy_init(self);
1040
1041         bot_clientconnect();
1042
1043         playerdemo_init();
1044
1045         anticheat_init();
1046
1047         // identify the right forced team
1048         if(autocvar_g_campaign)
1049         {
1050                 if(IS_REAL_CLIENT(self)) // only players, not bots
1051                 {
1052                         switch(autocvar_g_campaign_forceteam)
1053                         {
1054                                 case 1: self.team_forced = NUM_TEAM_1; break;
1055                                 case 2: self.team_forced = NUM_TEAM_2; break;
1056                                 case 3: self.team_forced = NUM_TEAM_3; break;
1057                                 case 4: self.team_forced = NUM_TEAM_4; break;
1058                                 default: self.team_forced = 0;
1059                         }
1060                 }
1061         }
1062         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1063                 self.team_forced = NUM_TEAM_1;
1064         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1065                 self.team_forced = NUM_TEAM_2;
1066         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1067                 self.team_forced = NUM_TEAM_3;
1068         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1069                 self.team_forced = NUM_TEAM_4;
1070         else if(autocvar_g_forced_team_otherwise == "red")
1071                 self.team_forced = NUM_TEAM_1;
1072         else if(autocvar_g_forced_team_otherwise == "blue")
1073                 self.team_forced = NUM_TEAM_2;
1074         else if(autocvar_g_forced_team_otherwise == "yellow")
1075                 self.team_forced = NUM_TEAM_3;
1076         else if(autocvar_g_forced_team_otherwise == "pink")
1077                 self.team_forced = NUM_TEAM_4;
1078         else if(autocvar_g_forced_team_otherwise == "spectate")
1079                 self.team_forced = -1;
1080         else if(autocvar_g_forced_team_otherwise == "spectator")
1081                 self.team_forced = -1;
1082         else
1083                 self.team_forced = 0;
1084
1085         if(!teamplay)
1086                 if(self.team_forced > 0)
1087                         self.team_forced = 0;
1088
1089         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1090
1091         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1092                 self.classname = "observer";
1093         } else {
1094                 if(teamplay)
1095                 {
1096                         if(autocvar_g_balance_teams)
1097                         {
1098                                 self.classname = "player";
1099                                 campaign_bots_may_start = 1;
1100                         }
1101                         else
1102                         {
1103                                 self.classname = "observer"; // do it anyway
1104                         }
1105                 }
1106                 else
1107                 {
1108                         self.classname = "player";
1109                         campaign_bots_may_start = 1;
1110                 }
1111         }
1112
1113         self.playerid = (playerid_last = playerid_last + 1);
1114
1115         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1116
1117     if(IS_BOT_CLIENT(self))
1118         PlayerStats_AddPlayer(self);
1119
1120         if(autocvar_sv_eventlog)
1121                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1122
1123         LogTeamchange(self.playerid, self.team, 1);
1124
1125         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1126
1127         self.netname_previous = strzone(self.netname);
1128
1129         if(IS_PLAYER(self) && teamplay)
1130                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1131         else
1132                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1133
1134         stuffcmd(self, strcat(clientstuff, "\n"));
1135         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1136
1137         FixClientCvars(self);
1138
1139         // spawnfunc_waypoint sprites
1140         WaypointSprite_InitClient(self);
1141
1142         // Wazat's grappling hook
1143         SetGrappleHookBindings();
1144
1145         // get version info from player
1146         stuffcmd(self, "cmd clientversion $gameversion\n");
1147
1148         // get other cvars from player
1149         GetCvars(0);
1150
1151         // notify about available teams
1152         if(teamplay)
1153         {
1154                 CheckAllowedTeams(self);
1155                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1156                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1157         }
1158         else
1159                 stuffcmd(self, "set _teams_available 0\n");
1160
1161         attach_entcs();
1162
1163         bot_relinkplayerlist();
1164
1165         self.spectatortime = time;
1166         if(blockSpectators)
1167         {
1168                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1169         }
1170
1171         self.jointime = time;
1172         self.allowed_timeouts = autocvar_sv_timeout_number;
1173
1174         if(IS_REAL_CLIENT(self))
1175         {
1176                 if(!autocvar_g_campaign)
1177                 {
1178                         self.motd_actived_time = -1;
1179                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1180                 }
1181
1182                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1183                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1184         }
1185
1186         if(!sv_foginterval && world.fog != "")
1187                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1188
1189         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1190         {
1191                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1192                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1193         }
1194         else
1195                 self.hitplotfh = -1;
1196
1197         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1198                 send_CSQC_teamnagger();
1199
1200         CheatInitClient();
1201
1202         CSQCMODEL_AUTOINIT();
1203
1204         self.model_randomizer = random();
1205
1206         if(IS_REAL_CLIENT(self))
1207                 sv_notice_join();
1208
1209         MUTATOR_CALLHOOK(ClientConnect);
1210 }
1211 /*
1212 =============
1213 ClientDisconnect
1214
1215 Called when a client disconnects from the server
1216 =============
1217 */
1218 .entity chatbubbleentity;
1219 void ReadyCount();
1220 void ClientDisconnect (void)
1221 {
1222         if(self.vehicle)
1223             vehicles_exit(VHEF_RELESE);
1224
1225         if (!IS_CLIENT(self))
1226         {
1227                 print("Warning: ClientDisconnect without ClientConnect\n");
1228                 return;
1229         }
1230
1231         PlayerStats_AddGlobalInfo(self);
1232
1233         CheatShutdownClient();
1234
1235         if(self.hitplotfh >= 0)
1236         {
1237                 fclose(self.hitplotfh);
1238                 self.hitplotfh = -1;
1239         }
1240
1241         anticheat_report();
1242         anticheat_shutdown();
1243
1244         playerdemo_shutdown();
1245
1246         bot_clientdisconnect();
1247
1248         if(self.entcs)
1249                 detach_entcs();
1250
1251         if(autocvar_sv_eventlog)
1252                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1253
1254         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1255
1256         MUTATOR_CALLHOOK(ClientDisconnect);
1257
1258         Portal_ClearAll(self);
1259
1260         RemoveGrapplingHook(self);
1261
1262         // Here, everything has been done that requires this player to be a client.
1263
1264         self.flags &= ~FL_CLIENT;
1265
1266         if (self.chatbubbleentity)
1267                 remove (self.chatbubbleentity);
1268
1269         if (self.killindicator)
1270                 remove (self.killindicator);
1271
1272         WaypointSprite_PlayerGone();
1273
1274         bot_relinkplayerlist();
1275
1276         accuracy_free(self);
1277         ClientData_Detach();
1278         PlayerScore_Detach(self);
1279
1280         if(self.netname_previous)
1281                 strunzone(self.netname_previous);
1282         if(self.clientstatus)
1283                 strunzone(self.clientstatus);
1284         if(self.weaponorder_byimpulse)
1285                 strunzone(self.weaponorder_byimpulse);
1286
1287         ClearPlayerSounds();
1288
1289         if(self.personal)
1290                 remove(self.personal);
1291
1292         self.playerid = 0;
1293         ReadyCount();
1294
1295         // free cvars
1296         GetCvars(-1);
1297 }
1298
1299 .float BUTTON_CHAT;
1300 void ChatBubbleThink()
1301 {
1302         self.nextthink = time;
1303         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1304         {
1305                 if(self.owner) // but why can that ever be world?
1306                         self.owner.chatbubbleentity = world;
1307                 remove(self);
1308                 return;
1309         }
1310         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1311 #ifdef TETRIS
1312                 || self.owner.tetris_on
1313 #endif
1314         )
1315                 self.model = self.mdl;
1316         else
1317                 self.model = "";
1318 }
1319
1320 void UpdateChatBubble()
1321 {
1322         if (self.alpha < 0)
1323                 return;
1324         // spawn a chatbubble entity if needed
1325         if (!self.chatbubbleentity)
1326         {
1327                 self.chatbubbleentity = spawn();
1328                 self.chatbubbleentity.owner = self;
1329                 self.chatbubbleentity.exteriormodeltoclient = self;
1330                 self.chatbubbleentity.think = ChatBubbleThink;
1331                 self.chatbubbleentity.nextthink = time;
1332                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1333                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1334                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1335                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1336                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1337                 self.chatbubbleentity.model = "";
1338                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1339         }
1340 }
1341
1342
1343 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1344 // added to the model skins
1345 /*void UpdateColorModHack()
1346 {
1347         float c;
1348         c = self.clientcolors & 15;
1349         // LordHavoc: only bothering to support white, green, red, yellow, blue
1350              if (!teamplay) self.colormod = '0 0 0';
1351         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1352         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1353         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1354         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1355         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1356         else self.colormod = '1 1 1';
1357 }*/
1358
1359 void respawn(void)
1360 {
1361         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1362         {
1363                 self.solid = SOLID_NOT;
1364                 self.takedamage = DAMAGE_NO;
1365                 self.movetype = MOVETYPE_FLY;
1366                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1367                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1368                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1369                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1370                 if(autocvar_g_respawn_ghosts_maxtime)
1371                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1372         }
1373
1374         CopyBody(1);
1375
1376         self.effects |= EF_NODRAW; // prevent another CopyBody
1377         PutClientInServer();
1378 }
1379
1380 void play_countdown(float finished, string samp)
1381 {
1382         if(IS_REAL_CLIENT(self))
1383                 if(floor(finished - time - frametime) != floor(finished - time))
1384                         if(finished - time < 6)
1385                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1386 }
1387
1388 void player_powerups (void)
1389 {
1390         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1391         olditems = self.items;
1392
1393         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1394                 self.modelflags |= MF_ROCKET;
1395         else
1396                 self.modelflags &= ~MF_ROCKET;
1397
1398         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1399
1400         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1401                 return;
1402
1403         Fire_ApplyDamage(self);
1404         Fire_ApplyEffect(self);
1405
1406         if (!g_minstagib)
1407         {
1408                 if (self.items & IT_STRENGTH)
1409                 {
1410                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1411                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1412                         if (time > self.strength_finished)
1413                         {
1414                                 self.items = self.items - (self.items & IT_STRENGTH);
1415                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1416                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1417                         }
1418                 }
1419                 else
1420                 {
1421                         if (time < self.strength_finished)
1422                         {
1423                                 self.items = self.items | IT_STRENGTH;
1424                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1425                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1426                         }
1427                 }
1428                 if (self.items & IT_INVINCIBLE)
1429                 {
1430                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1431                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1432                         if (time > self.invincible_finished)
1433                         {
1434                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1435                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1436                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1437                         }
1438                 }
1439                 else
1440                 {
1441                         if (time < self.invincible_finished)
1442                         {
1443                                 self.items = self.items | IT_INVINCIBLE;
1444                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1445                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1446                         }
1447                 }
1448                 if (self.items & IT_SUPERWEAPON)
1449                 {
1450                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1451                         {
1452                                 self.superweapons_finished = 0;
1453                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1454                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1455                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1456                         }
1457                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1458                         {
1459                                 // don't let them run out
1460                         }
1461                         else
1462                         {
1463                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1464                                 if (time > self.superweapons_finished)
1465                                 {
1466                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1467                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1468                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1469                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1470                                 }
1471                         }
1472                 }
1473                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1474                 {
1475                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1476                         {
1477                                 self.items = self.items | IT_SUPERWEAPON;
1478                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1479                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1480                         }
1481                         else
1482                         {
1483                                 self.superweapons_finished = 0;
1484                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1485                         }
1486                 }
1487                 else
1488                 {
1489                         self.superweapons_finished = 0;
1490                 }
1491         }
1492
1493         if(autocvar_g_nodepthtestplayers)
1494                 self.effects = self.effects | EF_NODEPTHTEST;
1495
1496         if(autocvar_g_fullbrightplayers)
1497                 self.effects = self.effects | EF_FULLBRIGHT;
1498
1499         if (time >= game_starttime)
1500         if (time < self.spawnshieldtime)
1501                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1502
1503         MUTATOR_CALLHOOK(PlayerPowerups);
1504 }
1505
1506 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1507 {
1508         if(current > stable)
1509                 return current;
1510         else if(current > stable - 0.25) // when close enough, "snap"
1511                 return stable;
1512         else
1513                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1514 }
1515
1516 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1517 {
1518         if(current < stable)
1519                 return current;
1520         else if(current < stable + 0.25) // when close enough, "snap"
1521                 return stable;
1522         else
1523                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1524 }
1525
1526 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1527 {
1528         if(current > rotstable)
1529         {
1530                 if(rotframetime > 0)
1531                 {
1532                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1533                         current = max(rotstable, current - rotlinear * rotframetime);
1534                 }
1535         }
1536         else if(current < regenstable)
1537         {
1538                 if(regenframetime > 0)
1539                 {
1540                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1541                         current = min(regenstable, current + regenlinear * regenframetime);
1542                 }
1543         }
1544
1545         if(current > limit)
1546                 current = limit;
1547
1548         return current;
1549 }
1550
1551 void player_regen (void)
1552 {
1553         if(!MUTATOR_CALLHOOK(PlayerRegen))
1554         {
1555                 float minh, mina, maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1556                 maxh = autocvar_g_balance_health_rotstable;
1557                 maxa = autocvar_g_balance_armor_rotstable;
1558                 minh = autocvar_g_balance_health_regenstable;
1559                 mina = autocvar_g_balance_armor_regenstable;
1560                 limith = autocvar_g_balance_health_limit;
1561                 limita = autocvar_g_balance_armor_limit;
1562
1563                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1564
1565                 maxh = maxh * max_mod;
1566                 minh = minh * max_mod;
1567                 limith = limith * limit_mod;
1568                 limita = limita * limit_mod;
1569
1570                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1571                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1572         }
1573
1574         // if player rotted to death...  die!
1575         // check this outside above checks, as player may still be able to rot to death
1576         if(self.health < 1)
1577                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1578
1579         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1580         {
1581                 float minf, maxf, limitf;
1582
1583                 maxf = autocvar_g_balance_fuel_rotstable;
1584                 minf = autocvar_g_balance_fuel_regenstable;
1585                 limitf = autocvar_g_balance_fuel_limit;
1586
1587                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1588         }
1589 }
1590
1591 float zoomstate_set;
1592 void SetZoomState(float z)
1593 {
1594         if(z != self.zoomstate)
1595         {
1596                 self.zoomstate = z;
1597                 ClientData_Touch(self);
1598         }
1599         zoomstate_set = 1;
1600 }
1601
1602 void GetPressedKeys(void) {
1603         MUTATOR_CALLHOOK(GetPressedKeys);
1604         if (self.movement_x > 0) // get if movement keys are pressed
1605         {       // forward key pressed
1606                 self.pressedkeys |= KEY_FORWARD;
1607                 self.pressedkeys &= ~KEY_BACKWARD;
1608         }
1609         else if (self.movement_x < 0)
1610         {       // backward key pressed
1611                 self.pressedkeys |= KEY_BACKWARD;
1612                 self.pressedkeys &= ~KEY_FORWARD;
1613         }
1614         else
1615         {       // no x input
1616                 self.pressedkeys &= ~KEY_FORWARD;
1617                 self.pressedkeys &= ~KEY_BACKWARD;
1618         }
1619
1620         if (self.movement_y > 0)
1621         {       // right key pressed
1622                 self.pressedkeys |= KEY_RIGHT;
1623                 self.pressedkeys &= ~KEY_LEFT;
1624         }
1625         else if (self.movement_y < 0)
1626         {       // left key pressed
1627                 self.pressedkeys |= KEY_LEFT;
1628                 self.pressedkeys &= ~KEY_RIGHT;
1629         }
1630         else
1631         {       // no y input
1632                 self.pressedkeys &= ~KEY_RIGHT;
1633                 self.pressedkeys &= ~KEY_LEFT;
1634         }
1635
1636         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1637                 self.pressedkeys |= KEY_JUMP;
1638         else
1639                 self.pressedkeys &= ~KEY_JUMP;
1640         if (self.BUTTON_CROUCH)
1641                 self.pressedkeys |= KEY_CROUCH;
1642         else
1643                 self.pressedkeys &= ~KEY_CROUCH;
1644
1645         if (self.BUTTON_ATCK)
1646                 self.pressedkeys |= KEY_ATCK;
1647         else
1648                 self.pressedkeys &= ~KEY_ATCK;
1649         if (self.BUTTON_ATCK2)
1650                 self.pressedkeys |= KEY_ATCK2;
1651         else
1652                 self.pressedkeys &= ~KEY_ATCK2;
1653 }
1654
1655 /*
1656 ======================
1657 spectate mode routines
1658 ======================
1659 */
1660
1661 void SpectateCopy(entity spectatee) {
1662         other = spectatee;
1663         MUTATOR_CALLHOOK(SpectateCopy);
1664         self.armortype = spectatee.armortype;
1665         self.armorvalue = spectatee.armorvalue;
1666         self.ammo_cells = spectatee.ammo_cells;
1667         self.ammo_shells = spectatee.ammo_shells;
1668         self.ammo_nails = spectatee.ammo_nails;
1669         self.ammo_rockets = spectatee.ammo_rockets;
1670         self.ammo_fuel = spectatee.ammo_fuel;
1671         self.clip_load = spectatee.clip_load;
1672         self.clip_size = spectatee.clip_size;
1673         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1674         self.health = spectatee.health;
1675         self.impulse = 0;
1676         self.items = spectatee.items;
1677         self.last_pickup = spectatee.last_pickup;
1678         self.hit_time = spectatee.hit_time;
1679         self.metertime = spectatee.metertime;
1680         self.strength_finished = spectatee.strength_finished;
1681         self.invincible_finished = spectatee.invincible_finished;
1682         self.pressedkeys = spectatee.pressedkeys;
1683         self.weapons = spectatee.weapons;
1684         self.switchweapon = spectatee.switchweapon;
1685         self.switchingweapon = spectatee.switchingweapon;
1686         self.weapon = spectatee.weapon;
1687         self.nex_charge = spectatee.nex_charge;
1688         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1689         self.hagar_load = spectatee.hagar_load;
1690         self.minelayer_mines = spectatee.minelayer_mines;
1691         self.punchangle = spectatee.punchangle;
1692         self.view_ofs = spectatee.view_ofs;
1693         self.velocity = spectatee.velocity;
1694         self.dmg_take = spectatee.dmg_take;
1695         self.dmg_save = spectatee.dmg_save;
1696         self.dmg_inflictor = spectatee.dmg_inflictor;
1697         self.v_angle = spectatee.v_angle;
1698         self.angles = spectatee.v_angle;
1699         if(!self.BUTTON_USE)
1700                 self.fixangle = TRUE;
1701         setorigin(self, spectatee.origin);
1702         setsize(self, spectatee.mins, spectatee.maxs);
1703         SetZoomState(spectatee.zoomstate);
1704
1705     anticheat_spectatecopy(spectatee);
1706         self.hud = spectatee.hud;
1707         if(spectatee.vehicle)
1708     {
1709         self.fixangle = FALSE;
1710         //self.velocity = spectatee.vehicle.velocity;
1711         self.vehicle_health = spectatee.vehicle_health;
1712         self.vehicle_shield = spectatee.vehicle_shield;
1713         self.vehicle_energy = spectatee.vehicle_energy;
1714         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1715         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1716         self.vehicle_reload1 = spectatee.vehicle_reload1;
1717         self.vehicle_reload2 = spectatee.vehicle_reload2;
1718
1719         msg_entity = self;
1720
1721         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1722             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1723             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1724             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1725
1726         //WriteByte (MSG_ONE, SVC_SETVIEW);
1727         //    WriteEntity(MSG_ONE, self);
1728         //makevectors(spectatee.v_angle);
1729         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1730     }
1731 }
1732
1733 float SpectateUpdate() {
1734         if(!self.enemy)
1735             return 0;
1736
1737         if (self == self.enemy)
1738                 return 0;
1739
1740         if (!IS_PLAYER(self.enemy))
1741                 return 0;
1742
1743         SpectateCopy(self.enemy);
1744
1745         return 1;
1746 }
1747
1748
1749 float SpectateSet()
1750 {
1751         if(self.enemy.classname != "player")
1752                 return FALSE;
1753         /*if(self.enemy.vehicle)
1754         {
1755
1756                 msg_entity = self;
1757                 WriteByte(MSG_ONE, SVC_SETVIEW);
1758                 WriteEntity(MSG_ONE, self.enemy);
1759                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1760
1761                 self.movetype = MOVETYPE_NONE;
1762                 accuracy_resend(self);
1763         }
1764         else
1765         {*/
1766                 msg_entity = self;
1767                 WriteByte(MSG_ONE, SVC_SETVIEW);
1768                 WriteEntity(MSG_ONE, self.enemy);
1769                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1770                 self.movetype = MOVETYPE_NONE;
1771                 accuracy_resend(self);
1772
1773                 if(!SpectateUpdate())
1774                         PutObserverInServer();
1775         //}
1776         return TRUE;
1777 }
1778
1779 float Spectate(entity pl)
1780 {
1781         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1782         if(pl.team != self.team)
1783                 return 0;
1784
1785         self.enemy = pl;
1786         return SpectateSet();
1787 }
1788
1789 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1790 entity CA_SpectateNext(entity start) {
1791         if (start.team == self.team) {
1792                 return start;
1793         }
1794
1795         other = start;
1796         // continue from current player
1797         while(other && other.team != self.team) {
1798                 other = find(other, classname, "player");
1799         }
1800
1801         if (!other) {
1802                 // restart from begining
1803                 other = find(other, classname, "player");
1804                 while(other && other.team != self.team) {
1805                         other = find(other, classname, "player");
1806                 }
1807         }
1808
1809         return other;
1810 }
1811
1812 float SpectateNext()
1813 {
1814         other = find(self.enemy, classname, "player");
1815
1816         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1817                 // CA and ca players when spectating enemies is forbidden
1818                 other = CA_SpectateNext(other);
1819         } else {
1820                 // other modes and ca spectators or spectating enemies is allowed
1821                 if (!other)
1822                         other = find(other, classname, "player");
1823         }
1824
1825         if (other)
1826                 self.enemy = other;
1827
1828         return SpectateSet();
1829 }
1830
1831 float SpectatePrev()
1832 {
1833         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1834         other = findchain(classname, "player");
1835         if (!other) // no player
1836                 return FALSE;
1837
1838         entity first = other;
1839         // skip players until current spectated player
1840         if(self.enemy)
1841         while(other && other != self.enemy)
1842                 other = other.chain;
1843
1844         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1845         {
1846                 do { other = other.chain; }
1847                 while(other && other.team != self.team);
1848
1849                 if (!other)
1850                 {
1851                         other = first;
1852                         while(other.team != self.team)
1853                                 other = other.chain;
1854                         if(other == self.enemy)
1855                                 return TRUE;
1856                 }
1857         }
1858         else
1859         {
1860                 if(other.chain)
1861                         other = other.chain;
1862                 else
1863                         other = first;
1864         }
1865         self.enemy = other;
1866         return SpectateSet();
1867 }
1868
1869 /*
1870 =============
1871 ShowRespawnCountdown()
1872
1873 Update a respawn countdown display.
1874 =============
1875 */
1876 void ShowRespawnCountdown()
1877 {
1878         float number;
1879         if(self.deadflag == DEAD_NO) // just respawned?
1880                 return;
1881         else
1882         {
1883                 number = ceil(self.respawn_time - time);
1884                 if(number <= 0)
1885                         return;
1886                 if(number <= self.respawn_countdown)
1887                 {
1888                         self.respawn_countdown = number - 1;
1889                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1890                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1891                 }
1892         }
1893 }
1894
1895 void LeaveSpectatorMode()
1896 {
1897         if(self.caplayer)
1898                 return;
1899         if(nJoinAllowed(self))
1900         {
1901                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1902                 {
1903                         self.classname = "player";
1904
1905                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1906                                 { JoinBestTeam(self, FALSE, TRUE); }
1907
1908                         if(autocvar_g_campaign)
1909                                 { campaign_bots_may_start = 1; }
1910
1911                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1912
1913                         PutClientInServer();
1914
1915                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1916                 }
1917                 else
1918                         stuffcmd(self, "menu_showteamselect\n");
1919         }
1920         else
1921         {
1922                 // Player may not join because g_maxplayers is set
1923                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1924         }
1925 }
1926
1927 /**
1928  * Determines whether the player is allowed to join. This depends on cvar
1929  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1930  * it checks whether the number of currently playing players exceeds g_maxplayers.
1931  * @return int number of free slots for players, 0 if none
1932  */
1933 float nJoinAllowed(entity ignore) {
1934         if(!ignore)
1935         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1936         // so report 0 free slots if restricted
1937         {
1938                 if(autocvar_g_forced_team_otherwise == "spectate")
1939                         return 0;
1940                 if(autocvar_g_forced_team_otherwise == "spectator")
1941                         return 0;
1942         }
1943
1944         if(self.team_forced < 0)
1945                 return 0; // forced spectators can never join
1946
1947         // TODO simplify this
1948         entity e;
1949         float totalClients = 0;
1950         FOR_EACH_CLIENT(e)
1951                 if(e != ignore)
1952                         totalClients += 1;
1953
1954         if (!autocvar_g_maxplayers)
1955                 return maxclients - totalClients;
1956
1957         float currentlyPlaying = 0;
1958         FOR_EACH_REALCLIENT(e)
1959                 if(IS_PLAYER(e) || e.caplayer == 1)
1960                         currentlyPlaying += 1;
1961
1962         if(currentlyPlaying < autocvar_g_maxplayers)
1963                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1964
1965         return 0;
1966 }
1967
1968 /**
1969  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1970  * g_maxplayers_spectator_blocktime seconds
1971  */
1972 void checkSpectatorBlock() {
1973         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1974                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1975                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1976                         dropclient(self);
1977                 }
1978         }
1979 }
1980
1981 void PrintWelcomeMessage()
1982 {
1983         if(self.motd_actived_time == 0)
1984         {
1985                 if (autocvar_g_campaign) {
1986                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1987                                 self.motd_actived_time = time;
1988                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1989                         }
1990                 } else {
1991                         if (self.BUTTON_INFO) {
1992                                 self.motd_actived_time = time;
1993                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1994                         }
1995                 }
1996         }
1997         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1998         {
1999                 if (autocvar_g_campaign) {
2000                         if (self.BUTTON_INFO)
2001                                 self.motd_actived_time = time;
2002                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2003                                 self.motd_actived_time = 0;
2004                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2005                         }
2006                 } else {
2007                         if (self.BUTTON_INFO)
2008                                 self.motd_actived_time = time;
2009                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2010                                 self.motd_actived_time = 0;
2011                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2012                         }
2013                 }
2014         }
2015         else //if(self.motd_actived_time < 0) // just connected, motd is active
2016         {
2017                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2018                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2019                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2020                 {
2021                         // instanctly hide MOTD
2022                         self.motd_actived_time = 0;
2023                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2024                 }
2025         }
2026 }
2027
2028 void ObserverThink()
2029 {
2030         float prefered_movetype;
2031         if (self.flags & FL_JUMPRELEASED) {
2032                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2033                         self.flags &= ~FL_JUMPRELEASED;
2034                         self.flags |= FL_SPAWNING;
2035                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2036                         self.flags &= ~FL_JUMPRELEASED;
2037                         if(SpectateNext()) {
2038                                 self.classname = "spectator";
2039                         }
2040                 } else {
2041                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2042                         if (self.movetype != prefered_movetype)
2043                                 self.movetype = prefered_movetype;
2044                 }
2045         } else {
2046                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2047                         self.flags |= FL_JUMPRELEASED;
2048                         if(self.flags & FL_SPAWNING)
2049                         {
2050                                 self.flags &= ~FL_SPAWNING;
2051                                 LeaveSpectatorMode();
2052                                 return;
2053                         }
2054                 }
2055         }
2056 }
2057
2058 void SpectatorThink()
2059 {
2060         if (self.flags & FL_JUMPRELEASED) {
2061                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2062                         self.flags &= ~FL_JUMPRELEASED;
2063                         self.flags |= FL_SPAWNING;
2064                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2065                         self.flags &= ~FL_JUMPRELEASED;
2066                         if(SpectateNext()) {
2067                                 self.classname = "spectator";
2068                         } else {
2069                                 self.classname = "observer";
2070                                 PutClientInServer();
2071                         }
2072                         self.impulse = 0;
2073                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2074                         self.flags &= ~FL_JUMPRELEASED;
2075                         if(SpectatePrev()) {
2076                                 self.classname = "spectator";
2077                         } else {
2078                                 self.classname = "observer";
2079                                 PutClientInServer();
2080                         }
2081                         self.impulse = 0;
2082                 } else if (self.BUTTON_ATCK2) {
2083                         self.flags &= ~FL_JUMPRELEASED;
2084                         self.classname = "observer";
2085                         PutClientInServer();
2086                 } else {
2087                         if(!SpectateUpdate())
2088                                 PutObserverInServer();
2089                 }
2090         } else {
2091                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2092                         self.flags |= FL_JUMPRELEASED;
2093                         if(self.flags & FL_SPAWNING)
2094                         {
2095                                 self.flags &= ~FL_SPAWNING;
2096                                 LeaveSpectatorMode();
2097                                 return;
2098                         }
2099                 }
2100                 if(!SpectateUpdate())
2101                         PutObserverInServer();
2102         }
2103
2104         self.flags |= FL_CLIENT | FL_NOTARGET;
2105 }
2106
2107 void PlayerUseKey()
2108 {
2109         if (!IS_PLAYER(self))
2110                 return;
2111
2112         if(self.vehicle)
2113         {
2114         vehicles_exit(VHEF_NORMAL);
2115         return;
2116         }
2117
2118         // a use key was pressed; call handlers
2119         MUTATOR_CALLHOOK(PlayerUseKey);
2120 }
2121
2122 /*
2123 =============
2124 PlayerPreThink
2125
2126 Called every frame for each client before the physics are run
2127 =============
2128 */
2129 .float usekeypressed;
2130 void() nexball_setstatus;
2131 .float items_added;
2132 void PlayerPreThink (void)
2133 {
2134         WarpZone_PlayerPhysics_FixVAngle();
2135
2136         self.stat_game_starttime = game_starttime;
2137         self.stat_round_starttime = round_starttime;
2138         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2139         self.stat_leadlimit = autocvar_leadlimit;
2140
2141         if(frametime)
2142         {
2143                 // physics frames: update anticheat stuff
2144                 anticheat_prethink();
2145         }
2146
2147         if(blockSpectators && frametime)
2148                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2149                 checkSpectatorBlock();
2150
2151         zoomstate_set = 0;
2152
2153         if(self.netname_previous != self.netname)
2154         {
2155                 if(autocvar_sv_eventlog)
2156                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2157                 if(self.netname_previous)
2158                         strunzone(self.netname_previous);
2159                 self.netname_previous = strzone(self.netname);
2160         }
2161
2162         // version nagging
2163         if(self.version_nagtime)
2164                 if(self.cvar_g_xonoticversion)
2165                         if(time > self.version_nagtime)
2166                         {
2167                                 // don't notify git users
2168                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2169                                 {
2170                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2171                                         {
2172                                                 // notify release users if connecting to git
2173                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2174                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2175                                         }
2176                                         else
2177                                         {
2178                                                 float r;
2179                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2180                                                 if(r < 0)
2181                                                 {
2182                                                         // give users new version
2183                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2184                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2185                                                 }
2186                                                 else if(r > 0)
2187                                                 {
2188                                                         // notify users about old server version
2189                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2190                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2191                                                 }
2192                                         }
2193                                 }
2194                                 self.version_nagtime = 0;
2195                         }
2196
2197         // GOD MODE info
2198         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2199         {
2200                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2201                 self.max_armorvalue = 0;
2202         }
2203
2204 #ifdef TETRIS
2205         if (TetrisPreFrame())
2206                 return;
2207 #endif
2208
2209         MUTATOR_CALLHOOK(PlayerPreThink);
2210
2211         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2212         {
2213                 if(self.BUTTON_USE && !self.usekeypressed)
2214                         PlayerUseKey();
2215                 self.usekeypressed = self.BUTTON_USE;
2216         }
2217
2218         if(IS_REAL_CLIENT(self))
2219                 PrintWelcomeMessage();
2220
2221         if(IS_PLAYER(self))
2222         {
2223
2224                 CheckRules_Player();
2225
2226                 if (intermission_running)
2227                 {
2228                         IntermissionThink ();   // otherwise a button could be missed between
2229                         return;                                 // the think tics
2230                 }
2231
2232                 //don't allow the player to turn around while game is paused!
2233                 if(timeout_status == TIMEOUT_ACTIVE) {
2234                         // FIXME turn this into CSQC stuff
2235                         self.v_angle = self.lastV_angle;
2236                         self.angles = self.lastV_angle;
2237                         self.fixangle = TRUE;
2238                 }
2239
2240                 if(frametime)
2241                 {
2242                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2243                         {
2244                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2245                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2246                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2247
2248                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2249                                 {
2250                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2251                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2252                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2253                                 }
2254                         }
2255                         else
2256                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2257
2258                         player_powerups();
2259                 }
2260
2261                 if (self.deadflag != DEAD_NO)
2262                 {
2263                         if(self.personal && g_race_qualifying)
2264                         {
2265                                 if(time > self.respawn_time)
2266                                 {
2267                                         self.respawn_time = time + 1; // only retry once a second
2268                                         self.stat_respawn_time = self.respawn_time;
2269                                         respawn();
2270                                         self.impulse = 141;
2271                                 }
2272                         }
2273                         else
2274                         {
2275                                 float button_pressed;
2276                                 if(frametime)
2277                                         player_anim();
2278                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2279
2280                                 if (self.deadflag == DEAD_DYING)
2281                                 {
2282                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2283                                                 self.deadflag = DEAD_RESPAWNING;
2284                                         else if(!button_pressed)
2285                                                 self.deadflag = DEAD_DEAD;
2286                                 }
2287                                 else if (self.deadflag == DEAD_DEAD)
2288                                 {
2289                                         if(button_pressed)
2290                                                 self.deadflag = DEAD_RESPAWNABLE;
2291                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2292                                                 self.deadflag = DEAD_RESPAWNING;
2293                                 }
2294                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2295                                 {
2296                                         if(!button_pressed)
2297                                                 self.deadflag = DEAD_RESPAWNING;
2298                                 }
2299                                 else if (self.deadflag == DEAD_RESPAWNING)
2300                                 {
2301                                         if(time > self.respawn_time)
2302                                         {
2303                                                 self.respawn_time = time + 1; // only retry once a second
2304                                                 self.respawn_time_max = self.respawn_time;
2305                                                 respawn();
2306                                         }
2307                                 }
2308
2309                                 ShowRespawnCountdown();
2310
2311                                 if(self.respawn_flags & RESPAWN_SILENT)
2312                                         self.stat_respawn_time = 0;
2313                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2314                                         self.stat_respawn_time = self.respawn_time_max;
2315                                 else
2316                                         self.stat_respawn_time = self.respawn_time;
2317                         }
2318
2319                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2320                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2321                                 self.stat_respawn_time *= -1;
2322
2323                         return;
2324                 }
2325
2326                 self.prevorigin = self.origin;
2327
2328                 float do_crouch = self.BUTTON_CROUCH;
2329                 if(self.hook.state)
2330                         do_crouch = 0;
2331                 if(self.vehicle)
2332                         do_crouch = 0;
2333                 if(self.freezetag_frozen)
2334                         do_crouch = 0;
2335                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2336                         do_crouch = 0;
2337
2338                 if (do_crouch)
2339                 {
2340                         if (!self.crouch)
2341                         {
2342                                 self.crouch = TRUE;
2343                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2344                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2345                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2346                         }
2347                 }
2348                 else
2349                 {
2350                         if (self.crouch)
2351                         {
2352                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2353                                 if (!trace_startsolid)
2354                                 {
2355                                         self.crouch = FALSE;
2356                                         self.view_ofs = PL_VIEW_OFS;
2357                                         setsize (self, PL_MIN, PL_MAX);
2358                                 }
2359                         }
2360                 }
2361
2362                 FixPlayermodel();
2363
2364                 GrapplingHookFrame();
2365
2366                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2367                 //if(frametime)
2368                 {
2369                         self.items &= ~self.items_added;
2370
2371                         W_WeaponFrame();
2372
2373                         self.items_added = 0;
2374                         if(self.items & IT_JETPACK)
2375                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2376                                         self.items_added |= IT_FUEL;
2377
2378                         self.items |= self.items_added;
2379                 }
2380
2381                 player_regen();
2382
2383                 // rot nex charge to the charge limit
2384                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2385                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2386
2387                 if(frametime)
2388                         player_anim();
2389
2390                 // secret status
2391                 secrets_setstatus();
2392
2393                 // monsters status
2394                 monsters_setstatus();
2395
2396                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2397
2398                 //self.angles_y=self.v_angle_y + 90;   // temp
2399         } else if(gameover) {
2400                 if (intermission_running)
2401                         IntermissionThink ();   // otherwise a button could be missed between
2402                 return;
2403         } else if(IS_OBSERVER(self)) {
2404                 ObserverThink();
2405         } else if(IS_SPEC(self)) {
2406                 SpectatorThink();
2407         }
2408
2409         if(!zoomstate_set)
2410                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2411
2412         float oldspectatee_status;
2413         oldspectatee_status = self.spectatee_status;
2414         if(IS_SPEC(self))
2415                 self.spectatee_status = num_for_edict(self.enemy);
2416         else if(IS_OBSERVER(self))
2417                 self.spectatee_status = num_for_edict(self);
2418         else
2419                 self.spectatee_status = 0;
2420         if(self.spectatee_status != oldspectatee_status)
2421         {
2422                 ClientData_Touch(self);
2423         }
2424
2425         if(self.teamkill_soundtime)
2426         if(time > self.teamkill_soundtime)
2427         {
2428                 self.teamkill_soundtime = 0;
2429
2430                 entity oldpusher, oldself;
2431
2432                 oldself = self; self = self.teamkill_soundsource;
2433                 oldpusher = self.pusher; self.pusher = oldself;
2434
2435                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2436
2437                 self.pusher = oldpusher;
2438                 self = oldself;
2439         }
2440
2441         if(self.taunt_soundtime)
2442         if(time > self.taunt_soundtime)
2443         {
2444                 self.taunt_soundtime = 0;
2445                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2446         }
2447
2448         target_voicescript_next(self);
2449
2450         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2451         if(!self.weapon)
2452                 self.clip_load = self.clip_size = 0;
2453 }
2454
2455 float isInvisibleString(string s)
2456 {
2457         float i, n, c;
2458         s = strdecolorize(s);
2459         for((i = 0), (n = strlen(s)); i < n; ++i)
2460         {
2461                 c = str2chr(s, i);
2462                 switch(c)
2463                 {
2464                         case 0:
2465                         case 32: // space
2466                                 break;
2467                         case 192: // charmap space
2468                                 if (!autocvar_utf8_enable)
2469                                         break;
2470                                 return FALSE;
2471                         case 160: // space in unicode fonts
2472                         case 0xE000 + 192: // utf8 charmap space
2473                                 if (autocvar_utf8_enable)
2474                                         break;
2475                         default:
2476                                 return FALSE;
2477                 }
2478         }
2479         return TRUE;
2480 }
2481
2482 /*
2483 =============
2484 PlayerPostThink
2485
2486 Called every frame for each client after the physics are run
2487 =============
2488 */
2489 .float idlekick_lasttimeleft;
2490 void PlayerPostThink (void)
2491 {
2492         // Savage: Check for nameless players
2493         if (isInvisibleString(self.netname)) {
2494                 self.netname = "Player";
2495                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2496         }
2497
2498         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2499         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2500         {
2501                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2502                 {
2503                         if(self.idlekick_lasttimeleft)
2504                         {
2505                                 self.idlekick_lasttimeleft = 0;
2506                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2507                         }
2508                 }
2509                 else
2510                 {
2511                         float timeleft;
2512                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2513                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2514                         {
2515                                 if(!self.idlekick_lasttimeleft)
2516                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2517                         }
2518                         if(timeleft <= 0)
2519                         {
2520                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2521                                 dropclient(self);
2522                                 return;
2523                         }
2524                         else if(timeleft <= 10)
2525                         {
2526                                 if(timeleft != self.idlekick_lasttimeleft)
2527                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2528                                 self.idlekick_lasttimeleft = timeleft;
2529                         }
2530                 }
2531         }
2532
2533 #ifdef TETRIS
2534         if(self.impulse == 100)
2535                 ImpulseCommands();
2536         if (!TetrisPostFrame())
2537         {
2538 #endif
2539
2540         CheatFrame();
2541
2542         //CheckPlayerJump();
2543
2544         if(IS_PLAYER(self)) {
2545                 CheckRules_Player();
2546                 UpdateChatBubble();
2547                 if (self.impulse)
2548                         ImpulseCommands();
2549                 if (intermission_running)
2550                         return;         // intermission or finale
2551                 GetPressedKeys();
2552         }
2553
2554 #ifdef TETRIS
2555         }
2556 #endif
2557
2558         /*
2559         float i;
2560         for(i = 0; i < 1000; ++i)
2561         {
2562                 vector end;
2563                 end = self.origin + '0 0 1024' + 512 * randomvec();
2564                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2565                 if(trace_fraction < 1)
2566                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2567                 {
2568                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2569                         break;
2570                 }
2571         }
2572         */
2573
2574         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2575
2576         if(self.waypointsprite_attachedforcarrier)
2577                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2578
2579         playerdemo_write();
2580
2581         CSQCMODEL_AUTOUPDATE();
2582 }