qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239     have_team_spawns_forteam[self.team] = 1;
 240
 241     if (autocvar_r_showbboxes)
 242     {
 243         // show where spawnpoints point at too
 244         makevectors(self.angles);
 245         entity e;
 246         e = spawn();
 247         e.classname = "info_player_foo";
 248         setorigin(e, self.origin + v_forward * 24);
 249         setsize(e, '-8 -8 -8', '8 8 8');
 250         e.solid = SOLID_TRIGGER;
 251     }
 252 }
 253
 254 #define strstr strstrofs
 255 /*
 256 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 257 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 258 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 259 // BE CONSTANT OR strzoneD!
 260 float strstr(string haystack, string needle, float offset)
 261 {
 262         float len, endpos;
 263         string found;
 264         len = strlen(needle);
 265         endpos = strlen(haystack) - len;
 266         while(offset <= endpos)
 267         {
 268                 found = substring(haystack, offset, len);
 269                 if(found == needle)
 270                         return offset;
 271                 offset = offset + 1;
 272         }
 273         return -1;
 274 }
 275 */
 276
 277 float NUM_NEAREST_ENTITIES = 4;
 278 entity nearest_entity[NUM_NEAREST_ENTITIES];
 279 float nearest_length[NUM_NEAREST_ENTITIES];
 280 entity findnearest(vector point, .string field, string value, vector axismod)
 281 {
 282     entity localhead;
 283     float i;
 284     float j;
 285     float len;
 286     vector dist;
 287
 288     float num_nearest;
 289     num_nearest = 0;
 290
 291     localhead = find(world, field, value);
 292     while (localhead)
 293     {
 294         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 295             dist = localhead.oldorigin;
 296         else
 297             dist = localhead.origin;
 298         dist = dist - point;
 299         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 300         len = vlen(dist);
 301
 302         for (i = 0; i < num_nearest; ++i)
 303         {
 304             if (len < nearest_length[i])
 305                 break;
 306         }
 307
 308         // now i tells us where to insert at
 309         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 310         if (i < NUM_NEAREST_ENTITIES)
 311         {
 312             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 313             {
 314                 nearest_length[j + 1] = nearest_length[j];
 315                 nearest_entity[j + 1] = nearest_entity[j];
 316             }
 317             nearest_length[i] = len;
 318             nearest_entity[i] = localhead;
 319             if (num_nearest < NUM_NEAREST_ENTITIES)
 320                 num_nearest = num_nearest + 1;
 321         }
 322
 323         localhead = find(localhead, field, value);
 324     }
 325
 326     // now use the first one from our list that we can see
 327     for (i = 0; i < num_nearest; ++i)
 328     {
 329         traceline(point, nearest_entity[i].origin, TRUE, world);
 330         if (trace_fraction == 1)
 331         {
 332             if (i != 0)
 333             {
 334                 dprint("Nearest point (");
 335                 dprint(nearest_entity[0].netname);
 336                 dprint(") is not visible, using a visible one.\n");
 337             }
 338             return nearest_entity[i];
 339         }
 340     }
 341
 342     if (num_nearest == 0)
 343         return world;
 344
 345     dprint("Not seeing any location point, using nearest as fallback.\n");
 346     /* DEBUGGING CODE:
 347     dprint("Candidates were: ");
 348     for(j = 0; j < num_nearest; ++j)
 349     {
 350         if(j != 0)
 351                 dprint(", ");
 352         dprint(nearest_entity[j].netname);
 353     }
 354     dprint("\n");
 355     */
 356
 357     return nearest_entity[0];
 358 }
 359
 360 void spawnfunc_target_location()
 361 {
 362     self.classname = "target_location";
 363     // location name in netname
 364     // eventually support: count, teamgame selectors, line of sight?
 365 };
 366
 367 void spawnfunc_info_location()
 368 {
 369     self.classname = "target_location";
 370     self.message = self.netname;
 371 };
 372
 373 string NearestLocation(vector p)
 374 {
 375     entity loc;
 376     string ret;
 377     ret = "somewhere";
 378     loc = findnearest(p, classname, "target_location", '1 1 1');
 379     if (loc)
 380     {
 381         ret = loc.message;
 382     }
 383     else
 384     {
 385         loc = findnearest(p, target, "###item###", '1 1 4');
 386         if (loc)
 387             ret = loc.netname;
 388     }
 389     return ret;
 390 }
 391
 392 string formatmessage(string msg)
 393 {
 394         float p, p1, p2;
 395         float n;
 396         vector cursor;
 397         entity cursor_ent;
 398         string escape;
 399         string replacement;
 400         p = 0;
 401         n = 7;
 402
 403         WarpZone_crosshair_trace(self);
 404         cursor = trace_endpos;
 405         cursor_ent = trace_ent;
 406
 407         while (1) {
 408                 if (n < 1)
 409                         break; // too many replacements
 410
 411                 n = n - 1;
 412                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 413                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 414
 415                 if (p1 < 0)
 416                         p1 = p2;
 417
 418                 if (p2 < 0)
 419                         p2 = p1;
 420
 421                 p = min(p1, p2);
 422
 423                 if (p < 0)
 424                         break;
 425
 426                 replacement = substring(msg, p, 2);
 427                 escape = substring(msg, p + 1, 1);
 428
 429                 if (escape == "%")
 430                         replacement = "%";
 431                 else if (escape == "\\")
 432                         replacement = "\\";
 433                 else if (escape == "n")
 434                         replacement = "\n";
 435                 else if (escape == "a")
 436                         replacement = ftos(floor(self.armorvalue));
 437                 else if (escape == "h")
 438                         replacement = ftos(floor(self.health));
 439                 else if (escape == "l")
 440                         replacement = NearestLocation(self.origin);
 441                 else if (escape == "y")
 442                         replacement = NearestLocation(cursor);
 443                 else if (escape == "d")
 444                         replacement = NearestLocation(self.death_origin);
 445                 else if (escape == "w") {
 446                         float wep;
 447                         wep = self.weapon;
 448                         if (!wep)
 449                                 wep = self.switchweapon;
 450                         if (!wep)
 451                                 wep = self.cnt;
 452                         replacement = W_Name(wep);
 453                 } else if (escape == "W") {
 454                         if (self.items & IT_SHELLS) replacement = "shells";
 455                         else if (self.items & IT_NAILS) replacement = "bullets";
 456                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 457                         else if (self.items & IT_CELLS) replacement = "cells";
 458                         else replacement = "batteries"; // ;)
 459                 } else if (escape == "x") {
 460                         replacement = cursor_ent.netname;
 461                         if (!replacement || !cursor_ent)
 462                                 replacement = "nothing";
 463                 } else if (escape == "s")
 464                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 465                 else if (escape == "S")
 466                         replacement = ftos(vlen(self.velocity));
 467
 468                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 469                 p = p + strlen(replacement);
 470         }
 471         return msg;
 472 }
 473
 474 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 475         return (value == 0) ? FALSE : TRUE;
 476 }
 477
 478 /*
 479 =============
 480 GetCvars
 481 =============
 482 Called with:
 483   0:  sends the request
 484   >0: receives a cvar from name=argv(f) value=argv(f+1)
 485 */
 486 void GetCvars_handleString(string thisname, float f, .string field, string name)
 487 {
 488         if (f < 0)
 489         {
 490                 if (self.field)
 491                         strunzone(self.field);
 492                 self.field = string_null;
 493         }
 494         else if (f > 0)
 495         {
 496                 if (thisname == name)
 497                 {
 498                         if (self.field)
 499                                 strunzone(self.field);
 500                         self.field = strzone(argv(f + 1));
 501                 }
 502         }
 503         else
 504                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 505 }
 506 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 507 {
 508         GetCvars_handleString(thisname, f, field, name);
 509         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 510                 if (thisname == name)
 511                 {
 512                         string s;
 513                         s = func(strcat1(self.field));
 514                         if (s != self.field)
 515                         {
 516                                 strunzone(self.field);
 517                                 self.field = strzone(s);
 518                         }
 519                 }
 520 }
 521 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 522 {
 523         if (f < 0)
 524         {
 525         }
 526         else if (f > 0)
 527         {
 528                 if (thisname == name)
 529                         self.field = stof(argv(f + 1));
 530         }
 531         else
 532                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 533 }
 534 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 535 {
 536         if (f < 0)
 537         {
 538         }
 539         else if (f > 0)
 540         {
 541                 if (thisname == name)
 542                 {
 543                         if(!self.field)
 544                         {
 545                                 self.field = stof(argv(f + 1));
 546                                 if(!self.field)
 547                                         self.field = -1;
 548                         }
 549                 }
 550         }
 551         else
 552         {
 553                 if(!self.field)
 554                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 555         }
 556 }
 557 float w_getbestweapon(entity e);
 558 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 559 {
 560         string o;
 561         o = W_FixWeaponOrder_ForceComplete(wo);
 562         if(self.weaponorder_byimpulse)
 563         {
 564                 strunzone(self.weaponorder_byimpulse);
 565                 self.weaponorder_byimpulse = string_null;
 566         }
 567         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 568         return o;
 569 }
 570 void GetCvars(float f)
 571 {
 572         string s;
 573
 574         if (f > 0)
 575                 s = strcat1(argv(f));
 576
 577         get_cvars_f = f;
 578         get_cvars_s = s;
 579         MUTATOR_CALLHOOK(GetCvars);
 580         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 581         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 582         GetCvars_handleFloat(s, f, cvar_hud_panel_centerprint_time, "hud_panel_centerprint_time");
 583         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 584         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 585         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 586         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 587         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 588         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 589         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 597         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 598         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 599         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 600         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 601         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 602         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 603
 604         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 605         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 606
 607 #ifdef ALLOW_FORCEMODELS
 608         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 609         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 610 #endif
 611         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 612         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 613         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 614
 615         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 616         if (f > 0)
 617         {
 618                 if (s == "cl_weaponpriority")
 619                         self.switchweapon = w_getbestweapon(self);
 620                 if (s == "cl_allow_uidtracking")
 621                         PlayerStats_AddPlayer(self);
 622         }
 623 }
 624
 625 void backtrace(string msg)
 626 {
 627     float dev, war;
 628     dev = autocvar_developer;
 629     war = autocvar_prvm_backtraceforwarnings;
 630     cvar_set("developer", "1");
 631     cvar_set("prvm_backtraceforwarnings", "1");
 632     print("\n");
 633     print("--- CUT HERE ---\nWARNING: ");
 634     print(msg);
 635     print("\n");
 636     remove(world); // isn't there any better way to cause a backtrace?
 637     print("\n--- CUT UNTIL HERE ---\n");
 638     cvar_set("developer", ftos(dev));
 639     cvar_set("prvm_backtraceforwarnings", ftos(war));
 640 }
 641
 642 string Team_ColorCode(float teamid)
 643 {
 644     if (teamid == COLOR_TEAM1)
 645         return "^1";
 646     else if (teamid == COLOR_TEAM2)
 647         return "^4";
 648     else if (teamid == COLOR_TEAM3)
 649         return "^3";
 650     else if (teamid == COLOR_TEAM4)
 651         return "^6";
 652     else
 653         return "^7";
 654 }
 655
 656 string Team_ColorName(float t)
 657 {
 658     // fixme: Search for team entities and get their .netname's!
 659     if (t == COLOR_TEAM1)
 660         return "Red";
 661     if (t == COLOR_TEAM2)
 662         return "Blue";
 663     if (t == COLOR_TEAM3)
 664         return "Yellow";
 665     if (t == COLOR_TEAM4)
 666         return "Pink";
 667     return "Neutral";
 668 }
 669
 670 string Team_ColorNameLowerCase(float t)
 671 {
 672     // fixme: Search for team entities and get their .netname's!
 673     if (t == COLOR_TEAM1)
 674         return "red";
 675     if (t == COLOR_TEAM2)
 676         return "blue";
 677     if (t == COLOR_TEAM3)
 678         return "yellow";
 679     if (t == COLOR_TEAM4)
 680         return "pink";
 681     return "neutral";
 682 }
 683
 684 float ColourToNumber(string team_colour)
 685 {
 686         if (team_colour == "red")
 687                 return COLOR_TEAM1;
 688
 689         if (team_colour == "blue")
 690                 return COLOR_TEAM2;
 691
 692         if (team_colour == "yellow")
 693                 return COLOR_TEAM3;
 694
 695         if (team_colour == "pink")
 696                 return COLOR_TEAM4;
 697
 698         if (team_colour == "auto")
 699                 return 0;
 700
 701         return -1;
 702 }
 703
 704 float NumberToTeamNumber(float number)
 705 {
 706         if (number == 1)
 707                 return COLOR_TEAM1;
 708
 709         if (number == 2)
 710                 return COLOR_TEAM2;
 711
 712         if (number == 3)
 713                 return COLOR_TEAM3;
 714
 715         if (number == 4)
 716                 return COLOR_TEAM4;
 717
 718         return -1;
 719 }
 720
 721 void Send_CSQC_Centerprint_Generic(entity e, float id, string s1, float duration, float countdown_num);
 722 void centerprint(entity e, string s)
 723 {
 724         Send_CSQC_Centerprint_Generic(e, 0, s, 0, 0);
 725 }
 726
 727 // decolorizes and team colors the player name when needed
 728 string playername(entity p)
 729 {
 730     string t;
 731     if (teamplay && !intermission_running && p.classname == "player")
 732     {
 733         t = Team_ColorCode(p.team);
 734         return strcat(t, strdecolorize(p.netname));
 735     }
 736     else
 737         return p.netname;
 738 }
 739
 740 vector randompos(vector m1, vector m2)
 741 {
 742     local vector v;
 743     m2 = m2 - m1;
 744     v_x = m2_x * random() + m1_x;
 745     v_y = m2_y * random() + m1_y;
 746     v_z = m2_z * random() + m1_z;
 747     return  v;
 748 };
 749
 750 //#NO AUTOCVARS START
 751
 752 float g_pickup_shells;
 753 float g_pickup_shells_max;
 754 float g_pickup_nails;
 755 float g_pickup_nails_max;
 756 float g_pickup_rockets;
 757 float g_pickup_rockets_max;
 758 float g_pickup_cells;
 759 float g_pickup_cells_max;
 760 float g_pickup_fuel;
 761 float g_pickup_fuel_jetpack;
 762 float g_pickup_fuel_max;
 763 float g_pickup_armorsmall;
 764 float g_pickup_armorsmall_max;
 765 float g_pickup_armorsmall_anyway;
 766 float g_pickup_armormedium;
 767 float g_pickup_armormedium_max;
 768 float g_pickup_armormedium_anyway;
 769 float g_pickup_armorbig;
 770 float g_pickup_armorbig_max;
 771 float g_pickup_armorbig_anyway;
 772 float g_pickup_armorlarge;
 773 float g_pickup_armorlarge_max;
 774 float g_pickup_armorlarge_anyway;
 775 float g_pickup_healthsmall;
 776 float g_pickup_healthsmall_max;
 777 float g_pickup_healthsmall_anyway;
 778 float g_pickup_healthmedium;
 779 float g_pickup_healthmedium_max;
 780 float g_pickup_healthmedium_anyway;
 781 float g_pickup_healthlarge;
 782 float g_pickup_healthlarge_max;
 783 float g_pickup_healthlarge_anyway;
 784 float g_pickup_healthmega;
 785 float g_pickup_healthmega_max;
 786 float g_pickup_healthmega_anyway;
 787 float g_pickup_ammo_anyway;
 788 float g_pickup_weapons_anyway;
 789 float g_weaponarena;
 790 float g_weaponarena_random;
 791 float g_weaponarena_random_with_laser;
 792 string g_weaponarena_list;
 793 float g_weaponspeedfactor;
 794 float g_weaponratefactor;
 795 float g_weapondamagefactor;
 796 float g_weaponforcefactor;
 797 float g_weaponspreadfactor;
 798
 799 float start_weapons;
 800 float start_items;
 801 float start_ammo_shells;
 802 float start_ammo_nails;
 803 float start_ammo_rockets;
 804 float start_ammo_cells;
 805 float start_ammo_fuel;
 806 float start_health;
 807 float start_armorvalue;
 808 float warmup_start_weapons;
 809 float warmup_start_ammo_shells;
 810 float warmup_start_ammo_nails;
 811 float warmup_start_ammo_rockets;
 812 float warmup_start_ammo_cells;
 813 float warmup_start_ammo_fuel;
 814 float warmup_start_health;
 815 float warmup_start_armorvalue;
 816 float g_weapon_stay;
 817 float g_ghost_items;
 818
 819 entity get_weaponinfo(float w);
 820
 821 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 822 {
 823         var float i = weaponinfo.weapon;
 824
 825         if (!i)
 826                 return 0;
 827
 828         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 829
 830         if (t < 0) // "default" weapon selection
 831         {
 832                 if (g_lms || g_ca || allguns)
 833                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 834                 else if(t < -1)
 835                         t = 0;
 836                 else if (g_cts)
 837                         t = (i == WEP_SHOTGUN);
 838                 else if (g_nexball)
 839                         t = 0; // weapon is set a few lines later
 840                 else
 841                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 842                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 843                         t |= (i == WEP_HOOK);
 844         }
 845
 846         // we cannot disable porto in Nexball, we must force it
 847         if(g_nexball && i == WEP_PORTO)
 848                 t = 1;
 849
 850         return t;
 851 }
 852
 853 void readplayerstartcvars()
 854 {
 855         entity e;
 856         float i, j, t;
 857         string s;
 858
 859         // initialize starting values for players
 860         start_weapons = 0;
 861         start_items = 0;
 862         start_ammo_shells = 0;
 863         start_ammo_nails = 0;
 864         start_ammo_rockets = 0;
 865         start_ammo_cells = 0;
 866         start_health = cvar("g_balance_health_start");
 867         start_armorvalue = cvar("g_balance_armor_start");
 868
 869         g_weaponarena = 0;
 870         s = cvar_string("g_weaponarena");
 871         if (s == "0" || s == "")
 872         {
 873                 if(g_lms || g_ca)
 874                         s = "most";
 875         }
 876
 877         if (s == "0" || s == "")
 878         {
 879                 // no arena
 880         }
 881         else if (s == "off")
 882         {
 883                 // forcibly turn off weaponarena
 884         }
 885         else if (s == "all")
 886         {
 887                 g_weaponarena_list = "All Weapons";
 888                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 889                 {
 890                         e = get_weaponinfo(j);
 891                         g_weaponarena |= e.weapons;
 892                         weapon_action(e.weapon, WR_PRECACHE);
 893                 }
 894         }
 895         else if (s == "most")
 896         {
 897                 g_weaponarena_list = "Most Weapons";
 898                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 899                 {
 900                         e = get_weaponinfo(j);
 901                         if (e.spawnflags & WEP_FLAG_NORMAL)
 902                         {
 903                                 g_weaponarena |= e.weapons;
 904                                 weapon_action(e.weapon, WR_PRECACHE);
 905                         }
 906                 }
 907         }
 908         else if (s == "none")
 909         {
 910                 g_weaponarena_list = "No Weapons";
 911                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 912         }
 913         else
 914         {
 915                 t = tokenize_console(s);
 916                 g_weaponarena_list = "";
 917                 for (i = 0; i < t; ++i)
 918                 {
 919                         s = argv(i);
 920                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 921                         {
 922                                 e = get_weaponinfo(j);
 923                                 if (e.netname == s)
 924                                 {
 925                                         g_weaponarena |= e.weapons;
 926                                         weapon_action(e.weapon, WR_PRECACHE);
 927                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 928                                         break;
 929                                 }
 930                         }
 931                         if (j > WEP_LAST)
 932                         {
 933                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 934                         }
 935                 }
 936                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 937         }
 938
 939         if(g_weaponarena)
 940                 g_weaponarena_random = cvar("g_weaponarena_random");
 941         else
 942                 g_weaponarena_random = 0;
 943         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 944
 945         if (g_weaponarena)
 946         {
 947                 start_weapons = g_weaponarena;
 948                 if(!(g_lms || g_ca))
 949                         start_items |= IT_UNLIMITED_AMMO;
 950         }
 951         else if (g_minstagib)
 952         {
 953                 start_health = 100;
 954                 start_armorvalue = 0;
 955                 start_weapons = WEPBIT_MINSTANEX;
 956                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 957                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 958
 959                 if (g_minstagib_invis_alpha <= 0)
 960                         g_minstagib_invis_alpha = -1;
 961         }
 962         else
 963         {
 964                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 965                 {
 966                         e = get_weaponinfo(i);
 967                         if(want_weapon("g_start_weapon_", e, FALSE))
 968                                 start_weapons |= e.weapons;
 969                 }
 970         }
 971
 972         if(!cvar("g_use_ammunition"))
 973                 start_items |= IT_UNLIMITED_AMMO;
 974
 975         if(g_minstagib)
 976         {
 977                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 978                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 979         }
 980         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 981         {
 982                 start_ammo_rockets = 999;
 983                 start_ammo_shells = 999;
 984                 start_ammo_cells = 999;
 985                 start_ammo_nails = 999;
 986                 start_ammo_fuel = 999;
 987         }
 988         else
 989         {
 990                 if(g_lms || g_ca)
 991                 {
 992                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 993                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 994                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 995                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 996                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 997                 }
 998                 else
 999                 {
1000                         start_ammo_shells = cvar("g_start_ammo_shells");
1001                         start_ammo_nails = cvar("g_start_ammo_nails");
1002                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1003                         start_ammo_cells = cvar("g_start_ammo_cells");
1004                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1005                 }
1006         }
1007
1008         if (g_lms || g_ca)
1009         {
1010                 start_health = cvar("g_lms_start_health");
1011                 start_armorvalue = cvar("g_lms_start_armor");
1012         }
1013
1014         if (inWarmupStage)
1015         {
1016                 warmup_start_ammo_shells = start_ammo_shells;
1017                 warmup_start_ammo_nails = start_ammo_nails;
1018                 warmup_start_ammo_rockets = start_ammo_rockets;
1019                 warmup_start_ammo_cells = start_ammo_cells;
1020                 warmup_start_ammo_fuel = start_ammo_fuel;
1021                 warmup_start_health = start_health;
1022                 warmup_start_armorvalue = start_armorvalue;
1023                 warmup_start_weapons = start_weapons;
1024
1025                 if (!g_weaponarena && !g_minstagib && !g_ca)
1026                 {
1027                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1028                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1029                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1030                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1031                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1032                         warmup_start_health = cvar("g_warmup_start_health");
1033                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1034                         warmup_start_weapons = 0;
1035                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1036                         {
1037                                 e = get_weaponinfo(i);
1038                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1039                                         warmup_start_weapons |= e.weapons;
1040                         }
1041                 }
1042         }
1043
1044         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1045         {
1046                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1047                 start_items |= IT_FUEL_REGEN;
1048                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1049                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1050         }
1051
1052         if (g_jetpack)
1053                 start_items |= IT_JETPACK;
1054
1055         if (g_weapon_stay == 2)
1056         {
1057                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1058                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1059                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1060                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1061                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1062                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1063                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1064                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1065                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1066                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1067         }
1068
1069         MUTATOR_CALLHOOK(SetStartItems);
1070
1071         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1072         {
1073                 e = get_weaponinfo(i);
1074                 if(e.weapons & (start_weapons | warmup_start_weapons))
1075                         weapon_action(e.weapon, WR_PRECACHE);
1076         }
1077
1078         start_ammo_shells = max(0, start_ammo_shells);
1079         start_ammo_nails = max(0, start_ammo_nails);
1080         start_ammo_cells = max(0, start_ammo_cells);
1081         start_ammo_rockets = max(0, start_ammo_rockets);
1082         start_ammo_fuel = max(0, start_ammo_fuel);
1083
1084         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1085         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1086         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1087         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1088         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1089 }
1090
1091 float g_bugrigs;
1092 float g_bugrigs_planar_movement;
1093 float g_bugrigs_planar_movement_car_jumping;
1094 float g_bugrigs_reverse_spinning;
1095 float g_bugrigs_reverse_speeding;
1096 float g_bugrigs_reverse_stopping;
1097 float g_bugrigs_air_steering;
1098 float g_bugrigs_angle_smoothing;
1099 float g_bugrigs_friction_floor;
1100 float g_bugrigs_friction_brake;
1101 float g_bugrigs_friction_air;
1102 float g_bugrigs_accel;
1103 float g_bugrigs_speed_ref;
1104 float g_bugrigs_speed_pow;
1105 float g_bugrigs_steer;
1106
1107 float g_touchexplode;
1108 float g_touchexplode_radius;
1109 float g_touchexplode_damage;
1110 float g_touchexplode_edgedamage;
1111 float g_touchexplode_force;
1112
1113 float sv_autotaunt;
1114 float sv_taunt;
1115
1116 float sv_pitch_min;
1117 float sv_pitch_max;
1118 float sv_pitch_fixyaw;
1119
1120 string GetGametype(); // g_world.qc
1121 void readlevelcvars(void)
1122 {
1123         // first load all the mutators
1124         if(cvar("g_nix"))
1125                 MUTATOR_ADD(mutator_nix);
1126         if(cvar("g_dodging"))
1127                 MUTATOR_ADD(mutator_dodging);
1128         if(cvar("g_rocket_flying"))
1129                 MUTATOR_ADD(mutator_rocketflying);
1130         if(cvar("g_vampire"))
1131                 MUTATOR_ADD(mutator_vampire);
1132
1133         if(cvar("sv_allow_fullbright"))
1134                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1135
1136     g_bugrigs = cvar("g_bugrigs");
1137     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1138     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1139     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1140     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1141     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1142     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1143     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1144     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1145     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1146     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1147     g_bugrigs_accel = cvar("g_bugrigs_accel");
1148     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1149     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1150     g_bugrigs_steer = cvar("g_bugrigs_steer");
1151
1152     g_touchexplode = cvar("g_touchexplode");
1153     g_touchexplode_radius = cvar("g_touchexplode_radius");
1154     g_touchexplode_damage = cvar("g_touchexplode_damage");
1155     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1156     g_touchexplode_force = cvar("g_touchexplode_force");
1157
1158 #ifdef ALLOW_FORCEMODELS
1159         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1160 #endif
1161         sv_loddistance1 = cvar("sv_loddistance1");
1162         sv_loddistance2 = cvar("sv_loddistance2");
1163
1164         if(sv_loddistance2 <= sv_loddistance1)
1165                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1166
1167         sv_clones = cvar("sv_clones");
1168         sv_gentle = cvar("sv_gentle");
1169         sv_foginterval = cvar("sv_foginterval");
1170         g_cloaked = cvar("g_cloaked");
1171     if(g_cts)
1172         g_cloaked = 1; // always enable cloak in CTS
1173         g_jump_grunt = cvar("g_jump_grunt");
1174         g_footsteps = cvar("g_footsteps");
1175         g_grappling_hook = cvar("g_grappling_hook");
1176         g_jetpack = cvar("g_jetpack");
1177         g_midair = cvar("g_midair");
1178         g_minstagib = cvar("g_minstagib");
1179         g_norecoil = cvar("g_norecoil");
1180         g_bloodloss = cvar("g_bloodloss");
1181         sv_maxidle = cvar("sv_maxidle");
1182         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1183         sv_pogostick = cvar("sv_pogostick");
1184         g_ctf_reverse = cvar("g_ctf_reverse");
1185         sv_autotaunt = cvar("sv_autotaunt");
1186         sv_taunt = cvar("sv_taunt");
1187
1188         inWarmupStage = cvar("g_warmup");
1189         g_warmup_limit = cvar("g_warmup_limit");
1190         g_warmup_allguns = cvar("g_warmup_allguns");
1191         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1192
1193         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1194                 inWarmupStage = 0; // these modes cannot work together, sorry
1195
1196         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1197         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1198         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1199         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1200         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1201         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1202         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1203         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1204         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1205         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1206         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1207         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1208
1209         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1210         g_weaponratefactor = cvar("g_weaponratefactor");
1211         g_weapondamagefactor = cvar("g_weapondamagefactor");
1212         g_weaponforcefactor = cvar("g_weaponforcefactor");
1213         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1214
1215         g_pickup_shells = cvar("g_pickup_shells");
1216         g_pickup_shells_max = cvar("g_pickup_shells_max");
1217         g_pickup_nails = cvar("g_pickup_nails");
1218         g_pickup_nails_max = cvar("g_pickup_nails_max");
1219         g_pickup_rockets = cvar("g_pickup_rockets");
1220         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1221         g_pickup_cells = cvar("g_pickup_cells");
1222         g_pickup_cells_max = cvar("g_pickup_cells_max");
1223         g_pickup_fuel = cvar("g_pickup_fuel");
1224         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1225         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1226         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1227         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1228         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1229         g_pickup_armormedium = cvar("g_pickup_armormedium");
1230         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1231         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1232         g_pickup_armorbig = cvar("g_pickup_armorbig");
1233         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1234         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1235         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1236         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1237         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1238         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1239         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1240         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1241         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1242         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1243         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1244         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1245         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1246         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1247         g_pickup_healthmega = cvar("g_pickup_healthmega");
1248         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1249         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1250
1251         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1252         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1253
1254         g_pinata = cvar("g_pinata");
1255
1256     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1257     if(!g_weapon_stay)
1258         g_weapon_stay = cvar("g_weapon_stay");
1259
1260         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1261                 g_weapon_stay = 1;
1262
1263         g_ghost_items = cvar("g_ghost_items");
1264
1265         if(g_ghost_items >= 1)
1266                 g_ghost_items = 0.25; // default alpha value
1267
1268         if not(inWarmupStage && !g_ca)
1269                 game_starttime = cvar("g_start_delay");
1270
1271         sv_pitch_min = cvar("sv_pitch_min");
1272         sv_pitch_max = cvar("sv_pitch_max");
1273         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1274
1275         readplayerstartcvars();
1276 }
1277
1278 //#NO AUTOCVARS END
1279
1280 // Sound functions
1281 string precache_sound (string s) = #19;
1282 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1283 float precache_sound_index (string s) = #19;
1284
1285 #define SND_VOLUME      1
1286 #define SND_ATTENUATION 2
1287 #define SND_LARGEENTITY 8
1288 #define SND_LARGESOUND  16
1289
1290 float sound_allowed(float dest, entity e)
1291 {
1292     // sounds from world may always pass
1293     for (;;)
1294     {
1295         if (e.classname == "body")
1296             e = e.enemy;
1297         if (e.owner && e.owner != e)
1298             e = e.owner;
1299         else
1300             break;
1301     }
1302     // sounds to self may always pass
1303     if (dest == MSG_ONE)
1304         if (e == msg_entity)
1305             return TRUE;
1306     // sounds by players can be removed
1307     if (autocvar_bot_sound_monopoly)
1308         if (clienttype(e) == CLIENTTYPE_REAL)
1309             return FALSE;
1310     // anything else may pass
1311     return TRUE;
1312 }
1313
1314 void sound(entity e, float chan, string samp, float vol, float atten)
1315 {
1316     if (!sound_allowed(MSG_BROADCAST, e))
1317         return;
1318     sound_builtin(e, chan, samp, vol, atten);
1319 }
1320 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1321 {
1322     float entno, idx;
1323
1324     if (!sound_allowed(dest, e))
1325         return;
1326
1327     entno = num_for_edict(e);
1328     idx = precache_sound_index(samp);
1329
1330     float sflags;
1331     sflags = 0;
1332
1333     atten = floor(atten * 64);
1334     vol = floor(vol * 255);
1335
1336     if (vol != 255)
1337         sflags |= SND_VOLUME;
1338     if (atten != 64)
1339         sflags |= SND_ATTENUATION;
1340     if (entno >= 8192)
1341         sflags |= SND_LARGEENTITY;
1342     if (idx >= 256)
1343         sflags |= SND_LARGESOUND;
1344
1345     WriteByte(dest, SVC_SOUND);
1346     WriteByte(dest, sflags);
1347     if (sflags & SND_VOLUME)
1348         WriteByte(dest, vol);
1349     if (sflags & SND_ATTENUATION)
1350         WriteByte(dest, atten);
1351     if (sflags & SND_LARGEENTITY)
1352     {
1353         WriteShort(dest, entno);
1354         WriteByte(dest, chan);
1355     }
1356     else
1357     {
1358         WriteShort(dest, entno * 8 + chan);
1359     }
1360     if (sflags & SND_LARGESOUND)
1361         WriteShort(dest, idx);
1362     else
1363         WriteByte(dest, idx);
1364
1365     WriteCoord(dest, o_x);
1366     WriteCoord(dest, o_y);
1367     WriteCoord(dest, o_z);
1368 }
1369 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1370 {
1371     vector o;
1372
1373     if (!sound_allowed(dest, e))
1374         return;
1375
1376     o = e.origin + 0.5 * (e.mins + e.maxs);
1377     soundtoat(dest, e, o, chan, samp, vol, atten);
1378 }
1379 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1380 {
1381     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1382 }
1383 void stopsoundto(float dest, entity e, float chan)
1384 {
1385     float entno;
1386
1387     if (!sound_allowed(dest, e))
1388         return;
1389
1390     entno = num_for_edict(e);
1391
1392     if (entno >= 8192)
1393     {
1394         float idx, sflags;
1395         idx = precache_sound_index("misc/null.wav");
1396         sflags = SND_LARGEENTITY;
1397         if (idx >= 256)
1398             sflags |= SND_LARGESOUND;
1399         WriteByte(dest, SVC_SOUND);
1400         WriteByte(dest, sflags);
1401         WriteShort(dest, entno);
1402         WriteByte(dest, chan);
1403         if (sflags & SND_LARGESOUND)
1404             WriteShort(dest, idx);
1405         else
1406             WriteByte(dest, idx);
1407         WriteCoord(dest, e.origin_x);
1408         WriteCoord(dest, e.origin_y);
1409         WriteCoord(dest, e.origin_z);
1410     }
1411     else
1412     {
1413         WriteByte(dest, SVC_STOPSOUND);
1414         WriteShort(dest, entno * 8 + chan);
1415     }
1416 }
1417 void stopsound(entity e, float chan)
1418 {
1419     if (!sound_allowed(MSG_BROADCAST, e))
1420         return;
1421
1422     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1423     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1424 }
1425
1426 void play2(entity e, string filename)
1427 {
1428     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1429     msg_entity = e;
1430     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1431 }
1432
1433 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1434 .float spamtime;
1435 float spamsound(entity e, float chan, string samp, float vol, float atten)
1436 {
1437     if (!sound_allowed(MSG_BROADCAST, e))
1438         return FALSE;
1439
1440     if (time > e.spamtime)
1441     {
1442         e.spamtime = time;
1443         sound(e, chan, samp, vol, atten);
1444         return TRUE;
1445     }
1446     return FALSE;
1447 }
1448
1449 void play2team(float t, string filename)
1450 {
1451     local entity head;
1452
1453     if (autocvar_bot_sound_monopoly)
1454         return;
1455
1456     FOR_EACH_REALPLAYER(head)
1457     {
1458         if (head.team == t)
1459             play2(head, filename);
1460     }
1461 }
1462
1463 void play2all(string samp)
1464 {
1465     if (autocvar_bot_sound_monopoly)
1466         return;
1467
1468     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1469 }
1470
1471 void PrecachePlayerSounds(string f);
1472 void precache_playermodel(string m)
1473 {
1474         float globhandle, i, n;
1475         string f;
1476
1477         if(substring(m, -9,5) == "_lod1")
1478                 return;
1479         if(substring(m, -9,5) == "_lod2")
1480                 return;
1481         precache_model(m);
1482         if(sv_loddistance1)
1483         {
1484                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1485                 if(fexists(f))
1486                         precache_model(f);
1487                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1488                 if(fexists(f))
1489                         precache_model(f);
1490         }
1491
1492         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1493         if (globhandle < 0)
1494                 return;
1495         n = search_getsize(globhandle);
1496         for (i = 0; i < n; ++i)
1497         {
1498                 //print(search_getfilename(globhandle, i), "\n");
1499                 f = search_getfilename(globhandle, i);
1500                 PrecachePlayerSounds(f);
1501         }
1502         search_end(globhandle);
1503 }
1504 void precache_all_playermodels(string pattern)
1505 {
1506         float globhandle, i, n;
1507         string f;
1508
1509         globhandle = search_begin(pattern, TRUE, FALSE);
1510         if (globhandle < 0)
1511                 return;
1512         n = search_getsize(globhandle);
1513         for (i = 0; i < n; ++i)
1514         {
1515                 //print(search_getfilename(globhandle, i), "\n");
1516                 f = search_getfilename(globhandle, i);
1517                 precache_playermodel(f);
1518         }
1519         search_end(globhandle);
1520 }
1521
1522 void precache()
1523 {
1524     // gamemode related things
1525     precache_model ("models/misc/chatbubble.spr");
1526     if (g_runematch)
1527     {
1528         precache_model ("models/runematch/curse.mdl");
1529         precache_model ("models/runematch/rune.mdl");
1530     }
1531
1532 #ifdef TTURRETS_ENABLED
1533     if (autocvar_g_turrets)
1534         turrets_precash();
1535 #endif
1536
1537     // Precache all player models if desired
1538     if (autocvar_sv_precacheplayermodels)
1539     {
1540         PrecachePlayerSounds("sound/player/default.sounds");
1541         precache_all_playermodels("models/player/*.zym");
1542         precache_all_playermodels("models/player/*.dpm");
1543         precache_all_playermodels("models/player/*.md3");
1544         precache_all_playermodels("models/player/*.psk");
1545         precache_all_playermodels("models/player/*.iqm");
1546     }
1547
1548     if (autocvar_sv_defaultcharacter)
1549     {
1550         string s;
1551         s = autocvar_sv_defaultplayermodel_red;
1552         if (s != "")
1553             precache_playermodel(s);
1554         s = autocvar_sv_defaultplayermodel_blue;
1555         if (s != "")
1556             precache_playermodel(s);
1557         s = autocvar_sv_defaultplayermodel_yellow;
1558         if (s != "")
1559             precache_playermodel(s);
1560         s = autocvar_sv_defaultplayermodel_pink;
1561         if (s != "")
1562             precache_playermodel(s);
1563         s = autocvar_sv_defaultplayermodel;
1564         if (s != "")
1565             precache_playermodel(s);
1566     }
1567
1568     if (g_footsteps)
1569     {
1570         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1571         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1572     }
1573
1574     // gore and miscellaneous sounds
1575     //precache_sound ("misc/h2ohit.wav");
1576     precache_model ("models/hook.md3");
1577     precache_sound ("misc/armorimpact.wav");
1578     precache_sound ("misc/bodyimpact1.wav");
1579     precache_sound ("misc/bodyimpact2.wav");
1580     precache_sound ("misc/gib.wav");
1581     precache_sound ("misc/gib_splat01.wav");
1582     precache_sound ("misc/gib_splat02.wav");
1583     precache_sound ("misc/gib_splat03.wav");
1584     precache_sound ("misc/gib_splat04.wav");
1585     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1586     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1587     precache_sound ("misc/null.wav");
1588     precache_sound ("misc/spawn.wav");
1589     precache_sound ("misc/talk.wav");
1590     precache_sound ("misc/teleport.wav");
1591     precache_sound ("misc/poweroff.wav");
1592     precache_sound ("player/lava.wav");
1593     precache_sound ("player/slime.wav");
1594
1595     if (g_jetpack)
1596         precache_sound ("misc/jetpack_fly.wav");
1597
1598     precache_model ("models/sprites/0.spr32");
1599     precache_model ("models/sprites/1.spr32");
1600     precache_model ("models/sprites/2.spr32");
1601     precache_model ("models/sprites/3.spr32");
1602     precache_model ("models/sprites/4.spr32");
1603     precache_model ("models/sprites/5.spr32");
1604     precache_model ("models/sprites/6.spr32");
1605     precache_model ("models/sprites/7.spr32");
1606     precache_model ("models/sprites/8.spr32");
1607     precache_model ("models/sprites/9.spr32");
1608     precache_model ("models/sprites/10.spr32");
1609
1610     // common weapon precaches
1611         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1612     precache_sound ("weapons/weapon_switch.wav");
1613     precache_sound ("weapons/weaponpickup.wav");
1614     precache_sound ("weapons/unavailable.wav");
1615     precache_sound ("weapons/dryfire.wav");
1616     if (g_grappling_hook)
1617     {
1618         precache_sound ("weapons/hook_fire.wav"); // hook
1619         precache_sound ("weapons/hook_impact.wav"); // hook
1620     }
1621
1622     if(autocvar_sv_precacheweapons)
1623     {
1624         //precache weapon models/sounds
1625         local float wep;
1626         wep = WEP_FIRST;
1627         while (wep <= WEP_LAST)
1628         {
1629             weapon_action(wep, WR_PRECACHE);
1630             wep = wep + 1;
1631         }
1632     }
1633
1634     precache_model("models/elaser.mdl");
1635     precache_model("models/laser.mdl");
1636     precache_model("models/ebomb.mdl");
1637
1638 #if 0
1639     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1640
1641     if (!self.noise && self.music) // quake 3 uses the music field
1642         self.noise = self.music;
1643
1644     // plays music for the level if there is any
1645     if (self.noise)
1646     {
1647         precache_sound (self.noise);
1648         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1649     }
1650 #endif
1651 }
1652
1653 // sorry, but using \ in macros breaks line numbers
1654 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1655 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1656 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1657
1658
1659 void Send_CSQC_Centerprint_Generic(entity e, float id, string s1, float duration, float countdown_num)
1660 {
1661         if (clienttype(e) == CLIENTTYPE_REAL)
1662         {
1663                 msg_entity = e;
1664                 WRITESPECTATABLE_MSG_ONE({
1665                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1666                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
1667                         WriteByte(MSG_ONE, CSQC_CENTERPRINT_GENERIC);
1668                         WriteByte(MSG_ONE, id);
1669                         WriteString(MSG_ONE, s1);
1670                         if (id != 0)
1671                         {
1672                                 WriteByte(MSG_ONE, duration);
1673                                 WriteByte(MSG_ONE, countdown_num);
1674                         }
1675                 });
1676         }
1677 }
1678 // WARNING: this kills the trace globals
1679 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1680 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1681
1682 #define INITPRIO_FIRST              0
1683 #define INITPRIO_GAMETYPE           0
1684 #define INITPRIO_GAMETYPE_FALLBACK  1
1685 #define INITPRIO_FINDTARGET        10
1686 #define INITPRIO_DROPTOFLOOR       20
1687 #define INITPRIO_SETLOCATION       90
1688 #define INITPRIO_LINKDOORS         91
1689 #define INITPRIO_LAST              99
1690
1691 .void(void) initialize_entity;
1692 .float initialize_entity_order;
1693 .entity initialize_entity_next;
1694 entity initialize_entity_first;
1695
1696 void make_safe_for_remove(entity e)
1697 {
1698     if (e.initialize_entity)
1699     {
1700         entity ent, prev;
1701         for (ent = initialize_entity_first; ent; )
1702         {
1703             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1704             {
1705                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1706                 // skip it in linked list
1707                 if (prev)
1708                 {
1709                     prev.initialize_entity_next = ent.initialize_entity_next;
1710                     ent = prev.initialize_entity_next;
1711                 }
1712                 else
1713                 {
1714                     initialize_entity_first = ent.initialize_entity_next;
1715                     ent = initialize_entity_first;
1716                 }
1717             }
1718             else
1719             {
1720                 prev = ent;
1721                 ent = ent.initialize_entity_next;
1722             }
1723         }
1724     }
1725 }
1726
1727 void objerror(string s)
1728 {
1729     make_safe_for_remove(self);
1730     objerror_builtin(s);
1731 }
1732
1733 .float remove_except_protected_forbidden;
1734 void remove_except_protected(entity e)
1735 {
1736         if(e.remove_except_protected_forbidden)
1737                 error("not allowed to remove this at this point");
1738         remove_builtin(e);
1739 }
1740
1741 void remove_unsafely(entity e)
1742 {
1743     remove_builtin(e);
1744 }
1745
1746 void remove_safely(entity e)
1747 {
1748     make_safe_for_remove(e);
1749     remove_builtin(e);
1750 }
1751
1752 void InitializeEntity(entity e, void(void) func, float order)
1753 {
1754     entity prev, cur;
1755
1756     if (!e || e.initialize_entity)
1757     {
1758         // make a proxy initializer entity
1759         entity e_old;
1760         e_old = e;
1761         e = spawn();
1762         e.classname = "initialize_entity";
1763         e.enemy = e_old;
1764     }
1765
1766     e.initialize_entity = func;
1767     e.initialize_entity_order = order;
1768
1769     cur = initialize_entity_first;
1770     for (;;)
1771     {
1772         if (!cur || cur.initialize_entity_order > order)
1773         {
1774             // insert between prev and cur
1775             if (prev)
1776                 prev.initialize_entity_next = e;
1777             else
1778                 initialize_entity_first = e;
1779             e.initialize_entity_next = cur;
1780             return;
1781         }
1782         prev = cur;
1783         cur = cur.initialize_entity_next;
1784     }
1785 }
1786 void InitializeEntitiesRun()
1787 {
1788     entity startoflist;
1789     startoflist = initialize_entity_first;
1790     initialize_entity_first = world;
1791     remove = remove_except_protected;
1792     for (self = startoflist; self; self = self.initialize_entity_next)
1793     {
1794         self.remove_except_protected_forbidden = 1;
1795     }
1796     for (self = startoflist; self; )
1797     {
1798         entity e;
1799         var void(void) func;
1800         e = self.initialize_entity_next;
1801         func = self.initialize_entity;
1802         self.initialize_entity_order = 0;
1803         self.initialize_entity = func_null;
1804         self.initialize_entity_next = world;
1805         self.remove_except_protected_forbidden = 0;
1806         if (self.classname == "initialize_entity")
1807         {
1808             entity e_old;
1809             e_old = self.enemy;
1810             remove_builtin(self);
1811             self = e_old;
1812         }
1813         //dprint("Delayed initialization: ", self.classname, "\n");
1814         if(func != func_null)
1815             func();
1816         else
1817         {
1818             eprint(self);
1819             backtrace(strcat("Null function in: ", self.classname, "\n"));
1820         }
1821         self = e;
1822     }
1823     remove = remove_unsafely;
1824 }
1825
1826 .float uncustomizeentityforclient_set;
1827 .void(void) uncustomizeentityforclient;
1828 void(void) SUB_Nullpointer = #0;
1829 void UncustomizeEntitiesRun()
1830 {
1831     entity oldself;
1832     oldself = self;
1833     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1834         self.uncustomizeentityforclient();
1835     self = oldself;
1836 }
1837 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1838 {
1839     e.customizeentityforclient = customizer;
1840     e.uncustomizeentityforclient = uncustomizer;
1841     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1842 }
1843
1844 .float nottargeted;
1845 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1846
1847 void() SUB_Remove;
1848 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1849 {
1850     vector mi, ma;
1851
1852     if (e.classname == "")
1853         e.classname = "net_linked";
1854
1855     if (e.model == "" || self.modelindex == 0)
1856     {
1857         mi = e.mins;
1858         ma = e.maxs;
1859         setmodel(e, "null");
1860         setsize(e, mi, ma);
1861     }
1862
1863     e.SendEntity = sendfunc;
1864     e.SendFlags = 0xFFFFFF;
1865
1866     if (!docull)
1867         e.effects |= EF_NODEPTHTEST;
1868
1869     if (dt)
1870     {
1871         e.nextthink = time + dt;
1872         e.think = SUB_Remove;
1873     }
1874 }
1875
1876 void adaptor_think2touch()
1877 {
1878     entity o;
1879     o = other;
1880     other = world;
1881     self.touch();
1882     other = o;
1883 }
1884
1885 void adaptor_think2use()
1886 {
1887     entity o, a;
1888     o = other;
1889     a = activator;
1890     activator = world;
1891     other = world;
1892     self.use();
1893     other = o;
1894     activator = a;
1895 }
1896
1897 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1898 {
1899         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1900                 self.projectiledeathtype |= HITTYPE_SPLASH;
1901         adaptor_think2use();
1902 }
1903
1904 // deferred dropping
1905 void DropToFloor_Handler()
1906 {
1907     droptofloor_builtin();
1908     self.dropped_origin = self.origin;
1909 }
1910
1911 void droptofloor()
1912 {
1913     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1914 }
1915
1916
1917
1918 float trace_hits_box_a0, trace_hits_box_a1;
1919
1920 float trace_hits_box_1d(float end, float thmi, float thma)
1921 {
1922     if (end == 0)
1923     {
1924         // just check if x is in range
1925         if (0 < thmi)
1926             return FALSE;
1927         if (0 > thma)
1928             return FALSE;
1929     }
1930     else
1931     {
1932         // do the trace with respect to x
1933         // 0 -> end has to stay in thmi -> thma
1934         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1935         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1936         if (trace_hits_box_a0 > trace_hits_box_a1)
1937             return FALSE;
1938     }
1939     return TRUE;
1940 }
1941
1942 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1943 {
1944     end -= start;
1945     thmi -= start;
1946     thma -= start;
1947     // now it is a trace from 0 to end
1948
1949     trace_hits_box_a0 = 0;
1950     trace_hits_box_a1 = 1;
1951
1952     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1953         return FALSE;
1954     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1955         return FALSE;
1956     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1957         return FALSE;
1958
1959     return TRUE;
1960 }
1961
1962 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1963 {
1964     return trace_hits_box(start, end, thmi - ma, thma - mi);
1965 }
1966
1967 float SUB_NoImpactCheck()
1968 {
1969         // zero hitcontents = this is not the real impact, but either the
1970         // mirror-impact of something hitting the projectile instead of the
1971         // projectile hitting the something, or a touchareagrid one. Neither of
1972         // these stop the projectile from moving, so...
1973         if(trace_dphitcontents == 0)
1974         {
1975                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1976                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1977                 checkclient();
1978         }
1979     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1980         return 1;
1981     if (other == world && self.size != '0 0 0')
1982     {
1983         vector tic;
1984         tic = self.velocity * sys_frametime;
1985         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1986         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1987         if (trace_fraction >= 1)
1988         {
1989             dprint("Odd... did not hit...?\n");
1990         }
1991         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1992         {
1993             dprint("Detected and prevented the sky-grapple bug.\n");
1994             return 1;
1995         }
1996     }
1997
1998     return 0;
1999 }
2000
2001 #define SUB_OwnerCheck() (other && (other == self.owner))
2002
2003 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2004 {
2005         if(SUB_OwnerCheck())
2006                 return TRUE;
2007         if(SUB_NoImpactCheck())
2008         {
2009                 remove(self);
2010                 return TRUE;
2011         }
2012         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2013                 UpdateCSQCProjectileNextFrame(self);
2014         return FALSE;
2015 }
2016 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2017
2018 float MAX_IPBAN_URIS           = 16;
2019
2020 float URI_GET_DISCARD          = 0;
2021 float URI_GET_IPBAN            = 1;
2022 float URI_GET_IPBAN_END        = 16;
2023 float URI_GET_PLAYERSTATS_SENT = 17;
2024
2025 void URI_Get_Callback(float id, float status, string data)
2026 {
2027     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2028     dprint(data);
2029     dprint("\nEnd of data.\n");
2030
2031     if (id == URI_GET_DISCARD)
2032     {
2033         // discard
2034     }
2035     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2036     {
2037         // online ban list
2038         OnlineBanList_URI_Get_Callback(id, status, data);
2039     }
2040     else if (id == URI_GET_PLAYERSTATS_SENT)
2041     {
2042         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2043     }
2044     else
2045     {
2046         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2047     }
2048 }
2049
2050 void print_to(entity e, string s)
2051 {
2052     if (e)
2053         sprint(e, strcat(s, "\n"));
2054     else
2055         print(s, "\n");
2056 }
2057
2058 string uid2name(string myuid) {
2059         string s;
2060         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2061
2062         if(s == "")
2063                 s = "^1Unregistered Player";
2064         return s;
2065 }
2066
2067 float race_readTime(string map, float pos)
2068 {
2069         string rr;
2070         if(g_cts)
2071                 rr = CTS_RECORD;
2072         else
2073                 rr = RACE_RECORD;
2074
2075         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2076 }
2077
2078 string race_readUID(string map, float pos)
2079 {
2080         string rr;
2081         if(g_cts)
2082                 rr = CTS_RECORD;
2083         else
2084                 rr = RACE_RECORD;
2085
2086         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2087 }
2088
2089 float race_readPos(string map, float t) {
2090         float i;
2091         for (i = 1; i <= RANKINGS_CNT; ++i)
2092                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2093                         return i;
2094
2095         return 0; // pos is zero if unranked
2096 }
2097
2098 void race_writeTime(string map, float t, string myuid)
2099 {
2100         string rr;
2101         if(g_cts)
2102                 rr = CTS_RECORD;
2103         else
2104                 rr = RACE_RECORD;
2105
2106         float newpos;
2107         newpos = race_readPos(map, t);
2108
2109         float i, prevpos;
2110         for(i = 1; i <= RANKINGS_CNT; ++i)
2111         {
2112                 if(race_readUID(map, i) == myuid)
2113                         prevpos = i;
2114         }
2115         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2116                 for (i = prevpos; i > newpos; --i) {
2117                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2118                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2119                 }
2120         } else { // player has no ranked record yet
2121                 for (i = RANKINGS_CNT; i > newpos; --i) {
2122                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2123                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2124                 }
2125         }
2126
2127         // store new time itself
2128         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2129         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2130 }
2131
2132 string race_readName(string map, float pos)
2133 {
2134         string rr;
2135         if(g_cts)
2136                 rr = CTS_RECORD;
2137         else
2138                 rr = RACE_RECORD;
2139
2140         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2141 }
2142
2143 string race_placeName(float pos) {
2144         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2145         {
2146                 if(mod(pos, 10) == 1)
2147                         return strcat(ftos(pos), "st");
2148                 else if(mod(pos, 10) == 2)
2149                         return strcat(ftos(pos), "nd");
2150                 else if(mod(pos, 10) == 3)
2151                         return strcat(ftos(pos), "rd");
2152                 else
2153                         return strcat(ftos(pos), "th");
2154         }
2155         else
2156                 return strcat(ftos(pos), "th");
2157 }
2158 string getrecords(float page) // 50 records per page
2159 {
2160     float rec;
2161     string h;
2162     float r;
2163     float i;
2164     string s;
2165
2166     rec = 0;
2167
2168     s = "";
2169
2170     if (g_ctf)
2171     {
2172         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2173         {
2174             if (MapInfo_Get_ByID(i))
2175             {
2176                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2177                 if (r == 0)
2178                     continue;
2179                 // TODO: uid2name
2180                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2181                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2182                 ++rec;
2183             }
2184         }
2185     }
2186
2187     if (g_race)
2188     {
2189         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2190         {
2191             if (MapInfo_Get_ByID(i))
2192             {
2193                 r = race_readTime(MapInfo_Map_bspname, 1);
2194                 if (r == 0)
2195                     continue;
2196                 h = race_readName(MapInfo_Map_bspname, 1);
2197                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2198                 ++rec;
2199             }
2200         }
2201     }
2202
2203     if (g_cts)
2204     {
2205         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2206         {
2207             if (MapInfo_Get_ByID(i))
2208             {
2209                 r = race_readTime(MapInfo_Map_bspname, 1);
2210                 if (r == 0)
2211                     continue;
2212                 h = race_readName(MapInfo_Map_bspname, 1);
2213                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2214                 ++rec;
2215             }
2216         }
2217     }
2218
2219     MapInfo_ClearTemps();
2220
2221     if (s == "" && page == 0)
2222         return "No records are available on this server.\n";
2223     else
2224         return s;
2225 }
2226
2227 string getrankings()
2228 {
2229     string n;
2230     float t;
2231     float i;
2232     string s;
2233     string p;
2234     string map;
2235
2236     s = "";
2237
2238     map = GetMapname();
2239
2240     for (i = 1; i <= RANKINGS_CNT; ++i)
2241     {
2242         t = race_readTime(map, i);
2243         if (t == 0)
2244             continue;
2245         n = race_readName(map, i);
2246         p = race_placeName(i);
2247         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2248     }
2249
2250     MapInfo_ClearTemps();
2251
2252     if (s == "")
2253         return strcat("No records are available for the map: ", map, "\n");
2254     else
2255         return strcat("Records for ", map, ":\n", s);
2256 }
2257
2258 #define LADDER_FIRSTPOINT 100
2259 #define LADDER_CNT 10
2260         // position X still gives LADDER_FIRSTPOINT/X points
2261 #define LADDER_SIZE 30
2262         // ladder shows the top X players
2263 string top_uids[LADDER_SIZE];
2264 float top_scores[LADDER_SIZE];
2265 string getladder()
2266 {
2267     float i, j, k, uidcnt;
2268     string s, temp_s;
2269
2270     s = "";
2271     temp_s = "";
2272
2273     string rr;
2274     if(g_cts)
2275         rr = CTS_RECORD;
2276     else
2277         rr = RACE_RECORD;
2278
2279     string myuid;
2280
2281     for (k = 0; k < MapInfo_count; ++k)
2282     {
2283         if (MapInfo_Get_ByID(k))
2284         {
2285                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2286                         if(i == 0) // speed award
2287                         {
2288                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2289                                         continue;
2290
2291                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2292                         }
2293                         else // normal record, if it exists (else break)
2294                         {
2295                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2296                                         continue;
2297
2298                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2299                         }
2300
2301                         // string s contains:
2302                         // arg 0 = # of speed recs
2303                         // arg 1 = # of 1st place recs
2304                         // arg 2 = # of 2nd place recs
2305                         // ... etc
2306                         // LADDER_CNT+1 = total points
2307
2308                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2309                         if (temp_s == "")
2310                         {
2311                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2312                             ++uidcnt;
2313                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2314                             {
2315                                 if(j != LADDER_CNT + 1)
2316                                     temp_s = strcat(temp_s, "0 ");
2317                                 else
2318                                     temp_s = strcat(temp_s, "0");
2319                             }
2320                         }
2321
2322                         tokenize_console(temp_s);
2323                         s = "";
2324
2325                         if(i == 0) // speed award
2326                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2327                             {
2328                                 if(j == 0) // speed award
2329                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2330                                 else
2331                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2332                             }
2333                         else // record
2334                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2335                             {
2336                                 if(j == 0)
2337                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2338                                 else if(j == i) // wanted rec!
2339                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2340                                 else
2341                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2342                             }
2343
2344                         // total points are (by default) calculated like this:
2345                         // speedrec = floor(100 / 10) = 10 points
2346                         // 1st place = floor(100 / 1) = 100 points
2347                         // 2nd place = floor(100 / 2) = 50 points
2348                         // 3rd place = floor(100 / 3) = 33 points
2349                         // 4th place = floor(100 / 4) = 25 points
2350                         // 5th place = floor(100 / 5) = 20 points
2351                         // ... etc
2352
2353                         if(i == 0)
2354                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2355                         else
2356                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2357
2358                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2359                 }
2360         }
2361     }
2362
2363     float thiscnt;
2364     string thisuid;
2365     for (i = 0; i <= uidcnt; ++i) // for each known uid
2366     {
2367         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2368         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2369         tokenize_console(temp_s);
2370         thiscnt = stof(argv(LADDER_CNT+1));
2371
2372         if(thiscnt > top_scores[LADDER_SIZE-1])
2373         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2374         {
2375             if(thiscnt > top_scores[j])
2376             {
2377                 for (k = LADDER_SIZE-1; k >= j; --k)
2378                 {
2379                     top_uids[k] = top_uids[k-1];
2380                     top_scores[k] = top_scores[k-1];
2381                 }
2382                 top_uids[j] = thisuid;
2383                 top_scores[j] = thiscnt;
2384                 break;
2385             }
2386         }
2387     }
2388
2389     s = "^3-----------------------\n\n";
2390
2391     s = strcat(s, "Pos ^3|");
2392     s = strcat(s, " ^7Total  ^3|");
2393     for (i = 1; i <= LADDER_CNT; ++i)
2394     {
2395         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2396     }
2397     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2398
2399     s = strcat(s, "\n^3----+--------");
2400     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2401     {
2402         s = strcat(s, "+-----");
2403     }
2404 #if LADDER_CNT > 9
2405     for (i = 1; i <= LADDER_CNT - 9; ++i)
2406     {
2407         s = strcat(s, "+------");
2408     }
2409 #endif
2410
2411     s = strcat(s, "+--------------+--------------------\n");
2412
2413     for (i = 0; i < LADDER_SIZE; ++i)
2414     {
2415         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2416         tokenize_console(temp_s);
2417         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2418             continue;
2419         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2420         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2421         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2422         {
2423             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2424         }
2425 #if LADDER_CNT > 9
2426         for (j = 10; j <= LADDER_CNT; ++j)
2427         {
2428             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2429         }
2430 #endif
2431
2432         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2433         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2434     }
2435
2436     MapInfo_ClearTemps();
2437
2438     if (s == "")
2439         return "No ladder on this server!\n";
2440     else
2441         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2442 }
2443
2444
2445 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2446 {
2447     float m, i;
2448     vector start, org, delta, end, enddown, mstart;
2449
2450     m = e.dphitcontentsmask;
2451     e.dphitcontentsmask = goodcontents | badcontents;
2452
2453     org = world.mins;
2454     delta = world.maxs - world.mins;
2455
2456     for (i = 0; i < attempts; ++i)
2457     {
2458         start_x = org_x + random() * delta_x;
2459         start_y = org_y + random() * delta_y;
2460         start_z = org_z + random() * delta_z;
2461
2462         // rule 1: start inside world bounds, and outside
2463         // solid, and don't start from somewhere where you can
2464         // fall down to evil
2465         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2466         if (trace_fraction >= 1)
2467             continue;
2468         if (trace_startsolid)
2469             continue;
2470         if (trace_dphitcontents & badcontents)
2471             continue;
2472         if (trace_dphitq3surfaceflags & badsurfaceflags)
2473             continue;
2474
2475         // rule 2: if we are too high, lower the point
2476         if (trace_fraction * delta_z > maxaboveground)
2477             start = trace_endpos + '0 0 1' * maxaboveground;
2478         enddown = trace_endpos;
2479
2480         // rule 3: make sure we aren't outside the map. This only works
2481         // for somewhat well formed maps. A good rule of thumb is that
2482         // the map should have a convex outside hull.
2483         // these can be traceLINES as we already verified the starting box
2484         mstart = start + 0.5 * (e.mins + e.maxs);
2485         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2486         if (trace_fraction >= 1)
2487             continue;
2488         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2489         if (trace_fraction >= 1)
2490             continue;
2491         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2492         if (trace_fraction >= 1)
2493             continue;
2494         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2495         if (trace_fraction >= 1)
2496             continue;
2497         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2498         if (trace_fraction >= 1)
2499             continue;
2500
2501         // find a random vector to "look at"
2502         end_x = org_x + random() * delta_x;
2503         end_y = org_y + random() * delta_y;
2504         end_z = org_z + random() * delta_z;
2505         end = start + normalize(end - start) * vlen(delta);
2506
2507         // rule 4: start TO end must not be too short
2508         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2509         if (trace_startsolid)
2510             continue;
2511         if (trace_fraction < minviewdistance / vlen(delta))
2512             continue;
2513
2514         // rule 5: don't want to look at sky
2515         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2516             continue;
2517
2518         // rule 6: we must not end up in trigger_hurt
2519         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2520             continue;
2521
2522         break;
2523     }
2524
2525     e.dphitcontentsmask = m;
2526
2527     if (i < attempts)
2528     {
2529         setorigin(e, start);
2530         e.angles = vectoangles(end - start);
2531         dprint("Needed ", ftos(i + 1), " attempts\n");
2532         return TRUE;
2533     }
2534     else
2535         return FALSE;
2536 }
2537
2538 float zcurveparticles_effectno;
2539 vector zcurveparticles_start;
2540 float zcurveparticles_spd;
2541
2542 void endzcurveparticles()
2543 {
2544         if(zcurveparticles_effectno)
2545         {
2546                 // terminator
2547                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2548         }
2549         zcurveparticles_effectno = 0;
2550 }
2551
2552 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2553 {
2554         spd = bound(0, floor(spd / 16), 32767);
2555         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2556         {
2557                 endzcurveparticles();
2558                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2559                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2560                 WriteShort(MSG_BROADCAST, effectno);
2561                 WriteCoord(MSG_BROADCAST, start_x);
2562                 WriteCoord(MSG_BROADCAST, start_y);
2563                 WriteCoord(MSG_BROADCAST, start_z);
2564                 zcurveparticles_effectno = effectno;
2565                 zcurveparticles_start = start;
2566         }
2567         else
2568                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2569         WriteCoord(MSG_BROADCAST, end_x);
2570         WriteCoord(MSG_BROADCAST, end_y);
2571         WriteCoord(MSG_BROADCAST, end_z);
2572         WriteCoord(MSG_BROADCAST, end_dz);
2573         zcurveparticles_spd = spd;
2574 }
2575
2576 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2577 {
2578         float end_dz;
2579         vector vecxy, velxy;
2580
2581         vecxy = end - start;
2582         vecxy_z = 0;
2583         velxy = vel;
2584         velxy_z = 0;
2585
2586         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2587         {
2588                 endzcurveparticles();
2589                 trailparticles(world, effectno, start, end);
2590                 return;
2591         }
2592
2593         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2594         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2595 }
2596
2597 void write_recordmarker(entity pl, float tstart, float dt)
2598 {
2599     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2600
2601     // also write a marker into demo files for demotc-race-record-extractor to find
2602     stuffcmd(pl,
2603              strcat(
2604                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2605                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2606 }
2607
2608 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2609 {
2610         switch(algn)
2611         {
2612                 default:
2613                 case 3: // right
2614                         break;
2615
2616                 case 4: // left
2617                         vecs_y = -vecs_y;
2618                         break;
2619
2620                 case 1:
2621                         if(allowcenter) // 2: allow center handedness
2622                         {
2623                                 // center
2624                                 vecs_y = 0;
2625                                 vecs_z -= 2;
2626                         }
2627                         else
2628                         {
2629                                 // right
2630                         }
2631                         break;
2632
2633                 case 2:
2634                         if(allowcenter) // 2: allow center handedness
2635                         {
2636                                 // center
2637                                 vecs_y = 0;
2638                                 vecs_z -= 2;
2639                         }
2640                         else
2641                         {
2642                                 // left
2643                                 vecs_y = -vecs_y;
2644                         }
2645                         break;
2646         }
2647         return vecs;
2648 }
2649
2650 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2651 {
2652         string s;
2653         vector v;
2654
2655         if (autocvar_g_shootfromeye)
2656         {
2657                 if (visual)
2658                 {
2659                         vecs_y = 0;
2660                         vecs_z -= 2;
2661                 }
2662                 else
2663                 {
2664                         vecs_y = 0;
2665                         vecs_z = 0;
2666                 }
2667         }
2668         else if (autocvar_g_shootfromcenter)
2669         {
2670                 vecs_y = 0;
2671                 vecs_z -= 2;
2672         }
2673         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2674         {
2675                 v = stov(s);
2676                 if (y_is_right)
2677                         v_y = -v_y;
2678                 if (v_x != 0)
2679                         vecs_x = v_x;
2680                 vecs_y = v_y;
2681                 vecs_z = v_z;
2682         }
2683         else if (autocvar_g_shootfromclient)
2684         {
2685                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2686         }
2687         return vecs;
2688 }
2689
2690 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2691 {
2692         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2693 }
2694
2695
2696 void attach_sameorigin(entity e, entity to, string tag)
2697 {
2698     vector org, t_forward, t_left, t_up, e_forward, e_up;
2699     vector org0, ang0;
2700     float tagscale;
2701
2702     ang0 = e.angles;
2703     org0 = e.origin;
2704
2705     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2706     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2707     t_forward = v_forward * tagscale;
2708     t_left = v_right * -tagscale;
2709     t_up = v_up * tagscale;
2710
2711     e.origin_x = org * t_forward;
2712     e.origin_y = org * t_left;
2713     e.origin_z = org * t_up;
2714
2715     // current forward and up directions
2716     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2717                 e.angles = AnglesTransform_FromVAngles(e.angles);
2718         else
2719                 e.angles = AnglesTransform_FromAngles(e.angles);
2720     fixedmakevectors(e.angles);
2721
2722     // untransform forward, up!
2723     e_forward_x = v_forward * t_forward;
2724     e_forward_y = v_forward * t_left;
2725     e_forward_z = v_forward * t_up;
2726     e_up_x = v_up * t_forward;
2727     e_up_y = v_up * t_left;
2728     e_up_z = v_up * t_up;
2729
2730     e.angles = fixedvectoangles2(e_forward, e_up);
2731     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2732                 e.angles = AnglesTransform_ToVAngles(e.angles);
2733         else
2734                 e.angles = AnglesTransform_ToAngles(e.angles);
2735
2736     setattachment(e, to, tag);
2737     setorigin(e, e.origin);
2738 }
2739
2740 void detach_sameorigin(entity e)
2741 {
2742     vector org;
2743     org = gettaginfo(e, 0);
2744     e.angles = fixedvectoangles2(v_forward, v_up);
2745     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2746                 e.angles = AnglesTransform_ToVAngles(e.angles);
2747         else
2748                 e.angles = AnglesTransform_ToAngles(e.angles);
2749     setorigin(e, org);
2750     setattachment(e, world, "");
2751     setorigin(e, e.origin);
2752 }
2753
2754 void follow_sameorigin(entity e, entity to)
2755 {
2756     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2757     e.aiment = to; // make the hole follow bmodel
2758     e.punchangle = to.angles; // the original angles of bmodel
2759     e.view_ofs = e.origin - to.origin; // relative origin
2760     e.v_angle = e.angles - to.angles; // relative angles
2761 }
2762
2763 void unfollow_sameorigin(entity e)
2764 {
2765     e.movetype = MOVETYPE_NONE;
2766 }
2767
2768 entity gettaginfo_relative_ent;
2769 vector gettaginfo_relative(entity e, float tag)
2770 {
2771     if (!gettaginfo_relative_ent)
2772     {
2773         gettaginfo_relative_ent = spawn();
2774         gettaginfo_relative_ent.effects = EF_NODRAW;
2775     }
2776     gettaginfo_relative_ent.model = e.model;
2777     gettaginfo_relative_ent.modelindex = e.modelindex;
2778     gettaginfo_relative_ent.frame = e.frame;
2779     return gettaginfo(gettaginfo_relative_ent, tag);
2780 }
2781
2782 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2783 {
2784     float p;
2785     p = pow(2, chan);
2786     if (pl.soundentity.cnt & p)
2787         return;
2788     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2789     pl.soundentity.cnt |= p;
2790 }
2791
2792 void SoundEntity_StopSound(entity pl, float chan)
2793 {
2794     float p;
2795     p = pow(2, chan);
2796     if (pl.soundentity.cnt & p)
2797     {
2798         stopsoundto(MSG_ALL, pl.soundentity, chan);
2799         pl.soundentity.cnt &~= p;
2800     }
2801 }
2802
2803 void SoundEntity_Attach(entity pl)
2804 {
2805     pl.soundentity = spawn();
2806     pl.soundentity.classname = "soundentity";
2807     pl.soundentity.owner = pl;
2808     setattachment(pl.soundentity, pl, "");
2809     setmodel(pl.soundentity, "null");
2810 }
2811
2812 void SoundEntity_Detach(entity pl)
2813 {
2814     float i;
2815     for (i = 0; i <= 7; ++i)
2816         SoundEntity_StopSound(pl, i);
2817 }
2818
2819
2820 float ParseCommandPlayerSlotTarget_firsttoken;
2821 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2822 {
2823         string s;
2824         entity e, head;
2825         float n;
2826
2827         s = string_null;
2828
2829         ParseCommandPlayerSlotTarget_firsttoken = -1;
2830
2831         if (tokens > idx)
2832         {
2833                 if (substring(argv(idx), 0, 1) == "#")
2834                 {
2835                         s = substring(argv(idx), 1, -1);
2836                         ++idx;
2837                         if (s == "") if (tokens > idx)
2838                         {
2839                                 s = argv(idx);
2840                                 ++idx;
2841                         }
2842                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2843                         n = stof(s);
2844                         if (s == ftos(n) && n > 0 && n <= maxclients)
2845                         {
2846                                 e = edict_num(n);
2847                                 if (e.flags & FL_CLIENT)
2848                                         return e;
2849                         }
2850                 }
2851                 else
2852                 {
2853                         // it must be a nick name
2854                         s = argv(idx);
2855                         ++idx;
2856                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2857
2858                         n = 0;
2859                         FOR_EACH_CLIENT(head)
2860                                 if (head.netname == s)
2861                                 {
2862                                         e = head;
2863                                         ++n;
2864                                 }
2865                         if (n == 1)
2866                                 return e;
2867
2868                         s = strdecolorize(s);
2869                         n = 0;
2870                         FOR_EACH_CLIENT(head)
2871                                 if (strdecolorize(head.netname) == s)
2872                                 {
2873                                         e = head;
2874                                         ++n;
2875                                 }
2876                         if (n == 1)
2877                                 return e;
2878                 }
2879         }
2880
2881         return world;
2882 }
2883
2884 .float scale2;
2885
2886 float modeleffect_SendEntity(entity to, float sf)
2887 {
2888         float f;
2889         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2890
2891         f = 0;
2892         if(self.velocity != '0 0 0')
2893                 f |= 1;
2894         if(self.angles != '0 0 0')
2895                 f |= 2;
2896         if(self.avelocity != '0 0 0')
2897                 f |= 4;
2898
2899         WriteByte(MSG_ENTITY, f);
2900         WriteShort(MSG_ENTITY, self.modelindex);
2901         WriteByte(MSG_ENTITY, self.skin);
2902         WriteByte(MSG_ENTITY, self.frame);
2903         WriteCoord(MSG_ENTITY, self.origin_x);
2904         WriteCoord(MSG_ENTITY, self.origin_y);
2905         WriteCoord(MSG_ENTITY, self.origin_z);
2906         if(f & 1)
2907         {
2908                 WriteCoord(MSG_ENTITY, self.velocity_x);
2909                 WriteCoord(MSG_ENTITY, self.velocity_y);
2910                 WriteCoord(MSG_ENTITY, self.velocity_z);
2911         }
2912         if(f & 2)
2913         {
2914                 WriteCoord(MSG_ENTITY, self.angles_x);
2915                 WriteCoord(MSG_ENTITY, self.angles_y);
2916                 WriteCoord(MSG_ENTITY, self.angles_z);
2917         }
2918         if(f & 4)
2919         {
2920                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2921                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2922                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2923         }
2924         WriteShort(MSG_ENTITY, self.scale * 256.0);
2925         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2926         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2927         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2928         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2929
2930         return TRUE;
2931 }
2932
2933 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2934 {
2935         entity e;
2936         float sz;
2937         e = spawn();
2938         e.classname = "modeleffect";
2939         setmodel(e, m);
2940         e.frame = f;
2941         setorigin(e, o);
2942         e.velocity = v;
2943         e.angles = ang;
2944         e.avelocity = angv;
2945         e.alpha = a;
2946         e.teleport_time = t1;
2947         e.fade_time = t2;
2948         e.skin = s;
2949         if(s0 >= 0)
2950                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2951         else
2952                 e.scale = -s0;
2953         if(s2 >= 0)
2954                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2955         else
2956                 e.scale2 = -s2;
2957         sz = max(e.scale, e.scale2);
2958         setsize(e, e.mins * sz, e.maxs * sz);
2959         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2960 }
2961
2962 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2963 {
2964         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2965 }
2966
2967 float randombit(float bits)
2968 {
2969         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2970                 return bits;
2971
2972         float n, f, b, r;
2973
2974         r = random();
2975         b = 0;
2976         n = 0;
2977
2978         for(f = 1; f <= bits; f *= 2)
2979         {
2980                 if(bits & f)
2981                 {
2982                         ++n;
2983                         r *= n;
2984                         if(r <= 1)
2985                                 b = f;
2986                         else
2987                                 r = (r - 1) / (n - 1);
2988                 }
2989         }
2990
2991         return b;
2992 }
2993
2994 float randombits(float bits, float k, float error_return)
2995 {
2996         float r;
2997         r = 0;
2998         while(k > 0 && bits != r)
2999         {
3000                 r += randombit(bits - r);
3001                 --k;
3002         }
3003         if(error_return)
3004                 if(k > 0)
3005                         return -1; // all
3006         return r;
3007 }
3008
3009 void randombit_test(float bits, float iter)
3010 {
3011         while(iter > 0)
3012         {
3013                 print(ftos(randombit(bits)), "\n");
3014                 --iter;
3015         }
3016 }
3017
3018 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3019 {
3020         if(halflifedist > 0)
3021                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3022         else if(halflifedist < 0)
3023                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3024         else
3025                 return 1;
3026 }
3027
3028
3029
3030
3031 #ifdef RELEASE
3032 #define cvar_string_normal cvar_string_builtin
3033 #define cvar_normal cvar_builtin
3034 #else
3035 string cvar_string_normal(string n)
3036 {
3037         if not(cvar_type(n) & 1)
3038                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3039         return cvar_string_builtin(n);
3040 }
3041
3042 float cvar_normal(string n)
3043 {
3044         return stof(cvar_string_normal(n));
3045 }
3046 #endif
3047 #define cvar_set_normal cvar_set_builtin
3048
3049 void defer_think()
3050 {
3051     entity oself;
3052
3053     oself           = self;
3054     self            = self.owner;
3055     oself.think     = SUB_Remove;
3056     oself.nextthink = time;
3057
3058     oself.use();
3059 }
3060
3061 /*
3062     Execute func() after time + fdelay.
3063     self when func is executed = self when defer is called
3064 */
3065 void defer(float fdelay, void() func)
3066 {
3067     entity e;
3068
3069     e           = spawn();
3070     e.owner     = self;
3071     e.use       = func;
3072     e.think     = defer_think;
3073     e.nextthink = time + fdelay;
3074 }