qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         this.strength_finished = 0;
 338         this.invincible_finished = 0;
 339         this.superweapons_finished = 0;
 340         this.air_finished = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_frame = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         this.strength_finished = 0;
 642         this.invincible_finished = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         this.air_finished = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         this.crouch = false;
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 delete(this.swampslug);
 691         this.in_swamp = false;
 692         STAT(HUD, this) = HUD_NORMAL;
 693
 694         this.event_damage = PlayerDamage;
 695         this.event_heal = PlayerHeal;
 696
 697         this.draggable = func_null;
 698
 699         if(!this.bot_attack)
 700                 IL_PUSH(g_bot_targets, this);
 701         this.bot_attack = true;
 702         if(!this.monster_attack)
 703                 IL_PUSH(g_monster_targets, this);
 704         this.monster_attack = true;
 705         navigation_dynamicgoal_init(this, false);
 706
 707         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 708
 709         // player was spectator
 710         if (CS(this).killcount == FRAGS_SPECTATOR) {
 711                 PlayerScore_Clear(this);
 712                 CS(this).killcount = 0;
 713                 CS(this).startplaytime = time;
 714         }
 715
 716         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717         {
 718                 .entity weaponentity = weaponentities[slot];
 719                 CL_SpawnWeaponentity(this, weaponentity);
 720         }
 721         this.alpha = default_player_alpha;
 722         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 723         this.exteriorweaponentity.alpha = default_weapon_alpha;
 724
 725         this.speedrunning = false;
 726
 727         this.counter_cnt = 0;
 728         this.fragsfilter_cnt = 0;
 729
 730         target_voicescript_clear(this);
 731
 732         // reset fields the weapons may use
 733         FOREACH(Weapons, true, {
 734                 it.wr_resetplayer(it, this);
 735                         // reload all reloadable weapons
 736                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 737                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 738                         {
 739                                 .entity weaponentity = weaponentities[slot];
 740                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 741                         }
 742                 }
 743         });
 744
 745         {
 746                 string s = spot.target;
 747                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 748                         spot.target = string_null;
 749                 SUB_UseTargets(spot, this, NULL);
 750                 if(g_assault || g_race)
 751                         spot.target = s;
 752         }
 753
 754         Unfreeze(this, false);
 755
 756         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 757
 758         if (autocvar_spawn_debug)
 759         {
 760                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 761                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 762         }
 763
 764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765         {
 766                 .entity weaponentity = weaponentities[slot];
 767                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 768                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 769                 else
 770                         this.(weaponentity).m_switchweapon = WEP_Null;
 771                 this.(weaponentity).m_weapon = WEP_Null;
 772                 this.(weaponentity).weaponname = "";
 773                 this.(weaponentity).m_switchingweapon = WEP_Null;
 774                 this.(weaponentity).cnt = -1;
 775         }
 776
 777         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 778
 779         if (CS(this).impulse) ImpulseCommands(this);
 780
 781         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 783         {
 784                 .entity weaponentity = weaponentities[slot];
 785                 W_WeaponFrame(this, weaponentity);
 786         }
 787
 788         if (!warmup_stage && !this.alivetime)
 789                 this.alivetime = time;
 790
 791         antilag_clear(this, CS(this));
 792 }
 793
 794 /** Called when a client spawns in the server */
 795 void PutClientInServer(entity this)
 796 {
 797         if (IS_BOT_CLIENT(this)) {
 798                 TRANSMUTE(Player, this);
 799         } else if (IS_REAL_CLIENT(this)) {
 800                 msg_entity = this;
 801                 WriteByte(MSG_ONE, SVC_SETVIEW);
 802                 WriteEntity(MSG_ONE, this);
 803         }
 804         if (game_stopped)
 805                 TRANSMUTE(Observer, this);
 806
 807         SetSpectatee(this, NULL);
 808
 809         // reset player keys
 810         if(PS(this))
 811                 PS(this).itemkeys = 0;
 812
 813         MUTATOR_CALLHOOK(PutClientInServer, this);
 814
 815         if (IS_OBSERVER(this)) {
 816                 PutObserverInServer(this);
 817         } else if (IS_PLAYER(this)) {
 818                 PutPlayerInServer(this);
 819         }
 820 }
 821
 822 // TODO do we need all these fields, or should we stop autodetecting runtime
 823 // changes and just have a console command to update this?
 824 bool ClientInit_SendEntity(entity this, entity to, int sf)
 825 {
 826         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 827         return = true;
 828         msg_entity = to;
 829         // MSG_INIT replacement
 830         // TODO: make easier to use
 831         Registry_send_all();
 832         W_PROP_reload(MSG_ONE, to);
 833         ClientInit_misc(this);
 834         MUTATOR_CALLHOOK(Ent_Init);
 835 }
 836 void ClientInit_misc(entity this)
 837 {
 838         int channel = MSG_ONE;
 839         WriteHeader(channel, ENT_CLIENT_INIT);
 840         WriteByte(channel, g_nexball_meter_period * 32);
 841         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 843         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 844         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 845         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 847         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 848         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 849
 850         if(sv_foginterval && world.fog != "")
 851                 WriteString(channel, world.fog);
 852         else
 853                 WriteString(channel, "");
 854         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 855         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 856         WriteByte(channel, serverflags);
 857         WriteCoord(channel, autocvar_g_trueaim_minrange);
 858 }
 859
 860 void ClientInit_CheckUpdate(entity this)
 861 {
 862         this.nextthink = time;
 863         if(this.count != autocvar_g_balance_armor_blockpercent)
 864         {
 865                 this.count = autocvar_g_balance_armor_blockpercent;
 866                 this.SendFlags |= 1;
 867         }
 868         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 869         {
 870                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 871                 this.SendFlags |= 1;
 872         }
 873 }
 874
 875 void ClientInit_Spawn()
 876 {
 877         entity e = new_pure(clientinit);
 878         setthink(e, ClientInit_CheckUpdate);
 879         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 880
 881         ClientInit_CheckUpdate(e);
 882 }
 883
 884 /*
 885 =============
 886 SetNewParms
 887 =============
 888 */
 889 void SetNewParms ()
 890 {
 891         // initialize parms for a new player
 892         parm1 = -(86400 * 366);
 893
 894         MUTATOR_CALLHOOK(SetNewParms);
 895 }
 896
 897 /*
 898 =============
 899 SetChangeParms
 900 =============
 901 */
 902 void SetChangeParms (entity this)
 903 {
 904         // save parms for level change
 905         parm1 = CS(this).parm_idlesince - time;
 906
 907         MUTATOR_CALLHOOK(SetChangeParms);
 908 }
 909
 910 /*
 911 =============
 912 DecodeLevelParms
 913 =============
 914 */
 915 void DecodeLevelParms(entity this)
 916 {
 917         // load parms
 918         CS(this).parm_idlesince = parm1;
 919         if (CS(this).parm_idlesince == -(86400 * 366))
 920                 CS(this).parm_idlesince = time;
 921
 922         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 923         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 924
 925         MUTATOR_CALLHOOK(DecodeLevelParms);
 926 }
 927
 928 void FixClientCvars(entity e)
 929 {
 930         // send prediction settings to the client
 931         stuffcmd(e, "\nin_bindmap 0 0\n");
 932         if(autocvar_g_antilag == 3) // client side hitscan
 933                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 934         if(autocvar_sv_gentle)
 935                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 936
 937         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 938         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 939
 940         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 941
 942         MUTATOR_CALLHOOK(FixClientCvars, e);
 943 }
 944
 945 bool findinlist_abbrev(string tofind, string list)
 946 {
 947         if(list == "" || tofind == "")
 948                 return false; // empty list or search, just return
 949
 950         // this function allows abbreviated strings!
 951         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 952         {
 953                 return true;
 954         });
 955
 956         return false;
 957 }
 958
 959 bool PlayerInIPList(entity p, string iplist)
 960 {
 961         // some safety checks (never allow local?)
 962         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 963                 return false;
 964
 965         return findinlist_abbrev(p.netaddress, iplist);
 966 }
 967
 968 bool PlayerInIDList(entity p, string idlist)
 969 {
 970         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 971         if(!p.crypto_idfp)
 972                 return false;
 973
 974         return findinlist_abbrev(p.crypto_idfp, idlist);
 975 }
 976
 977 bool PlayerInList(entity player, string list)
 978 {
 979         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 980 }
 981
 982 #ifdef DP_EXT_PRECONNECT
 983 /*
 984 =============
 985 ClientPreConnect
 986
 987 Called once (not at each match start) when a client begins a connection to the server
 988 =============
 989 */
 990 void ClientPreConnect(entity this)
 991 {
 992         if(autocvar_sv_eventlog)
 993         {
 994                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 995                         this.playerid,
 996                         etof(this),
 997                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 998                 ));
 999         }
