qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(g_ca) { self.caplayer = 1; }
 158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 159
 160                                                 self.classname = "player";
 161                                                 PlayerScore_Clear(self);
 162                                                 bprint ("^4", self.netname, "^4 is playing now\n");
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 centerprint(self, PREVENT_JOIN_TEXT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobspawn(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         entity e;
 192                         string tospawn, mname, s;
 193                         float spawncount = 0, moveflag, max_global, max_perplayer, i;
 194
 195                         max_global = autocvar_g_monsters_max;
 196                         max_perplayer = autocvar_g_monsters_max_perplayer;
 197                         moveflag = (argv(3) ? stof(argv(3)) : 1); // follow owner if not defined
 198                         spawncount = ((argv(2)) ? stof(argv(2)) : 1);
 199                         tospawn = argv(1);
 200                         mname = argv(4);
 201                         s = ((spawncount == 1) ? "" : "s");
 202
 203                         if(tospawn == "list")
 204                         {
 205                                 sprint(self, "Available monsters:\n");
 206                                 sprint(self, strcat(monsterlist(), "\n"));
 207                                 return;
 208                         }
 209
 210                         if(self.classname != STR_PLAYER) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 211                         else if(self.deadflag) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 212                         else if(self.monstercount > max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 213                         else if(totalspawned > max_global) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 214                         else if(spawncount == 0) { sprint(self, "No monsters to spawn.\n"); return; }
 215
 216                         makevectors(self.v_angle);
 217             WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 218
 219                         for(i = 0; i < spawncount; i++)
 220                         {
 221                                 self.monstercount++;
 222                                 if(self.monstercount > max_perplayer) break; // FIXME: check for these properly
 223                                 e = spawnmonster(tospawn, self, self, trace_endpos, FALSE, moveflag);
 224                                 if(e == world) { self.monstercount -= 1; break; } // take back the 1 that was lost
 225                                 if(mname != "") e.netname = mname;
 226                                 totalspawned++;
 227                         }
 228
 229                         sprint(self, sprintf("Spawned %d %s%s\n", spawncount, tospawn, s));
 230
 231                         return;
 232                 }
 233
 234                 default:
 235                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 236                 case CMD_REQUEST_USAGE:
 237                 {
 238                         sprint(self, "\nUsage:^3 cmd mobspawn monster\n");
 239                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 240                         return;
 241                 }
 242         }
 243 }
 244
 245 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 246 {
 247         switch(request)
 248         {
 249                 case CMD_REQUEST_COMMAND:
 250                 {
 251                         if(self.flags & FL_CLIENT)
 252                         {
 253                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 254                                 {
 255                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 256                                         {
 257                                                 if (self.ready) // toggle
 258                                                 {
 259                                                         self.ready = FALSE;
 260                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 261                                                 }
 262                                                 else
 263                                                 {
 264                                                         self.ready = TRUE;
 265                                                         bprint(self.netname, "^2 is ready\n");
 266                                                 }
 267
 268                                                 // cannot reset the game while a timeout is active!
 269                                                 if not(timeout_status)
 270                                                         ReadyCount();
 271                                         } else {
 272                                                 sprint(self, "^1Game has already been restarted\n");
 273                                         }
 274                                 }
 275                         }
 276                         return; // never fall through to usage
 277                 }
 278
 279                 default:
 280                 case CMD_REQUEST_USAGE:
 281                 {
 282                         sprint(self, "\nUsage:^3 cmd ready\n");
 283                         sprint(self, "  No arguments required.\n");
 284                         return;
 285                 }
 286         }
 287 }
 288
 289 void ClientCommand_say(float request, float argc, string command)
 290 {
 291         switch(request)
 292         {
 293                 case CMD_REQUEST_COMMAND:
 294                 {
 295                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 296                         return; // never fall through to usage
 297                 }
 298
 299                 default:
 300                 case CMD_REQUEST_USAGE:
 301                 {
 302                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 303                         sprint(self, "  Where 'message' is the string of text to say.\n");
 304                         return;
 305                 }
 306         }
 307 }
 308
 309 void ClientCommand_say_team(float request, float argc, string command)
 310 {
 311         switch(request)
 312         {
 313                 case CMD_REQUEST_COMMAND:
 314                 {
 315                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 316                         return; // never fall through to usage
 317                 }
 318
 319                 default:
 320                 case CMD_REQUEST_USAGE:
 321                 {
 322                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 323                         sprint(self, "  Where 'message' is the string of text to say.\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void ClientCommand_selectteam(float request, float argc)
 330 {
 331         switch(request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         if(argv(1) != "")
 336                         {
 337                                 if(self.flags & FL_CLIENT)
 338                                 {
 339                                         if(teamplay)
 340                                                 if not(self.team_forced > 0)
 341                                                         if not(lockteams)
 342                                                         {
 343                                                                 float selection;
 344
 345                                                                 switch(argv(1))
 346                                                                 {
 347                                                                         case "red": selection = COLOR_TEAM1; break;
 348                                                                         case "blue": selection = COLOR_TEAM2; break;
 349                                                                         case "yellow": selection = COLOR_TEAM3; break;
 350                                                                         case "pink": selection = COLOR_TEAM4; break;
 351                                                                         case "auto": selection = (-1); break;
 352
 353                                                                         default: selection = 0; break;
 354                                                                 }
 355
 356                                                                 if(selection)
 357                                                                 {
 358                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 359                                                                                 sprint(self, "^7You already are on that team.\n");
 360                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 361                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 362                                                                         else
 363                                                                                 ClientKill_TeamChange(selection);
 364                                                                 }
 365                                                         }
 366                                                         else
 367                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 368                                                 else
 369                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 370                                         else
 371                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 372                                 }
 373                                 return;
 374                         }
 375                 }
 376
 377                 default:
 378                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 379                 case CMD_REQUEST_USAGE:
 380                 {
 381                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 382                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 383                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 384                         return;
 385                 }
 386         }
 387 }
 388
 389 void ClientCommand_selfstuff(float request, string command)
 390 {
 391         switch(request)
 392         {
 393                 case CMD_REQUEST_COMMAND:
 394                 {
 395                         if(argv(1) != "")
 396                         {
 397                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 398                                 return;
 399                         }
 400                 }
 401
 402                 default:
 403                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 404                 case CMD_REQUEST_USAGE:
 405                 {
 406                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 407                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 408                         return;
 409                 }
 410         }
 411 }
 412
 413 void ClientCommand_sentcvar(float request, float argc, string command)
 414 {
 415         switch(request)
 416         {
 417                 case CMD_REQUEST_COMMAND:
 418                 {
 419                         if(argv(1) != "")
 420                         {
 421                                 //float tokens;
 422                                 string s;
 423
 424                                 if(argc == 2) // undefined cvar: use the default value on the server then
 425                                 {
 426                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 427                                         tokenize_console(s);
 428                                 }
 429
 430                                 GetCvars(1);
 431
 432                                 return;
 433                         }
 434                 }
 435
 436                 default:
 437                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 438                 case CMD_REQUEST_USAGE:
 439                 {
 440                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 441                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 442                         return;
 443                 }
 444         }
 445 }
 446
 447 void ClientCommand_spectate(float request)
 448 {
 449         switch(request)
 450         {
 451                 case CMD_REQUEST_COMMAND:
 452                 {
 453                         if(self.flags & FL_CLIENT)
 454                         {
 455                                 if(g_arena) { return; }
 456                                 if(g_lms)
 457                                 {
 458                                         if(self.lms_spectate_warning)
 459                                         {
 460                                                 // mark player as spectator
 461                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 462                                         }
 463                                         else
 464                                         {
 465                                                 self.lms_spectate_warning = 1;
 466                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 467                                                 return;
 468                                         }
 469                                 }
 470
 471                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 472                                         ClientKill_TeamChange(-2); // observe
 473
 474                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 475                                 // note: if arena game mode is ever done properly, this needs to be removed.
 476                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 477                                 {
 478                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 479                                         self.caplayer = 0;
 480                                 }
 481                         }
 482                         return; // never fall through to usage
 483                 }
 484
 485                 default:
 486                 case CMD_REQUEST_USAGE:
 487                 {
 488                         sprint(self, "\nUsage:^3 cmd spectate\n");
 489                         sprint(self, "  No arguments required.\n");
 490                         return;
 491                 }
 492         }
 493 }
 494
 495 void ClientCommand_suggestmap(float request, float argc)
 496 {
 497         switch(request)
 498         {
 499                 case CMD_REQUEST_COMMAND:
 500                 {
 501                         if(argv(1) != "")
 502                         {
 503                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 504                                 return;
 505                         }
 506                 }
 507
 508                 default:
 509                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 510                 case CMD_REQUEST_USAGE:
 511                 {
 512                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 513                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 514                         return;
 515                 }
 516         }
 517 }
 518
 519 void ClientCommand_tell(float request, float argc, string command)
 520 {
 521         switch(request)
 522         {
 523                 case CMD_REQUEST_COMMAND:
 524                 {
 525                         if(argc >= 3)
 526                         {
 527                                 entity tell_to = GetIndexedEntity(argc, 1);
 528                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 529
 530                                 if(tell_accepted > 0) // the target is a real client
 531                                 {
 532                                         if(tell_to != self) // and we're allowed to send to them :D
 533                                         {
 534                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 535                                                 return;
 536                                         }
 537                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 538                                 }
 539                                 else if(argv(1) == "#0")
 540                                 {
 541                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 542                                         return;
 543                                 }
 544                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 545                         }
 546                 }
 547
 548                 default:
 549                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 550                 case CMD_REQUEST_USAGE:
 551                 {
 552                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 553                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 554                         return;
 555                 }
 556         }
 557 }
 558
 559 void ClientCommand_voice(float request, float argc, string command)
 560 {
 561         switch(request)
 562         {
 563                 case CMD_REQUEST_COMMAND:
 564                 {
 565                         if(argv(1) != "")
 566                         {
 567                                 if(argc >= 3)
 568                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 569                                 else
 570                                         VoiceMessage(argv(1), "");
 571
 572                                 return;
 573                         }
 574                 }
 575
 576                 default:
 577                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 578                 case CMD_REQUEST_USAGE:
 579                 {
 580                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 581                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 582                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 583                         return;
 584                 }
 585         }
 586 }
 587
 588 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 589 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 590 void ClientCommand_(float request)
 591 {
 592         switch(request)
 593         {
 594                 case CMD_REQUEST_COMMAND:
 595                 {
 596
 597                         return; // never fall through to usage
 598                 }
 599
 600                 default:
 601                 case CMD_REQUEST_USAGE:
 602                 {
 603                         sprint(self, "\nUsage:^3 cmd \n");
 604                         sprint(self, "  No arguments required.\n");
 605                         return;
 606                 }
 607         }
 608 }
 609 */
 610
 611
 612 // =====================================
 613 //  Macro system for networked commands
 614 // =====================================
 615
 616 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 617 #define CLIENT_COMMANDS(request,arguments,command) \
 618         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 619         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 620         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 621         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 622         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 623         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 624         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 625         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 626         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 627         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 628         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 629         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 630         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 631         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 632         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 633         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 634         /* nothing */
 635
 636 void ClientCommand_macro_help()
 637 {
 638         #define CLIENT_COMMAND(name,function,description) \
 639                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 640
 641         CLIENT_COMMANDS(0, 0, "")
 642         #undef CLIENT_COMMAND
 643
 644         return;
 645 }
 646
 647 float ClientCommand_macro_command(float argc, string command)
 648 {
 649         #define CLIENT_COMMAND(name,function,description) \
 650                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 651
 652         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 653         #undef CLIENT_COMMAND
 654
 655         return FALSE;
 656 }
 657
 658 float ClientCommand_macro_usage(float argc)
 659 {
 660         #define CLIENT_COMMAND(name,function,description) \
 661                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 662
 663         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 664         #undef CLIENT_COMMAND
 665
 666         return FALSE;
 667 }
 668
 669 void ClientCommand_macro_write_aliases(float fh)
 670 {
 671         #define CLIENT_COMMAND(name,function,description) \
 672                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 673
 674         CLIENT_COMMANDS(0, 0, "")
 675         #undef CLIENT_COMMAND
 676
 677         return;
 678 }
 679
 680 // ======================================
 681 //  Main Function Called By Engine (cmd)
 682 // ======================================
 683 // If this function exists, server game code parses clientcommand before the engine code gets it.
 684
 685 void SV_ParseClientCommand(string command)
 686 {
 687         // if we're banned, don't even parse the command
 688         if(Ban_MaybeEnforceBanOnce(self))
 689                 return;
 690
 691         float argc = tokenize_console(command);
 692
 693         // for the mutator hook system
 694         cmd_name = strtolower(argv(0));
 695         cmd_argc = argc;
 696         cmd_string = command;
 697
 698         // Guide for working with argc arguments by example:
 699         // argc:   1    - 2      - 3     - 4
 700         // argv:   0    - 1      - 2     - 3
 701         // cmd     vote - master - login - password
 702
 703         // for floodcheck
 704         switch(strtolower(argv(0)))
 705         {
 706                 // exempt commands which are not subject to floodcheck
 707                 case "begin": break; // handled by engine in host_cmd.c
 708                 case "download": break; // handled by engine in cl_parse.c
 709                 case "mv_getpicture": break; // handled by server in this file
 710                 case "pause": break; // handled by engine in host_cmd.c
 711                 case "prespawn": break; // handled by engine in host_cmd.c
 712                 case "sentcvar": break; // handled by server in this file
 713                 case "spawn": break; // handled by engine in host_cmd.c
 714
 715                 default:
 716                         if(SV_ParseClientCommand_floodcheck())
 717                                 break; // "TRUE": continue, as we're not flooding yet
 718                         else
 719                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 720         }
 721
 722         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 723         if(argv(0) == "help")
 724         {
 725                 if(argc == 1)
 726                 {
 727                         sprint(self, "\nClient networked commands:\n");
 728                         ClientCommand_macro_help();
 729
 730                         sprint(self, "\nCommon networked commands:\n");
 731                         CommonCommand_macro_help(self);
 732
 733                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 734                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 735                         return;
 736                 }
 737                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 738                 {
 739                         return;
 740                 }
 741                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 742                 {
 743                         return;
 744                 }
 745         }
 746         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 747         {
 748                 return; // handled by a mutator
 749         }
 750         else if(CheatCommand(argc))
 751         {
 752                 return; // handled by server/cheats.qc
 753         }
 754         else if(CommonCommand_macro_command(argc, self, command))
 755         {
 756                 return; // handled by server/command/common.qc
 757         }
 758         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 759         {
 760                 return; // handled by one of the above ClientCommand_* functions
 761         }
 762         else
 763                 clientcommand(self, command);
 764 }