qcsrc/server/main.qc

   1 #include "main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "hook.qh"
   5 #include "damage.qh"
   6 #include "world.qh"
   7 #include "spawnpoints.qh"
   8 #include <server/gamelog.qh>
   9
  10 #include "bot/api.qh"
  11
  12 #include "command/common.qh"
  13
  14 #include <server/mutators/_mod.qh>
  15 #include "weapons/csqcprojectile.qh"
  16 #include <server/weapons/common.qh>
  17 #include <server/compat/quake3.qh>
  18
  19 #include "../common/constants.qh"
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/debug.qh"
  22 #include "../common/mapinfo.qh"
  23 #include "../common/util.qh"
  24
  25 #include "../common/vehicles/all.qh"
  26 #include <common/monsters/sv_monsters.qh>
  27 #include <common/weapons/_all.qh>
  28
  29 #include "../lib/csqcmodel/sv_model.qh"
  30
  31 #include "../lib/warpzone/common.qh"
  32 #include "../lib/warpzone/server.qh"
  33
  34 void CreatureFrame_hotliquids(entity this)
  35 {
  36         if (this.contents_damagetime >= time)
  37         {
  38                 return;
  39         }
  40
  41         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  42
  43         if (this.flags & FL_PROJECTILE)
  44         {
  45                 if (this.watertype == CONTENT_LAVA)
  46                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  47                 else if (this.watertype == CONTENT_SLIME)
  48                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  49         }
  50         else
  51         {
  52                 if (STAT(FROZEN, this))
  53                 {
  54                         if (this.watertype == CONTENT_LAVA)
  55                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  56                         else if (this.watertype == CONTENT_SLIME)
  57                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  58                 }
  59                 else if (this.watertype == CONTENT_LAVA)
  60                 {
  61                         if (this.watersound_finished < time)
  62                         {
  63                                 this.watersound_finished = time + 0.5;
  64                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  65                         }
  66                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  67                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  68                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  69                 }
  70                 else if (this.watertype == CONTENT_SLIME)
  71                 {
  72                         if (this.watersound_finished < time)
  73                         {
  74                                 this.watersound_finished = time + 0.5;
  75                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  76                         }
  77                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  78                 }
  79         }
  80 }
  81
  82 void CreatureFrame_Liquids(entity this)
  83 {
  84         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  85         {
  86                 if (!(this.flags & FL_INWATER))
  87                 {
  88                         this.flags |= FL_INWATER;
  89                         this.contents_damagetime = 0;
  90                 }
  91
  92                 CreatureFrame_hotliquids(this);
  93         }
  94         else
  95         {
  96                 if (this.flags & FL_INWATER)
  97                 {
  98                         // play leave water sound
  99                         this.flags &= ~FL_INWATER;
 100                         this.contents_damagetime = 0;
 101                 }
 102         }
 103 }
 104
 105 void CreatureFrame_FallDamage(entity this)
 106 {
 107         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 108                 return; // vehicles and projectiles don't receive fall damage
 109         if(!(this.velocity || this.oldvelocity))
 110                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 111
 112         // check for falling damage
 113         bool have_hook = false;
 114         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 115         {
 116             .entity weaponentity = weaponentities[slot];
 117             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 118             {
 119                 have_hook = true;
 120                 break;
 121             }
 122         }
 123         if(!have_hook)
 124         {
 125                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 126                 if(autocvar_g_balance_falldamage_onlyvertical)
 127                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 128                 else
 129                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 130                 if (IS_DEAD(this))
 131                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 132                 else
 133                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 134                 if (dm > 0)
 135                 {
 136                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 137                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 138                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 139                 }
 140         }
 141
 142         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 143                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 144 }
 145
 146 void CreatureFrame_All()
 147 {
 148         if(game_stopped || time < game_starttime)
 149                 return;
 150
 151         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 152         {
 153                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 154                 CreatureFrame_Liquids(it);
 155                 CreatureFrame_FallDamage(it);
 156                 it.oldvelocity = it.velocity;
 157         });
 158 }
 159
 160 void Pause_TryPause(bool ispaused)
 161 {
 162         int n = 0;
 163         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 164                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 165                 ++n;
 166         });
 167         if (!n) return;
 168         setpause(ispaused);
 169 }
 170
 171 void SV_PausedTic(float elapsedtime)
 172 {
 173         if (!server_is_dedicated) Pause_TryPause(false);
 174 }
 175
 176 void dedicated_print(string input)
 177 {
 178         if (server_is_dedicated) print(input);
 179 }
 180
 181 /*
 182 =============
 183 StartFrame
 184
 185 Called before each frame by the server
 186 =============
 187 */
 188
 189 bool game_delay_last;
 190
 191 bool autocvar_sv_autopause = false;
 192 void systems_update();
 193 void sys_phys_update(entity this, float dt);
 194 void StartFrame()
 195 {
 196     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 197     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 198     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 199
 200         execute_next_frame();
 201         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 202
 203         delete_fn = remove_unsafely; // not during spawning!
 204         serverprevtime = servertime;
 205         servertime = time;
 206         serverframetime = frametime;
 207
 208 #ifdef PROFILING
 209         if(time > client_cefc_accumulatortime + 1)
 210         {
 211                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 212                 int c_seeing = 0;
 213                 int c_seen = 0;
 214                 FOREACH_CLIENT(true, {
 215                         if(IS_REAL_CLIENT(it))
 216                                 ++c_seeing;
 217                         if(IS_PLAYER(it))
 218                                 ++c_seen;
 219                 });
 220                 LOG_INFO(
 221                     "CEFC time: ", ftos(t * 1000), "ms; ",
 222             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 223             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 224         );
 225                 client_cefc_accumulatortime = time;
 226                 client_cefc_accumulator = 0;
 227         }
 228 #endif
 229
 230         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 231
 232         if (RedirectionThink()) return;
 233
 234         UncustomizeEntitiesRun();
 235         InitializeEntitiesRun();
 236
 237         WarpZone_StartFrame();
 238
 239         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 240         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 241
 242         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 243                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 244
 245         // detect when the pre-game countdown (if any) has ended and the game has started
 246         bool game_delay = (time < game_starttime);
 247         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 248                 GameLogEcho(":startdelay_ended");
 249         game_delay_last = game_delay;
 250
 251         CreatureFrame_All();
 252         CheckRules_World();
 253
 254         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 255                 ReadyRestart();
 256                 return;
 257         }
 258
 259         bot_serverframe();
 260         anticheat_startframe();
 261         MUTATOR_CALLHOOK(SV_StartFrame);
 262
 263         GlobalStats_updateglobal();
 264     FOREACH_CLIENT(true, GlobalStats_update(it));
 265     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 266 }
 267
 268 .vector originjitter;
 269 .vector anglesjitter;
 270 .float anglejitter;
 271 .string gametypefilter;
 272 .string cvarfilter;
 273
 274 /**
 275  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 276  * +: all must match. this is the default
 277  * -: one must NOT match
 278  *
 279  * var>x
 280  * var<x
 281  * var>=x
 282  * var<=x
 283  * var==x
 284  * var!=x
 285  * var===x
 286  * var!==x
 287  */
 288 bool expr_evaluate(string s)
 289 {
 290     bool ret = false;
 291     if (str2chr(s, 0) == '+') {
 292         s = substring(s, 1, -1);
 293     } else if (str2chr(s, 0) == '-') {
 294         ret = true;
 295         s = substring(s, 1, -1);
 296     }
 297     bool expr_fail = false;
 298     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 299         int o;
 300         string k, v;
 301         s = argv(i);
 302         #define X(expr) \
 303             if (expr) \
 304                 continue; \
 305             expr_fail = true; \
 306             break;
 307
 308         #define BINOP(op, len, expr) \
 309             if ((o = strstrofs(s, op, 0)) >= 0) { \
 310                 k = substring(s, 0, o); \
 311                 v = substring(s, o + len, -1); \
 312                 X(expr); \
 313             }
 314         BINOP(">=", 2, cvar(k) >= stof(v));
 315         BINOP("<=", 2, cvar(k) <= stof(v));
 316         BINOP(">",  1, cvar(k) >  stof(v));
 317         BINOP("<",  1, cvar(k) <  stof(v));
 318         BINOP("==", 2, cvar(k) == stof(v));
 319         BINOP("!=", 2, cvar(k) != stof(v));
 320         BINOP("===", 3, cvar_string(k) == v);
 321         BINOP("!==", 3, cvar_string(k) != v);
 322         {
 323             k = s;
 324             bool b = true;
 325             if (str2chr(k, 0) == '!') {
 326                 k = substring(s, 1, -1);
 327                 b = false;
 328             }
 329             float f = stof(k);
 330             bool isnum = ftos(f) == k;
 331             X(boolean(isnum ? f : cvar(k)) == b);
 332         }
 333         #undef BINOP
 334         #undef X
 335     }
 336     if (!expr_fail) {
 337         ret = !ret;
 338     }
 339     // now ret is true if we want to keep the item, and false if we want to get rid of it
 340     return ret;
 341 }
 342
 343 void SV_OnEntityPreSpawnFunction(entity this)
 344 {
 345         if (this)
 346         if (this.gametypefilter != "")
 347         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 348         {
 349                 delete(this);
 350                 return;
 351         }
 352         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 353                 delete(this);
 354                 return;
 355         }
 356
 357         if (DoesQ3ARemoveThisEntity(this)) {
 358                 delete(this);
 359                 return;
 360         }
 361
 362         set_movetype(this, this.movetype);
 363
 364         if (this.monster_attack) {
 365                 IL_PUSH(g_monster_targets, this);
 366     }
 367
 368         // support special -1 and -2 angle from radiant
 369         if (this.angles == '0 -1 0') {
 370                 this.angles = '-90 0 0';
 371         } else if (this.angles == '0 -2 0') {
 372                 this.angles = '+90 0 0';
 373     }
 374
 375     #define X(out, in) MACRO_BEGIN \
 376         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 377     MACRO_END
 378     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 379     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 380     X(this.angles.y, this.anglejitter);
 381     #undef X
 382
 383         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 384                 delete(this);
 385                 return;
 386         }
 387 }
 388
 389 void WarpZone_PostInitialize_Callback()
 390 {
 391         // create waypoint links for warpzones
 392         entity tracetest_ent = spawn();
 393         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 394         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 395         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 396         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 397                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 398         delete(tracetest_ent);
 399 }
 400
 401 /*
 402 ==================
 403 main
 404
 405 unused but required by the engine
 406 ==================
 407 */
 408 void main ()
 409 {
 410
 411 }