qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = (self.cnt + 1) % maxclients;
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void GotoFirstMap()
  85 {
  86         float n;
  87         if(autocvar__sv_init)
  88         {
  89                 // cvar_set("_sv_init", "0");
  90                 // we do NOT set this to 0 any more, so someone "accidentally" changing
  91                 // to this "init" map on a dedicated server will cause no permanent
  92                 // harm
  93                 if(autocvar_g_maplist_shuffle)
  94                         ShuffleMaplist();
  95                 n = tokenizebyseparator(autocvar_g_maplist, " ");
  96                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
  97
  98                 MapInfo_Enumerate();
  99                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 100
 101                 if(!DoNextMapOverride(1))
 102                         GotoNextMap(1);
 103
 104                 return;
 105         }
 106
 107         if(time < 5)
 108         {
 109                 self.nextthink = time;
 110         }
 111         else
 112         {
 113                 self.nextthink = time + 1;
 114                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 115         }
 116 }
 117
 118 void cvar_changes_init()
 119 {
 120         float h;
 121         string k, v, d;
 122         float n, i, adding, pureadding;
 123
 124         if(cvar_changes)
 125                 strunzone(cvar_changes);
 126         cvar_changes = string_null;
 127         if(cvar_purechanges)
 128                 strunzone(cvar_purechanges);
 129         cvar_purechanges = string_null;
 130         cvar_purechanges_count = 0;
 131
 132         h = buf_create();
 133         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 134         n = buf_getsize(h);
 135
 136         adding = TRUE;
 137         pureadding = TRUE;
 138
 139         for(i = 0; i < n; ++i)
 140         {
 141                 k = bufstr_get(h, i);
 142
 143 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 144 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 145 #define BADCVAR(p) if(k == p) continue
 146
 147                 // general excludes and namespaces for server admin used cvars
 148                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 149
 150                 // internal
 151                 BADPREFIX("csqc_");
 152                 BADPREFIX("cvar_check_");
 153                 BADCVAR("gamecfg");
 154                 BADCVAR("g_configversion");
 155                 BADCVAR("g_maplist_index");
 156                 BADCVAR("halflifebsp");
 157                 BADPREFIX("sv_world");
 158
 159                 // client
 160                 BADPREFIX("chase_");
 161                 BADPREFIX("cl_");
 162                 BADPREFIX("con_");
 163                 BADPREFIX("scoreboard_");
 164                 BADPREFIX("g_campaign");
 165                 BADPREFIX("g_waypointsprite_");
 166                 BADPREFIX("gl_");
 167                 BADPREFIX("joy");
 168                 BADPREFIX("hud_");
 169                 BADPREFIX("m_");
 170                 BADPREFIX("menu_");
 171                 BADPREFIX("net_slist_");
 172                 BADPREFIX("r_");
 173                 BADPREFIX("sbar_");
 174                 BADPREFIX("scr_");
 175                 BADPREFIX("snd_");
 176                 BADPREFIX("show");
 177                 BADPREFIX("sensitivity");
 178                 BADPREFIX("userbind");
 179                 BADPREFIX("v_");
 180                 BADPREFIX("vid_");
 181                 BADPREFIX("crosshair");
 182                 BADCVAR("mod_q3bsp_lightmapmergepower");
 183                 BADCVAR("mod_q3bsp_nolightmaps");
 184                 BADCVAR("fov");
 185                 BADCVAR("mastervolume");
 186                 BADCVAR("volume");
 187                 BADCVAR("bgmvolume");
 188
 189                 // private
 190                 BADCVAR("developer");
 191                 BADCVAR("log_dest_udp");
 192                 BADCVAR("net_address");
 193                 BADCVAR("net_address_ipv6");
 194                 BADCVAR("port");
 195                 BADCVAR("savedgamecfg");
 196                 BADCVAR("serverconfig");
 197                 BADCVAR("sv_autoscreenshot");
 198                 BADCVAR("sv_heartbeatperiod");
 199                 BADCVAR("sv_vote_master_password");
 200                 BADCVAR("sys_colortranslation");
 201                 BADCVAR("sys_specialcharactertranslation");
 202                 BADCVAR("timeformat");
 203                 BADCVAR("timestamps");
 204                 BADPREFIX("developer_");
 205                 BADPREFIX("g_ban_");
 206                 BADPREFIX("g_banned_list");
 207                 BADPREFIX("g_chat_flood_");
 208                 BADPREFIX("g_ghost_items");
 209                 BADPREFIX("g_playerstats_");
 210                 BADPREFIX("g_respawn_ghosts");
 211                 BADPREFIX("g_voice_flood_");
 212                 BADPREFIX("log_file");
 213                 BADPREFIX("rcon_");
 214                 BADPREFIX("sv_allowdownloads");
 215                 BADPREFIX("sv_autodemo");
 216                 BADPREFIX("sv_curl_");
 217                 BADPREFIX("sv_eventlog");
 218                 BADPREFIX("sv_logscores_");
 219                 BADPREFIX("sv_master");
 220                 BADPREFIX("sv_weaponstats_");
 221                 BADPREFIX("sv_waypointsprite_");
 222                 BADCVAR("rescan_pending");
 223
 224                 // these can contain player IDs, so better hide
 225                 BADPREFIX("g_forced_team_");
 226
 227                 // mapinfo
 228                 BADCVAR("fraglimit");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ca");
 231                 BADCVAR("g_ca_teams");
 232                 BADCVAR("g_ctf");
 233                 BADCVAR("g_cts");
 234                 BADCVAR("g_dm");
 235                 BADCVAR("g_domination");
 236                 BADCVAR("g_domination_default_teams");
 237                 BADCVAR("g_freezetag");
 238                 BADCVAR("g_freezetag_teams");
 239                 BADCVAR("g_keepaway");
 240                 BADCVAR("g_keyhunt");
 241                 BADCVAR("g_keyhunt_teams");
 242                 BADCVAR("g_lms");
 243                 BADCVAR("g_nexball");
 244                 BADCVAR("g_onslaught");
 245                 BADCVAR("g_race");
 246                 BADCVAR("g_race_qualifying_timelimit");
 247                 BADCVAR("g_tdm");
 248                 BADCVAR("g_tdm_teams");
 249                 BADCVAR("leadlimit");
 250                 BADCVAR("nextmap");
 251                 BADCVAR("teamplay");
 252                 BADCVAR("timelimit");
 253
 254                 // long
 255                 BADCVAR("hostname");
 256                 BADCVAR("g_maplist");
 257                 BADCVAR("g_maplist_mostrecent");
 258                 BADCVAR("sv_motd");
 259
 260                 v = cvar_string(k);
 261                 d = cvar_defstring(k);
 262                 if(v == d)
 263                         continue;
 264
 265                 if(adding)
 266                 {
 267                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 268                         if(strlen(cvar_changes) > 16384)
 269                         {
 270                                 cvar_changes = "// too many settings have been changed to show them here\n";
 271                                 adding = 0;
 272                         }
 273                 }
 274
 275                 // now check if the changes are actually gameplay relevant
 276
 277                 // does nothing visible
 278                 BADCVAR("captureleadlimit_override");
 279                 BADCVAR("g_balance_kill_delay");
 280                 BADCVAR("g_ca_point_leadlimit");
 281                 BADCVAR("g_ctf_captimerecord_always");
 282                 BADCVAR("g_ctf_flag_glowtrails");
 283                 BADCVAR("g_ctf_flag_pickup_verbosename");
 284                 BADCVAR("g_domination_point_leadlimit");
 285                 BADCVAR("g_forced_respawn");
 286                 BADCVAR("g_keyhunt_point_leadlimit");
 287                 BADPREFIX("g_mod_");
 288                 BADCVAR("g_nexball_goalleadlimit");
 289                 BADCVAR("leadlimit_and_fraglimit");
 290                 BADCVAR("leadlimit_override");
 291                 BADCVAR("pausable");
 292                 BADCVAR("sv_allow_fullbright");
 293                 BADCVAR("sv_checkforpacketsduringsleep");
 294                 BADCVAR("sv_fraginfo");
 295                 BADCVAR("sv_timeout");
 296                 BADPREFIX("sv_timeout_");
 297                 BADPREFIX("crypto_");
 298                 BADPREFIX("g_chat_");
 299                 BADPREFIX("g_ctf_captimerecord_");
 300                 BADPREFIX("g_maplist_votable_");
 301                 BADPREFIX("net_");
 302                 BADPREFIX("prvm_");
 303                 BADPREFIX("skill_");
 304                 BADPREFIX("sv_cullentities_");
 305                 BADPREFIX("sv_fraginfo_");
 306                 BADPREFIX("sv_maxidle_");
 307                 BADPREFIX("sv_vote_");
 308                 BADPREFIX("timelimit_");
 309                 BADCVAR("gameversion");
 310                 BADPREFIX("gameversion_");
 311                 BADCVAR("sv_namechangetimer");
 312
 313                 // allowed changes to server admins (please sync this to server.cfg)
 314                 // vi commands:
 315                 //   :/"impure"/,$d
 316                 //   :g!,^\/\/[^ /],d
 317                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 318                 //   :%!sort
 319                 // yes, this does contain some redundant stuff, don't really care
 320                 BADCVAR("bot_config_file");
 321                 BADCVAR("bot_number");
 322                 BADCVAR("bot_prefix");
 323                 BADCVAR("bot_suffix");
 324                 BADCVAR("capturelimit_override");
 325                 BADCVAR("fraglimit_override");
 326                 BADCVAR("gametype");
 327                 BADCVAR("g_antilag");
 328                 BADCVAR("g_balance_teams");
 329                 BADCVAR("g_balance_teams_prevent_imbalance");
 330                 BADCVAR("g_balance_teams_scorefactor");
 331                 BADCVAR("g_ban_sync_trusted_servers");
 332                 BADCVAR("g_ban_sync_uri");
 333                 BADCVAR("g_ca_teams_override");
 334                 BADCVAR("g_ctf_ignore_frags");
 335                 BADCVAR("g_domination_point_limit");
 336                 BADCVAR("g_freezetag_teams_override");
 337                 BADCVAR("g_friendlyfire");
 338                 BADCVAR("g_fullbrightitems");
 339                 BADCVAR("g_fullbrightplayers");
 340                 BADCVAR("g_keyhunt_point_limit");
 341                 BADCVAR("g_keyhunt_teams_override");
 342                 BADCVAR("g_lms_lives_override");
 343                 BADCVAR("g_maplist");
 344                 BADCVAR("g_maplist_check_waypoints");
 345                 BADCVAR("g_maplist_mostrecent_count");
 346                 BADCVAR("g_maplist_shuffle");
 347                 BADCVAR("g_maplist_votable");
 348                 BADCVAR("g_maplist_votable_abstain");
 349                 BADCVAR("g_maplist_votable_nodetail");
 350                 BADCVAR("g_maplist_votable_suggestions");
 351                 BADCVAR("g_maxplayers");
 352                 BADCVAR("g_mirrordamage");
 353                 BADCVAR("g_nexball_goallimit");
 354                 BADCVAR("g_powerups");
 355                 BADCVAR("g_start_delay");
 356                 BADCVAR("g_warmup");
 357                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 358                 BADCVAR("hostname");
 359                 BADCVAR("log_file");
 360                 BADCVAR("maxplayers");
 361                 BADCVAR("minplayers");
 362                 BADCVAR("net_address");
 363                 BADCVAR("port");
 364                 BADCVAR("rcon_password");
 365                 BADCVAR("rcon_restricted_commands");
 366                 BADCVAR("rcon_restricted_password");
 367                 BADCVAR("skill");
 368                 BADCVAR("sv_adminnick");
 369                 BADCVAR("sv_autoscreenshot");
 370                 BADCVAR("sv_autotaunt");
 371                 BADCVAR("sv_curl_defaulturl");
 372                 BADCVAR("sv_defaultcharacter");
 373                 BADCVAR("sv_defaultplayercolors");
 374                 BADCVAR("sv_defaultplayermodel");
 375                 BADCVAR("sv_defaultplayerskin");
 376                 BADCVAR("sv_maxidle");
 377                 BADCVAR("sv_maxrate");
 378                 BADCVAR("sv_motd");
 379                 BADCVAR("sv_public");
 380                 BADCVAR("sv_ready_restart");
 381                 BADCVAR("sv_status_privacy");
 382                 BADCVAR("sv_taunt");
 383                 BADCVAR("sv_vote_call");
 384                 BADCVAR("sv_vote_commands");
 385                 BADCVAR("sv_vote_majority_factor");
 386                 BADCVAR("sv_vote_master");
 387                 BADCVAR("sv_vote_master_commands");
 388                 BADCVAR("sv_vote_master_password");
 389                 BADCVAR("sv_vote_simple_majority_factor");
 390                 BADCVAR("teamplay_mode");
 391                 BADCVAR("timelimit_override");
 392                 BADCVAR("g_spawnshieldtime");
 393                 BADPREFIX("g_warmup_");
 394                 BADPREFIX("sv_ready_restart_");
 395
 396                 // mutators that announce themselves properly to the server browser
 397                 BADCVAR("g_instagib");
 398                 BADCVAR("g_new_toys");
 399                 BADCVAR("g_nix");
 400                 BADCVAR("g_grappling_hook");
 401                 BADCVAR("g_jetpack");
 402
 403 #undef BADPREFIX
 404 #undef BADCVAR
 405
 406                 if(pureadding)
 407                 {
 408                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 409                         if(strlen(cvar_purechanges) > 16384)
 410                         {
 411                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 412                                 pureadding = 0;
 413                         }
 414                 }
 415                 ++cvar_purechanges_count;
 416                 // WARNING: this variable is used for the server list
 417                 // NEVER dare to skip this code!
 418                 // Hacks to intentionally appearing as "pure server" even though you DO have
 419                 // modified settings may be punished by removal from the server list.
 420                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 421                 // though.
 422         }
 423         buf_del(h);
 424         if(cvar_changes == "")
 425                 cvar_changes = "// this server runs at default server settings\n";
 426         else
 427                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 428         cvar_changes = strzone(cvar_changes);
 429         if(cvar_purechanges == "")
 430                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 431         else
 432                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 433         cvar_purechanges = strzone(cvar_purechanges);
 434 }
 435
 436 void detect_maptype()
 437 {
 438 #if 0
 439         vector o, v;
 440         float i;
 441
 442         for(;;)
 443         {
 444                 o = world.mins;
 445                 o_x += random() * (world.maxs_x - world.mins_x);
 446                 o_y += random() * (world.maxs_y - world.mins_y);
 447                 o_z += random() * (world.maxs_z - world.mins_z);
 448
 449                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 450                 if(trace_fraction == 1)
 451                         continue;
 452
 453                 v = trace_endpos;
 454
 455                 for(i = 0; i < 64; i += 4)
 456                 {
 457                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 458         if(trace_fraction == 1)
 459                 continue;
 460                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 461                 }
 462
 463                 break;
 464         }
 465 #endif
 466 }
 467
 468 entity randomseed;
 469 float RandomSeed_Send(entity to, float sf)
 470 {
 471         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 472         WriteShort(MSG_ENTITY, self.cnt);
 473         return TRUE;
 474 }
 475 void RandomSeed_Think()
 476 {
 477         self.cnt = bound(0, floor(random() * 65536), 65535);
 478         self.nextthink = time + 5;
 479
 480         self.SendFlags |= 1;
 481 }
 482 void RandomSeed_Spawn()
 483 {
 484         randomseed = spawn();
 485         randomseed.think = RandomSeed_Think;
 486         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 487
 488         entity oldself;
 489         oldself = self;
 490         self = randomseed;
 491         self.think(); // sets random seed and nextthink
 492         self = oldself;
 493 }
 494
 495 void spawnfunc___init_dedicated_server(void)
 496 {
 497         // handler for _init/_init map (only for dedicated server initialization)
 498
 499         world_initialized = -1; // don't complain
 500         cvar = cvar_normal;
 501         cvar_string = cvar_string_normal;
 502         cvar_set = cvar_set_normal;
 503
 504         remove = remove_unsafely;
 505
 506         entity e;
 507         e = spawn();
 508         e.think = GotoFirstMap;
 509         e.nextthink = time; // this is usually 1 at this point
 510
 511         e = spawn();
 512         e.classname = "info_player_deathmatch"; // safeguard against player joining
 513
 514         self.classname = "worldspawn"; // safeguard against various stuff ;)
 515
 516         // needs to be done so early because of the constants they create
 517         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 518         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 519         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 520         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 521         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 522         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 523
 524         MapInfo_Enumerate();
 525         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 526 }
 527
 528 void Map_MarkAsRecent(string m);
 529 float world_already_spawned;
 530 void Nagger_Init();
 531 void ClientInit_Spawn();
 532 void WeaponStats_Init();
 533 void WeaponStats_Shutdown();
 534 void spawnfunc_worldspawn (void)
 535 {
 536         float fd, l, i, j, n;
 537         string s;
 538
 539         cvar = cvar_normal;
 540         cvar_string = cvar_string_normal;
 541         cvar_set = cvar_set_normal;
 542
 543         if(world_already_spawned)
 544                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 545         world_already_spawned = TRUE;
 546
 547         remove = remove_safely; // during spawning, watch what you remove!
 548
 549         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 550
 551         compressShortVector_init();
 552
 553         entity head;
 554         head = nextent(world);
 555         maxclients = 0;
 556         while(head)
 557         {
 558                 ++maxclients;
 559                 head = nextent(head);
 560         }
 561
 562         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 563
 564         // needs to be done so early because of the constants they create
 565         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 566         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 567         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 568         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 569         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 570         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 571
 572         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 573
 574         TemporaryDB = db_create();
 575
 576         // 0 normal
 577         lightstyle(0, "m");
 578
 579         // 1 FLICKER (first variety)
 580         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 581
 582         // 2 SLOW STRONG PULSE
 583         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 584
 585         // 3 CANDLE (first variety)
 586         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 587
 588         // 4 FAST STROBE
 589         lightstyle(4, "mamamamamama");
 590
 591         // 5 GENTLE PULSE 1
 592         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 593
 594         // 6 FLICKER (second variety)
 595         lightstyle(6, "nmonqnmomnmomomno");
 596
 597         // 7 CANDLE (second variety)
 598         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 599
 600         // 8 CANDLE (third variety)
 601         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 602
 603         // 9 SLOW STROBE (fourth variety)
 604         lightstyle(9, "aaaaaaaazzzzzzzz");
 605
 606         // 10 FLUORESCENT FLICKER
 607         lightstyle(10, "mmamammmmammamamaaamammma");
 608
 609         // 11 SLOW PULSE NOT FADE TO BLACK
 610         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 611
 612         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 613
 614         // 63 testing
 615         lightstyle(63, "a");
 616
 617         if(autocvar_g_campaign)
 618                 CampaignPreInit();
 619
 620         Map_MarkAsRecent(mapname);
 621
 622         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 623
 624         precache_model ("null"); // we need this one before InitGameplayMode
 625         InitGameplayMode();
 626         readlevelcvars();
 627         GrappleHookInit();
 628
 629         player_count = 0;
 630         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 631         if(bot_waypoints_for_items == 1)
 632                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 633                         bot_waypoints_for_items = 0;
 634
 635         precache();
 636
 637         WaypointSprite_Init();
 638
 639         GameLogInit(); // prepare everything
 640         // NOTE for matchid:
 641         // changing the logic generating it is okay. But:
 642         // it HAS to stay <= 64 chars
 643         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 644         if(autocvar_sv_eventlog)
 645         {
 646                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 647                 matchid = strzone(s);
 648
 649                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 650                 s = ":gameinfo:mutators:LIST";
 651
 652                 ret_string = s;
 653                 MUTATOR_CALLHOOK(BuildMutatorsString);
 654                 s = ret_string;
 655
 656                 // simple, probably not good in the mutator system
 657                 if(autocvar_g_grappling_hook)
 658                         s = strcat(s, ":grappling_hook");
 659
 660                 // initialiation stuff, not good in the mutator system
 661                 if(!autocvar_g_use_ammunition)
 662                         s = strcat(s, ":no_use_ammunition");
 663
 664                 // initialiation stuff, not good in the mutator system
 665                 if(autocvar_g_pickup_items == 0)
 666                         s = strcat(s, ":no_pickup_items");
 667                 if(autocvar_g_pickup_items > 0)
 668                         s = strcat(s, ":pickup_items");
 669
 670                 // initialiation stuff, not good in the mutator system
 671                 if(autocvar_g_weaponarena != "0")
 672                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 673
 674                 // TODO to mutator system
 675                 if(autocvar_g_norecoil)
 676                         s = strcat(s, ":norecoil");
 677
 678                 // TODO to mutator system
 679                 if(autocvar_g_powerups == 0)
 680                         s = strcat(s, ":no_powerups");
 681                 if(autocvar_g_powerups > 0)
 682                         s = strcat(s, ":powerups");
 683
 684                 GameLogEcho(s);
 685                 GameLogEcho(":gameinfo:end");
 686         }
 687         else
 688                 matchid = strzone(ftos(random()));
 689
 690         cvar_set("nextmap", "");
 691
 692         SetDefaultAlpha();
 693
 694         if(autocvar_g_campaign)
 695                 CampaignPostInit();
 696
 697         Ban_LoadBans();
 698
 699         MapInfo_Enumerate();
 700         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 701
 702         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 703         {
 704                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 705                 if(fd != -1)
 706                 {
 707                         while((s = fgets(fd)))
 708                         {
 709                                 l = tokenize_console(s);
 710                                 if(l < 2)
 711                                         continue;
 712                                 if(argv(0) == "cd")
 713                                 {
 714                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 715                                         print("  cdtrack ", argv(2), "\n");
 716                                 }
 717                                 else if(argv(0) == "fog")
 718                                 {
 719                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 720                                         print("  \"fog\" \"", s, "\"\n");
 721                                 }
 722                                 else if(argv(0) == "set")
 723                                 {
 724                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 725                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 726                                 }
 727                                 else if(argv(0) != "//")
 728                                 {
 729                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 730                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 731                                 }
 732                         }
 733                         fclose(fd);
 734                 }
 735         }
 736
 737         WeaponStats_Init();
 738
 739         WepSet_AddStat();
 740         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 741         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 742         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 743         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 744         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 745         Nagger_Init();
 746
 747         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 748         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 749         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 750         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 751         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 752         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 753         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 754         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 755         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 756         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 757         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 758         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 759         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 760         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 761         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 762
 763         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 764         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 765
 766         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 767
 768         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 769
 770         // freeze attacks
 771         addstat(STAT_FROZEN, AS_INT, frozen);
 772         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 773
 774         // g_movementspeed hack
 775         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 776         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 777         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 778         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 779
 780         // new properties
 781         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 782         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 783         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 784         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 785         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 786         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 787         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 788         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 789         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 790         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 791         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 792         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 793         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 794         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 795         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 796         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 797         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 798         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 799         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 800
 801         // secrets
 802         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 803         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 804
 805         // monsters
 806         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 807         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 808
 809         // misc
 810         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 811
 812         next_pingtime = time + 5;
 813
 814         detect_maptype();
 815
 816         // set up information replies for clients and server to use
 817         maplist_reply = strzone(getmaplist());
 818         lsmaps_reply = strzone(getlsmaps());
 819         monsterlist_reply = strzone(getmonsterlist());
 820         for(i = 0; i < 10; ++i)
 821         {
 822                 s = getrecords(i);
 823                 if (s)
 824                         records_reply[i] = strzone(s);
 825         }
 826         ladder_reply = strzone(getladder());
 827         rankings_reply = strzone(getrankings());
 828
 829         // begin other init
 830         ClientInit_Spawn();
 831         RandomSeed_Spawn();
 832         PingPLReport_Spawn();
 833
 834         CheatInit();
 835
 836         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 837
 838         // fill sv_curl_serverpackages from .serverpackage files
 839         if(autocvar_sv_curl_serverpackages_auto)
 840         {
 841                 s = "";
 842                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 843                 for(i = 0; i < n; ++i)
 844                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 845                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 846                                 s = strcat(s, " ", argv(i));
 847                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 848                 if(fd >= 0)
 849                 {
 850                         j = search_getsize(fd);
 851                         for(i = 0; i < j; ++i)
 852                                 s = strcat(s, " ", search_getfilename(fd, i));
 853                         search_end(fd);
 854                 }
 855                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 856                 if(fd >= 0)
 857                 {
 858                         j = search_getsize(fd);
 859                         for(i = 0; i < j; ++i)
 860                                 s = strcat(s, " ", search_getfilename(fd, i));
 861                         search_end(fd);
 862                 }
 863                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 864         }
 865
 866         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 867         modname = "Xonotic";
 868         // physics/balance/config changes that count as mod
 869         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 870                 modname = cvar_string("g_mod_physics");
 871         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 872                 modname = cvar_string("g_mod_balance");
 873         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 874                 modname = cvar_string("g_mod_config");
 875         // extra mutators that deserve to count as mod
 876         MUTATOR_CALLHOOK(SetModname);
 877
 878         // save it for later
 879         modname = strzone(modname);
 880
 881         WinningConditionHelper(); // set worldstatus
 882
 883         world_initialized = 1;
 884 }
 885
 886 void spawnfunc_light (void)
 887 {
 888         //makestatic (self); // Who the f___ did that?
 889         remove(self);
 890 }
 891
 892 string GetGametype()
 893 {
 894         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 895 }
 896
 897 string GetMapname()
 898 {
 899         return mapname;
 900 }
 901
 902 float Map_Count, Map_Current;
 903 string Map_Current_Name;
 904
 905 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 906 float GetMaplistPosition()
 907 {
 908         float pos, idx;
 909         string map;
 910
 911         map = GetMapname();
 912         idx = autocvar_g_maplist_index;
 913
 914         if(idx >= 0)
 915                 if(idx < Map_Count)
 916                         if(map == argv(idx))
 917                                 return idx;
 918
 919         for(pos = 0; pos < Map_Count; ++pos)
 920                 if(map == argv(pos))
 921                         return pos;
 922
 923         // resume normal maplist rotation if current map is not in g_maplist
 924         return idx;
 925 }
 926
 927 float MapHasRightSize(string map)
 928 {
 929         float fh;
 930         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 931         if(autocvar_g_maplist_check_waypoints)
 932         {
 933                 dprint("checkwp "); dprint(map);
 934                 if(!fexists(strcat("maps/", map, ".waypoints")))
 935                 {
 936                         dprint(": no waypoints\n");
 937                         return FALSE;
 938                 }
 939                 dprint(": has waypoints\n");
 940         }
 941
 942         // open map size restriction file
 943         dprint("opensize "); dprint(map);
 944         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 945         if(fh >= 0)
 946         {
 947                 float mapmin, mapmax;
 948                 dprint(": ok, ");
 949                 mapmin = stof(fgets(fh));
 950                 mapmax = stof(fgets(fh));
 951                 fclose(fh);
 952                 if(player_count < mapmin)
 953                 {
 954                         dprint("not enough\n");
 955                         return FALSE;
 956                 }
 957                 if(player_count > mapmax)
 958                 {
 959                         dprint("too many\n");
 960                         return FALSE;
 961                 }
 962                 dprint("right size\n");
 963                 return TRUE;
 964         }
 965         dprint(": not found\n");
 966         return TRUE;
 967 }
 968
 969 string Map_Filename(float position)
 970 {
 971         return strcat("maps/", argv(position), ".bsp");
 972 }
 973
 974 string strwords(string s, float w)
 975 {
 976         float endpos;
 977         for(endpos = 0; w && endpos >= 0; --w)
 978                 endpos = strstrofs(s, " ", endpos + 1);
 979         if(endpos < 0)
 980                 return s;
 981         else
 982                 return substring(s, 0, endpos);
 983 }
 984
 985 float strhasword(string s, string w)
 986 {
 987         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 988 }
 989
 990 void Map_MarkAsRecent(string m)
 991 {
 992         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 993 }
 994
 995 float Map_IsRecent(string m)
 996 {
 997         return strhasword(autocvar_g_maplist_mostrecent, m);
 998 }
 999