1000 }
1001 #endif
1002
1003 string GetClientVersionMessage(entity this)
1004 {
1005         if (CS(this).version_mismatch) {
1006                 if(CS(this).version < autocvar_gameversion) {
1007                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1008                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1009                 } else {
1010                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1011                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1012                 }
1013         } else {
1014                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1015         }
1016 }
1017
1018 string getwelcomemessage(entity this)
1019 {
1020         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1021         string modifications = M_ARGV(0, string);
1022
1023         if(g_weaponarena)
1024         {
1025                 if(g_weaponarena_random)
1026                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1027                 else
1028                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1029         }
1030         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1031                 modifications = strcat(modifications, ", No start weapons");
1032         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1033                 modifications = strcat(modifications, ", Low gravity");
1034         if(g_weapon_stay && !g_cts)
1035                 modifications = strcat(modifications, ", Weapons stay");
1036         if(g_jetpack)
1037                 modifications = strcat(modifications, ", Jet pack");
1038         if(autocvar_g_powerups == 0)
1039                 modifications = strcat(modifications, ", No powerups");
1040         if(autocvar_g_powerups > 0)
1041                 modifications = strcat(modifications, ", Powerups");
1042         modifications = substring(modifications, 2, strlen(modifications) - 2);
1043
1044         string versionmessage = GetClientVersionMessage(this);
1045         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1046
1047         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1048
1049         if(modifications != "")
1050                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1051
1052         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1053         {
1054                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1055                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1056         }
1057
1058         if (cache_mutatormsg != "") {
1059                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1060         }
1061
1062         string mutator_msg = "";
1063         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1064         mutator_msg = M_ARGV(0, string);
1065
1066         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1067
1068         string motd = autocvar_sv_motd;
1069         if (motd != "") {
1070                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1071         }
1072         return s;
1073 }
1074
1075 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1076
1077 /**
1078 =============
1079 ClientConnect
1080
1081 Called when a client connects to the server
1082 =============
1083 */
1084 void ClientConnect(entity this)
1085 {
1086         if (Ban_MaybeEnforceBanOnce(this)) return;
1087         assert(!IS_CLIENT(this), return);
1088         this.flags |= FL_CLIENT;
1089         assert(player_count >= 0, player_count = 0);
1090
1091 #ifdef WATERMARK
1092         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1093 #endif
1094         TRANSMUTE(Client, this);
1095         CS(this).version_nagtime = time + 10 + random() * 10;
1096
1097         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1098
1099         bot_clientconnect(this);
1100
1101         Player_DetermineForcedTeam(this);
1102
1103         TRANSMUTE(Observer, this);
1104
1105         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1106
1107         // always track bots, don't ask for cl_allow_uidtracking
1108         if (IS_BOT_CLIENT(this))
1109                 PlayerStats_GameReport_AddPlayer(this);
1110         else
1111                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1112
1113         if (autocvar_sv_eventlog)
1114                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1115
1116         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1117
1118         stuffcmd(this, clientstuff, "\n");
1119         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1120
1121         FixClientCvars(this);
1122
1123         // get version info from player
1124         stuffcmd(this, "cmd clientversion $gameversion\n");
1125
1126         // notify about available teams
1127         if (teamplay)
1128         {
1129                 entity balance = TeamBalance_CheckAllowedTeams(this);
1130                 int t = TeamBalance_GetAllowedTeams(balance);
1131                 TeamBalance_Destroy(balance);
1132                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1133         }
1134         else
1135         {
1136                 stuffcmd(this, "set _teams_available 0\n");
1137         }
1138
1139         bot_relinkplayerlist();
1140
1141         CS(this).spectatortime = time;
1142         if (blockSpectators)
1143         {
1144                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1145         }
1146
1147         CS(this).jointime = time;
1148
1149         if (IS_REAL_CLIENT(this))
1150         {
1151                 if (g_weaponarena_weapons == WEPSET(TUBA))
1152                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1153         }
1154
1155         if (!sv_foginterval && world.fog != "")
1156                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1157
1158         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1159                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1160                         send_CSQC_teamnagger();
1161
1162         CSQCMODEL_AUTOINIT(this);
1163
1164         CS(this).model_randomizer = random();
1165
1166         if (IS_REAL_CLIENT(this))
1167                 sv_notice_join(this);
1168
1169         this.move_qcphysics = autocvar_sv_qcphysics;
1170
1171         // update physics stats (players can spawn before physics runs)
1172         Physics_UpdateStats(this);
1173
1174         IL_EACH(g_initforplayer, it.init_for_player, {
1175                 it.init_for_player(it, this);
1176         });
1177
1178         Handicap_Initialize(this);
1179
1180         MUTATOR_CALLHOOK(ClientConnect, this);
1181
1182         if (IS_REAL_CLIENT(this))
1183         {
1184                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1185                 {
1186                         CS(this).motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1188                 }
1189         }
1190 }
1191 /*
1192 =============
1193 ClientDisconnect
1194
1195 Called when a client disconnects from the server
1196 =============
1197 */
1198 .entity chatbubbleentity;
1199 void ClientDisconnect(entity this)
1200 {
1201         assert(IS_CLIENT(this), return);
1202
1203         PlayerStats_GameReport_FinalizePlayer(this);
1204         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1205         if (CS(this).active_minigame) part_minigame(this);
1206         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1207
1208         if (autocvar_sv_eventlog)
1209                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1210
1211         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1212
1213         if(IS_SPEC(this))
1214                 SetSpectatee(this, NULL);
1215
1216     MUTATOR_CALLHOOK(ClientDisconnect, this);
1217
1218         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1219         strfree(CS(this).weaponorder_byimpulse);
1220         ClientState_detach(this);
1221
1222         Portal_ClearAll(this);
1223
1224         Unfreeze(this, false);
1225
1226         RemoveGrapplingHooks(this);
1227
1228         // Here, everything has been done that requires this player to be a client.
1229
1230         this.flags &= ~FL_CLIENT;
1231
1232         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1233         if (this.killindicator) delete(this.killindicator);
1234
1235         WaypointSprite_PlayerGone(this);
1236
1237         bot_relinkplayerlist();
1238
1239         strfree(this.clientstatus);
1240         if (this.personal) delete(this.personal);
1241
1242         this.playerid = 0;
1243         ReadyCount();
1244         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1245
1246         ONREMOVE(this);
1247 }
1248
1249 void ChatBubbleThink(entity this)
1250 {
1251         this.nextthink = time;
1252         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1253         {
1254                 if(this.owner) // but why can that ever be NULL?
1255                         this.owner.chatbubbleentity = NULL;
1256                 delete(this);
1257                 return;
1258         }
1259
1260         this.mdl = "";
1261
1262         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1263         {
1264                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1265                         this.mdl = "models/sprites/minigame_busy.iqm";
1266                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1267                         this.mdl = "models/misc/chatbubble.spr";
1268         }
1269
1270         if ( this.model != this.mdl )
1271                 _setmodel(this, this.mdl);
1272
1273 }
1274
1275 void UpdateChatBubble(entity this)
1276 {
1277         if (this.alpha < 0)
1278                 return;
1279         // spawn a chatbubble entity if needed
1280         if (!this.chatbubbleentity)
1281         {
1282                 this.chatbubbleentity = new(chatbubbleentity);
1283                 this.chatbubbleentity.owner = this;
1284                 this.chatbubbleentity.exteriormodeltoclient = this;
1285                 setthink(this.chatbubbleentity, ChatBubbleThink);
1286                 this.chatbubbleentity.nextthink = time;
1287                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1288                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1289                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1290                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1291                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1292                 //this.chatbubbleentity.model = "";
1293                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1294         }
1295 }
1296
1297
1298 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1299 // added to the model skins
1300 /*void UpdateColorModHack()
1301 {
1302         float c;
1303         c = this.clientcolors & 15;
1304         // LordHavoc: only bothering to support white, green, red, yellow, blue
1305              if (!teamplay) this.colormod = '0 0 0';
1306         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1307         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1308         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1309         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1310         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1311         else this.colormod = '1 1 1';
1312 }*/
1313
1314 void respawn(entity this)
1315 {
1316         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1317         {
1318                 this.solid = SOLID_NOT;
1319                 this.takedamage = DAMAGE_NO;
1320                 set_movetype(this, MOVETYPE_FLY);
1321                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1322                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1323                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1324                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1325                 if(autocvar_g_respawn_ghosts_maxtime)
1326                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1327         }
1328
1329         CopyBody(this, 1);
1330
1331         this.effects |= EF_NODRAW; // prevent another CopyBody
1332         PutClientInServer(this);
1333 }
1334
1335 ERASEABLE
1336 void PrintToChat(entity client, string text)
1337 {
1338         text = strcat("\{1}^7", text, "\n");
1339         sprint(client, text);
1340 }
1341
1342 ERASEABLE
1343 void DebugPrintToChat(entity client, string text)
1344 {
1345         if (autocvar_developer > 0)
1346         {
1347                 PrintToChat(client, text);
1348         }
1349 }
1350
1351 ERASEABLE
1352 void PrintToChatAll(string text)
1353 {
1354         text = strcat("\{1}^7", text, "\n");
1355         bprint(text);
1356 }
1357
1358 ERASEABLE
1359 void DebugPrintToChatAll(string text)
1360 {
1361         if (autocvar_developer > 0)
1362         {
1363                 PrintToChatAll(text);
1364         }
1365 }
1366
1367 ERASEABLE
1368 void PrintToChatTeam(int team_num, string text)
1369 {
1370         text = strcat("\{1}^7", text, "\n");
1371         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1372         {
1373                 if (it.team == team_num)
1374                 {
1375                         sprint(it, text);
1376                 }
1377         });
1378 }
1379
1380 ERASEABLE
1381 void DebugPrintToChatTeam(int team_num, string text)
1382 {
1383         if (autocvar_developer > 0)
1384         {
1385                 PrintToChatTeam(team_num, text);
1386         }
1387 }
1388
1389 void play_countdown(entity this, float finished, Sound samp)
1390 {
1391         TC(Sound, samp);
1392         if(IS_REAL_CLIENT(this))
1393                 if(floor(finished - time - frametime) != floor(finished - time))
1394                         if(finished - time < 6)
1395                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1396 }
1397
1398 void player_powerups(entity this)
1399 {
1400         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1401         int items_prev = this.items;
1402
1403         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1404                 this.modelflags |= MF_ROCKET;
1405         else
1406                 this.modelflags &= ~MF_ROCKET;
1407
1408         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1409
1410         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1411                 return;
1412
1413         Fire_ApplyDamage(this);
1414         Fire_ApplyEffect(this);
1415
1416         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1417         {
1418                 if (this.items & ITEM_Strength.m_itemid)
1419                 {
1420                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1421                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1422                         if (time > this.strength_finished)
1423                         {
1424                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1425                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1426                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1427                         }
1428                 }
1429                 else
1430                 {
1431                         if (time < this.strength_finished)
1432                         {
1433                                 this.items = this.items | ITEM_Strength.m_itemid;
1434                                 if(!g_cts)
1435                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1437                         }
1438                 }
1439                 if (this.items & ITEM_Shield.m_itemid)
1440                 {
1441                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1442                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1443                         if (time > this.invincible_finished)
1444                         {
1445                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1446                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1447                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1448                         }
1449                 }
1450                 else
1451                 {
1452                         if (time < this.invincible_finished)
1453                         {
1454                                 this.items = this.items | ITEM_Shield.m_itemid;
1455                                 if(!g_cts)
1456                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1457                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1458                         }
1459                 }
1460                 if (this.items & IT_SUPERWEAPON)
1461                 {
1462                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1463                         {
1464                                 this.superweapons_finished = 0;
1465                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1466                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1468                         }
1469                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1470                         {
1471                                 // don't let them run out
1472                         }
1473                         else
1474                         {
1475                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1476                                 if (time > this.superweapons_finished)
1477                                 {
1478                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1479                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1480                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1481                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1482                                 }
1483                         }
1484                 }
1485                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1486                 {
1487                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1488                         {
1489                                 this.items = this.items | IT_SUPERWEAPON;
1490                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1491                                 {
1492                                         if(!g_cts)
1493                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1494                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1495                                 }
1496                         }
1497                         else
1498                         {
1499                                 this.superweapons_finished = 0;
1500                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1501                         }
1502                 }
1503                 else
1504                 {
1505                         this.superweapons_finished = 0;
1506                 }
1507         }
1508
1509         if(autocvar_g_nodepthtestplayers)
1510                 this.effects = this.effects | EF_NODEPTHTEST;
1511
1512         if(autocvar_g_fullbrightplayers)
1513                 this.effects = this.effects | EF_FULLBRIGHT;
1514
1515         if (time >= game_starttime)
1516         if (time < this.spawnshieldtime)
1517                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1518
1519         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1520 }
1521
1522 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1523 {
1524         if(current > stable)
1525                 return current;
1526         else if(current > stable - 0.25) // when close enough, "snap"
1527                 return stable;
1528         else
1529                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1530 }
1531
1532 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1533 {
1534         if(current < stable)
1535                 return current;
1536         else if(current < stable + 0.25) // when close enough, "snap"
1537                 return stable;
1538         else
1539                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1540 }
1541
1542 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1543 {
1544         float old = GetResource(this, res);
1545         float current = old;
1546         if(current > rotstable)
1547         {
1548                 if(rotframetime > 0)
1549                 {
1550                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1551                         current = max(rotstable, current - rotlinear * rotframetime);
1552                 }
1553         }
1554         else if(current < regenstable)
1555         {
1556                 if(regenframetime > 0)
1557                 {
1558                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1559                         current = min(regenstable, current + regenlinear * regenframetime);
1560                 }
1561         }
1562
1563         float limit = GetResourceLimit(this, res) * limit_mod;
1564         if(current > limit)
1565                 current = limit;
1566
1567         if (current != old)
1568                 SetResource(this, res, current);
1569 }
1570
1571 void player_regen(entity this)
1572 {
1573         float max_mod, regen_mod, rot_mod, limit_mod;
1574         max_mod = regen_mod = rot_mod = limit_mod = 1;
1575
1576         float regen_health = autocvar_g_balance_health_regen;
1577         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1578         float regen_health_rot = autocvar_g_balance_health_rot;
1579         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1580         float regen_health_stable = autocvar_g_balance_health_regenstable;
1581         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1582         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1583                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1584         max_mod = M_ARGV(1, float);
1585         regen_mod = M_ARGV(2, float);
1586         rot_mod = M_ARGV(3, float);
1587         limit_mod = M_ARGV(4, float);
1588         regen_health = M_ARGV(5, float);
1589         regen_health_linear = M_ARGV(6, float);
1590         regen_health_rot = M_ARGV(7, float);
1591         regen_health_rotlinear = M_ARGV(8, float);
1592         regen_health_stable = M_ARGV(9, float);
1593         regen_health_rotstable = M_ARGV(10, float);
1594
1595         if(!mutator_returnvalue)
1596         if(!STAT(FROZEN, this))
1597         {
1598                 float maxa = autocvar_g_balance_armor_rotstable;
1599                 float mina = autocvar_g_balance_armor_regenstable;
1600
1601                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1602                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1603                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1604
1605                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1606                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1607                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1608         }
1609
1610         // if player rotted to death...  die!
1611         // check this outside above checks, as player may still be able to rot to death
1612         if(GetResource(this, RES_HEALTH) < 1)
1613         {
1614                 if(this.vehicle)
1615                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1616                 if(this.event_damage)
1617                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1618         }
1619
1620         if (!(this.items & IT_UNLIMITED_AMMO))
1621         {
1622                 float maxf = autocvar_g_balance_fuel_rotstable;
1623                 float minf = autocvar_g_balance_fuel_regenstable;
1624
1625                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1626                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1627                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1628         }
1629 }
1630
1631 bool zoomstate_set;
1632 void SetZoomState(entity this, float newzoom)
1633 {
1634         if(newzoom != CS(this).zoomstate)
1635         {
1636                 CS(this).zoomstate = newzoom;
1637                 ClientData_Touch(this);
1638         }
1639         zoomstate_set = true;
1640 }
1641
1642 void GetPressedKeys(entity this)
1643 {
1644         MUTATOR_CALLHOOK(GetPressedKeys, this);
1645         int keys = STAT(PRESSED_KEYS, this);
1646         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1647         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1648         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1649         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1650
1651         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1652         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1653         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1654         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1655         CS(this).pressedkeys = keys; // store for other users
1656
1657         STAT(PRESSED_KEYS, this) = keys;
1658 }
1659
1660 /*
1661 ======================
1662 spectate mode routines
1663 ======================
1664 */
1665
1666 void SpectateCopy(entity this, entity spectatee)
1667 {
1668         TC(Client, this); TC(Client, spectatee);
1669
1670         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1671         PS(this) = PS(spectatee);
1672         this.armortype = spectatee.armortype;
1673         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1674         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1675         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1676         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1677         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1678         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1679         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1680         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1681         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1682         CS(this).impulse = 0;
1683         this.disableclientprediction = 1; // no need to run prediction on a spectator
1684         this.items = spectatee.items;
1685         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1686         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1687         this.strength_finished = spectatee.strength_finished;
1688         this.invincible_finished = spectatee.invincible_finished;
1689         this.superweapons_finished = spectatee.superweapons_finished;
1690         this.air_finished = spectatee.air_finished;
1691         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1692         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1693         this.punchangle = spectatee.punchangle;
1694         this.view_ofs = spectatee.view_ofs;
1695         this.velocity = spectatee.velocity;
1696         this.dmg_take = spectatee.dmg_take;
1697         this.dmg_save = spectatee.dmg_save;
1698         this.dmg_inflictor = spectatee.dmg_inflictor;
1699         this.v_angle = spectatee.v_angle;
1700         this.angles = spectatee.v_angle;
1701         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1702         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1703         this.viewloc = spectatee.viewloc;
1704         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1705                 this.fixangle = true;
1706         setorigin(this, spectatee.origin);
1707         setsize(this, spectatee.mins, spectatee.maxs);
1708         SetZoomState(this, CS(spectatee).zoomstate);
1709
1710     anticheat_spectatecopy(this, spectatee);
1711         STAT(HUD, this) = STAT(HUD, spectatee);
1712         if(spectatee.vehicle)
1713     {
1714         this.angles = spectatee.v_angle;
1715
1716         //this.fixangle = false;
1717         //this.velocity = spectatee.vehicle.velocity;
1718         this.vehicle_health = spectatee.vehicle_health;
1719         this.vehicle_shield = spectatee.vehicle_shield;
1720         this.vehicle_energy = spectatee.vehicle_energy;
1721         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1722         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1723         this.vehicle_reload1 = spectatee.vehicle_reload1;
1724         this.vehicle_reload2 = spectatee.vehicle_reload2;
1725
1726         //msg_entity = this;
1727
1728        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1729             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1730            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1731            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1732
1733         //WriteByte (MSG_ONE, SVC_SETVIEW);
1734         //    WriteEntity(MSG_ONE, this);
1735         //makevectors(spectatee.v_angle);
1736         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1737     }
1738 }
1739
1740 bool SpectateUpdate(entity this)
1741 {
1742         if(!this.enemy)
1743                 return false;
1744
1745         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1746         {
1747                 SetSpectatee(this, NULL);
1748                 return false;
1749         }
1750
1751         SpectateCopy(this, this.enemy);
1752
1753         return true;
1754 }
1755
1756 bool SpectateSet(entity this)
1757 {
1758         if(!IS_PLAYER(this.enemy))
1759                 return false;
1760
1761         ClientData_Touch(this.enemy);
1762
1763         msg_entity = this;
1764         WriteByte(MSG_ONE, SVC_SETVIEW);
1765         WriteEntity(MSG_ONE, this.enemy);
1766         set_movetype(this, MOVETYPE_NONE);
1767         accuracy_resend(this);
1768
1769         if(!SpectateUpdate(this))
1770                 PutObserverInServer(this);
1771
1772         return true;
1773 }
1774
1775 void SetSpectatee_status(entity this, int spectatee_num)
1776 {
1777         int oldspectatee_status = CS(this).spectatee_status;
1778         CS(this).spectatee_status = spectatee_num;
1779
1780         if (CS(this).spectatee_status != oldspectatee_status)
1781         {
1782                 if (STAT(PRESSED_KEYS, this))
1783                 {
1784                         CS(this).pressedkeys = 0;
1785                         STAT(PRESSED_KEYS, this) = 0;
1786                 }
1787                 ClientData_Touch(this);
1788                 if (g_race || g_cts) race_InitSpectator();
1789         }
1790 }
1791
1792 void SetSpectatee(entity this, entity spectatee)
1793 {
1794         if(IS_BOT_CLIENT(this))
1795                 return; // bots abuse .enemy, this code is useless to them
1796
1797         entity old_spectatee = this.enemy;
1798
1799         this.enemy = spectatee;
1800
1801         // WEAPONTODO
1802         // these are required to fix the spectator bug with arc
1803         if(old_spectatee)
1804         {
1805                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1806                 {
1807                         .entity weaponentity = weaponentities[slot];
1808                         if(old_spectatee.(weaponentity).arc_beam)
1809                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1810                 }
1811         }
1812         if(this.enemy)
1813         {
1814                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1815                 {
1816                         .entity weaponentity = weaponentities[slot];
1817                         if(this.enemy.(weaponentity).arc_beam)
1818                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1819                 }
1820         }
1821
1822         if (this.enemy)
1823                 SetSpectatee_status(this, etof(this.enemy));
1824
1825         // needed to update spectator list
1826         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1827 }
1828
1829 bool Spectate(entity this, entity pl)
1830 {
1831         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1832                 return false;
1833         pl = M_ARGV(1, entity);
1834
1835         SetSpectatee(this, pl);
1836         return SpectateSet(this);
1837 }
1838
1839 bool SpectateNext(entity this)
1840 {
1841         entity ent = find(this.enemy, classname, STR_PLAYER);
1842
1843         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1844                 ent = M_ARGV(1, entity);
1845         else if (!ent)
1846                 ent = find(ent, classname, STR_PLAYER);
1847
1848         if(ent) { SetSpectatee(this, ent); }
1849
1850         return SpectateSet(this);
1851 }
1852
1853 bool SpectatePrev(entity this)
1854 {
1855         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1856         entity ent = findchain(classname, STR_PLAYER);
1857         if (!ent) // no player
1858                 return false;
1859
1860         entity first = ent;
1861         // skip players until current spectated player
1862         if(this.enemy)
1863         while(ent && ent != this.enemy)
1864                 ent = ent.chain;
1865
1866         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1867         {
1868                 case MUT_SPECPREV_FOUND:
1869                     ent = M_ARGV(1, entity);
1870                     break;
1871                 case MUT_SPECPREV_RETURN:
1872                     return true;
1873                 case MUT_SPECPREV_CONTINUE:
1874                 default:
1875                 {
1876                         if(ent.chain)
1877                                 ent = ent.chain;
1878                         else
1879                                 ent = first;
1880                         break;
1881                 }
1882         }
1883
1884         SetSpectatee(this, ent);
1885         return SpectateSet(this);
1886 }
1887
1888 /*
1889 =============
1890 ShowRespawnCountdown()
1891
1892 Update a respawn countdown display.
1893 =============
1894 */
1895 void ShowRespawnCountdown(entity this)
1896 {
1897         float number;
1898         if(!IS_DEAD(this)) // just respawned?
1899                 return;
1900         else
1901         {
1902                 number = ceil(this.respawn_time - time);
1903                 if(number <= 0)
1904                         return;
1905                 if(number <= this.respawn_countdown)
1906                 {
1907                         this.respawn_countdown = number - 1;
1908                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1909                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1910                 }
1911         }
1912 }
1913
1914 .bool team_selected;
1915 bool ShowTeamSelection(entity this)
1916 {
1917         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1918                 return false;
1919         stuffcmd(this, "menu_showteamselect\n");
1920         return true;
1921 }
1922 void Join(entity this)
1923 {
1924         TRANSMUTE(Player, this);
1925
1926         if(!this.team_selected)
1927         if(autocvar_g_campaign || autocvar_g_balance_teams)
1928                 TeamBalance_JoinBestTeam(this);
1929
1930         if(autocvar_g_campaign)
1931                 campaign_bots_may_start = true;
1932
1933         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1934
1935         PutClientInServer(this);
1936
1937         if(IS_PLAYER(this))
1938         if(teamplay && this.team != -1)
1939         {
1940         }
1941         else
1942                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1943         this.team_selected = false;
1944 }
1945
1946 int GetPlayerLimit()
1947 {
1948         int player_limit = autocvar_g_maxplayers;
1949         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1950         player_limit = M_ARGV(0, int);
1951         return player_limit;
1952 }
1953
1954 /**
1955  * Determines whether the player is allowed to join. This depends on cvar
1956  * g_maxplayers, if it isn't used this function always return true, otherwise
1957  * it checks whether the number of currently playing players exceeds g_maxplayers.
1958  * @return int number of free slots for players, 0 if none
1959  */
1960 int nJoinAllowed(entity this, entity ignore)
1961 {
1962         if(!ignore)
1963         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1964         // so report 0 free slots if restricted
1965         {
1966                 if(autocvar_g_forced_team_otherwise == "spectate")
1967                         return 0;
1968                 if(autocvar_g_forced_team_otherwise == "spectator")
1969                         return 0;
1970         }
1971
1972         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1973                 return 0; // forced spectators can never join
1974
1975         // TODO simplify this
1976         int totalClients = 0;
1977         int currentlyPlaying = 0;
1978         FOREACH_CLIENT(true, {
1979                 if(it != ignore)
1980                         ++totalClients;
1981                 if(IS_REAL_CLIENT(it))
1982                 if(IS_PLAYER(it) || it.caplayer)
1983                         ++currentlyPlaying;
1984         });
1985
1986         int player_limit = GetPlayerLimit();
1987
1988         float free_slots = 0;
1989         if (!player_limit)
1990                 free_slots = maxclients - totalClients;
1991         else if(currentlyPlaying < player_limit)
1992                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1993
1994         static float join_prevent_msg_time = 0;
1995         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1996         {
1997                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1998                 join_prevent_msg_time = time + 3;
1999         }
2000
2001         return free_slots;
2002 }
2003
2004 /**
2005  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2006  * g_maxplayers_spectator_blocktime seconds
2007  */
2008 void checkSpectatorBlock(entity this)
2009 {
2010         if(IS_SPEC(this) || IS_OBSERVER(this))
2011         if(!this.caplayer)
2012         if(IS_REAL_CLIENT(this))
2013         {
2014                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2015                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2016                         dropclient(this);
2017                 }
2018         }
2019 }
2020
2021 void PrintWelcomeMessage(entity this)
2022 {
2023         if(CS(this).motd_actived_time == 0)
2024         {
2025                 if (autocvar_g_campaign) {
2026                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2027                                 CS(this).motd_actived_time = time;
2028                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2029                         }
2030                 } else {
2031                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2032                                 CS(this).motd_actived_time = time;
2033                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2034                         }
2035                 }
2036         }
2037         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2038         {
2039                 if (autocvar_g_campaign) {
2040                         if (PHYS_INPUT_BUTTON_INFO(this))
2041                                 CS(this).motd_actived_time = time;
2042                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2043                                 CS(this).motd_actived_time = 0;
2044                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2045                         }
2046                 } else {
2047                         if (PHYS_INPUT_BUTTON_INFO(this))
2048                                 CS(this).motd_actived_time = time;
2049                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2050                                 CS(this).motd_actived_time = 0;
2051                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2052                         }
2053                 }
2054         }
2055         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2056         {
2057                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2058                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2059                 else if (CS(this).motd_actived_time == -2)
2060                 {
2061                         // instantly hide MOTD
2062                         CS(this).motd_actived_time = 0;
2063                         if (autocvar_g_campaign)
2064                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2065                         else
2066                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2067                 }
2068                 else if (IS_PLAYER(this) || IS_SPEC(this))
2069                 {
2070                         // FIXME occasionally for some reason MOTD never goes away
2071                         // delay MOTD removal a little bit in the hope it fixes this bug
2072                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2073                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2074                         else //if (CS(this).motd_actived_time < -2)
2075                                 CS(this).motd_actived_time++;
2076                 }
2077         }
2078 }
2079
2080 const int MIN_SPEC_TIME = 1;
2081 bool joinAllowed(entity this)
2082 {
2083         if (CS(this).version_mismatch) return false;
2084         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2085         if (!nJoinAllowed(this, this)) return false;
2086         if (teamplay && lockteams) return false;
2087         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2088         if (ShowTeamSelection(this)) return false;
2089         return true;
2090 }
2091
2092 .int items_added;
2093 .string shootfromfixedorigin;
2094 .bool dualwielding_prev;
2095 bool PlayerThink(entity this)
2096 {
2097         if (game_stopped || intermission_running) {
2098                 this.modelflags &= ~MF_ROCKET;
2099                 if(intermission_running)
2100                         IntermissionThink(this);
2101                 return false;
2102         }
2103
2104         if (timeout_status == TIMEOUT_ACTIVE) {
2105         // don't allow the player to turn around while game is paused
2106                 // FIXME turn this into CSQC stuff
2107                 this.v_angle = this.lastV_angle;
2108                 this.angles = this.lastV_angle;
2109                 this.fixangle = true;
2110         }
2111
2112         if (frametime) player_powerups(this);
2113
2114         if (IS_DEAD(this)) {
2115                 if (this.personal && g_race_qualifying) {
2116                         if (time > this.respawn_time) {
2117                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2118                                 respawn(this);
2119                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2120                         }
2121                 } else {
2122                         if (frametime) player_anim(this);
2123
2124                         if (this.respawn_flags & RESPAWN_DENY)
2125                         {
2126                                 STAT(RESPAWN_TIME, this) = 0;
2127                                 return false;
2128                         }
2129
2130                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2131
2132                         switch(this.deadflag)
2133                         {
2134                                 case DEAD_DYING:
2135                                 {
2136                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2137                                                 this.deadflag = DEAD_RESPAWNING;
2138                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2139                                                 this.deadflag = DEAD_DEAD;
2140                                         break;
2141                                 }
2142                                 case DEAD_DEAD:
2143                                 {
2144                                         if (button_pressed)
2145                                                 this.deadflag = DEAD_RESPAWNABLE;
2146                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2147                                                 this.deadflag = DEAD_RESPAWNING;
2148                                         break;
2149                                 }
2150                                 case DEAD_RESPAWNABLE:
2151                                 {
2152                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2153                                                 this.deadflag = DEAD_RESPAWNING;
2154                                         break;
2155                                 }
2156                                 case DEAD_RESPAWNING:
2157                                 {
2158                                         if (time > this.respawn_time)
2159                                         {
2160                                                 this.respawn_time = time + 1; // only retry once a second
2161                                                 this.respawn_time_max = this.respawn_time;
2162                                                 respawn(this);
2163                                         }
2164                                         break;
2165                                 }
2166                         }
2167
2168                         ShowRespawnCountdown(this);
2169
2170                         if (this.respawn_flags & RESPAWN_SILENT)
2171                                 STAT(RESPAWN_TIME, this) = 0;
2172                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2173                         {
2174                                 if (time < this.respawn_time)
2175                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2176                                 else if (this.deadflag != DEAD_RESPAWNING)
2177                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2178                         }
2179                         else
2180                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2181                 }
2182
2183                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2184                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2185                         STAT(RESPAWN_TIME, this) *= -1;
2186
2187                 return false;
2188         }
2189
2190         FixPlayermodel(this);
2191
2192         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2193                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2194                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2195         }
2196
2197         // reset gun alignment when dual wielding status changes
2198         // to ensure guns are always aligned right and left
2199         bool dualwielding = W_DualWielding(this);
2200         if(this.dualwielding_prev != dualwielding)
2201         {
2202                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2203                 this.dualwielding_prev = dualwielding;
2204         }
2205
2206         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2207         //if(frametime)
2208         {
2209                 this.items &= ~this.items_added;
2210
2211                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2212                 {
2213                         .entity weaponentity = weaponentities[slot];
2214                         if(WEP_CVAR(vortex, charge_always))
2215                                 W_Vortex_Charge(this, weaponentity, frametime);
2216                         W_WeaponFrame(this, weaponentity);
2217                 }
2218
2219                 this.items_added = 0;
2220                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2221             this.items_added |= IT_FUEL;
2222
2223                 this.items |= this.items_added;
2224         }
2225
2226         if (frametime)
2227         {
2228                 // WEAPONTODO: Add a weapon request for this
2229                 // rot vortex charge to the charge limit
2230                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2231                 {
2232                         .entity weaponentity = weaponentities[slot];
2233                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2234                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2235                 }
2236
2237                 player_regen(this);
2238                 player_anim(this);
2239                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2240         }
2241
2242         secrets_setstatus(this);
2243         monsters_setstatus(this);
2244
2245         return true;
2246 }
2247
2248 .bool would_spectate;
2249 void ObserverThink(entity this)
2250 {
2251         if ( CS(this).impulse )
2252         {
2253                 MinigameImpulse(this, CS(this).impulse);
2254                 CS(this).impulse = 0;
2255         }
2256
2257         if (this.flags & FL_JUMPRELEASED) {
2258                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2259                         this.flags &= ~FL_JUMPRELEASED;
2260                         this.flags |= FL_SPAWNING;
2261                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2262                         this.flags &= ~FL_JUMPRELEASED;
2263                         if(SpectateNext(this)) {
2264                                 TRANSMUTE(Spectator, this);
2265                         }
2266                 } else {
2267                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2268                         set_movetype(this, preferred_movetype);
2269                 }
2270         } else {
2271                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2272                         this.flags |= FL_JUMPRELEASED;
2273                         if(this.flags & FL_SPAWNING)
2274                         {
2275                                 this.flags &= ~FL_SPAWNING;
2276                                 if(joinAllowed(this))
2277                                         Join(this);
2278                                 return;
2279                         }
2280                 }
2281         }
2282 }
2283
2284 void SpectatorThink(entity this)
2285 {
2286         if ( CS(this).impulse )
2287         {
2288                 if(MinigameImpulse(this, CS(this).impulse))
2289                         CS(this).impulse = 0;
2290
2291                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2292                 {
2293                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2294                         CS(this).impulse = 0;
2295                         return;
2296                 }
2297         }
2298
2299         if (this.flags & FL_JUMPRELEASED) {
2300                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2301                         this.flags &= ~FL_JUMPRELEASED;
2302                         this.flags |= FL_SPAWNING;
2303                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2304                         this.flags &= ~FL_JUMPRELEASED;
2305                         if(SpectateNext(this)) {
2306                                 TRANSMUTE(Spectator, this);
2307                         } else {
2308                                 TRANSMUTE(Observer, this);
2309                                 PutClientInServer(this);
2310                         }
2311                         CS(this).impulse = 0;
2312                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2313                         this.flags &= ~FL_JUMPRELEASED;
2314                         if(SpectatePrev(this)) {
2315                                 TRANSMUTE(Spectator, this);
2316                         } else {
2317                                 TRANSMUTE(Observer, this);
2318                                 PutClientInServer(this);
2319                         }
2320                         CS(this).impulse = 0;
2321                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2322                         this.would_spectate = false;
2323                         this.flags &= ~FL_JUMPRELEASED;
2324                         TRANSMUTE(Observer, this);
2325                         PutClientInServer(this);
2326                 } else {
2327                         if(!SpectateUpdate(this))
2328                         {
2329                                 if(!SpectateNext(this))
2330                                 {
2331                                         PutObserverInServer(this);
2332                                         this.would_spectate = true;
2333                                 }
2334                         }
2335                 }
2336         } else {
2337                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2338                         this.flags |= FL_JUMPRELEASED;
2339                         if(this.flags & FL_SPAWNING)
2340                         {
2341                                 this.flags &= ~FL_SPAWNING;
2342                                 Join(this);
2343                                 return;
2344                         }
2345                 }
2346                 if(!SpectateUpdate(this))
2347                         PutObserverInServer(this);
2348         }
2349
2350         this.flags |= FL_CLIENT | FL_NOTARGET;
2351 }
2352
2353 void PlayerUseKey(entity this)
2354 {
2355         if (!IS_PLAYER(this))
2356                 return;
2357
2358         if(this.vehicle)
2359         {
2360                 if(!game_stopped)
2361                 {
2362                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2363                         return;
2364                 }
2365         }
2366         else if(autocvar_g_vehicles_enter)
2367         {
2368                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2369                 {
2370                         entity head, closest_target = NULL;
2371                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2372
2373                         while(head) // find the closest acceptable target to enter
2374                         {
2375                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2376                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2377                                 {
2378                                         if(closest_target)
2379                                         {
2380                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2381                                                 { closest_target = head; }
2382                                         }
2383                                         else { closest_target = head; }
2384                                 }
2385
2386                                 head = head.chain;
2387                         }
2388
2389                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2390                 }
2391         }
2392
2393         // a use key was pressed; call handlers
2394         MUTATOR_CALLHOOK(PlayerUseKey, this);
2395 }
2396
2397
2398 /*
2399 =============
2400 PlayerPreThink
2401
2402 Called every frame for each client before the physics are run
2403 =============
2404 */
2405 .float last_vehiclecheck;
2406 void PlayerPreThink (entity this)
2407 {
2408         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2409         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2410
2411         WarpZone_PlayerPhysics_FixVAngle(this);
2412
2413         if (frametime) {
2414                 // physics frames: update anticheat stuff
2415                 anticheat_prethink(this);
2416         }
2417
2418         if (blockSpectators && frametime) {
2419                 // WORKAROUND: only use dropclient in server frames (frametime set).
2420                 // Never use it in cl_movement frames (frametime zero).
2421                 checkSpectatorBlock(this);
2422         }
2423
2424         zoomstate_set = false;
2425
2426         // Check for nameless players
2427         if (this.netname == "" || this.netname != CS(this).netname_previous)
2428         {
2429                 bool assume_unchanged = (CS(this).netname_previous == "");
2430                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2431                 {
2432                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2433                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2434                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2435                         assume_unchanged = false;
2436                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2437                 }
2438                 if (isInvisibleString(this.netname))
2439                 {
2440                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2441                         sprint(this, "Warning: invisible names are not allowed.\n");
2442                         assume_unchanged = false;
2443                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2444                 }
2445                 if (!assume_unchanged && autocvar_sv_eventlog)
2446                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2447                 strcpy(CS(this).netname_previous, this.netname);
2448         }
2449
2450         // version nagging
2451         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2452         CS(this).version_nagtime = 0;
2453         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2454             // git client
2455         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2456             // git server
2457             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2458         } else {
2459             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2460             if (r < 0) { // old client
2461                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2462             } else if (r > 0) { // old server
2463                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2464             }
2465         }
2466     }
2467
2468         // GOD MODE info
2469         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2470         {
2471                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2472                 this.max_armorvalue = 0;
2473         }
2474
2475         if (frametime && IS_PLAYER(this))
2476         {
2477                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2478                 {
2479                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2480                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2481                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2482
2483                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2484                                 Unfreeze(this, false);
2485                 }
2486                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2487                 {
2488                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2489                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2490
2491                         if (GetResource(this, RES_HEALTH) < 1)
2492                         {
2493                                 if (this.vehicle)
2494                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2495                                 if(this.event_damage)
2496                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2497                         }
2498                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2499                                 Unfreeze(this, false);
2500                 }
2501         }
2502
2503         MUTATOR_CALLHOOK(PlayerPreThink, this);
2504
2505         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2506         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2507         {
2508                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2509                 {
2510                         if(!it.owner)
2511                         {
2512                                 if(!it.team || SAME_TEAM(this, it))
2513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2514                                 else if(autocvar_g_vehicles_steal)
2515                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2516                         }
2517                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2518                         {
2519                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2520                         }
2521                 });
2522
2523                 this.last_vehiclecheck = time + 1;
2524         }
2525
2526         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2527         {
2528                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2529                         PlayerUseKey(this);
2530                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2531         }
2532
2533         if (IS_REAL_CLIENT(this))
2534                 PrintWelcomeMessage(this);
2535
2536         if (IS_PLAYER(this)) {
2537                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2538                         error("Client can't be spawned as player on connection!");
2539                 if(!PlayerThink(this))
2540                         return;
2541         }
2542         else if (game_stopped || intermission_running) {
2543                 if(intermission_running)
2544                         IntermissionThink(this);
2545                 return;
2546         }
2547         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2548         {
2549                 CS(this).autojoin_checked = true;
2550                 // don't do this in ClientConnect
2551                 // many things can go wrong if a client is spawned as player on connection
2552                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2553                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2554                                 && (!teamplay || autocvar_g_balance_teams)))
2555                 {
2556                         campaign_bots_may_start = true;
2557                         Join(this);
2558                         return;
2559                 }
2560         }
2561         else if (IS_OBSERVER(this)) {
2562                 ObserverThink(this);
2563         }
2564         else if (IS_SPEC(this)) {
2565                 SpectatorThink(this);
2566         }
2567
2568         // WEAPONTODO: Add weapon request for this
2569         if (!zoomstate_set) {
2570                 bool wep_zoomed = false;
2571                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2572                 {
2573                         .entity weaponentity = weaponentities[slot];
2574                         Weapon thiswep = this.(weaponentity).m_weapon;
2575                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2576                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2577                 }
2578                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2579     }
2580
2581         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2582         {
2583                 CS(this).teamkill_soundtime = 0;
2584
2585                 entity e = CS(this).teamkill_soundsource;
2586                 entity oldpusher = e.pusher;
2587                 e.pusher = this;
2588                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2589                 e.pusher = oldpusher;
2590         }
2591
2592         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2593                 CS(this).taunt_soundtime = 0;
2594                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2595         }
2596
2597         target_voicescript_next(this);
2598
2599         // WEAPONTODO: Move into weaponsystem somehow
2600         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2601         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2602         {
2603                 .entity weaponentity = weaponentities[slot];
2604                 if(this.(weaponentity).m_weapon == WEP_Null)
2605                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2606         }
2607 }
2608
2609 void DrownPlayer(entity this)
2610 {
2611         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2612                 return;
2613
2614         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2615         {
2616                 if(this.air_finished && this.air_finished < time)
2617                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2618                 this.air_finished = 0;
2619         }
2620         else
2621         {
2622                 if (!this.air_finished)
2623                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2624                 if (this.air_finished < time)
2625                 {       // drown!
2626                         if (this.pain_finished < time)
2627                         {
2628                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2629                                 this.pain_finished = time + 0.5;
2630                         }
2631                 }
2632         }
2633 }
2634
2635 .bool move_qcphysics;
2636
2637 void Player_Physics(entity this)
2638 {
2639         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2640
2641         if(!this.move_qcphysics)
2642                 return;
2643
2644         if(!frametime && !CS(this).pm_frametime)
2645                 return;
2646
2647         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2648
2649         CS(this).pm_frametime = 0;
2650 }
2651
2652 /*
2653 =============
2654 PlayerPostThink
2655
2656 Called every frame for each client after the physics are run
2657 =============
2658 */
2659 void PlayerPostThink (entity this)
2660 {
2661         Player_Physics(this);
2662
2663         if (sv_maxidle > 0)
2664         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2665         if (IS_REAL_CLIENT(this))
2666         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2667         {
2668                 int totalClients = 0;
2669                 if(sv_maxidle_slots > 0)
2670                 {
2671                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2672                         {
2673                                 ++totalClients;
2674                         });
2675                 }
2676
2677                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2678                 { /* do nothing */ }
2679                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2680                 {
2681                         if (CS(this).idlekick_lasttimeleft)
2682                         {
2683                                 CS(this).idlekick_lasttimeleft = 0;
2684                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2685                         }
2686                 }
2687                 else
2688                 {
2689                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2690                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2691                                 if (!CS(this).idlekick_lasttimeleft)
2692                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2693                         }
2694                         if (timeleft <= 0) {
2695                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2696                                 dropclient(this);
2697                                 return;
2698                         }
2699                         else if (timeleft <= 10) {
2700                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2701                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2702                 }
2703                                 CS(this).idlekick_lasttimeleft = timeleft;
2704                         }
2705                 }
2706         }
2707
2708         CheatFrame(this);
2709
2710         if (game_stopped)
2711         {
2712                 this.solid = SOLID_NOT;
2713                 this.takedamage = DAMAGE_NO;
2714                 set_movetype(this, MOVETYPE_NONE);
2715         }
2716
2717         if (IS_PLAYER(this)) {
2718                 if(this.death_time == time && IS_DEAD(this))
2719                 {
2720                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2721                         // once all the damage events of this frame have been processed with normal size
2722                         this.maxs.z = 5;
2723                         setsize(this, this.mins, this.maxs);
2724                 }
2725                 DrownPlayer(this);
2726                 UpdateChatBubble(this);
2727                 if (CS(this).impulse) ImpulseCommands(this);
2728                 if (game_stopped)
2729                 {
2730                         CSQCMODEL_AUTOUPDATE(this);
2731                         return;
2732                 }
2733                 GetPressedKeys(this);
2734         }
2735         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2736         {
2737                 CS(this).pressedkeys = 0;
2738                 STAT(PRESSED_KEYS, this) = 0;
2739         }
2740
2741         if (this.waypointsprite_attachedforcarrier) {
2742                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2743                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2744         }
2745
2746         CSQCMODEL_AUTOUPDATE(this);
2747 }
2748
2749 /**
2750  * message "": do not say, just test flood control
2751  * return value:
2752  *   1 = accept
2753  *   0 = reject
2754  *  -1 = fake accept
2755  */
2756 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2757 {
2758         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2759                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2760
2761         if (source)
2762                 msgin = formatmessage(source, msgin);
2763
2764         string colorstr;
2765         if (!(IS_PLAYER(source) || source.caplayer))
2766                 colorstr = "^0"; // black for spectators
2767         else if(teamplay)
2768                 colorstr = Team_ColorCode(source.team);
2769         else
2770         {
2771                 colorstr = "";
2772                 teamsay = false;
2773         }
2774
2775         if (!source) {
2776                 colorstr = "";
2777                 teamsay = false;
2778         }
2779
2780         if(msgin != "")
2781                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2782
2783         /*
2784          * using bprint solves this... me stupid
2785         // how can we prevent the message from appearing in a listen server?
2786         // for now, just give "say" back and only handle say_team
2787         if(!teamsay)
2788         {
2789                 clientcommand(source, strcat("say ", msgin));
2790                 return;
2791         }
2792         */
2793
2794         string namestr = "";
2795         if (source)
2796                 namestr = playername(source, autocvar_g_chat_teamcolors);
2797
2798         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2799
2800         string msgstr = "", cmsgstr = "";
2801         string privatemsgprefix = string_null;
2802         int privatemsgprefixlen = 0;
2803         if (msgin != "")
2804         {
2805                 bool found_me = false;
2806                 if(strstrofs(msgin, "/me", 0) >= 0)
2807                 {
2808                         string newmsgin = "";
2809                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2810                         FOREACH_WORD(msgin, true,
2811                         {
2812                                 if(strdecolorize(it) == "/me")
2813                                 {
2814                                         found_me = true;
2815                                         newmsgin = cons(newmsgin, newnamestr);
2816                                 }
2817                                 else
2818                                         newmsgin = cons(newmsgin, it);
2819                         });
2820                         msgin = newmsgin;
2821                 }
2822
2823                 if(privatesay)
2824                 {
2825                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2826                         privatemsgprefixlen = strlen(msgstr);
2827                         msgstr = strcat(msgstr, msgin);
2828                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2829                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2830                 }
2831                 else if(teamsay)
2832                 {
2833                         if(found_me)
2834                         {
2835                                 //msgin = strreplace("/me", "", msgin);
2836                                 //msgin = substring(msgin, 3, strlen(msgin));
2837                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2838                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2839                         }
2840                         else
2841                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2842                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2843                 }
2844                 else
2845                 {
2846                         if(found_me)
2847                         {
2848                                 //msgin = strreplace("/me", "", msgin);
2849                                 //msgin = substring(msgin, 3, strlen(msgin));
2850                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2851                                 msgstr = strcat("\{1}^4* ^7", msgin);
2852                         }
2853                         else {
2854                                 msgstr = "\{1}";
2855                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2856                                 msgstr = strcat(msgstr, msgin);
2857                         }
2858                         cmsgstr = "";
2859                 }
2860                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2861         }
2862
2863         string fullmsgstr = msgstr;
2864         string fullcmsgstr = cmsgstr;
2865
2866         // FLOOD CONTROL
2867         int flood = 0;
2868         var .float flood_field = floodcontrol_chat;
2869         if(floodcontrol && source)
2870         {
2871                 float flood_spl;
2872                 float flood_burst;
2873                 float flood_lmax;
2874                 float lines;
2875                 if(privatesay)
2876                 {
2877                         flood_spl = autocvar_g_chat_flood_spl_tell;
2878                         flood_burst = autocvar_g_chat_flood_burst_tell;
2879                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2880                         flood_field = floodcontrol_chattell;
2881                 }
2882                 else if(teamsay)
2883                 {
2884                         flood_spl = autocvar_g_chat_flood_spl_team;
2885                         flood_burst = autocvar_g_chat_flood_burst_team;
2886                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2887                         flood_field = floodcontrol_chatteam;
2888                 }
2889                 else
2890                 {
2891                         flood_spl = autocvar_g_chat_flood_spl;
2892                         flood_burst = autocvar_g_chat_flood_burst;
2893                         flood_lmax = autocvar_g_chat_flood_lmax;
2894                         flood_field = floodcontrol_chat;
2895                 }
2896                 flood_burst = max(0, flood_burst - 1);
2897                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2898
2899                 // do flood control for the default line size
2900                 if(msgstr != "")
2901                 {
2902                         getWrappedLine_remaining = msgstr;
2903                         msgstr = "";
2904                         lines = 0;
2905                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2906                         {
2907                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2908                                 ++lines;
2909                         }
2910                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2911
2912                         if(getWrappedLine_remaining != "")
2913                         {
2914                                 msgstr = strcat(msgstr, "\n");
2915                                 flood = 2;
2916                         }
2917
2918                         if (time >= source.(flood_field))
2919                         {
2920                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2921                         }
2922                         else
2923                         {
2924                                 flood = 1;
2925                                 msgstr = fullmsgstr;
2926                         }
2927                 }
2928                 else
2929                 {
2930                         if (time >= source.(flood_field))
2931                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2932                         else
2933                                 flood = 1;
2934                 }
2935
2936                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2937                         source.(flood_field) = flood = 0;
2938         }
2939
2940         string sourcemsgstr, sourcecmsgstr;
2941         if(flood == 2) // cannot happen for empty msgstr
2942         {
2943                 if(autocvar_g_chat_flood_notify_flooder)
2944                 {
2945                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2946                         sourcecmsgstr = "";
2947                 }
2948                 else
2949                 {
2950                         sourcemsgstr = fullmsgstr;
2951                         sourcecmsgstr = fullcmsgstr;
2952                 }
2953                 cmsgstr = "";
2954         }
2955         else
2956         {
2957                 sourcemsgstr = msgstr;
2958                 sourcecmsgstr = cmsgstr;
2959         }
2960
2961         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2962         {
2963                 if (!game_stopped)
2964                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2965                         teamsay = -1; // spectators
2966         }
2967
2968         if(flood)
2969                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2970
2971         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2972         if(privatesay)
2973                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2974
2975         int ret;
2976         if(source && CS(source).muted)
2977         {
2978                 // always fake the message
2979                 ret = -1;
2980         }
2981         else if(flood == 1)
2982         {
2983                 if (autocvar_g_chat_flood_notify_flooder)
2984                 {
2985                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2986                         ret = 0;
2987                 }
2988                 else
2989                         ret = -1;
2990         }
2991         else
2992         {
2993                 ret = 1;
2994         }
2995
2996         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2997         {
2998                 if (!game_stopped)
2999                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3000                         ret = -1; // just hide the message completely
3001         }
3002
3003         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3004         ret = M_ARGV(1, int);
3005
3006         string event_log_msg = "";
3007
3008         if(sourcemsgstr != "" && ret != 0)
3009         {
3010                 if(ret < 0) // faked message, because the player is muted
3011                 {
3012                         sprint(source, sourcemsgstr);
3013                         if(sourcecmsgstr != "" && !privatesay)
3014                                 centerprint(source, sourcecmsgstr);
3015                 }
3016                 else if(privatesay) // private message, between 2 people only
3017                 {
3018                         sprint(source, sourcemsgstr);
3019                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3020                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3021                         {
3022                                 sprint(privatesay, msgstr);
3023                                 if(cmsgstr != "")
3024                                         centerprint(privatesay, cmsgstr);
3025                         }
3026                 }
3027                 else if ( teamsay && CS(source).active_minigame )
3028                 {
3029                         sprint(source, sourcemsgstr);
3030                         dedicated_print(msgstr); // send to server console too
3031                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3032                                 sprint(it, msgstr);
3033                         });
3034                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3035
3036                 }
3037                 else if(teamsay > 0) // team message, only sent to team mates
3038                 {
3039                         sprint(source, sourcemsgstr);
3040                         dedicated_print(msgstr); // send to server console too
3041                         if(sourcecmsgstr != "")
3042                                 centerprint(source, sourcecmsgstr);
3043                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3044                                 sprint(it, msgstr);
3045                                 if(cmsgstr != "")
3046                                         centerprint(it, cmsgstr);
3047                         });
3048                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3049                 }
3050                 else if(teamsay < 0) // spectator message, only sent to spectators
3051                 {
3052                         sprint(source, sourcemsgstr);
3053                         dedicated_print(msgstr); // send to server console too
3054                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3055                                 sprint(it, msgstr);
3056                         });
3057                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3058                 }
3059                 else
3060                 {
3061                         if (source) {
3062                                 sprint(source, sourcemsgstr);
3063                                 dedicated_print(msgstr); // send to server console too
3064                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3065                         }
3066                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3067                                 sprint(it, msgstr);
3068                         });
3069                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3070                 }
3071         }
3072
3073         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3074                 GameLogEcho(event_log_msg);
3075         }
3076
3077         return ret;
3078 }
3079
3080 // hack to copy the button fields from the client entity to the Client State
3081 void PM_UpdateButtons(entity this, entity store)
3082 {
3083         if(this.impulse)
3084                 store.impulse = this.impulse;
3085         this.impulse = 0;
3086
3087         bool typing = this.buttonchat || this.button12;
3088
3089         store.button0 = (typing) ? 0 : this.button0;
3090         //button1?!
3091         store.button2 = (typing) ? 0 : this.button2;
3092         store.button3 = (typing) ? 0 : this.button3;
3093         store.button4 = this.button4;
3094         store.button5 = (typing) ? 0 : this.button5;
3095         store.button6 = this.button6;
3096         store.button7 = this.button7;
3097         store.button8 = this.button8;
3098         store.button9 = this.button9;
3099         store.button10 = this.button10;
3100         store.button11 = this.button11;
3101         store.button12 = this.button12;
3102         store.button13 = this.button13;
3103         store.button14 = this.button14;
3104         store.button15 = this.button15;
3105         store.button16 = this.button16;
3106         store.buttonuse = this.buttonuse;
3107         store.buttonchat = this.buttonchat;
3108
3109         store.cursor_active = this.cursor_active;
3110         store.cursor_screen = this.cursor_screen;
3111         store.cursor_trace_start = this.cursor_trace_start;
3112         store.cursor_trace_endpos = this.cursor_trace_endpos;
3113         store.cursor_trace_ent = this.cursor_trace_ent;
3114
3115         store.ping = this.ping;
3116         store.ping_packetloss = this.ping_packetloss;
3117         store.ping_movementloss = this.ping_movementloss;
3118
3119         store.v_angle = this.v_angle;
3120         store.movement = (typing) ? '0 0 0' : this.movement;
3121 }
3122
3123 NET_HANDLE(fpsreport, bool)
3124 {
3125         int fps = ReadShort();
3126         PlayerScore_Set(sender, SP_FPS, fps);
3127         return true;
3128 }