qcsrc/server/command/sv_cmd.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../../dpdefs/progsdefs.qh"
   5     #include "../../dpdefs/dpextensions.qh"
   6     #include "../../warpzonelib/mathlib.qh"
   7     #include "../../common/constants.qh"
   8     #include "../../common/teams.qh"
   9     #include "../../common/util.qh"
  10     #include "../../common/command/shared_defs.qh"
  11     #include "../../common/monsters/sv_monsters.qh"
  12     #include "../autocvars.qh"
  13     #include "../defs.qh"
  14     #include "../../common/notifications.qh"
  15     #include "../mutators/mutators_include.qh"
  16     #include "../../common/mapinfo.qh"
  17     #include "common.qh"
  18     #include "cmd.qh"
  19     #include "sv_cmd.qh"
  20     #include "../anticheat.qh"
  21     #include "../playerdemo.qh"
  22 #endif
  23
  24 // =====================================================
  25 //  Server side game commands code, reworked by Samual
  26 //  Last updated: December 29th, 2011
  27 // =====================================================
  28
  29 //  used by GameCommand_make_mapinfo()
  30 void make_mapinfo_Think()
  31 {
  32         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  33         {
  34                 print("Done rebuiling mapinfos.\n");
  35                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  36                 remove(self);
  37         }
  38         else
  39         {
  40                 self.think = make_mapinfo_Think;
  41                 self.nextthink = time;
  42         }
  43 }
  44
  45 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  46 void changematchtime(float delta, float mi, float ma)
  47 {
  48         float cur;
  49         float new;
  50         float lim;
  51
  52         if(delta == 0)
  53                 return;
  54         if(autocvar_timelimit < 0)
  55                 return;
  56
  57         if(mi <= 10)
  58                 mi = 10; // at least ten sec in the future
  59         cur = time - game_starttime;
  60         if(cur > 0)
  61                 mi += cur; // from current time!
  62
  63         lim = autocvar_timelimit * 60;
  64
  65         if(delta > 0)
  66         {
  67                 if(lim == 0)
  68                         return; // cannot increase any further
  69                 else if(lim < ma)
  70                         new = min(ma, lim + delta);
  71                 else // already above maximum: FAIL
  72                         return;
  73         }
  74         else
  75         {
  76                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  77                         new = max(mi, ma);
  78                 else if(lim > mi) // above minimum: decrease
  79                         new = max(mi, lim + delta);
  80                 else // already below minimum: FAIL
  81                         return;
  82         }
  83
  84         cvar_set("timelimit", ftos(new / 60));
  85 }
  86
  87
  88 // =======================
  89 //  Command Sub-Functions
  90 // =======================
  91
  92 void GameCommand_adminmsg(float request, float argc)
  93 {
  94         switch(request)
  95         {
  96                 case CMD_REQUEST_COMMAND:
  97                 {
  98                         entity client;
  99                         float accepted;
 100
 101                         string targets = strreplace(",", " ", argv(1));
 102                         string original_targets = strreplace(" ", ", ", targets);
 103                         string admin_message = argv(2);
 104                         float infobartime = stof(argv(3));
 105
 106                         string successful, t;
 107                         successful = string_null;
 108
 109                         if((targets) && (admin_message))
 110                         {
 111                                 for (;targets;)
 112                                 {
 113                                         t = car(targets); targets = cdr(targets);
 114
 115                                         // Check to see if the player is a valid target
 116                                         client = GetFilteredEntity(t);
 117                                         accepted = VerifyClientEntity(client, true, false);
 118
 119                                         if(accepted <= 0)
 120                                         {
 121                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 122                                                 continue;
 123                                         }
 124
 125                                         // send the centerprint/console print or infomessage
 126                                         if(infobartime)
 127                                         {
 128                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 129                                         }
 130                                         else
 131                                         {
 132                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 133                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 134                                         }
 135
 136                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 137                                         dprint("Message sent to ", client.netname, "\n");
 138                                         continue;
 139                                 }
 140
 141                                 if(successful)
 142                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 143                                 else
 144                                         print("No players given (", original_targets, ") could receive the message.\n");
 145
 146                                 return;
 147                         }
 148                 }
 149
 150                 default:
 151                         print("Incorrect parameters for ^2adminmsg^7\n");
 152                 case CMD_REQUEST_USAGE:
 153                 {
 154                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 155                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 156                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 157                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 158                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 159                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 160                         return;
 161                 }
 162         }
 163 }
 164
 165 void GameCommand_mobbutcher(float request)
 166 {
 167         switch(request)
 168         {
 169                 case CMD_REQUEST_COMMAND:
 170                 {
 171                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 172                         if(g_invasion) { print("This command doesn't work during an invasion.\n"); return; }
 173
 174                         float removed_count = 0;
 175                         entity head;
 176
 177                         FOR_EACH_MONSTER(head)
 178                         {
 179                                 monster_remove(head);
 180                                 ++removed_count;
 181                         }
 182
 183                         monsters_total = 0; // reset stats?
 184                         monsters_killed = 0;
 185
 186                         totalspawned = 0;
 187
 188                         if(removed_count <= 0)
 189                                 print("No monsters to kill\n");
 190                         else
 191                                 printf("Killed %d monster%s\n", removed_count, ((removed_count == 1) ? "" : "s"));
 192
 193                         return; // never fall through to usage
 194                 }
 195
 196                 default:
 197                 case CMD_REQUEST_USAGE:
 198                 {
 199                         print("\nUsage:^3 sv_cmd mobbutcher\n");
 200                         print("  No arguments required.\n");
 201                         return;
 202                 }
 203         }
 204 }
 205
 206 void GameCommand_allready(float request)
 207 {
 208         switch(request)
 209         {
 210                 case CMD_REQUEST_COMMAND:
 211                 {
 212                         ReadyRestart();
 213                         return;
 214                 }
 215
 216                 default:
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print("\nUsage:^3 sv_cmd allready\n");
 220                         print("  No arguments required.\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void GameCommand_allspec(float request, float argc)
 227 {
 228         switch(request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         entity client;
 233                         string reason = argv(1);
 234                         float i = 0;
 235
 236                         FOR_EACH_REALPLAYER(client)
 237                         {
 238                                 self = client;
 239                                 if(self.caplayer)
 240                                         self.caplayer = 0;
 241                                 PutObserverInServer();
 242                                 ++i;
 243                         }
 244                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 245                         else { print("No players found to spectate.\n"); }
 246                         return;
 247                 }
 248
 249                 default:
 250                 case CMD_REQUEST_USAGE:
 251                 {
 252                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 253                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 254                         print("See also: ^2moveplayer, shuffleteams^7\n");
 255                         return;
 256                 }
 257         }
 258 }
 259
 260 void GameCommand_anticheat(float request, float argc)
 261 {
 262         switch(request)
 263         {
 264                 case CMD_REQUEST_COMMAND:
 265                 {
 266                         entity client = GetIndexedEntity(argc, 1);
 267                         float accepted = VerifyClientEntity(client, false, false);
 268
 269                         if(accepted > 0)
 270                         {
 271                                 self = client;
 272                                 anticheat_report();
 273                                 return;
 274                         }
 275                         else
 276                         {
 277                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 278                         }
 279                 }
 280
 281                 default:
 282                         print("Incorrect parameters for ^2anticheat^7\n");
 283                 case CMD_REQUEST_USAGE:
 284                 {
 285                         print("\nUsage:^3 sv_cmd anticheat client\n");
 286                         print("  'client' is the entity number or name of the player.\n");
 287                         return;
 288                 }
 289         }
 290 }
 291
 292 void GameCommand_bbox(float request)
 293 {
 294         switch(request)
 295         {
 296                 case CMD_REQUEST_COMMAND:
 297                 {
 298                         print("Original size: ", ftos(world.absmin.x), " ", ftos(world.absmin.y), " ", ftos(world.absmin.z));
 299                         print(" ", ftos(world.absmax.x), " ", ftos(world.absmax.y), " ", ftos(world.absmax.z), "\n");
 300                         print("Currently set size: ", ftos(world.mins.x), " ", ftos(world.mins.y), " ", ftos(world.mins.z));
 301                         print(" ", ftos(world.maxs.x), " ", ftos(world.maxs.y), " ", ftos(world.maxs.z), "\n");
 302                         print("Solid bounding box size:");
 303
 304                         tracebox('1 0 0' * world.absmin.x,
 305                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 306                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 307                                                         '1 0 0' * world.absmax.x,
 308                                         MOVE_WORLDONLY,
 309                                         world);
 310                         if(trace_startsolid)
 311                                 print(" ", ftos(world.absmin.x));
 312                         else
 313                                 print(" ", ftos(trace_endpos.x));
 314
 315                         tracebox('0 1 0' * world.absmin.y,
 316                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 317                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 318                                                         '0 1 0' * world.absmax.y,
 319                                         MOVE_WORLDONLY,
 320                                         world);
 321                         if(trace_startsolid)
 322                                 print(" ", ftos(world.absmin.y));
 323                         else
 324                                 print(" ", ftos(trace_endpos.y));
 325
 326                         tracebox('0 0 1' * world.absmin.z,
 327                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 328                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 329                                                         '0 0 1' * world.absmax.z,
 330                                         MOVE_WORLDONLY,
 331                                         world);
 332                         if(trace_startsolid)
 333                                 print(" ", ftos(world.absmin.z));
 334                         else
 335                                 print(" ", ftos(trace_endpos.z));
 336
 337                         tracebox('1 0 0' * world.absmax.x,
 338                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 339                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 340                                                         '1 0 0' * world.absmin.x,
 341                                         MOVE_WORLDONLY,
 342                                         world);
 343                         if(trace_startsolid)
 344                                 print(" ", ftos(world.absmax.x));
 345                         else
 346                                 print(" ", ftos(trace_endpos.x));
 347
 348                         tracebox('0 1 0' * world.absmax.y,
 349                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 350                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 351                                                         '0 1 0' * world.absmin.y,
 352                                         MOVE_WORLDONLY,
 353                                         world);
 354                         if(trace_startsolid)
 355                                 print(" ", ftos(world.absmax.y));
 356                         else
 357                                 print(" ", ftos(trace_endpos.y));
 358
 359                         tracebox('0 0 1' * world.absmax.z,
 360                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 361                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 362                                                         '0 0 1' * world.absmin.z,
 363                                         MOVE_WORLDONLY,
 364                                         world);
 365                         if(trace_startsolid)
 366                                 print(" ", ftos(world.absmax.z));
 367                         else
 368                                 print(" ", ftos(trace_endpos.z));
 369
 370                         print("\n");
 371                         return;
 372                 }
 373
 374                 default:
 375                 case CMD_REQUEST_USAGE:
 376                 {
 377                         print("\nUsage:^3 sv_cmd bbox\n");
 378                         print("  No arguments required.\n");
 379                         print("See also: ^2gettaginfo, trace^7\n");
 380                         return;
 381                 }
 382         }
 383 }
 384
 385 void GameCommand_bot_cmd(float request, float argc, string command)
 386 {
 387         switch(request)
 388         {
 389                 case CMD_REQUEST_COMMAND:
 390                 {
 391                         entity bot;
 392
 393                         if(argv(1) == "reset")
 394                         {
 395                                 bot_resetqueues();
 396                                 return;
 397                         }
 398                         else if(argv(1) == "setbots")
 399                         {
 400                                 cvar_settemp("bot_vs_human", "0");
 401                                 cvar_settemp("minplayers", "0");
 402                                 cvar_settemp("bot_number", "0");
 403                                 bot_fixcount();
 404                                 cvar_settemp("bot_number", argv(2));
 405                                 if(!bot_fixcount())
 406                                         print("Sorry, could not set requested bot count\n");
 407                                 return;
 408                         }
 409                         else if(argv(1) == "load" && argc == 3)
 410                         {
 411                                 float fh, i;
 412                                 string s;
 413                                 fh = fopen(argv(2), FILE_READ);
 414                                 if(fh < 0)
 415                                 {
 416                                         print("cannot open the file\n");
 417                                         return;
 418                                 }
 419
 420                                 i = 0;
 421                                 while((s = fgets(fh)))
 422                                 {
 423                                         argc = tokenize_console(s);
 424
 425                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 426                                         {
 427                                                 if(argv(2) == "reset")
 428                                                 {
 429                                                         bot_resetqueues();
 430                                                 }
 431                                                 else if(argv(2) == "setbots")
 432                                                 {
 433                                                         cvar_settemp("bot_vs_human", "0");
 434                                                         cvar_settemp("minplayers", "0");
 435                                                         cvar_settemp("bot_number", "0");
 436                                                         bot_fixcount();
 437                                                         cvar_settemp("bot_number", argv(3));
 438                                                         if(!bot_fixcount())
 439                                                                 print("Sorry, could not set requested bot count\n");
 440                                                 }
 441                                                 else
 442                                                 {
 443                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 444                                                         bot = find_bot_by_number(stof(argv(2)));
 445                                                         if(bot == world)
 446                                                                 bot = find_bot_by_name(argv(2));
 447                                                         if(bot)
 448                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 449                                                 }
 450                                         }
 451                                         else
 452                                                 localcmd(strcat(s, "\n"));
 453
 454                                         ++i;
 455                                 }
 456                                 print(ftos(i), " commands read\n");
 457                                 fclose(fh);
 458                                 return;
 459                         }
 460                         else if(argv(1) == "help")
 461                         {
 462                                 if(argv(2))
 463                                         bot_cmdhelp(argv(2));
 464                                 else
 465                                         bot_list_commands();
 466                                 return;
 467                         }
 468                         else if(argc >= 3) // this comes last
 469                         {
 470                                 bot = find_bot_by_number(stof(argv(1)));
 471                                 if(bot == world)
 472                                         bot = find_bot_by_name(argv(1));
 473                                 if(bot)
 474                                 {
 475                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 476                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 477                                         return;
 478                                 }
 479                                 else
 480                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 481                         }
 482                 }
 483
 484                 default:
 485                         print("Incorrect parameters for ^2bot_cmd^7\n");
 486                 case CMD_REQUEST_USAGE:
 487                 {
 488                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 489                         print("  'client' can be either the name or entity id of the bot\n");
 490                         print("  For full list of commands, see bot_cmd help [command].\n");
 491                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 492                         print("          sv_cmd bot_cmd client presskey jump\n");
 493                         return;
 494                 }
 495         }
 496 }
 497
 498 void GameCommand_cointoss(float request, float argc)
 499 {
 500         switch(request)
 501         {
 502                 case CMD_REQUEST_COMMAND:
 503                 {
 504                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 505                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 506                         string choice = ((random() > 0.5) ? result1 : result2);
 507
 508                         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_COINTOSS, choice);
 509                         return;
 510                 }
 511
 512                 default:
 513                 case CMD_REQUEST_USAGE:
 514                 {
 515                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 516                         print("  Where 'result1' and 'result2' are user created options.\n");
 517                         return;
 518                 }
 519         }
 520 }
 521
 522 void GameCommand_database(float request, float argc)
 523 {
 524         switch(request)
 525         {
 526                 case CMD_REQUEST_COMMAND:
 527                 {
 528                         if(argc == 3)
 529                         {
 530                                 if(argv(1) == "save")
 531                                 {
 532                                         db_save(ServerProgsDB, argv(2));
 533                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 534                                         return;
 535                                 }
 536                                 else if(argv(1) == "dump")
 537                                 {
 538                                         db_dump(ServerProgsDB, argv(2));
 539                                         print("DB dumped.\n"); // wtf does this do?
 540                                         return;
 541                                 }
 542                                 else if(argv(1) == "load")
 543                                 {
 544                                         db_close(ServerProgsDB);
 545                                         ServerProgsDB = db_load(argv(2));
 546                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 547                                         return;
 548                                 }
 549                         }
 550                 }
 551
 552                 default:
 553                         print("Incorrect parameters for ^2database^7\n");
 554                 case CMD_REQUEST_USAGE:
 555                 {
 556                         print("\nUsage:^3 sv_cmd database action filename\n");
 557                         print("  Where 'action' is the command to complete,\n");
 558                         print("  and 'filename' is what it acts upon.\n");
 559                         print("  Full list of commands here: \"save, dump, load.\"\n");
 560                         return;
 561                 }
 562         }
 563 }
 564
 565 void GameCommand_defer_clear(float request, float argc)
 566 {
 567         switch(request)
 568         {
 569                 case CMD_REQUEST_COMMAND:
 570                 {
 571                         entity client;
 572                         float accepted;
 573
 574                         if(argc >= 2)
 575                         {
 576                                 client = GetIndexedEntity(argc, 1);
 577                                 accepted = VerifyClientEntity(client, true, false);
 578
 579                                 if(accepted > 0)
 580                                 {
 581                                         stuffcmd(client, "defer clear\n");
 582                                         print("defer clear stuffed to ", client.netname, "\n");
 583                                 }
 584                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 585
 586                                 return;
 587                         }
 588                 }
 589
 590                 default:
 591                         print("Incorrect parameters for ^2defer_clear^7\n");
 592                 case CMD_REQUEST_USAGE:
 593                 {
 594                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 595                         print("  'client' is the entity number or name of the player.\n");
 596                         print("See also: ^2defer_clear_all^7\n");
 597                         return;
 598                 }
 599         }
 600 }
 601
 602 void GameCommand_defer_clear_all(float request)
 603 {
 604         switch(request)
 605         {
 606                 case CMD_REQUEST_COMMAND:
 607                 {
 608                         entity client;
 609                         float i = 0;
 610                         float argc;
 611
 612                         FOR_EACH_CLIENT(client)
 613                         {
 614                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 615                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 616                                 ++i;
 617                         }
 618                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 619                         return;
 620                 }
 621
 622                 default:
 623                 case CMD_REQUEST_USAGE:
 624                 {
 625                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 626                         print("  No arguments required.\n");
 627                         print("See also: ^2defer_clear^7\n");
 628                         return;
 629                 }
 630         }
 631 }
 632
 633 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 634 {
 635         switch(request)
 636         {
 637                 case CMD_REQUEST_COMMAND:
 638                 {
 639                         if(argv(1))
 640                         {
 641                                 if(argv(2))
 642                                         race_deleteTime(argv(2), stof(argv(1)));
 643                                 else
 644                                         race_deleteTime(GetMapname(), stof(argv(1)));
 645                                 return;
 646                         }
 647                 }
 648
 649                 default:
 650                         print("Incorrect parameters for ^2delrec^7\n");
 651                 case CMD_REQUEST_USAGE:
 652                 {
 653                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 654                         print("  'ranking' is which ranking level to clear up to, \n");
 655                         print("  it will clear all records up to nth place.\n");
 656                         print("  if 'map' is not provided it will use current map.\n");
 657                         return;
 658                 }
 659         }
 660 }
 661
 662 void GameCommand_effectindexdump(float request)
 663 {
 664         switch(request)
 665         {
 666                 case CMD_REQUEST_COMMAND:
 667                 {
 668                         float fh, d;
 669                         string s;
 670
 671                         d = db_create();
 672                         print("begin of effects list\n");
 673                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 674                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 675                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 676                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 677                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 678                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 679                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 680                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 681                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 682                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 683                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 684                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 685                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 686                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 687                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 688                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 689                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 690                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 691                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 692                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 693                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 694                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 695                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 696                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 697                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 698                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 699                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 700                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 701                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 702                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 703                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 704                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 705                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 706                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 707                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 708                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 709
 710                         fh = fopen("effectinfo.txt", FILE_READ);
 711                         while((s = fgets(fh)))
 712                         {
 713                                 tokenize_console(s);
 714                                 if(argv(0) == "effect")
 715                                 {
 716                                         if(db_get(d, argv(1)) != "1")
 717                                         {
 718                                                 if(particleeffectnum(argv(1)) >= 0)
 719                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 720                                                 db_put(d, argv(1), "1");
 721                                         }
 722                                 }
 723                         }
 724                         print("end of effects list\n");
 725
 726                         db_close(d);
 727                         return;
 728                 }
 729
 730                 default:
 731                 case CMD_REQUEST_USAGE:
 732                 {
 733                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 734                         print("  No arguments required.\n");
 735                         return;
 736                 }
 737         }
 738 }
 739
 740 void GameCommand_extendmatchtime(float request)
 741 {
 742         switch(request)
 743         {
 744                 case CMD_REQUEST_COMMAND:
 745                 {
 746                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 747                         return;
 748                 }
 749
 750                 default:
 751                 case CMD_REQUEST_USAGE:
 752                 {
 753                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 754                         print("  No arguments required.\n");
 755                         print("See also: ^2reducematchtime^7\n");
 756                         return;
 757                 }
 758         }
 759 }
 760
 761 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 762 {
 763         switch(request)
 764         {
 765                 case CMD_REQUEST_COMMAND:
 766                 {
 767                         entity client;
 768
 769                         for(client = world; (client = find(client, classname, argv(1))); )
 770                                 print(etos(client), "\n");
 771
 772                         return;
 773                 }
 774
 775                 default:
 776                         print("Incorrect parameters for ^2find^7\n");
 777                 case CMD_REQUEST_USAGE:
 778                 {
 779                         print("\nUsage:^3 sv_cmd find classname\n");
 780                         print("  Where 'classname' is the classname to search for.\n");
 781                         return;
 782                 }
 783         }
 784 }
 785
 786 void GameCommand_gametype(float request, float argc)
 787 {
 788         switch(request)
 789         {
 790                 case CMD_REQUEST_COMMAND:
 791                 {
 792                         if(argv(1) != "")
 793                         {
 794                                 string s = argv(1);
 795                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 796
 797                                 if(t)
 798                                 {
 799                                         MapInfo_SwitchGameType(t);
 800                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 801                                         if(MapInfo_count > 0)
 802                                         {
 803                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 804                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 805                                                 lsmaps_reply = strzone(getlsmaps());
 806                                                 bprint("Game type successfully switched to ", s, "\n");
 807                                         }
 808                                         else
 809                                         {
 810                                                 bprint("Cannot use this game type: no map for it found\n");
 811                                                 MapInfo_SwitchGameType(tsave);
 812                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 813                                         }
 814                                 }
 815                                 else
 816                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 817
 818                                 return;
 819                         }
 820                 }
 821
 822                 default:
 823                         print("Incorrect parameters for ^2gametype^7\n");
 824                 case CMD_REQUEST_USAGE:
 825                 {
 826                         print("\nUsage:^3 sv_cmd gametype mode\n");
 827                         print("  Where 'mode' is the gametype mode to switch to.\n");
 828                         print("See also: ^2gotomap^7\n");
 829                         return;
 830                 }
 831         }
 832 }
 833
 834 void GameCommand_gettaginfo(float request, float argc)
 835 {
 836         switch(request)
 837         {
 838                 case CMD_REQUEST_COMMAND:
 839                 {
 840                         entity tmp_entity;
 841                         float i;
 842                         vector v;
 843
 844                         if(argc >= 4)
 845                         {
 846                                 tmp_entity = spawn();
 847                                 if(argv(1) == "w")
 848                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 849                                 else
 850                                 {
 851                                         precache_model(argv(1));
 852                                         setmodel(tmp_entity, argv(1));
 853                                 }
 854                                 tmp_entity.frame = stof(argv(2));
 855                                 if(substring(argv(3), 0, 1) == "#")
 856                                         i = stof(substring(argv(3), 1, -1));
 857                                 else
 858                                         i = gettagindex(tmp_entity, argv(3));
 859                                 if(i)
 860                                 {
 861                                         v = gettaginfo(tmp_entity, i);
 862                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 863                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 864                                         print(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
 865                                         print(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
 866                                         print(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
 867                                         print(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
 868                                         print(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
 869                                         if(argc >= 6)
 870                                         {
 871                                                 v.y = -v.y;
 872                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 873                                         }
 874                                 }
 875                                 else
 876                                         print("bone not found\n");
 877
 878                                 remove(tmp_entity);
 879                                 return;
 880                         }
 881                 }
 882
 883                 default:
 884                         print("Incorrect parameters for ^2gettaginfo^7\n");
 885                 case CMD_REQUEST_USAGE:
 886                 {
 887                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 888                         print("See also: ^2bbox, trace^7\n");
 889                         return;
 890                 }
 891         }
 892 }
 893
 894 void GameCommand_animbench(float request, float argc)
 895 {
 896         switch(request)
 897         {
 898                 case CMD_REQUEST_COMMAND:
 899                 {
 900                         entity tmp_entity;
 901
 902                         if(argc >= 4)
 903                         {
 904                                 tmp_entity = spawn();
 905                                 if(argv(1) == "w")
 906                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 907                                 else
 908                                 {
 909                                         precache_model(argv(1));
 910                                         setmodel(tmp_entity, argv(1));
 911                                 }
 912                                 float f1 = stof(argv(2));
 913                                 float f2 = stof(argv(3));
 914                                 float t0;
 915                                 float t1 = 0;
 916                                 float t2 = 0;
 917                                 float n = 0;
 918
 919                                 while(t1 + t2 < 1)
 920                                 {
 921                                         tmp_entity.frame = f1;
 922                                         t0 = gettime(GETTIME_HIRES);
 923                                         getsurfacepoint(tmp_entity, 0, 0);
 924                                         t1 += gettime(GETTIME_HIRES) - t0;
 925                                         tmp_entity.frame = f2;
 926                                         t0 = gettime(GETTIME_HIRES);
 927                                         getsurfacepoint(tmp_entity, 0, 0);
 928                                         t2 += gettime(GETTIME_HIRES) - t0;
 929                                         n += 1;
 930                                 }
 931                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 932                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 933
 934                                 remove(tmp_entity);
 935                                 return;
 936                         }
 937                 }
 938
 939                 default:
 940                         print("Incorrect parameters for ^2gettaginfo^7\n");
 941                 case CMD_REQUEST_USAGE:
 942                 {
 943                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 944                         print("See also: ^2bbox, trace^7\n");
 945                         return;
 946                 }
 947         }
 948 }
 949
 950 void GameCommand_gotomap(float request, float argc)
 951 {
 952         switch(request)
 953         {
 954                 case CMD_REQUEST_COMMAND:
 955                 {
 956                         if(argv(1))
 957                         {
 958                                 print(GotoMap(argv(1)), "\n");
 959                                 return;
 960                         }
 961                 }
 962
 963                 default:
 964                         print("Incorrect parameters for ^2gotomap^7\n");
 965                 case CMD_REQUEST_USAGE:
 966                 {
 967                         print("\nUsage:^3 sv_cmd gotomap map\n");
 968                         print("  Where 'map' is the *.bsp file to change to.\n");
 969                         print("See also: ^2gametype^7\n");
 970                         return;
 971                 }
 972         }
 973 }
 974
 975 void GameCommand_lockteams(float request)
 976 {
 977         switch(request)
 978         {
 979                 case CMD_REQUEST_COMMAND:
 980                 {
 981                         if(teamplay)
 982                         {
 983                                 lockteams = 1;
 984                                 bprint("^1The teams are now locked.\n");
 985                         }
 986                         else
 987                         {
 988                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 989                         }
 990                         return;
 991                 }
 992
 993                 default:
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         print("\nUsage:^3 sv_cmd lockteams\n");
 997                         print("  No arguments required.\n");
 998                         print("See also: ^2unlockteams^7\n");
 999                         return;
1000                 }
1001         }
1002 }
1003
1004 void GameCommand_make_mapinfo(float request)
1005 {
1006         switch(request)
1007         {
1008                 case CMD_REQUEST_COMMAND:
1009                 {
1010                         entity tmp_entity;
1011
1012                         tmp_entity = spawn();
1013                         tmp_entity.classname = "make_mapinfo";
1014                         tmp_entity.think = make_mapinfo_Think;
1015                         tmp_entity.nextthink = time;
1016                         MapInfo_Enumerate();
1017                         return;
1018                 }
1019
1020                 default:
1021                 case CMD_REQUEST_USAGE:
1022                 {
1023                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1024                         print("  No arguments required.\n");
1025                         print("See also: ^2radarmap^7\n");
1026                         return;
1027                 }
1028         }
1029 }
1030
1031 void GameCommand_moveplayer(float request, float argc)
1032 {
1033         switch(request)
1034         {
1035                 case CMD_REQUEST_COMMAND:
1036                 {
1037                         float accepted;
1038                         entity client;
1039
1040                         string targets = strreplace(",", " ", argv(1));
1041                         string original_targets = strreplace(" ", ", ", targets);
1042                         string destination = argv(2);
1043
1044                         string successful, t;
1045                         successful = string_null;
1046
1047                         // lets see if the target(s) even actually exist.
1048                         if((targets) && (destination))
1049                         {
1050                                 for (;targets;)
1051                                 {
1052                                         t = car(targets); targets = cdr(targets);
1053
1054                                         // Check to see if the player is a valid target
1055                                         client = GetFilteredEntity(t);
1056                                         accepted = VerifyClientEntity(client, false, false);
1057
1058                                         if(accepted <= 0)
1059                                         {
1060                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1061                                                 continue;
1062                                         }
1063
1064                                         // Where are we putting this player?
1065                                         if(destination == "spec" || destination == "spectator")
1066                                         {
1067                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1068                                                 {
1069                                                         self = client;
1070                                                         if(self.caplayer)
1071                                                                 self.caplayer = 0;
1072                                                         PutObserverInServer();
1073
1074                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1075                                                 }
1076                                                 else
1077                                                 {
1078                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1079                                                 }
1080                                                 continue;
1081                                         }
1082                                         else
1083                                         {
1084                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1085                                                 {
1086                                                         if(teamplay)
1087                                                         {
1088                                                                 // set up
1089                                                                 float team_id;
1090                                                                 float save = client.team_forced;
1091                                                                 client.team_forced = 0;
1092
1093                                                                 // find the team to move the player to
1094                                                                 team_id = Team_ColorToTeam(destination);
1095                                                                 if(team_id == client.team) // already on the destination team
1096                                                                 {
1097                                                                         // keep the forcing undone
1098                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1099                                                                         continue;
1100                                                                 }
1101                                                                 else if(team_id == 0)  // auto team
1102                                                                 {
1103                                                                         CheckAllowedTeams(client);
1104                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1105                                                                 }
1106                                                                 else
1107                                                                 {
1108                                                                         CheckAllowedTeams(client);
1109                                                                 }
1110                                                                 client.team_forced = save;
1111
1112                                                                 // Check to see if the destination team is even available
1113                                                                 switch(team_id)
1114                                                                 {
1115                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1116                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1117                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1118                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1119
1120                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1121                                                                 }
1122
1123                                                                 // If so, lets continue and finally move the player
1124                                                                 client.team_forced = 0;
1125                                                                 MoveToTeam(client, team_id, 6);
1126                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1127                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1128                                                                 continue;
1129                                                         }
1130                                                         else
1131                                                         {
1132                                                                 print("Can't change teams when currently not playing a team game.\n");
1133                                                                 return;
1134                                                         }
1135                                                 }
1136                                                 else
1137                                                 {
1138                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1139                                                         return;
1140                                                 }
1141                                         }
1142                                 }
1143
1144                                 if(successful)
1145                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1146                                 else
1147                                         print("No players given (", original_targets, ") are able to move.\n");
1148
1149                                 return; // still correct parameters so return to avoid usage print
1150                         }
1151                 }
1152
1153                 default:
1154                         print("Incorrect parameters for ^2moveplayer^7\n");
1155                 case CMD_REQUEST_USAGE:
1156                 {
1157                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1158                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1159                         print("  'destination' is what to send the player to, be it team or spectating\n");
1160                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1161                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1162                         print("          sv_cmd moveplayer 2 spec \n");
1163                         print("See also: ^2allspec, shuffleteams^7\n");
1164                         return;
1165                 }
1166         }
1167 }
1168
1169 void GameCommand_nospectators(float request)
1170 {
1171         switch(request)
1172         {
1173                 case CMD_REQUEST_COMMAND:
1174                 {
1175                         blockSpectators = 1;
1176                         entity plr;
1177                         FOR_EACH_REALCLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1178                         {
1179                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1180                                 if(!plr.caplayer)
1181                                 {
1182                                         plr.spectatortime = time;
1183                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1184                                 }
1185                         }
1186                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1187                         return;
1188                 }
1189
1190                 default:
1191                 case CMD_REQUEST_USAGE:
1192                 {
1193                         print("\nUsage:^3 sv_cmd nospectators\n");
1194                         print("  No arguments required.\n");
1195                         return;
1196                 }
1197         }
1198 }
1199
1200 void GameCommand_playerdemo(float request, float argc)
1201 {
1202         switch(request)
1203         {
1204                 case CMD_REQUEST_COMMAND:
1205                 {
1206                         if(argv(2) && argv(3))
1207                         {
1208                                 entity client;
1209                                 float i, n, accepted;
1210
1211                                 switch(argv(1))
1212                                 {
1213                                         case "read":
1214                                         {
1215                                                 client = GetIndexedEntity(argc, 2);
1216                                                 accepted = VerifyClientEntity(client, false, true);
1217
1218                                                 if(accepted <= 0)
1219                                                 {
1220                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1221                                                         return;
1222                                                 }
1223
1224                                                 self = client;
1225                                                 playerdemo_open_read(argv(next_token));
1226                                                 return;
1227                                         }
1228
1229                                         case "write":
1230                                         {
1231                                                 client = GetIndexedEntity(argc, 2);
1232                                                 accepted = VerifyClientEntity(client, false, false);
1233
1234                                                 if(accepted <= 0)
1235                                                 {
1236                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1237                                                         return;
1238                                                 }
1239
1240                                                 self = client;
1241                                                 playerdemo_open_write(argv(next_token));
1242                                                 return;
1243                                         }
1244
1245                                         case "auto_read_and_write":
1246                                         {
1247                                                 n = GetFilteredNumber(argv(3));
1248                                                 cvar_set("bot_number", ftos(n));
1249
1250                                                 localcmd("wait; wait; wait\n");
1251                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1252
1253                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1254                                                 return;
1255                                         }
1256
1257                                         case "auto_read":
1258                                         {
1259                                                 n = GetFilteredNumber(argv(3));
1260                                                 cvar_set("bot_number", ftos(n));
1261
1262                                                 localcmd("wait; wait; wait\n");
1263                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1264                                                 return;
1265                                         }
1266                                 }
1267                         }
1268                 }
1269
1270                 default:
1271                         print("Incorrect parameters for ^2playerdemo^7\n");
1272                 case CMD_REQUEST_USAGE:
1273                 {
1274                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1275                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1276                         return;
1277                 }
1278         }
1279 }
1280
1281 void GameCommand_printstats(float request)
1282 {
1283         switch(request)
1284         {
1285                 case CMD_REQUEST_COMMAND:
1286                 {
1287                         DumpStats(false);
1288                         print("stats dumped.\n");
1289                         return;
1290                 }
1291
1292                 default:
1293                 case CMD_REQUEST_USAGE:
1294                 {
1295                         print("\nUsage:^3 sv_cmd printstats\n");
1296                         print("  No arguments required.\n");
1297                         return;
1298                 }
1299         }
1300 }
1301
1302 void GameCommand_radarmap(float request, float argc)
1303 {
1304         switch(request)
1305         {
1306                 case CMD_REQUEST_COMMAND:
1307                 {
1308                         if(RadarMap_Make(argc))
1309                                 return;
1310                 }
1311
1312                 default:
1313                         print("Incorrect parameters for ^2radarmap^7\n");
1314                 case CMD_REQUEST_USAGE:
1315                 {
1316                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1317                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1318                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1319                         print("See also: ^2make_mapinfo^7\n");
1320                         return;
1321                 }
1322         }
1323 }
1324
1325 void GameCommand_reducematchtime(float request)
1326 {
1327         switch(request)
1328         {
1329                 case CMD_REQUEST_COMMAND:
1330                 {
1331                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1332                         return;
1333                 }
1334
1335                 default:
1336                 case CMD_REQUEST_USAGE:
1337                 {
1338                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1339                         print("  No arguments required.\n");
1340                         print("See also: ^2extendmatchtime^7\n");
1341                         return;
1342                 }
1343         }
1344 }
1345
1346 void GameCommand_setbots(float request, float argc)
1347 {
1348         switch(request)
1349         {
1350                 case CMD_REQUEST_COMMAND:
1351                 {
1352                         if(argc >= 2)
1353                         {
1354                                 cvar_settemp("minplayers", "0");
1355                                 cvar_settemp("bot_number", argv(1));
1356                                 bot_fixcount();
1357                                 return;
1358                         }
1359                 }
1360
1361                 default:
1362                         print("Incorrect parameters for ^2setbots^7\n");
1363                 case CMD_REQUEST_USAGE:
1364                 {
1365                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1366                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1367                         print("See also: ^2bot_cmd^7\n");
1368                         return;
1369                 }
1370         }
1371 }
1372
1373 void GameCommand_shuffleteams(float request)
1374 {
1375         switch(request)
1376         {
1377                 case CMD_REQUEST_COMMAND:
1378                 {
1379                         if(teamplay)
1380                         {
1381                                 entity tmp_player;
1382                                 int i;
1383                                 float x, t_teams, t_players, team_color;
1384
1385                                 // count the total amount of players and total amount of teams
1386                                 t_players = 0;
1387                                 t_teams = 0;
1388                                 FOR_EACH_PLAYER(tmp_player)
1389                                 {
1390                                         CheckAllowedTeams(tmp_player);
1391
1392                                         if(c1 >= 0) t_teams = max(1, t_teams);
1393                                         if(c2 >= 0) t_teams = max(2, t_teams);
1394                                         if(c3 >= 0) t_teams = max(3, t_teams);
1395                                         if(c4 >= 0) t_teams = max(4, t_teams);
1396
1397                                         ++t_players;
1398                                 }
1399
1400                                 // build a list of the players in a random order
1401                                 FOR_EACH_PLAYER(tmp_player)
1402                                 {
1403                                         for (;;)
1404                                         {
1405                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1406
1407                                                 if(shuffleteams_players[i])
1408                                                 {
1409                                                         continue; // a player is already assigned to this slot
1410                                                 }
1411                                                 else
1412                                                 {
1413                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1414                                                         break;
1415                                                 }
1416                                         }
1417                                 }
1418
1419                                 // finally, from the list made earlier, re-join the players in different order.
1420                                 for (int i = 1; i <= t_teams; ++i)
1421                                 {
1422                                         // find out how many players to assign to this team
1423                                         x = (t_players / t_teams);
1424                                         x = ((i == 1) ? ceil(x) : floor(x));
1425
1426                                         team_color = Team_NumberToTeam(i);
1427
1428                                         // sort through the random list of players made earlier
1429                                         for (int z = 1; z <= maxclients; ++z)
1430                                         {
1431                                                 if (!(shuffleteams_teams[i] >= x))
1432                                                 {
1433                                                         if (!(shuffleteams_players[z]))
1434                                                                 continue; // not a player, move on to next random slot
1435
1436                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1437                                                                 self = edict_num(shuffleteams_players[z]);
1438
1439                                                         if(self.team != team_color)
1440                                                                 MoveToTeam(self, team_color, 6);
1441
1442                                                         shuffleteams_players[z] = 0;
1443                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1444                                                 }
1445                                                 else
1446                                                 {
1447                                                         break; // move on to next team
1448                                                 }
1449                                         }
1450                                 }
1451
1452                                 bprint("Successfully shuffled the players around randomly.\n");
1453
1454                                 // clear the buffers now
1455                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1456                                         shuffleteams_players[i] = 0;
1457
1458                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1459                                         shuffleteams_teams[i] = 0;
1460                         }
1461                         else
1462                         {
1463                                 print("Can't shuffle teams when currently not playing a team game.\n");
1464                         }
1465
1466                         return;
1467                 }
1468
1469                 default:
1470                 case CMD_REQUEST_USAGE:
1471                 {
1472                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1473                         print("  No arguments required.\n");
1474                         print("See also: ^2moveplayer, allspec^7\n");
1475                         return;
1476                 }
1477         }
1478 }
1479
1480 void GameCommand_stuffto(float request, float argc)
1481 {
1482         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1483         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1484         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1485
1486         #ifdef STUFFTO_ENABLED
1487         #message "stuffto command enabled"
1488         switch(request)
1489         {
1490                 case CMD_REQUEST_COMMAND:
1491                 {
1492                         if(argv(2))
1493                         {
1494                                 entity client = GetIndexedEntity(argc, 1);
1495                                 float accepted = VerifyClientEntity(client, true, false);
1496
1497                                 if(accepted > 0)
1498                                 {
1499                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1500                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1501                                 }
1502                                 else
1503                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1504
1505                                 return;
1506                         }
1507                 }
1508
1509                 default:
1510                         print("Incorrect parameters for ^2stuffto^7\n");
1511                 case CMD_REQUEST_USAGE:
1512                 {
1513                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1514                         print("  'client' is the entity number or name of the player,\n");
1515                         print("  and 'command' is the command to be sent to that player.\n");
1516                         return;
1517                 }
1518         }
1519         #else
1520         if(request)
1521         {
1522                 print("stuffto command is not enabled on this server.\n");
1523                 return;
1524         }
1525         #endif
1526 }
1527
1528 void GameCommand_trace(float request, float argc)
1529 {
1530         switch(request)
1531         {
1532                 case CMD_REQUEST_COMMAND:
1533                 {
1534                         entity e;
1535                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1536                         float i, f, safe, unsafe, dq, dqf;
1537
1538                         switch(argv(1))
1539                         {
1540                                 case "debug":
1541                                 {
1542                                         float hitcount = 0;
1543                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1544                                         float worst_endpos_bug = 0;
1545                                         for (;;)
1546                                         {
1547                                                 org = world.mins;
1548                                                 delta = world.maxs - world.mins;
1549
1550                                                 start.x = org.x + random() * delta.x;
1551                                                 start.y = org.y + random() * delta.y;
1552                                                 start.z = org.z + random() * delta.z;
1553
1554                                                 end.x = org.x + random() * delta.x;
1555                                                 end.y = org.y + random() * delta.y;
1556                                                 end.z = org.z + random() * delta.z;
1557
1558                                                 start = stov(vtos(start));
1559                                                 end = stov(vtos(end));
1560
1561                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1562                                                 if(!trace_startsolid && trace_fraction < 1)
1563                                                 {
1564                                                         p = trace_endpos;
1565                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1566                                                         if(trace_startsolid)
1567                                                         {
1568                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1569                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1570
1571                                                                 // how much do we need to back off?
1572                                                                 safe = 1;
1573                                                                 unsafe = 0;
1574                                                                 for (;;)
1575                                                                 {
1576                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1577                                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1578                                                                         if(trace_startsolid)
1579                                                                         {
1580                                                                                 if((safe + unsafe) * 0.5 == unsafe)
1581                                                                                         break;
1582                                                                                 unsafe = (safe + unsafe) * 0.5;
1583                                                                         }
1584                                                                         else
1585                                                                         {
1586                                                                                 if((safe + unsafe) * 0.5 == safe)
1587                                                                                         break;
1588                                                                                 safe = (safe + unsafe) * 0.5;
1589                                                                         }
1590                                                                 }
1591
1592                                                                 print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1593                                                                 print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1594
1595                                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1596                                                                 if(trace_startsolid)
1597                                                                         print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1598                                                                 else
1599                                                                         print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1600                                                                 if (++hitcount >= 10)
1601                                                                         break;
1602                                                         }
1603                                                         else
1604                                                         {
1605                                                                 q0 = p;
1606                                                                 dq = 0;
1607                                                                 dqf = 1;
1608                                                                 for (;;)
1609                                                                 {
1610                                                                         q = p + normalize(end - p) * (dq + dqf);
1611                                                                         if(q == q0)
1612                                                                                 break;
1613                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1614                                                                         if(trace_startsolid)
1615                                                                                 error("THIS ONE cannot happen");
1616                                                                         if(trace_fraction > 0)
1617                                                                                 dq += dqf * trace_fraction;
1618                                                                         dqf *= 0.5;
1619                                                                         q0 = q;
1620                                                                 }
1621                                                                 if(dq > worst_endpos_bug)
1622                                                                 {
1623                                                                         worst_endpos_bug = dq;
1624                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1625                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1626                                                                         if (++hitcount >= 10)
1627                                                                                 break;
1628                                                                 }
1629                                                         }
1630                                                 }
1631                                         }
1632                                         return;
1633                                 }
1634
1635                                 case "debug2":
1636                                 {
1637                                         e = nextent(world);
1638                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1639                                         vv = trace_endpos;
1640                                         if(trace_fraction == 1)
1641                                         {
1642                                                 print("not above ground, aborting\n");
1643                                                 return;
1644                                         }
1645                                         f = 0;
1646                                         for(i = 0; i < 100000; ++i)
1647                                         {
1648                                                 dv = randomvec();
1649                                                 if(dv.z > 0)
1650                                                         dv = -1 * dv;
1651                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1652                                                 if(trace_startsolid)
1653                                                         print("bug 1\n");
1654                                                 if(trace_fraction == 1)
1655                                                 if(dv.z < f)
1656                                                 {
1657                                                         print("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1658                                                         print(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1659                                                         f = dv.z;
1660                                                 }
1661                                         }
1662                                         print("highest possible dist: ", ftos(f), "\n");
1663                                         return;
1664                                 }
1665
1666                                 case "walk":
1667                                 {
1668                                         if(argc == 4)
1669                                         {
1670                                                 e = nextent(world);
1671                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1672                                                         print("can walk\n");
1673                                                 else
1674                                                         print("cannot walk\n");
1675                                                 return;
1676                                         }
1677                                 }
1678
1679                                 case "showline":
1680                                 {
1681                                         if(argc == 4)
1682                                         {
1683                                                 vv = stov(argv(2));
1684                                                 dv = stov(argv(3));
1685                                                 traceline(vv, dv, MOVE_NORMAL, world);
1686                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1687                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1688                                                 return;
1689                                         }
1690                                 }
1691
1692                                 // no default case, just go straight to invalid
1693                         }
1694                 }
1695
1696                 default:
1697                         print("Incorrect parameters for ^2trace^7\n");
1698                 case CMD_REQUEST_USAGE:
1699                 {
1700                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1701                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1702                         print("See also: ^2bbox, gettaginfo^7\n");
1703                         return;
1704                 }
1705         }
1706 }
1707
1708 void GameCommand_unlockteams(float request)
1709 {
1710         switch(request)
1711         {
1712                 case CMD_REQUEST_COMMAND:
1713                 {
1714                         if(teamplay)
1715                         {
1716                                 lockteams = 0;
1717                                 bprint("^1The teams are now unlocked.\n");
1718                         }
1719                         else
1720                         {
1721                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1722                         }
1723                         return;
1724                 }
1725
1726                 default:
1727                 case CMD_REQUEST_USAGE:
1728                 {
1729                         print("\nUsage:^3 sv_cmd unlockteams\n");
1730                         print("  No arguments required.\n");
1731                         print("See also: ^2lockteams^7\n");
1732                         return;
1733                 }
1734         }
1735 }
1736
1737 void GameCommand_warp(float request, float argc)
1738 {
1739         switch (request)
1740         {
1741                 case CMD_REQUEST_COMMAND:
1742                 {
1743                         if(autocvar_g_campaign)
1744                         {
1745                                 if(argc >= 2)
1746                                 {
1747                                         CampaignLevelWarp(stof(argv(1)));
1748                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1749                                 }
1750                                 else
1751                                 {
1752                                         CampaignLevelWarp(-1);
1753                                         print("Successfully warped to next campaign level.\n");
1754                                 }
1755                         }
1756                         else
1757                                 print("Not in campaign, can't level warp\n");
1758                         return;
1759                 }
1760
1761                 default:
1762                 case CMD_REQUEST_USAGE:
1763                 {
1764                         print("\nUsage:^3 sv_cmd warp [level]\n");
1765                         print("  'level' is the level to change campaign mode to.\n");
1766                         print("  if 'level' is not provided it will change to the next level.\n");
1767                         return;
1768                 }
1769         }
1770 }
1771
1772 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1773 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1774 void GameCommand_(float request)
1775 {
1776         switch(request)
1777         {
1778                 case CMD_REQUEST_COMMAND:
1779                 {
1780
1781                         return;
1782                 }
1783
1784                 default:
1785                 case CMD_REQUEST_USAGE:
1786                 {
1787                         print("\nUsage:^3 sv_cmd \n");
1788                         print("  No arguments required.\n");
1789                         return;
1790                 }
1791         }
1792 }
1793 */
1794
1795
1796 // ==================================
1797 //  Macro system for server commands
1798 // ==================================
1799
1800 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1801 #define SERVER_COMMANDS(request,arguments,command) \
1802         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1803         SERVER_COMMAND("mobbutcher", GameCommand_mobbutcher(request), "Instantly removes all monsters on the map") \
1804         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1805         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1806         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1807         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1808         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1809         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1810         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1811         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1812         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1813         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1814         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1815         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1816         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1817         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1818         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1819         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1820         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1821         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1822         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1823         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1824         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1825         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1826         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1827         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1828         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1829         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1830         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1831         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1832         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1833         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1834         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1835         /* nothing */
1836
1837 void GameCommand_macro_help()
1838 {
1839         #define SERVER_COMMAND(name,function,description) \
1840                 { print("  ^2", name, "^7: ", description, "\n"); }
1841
1842         SERVER_COMMANDS(0, 0, "");
1843         #undef SERVER_COMMAND
1844
1845         return;
1846 }
1847
1848 float GameCommand_macro_command(float argc, string command)
1849 {
1850         #define SERVER_COMMAND(name,function,description) \
1851                 { if(name == strtolower(argv(0))) { function; return true; } }
1852
1853         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
1854         #undef SERVER_COMMAND
1855
1856         return false;
1857 }
1858
1859 float GameCommand_macro_usage(float argc)
1860 {
1861         #define SERVER_COMMAND(name,function,description) \
1862                 { if(name == strtolower(argv(1))) { function; return true; } }
1863
1864         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "");
1865         #undef SERVER_COMMAND
1866
1867         return false;
1868 }
1869
1870 void GameCommand_macro_write_aliases(float fh)
1871 {
1872         #define SERVER_COMMAND(name,function,description) \
1873                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1874
1875         SERVER_COMMANDS(0, 0, "");
1876         #undef SERVER_COMMAND
1877
1878         return;
1879 }
1880
1881
1882 // =========================================
1883 //  Main Function Called By Engine (sv_cmd)
1884 // =========================================
1885 // If this function exists, game code handles gamecommand instead of the engine code.
1886
1887 void GameCommand(string command)
1888 {
1889         float argc = tokenize_console(command);
1890
1891         // Guide for working with argc arguments by example:
1892         // argc:   1    - 2      - 3     - 4
1893         // argv:   0    - 1      - 2     - 3
1894         // cmd     vote - master - login - password
1895
1896         if(strtolower(argv(0)) == "help")
1897         {
1898                 if(argc == 1)
1899                 {
1900                         print("\nServer console commands:\n");
1901                         GameCommand_macro_help();
1902
1903                         print("\nBanning commands:\n");
1904                         BanCommand_macro_help();
1905
1906                         print("\nCommon networked commands:\n");
1907                         CommonCommand_macro_help(world);
1908
1909                         print("\nGeneric commands shared by all programs:\n");
1910                         GenericCommand_macro_help();
1911
1912                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1913                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1914
1915                         return;
1916                 }
1917                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1918                 {
1919                         return;
1920                 }
1921                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1922                 {
1923                         return;
1924                 }
1925                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1926                 {
1927                         return;
1928                 }
1929                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1930                 {
1931                         return;
1932                 }
1933         }
1934         else if(BanCommand(command))
1935         {
1936                 return; // handled by server/command/ipban.qc
1937         }
1938         else if(CommonCommand_macro_command(argc, world, command))
1939         {
1940                 return; // handled by server/command/common.qc
1941         }
1942         else if(GenericCommand(command))
1943         {
1944                 return; // handled by common/command/generic.qc
1945         }
1946         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1947         {
1948                 return; // handled by one of the above GameCommand_* functions
1949         }
1950
1951         // nothing above caught the command, must be invalid
1952         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1953
1954         return;
1955 }