1000 float Map_Check(float position, float pass)
1001 {
1002         string filename;
1003         string map_next;
1004         map_next = argv(position);
1005         if(pass <= 1)
1006         {
1007                 if(Map_IsRecent(map_next))
1008                         return 0;
1009         }
1010         filename = Map_Filename(position);
1011         if(MapInfo_CheckMap(map_next))
1012         {
1013                 if(pass == 2)
1014                         return 1;
1015                 if(MapHasRightSize(map_next))
1016                         return 1;
1017                 return 0;
1018         }
1019         else
1020                 dprint( "Couldn't select '", filename, "'..\n" );
1021
1022         return 0;
1023 }
1024
1025 void Map_Goto_SetStr(string nextmapname)
1026 {
1027         if(getmapname_stored != "")
1028                 strunzone(getmapname_stored);
1029         if(nextmapname == "")
1030                 getmapname_stored = "";
1031         else
1032                 getmapname_stored = strzone(nextmapname);
1033 }
1034
1035 void Map_Goto_SetFloat(float position)
1036 {
1037         cvar_set("g_maplist_index", ftos(position));
1038         Map_Goto_SetStr(argv(position));
1039 }
1040
1041 void Map_Goto(float reinit)
1042 {
1043         MapInfo_LoadMap(getmapname_stored, reinit);
1044 }
1045
1046 // return codes of map selectors:
1047 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1048 //   -2 = permanent failure
1049 float() MaplistMethod_Iterate = // usual method
1050 {
1051         float pass, i;
1052
1053         dprint("Trying MaplistMethod_Iterate\n");
1054
1055         for(pass = 1; pass <= 2; ++pass)
1056         {
1057                 for(i = 1; i < Map_Count; ++i)
1058                 {
1059                         float mapindex;
1060                         mapindex = (i + Map_Current) % Map_Count;
1061                         if(Map_Check(mapindex, pass))
1062                                 return mapindex;
1063                 }
1064         }
1065         return -1;
1066 }
1067
1068 float() MaplistMethod_Repeat = // fallback method
1069 {
1070         dprint("Trying MaplistMethod_Repeat\n");
1071
1072         if(Map_Check(Map_Current, 2))
1073                 return Map_Current;
1074         return -2;
1075 }
1076
1077 float() MaplistMethod_Random = // random map selection
1078 {
1079         float i, imax;
1080
1081         dprint("Trying MaplistMethod_Random\n");
1082
1083         imax = 42;
1084
1085         for(i = 0; i <= imax; ++i)
1086         {
1087                 float mapindex;
1088                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1089                 if(Map_Check(mapindex, 1))
1090                         return mapindex;
1091         }
1092         return -1;
1093 }
1094
1095 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1096 // the exponent sets a bias on the map selection:
1097 // the higher the exponent, the less likely "shortly repeated" same maps are
1098 {
1099         float i, j, imax, insertpos;
1100
1101         dprint("Trying MaplistMethod_Shuffle\n");
1102
1103         imax = 42;
1104
1105         for(i = 0; i <= imax; ++i)
1106         {
1107                 string newlist;
1108
1109                 // now reinsert this at another position
1110                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1111                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1112                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1113                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1114
1115                 // insert the current map there
1116                 newlist = "";
1117                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1118                         newlist = strcat(newlist, " ", argv(j));
1119                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1120                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1121                         newlist = strcat(newlist, " ", argv(j));
1122                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1123                 cvar_set("g_maplist", newlist);
1124                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1125
1126                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1127                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1128                 if(Map_Check(Map_Current, 1))
1129                         return Map_Current;
1130         }
1131         return -1;
1132 }
1133
1134 void Maplist_Init()
1135 {
1136         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1137         float i;
1138         for (i = 0; i < Map_Count; ++i)
1139                 if (Map_Check(i, 2))
1140                         break;
1141         if (i == Map_Count)
1142         {
1143                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1144                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1145                 if(autocvar_g_maplist_shuffle)
1146                         ShuffleMaplist();
1147                 localcmd("\nmenu_cmd sync\n");
1148                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1149         }
1150         if(Map_Count == 0)
1151                 error("empty maplist, cannot select a new map");
1152         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1153
1154         if(Map_Current_Name)
1155                 strunzone(Map_Current_Name);
1156         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1157         // this may or may not be correct, but who cares, in the worst case a map
1158         // isn't chosen in the first pass that should have been
1159 }
1160
1161 string GetNextMap()
1162 {
1163         float nextMap;
1164
1165         Maplist_Init();
1166         nextMap = -1;
1167
1168         if(nextMap == -1)
1169                 if(autocvar_g_maplist_shuffle > 0)
1170                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1171
1172         if(nextMap == -1)
1173                 if(autocvar_g_maplist_selectrandom)
1174                         nextMap = MaplistMethod_Random();
1175
1176         if(nextMap == -1)
1177                 nextMap = MaplistMethod_Iterate();
1178
1179         if(nextMap == -1)
1180                 nextMap = MaplistMethod_Repeat();
1181
1182         if(nextMap >= 0)
1183         {
1184                 Map_Goto_SetFloat(nextMap);
1185                 return getmapname_stored;
1186         }
1187
1188         return "";
1189 }
1190
1191 float DoNextMapOverride(float reinit)
1192 {
1193         if(autocvar_g_campaign)
1194         {
1195                 CampaignPostIntermission();
1196                 alreadychangedlevel = TRUE;
1197                 return TRUE;
1198         }
1199         if(autocvar_quit_when_empty)
1200         {
1201                 if(player_count <= currentbots)
1202                 {
1203                         localcmd("quit\n");
1204                         alreadychangedlevel = TRUE;
1205                         return TRUE;
1206                 }
1207         }
1208         if(autocvar_quit_and_redirect != "")
1209         {
1210                 redirection_target = strzone(autocvar_quit_and_redirect);
1211                 alreadychangedlevel = TRUE;
1212                 return TRUE;
1213         }
1214         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1215         {
1216                 localcmd("restart\n");
1217                 alreadychangedlevel = TRUE;
1218                 return TRUE;
1219         }
1220         if(autocvar_nextmap != "")
1221         {
1222                 string m;
1223                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1224                 cvar_set("nextmap",m);
1225
1226                 if(!m || gametypevote)
1227                         return FALSE;
1228                 if(autocvar_sv_vote_gametype)
1229                 {
1230                         Map_Goto_SetStr(m);
1231                         return FALSE;
1232                 }
1233
1234                 if(MapInfo_CheckMap(m))
1235                 {
1236                         Map_Goto_SetStr(m);
1237                         Map_Goto(reinit);
1238                         alreadychangedlevel = TRUE;
1239                         return TRUE;
1240                 }
1241         }
1242         if(!reinit && autocvar_lastlevel)
1243         {
1244                 cvar_settemp_restore();
1245                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1246                 alreadychangedlevel = TRUE;
1247                 return TRUE;
1248         }
1249         return FALSE;
1250 }
1251
1252 void GotoNextMap(float reinit)
1253 {
1254         //string nextmap;
1255         //float n, nummaps;
1256         //string s;
1257         if (alreadychangedlevel)
1258                 return;
1259         alreadychangedlevel = TRUE;
1260
1261         string nextMap;
1262
1263         nextMap = GetNextMap();
1264         if(nextMap == "")
1265                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1266         Map_Goto(reinit);
1267 }
1268
1269
1270 /*
1271 ============
1272 IntermissionThink
1273
1274 When the player presses attack or jump, change to the next level
1275 ============
1276 */
1277 .float autoscreenshot;
1278 void IntermissionThink()
1279 {
1280         FixIntermissionClient(self);
1281
1282         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1283         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1284
1285         if( (server_screenshot || client_screenshot)
1286                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1287         {
1288                 self.autoscreenshot = -1;
1289                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1290                 return;
1291         }
1292
1293         if (time < intermission_exittime)
1294                 return;
1295
1296         if(!mapvote_initialized)
1297                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1298                         return;
1299
1300         MapVote_Start();
1301 }
1302
1303 /*
1304 ============
1305 FindIntermission
1306
1307 Returns the entity to view from
1308 ============
1309 */
1310 /*
1311 entity FindIntermission()
1312 {
1313         local   entity spot;
1314         local   float cyc;
1315
1316 // look for info_intermission first
1317         spot = find (world, classname, "info_intermission");
1318         if (spot)
1319         {       // pick a random one
1320                 cyc = random() * 4;
1321                 while (cyc > 1)
1322                 {
1323                         spot = find (spot, classname, "info_intermission");
1324                         if (!spot)
1325                                 spot = find (spot, classname, "info_intermission");
1326                         cyc = cyc - 1;
1327                 }
1328                 return spot;
1329         }
1330
1331 // then look for the start position
1332         spot = find (world, classname, "info_player_start");
1333         if (spot)
1334                 return spot;
1335
1336 // testinfo_player_start is only found in regioned levels
1337         spot = find (world, classname, "testplayerstart");
1338         if (spot)
1339                 return spot;
1340
1341 // then look for the start position
1342         spot = find (world, classname, "info_player_deathmatch");
1343         if (spot)
1344                 return spot;
1345
1346         //objerror ("FindIntermission: no spot");
1347         return world;
1348 }
1349 */
1350
1351 /*
1352 ===============================================================================
1353
1354 RULES
1355
1356 ===============================================================================
1357 */
1358
1359 void DumpStats(float final)
1360 {
1361         float file;
1362         string s;
1363         float to_console;
1364         float to_eventlog;
1365         float to_file;
1366         float i;
1367
1368         to_console = autocvar_sv_logscores_console;
1369         to_eventlog = autocvar_sv_eventlog;
1370         to_file = autocvar_sv_logscores_file;
1371
1372         if(!final)
1373         {
1374                 to_console = TRUE; // always print printstats replies
1375                 to_eventlog = FALSE; // but never print them to the event log
1376         }
1377
1378         if(to_eventlog)
1379                 if(autocvar_sv_eventlog_console)
1380                         to_console = FALSE; // otherwise we get the output twice
1381
1382         if(final)
1383                 s = ":scores:";
1384         else
1385                 s = ":status:";
1386         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1387
1388         if(to_console)
1389                 print(s, "\n");
1390         if(to_eventlog)
1391                 GameLogEcho(s);
1392
1393         file = -1;
1394         if(to_file)
1395         {
1396                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1397                 if(file == -1)
1398                         to_file = FALSE;
1399                 else
1400                         fputs(file, strcat(s, "\n"));
1401         }
1402
1403         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1404         if(to_console)
1405                 print(s, "\n");
1406         if(to_eventlog)
1407                 GameLogEcho(s);
1408         if(to_file)
1409                 fputs(file, strcat(s, "\n"));
1410
1411         FOR_EACH_CLIENT(other)
1412         {
1413                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1414                 {
1415                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1416                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1417                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1418                                 s = strcat(s, ftos(other.team), ":");
1419                         else
1420                                 s = strcat(s, "spectator:");
1421
1422                         if(to_console)
1423                                 print(s, other.netname, "\n");
1424                         if(to_eventlog)
1425                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1426                         if(to_file)
1427                                 fputs(file, strcat(s, other.netname, "\n"));
1428                 }
1429         }
1430
1431         if(teamplay)
1432         {
1433                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1434                 if(to_console)
1435                         print(s, "\n");
1436                 if(to_eventlog)
1437                         GameLogEcho(s);
1438                 if(to_file)
1439                         fputs(file, strcat(s, "\n"));
1440
1441                 for(i = 1; i < 16; ++i)
1442                 {
1443                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1444                         s = strcat(s, ":", ftos(i));
1445                         if(to_console)
1446                                 print(s, "\n");
1447                         if(to_eventlog)
1448                                 GameLogEcho(s);
1449                         if(to_file)
1450                                 fputs(file, strcat(s, "\n"));
1451                 }
1452         }
1453
1454         if(to_console)
1455                 print(":end\n");
1456         if(to_eventlog)
1457                 GameLogEcho(":end");
1458         if(to_file)
1459         {
1460                 fputs(file, ":end\n");
1461                 fclose(file);
1462         }
1463 }
1464
1465 void FixIntermissionClient(entity e)
1466 {
1467         string s;
1468         if(!e.autoscreenshot) // initial call
1469         {
1470                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1471                 e.health = -2342;
1472                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1473                 e.solid = SOLID_NOT;
1474                 e.movetype = MOVETYPE_NONE;
1475                 e.takedamage = DAMAGE_NO;
1476                 if(e.weaponentity)
1477                 {
1478                         e.weaponentity.effects = EF_NODRAW;
1479                         if (e.weaponentity.weaponentity)
1480                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1481                 }
1482                 if(IS_REAL_CLIENT(e))
1483                 {
1484                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1485                         s = autocvar_sv_intermission_cdtrack;
1486                         if(s != "")
1487                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1488                         msg_entity = e;
1489                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1490                 }
1491         }
1492 }
1493
1494 /*
1495 go to the next level for deathmatch
1496 only called if a time or frag limit has expired
1497 */
1498 void NextLevel()
1499 {
1500         gameover = TRUE;
1501
1502         intermission_running = 1;
1503
1504 // enforce a wait time before allowing changelevel
1505         if(player_count > 0)
1506                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1507         else
1508                 intermission_exittime = -1;
1509
1510         /*
1511         WriteByte (MSG_ALL, SVC_CDTRACK);
1512         WriteByte (MSG_ALL, 3);
1513         WriteByte (MSG_ALL, 3);
1514         // done in FixIntermission
1515         */
1516
1517         //pos = FindIntermission ();
1518
1519         VoteReset();
1520
1521         DumpStats(TRUE);
1522
1523         // send statistics
1524         PlayerStats_GameReport(TRUE);
1525         WeaponStats_Shutdown();
1526
1527         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1528
1529         if(autocvar_sv_eventlog)
1530                 GameLogEcho(":gameover");
1531
1532         GameLogClose();
1533
1534         FOR_EACH_PLAYER(other) {
1535                 FixIntermissionClient(other);
1536                 if(other.winning)
1537                         bprint(other.netname, " ^7wins.\n");
1538         }
1539
1540         if(autocvar_g_campaign)
1541                 CampaignPreIntermission();
1542
1543         MUTATOR_CALLHOOK(MatchEnd);
1544
1545         localcmd("\nsv_hook_gameend\n");
1546 }
1547
1548 /*
1549 ============
1550 CheckRules_Player
1551
1552 Exit deathmatch games upon conditions
1553 ============
1554 */
1555 void CheckRules_Player()
1556 {
1557         if (gameover)   // someone else quit the game already
1558                 return;
1559
1560         if(self.deadflag == DEAD_NO)
1561                 self.play_time += frametime;
1562
1563         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1564         //   (div0: and that in CheckRules_World please)
1565 }
1566
1567 float checkrules_equality;
1568 float checkrules_suddendeathwarning;
1569 float checkrules_suddendeathend;
1570 float checkrules_overtimesadded; //how many overtimes have been already added
1571
1572 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1573 const float WINNING_YES = 1; // winner found
1574 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1575 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1576
1577 float InitiateSuddenDeath()
1578 {
1579         // Check first whether normal overtimes could be added before initiating suddendeath mode
1580         // - for this timelimit_overtime needs to be >0 of course
1581         // - also check the winning condition calculated in the previous frame and only add normal overtime
1582         //   again, if at the point at which timelimit would be extended again, still no winner was found
1583         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1584         {
1585                 return 1; // need to call InitiateOvertime later
1586         }
1587         else
1588         {
1589                 if(!checkrules_suddendeathend)
1590                 {
1591                         if(autocvar_g_campaign)
1592                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1593                         else
1594                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1595                         if(g_race && !g_race_qualifying)
1596                                 race_StartCompleting();
1597                 }
1598                 return 0;
1599         }
1600 }
1601
1602 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1603 {
1604         ++checkrules_overtimesadded;
1605         //add one more overtime by simply extending the timelimit
1606         float tl;
1607         tl = autocvar_timelimit;
1608         tl += autocvar_timelimit_overtime;
1609         cvar_set("timelimit", ftos(tl));
1610
1611         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1612 }
1613
1614 float GetWinningCode(float fraglimitreached, float equality)
1615 {
1616         if(autocvar_g_campaign == 1)
1617                 if(fraglimitreached)
1618                         return WINNING_YES;
1619                 else
1620                         return WINNING_NO;
1621
1622         else
1623                 if(equality)
1624                         if(fraglimitreached)
1625                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1626                         else
1627                                 return WINNING_NEVER;
1628                 else
1629                         if(fraglimitreached)
1630                                 return WINNING_YES;
1631                         else
1632                                 return WINNING_NO;
1633 }
1634
1635 // set the .winning flag for exactly those players with a given field value
1636 void SetWinners(.float field, float value)
1637 {
1638         entity head;
1639         FOR_EACH_PLAYER(head)
1640                 head.winning = (head.field == value);
1641 }
1642
1643 // set the .winning flag for those players with a given field value
1644 void AddWinners(.float field, float value)
1645 {
1646         entity head;
1647         FOR_EACH_PLAYER(head)
1648                 if(head.field == value)
1649                         head.winning = 1;
1650 }
1651
1652 // clear the .winning flags
1653 void ClearWinners(void)
1654 {
1655         entity head;
1656         FOR_EACH_PLAYER(head)
1657                 head.winning = 0;
1658 }
1659
1660 // Onslaught winning condition:
1661 // game terminates if only one team has a working generator (or none)
1662 float WinningCondition_Onslaught()
1663 {
1664         entity head;
1665         float t1, t2, t3, t4;
1666
1667         WinningConditionHelper(); // set worldstatus
1668
1669         if(warmup_stage)
1670                 return WINNING_NO;
1671
1672         // first check if the game has ended
1673         t1 = t2 = t3 = t4 = 0;
1674         head = find(world, classname, "onslaught_generator");
1675         while (head)
1676         {
1677                 if (head.health > 0)
1678                 {
1679                         if (head.team == NUM_TEAM_1) t1 = 1;
1680                         if (head.team == NUM_TEAM_2) t2 = 1;
1681                         if (head.team == NUM_TEAM_3) t3 = 1;
1682                         if (head.team == NUM_TEAM_4) t4 = 1;
1683                 }
1684                 head = find(head, classname, "onslaught_generator");
1685         }
1686         if (t1 + t2 + t3 + t4 < 2)
1687         {
1688                 // game over, only one team remains (or none)
1689                 ClearWinners();
1690                 if (t1) SetWinners(team, NUM_TEAM_1);
1691                 if (t2) SetWinners(team, NUM_TEAM_2);
1692                 if (t3) SetWinners(team, NUM_TEAM_3);
1693                 if (t4) SetWinners(team, NUM_TEAM_4);
1694                 dprint("Have a winner, ending game.\n");
1695                 return WINNING_YES;
1696         }
1697
1698         // Two or more teams remain
1699         return WINNING_NO;
1700 }
1701
1702 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1703 // they win. Otherwise the defending team wins once the timelimit passes.
1704 void assault_new_round();
1705 float WinningCondition_Assault()
1706 {
1707         float status;
1708
1709         WinningConditionHelper(); // set worldstatus
1710
1711         status = WINNING_NO;
1712         // as the timelimit has not yet passed just assume the defending team will win
1713         if(assault_attacker_team == NUM_TEAM_1)
1714         {
1715                 SetWinners(team, NUM_TEAM_2);
1716         }
1717         else
1718         {
1719                 SetWinners(team, NUM_TEAM_1);
1720         }
1721
1722         entity ent;
1723         ent = find(world, classname, "target_assault_roundend");
1724         if(ent)
1725         {
1726                 if(ent.winning) // round end has been triggered by attacking team
1727                 {
1728                         bprint("ASSAULT: round completed...\n");
1729                         SetWinners(team, assault_attacker_team);
1730
1731                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1732
1733                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1734                         {
1735                                 status = WINNING_YES;
1736                         }
1737                         else
1738                         {
1739                                 entity oldself;
1740                                 oldself = self;
1741                                 self = ent;
1742                                 assault_new_round();
1743                                 self = oldself;
1744                         }
1745                 }
1746         }
1747
1748         return status;
1749 }
1750
1751 // LMS winning condition: game terminates if and only if there's at most one
1752 // one player who's living lives. Top two scores being equal cancels the time
1753 // limit.
1754 float WinningCondition_LMS()
1755 {
1756         entity head, head2;
1757         float have_player;
1758         float have_players;
1759         float l;
1760
1761         have_player = FALSE;
1762         have_players = FALSE;
1763         l = LMS_NewPlayerLives();
1764
1765         head = find(world, classname, "player");
1766         if(head)
1767                 have_player = TRUE;
1768         head2 = find(head, classname, "player");
1769         if(head2)
1770                 have_players = TRUE;
1771
1772         if(have_player)
1773         {
1774                 // we have at least one player
1775                 if(have_players)
1776                 {
1777                         // two or more active players - continue with the game
1778                 }
1779                 else
1780                 {
1781                         // exactly one player?
1782
1783                         ClearWinners();
1784                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1785
1786                         if(l)
1787                         {
1788                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1789                                 return WINNING_NO;
1790                         }
1791                         else
1792                         {
1793                                 // a winner!
1794                                 // and assign him his first place
1795                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1796                                 return WINNING_YES;
1797                         }
1798                 }
1799         }
1800         else
1801         {
1802                 // nobody is playing at all...
1803                 if(l)
1804                 {
1805                         // wait for players...
1806                 }
1807                 else
1808                 {
1809                         // SNAFU (maybe a draw game?)
1810                         ClearWinners();
1811                         dprint("No players, ending game.\n");
1812                         return WINNING_YES;
1813                 }
1814         }
1815
1816         // When we get here, we have at least two players who are actually LIVING,
1817         // now check if the top two players have equal score.
1818         WinningConditionHelper();
1819
1820         ClearWinners();
1821         if(WinningConditionHelper_winner)
1822                 WinningConditionHelper_winner.winning = TRUE;
1823         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1824                 return WINNING_NEVER;
1825
1826         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1827         return WINNING_NO;
1828 }
1829
1830 void ShuffleMaplist()
1831 {
1832         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1833 }
1834
1835 float leaderfrags;
1836 float WinningCondition_Scores(float limit, float leadlimit)
1837 {
1838         float limitreached;
1839
1840         // TODO make everything use THIS winning condition (except LMS)
1841         WinningConditionHelper();
1842
1843         if(teamplay)
1844         {
1845                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1846                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1847                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1848                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1849         }
1850
1851         ClearWinners();
1852         if(WinningConditionHelper_winner)
1853                 WinningConditionHelper_winner.winning = 1;
1854         if(WinningConditionHelper_winnerteam >= 0)
1855                 SetWinners(team, WinningConditionHelper_winnerteam);
1856
1857         if(WinningConditionHelper_lowerisbetter)
1858         {
1859                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1860                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1861                 limit = -limit;
1862         }
1863
1864         if(WinningConditionHelper_zeroisworst)
1865                 leadlimit = 0; // not supported in this mode
1866
1867         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1868         // these modes always score in increments of 1, thus this makes sense
1869         {
1870                 if(leaderfrags != WinningConditionHelper_topscore)
1871                 {
1872                         leaderfrags = WinningConditionHelper_topscore;
1873
1874                         if (limit)
1875                         if (leaderfrags == limit - 1)
1876                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1877                         else if (leaderfrags == limit - 2)
1878                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1879                         else if (leaderfrags == limit - 3)
1880                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1881                 }
1882         }
1883
1884         limitreached = FALSE;
1885         if(limit)
1886                 if(WinningConditionHelper_topscore >= limit)
1887                         limitreached = TRUE;
1888         if(leadlimit)
1889         {
1890                 float leadlimitreached;
1891                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1892                 if(autocvar_leadlimit_and_fraglimit)
1893                         limitreached = (limitreached && leadlimitreached);
1894                 else
1895                         limitreached = (limitreached || leadlimitreached);
1896         }
1897
1898         if(limit)
1899                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1900
1901         return GetWinningCode(
1902                 WinningConditionHelper_topscore && limitreached,
1903                 WinningConditionHelper_equality
1904         );
1905 }
1906
1907 float WinningCondition_Race(float fraglimit)
1908 {
1909         float wc;
1910         entity p;
1911         float n, c;
1912
1913         n = 0;
1914         c = 0;
1915         FOR_EACH_PLAYER(p)
1916         {
1917                 ++n;
1918                 if(p.race_completed)
1919                         ++c;
1920         }
1921         if(n && (n == c))
1922                 return WINNING_YES;
1923         wc = WinningCondition_Scores(fraglimit, 0);
1924
1925         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1926         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1927         // do NOT support equality when the laps are all raced!
1928                 return WINNING_STARTSUDDENDEATHOVERTIME;
1929         else
1930                 return WINNING_NEVER;
1931 }
1932
1933 float WinningCondition_QualifyingThenRace(float limit)
1934 {
1935         float wc;
1936         wc = WinningCondition_Scores(limit, 0);
1937
1938         // NEVER initiate overtime
1939         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1940         {
1941                 return WINNING_YES;
1942         }
1943
1944         return wc;
1945 }
1946
1947 float WinningCondition_RanOutOfSpawns()
1948 {
1949         entity head;
1950
1951         if(have_team_spawns <= 0)
1952                 return WINNING_NO;
1953
1954         if(autocvar_g_spawn_useallspawns <= 0)
1955                 return WINNING_NO;
1956
1957         if(!some_spawn_has_been_used)
1958                 return WINNING_NO;
1959
1960         team1_score = team2_score = team3_score = team4_score = 0;
1961
1962         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1963         {
1964                 if(head.team == NUM_TEAM_1)
1965                         team1_score = 1;
1966                 else if(head.team == NUM_TEAM_2)
1967                         team2_score = 1;
1968                 else if(head.team == NUM_TEAM_3)
1969                         team3_score = 1;
1970                 else if(head.team == NUM_TEAM_4)
1971                         team4_score = 1;
1972         }
1973
1974         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1975         {
1976                 if(head.team == NUM_TEAM_1)
1977                         team1_score = 1;
1978                 else if(head.team == NUM_TEAM_2)
1979                         team2_score = 1;
1980                 else if(head.team == NUM_TEAM_3)
1981                         team3_score = 1;
1982                 else if(head.team == NUM_TEAM_4)
1983                         team4_score = 1;
1984         }
1985
1986         ClearWinners();
1987         if(team1_score + team2_score + team3_score + team4_score == 0)
1988         {
1989                 checkrules_equality = TRUE;
1990                 return WINNING_YES;
1991         }
1992         else if(team1_score + team2_score + team3_score + team4_score == 1)
1993         {
1994                 float t, i;
1995                 if(team1_score)
1996                         t = NUM_TEAM_1;
1997                 else if(team2_score)
1998                         t = NUM_TEAM_2;
1999                 else if(team3_score)
2000                         t = NUM_TEAM_3;
2001                 else // if(team4_score)
2002                         t = NUM_TEAM_4;
2003                 CheckAllowedTeams(world);
2004                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2005                 {
2006                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2007                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2008                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2009                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2010                 }
2011
2012                 AddWinners(team, t);
2013                 return WINNING_YES;
2014         }
2015         else
2016                 return WINNING_NO;
2017 }
2018
2019 /*
2020 ============
2021 CheckRules_World
2022
2023 Exit deathmatch games upon conditions
2024 ============
2025 */
2026 void ReadyRestart();
2027 void CheckRules_World()
2028 {
2029         float timelimit;
2030         float fraglimit;
2031         float leadlimit;
2032
2033         VoteThink();
2034         MapVote_Think();
2035
2036         SetDefaultAlpha();
2037
2038         if (gameover)   // someone else quit the game already
2039         {
2040                 if(player_count == 0) // Nobody there? Then let's go to the next map
2041                         MapVote_Start();
2042                         // this will actually check the player count in the next frame
2043                         // again, but this shouldn't hurt
2044                 return;
2045         }
2046
2047         timelimit = autocvar_timelimit * 60;
2048         fraglimit = autocvar_fraglimit;
2049         leadlimit = autocvar_leadlimit;
2050
2051         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2052         {
2053                 if(timelimit > 0)
2054                         timelimit = 0; // timelimit is not made for warmup
2055                 if(fraglimit > 0)
2056                         fraglimit = 0; // no fraglimit for now
2057                 leadlimit = 0; // no leadlimit for now
2058         }
2059
2060         if(timelimit > 0)
2061         {
2062                 timelimit += game_starttime;
2063         }
2064         else if (timelimit < 0)
2065         {
2066                 // endmatch
2067                 NextLevel();
2068                 return;
2069         }
2070
2071         if(g_onslaught)
2072                 timelimit = 0; // ONS has its own overtime rule
2073
2074         float wantovertime;
2075         wantovertime = 0;
2076
2077         if(timelimit > game_starttime)
2078                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2079         else
2080                 game_completion_ratio = 0;
2081
2082         if(checkrules_suddendeathend)
2083         {
2084                 if(!checkrules_suddendeathwarning)
2085                 {
2086                         checkrules_suddendeathwarning = TRUE;
2087                         if(g_race && !g_race_qualifying)
2088                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2089                         else
2090                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2091                 }
2092         }
2093         else
2094         {
2095                 if (timelimit && time >= timelimit)
2096                 {
2097                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2098                         {
2099                                 float totalplayers;
2100                                 float playerswithlaps;
2101                                 float readyplayers;
2102                                 entity head;
2103                                 totalplayers = playerswithlaps = readyplayers = 0;
2104                                 FOR_EACH_PLAYER(head)
2105                                 {
2106                                         ++totalplayers;
2107                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2108                                                 ++playerswithlaps;
2109                                         if(head.ready)
2110                                                 ++readyplayers;
2111                                 }
2112
2113                                 // at least 2 of the players have completed a lap: start the RACE
2114                                 // otherwise, the players should end the qualifying on their own
2115                                 if(readyplayers || playerswithlaps >= 2)
2116                                 {
2117                                         checkrules_suddendeathend = 0;
2118                                         ReadyRestart(); // go to race
2119                                         return;
2120                                 }
2121                                 else
2122                                         wantovertime |= InitiateSuddenDeath();
2123                         }
2124                         else
2125                                 wantovertime |= InitiateSuddenDeath();
2126                 }
2127         }
2128
2129         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2130         {
2131                 NextLevel();
2132                 return;
2133         }
2134
2135         float checkrules_status;
2136         checkrules_status = WinningCondition_RanOutOfSpawns();
2137         if(checkrules_status == WINNING_YES)
2138         {
2139                 bprint("Hey! Someone ran out of spawns!\n");
2140         }
2141         else if(g_race && !g_race_qualifying && timelimit >= 0)
2142         {
2143                 checkrules_status = WinningCondition_Race(fraglimit);
2144                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2145         }
2146         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2147         {
2148                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2149                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2150         }
2151         else if(g_assault)
2152         {
2153                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2154         }
2155         else if(g_lms)
2156         {
2157                 checkrules_status = WinningCondition_LMS();
2158         }
2159         else if (g_onslaught)
2160         {
2161                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2162         }
2163         else
2164         {
2165                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2166                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2167         }
2168
2169         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2170         {
2171                 checkrules_status = WINNING_NEVER;
2172                 checkrules_overtimesadded = -1;
2173                 wantovertime |= InitiateSuddenDeath();
2174         }
2175
2176         if(checkrules_status == WINNING_NEVER)
2177                 // equality cases! Nobody wins if the overtime ends in a draw.
2178                 ClearWinners();
2179
2180         if(wantovertime)
2181         {
2182                 if(checkrules_status == WINNING_NEVER)
2183                         InitiateOvertime();
2184                 else
2185                         checkrules_status = WINNING_YES;
2186         }
2187
2188         if(checkrules_suddendeathend)
2189                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2190                         checkrules_status = WINNING_YES;
2191
2192         if(checkrules_status == WINNING_YES)
2193         {
2194                 //print("WINNING\n");
2195                 NextLevel();
2196         }
2197 }
2198
2199 string GotoMap(string m)
2200 {
2201         m = GameTypeVote_MapInfo_FixName(m);
2202         if (!m)
2203                 return "The map you suggested is not available on this server.";
2204         if (!autocvar_sv_vote_gametype)
2205         if(!MapInfo_CheckMap(m))
2206                 return "The map you suggested does not support the current game mode.";
2207         cvar_set("nextmap", m);
2208         cvar_set("timelimit", "-1");
2209         if(mapvote_initialized || alreadychangedlevel)
2210         {
2211                 if(DoNextMapOverride(0))
2212                         return "Map switch initiated.";
2213                 else
2214                         return "Hm... no. For some reason I like THIS map more.";
2215         }
2216         else
2217                 return "Map switch will happen after scoreboard.";
2218 }
2219
2220
2221 void EndFrame()
2222 {
2223         anticheat_endframe();
2224
2225         float altime;
2226         FOR_EACH_REALCLIENT(self)
2227         {
2228                 entity e = IS_SPEC(self) ? self.enemy : self;
2229                 if(e.typehitsound)
2230                         self.typehit_time = time;
2231                 else if(e.damage_dealt)
2232                 {
2233                         self.hit_time = time;
2234                         self.damage_dealt_total += ceil(e.damage_dealt);
2235                 }
2236         }
2237         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2238         // add 1 frametime because after this, engine SV_Physics
2239         // increases time by a frametime and then networks the frame
2240         // add another frametime because client shows everything with
2241         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2242         // needed!
2243         FOR_EACH_CLIENT(self)
2244         {
2245                 self.typehitsound = FALSE;
2246                 self.damage_dealt = 0;
2247                 antilag_record(self, altime);
2248         }
2249         FOR_EACH_MONSTER(self)
2250                 antilag_record(self, altime);
2251 }
2252
2253
2254 /*
2255  * RedirectionThink:
2256  * returns TRUE if redirecting
2257  */
2258 float redirection_timeout;
2259 float redirection_nextthink;
2260 float RedirectionThink()
2261 {
2262         float clients_found;
2263
2264         if(redirection_target == "")
2265                 return FALSE;
2266
2267         if(!redirection_timeout)
2268         {
2269                 cvar_set("sv_public", "-2");
2270                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2271                 if(redirection_target == "self")
2272                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2273                 else
2274                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2275         }
2276
2277         if(time < redirection_nextthink)
2278                 return TRUE;
2279
2280         redirection_nextthink = time + 1;
2281
2282         clients_found = 0;
2283         FOR_EACH_REALCLIENT(self)
2284         {
2285                 // TODO add timer
2286                 print("Redirecting: sending connect command to ", self.netname, "\n");
2287                 if(redirection_target == "self")
2288                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2289                 else
2290                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2291                 ++clients_found;
2292         }
2293
2294         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2295
2296         if(time > redirection_timeout || clients_found == 0)
2297                 localcmd("\nwait; wait; wait; quit\n");
2298
2299         return TRUE;
2300 }
2301
2302 void TargetMusic_RestoreGame();
2303 void RestoreGame()
2304 {
2305         // Loaded from a save game
2306         // some things then break, so let's work around them...
2307
2308         // Progs DB (capture records)
2309         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2310
2311         // Mapinfo
2312         MapInfo_Shutdown();
2313         MapInfo_Enumerate();
2314         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2315         WeaponStats_Init();
2316
2317         TargetMusic_RestoreGame();
2318 }
2319
2320 void Shutdown()
2321 {
2322         gameover = 2;
2323
2324         if(world_initialized > 0)
2325         {
2326                 world_initialized = 0;
2327                 print("Saving persistent data...\n");
2328                 Ban_SaveBans();
2329
2330                 // playerstats with unfinished match
2331                 PlayerStats_GameReport(FALSE);
2332
2333                 if(!cheatcount_total)
2334                 {
2335                         if(autocvar_sv_db_saveasdump)
2336                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2337                         else
2338                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2339                 }
2340                 if(autocvar_developer)
2341                 {
2342                         if(autocvar_sv_db_saveasdump)
2343                                 db_dump(TemporaryDB, "server-temp.db");
2344                         else
2345                                 db_save(TemporaryDB, "server-temp.db");
2346                 }
2347                 CheatShutdown(); // must be after cheatcount check
2348                 db_close(ServerProgsDB);
2349                 db_close(TemporaryDB);
2350                 print("done!\n");
2351                 // tell the bot system the game is ending now
2352                 bot_endgame();
2353
2354                 WeaponStats_Shutdown();
2355                 MapInfo_Shutdown();
2356         }
2357         else if(world_initialized == 0)
2358         {
2359                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2360         }
2361 }