qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/debug.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/effects/qc/globalsound.qh>
   8 #include <common/ent_cs.qh>
   9 #include <common/gamemodes/_mod.qh>
  10 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  11 #include <common/items/_mod.qh>
  12 #include <common/items/inventory.qh>
  13 #include <common/mapobjects/func/conveyor.qh>
  14 #include <common/mapobjects/func/ladder.qh>
  15 #include <common/mapobjects/subs.qh>
  16 #include <common/mapobjects/target/spawnpoint.qh>
  17 #include <common/mapobjects/teleporters.qh>
  18 #include <common/mapobjects/trigger/counter.qh>
  19 #include <common/mapobjects/trigger/secret.qh>
  20 #include <common/mapobjects/trigger/swamp.qh>
  21 #include <common/mapobjects/triggers.qh>
  22 #include <common/minigames/sv_minigames.qh>
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  25 #include <common/mutators/mutator/nades/nades.qh>
  26 #include <common/mutators/mutator/overkill/oknex.qh>
  27 #include <common/mutators/mutator/status_effects/_mod.qh>
  28 #include <common/mutators/mutator/waypoints/all.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/playerstats.qh>
  34 #include <common/resources/sv_resources.qh>
  35 #include <common/state.qh>
  36 #include <common/stats.qh>
  37 #include <common/vehicles/all.qh>
  38 #include <common/vehicles/sv_vehicles.qh>
  39 #include <common/viewloc.qh>
  40 #include <common/weapons/_all.qh>
  41 #include <common/weapons/weapon/vortex.qh>
  42 #include <common/wepent.qh>
  43 #include <lib/csqcmodel/sv_model.qh>
  44 #include <lib/warpzone/common.qh>
  45 #include <lib/warpzone/server.qh>
  46 #include <server/anticheat.qh>
  47 #include <server/antilag.qh>
  48 #include <server/bot/api.qh>
  49 #include <server/bot/default/cvars.qh>
  50 #include <server/bot/default/waypoints.qh>
  51 #include <server/campaign.qh>
  52 #include <server/chat.qh>
  53 #include <server/cheats.qh>
  54 #include <server/clientkill.qh>
  55 #include <server/command/banning.qh>
  56 #include <server/command/cmd.qh>
  57 #include <server/command/common.qh>
  58 #include <server/command/vote.qh>
  59 #include <server/compat/quake3.qh>
  60 #include <server/damage.qh>
  61 #include <server/gamelog.qh>
  62 #include <server/handicap.qh>
  63 #include <server/hook.qh>
  64 #include <server/impulse.qh>
  65 #include <server/intermission.qh>
  66 #include <server/ipban.qh>
  67 #include <server/main.qh>
  68 #include <server/mutators/_mod.qh>
  69 #include <server/player.qh>
  70 #include <server/portals.qh>
  71 #include <server/race.qh>
  72 #include <server/scores.qh>
  73 #include <server/scores_rules.qh>
  74 #include <server/spawnpoints.qh>
  75 #include <server/teamplay.qh>
  76 #include <server/weapons/accuracy.qh>
  77 #include <server/weapons/common.qh>
  78 #include <server/weapons/hitplot.qh>
  79 #include <server/weapons/selection.qh>
  80 #include <server/weapons/tracing.qh>
  81 #include <server/weapons/weaponsystem.qh>
  82 #include <server/world.qh>
  83
  84 STATIC_METHOD(Client, Add, void(Client this, int _team))
  85 {
  86     ClientConnect(this);
  87     TRANSMUTE(Player, this);
  88     this.frame = 12; // 7
  89     this.team = _team;
  90     PutClientInServer(this);
  91 }
  92
  93 STATIC_METHOD(Client, Remove, void(Client this))
  94 {
  95     TRANSMUTE(Observer, this);
  96     PutClientInServer(this);
  97     ClientDisconnect(this);
  98 }
  99
 100 void send_CSQC_teamnagger() {
 101         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 102 }
 103
 104 int CountSpectators(entity player, entity to)
 105 {
 106         if(!player) { return 0; } // not sure how, but best to be safe
 107
 108         int spec_count = 0;
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 spec_count++;
 113         });
 114
 115         return spec_count;
 116 }
 117
 118 void WriteSpectators(entity player, entity to)
 119 {
 120         if(!player) { return; } // not sure how, but best to be safe
 121
 122         int spec_count = 0;
 123         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 124         {
 125                 if(spec_count >= MAX_SPECTATORS)
 126                         break;
 127                 WriteByte(MSG_ENTITY, num_for_edict(it));
 128                 ++spec_count;
 129         });
 130 }
 131
 132 bool ClientData_Send(entity this, entity to, int sf)
 133 {
 134         assert(to == this.owner, return false);
 135
 136         entity e = to;
 137         if (IS_SPEC(e)) e = e.enemy;
 138
 139         sf = 0;
 140         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 141         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 142         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 143         if (observe_blocked_if_eliminated && INGAME(to))
 144                                         sf |= BIT(3); // observing blocked
 145         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 146                                         sf |= BIT(4); // show spectators
 147
 148         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 149         WriteByte(MSG_ENTITY, sf);
 150
 151         if (sf & BIT(1))
 152                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 153
 154         if(sf & BIT(4))
 155         {
 156                 float specs = CountSpectators(e, to);
 157                 WriteByte(MSG_ENTITY, specs);
 158                 WriteSpectators(e, to);
 159         }
 160
 161         return true;
 162 }
 163
 164 void ClientData_Attach(entity this)
 165 {
 166         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 167         CS(this).clientdata.drawonlytoclient = this;
 168         CS(this).clientdata.owner = this;
 169 }
 170
 171 void ClientData_Detach(entity this)
 172 {
 173         delete(CS(this).clientdata);
 174         CS(this).clientdata = NULL;
 175 }
 176
 177 void ClientData_Touch(entity e)
 178 {
 179         entity cd = CS(e).clientdata;
 180         if (cd) { cd.SendFlags = 1; }
 181
 182         // make it spectatable
 183         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 184         {
 185                 entity cd = CS(it).clientdata;
 186                 if (cd) { cd.SendFlags = 1; }
 187         });
 188 }
 189
 190
 191 /*
 192 =============
 193 CheckPlayerModel
 194
 195 Checks if the argument string can be a valid playermodel.
 196 Returns a valid one in doubt.
 197 =============
 198 */
 199 string FallbackPlayerModel;
 200 string CheckPlayerModel(string plyermodel) {
 201         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 202         {
 203                 // note: we cannot summon Don Strunzone here, some player may
 204                 // still have the model string set. In case anyone manages how
 205                 // to change a cvar default, we'll have a small leak here.
 206                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 207         }
 208         // only in right path
 209         if(substring(plyermodel, 0, 14) != "models/player/")
 210                 return FallbackPlayerModel;
 211         // only good file extensions
 212         if(substring(plyermodel, -4, 4) != ".iqm"
 213                 && substring(plyermodel, -4, 4) != ".zym"
 214                 && substring(plyermodel, -4, 4) != ".dpm"
 215                 && substring(plyermodel, -4, 4) != ".md3"
 216                 && substring(plyermodel, -4, 4) != ".psk")
 217         {
 218                 return FallbackPlayerModel;
 219         }
 220         // forbid the LOD models
 221         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 222                 return FallbackPlayerModel;
 223         if(plyermodel != strtolower(plyermodel))
 224                 return FallbackPlayerModel;
 225         // also, restrict to server models
 226         if(autocvar_sv_servermodelsonly)
 227         {
 228                 if(!fexists(plyermodel))
 229                         return FallbackPlayerModel;
 230         }
 231         return plyermodel;
 232 }
 233
 234 void setplayermodel(entity e, string modelname)
 235 {
 236         precache_model(modelname);
 237         _setmodel(e, modelname);
 238         player_setupanimsformodel(e);
 239         if(!autocvar_g_debug_globalsounds)
 240                 UpdatePlayerSounds(e);
 241 }
 242
 243 /** putting a client as observer in the server */
 244 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 245 {
 246         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 247         bool recount_ready = false;
 248         PlayerState_detach(this);
 249
 250         if (IS_PLAYER(this))
 251         {
 252                 if(GetResource(this, RES_HEALTH) >= 1)
 253                 {
 254                         // despawn effect
 255                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 256                 }
 257
 258                 // was a player, recount votes and ready status
 259                 if(IS_REAL_CLIENT(this))
 260                 {
 261                         if (vote_called) { VoteCount(false); }
 262                         this.ready = false;
 263                         if (warmup_stage || game_starttime > time) recount_ready = true;
 264                 }
 265                 entcs_update_players(this);
 266         }
 267
 268         if (use_spawnpoint)
 269         {
 270                 entity spot = SelectSpawnPoint(this, true);
 271                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 272                 this.angles = vec2(spot.angles);
 273                 // offset it so that the spectator spawns higher off the ground, looks better this way
 274                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 275         }
 276         else // change origin to restore previous view origin
 277                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 278         this.fixangle = true;
 279
 280         if (IS_REAL_CLIENT(this))
 281         {
 282                 msg_entity = this;
 283                 WriteByte(MSG_ONE, SVC_SETVIEW);
 284                 WriteEntity(MSG_ONE, this);
 285         }
 286         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 287         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 288         if(!autocvar_g_debug_globalsounds)
 289         {
 290                 // needed for player sounds
 291                 this.model = "";
 292                 FixPlayermodel(this);
 293         }
 294         setmodel(this, MDL_Null);
 295         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 296         this.view_ofs = '0 0 0';
 297
 298         RemoveGrapplingHooks(this);
 299         Portal_ClearAll(this);
 300         Unfreeze(this, false);
 301         SetSpectatee(this, NULL);
 302
 303         if (this.alivetime)
 304         {
 305                 if (!warmup_stage)
 306                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 307                 this.alivetime = 0;
 308         }
 309
 310         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 311
 312         TRANSMUTE(Observer, this);
 313
 314         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 315
 316         WaypointSprite_PlayerDead(this);
 317         accuracy_resend(this);
 318
 319         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 320                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 321
 322         CS(this).spectatortime = time;
 323         if(this.bot_attack)
 324                 IL_REMOVE(g_bot_targets, this);
 325         this.bot_attack = false;
 326         if(this.monster_attack)
 327                 IL_REMOVE(g_monster_targets, this);
 328         this.monster_attack = false;
 329         STAT(HUD, this) = HUD_NORMAL;
 330         this.iscreature = false;
 331         this.teleportable = TELEPORT_SIMPLE;
 332         if(this.damagedbycontents)
 333                 IL_REMOVE(g_damagedbycontents, this);
 334         this.damagedbycontents = false;
 335         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 336         SetSpectatee_status(this, etof(this));
 337         this.takedamage = DAMAGE_NO;
 338         this.solid = SOLID_NOT;
 339         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 340         this.flags = FL_CLIENT | FL_NOTARGET;
 341         this.effects = 0;
 342         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 343         this.pauserotarmor_finished = 0;
 344         this.pauserothealth_finished = 0;
 345         this.pauseregen_finished = 0;
 346         this.damageforcescale = 0;
 347         this.death_time = 0;
 348         this.respawn_flags = 0;
 349         this.respawn_time = 0;
 350         STAT(RESPAWN_TIME, this) = 0;
 351         this.alpha = 0;
 352         this.scale = 0;
 353         this.fade_time = 0;
 354         this.pain_finished = 0;
 355         STAT(AIR_FINISHED, this) = 0;
 356         //this.dphitcontentsmask = 0;
 357         this.dphitcontentsmask = DPCONTENTS_SOLID;
 358         if (autocvar_g_playerclip_collisions)
 359                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 360         this.pushltime = 0;
 361         this.istypefrag = 0;
 362         setthink(this, func_null);
 363         this.nextthink = 0;
 364         this.deadflag = DEAD_NO;
 365         UNSET_DUCKED(this);
 366         STAT(REVIVE_PROGRESS, this) = 0;
 367         this.revival_time = 0;
 368         this.draggable = drag_undraggable;
 369
 370         player_powerups_remove_all(this);
 371         this.items = 0;
 372         STAT(WEAPONS, this) = '0 0 0';
 373         this.drawonlytoclient = this;
 374
 375         this.viewloc = NULL;
 376
 377         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 378
 379         this.weaponmodel = "";
 380         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 381         {
 382                 this.weaponentities[slot] = NULL;
 383         }
 384         this.exteriorweaponentity = NULL;
 385         CS(this).killcount = FRAGS_SPECTATOR;
 386         this.velocity = '0 0 0';
 387         this.avelocity = '0 0 0';
 388         this.punchangle = '0 0 0';
 389         this.punchvector = '0 0 0';
 390         this.oldvelocity = this.velocity;
 391         this.event_damage = func_null;
 392         this.event_heal = func_null;
 393
 394         for(int slot = 0; slot < MAX_AXH; ++slot)
 395         {
 396                 entity axh = this.(AuxiliaryXhair[slot]);
 397                 this.(AuxiliaryXhair[slot]) = NULL;
 398
 399                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 400                         delete(axh);
 401         }
 402
 403         if (mutator_returnvalue)
 404         {
 405                 // mutator prevents resetting teams+score
 406         }
 407         else
 408         {
 409                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 410                 this.frags = FRAGS_SPECTATOR;
 411         }
 412
 413         bot_relinkplayerlist();
 414
 415         if (CS(this).just_joined)
 416                 CS(this).just_joined = false;
 417 }
 418
 419 int player_getspecies(entity this)
 420 {
 421         get_model_parameters(this.model, this.skin);
 422         int s = get_model_parameters_species;
 423         get_model_parameters(string_null, 0);
 424         if (s < 0) return SPECIES_HUMAN;
 425         return s;
 426 }
 427
 428 .float model_randomizer;
 429 void FixPlayermodel(entity player)
 430 {
 431         string defaultmodel = "";
 432         int defaultskin = 0;
 433         if(autocvar_sv_defaultcharacter)
 434         {
 435                 if(teamplay)
 436                 {
 437                         switch(player.team)
 438                         {
 439                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 440                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 441                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 442                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 443                         }
 444                 }
 445
 446                 if(defaultmodel == "")
 447                 {
 448                         defaultmodel = autocvar_sv_defaultplayermodel;
 449                         defaultskin = autocvar_sv_defaultplayerskin;
 450                 }
 451
 452                 int n = tokenize_console(defaultmodel);
 453                 if(n > 0)
 454                 {
 455                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 456                         // However, do NOT randomize if the player-selected model is in the list.
 457                         for (int i = 0; i < n; ++i)
 458                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 459                                         defaultmodel = argv(i);
 460                 }
 461
 462                 int i = strstrofs(defaultmodel, ":", 0);
 463                 if(i >= 0)
 464                 {
 465                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 466                         defaultmodel = substring(defaultmodel, 0, i);
 467                 }
 468         }
 469         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 470         {
 471                 if(teamplay)
 472                 {
 473                         switch(player.team)
 474                         {
 475                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 476                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 477                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 478                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 479                         }
 480                 }
 481
 482                 if(!defaultskin)
 483                         defaultskin = autocvar_sv_defaultplayerskin;
 484         }
 485
 486         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 487         defaultmodel = M_ARGV(0, string);
 488         defaultskin = M_ARGV(1, int);
 489
 490         bool chmdl = false;
 491         int oldskin;
 492         if(defaultmodel != "")
 493         {
 494                 if (defaultmodel != player.model)
 495                 {
 496                         vector m1 = player.mins;
 497                         vector m2 = player.maxs;
 498                         setplayermodel (player, defaultmodel);
 499                         setsize (player, m1, m2);
 500                         chmdl = true;
 501                 }
 502
 503                 oldskin = player.skin;
 504                 player.skin = defaultskin;
 505         } else {
 506                 if (player.playermodel != player.model || player.playermodel == "")
 507                 {
 508                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 509                         vector m1 = player.mins;
 510                         vector m2 = player.maxs;
 511                         setplayermodel (player, player.playermodel);
 512                         setsize (player, m1, m2);
 513                         chmdl = true;
 514                 }
 515
 516                 if(!autocvar_sv_defaultcharacterskin)
 517                 {
 518                         oldskin = player.skin;
 519                         player.skin = stof(player.playerskin);
 520                 }
 521                 else
 522                 {
 523                         oldskin = player.skin;
 524                         player.skin = defaultskin;
 525                 }
 526         }
 527
 528         if(chmdl || oldskin != player.skin) // model or skin has changed
 529         {
 530                 player.species = player_getspecies(player); // update species
 531                 if(!autocvar_g_debug_globalsounds)
 532                         UpdatePlayerSounds(player); // update skin sounds
 533         }
 534
 535         if(!teamplay)
 536                 if(strlen(autocvar_sv_defaultplayercolors))
 537                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 538                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 539 }
 540
 541 void GiveWarmupResources(entity this)
 542 {
 543         SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 544         SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 545         SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 546         SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 547         SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 548         SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 549         SetResource(this, RES_HEALTH, warmup_start_health);
 550         SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 551         STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 552 }
 553
 554 void PutPlayerInServer(entity this)
 555 {
 556         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 557
 558         PlayerState_attach(this);
 559         accuracy_resend(this);
 560
 561         if (teamplay && this.bot_forced_team)
 562                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 563
 564         if (this.team < 0)
 565                 TeamBalance_JoinBestTeam(this);
 566
 567         entity spot = SelectSpawnPoint(this, false);
 568         if (!spot) {
 569                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 570                 return; // spawn failed
 571         }
 572
 573         TRANSMUTE(Player, this);
 574
 575         CS(this).wasplayer = true;
 576         this.iscreature = true;
 577         this.teleportable = TELEPORT_NORMAL;
 578         if(!this.damagedbycontents)
 579                 IL_PUSH(g_damagedbycontents, this);
 580         this.damagedbycontents = true;
 581         set_movetype(this, MOVETYPE_WALK);
 582         this.solid = SOLID_SLIDEBOX;
 583         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 584         if (autocvar_g_playerclip_collisions)
 585                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 586         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 587                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 588         this.frags = FRAGS_PLAYER;
 589         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 590         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 591         if (autocvar__notarget)
 592                 this.flags |= FL_NOTARGET;
 593         this.takedamage = DAMAGE_AIM;
 594         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 595
 596         if (warmup_stage)
 597                 GiveWarmupResources(this);
 598         else
 599         {
 600                 SetResource(this, RES_SHELLS, start_ammo_shells);
 601                 SetResource(this, RES_BULLETS, start_ammo_nails);
 602                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 603                 SetResource(this, RES_CELLS, start_ammo_cells);
 604                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 605                 SetResource(this, RES_FUEL, start_ammo_fuel);
 606                 SetResource(this, RES_HEALTH, start_health);
 607                 SetResource(this, RES_ARMOR, start_armorvalue);
 608                 STAT(WEAPONS, this) = start_weapons;
 609                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 610                 {
 611                         GiveRandomWeapons(this, random_start_weapons_count,
 612                                 autocvar_g_random_start_weapons, random_start_ammo);
 613                 }
 614         }
 615         SetSpectatee_status(this, 0);
 616
 617         PS(this).dual_weapons = '0 0 0';
 618
 619         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 620                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 621
 622         this.items = start_items;
 623
 624         float shieldtime = time + autocvar_g_spawnshieldtime;
 625
 626         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 627         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 628         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 629         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 630         if (!sv_ready_restart_after_countdown && time < game_starttime)
 631         {
 632                 float f = game_starttime - time;
 633                 shieldtime += f;
 634                 this.pauserotarmor_finished += f;
 635                 this.pauserothealth_finished += f;
 636                 this.pauseregen_finished += f;
 637         }
 638
 639         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 640
 641         this.damageforcescale = autocvar_g_player_damageforcescale;
 642         this.death_time = 0;
 643         this.respawn_flags = 0;
 644         this.respawn_time = 0;
 645         STAT(RESPAWN_TIME, this) = 0;
 646         // DP model scaling uses 1/16 accuracy and 13/16 is closest to 56/69
 647         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.8125 : autocvar_sv_player_scale);
 648         this.fade_time = 0;
 649         this.pain_finished = 0;
 650         this.pushltime = 0;
 651         setthink(this, func_null); // players have no think function
 652         this.nextthink = 0;
 653         this.dmg_team = 0;
 654         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 655
 656         this.deadflag = DEAD_NO;
 657
 658         this.angles = spot.angles;
 659         this.angles_z = 0; // never spawn tilted even if the spot says to
 660         if (IS_BOT_CLIENT(this))
 661         {
 662                 this.v_angle = this.angles;
 663                 bot_aim_reset(this);
 664         }
 665         this.fixangle = true; // turn this way immediately
 666         this.oldvelocity = this.velocity = '0 0 0';
 667         this.avelocity = '0 0 0';
 668         this.punchangle = '0 0 0';
 669         this.punchvector = '0 0 0';
 670
 671         STAT(REVIVE_PROGRESS, this) = 0;
 672         this.revival_time = 0;
 673
 674         STAT(AIR_FINISHED, this) = 0;
 675         this.waterlevel = WATERLEVEL_NONE;
 676         this.watertype = CONTENT_EMPTY;
 677
 678         entity spawnevent = new_pure(spawnevent);
 679         spawnevent.owner = this;
 680         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 681
 682         // Cut off any still running player sounds.
 683         stopsound(this, CH_PLAYER_SINGLE);
 684
 685         this.model = "";
 686         FixPlayermodel(this);
 687         this.drawonlytoclient = NULL;
 688
 689         this.viewloc = NULL;
 690
 691         for(int slot = 0; slot < MAX_AXH; ++slot)
 692         {
 693                 entity axh = this.(AuxiliaryXhair[slot]);
 694                 this.(AuxiliaryXhair[slot]) = NULL;
 695
 696                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 697                         delete(axh);
 698         }
 699
 700         this.spawnpoint_targ = NULL;
 701
 702         UNSET_DUCKED(this);
 703         this.view_ofs = STAT(PL_VIEW_OFS, this);
 704         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 705         this.spawnorigin = spot.origin;
 706         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 707         // don't reset back to last position, even if new position is stuck in solid
 708         this.oldorigin = this.origin;
 709         if(this.conveyor)
 710                 IL_REMOVE(g_conveyed, this);
 711         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 712         if(this.swampslug)
 713                 IL_REMOVE(g_swamped, this);
 714         this.swampslug = NULL;
 715         this.swamp_interval = 0;
 716         if(this.ladder_entity)
 717                 IL_REMOVE(g_ladderents, this);
 718         this.ladder_entity = NULL;
 719         IL_EACH(g_counters, it.realowner == this,
 720         {
 721                 delete(it);
 722         });
 723         STAT(HUD, this) = HUD_NORMAL;
 724
 725         this.event_damage = PlayerDamage;
 726         this.event_heal = PlayerHeal;
 727
 728         this.draggable = func_null;
 729
 730         if(!this.bot_attack)
 731                 IL_PUSH(g_bot_targets, this);
 732         this.bot_attack = true;
 733         if(!this.monster_attack)
 734                 IL_PUSH(g_monster_targets, this);
 735         this.monster_attack = true;
 736         navigation_dynamicgoal_init(this, false);
 737
 738         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 739
 740         // player was spectator
 741         if (CS(this).killcount == FRAGS_SPECTATOR) {
 742                 PlayerScore_Clear(this);
 743                 CS(this).killcount = 0;
 744                 CS(this).startplaytime = time;
 745         }
 746
 747         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 748         {
 749                 .entity weaponentity = weaponentities[slot];
 750                 CL_SpawnWeaponentity(this, weaponentity);
 751         }
 752         this.alpha = default_player_alpha;
 753         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 754         this.exteriorweaponentity.alpha = default_weapon_alpha;
 755
 756         this.speedrunning = false;
 757
 758         this.counter_cnt = 0;
 759         this.fragsfilter_cnt = 0;
 760
 761         target_voicescript_clear(this);
 762
 763         // reset fields the weapons may use
 764         FOREACH(Weapons, true, {
 765                 it.wr_resetplayer(it, this);
 766                         // reload all reloadable weapons
 767                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 768                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 769                         {
 770                                 .entity weaponentity = weaponentities[slot];
 771                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 772                         }
 773                 }
 774         });
 775
 776         Unfreeze(this, false);
 777
 778         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 779         {
 780                 string s = spot.target;
 781                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 782                         spot.target = string_null;
 783                 SUB_UseTargets(spot, this, NULL);
 784                 if(g_assault || g_race)
 785                         spot.target = s;
 786         }
 787
 788         if (autocvar_spawn_debug)
 789         {
 790                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 791                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 792         }
 793
 794         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 795         {
 796                 .entity weaponentity = weaponentities[slot];
 797                 entity w_ent = this.(weaponentity);
 798                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 799                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 800                 else
 801                         w_ent.m_switchweapon = WEP_Null;
 802                 w_ent.m_weapon = WEP_Null;
 803                 w_ent.weaponname = "";
 804                 w_ent.m_switchingweapon = WEP_Null;
 805                 w_ent.cnt = -1;
 806         }
 807
 808         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 809
 810         if (CS(this).impulse) ImpulseCommands(this);
 811
 812         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 813         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 814         {
 815                 .entity weaponentity = weaponentities[slot];
 816                 W_WeaponFrame(this, weaponentity);
 817         }
 818
 819         if (!warmup_stage && !this.alivetime)
 820                 this.alivetime = time;
 821
 822         antilag_clear(this, CS(this));
 823
 824         if (warmup_stage < 0 || warmup_stage > 1)
 825                 ReadyCount();
 826 }
 827
 828 /** Called when a client spawns in the server */
 829 void PutClientInServer(entity this)
 830 {
 831         if (IS_REAL_CLIENT(this)) {
 832                 msg_entity = this;
 833                 WriteByte(MSG_ONE, SVC_SETVIEW);
 834                 WriteEntity(MSG_ONE, this);
 835         }
 836         if (game_stopped)
 837                 TRANSMUTE(Observer, this);
 838
 839         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 840         SetSpectatee(this, NULL);
 841
 842         // reset player keys
 843         if(PS(this))
 844                 PS(this).itemkeys = 0;
 845
 846         MUTATOR_CALLHOOK(PutClientInServer, this);
 847
 848         if (IS_OBSERVER(this)) {
 849                 PutObserverInServer(this, false, use_spawnpoint);
 850         } else if (IS_PLAYER(this)) {
 851                 PutPlayerInServer(this);
 852         }
 853
 854         bot_relinkplayerlist();
 855 }
 856
 857 // TODO do we need all these fields, or should we stop autodetecting runtime
 858 // changes and just have a console command to update this?
 859 bool ClientInit_SendEntity(entity this, entity to, int sf)
 860 {
 861         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 862         return = true;
 863         msg_entity = to;
 864         // MSG_INIT replacement
 865         // TODO: make easier to use
 866         Registry_send_all();
 867         W_PROP_reload(MSG_ONE, to);
 868         ClientInit_misc(this);
 869         MUTATOR_CALLHOOK(Ent_Init);
 870 }
 871 void ClientInit_misc(entity this)
 872 {
 873         int channel = MSG_ONE;
 874         WriteHeader(channel, ENT_CLIENT_INIT);
 875         WriteByte(channel, g_nexball_meter_period * 32);
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 877         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 878         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 879         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 881         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 882         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 883         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 884
 885         if(autocvar_sv_foginterval && world.fog != "")
 886                 WriteString(channel, world.fog);
 887         else
 888                 WriteString(channel, "");
 889         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 890         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 891         WriteByte(channel, serverflags);
 892         WriteCoord(channel, autocvar_g_trueaim_minrange);
 893 }
 894
 895 void ClientInit_CheckUpdate(entity this)
 896 {
 897         this.nextthink = time;
 898         if(this.count != autocvar_g_balance_armor_blockpercent)
 899         {
 900                 this.count = autocvar_g_balance_armor_blockpercent;
 901                 this.SendFlags |= 1;
 902         }
 903         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 904         {
 905                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 906                 this.SendFlags |= 1;
 907         }
 908 }
 909
 910 void ClientInit_Spawn()
 911 {
 912         entity e = new_pure(clientinit);
 913         setthink(e, ClientInit_CheckUpdate);
 914         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 915
 916         ClientInit_CheckUpdate(e);
 917 }
 918
 919 /*
 920 =============
 921 SetNewParms
 922 =============
 923 */
 924 void SetNewParms ()
 925 {
 926         // initialize parms for a new player
 927         parm1 = -(86400 * 366);
 928
 929         MUTATOR_CALLHOOK(SetNewParms);
 930 }
 931
 932 /*
 933 =============
 934 SetChangeParms
 935 =============
 936 */
 937 void SetChangeParms (entity this)
 938 {
 939         // save parms for level change
 940         parm1 = CS(this).parm_idlesince - time;
 941
 942         MUTATOR_CALLHOOK(SetChangeParms);
 943 }
 944
 945 /*
 946 =============
 947 DecodeLevelParms
 948 =============
 949 */
 950 void DecodeLevelParms(entity this)
 951 {
 952         // load parms
 953         CS(this).parm_idlesince = parm1;
 954         if (CS(this).parm_idlesince == -(86400 * 366))
 955                 CS(this).parm_idlesince = time;
 956
 957         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 958         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 959
 960         MUTATOR_CALLHOOK(DecodeLevelParms);
 961 }
 962
 963 void FixClientCvars(entity e)
 964 {
 965         // send prediction settings to the client
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970
 971         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 972         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 973
 974         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 975
 976         MUTATOR_CALLHOOK(FixClientCvars, e);
 977 }
 978
 979 bool findinlist_abbrev(string tofind, string list)
 980 {
 981         if(list == "" || tofind == "")
 982                 return false; // empty list or search, just return
 983
 984         // this function allows abbreviated strings!
 985         FOREACH_WORD(list, it != "" && it == substring(tofind, 0, strlen(it)),
 986         {
 987                 return true;
 988         });
 989
 990         return false;
 991 }
 992
 993 bool PlayerInIPList(entity p, string iplist)
 994 {
 995         // some safety checks (never allow local?)
 996         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 997                 return false;
 998
 999         return findinlist_abbrev(p.netaddress, iplist);
1000 }
1001
1002 bool PlayerInIDList(entity p, string idlist)
1003 {
1004         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1005         if(!p.crypto_idfp)
1006                 return false;
1007
1008         return findinlist_abbrev(p.crypto_idfp, idlist);
1009 }
1010
1011 bool PlayerInList(entity player, string list)
1012 {
1013         if (list == "")
1014                 return false;
1015         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1016 }
1017
1018 #ifdef DP_EXT_PRECONNECT
1019 /*
1020 =============
1021 ClientPreConnect
1022
1023 Called once (not at each match start) when a client begins a connection to the server
1024 =============
1025 */
1026 void ClientPreConnect(entity this)
1027 {
1028         if(autocvar_sv_eventlog)
1029         {
1030                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1031                         this.playerid,
1032                         etof(this),
1033                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1034                 ));
1035         }
1036 }
1037 #endif
1038
1039 // NOTE csqc uses the active mutators list sent by this function
1040 // to understand which mutators are enabled
1041 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1042 void SendWelcomeMessage(entity this, int msg_type)
1043 {
1044         WriteByte(msg_type, boolean(autocvar_g_campaign));
1045         if (boolean(autocvar_g_campaign))
1046         {
1047                 WriteString(msg_type, Campaign_GetTitle());
1048                 WriteByte(msg_type, Campaign_GetLevelNum());
1049                 WriteString(msg_type, Campaign_GetMessage());
1050                 return;
1051         }
1052         WriteString(msg_type, autocvar_hostname);
1053         WriteString(msg_type, autocvar_g_xonoticversion);
1054         WriteByte(msg_type, CS(this).version_mismatch);
1055         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1056         WriteByte(msg_type, autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers);
1057         WriteByte(msg_type, GetPlayerLimit());
1058
1059         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1060         string modifications = M_ARGV(0, string);
1061
1062         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1063                 modifications = strcat(modifications, ", No start weapons");
1064         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1065                 modifications = strcat(modifications, ", Low gravity");
1066         if(g_weapon_stay && !g_cts)
1067                 modifications = strcat(modifications, ", Weapons stay");
1068         if(autocvar_g_jetpack)
1069                 modifications = strcat(modifications, ", Jetpack");
1070         modifications = substring(modifications, 2, strlen(modifications) - 2);
1071
1072         WriteString(msg_type, modifications);
1073
1074         WriteString(msg_type, g_weaponarena_list);
1075
1076         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1077         {
1078                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1079                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1080         }
1081
1082         WriteString(msg_type, cache_mutatormsg);
1083
1084         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1085 }
1086
1087 /**
1088 =============
1089 ClientConnect
1090
1091 Called when a client connects to the server
1092 =============
1093 */
1094 void ClientConnect(entity this)
1095 {
1096         if (Ban_MaybeEnforceBanOnce(this)) return;
1097         assert(!IS_CLIENT(this), return);
1098         this.flags |= FL_CLIENT;
1099         assert(player_count >= 0, player_count = 0);
1100
1101         TRANSMUTE(Client, this);
1102         CS(this).version_nagtime = time + 10 + random() * 10;
1103
1104         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1105
1106         bot_clientconnect(this);
1107
1108         Player_DetermineForcedTeam(this);
1109
1110         TRANSMUTE(Observer, this);
1111
1112         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1113
1114         // always track bots, don't ask for cl_allow_uidtracking
1115         if (IS_BOT_CLIENT(this))
1116                 PlayerStats_GameReport_AddPlayer(this);
1117         else
1118                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1119
1120         if (autocvar_sv_eventlog)
1121                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1122
1123         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1124
1125         stuffcmd(this, clientstuff, "\n");
1126         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1127
1128         FixClientCvars(this);
1129
1130         // get version info from player
1131         stuffcmd(this, "cmd clientversion $gameversion\n");
1132
1133         // notify about available teams
1134         if (teamplay)
1135         {
1136                 entity balance = TeamBalance_CheckAllowedTeams(this);
1137                 int t = TeamBalance_GetAllowedTeams(balance);
1138                 TeamBalance_Destroy(balance);
1139                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1140         }
1141         else
1142         {
1143                 stuffcmd(this, "set _teams_available 0\n");
1144         }
1145
1146         bot_relinkplayerlist();
1147
1148         CS(this).spectatortime = time;
1149         if (blockSpectators)
1150         {
1151                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1152         }
1153
1154         CS(this).jointime = time;
1155
1156         if (IS_REAL_CLIENT(this))
1157         {
1158                 if (g_weaponarena_weapons == WEPSET(TUBA))
1159                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1160                 // quickmenu file must be put in a subfolder with an unique name
1161                 // to reduce chances of overriding custom client quickmenus
1162                 if (waypointeditor_enabled)
1163                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1164                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1165                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1166         }
1167
1168         if (!autocvar_sv_foginterval && world.fog != "")
1169                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1170
1171         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1172                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1173                         send_CSQC_teamnagger();
1174
1175         CSQCMODEL_AUTOINIT(this);
1176
1177         CS(this).model_randomizer = random();
1178
1179         if (IS_REAL_CLIENT(this))
1180                 sv_notice_join(this);
1181
1182         this.move_qcphysics = true;
1183
1184         // update physics stats (players can spawn before physics runs)
1185         Physics_UpdateStats(this);
1186
1187         IL_EACH(g_initforplayer, it.init_for_player, {
1188                 it.init_for_player(it, this);
1189         });
1190
1191         Handicap_Initialize(this);
1192
1193         // playban
1194         if (PlayerInList(this, autocvar_g_playban_list))
1195                 TRANSMUTE(Observer, this);
1196
1197         if (PlayerInList(this, autocvar_g_chatban_list)) // chatban
1198                 CS(this).muted = true;
1199
1200         MUTATOR_CALLHOOK(ClientConnect, this);
1201
1202         if (player_count == 1)
1203         {
1204                 if (autocvar_sv_autopause && server_is_dedicated)
1205                         setpause(0);
1206                 localcmd("\nsv_hook_firstjoin\n");
1207         }
1208 }
1209 /*
1210 =============
1211 ClientDisconnect
1212
1213 Called when a client disconnects from the server
1214 =============
1215 */
1216 .entity chatbubbleentity;
1217 void player_powerups_remove_all(entity this);
1218
1219 void ClientDisconnect(entity this)
1220 {
1221         assert(IS_CLIENT(this), return);
1222
1223         /* from "ignore" command */
1224         strfree(this.ignore_list);
1225         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it.ignore_list,
1226         {
1227                 if(it.crypto_idfp && it.crypto_idfp != "")
1228                         continue;
1229                 string mylist = ignore_removefromlist(it, this);
1230                 if(it.ignore_list)
1231                         strunzone(it.ignore_list);
1232
1233                 it.ignore_list = strzone(mylist);
1234         });
1235         /* from "ignore" command */
1236
1237         PlayerStats_GameReport_FinalizePlayer(this);
1238         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1239         if (CS(this).active_minigame) part_minigame(this);
1240         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1241
1242         if (autocvar_sv_eventlog)
1243                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1244
1245         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1246
1247         if(IS_SPEC(this))
1248                 SetSpectatee(this, NULL);
1249
1250         MUTATOR_CALLHOOK(ClientDisconnect, this);
1251
1252         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1253         strfree(CS_CVAR(this).weaponorder_byimpulse);
1254         ClientState_detach(this);
1255
1256         Portal_ClearAll(this);
1257
1258         Unfreeze(this, false);
1259
1260         RemoveGrapplingHooks(this);
1261
1262         // Here, everything has been done that requires this player to be a client.
1263
1264         this.flags &= ~FL_CLIENT;
1265
1266         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1267         if (this.killindicator) delete(this.killindicator);
1268
1269         IL_EACH(g_counters, it.realowner == this,
1270         {
1271                 delete(it);
1272         });
1273
1274         WaypointSprite_PlayerGone(this);
1275
1276         bot_relinkplayerlist();
1277
1278         strfree(this.clientstatus);
1279         if (this.personal) delete(this.personal);
1280
1281         this.playerid = 0;
1282         if (warmup_stage || game_starttime > time) ReadyCount();
1283         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1284
1285         player_powerups_remove_all(this); // stop powerup sound
1286
1287         ONREMOVE(this);
1288
1289         if (player_count == 0)
1290                 localcmd("\nsv_hook_lastleave\n");
1291 }
1292
1293 void ChatBubbleThink(entity this)
1294 {
1295         this.nextthink = time;
1296         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1297         {
1298                 if(this.owner) // but why can that ever be NULL?
1299                         this.owner.chatbubbleentity = NULL;
1300                 delete(this);
1301                 return;
1302         }
1303
1304         this.mdl = "";
1305
1306         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1307         {
1308                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1309                         this.mdl = "models/sprites/minigame_busy.iqm";
1310                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1311                         this.mdl = "models/misc/chatbubble.spr";
1312         }
1313
1314         if ( this.model != this.mdl )
1315                 _setmodel(this, this.mdl);
1316
1317 }
1318
1319 void UpdateChatBubble(entity this)
1320 {
1321         if (this.alpha < 0)
1322                 return;
1323         // spawn a chatbubble entity if needed
1324         if (!this.chatbubbleentity)
1325         {
1326                 this.chatbubbleentity = new(chatbubbleentity);
1327                 this.chatbubbleentity.owner = this;
1328                 this.chatbubbleentity.exteriormodeltoclient = this;
1329                 setthink(this.chatbubbleentity, ChatBubbleThink);
1330                 this.chatbubbleentity.nextthink = time;
1331                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1332                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1333                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1334                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1335                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1336                 //this.chatbubbleentity.model = "";
1337                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1338         }
1339 }
1340
1341 void calculate_player_respawn_time(entity this)
1342 {
1343         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1344                 return;
1345
1346         float gametype_setting_tmp;
1347         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1348         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1349         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1350         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1351         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1352         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1353
1354         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1355         if (teamplay)
1356         {
1357                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1358                         if(it.team == this.team)
1359                                 ++pcount;
1360                 });
1361                 if (sdelay_small_count == 0)
1362                         sdelay_small_count = 1;
1363                 if (sdelay_large_count == 0)
1364                         sdelay_large_count = 1;
1365         }
1366         else
1367         {
1368                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1369                         ++pcount;
1370                 });
1371                 if (sdelay_small_count == 0)
1372                 {
1373                         if (IS_INDEPENDENT_PLAYER(this))
1374                         {
1375                                 // Players play independently. No point in requiring enemies.
1376                                 sdelay_small_count = 1;
1377                         }
1378                         else
1379                         {
1380                                 // Players play AGAINST each other. Enemies required.
1381                                 sdelay_small_count = 2;
1382                         }
1383                 }
1384                 if (sdelay_large_count == 0)
1385                 {
1386                         if (IS_INDEPENDENT_PLAYER(this))
1387                         {
1388                                 // Players play independently. No point in requiring enemies.
1389                                 sdelay_large_count = 1;
1390                         }
1391                         else
1392                         {
1393                                 // Players play AGAINST each other. Enemies required.
1394                                 sdelay_large_count = 2;
1395                         }
1396                 }
1397         }
1398
1399         float sdelay;
1400
1401         if (pcount <= sdelay_small_count)
1402                 sdelay = sdelay_small;
1403         else if (pcount >= sdelay_large_count)
1404                 sdelay = sdelay_large;
1405         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1406                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1407
1408         if(waves)
1409                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1410         else
1411                 this.respawn_time = time + sdelay;
1412
1413         if(sdelay < sdelay_max)
1414                 this.respawn_time_max = time + sdelay_max;
1415         else
1416                 this.respawn_time_max = this.respawn_time;
1417
1418         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1419                 this.respawn_countdown = 10; // first number to count down from is 10
1420         else
1421                 this.respawn_countdown = -1; // do not count down
1422
1423         if(autocvar_g_forced_respawn)
1424                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1425 }
1426
1427 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1428 // added to the model skins
1429 /*void UpdateColorModHack()
1430 {
1431         float c;
1432         c = this.clientcolors & 15;
1433         // LordHavoc: only bothering to support white, green, red, yellow, blue
1434              if (!teamplay) this.colormod = '0 0 0';
1435         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1436         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1437         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1438         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1439         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1440         else this.colormod = '1 1 1';
1441 }*/
1442
1443 void respawn(entity this)
1444 {
1445         bool damagedbycontents_prev = this.damagedbycontents;
1446         if(this.alpha >= 0)
1447         {
1448                 if(autocvar_g_respawn_ghosts)
1449                 {
1450                         this.solid = SOLID_NOT;
1451                         this.takedamage = DAMAGE_NO;
1452                         this.damagedbycontents = false;
1453                         set_movetype(this, MOVETYPE_FLY);
1454                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1455                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1456                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1457                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1458                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1459                         if(autocvar_g_respawn_ghosts_time > 0)
1460                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1461                 }
1462                 else
1463                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1464         }
1465
1466         CopyBody(this, 1);
1467         this.damagedbycontents = damagedbycontents_prev;
1468
1469         this.effects |= EF_NODRAW; // prevent another CopyBody
1470         PutClientInServer(this);
1471 }
1472
1473 void play_countdown(entity this, float finished, Sound samp)
1474 {
1475         TC(Sound, samp);
1476         float time_left = finished - time;
1477         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1478                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1479 }
1480
1481 // it removes special powerups not handled by StatusEffects
1482 void player_powerups_remove_all(entity this)
1483 {
1484         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1485         {
1486                 // don't play the poweroff sound when the game restarts or the player disconnects
1487                 if (time > game_starttime + 1 && IS_CLIENT(this)
1488                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1489                 {
1490                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1491                 }
1492                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1493                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1494                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1495         }
1496 }
1497
1498 void player_powerups(entity this)
1499 {
1500         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1501                 this.modelflags |= MF_ROCKET;
1502         else
1503                 this.modelflags &= ~MF_ROCKET;
1504
1505         this.effects &= ~EF_NODEPTHTEST;
1506
1507         if (IS_DEAD(this))
1508                 player_powerups_remove_all(this);
1509
1510         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1511                 return;
1512
1513         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1514         int items_prev = this.items;
1515
1516         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1517         {
1518                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1519                 if (this.items & IT_SUPERWEAPON)
1520                 {
1521                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1522                         {
1523                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1524                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1525                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1526                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1527                         }
1528                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1529                         {
1530                                 // don't let them run out
1531                         }
1532                         else
1533                         {
1534                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1535                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1536                                 {
1537                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1538                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1539                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1540                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1541                                 }
1542                         }
1543                 }
1544                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1545                 {
1546                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1547                         {
1548                                 this.items = this.items | IT_SUPERWEAPON;
1549                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1550                                 {
1551                                         if(!g_cts)
1552                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1553                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1554                                 }
1555                         }
1556                         else
1557                         {
1558                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1559                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1560                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1561                         }
1562                 }
1563                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1564                 {
1565                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1566                 }
1567         }
1568
1569         if(autocvar_g_nodepthtestplayers)
1570                 this.effects = this.effects | EF_NODEPTHTEST;
1571
1572         if(autocvar_g_fullbrightplayers)
1573                 this.effects = this.effects | EF_FULLBRIGHT;
1574
1575         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1576 }
1577
1578 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1579 {
1580         if(current > stable)
1581                 return current;
1582         else if(current > stable - 0.25) // when close enough, "snap"
1583                 return stable;
1584         else
1585                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1586 }
1587
1588 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1589 {
1590         if(current < stable)
1591                 return current;
1592         else if(current < stable + 0.25) // when close enough, "snap"
1593                 return stable;
1594         else
1595                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1596 }
1597
1598 void RotRegen(entity this, Resource res, float limit_mod,
1599         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1600         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1601 {
1602         float old = GetResource(this, res);
1603         float current = old;
1604         if(current > rotstable)
1605         {
1606                 if(rotframetime > 0)
1607                 {
1608                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1609                         current = max(rotstable, current - rotlinear * rotframetime);
1610                 }
1611         }
1612         else if(current < regenstable)
1613         {
1614                 if(regenframetime > 0)
1615                 {
1616                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1617                         current = min(regenstable, current + regenlinear * regenframetime);
1618                 }
1619         }
1620
1621         float limit = GetResourceLimit(this, res) * limit_mod;
1622         if(current > limit)
1623                 current = limit;
1624
1625         if (current != old)
1626                 SetResource(this, res, current);
1627 }
1628
1629 void player_regen(entity this)
1630 {
1631         float max_mod, regen_mod, rot_mod, limit_mod;
1632         max_mod = regen_mod = rot_mod = limit_mod = 1;
1633
1634         float regen_health = autocvar_g_balance_health_regen;
1635         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1636         float regen_health_rot = autocvar_g_balance_health_rot;
1637         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1638         float regen_health_stable = autocvar_g_balance_health_regenstable;
1639         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1640         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1641                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1642         max_mod = M_ARGV(1, float);
1643         regen_mod = M_ARGV(2, float);
1644         rot_mod = M_ARGV(3, float);
1645         limit_mod = M_ARGV(4, float);
1646         regen_health = M_ARGV(5, float);
1647         regen_health_linear = M_ARGV(6, float);
1648         regen_health_rot = M_ARGV(7, float);
1649         regen_health_rotlinear = M_ARGV(8, float);
1650         regen_health_stable = M_ARGV(9, float);
1651         regen_health_rotstable = M_ARGV(10, float);
1652
1653         float rotstable, regenstable, rotframetime, regenframetime;
1654
1655         if(!mutator_returnvalue)
1656         if(!STAT(FROZEN, this))
1657         {
1658                 regenstable = autocvar_g_balance_armor_regenstable;
1659                 rotstable = autocvar_g_balance_armor_rotstable;
1660                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1661                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1662                 RotRegen(this, RES_ARMOR, limit_mod,
1663                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1664                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1665
1666                 // NOTE: max_mod is only applied to health
1667                 regenstable = regen_health_stable * max_mod;
1668                 rotstable = regen_health_rotstable * max_mod;
1669                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1670                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1671                 RotRegen(this, RES_HEALTH, limit_mod,
1672                         regenstable, regen_health, regen_health_linear, regenframetime,
1673                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1674         }
1675
1676         // if player rotted to death...  die!
1677         // check this outside above checks, as player may still be able to rot to death
1678         if(GetResource(this, RES_HEALTH) < 1)
1679         {
1680                 if(this.vehicle)
1681                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1682                 if(this.event_damage)
1683                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1684         }
1685
1686         if (!(this.items & IT_UNLIMITED_AMMO))
1687         {
1688                 regenstable = autocvar_g_balance_fuel_regenstable;
1689                 rotstable = autocvar_g_balance_fuel_rotstable;
1690                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1691                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1692                 RotRegen(this, RES_FUEL, 1,
1693                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1694                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1695         }
1696 }
1697
1698 bool zoomstate_set;
1699 void SetZoomState(entity this, float newzoom)
1700 {
1701         if(newzoom != CS(this).zoomstate)
1702         {
1703                 CS(this).zoomstate = newzoom;
1704                 ClientData_Touch(this);
1705         }
1706         zoomstate_set = true;
1707 }
1708
1709 void GetPressedKeys(entity this)
1710 {
1711         MUTATOR_CALLHOOK(GetPressedKeys, this);
1712         if (game_stopped)
1713         {
1714                 CS(this).pressedkeys = 0;
1715                 STAT(PRESSED_KEYS, this) = 0;
1716                 return;
1717         }
1718
1719         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1720         int keys = STAT(PRESSED_KEYS, this);
1721         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1722         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1723         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1724         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1725
1726         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1727         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1728         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1729         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1730         CS(this).pressedkeys = keys; // store for other users
1731
1732         STAT(PRESSED_KEYS, this) = keys;
1733 }
1734
1735 /*
1736 ======================
1737 spectate mode routines
1738 ======================
1739 */
1740
1741 void SpectateCopy(entity this, entity spectatee)
1742 {
1743         TC(Client, this); TC(Client, spectatee);
1744
1745         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1746         PS(this) = PS(spectatee);
1747         this.armortype = spectatee.armortype;
1748         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1749         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1750         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1751         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1752         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1753         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1754         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1755         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1756         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1757         CS(this).impulse = 0;
1758         this.disableclientprediction = 1; // no need to run prediction on a spectator
1759         this.items = spectatee.items;
1760         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1761         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1762         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1763         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1764         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1765         this.punchangle = spectatee.punchangle;
1766         this.view_ofs = spectatee.view_ofs;
1767         this.velocity = spectatee.velocity;
1768         this.dmg_take = spectatee.dmg_take;
1769         this.dmg_save = spectatee.dmg_save;
1770         this.dmg_inflictor = spectatee.dmg_inflictor;
1771         this.v_angle = spectatee.v_angle;
1772         this.angles = spectatee.v_angle;
1773         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1774         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1775         this.viewloc = spectatee.viewloc;
1776         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1777                 this.fixangle = true;
1778         setorigin(this, spectatee.origin);
1779         setsize(this, spectatee.mins, spectatee.maxs);
1780         SetZoomState(this, CS(spectatee).zoomstate);
1781
1782     anticheat_spectatecopy(this, spectatee);
1783         STAT(HUD, this) = STAT(HUD, spectatee);
1784         if(spectatee.vehicle)
1785     {
1786         this.angles = spectatee.v_angle;
1787
1788         //this.fixangle = false;
1789         //this.velocity = spectatee.vehicle.velocity;
1790         this.vehicle_health = spectatee.vehicle_health;
1791         this.vehicle_shield = spectatee.vehicle_shield;
1792         this.vehicle_energy = spectatee.vehicle_energy;
1793         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1794         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1795         this.vehicle_reload1 = spectatee.vehicle_reload1;
1796         this.vehicle_reload2 = spectatee.vehicle_reload2;
1797
1798         //msg_entity = this;
1799
1800        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1801             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1802            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1803            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1804
1805         //WriteByte (MSG_ONE, SVC_SETVIEW);
1806         //    WriteEntity(MSG_ONE, this);
1807         //makevectors(spectatee.v_angle);
1808         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1809     }
1810 }
1811
1812 bool SpectateUpdate(entity this)
1813 {
1814         if(!this.enemy)
1815                 return false;
1816
1817         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1818         {
1819                 SetSpectatee(this, NULL);
1820                 return false;
1821         }
1822
1823         SpectateCopy(this, this.enemy);
1824
1825         return true;
1826 }
1827
1828 bool SpectateSet(entity this)
1829 {
1830         if(!IS_PLAYER(this.enemy))
1831                 return false;
1832
1833         ClientData_Touch(this.enemy);
1834
1835         msg_entity = this;
1836         WriteByte(MSG_ONE, SVC_SETVIEW);
1837         WriteEntity(MSG_ONE, this.enemy);
1838         set_movetype(this, MOVETYPE_NONE);
1839         accuracy_resend(this);
1840
1841         if(!SpectateUpdate(this))
1842                 PutObserverInServer(this, false, true);
1843
1844         return true;
1845 }
1846
1847 void SetSpectatee_status(entity this, int spectatee_num)
1848 {
1849         int oldspectatee_status = CS(this).spectatee_status;
1850         CS(this).spectatee_status = spectatee_num;
1851
1852         if (CS(this).spectatee_status != oldspectatee_status)
1853         {
1854                 if (STAT(PRESSED_KEYS, this))
1855                 {
1856                         CS(this).pressedkeys = 0;
1857                         STAT(PRESSED_KEYS, this) = 0;
1858                 }
1859                 ClientData_Touch(this);
1860                 if (g_race || g_cts) race_InitSpectator();
1861         }
1862 }
1863
1864 void SetSpectatee(entity this, entity spectatee)
1865 {
1866         if(IS_BOT_CLIENT(this))
1867                 return; // bots abuse .enemy, this code is useless to them
1868
1869         entity old_spectatee = this.enemy;
1870
1871         this.enemy = spectatee;
1872
1873         // WEAPONTODO
1874         // these are required to fix the spectator bug with arc
1875         if(old_spectatee)
1876         {
1877                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1878                 {
1879                         .entity weaponentity = weaponentities[slot];
1880                         if(old_spectatee.(weaponentity).arc_beam)
1881                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1882                 }
1883         }
1884         if(spectatee)
1885         {
1886                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1887                 {
1888                         .entity weaponentity = weaponentities[slot];
1889                         if(spectatee.(weaponentity).arc_beam)
1890                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1891                 }
1892         }
1893
1894         if (spectatee)
1895                 SetSpectatee_status(this, etof(spectatee));
1896
1897         // needed to update spectator list
1898         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1899 }
1900
1901 bool Spectate(entity this, entity pl)
1902 {
1903         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1904                 return false;
1905         pl = M_ARGV(1, entity);
1906
1907         SetSpectatee(this, pl);
1908         return SpectateSet(this);
1909 }
1910
1911 bool SpectateNext(entity this)
1912 {
1913         entity ent = find(this.enemy, classname, STR_PLAYER);
1914
1915         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1916                 ent = M_ARGV(1, entity);
1917         else if (!ent)
1918                 ent = find(ent, classname, STR_PLAYER);
1919
1920         if(ent) { SetSpectatee(this, ent); }
1921
1922         return SpectateSet(this);
1923 }
1924
1925 bool SpectatePrev(entity this)
1926 {
1927         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1928         entity ent = findchain(classname, STR_PLAYER);
1929         if (!ent) // no player
1930                 return false;
1931
1932         entity first = ent;
1933         // skip players until current spectated player
1934         if(this.enemy)
1935         while(ent && ent != this.enemy)
1936                 ent = ent.chain;
1937
1938         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1939         {
1940                 case MUT_SPECPREV_FOUND:
1941                         ent = M_ARGV(1, entity);
1942                         break;
1943                 case MUT_SPECPREV_RETURN:
1944                         return true;
1945                 case MUT_SPECPREV_CONTINUE:
1946                 default:
1947                 {
1948                         if(ent.chain)
1949                                 ent = ent.chain;
1950                         else
1951                                 ent = first;
1952                         break;
1953                 }
1954         }
1955
1956         SetSpectatee(this, ent);
1957         return SpectateSet(this);
1958 }
1959
1960 /*
1961 =============
1962 ShowRespawnCountdown()
1963
1964 Update a respawn countdown display.
1965 =============
1966 */
1967 void ShowRespawnCountdown(entity this)
1968 {
1969         float number;
1970         if(!IS_DEAD(this)) // just respawned?
1971                 return;
1972         else
1973         {
1974                 number = ceil(this.respawn_time - time);
1975                 if(number <= 0)
1976                         return;
1977                 if(number <= this.respawn_countdown)
1978                 {
1979                         this.respawn_countdown = number - 1;
1980                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1981                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1982                 }
1983         }
1984 }
1985
1986 .bool team_selected;
1987 bool ShowTeamSelection(entity this)
1988 {
1989         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1990                 return false;
1991         if (frametime) // once per frame is more than enough
1992                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1993         return true;
1994 }
1995 void Join(entity this)
1996 {
1997         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1998                 ReadyRestart(true);
1999
2000         TRANSMUTE(Player, this);
2001
2002         if(!this.team_selected)
2003         if(autocvar_g_campaign || autocvar_g_balance_teams)
2004                 TeamBalance_JoinBestTeam(this);
2005
2006         if(autocvar_g_campaign)
2007                 campaign_bots_may_start = true;
2008
2009         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2010
2011         PutClientInServer(this);
2012
2013         if(IS_PLAYER(this))
2014         if(teamplay && this.team != -1)
2015         {
2016         }
2017         else
2018                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2019         this.team_selected = false;
2020 }
2021
2022 int GetPlayerLimit()
2023 {
2024         if(g_duel)
2025                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2026         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
2027         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
2028         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2029         player_limit = M_ARGV(0, int);
2030         return player_limit < maxclients ? player_limit : 0;
2031 }
2032
2033 /**
2034  * Determines whether the player is allowed to join. This depends on cvar
2035  * g_maxplayers, if it isn't used this function always return true, otherwise
2036  * it checks whether the number of currently playing players exceeds g_maxplayers.
2037  * @return int number of free slots for players, 0 if none
2038  */
2039 int nJoinAllowed(entity this, entity ignore)
2040 {
2041         if(!ignore)
2042         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2043         // so report 0 free slots if restricted
2044         {
2045                 if(autocvar_g_forced_team_otherwise == "spectate")
2046                         return 0;
2047                 if(autocvar_g_forced_team_otherwise == "spectator")
2048                         return 0;
2049         }
2050
2051         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2052                 return 0; // forced spectators can never join
2053
2054         static float msg_time = 0;
2055         if(this && !INGAME(this) && ignore && PlayerInList(this, autocvar_g_playban_list))
2056         {
2057                 if(time > msg_time)
2058                 {
2059                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PLAYBAN);
2060                         msg_time = time + 0.5;
2061                 }
2062                 return 0;
2063         }
2064
2065         // TODO simplify this
2066         int totalClients = 0;
2067         int currentlyPlaying = 0;
2068         FOREACH_CLIENT(true, {
2069                 if(it != ignore)
2070                         ++totalClients;
2071                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2072                         ++currentlyPlaying;
2073         });
2074
2075         int player_limit = GetPlayerLimit();
2076
2077         int free_slots = 0;
2078         if (!player_limit)
2079                 free_slots = maxclients - totalClients;
2080         else if(player_limit > 0 && currentlyPlaying < player_limit)
2081                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2082
2083         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2084         {
2085                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT, player_limit);
2086                 msg_time = time + 0.5;
2087         }
2088
2089         return free_slots;
2090 }
2091
2092 bool joinAllowed(entity this)
2093 {
2094         if (CS(this).version_mismatch) return false;
2095         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2096         if (!nJoinAllowed(this, this)) return false;
2097         if (teamplay && lockteams) return false;
2098         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2099         if (ShowTeamSelection(this)) return false;
2100         return true;
2101 }
2102
2103 void show_entnum(entity this)
2104 {
2105         // waypoint editor implements a similar feature for waypoints
2106         if (waypointeditor_enabled)
2107                 return;
2108
2109         if (wasfreed(this.wp_aimed))
2110                 this.wp_aimed = NULL;
2111
2112         WarpZone_crosshair_trace_plusvisibletriggers(this);
2113         entity ent = NULL;
2114         if (trace_ent)
2115         {
2116                 ent = trace_ent;
2117                 if (ent != this.wp_aimed)
2118                 {
2119                         string str = sprintf(
2120                                 "^7ent #%d\n^8 netname: ^3%s\n^8 classname: ^5%s\n^8 origin: ^2'%s'",
2121                                 etof(ent), ent.netname, ent.classname, vtos(ent.origin));
2122                         debug_text_3d((ent.absmin + ent.absmax) * 0.5, str, 0, 7, '0 0 0');
2123                 }
2124         }
2125         if (this.wp_aimed != ent)
2126                 this.wp_aimed = ent;
2127 }
2128
2129 .string shootfromfixedorigin;
2130 .bool dualwielding_prev;
2131 bool PlayerThink(entity this)
2132 {
2133         if (game_stopped || intermission_running) {
2134                 this.modelflags &= ~MF_ROCKET;
2135                 if(intermission_running)
2136                         IntermissionThink(this);
2137                 return false;
2138         }
2139
2140         if (timeout_status == TIMEOUT_ACTIVE) {
2141                 // don't allow the player to turn around while game is paused
2142                 // FIXME turn this into CSQC stuff
2143                 this.v_angle = this.lastV_angle;
2144                 this.angles = this.lastV_angle;
2145                 this.fixangle = true;
2146         }
2147
2148         if (frametime) player_powerups(this);
2149
2150         if (frametime && autocvar_sv_show_entnum) show_entnum(this);
2151
2152         if (IS_DEAD(this)) {
2153                 if (this.personal && g_race_qualifying) {
2154                         if (time > this.respawn_time) {
2155                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2156                                 respawn(this);
2157                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2158                         }
2159                 } else {
2160                         if (frametime) player_anim(this);
2161
2162                         if (this.respawn_flags & RESPAWN_DENY)
2163                         {
2164                                 STAT(RESPAWN_TIME, this) = 0;
2165                                 return false;
2166                         }
2167
2168                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2169
2170                         switch(this.deadflag)
2171                         {
2172                                 case DEAD_DYING:
2173                                 {
2174                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2175                                                 this.deadflag = DEAD_RESPAWNING;
2176                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2177                                                 this.deadflag = DEAD_DEAD;
2178                                         break;
2179                                 }
2180                                 case DEAD_DEAD:
2181                                 {
2182                                         if (button_pressed)
2183                                                 this.deadflag = DEAD_RESPAWNABLE;
2184                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2185                                                 this.deadflag = DEAD_RESPAWNING;
2186                                         break;
2187                                 }
2188                                 case DEAD_RESPAWNABLE:
2189                                 {
2190                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2191                                                 this.deadflag = DEAD_RESPAWNING;
2192                                         break;
2193                                 }
2194                                 case DEAD_RESPAWNING:
2195                                 {
2196                                         if (time > this.respawn_time)
2197                                         {
2198                                                 this.respawn_time = time + 1; // only retry once a second
2199                                                 this.respawn_time_max = this.respawn_time;
2200                                                 respawn(this);
2201                                         }
2202                                         break;
2203                                 }
2204                         }
2205
2206                         ShowRespawnCountdown(this);
2207
2208                         if (this.respawn_flags & RESPAWN_SILENT)
2209                                 STAT(RESPAWN_TIME, this) = 0;
2210                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2211                         {
2212                                 if (time < this.respawn_time)
2213                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2214                                 else if (this.deadflag != DEAD_RESPAWNING)
2215                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2216                         }
2217                         else
2218                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2219                 }
2220
2221                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2222                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2223                         STAT(RESPAWN_TIME, this) *= -1;
2224
2225                 return false;
2226         }
2227
2228         FixPlayermodel(this);
2229
2230         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2231                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2232                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2233         }
2234
2235         // reset gun alignment when dual wielding status changes
2236         // to ensure guns are always aligned right and left
2237         bool dualwielding = W_DualWielding(this);
2238         if(this.dualwielding_prev != dualwielding)
2239         {
2240                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2241                 this.dualwielding_prev = dualwielding;
2242         }
2243
2244         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2245         //if(frametime)
2246         {
2247                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2248                 {
2249                         .entity weaponentity = weaponentities[slot];
2250                         if(WEP_CVAR(vortex, charge_always))
2251                                 W_Vortex_Charge(this, weaponentity, frametime);
2252                         W_WeaponFrame(this, weaponentity);
2253                 }
2254         }
2255
2256         if (frametime)
2257         {
2258                 // WEAPONTODO: Add a weapon request for this
2259                 // rot vortex charge to the charge limit
2260                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2261                 {
2262                         .entity weaponentity = weaponentities[slot];
2263                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2264                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2265                 }
2266
2267                 player_regen(this);
2268                 player_anim(this);
2269                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2270         }
2271
2272         monsters_setstatus(this);
2273
2274         return true;
2275 }
2276
2277 .bool would_spectate;
2278 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2279 void ObserverOrSpectatorThink(entity this)
2280 {
2281         bool is_spec = IS_SPEC(this);
2282         if ( CS(this).impulse )
2283         {
2284                 int r = MinigameImpulse(this, CS(this).impulse);
2285                 if (!is_spec || r)
2286                         CS(this).impulse = 0;
2287
2288                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2289                 {
2290                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2291                         CS(this).impulse = 0;
2292                         return;
2293                 }
2294         }
2295
2296         if (frametime && autocvar_sv_show_entnum) show_entnum(this);
2297
2298         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2299         {
2300                 CS(this).autojoin_checked = true;
2301                 TRANSMUTE(Player, this);
2302                 PutClientInServer(this);
2303
2304                 .entity weaponentity = weaponentities[0];
2305                 if(this.(weaponentity).m_weapon == WEP_Null)
2306                         W_NextWeapon(this, 0, weaponentity);
2307
2308                 return;
2309         }
2310
2311         if (this.flags & FL_JUMPRELEASED) {
2312                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2313                         this.flags &= ~FL_JUMPRELEASED;
2314                         this.flags |= FL_SPAWNING;
2315                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2316                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2317                         this.flags &= ~FL_JUMPRELEASED;
2318                         if(SpectateNext(this)) {
2319                                 TRANSMUTE(Spectator, this);
2320                         } else if (is_spec) {
2321                                 TRANSMUTE(Observer, this);
2322                                 PutClientInServer(this);
2323                         }
2324                         else
2325                                 this.would_spectate = false; // unable to spectate anyone
2326                         if (is_spec)
2327                                 CS(this).impulse = 0;
2328                 } else if (is_spec) {
2329                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2330                                 this.flags &= ~FL_JUMPRELEASED;
2331                                 if(SpectatePrev(this)) {
2332                                         TRANSMUTE(Spectator, this);
2333                                 } else {
2334                                         TRANSMUTE(Observer, this);
2335                                         PutClientInServer(this);
2336                                 }
2337                                 CS(this).impulse = 0;
2338                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2339                                 if(!observe_blocked_if_eliminated || !INGAME(this)) {
2340                                         this.would_spectate = false;
2341                                         this.flags &= ~FL_JUMPRELEASED;
2342                                         TRANSMUTE(Observer, this);
2343                                         PutClientInServer(this);
2344                                 }
2345                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2346                                 PutObserverInServer(this, false, true);
2347                                 this.would_spectate = true;
2348                         }
2349                 }
2350                 else {
2351                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2352                         if (PHYS_INPUT_BUTTON_USE(this))
2353                                 wouldclip = !wouldclip;
2354                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2355                         set_movetype(this, preferred_movetype);
2356                 }
2357         } else { // jump pressed
2358                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2359                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2360                         this.flags |= FL_JUMPRELEASED;
2361                         // primary attack pressed
2362                         if(this.flags & FL_SPAWNING)
2363                         {
2364                                 this.flags &= ~FL_SPAWNING;
2365                                 if(joinAllowed(this))
2366                                         Join(this);
2367                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2368                                         CS(this).autojoin_checked = -1;
2369                                 return;
2370                         }
2371                 }
2372                 if(is_spec && !SpectateUpdate(this))
2373                         PutObserverInServer(this, false, true);
2374         }
2375         if (is_spec)
2376                 this.flags |= FL_CLIENT | FL_NOTARGET;
2377 }
2378
2379 void PlayerUseKey(entity this)
2380 {
2381         if (!IS_PLAYER(this))
2382                 return;
2383
2384         if(this.vehicle)
2385         {
2386                 if(!game_stopped)
2387                 {
2388                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2389                         return;
2390                 }
2391         }
2392         else if(autocvar_g_vehicles_enter)
2393         {
2394                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2395                 {
2396                         entity head, closest_target = NULL;
2397                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2398
2399                         while(head) // find the closest acceptable target to enter
2400                         {
2401                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2402                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2403                                 {
2404                                         if(closest_target)
2405                                         {
2406                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2407                                                 { closest_target = head; }
2408                                         }
2409                                         else { closest_target = head; }
2410                                 }
2411
2412                                 head = head.chain;
2413                         }
2414
2415                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2416                 }
2417         }
2418
2419         // a use key was pressed; call handlers
2420         MUTATOR_CALLHOOK(PlayerUseKey, this);
2421 }
2422
2423
2424 /*
2425 =============
2426 PlayerPreThink
2427
2428 Called every frame for each client before the physics are run
2429 =============
2430 */
2431 .float last_vehiclecheck;
2432 void PlayerPreThink (entity this)
2433 {
2434         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2435         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2436
2437         WarpZone_PlayerPhysics_FixVAngle(this);
2438
2439         if (frametime) {
2440                 // physics frames: update anticheat stuff
2441                 anticheat_prethink(this);
2442
2443                 // WORKAROUND: only use dropclient in server frames (frametime set).
2444                 // Never use it in cl_movement frames (frametime zero).
2445                 if (blockSpectators && IS_REAL_CLIENT(this)
2446                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2447                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2448                 {
2449                         if (dropclient_schedule(this))
2450                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2451                 }
2452         }
2453
2454         zoomstate_set = false;
2455
2456         // Check for nameless players
2457         if (this.netname == "" || this.netname != CS(this).netname_previous)
2458         {
2459                 bool assume_unchanged = (CS(this).netname_previous == "");
2460                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2461                 {
2462                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2463                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2464                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2465                         assume_unchanged = false;
2466                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2467                 }
2468                 if (isInvisibleString(this.netname))
2469                 {
2470                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2471                         sprint(this, "Warning: invisible names are not allowed.\n");
2472                         assume_unchanged = false;
2473                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2474                 }
2475                 if (!assume_unchanged && autocvar_sv_eventlog)
2476                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2477                 strcpy(CS(this).netname_previous, this.netname);
2478         }
2479
2480         // version nagging
2481         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2482         CS(this).version_nagtime = 0;
2483         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2484             // git client
2485         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2486             // git server
2487             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2488         } else {
2489             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2490             if (r < 0) { // old client
2491                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2492             } else if (r > 0) { // old server
2493                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2494             }
2495         }
2496     }
2497
2498         // GOD MODE info
2499         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2500         {
2501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2502                 this.max_armorvalue = 0;
2503         }
2504
2505         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2506         {
2507                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2508                 {
2509                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2510                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2511                         if (this.iceblock)
2512                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2513
2514                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2515                                 Unfreeze(this, false);
2516                 }
2517                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2518                 {
2519                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2520                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2521
2522                         if (GetResource(this, RES_HEALTH) < 1)
2523                         {
2524                                 if (this.vehicle)
2525                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2526                                 if(this.event_damage)
2527                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2528                         }
2529                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2530                                 Unfreeze(this, false);
2531                 }
2532         }
2533
2534         MUTATOR_CALLHOOK(PlayerPreThink, this);
2535
2536         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2537         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2538         {
2539                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2540                 {
2541                         if(!it.owner)
2542                         {
2543                                 if(!it.team || SAME_TEAM(this, it))
2544                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2545                                 else if(autocvar_g_vehicles_steal)
2546                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2547                         }
2548                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2549                         {
2550                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2551                         }
2552                 });
2553
2554                 this.last_vehiclecheck = time + 1;
2555         }
2556
2557         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2558                 PlayerUseKey(this);
2559         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2560
2561         if (IS_PLAYER(this)) {
2562                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2563                         error("Client can't be spawned as player on connection!");
2564                 if(!PlayerThink(this))
2565                         return;
2566         }
2567         else if (game_stopped || intermission_running) {
2568                 if(intermission_running)
2569                         IntermissionThink(this);
2570                 return;
2571         }
2572         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2573         {
2574                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2575                 CS(this).autojoin_checked = 1;
2576                 // don't do this in ClientConnect
2577                 // many things can go wrong if a client is spawned as player on connection
2578                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2579                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2580                                 && (!teamplay || autocvar_g_balance_teams)))
2581                 {
2582                         if(joinAllowed(this))
2583                                 Join(this);
2584                         return;
2585                 }
2586         }
2587         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2588                 ObserverOrSpectatorThink(this);
2589         }
2590
2591         // WEAPONTODO: Add weapon request for this
2592         if (!zoomstate_set) {
2593                 bool wep_zoomed = false;
2594                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2595                 {
2596                         .entity weaponentity = weaponentities[slot];
2597                         Weapon thiswep = this.(weaponentity).m_weapon;
2598                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2599                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2600                 }
2601                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2602         }
2603
2604         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2605         {
2606                 CS(this).teamkill_soundtime = 0;
2607
2608                 entity e = CS(this).teamkill_soundsource;
2609                 entity oldpusher = e.pusher;
2610                 e.pusher = this;
2611                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2612                 e.pusher = oldpusher;
2613         }
2614
2615         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2616                 CS(this).taunt_soundtime = 0;
2617                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2618         }
2619
2620         target_voicescript_next(this);
2621 }
2622
2623 void DrownPlayer(entity this)
2624 {
2625         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2626                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2627         {
2628                 STAT(AIR_FINISHED, this) = 0;
2629                 return;
2630         }
2631
2632         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2633         {
2634                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2635                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2636                 STAT(AIR_FINISHED, this) = 0;
2637         }
2638         else
2639         {
2640                 if (!STAT(AIR_FINISHED, this))
2641                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2642                 if (STAT(AIR_FINISHED, this) < time)
2643                 {       // drown!
2644                         if (this.pain_finished < time)
2645                         {
2646                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2647                                 this.pain_finished = time + 0.5;
2648                         }
2649                 }
2650         }
2651 }
2652
2653 .bool move_qcphysics;
2654
2655 void Player_Physics(entity this)
2656 {
2657         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2658
2659         if(!this.move_qcphysics)
2660                 return;
2661
2662         if(!frametime && !CS(this).pm_frametime)
2663                 return;
2664
2665         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2666
2667         CS(this).pm_frametime = 0;
2668 }
2669
2670 /*
2671 =============
2672 PlayerPostThink
2673
2674 Called every frame for each client after the physics are run
2675 =============
2676 */
2677 void PlayerPostThink (entity this)
2678 {
2679         Player_Physics(this);
2680
2681         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2682         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2683         if (IS_REAL_CLIENT(this))
2684         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2685         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2686         {
2687                 int totalClients = 0;
2688                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2689                 {
2690                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2691                         if (server_is_dedicated)
2692                         {
2693                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2694                                 {
2695                                         ++totalClients;
2696                                 });
2697                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2698                                         totalClients = 0;
2699                         }
2700                 }
2701                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2702                 {
2703                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2704                         {
2705                                 ++totalClients;
2706                         });
2707                 }
2708
2709                 if (totalClients < autocvar_sv_maxidle_minplayers)
2710                 {
2711                         // idle kick disabled
2712                         CS(this).parm_idlesince = time;
2713                 }
2714                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2715                 {
2716                         if (CS(this).idlekick_lasttimeleft)
2717                         {
2718                                 CS(this).idlekick_lasttimeleft = 0;
2719                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2720                         }
2721                 }
2722                 else
2723                 {
2724                         float maxidle_time = autocvar_sv_maxidle;
2725                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2726                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2727                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2728                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2729                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2730                         {
2731                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2732                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2733                                 else
2734                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2735                         }
2736                         if (timeleft <= 0) {
2737                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2738                                 {
2739                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2740                                         PutObserverInServer(this, true, true);
2741                                 }
2742                                 else
2743                                 {
2744                                         if (dropclient_schedule(this))
2745                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2746                                 }
2747                                 return;
2748                         }
2749                         else if (timeleft <= countdown_time) {
2750                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2751                                         play2(this, SND(TALK2));
2752                                 CS(this).idlekick_lasttimeleft = timeleft;
2753                         }
2754                 }
2755         }
2756
2757         CheatFrame(this);
2758
2759         if (game_stopped)
2760         {
2761                 this.solid = SOLID_NOT;
2762                 this.takedamage = DAMAGE_NO;
2763                 set_movetype(this, MOVETYPE_NONE);
2764                 CS(this).teamkill_complain = 0;
2765                 CS(this).teamkill_soundtime = 0;
2766                 CS(this).teamkill_soundsource = NULL;
2767         }
2768
2769         if (IS_PLAYER(this)) {
2770                 if(this.death_time == time && IS_DEAD(this))
2771                 {
2772                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2773                         // once all the damage events of this frame have been processed with normal size
2774                         this.maxs.z = 5;
2775                         setsize(this, this.mins, this.maxs);
2776                 }
2777                 DrownPlayer(this);
2778                 UpdateChatBubble(this);
2779                 if (CS(this).impulse) ImpulseCommands(this);
2780                 GetPressedKeys(this);
2781                 if (game_stopped)
2782                 {
2783                         CSQCMODEL_AUTOUPDATE(this);
2784                         return;
2785                 }
2786         }
2787         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2788         {
2789                 CS(this).pressedkeys = 0;
2790                 STAT(PRESSED_KEYS, this) = 0;
2791         }
2792
2793         if (this.waypointsprite_attachedforcarrier) {
2794                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2795                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2796         }
2797
2798         CSQCMODEL_AUTOUPDATE(this);
2799 }
2800
2801 // hack to copy the button fields from the client entity to the Client State
2802 void PM_UpdateButtons(entity this, entity store)
2803 {
2804         if(this.impulse)
2805                 store.impulse = this.impulse;
2806         this.impulse = 0;
2807
2808         bool typing = this.buttonchat || this.button12;
2809
2810         store.button0 = (typing) ? 0 : this.button0;
2811         //button1?!
2812         store.button2 = (typing) ? 0 : this.button2;
2813         store.button3 = (typing) ? 0 : this.button3;
2814         store.button4 = this.button4;
2815         store.button5 = (typing) ? 0 : this.button5;
2816         store.button6 = this.button6;
2817         store.button7 = this.button7;
2818         store.button8 = this.button8;
2819         store.button9 = this.button9;
2820         store.button10 = this.button10;
2821         store.button11 = this.button11;
2822         store.button12 = this.button12;
2823         store.button13 = this.button13;
2824         store.button14 = this.button14;
2825         store.button15 = this.button15;
2826         store.button16 = this.button16;
2827         store.buttonuse = this.buttonuse;
2828         store.buttonchat = this.buttonchat;
2829
2830         store.cursor_active = this.cursor_active;
2831         store.cursor_screen = this.cursor_screen;
2832         store.cursor_trace_start = this.cursor_trace_start;
2833         store.cursor_trace_endpos = this.cursor_trace_endpos;
2834         store.cursor_trace_ent = this.cursor_trace_ent;
2835
2836         store.ping = this.ping;
2837         store.ping_packetloss = this.ping_packetloss;
2838         store.ping_movementloss = this.ping_movementloss;
2839
2840         store.v_angle = this.v_angle;
2841         store.movement = this.movement;
2842 }
2843
2844 NET_HANDLE(fpsreport, bool)
2845 {
2846         int fps = ReadShort();
2847         PlayerScore_Set(sender, SP_FPS, fps);
2848         return true;
2849 }