qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void() spawnfunc_item_minst_cells;
   4
   5 void M_Item_Touch ()
   6 {
   7         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   8         {
   9                 Item_Touch();
  10                 self.think = SUB_Remove;
  11                 self.nextthink = time + 0.1;
  12         }
  13 }
  14
  15 void monster_item_spawn()
  16 {
  17         if(self.monster_loot)
  18                 self.monster_loot();
  19
  20         self.gravity = 1;
  21         self.velocity = randomvec() * 175 + '0 0 325';
  22         self.touch = M_Item_Touch;
  23
  24         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  25 }
  26
  27 void Monster_DropItem (string itype, string itemsize)
  28 {
  29         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  30         entity e = spawn();
  31
  32         setorigin(e, org);
  33
  34         switch(itype)
  35         {
  36                 case "armor":
  37                 {
  38                         switch(itemsize)
  39                         {
  40                                 case "mega": e.monster_loot = spawnfunc_item_armor_large; break;
  41                                 case "large": e.monster_loot = spawnfunc_item_armor_big; break;
  42                                 case "medium": e.monster_loot = spawnfunc_item_armor_medium; break;
  43                                 case "small": e.monster_loot = spawnfunc_item_armor_small; break;
  44                         }
  45                         break;
  46                 }
  47                 case "health":
  48                 {
  49                         switch(itemsize)
  50                         {
  51                                 case "mega": e.monster_loot = spawnfunc_item_health_mega; break;
  52                                 case "large": e.monster_loot = spawnfunc_item_health_large; break;
  53                                 case "medium": e.monster_loot = spawnfunc_item_health_medium; break;
  54                                 case "small": e.monster_loot = spawnfunc_item_health_small; break;
  55                         }
  56                         break;
  57                 }
  58                 case "ammo":
  59                 {
  60                         switch(itemsize)
  61                         {
  62                                 case "shells": e.monster_loot = spawnfunc_item_shells; break;
  63                                 case "cells": e.monster_loot = spawnfunc_item_cells; break;
  64                                 case "rockets": e.monster_loot = spawnfunc_item_rockets; break;
  65                                 case "bullets":
  66                                 case "nails": e.monster_loot = spawnfunc_item_bullets; break;
  67                         }
  68                         break;
  69                 }
  70         }
  71
  72         other = e;
  73         MUTATOR_CALLHOOK(MonsterDropItem);
  74         e = other;
  75
  76         e.think = monster_item_spawn;
  77         e.nextthink = time + 0.1;
  78 }
  79
  80 void monsters_setframe(float _frame)
  81 {
  82         if(self.frame == _frame)
  83                 return;
  84
  85         self.anim_start_time = time;
  86         self.frame = _frame;
  87         self.SendFlags |= MSF_ANIM;
  88 }
  89
  90 float monster_isvalidtarget (entity targ, entity ent)
  91 {
  92         if(!targ || !ent)
  93                 return FALSE; // someone doesn't exist
  94
  95         if(time < game_starttime)
  96                 return FALSE; // monsters do nothing before the match has started
  97
  98         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  99
 100         if(vlen(targ.origin - ent.origin) >= ent.target_range)
 101                 return FALSE; // enemy is too far away
 102
 103         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 104         if(trace_ent != targ)
 105                 return FALSE; // we can't see the enemy
 106
 107         if(targ.takedamage == DAMAGE_NO)
 108                 return FALSE; // enemy can't be damaged
 109
 110         if(targ.items & IT_INVISIBILITY)
 111                 return FALSE; // enemy is invisible
 112
 113         if(substring(targ.classname, 0, 10) == "onslaught_")
 114                 return FALSE; // don't attack onslaught targets
 115
 116         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 117                 return FALSE; // enemy is a spectator
 118
 119         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 120         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 121                 return FALSE; // enemy/self is dead
 122
 123         if(targ.monster_owner == ent || ent.monster_owner == targ)
 124                 return FALSE; // enemy owns us, or we own them
 125
 126         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 127         if(targ.flags & FL_NOTARGET)
 128                 return FALSE; // enemy can't be targeted
 129
 130         if not(autocvar_g_monsters_typefrag)
 131         if(targ.BUTTON_CHAT)
 132                 return FALSE; // no typefragging!
 133
 134         if not(IsDifferentTeam(targ, ent))
 135                 return FALSE; // enemy is on our team
 136
 137         if(autocvar_g_monsters_target_infront)
 138         if(ent.enemy != targ)
 139         {
 140                 float dot;
 141
 142                 makevectors (ent.angles);
 143                 dot = normalize (targ.origin - ent.origin) * v_forward;
 144
 145                 if(dot <= 0.3)
 146                         return FALSE;
 147         }
 148
 149         return TRUE;
 150 }
 151
 152 entity FindTarget (entity ent)
 153 {
 154         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 155         entity e;
 156
 157         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 158         if(monster_isvalidtarget(e, ent))
 159                 return e;
 160
 161         return world;
 162 }
 163
 164 void MonsterTouch ()
 165 {
 166         if(other == world)
 167                 return;
 168
 169         if(self.enemy != other)
 170         if not(other.flags & FL_MONSTER)
 171         if(monster_isvalidtarget(other, self))
 172                 self.enemy = other;
 173 }
 174
 175 void monster_sound(string msound, float sound_delay, float delaytoo)
 176 {
 177         if(delaytoo && time < self.msound_delay)
 178                 return; // too early
 179
 180         if(msound == "")
 181                 return; // sound doesn't exist
 182
 183         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 184
 185         self.msound_delay = time + sound_delay;
 186 }
 187
 188 void monster_precachesounds(entity e)
 189 {
 190         precache_sound(e.msound_idle);
 191         precache_sound(e.msound_death);
 192         precache_sound(e.msound_attack_melee);
 193         precache_sound(e.msound_attack_ranged);
 194         precache_sound(e.msound_sight);
 195         precache_sound(e.msound_pain);
 196 }
 197
 198 void monster_setupsounds(string mon)
 199 {
 200         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 201         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 202         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 203         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 204         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 205         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 206 }
 207
 208 float monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 209 {
 210         float dot, rdmg = damg * random();
 211
 212         if (self.health <= 0)
 213                 return FALSE;
 214         if (targ == world)
 215                 return FALSE;
 216
 217         if(dostop)
 218         {
 219                 self.velocity_x = 0;
 220                 self.velocity_y = 0;
 221                 self.state = MONSTER_STATE_ATTACK_MELEE;
 222                 self.SendFlags |= MSF_MOVE;
 223         }
 224
 225         makevectors (self.angles);
 226         dot = normalize (targ.origin - self.origin) * v_forward;
 227
 228         if(dot > er)
 229                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 230
 231         return TRUE;
 232 }
 233
 234 void Monster_CheckDropCvars (string mon)
 235 {
 236         if not(self.candrop)
 237                 return; // forced off
 238
 239         string dropitem;
 240         string dropsize;
 241
 242         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 243         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 244
 245         if(autocvar_g_monsters_forcedrop)
 246                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 247         else if(dropitem != "")
 248                 Monster_DropItem(dropitem, dropsize);
 249         else
 250                 Monster_DropItem("armor", "medium");
 251 }
 252
 253 void Monster_CheckMinibossFlag ()
 254 {
 255         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 256                 return;
 257
 258         float chance = random() * 100;
 259
 260         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 261         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 262         {
 263                 self.health += autocvar_g_monsters_miniboss_healthboost;
 264                 self.flags |= MONSTERFLAG_MINIBOSS;
 265                 if not(self.weapon)
 266                         self.weapon = WEP_NEX;
 267         }
 268 }
 269
 270 float Monster_CanRespawn(entity ent)
 271 {
 272         other = ent;
 273         if(MUTATOR_CALLHOOK(MonsterRespawn))
 274                 return TRUE; // enabled by a mutator
 275
 276         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 277                 return FALSE;
 278
 279         if not(autocvar_g_monsters_respawn)
 280                 return FALSE;
 281
 282         return TRUE;
 283 }
 284
 285 void Monster_Fade ()
 286 {
 287         if(Monster_CanRespawn(self))
 288         {
 289                 self.monster_respawned = TRUE;
 290                 self.think = self.monster_spawnfunc;
 291                 self.nextthink = time + self.respawntime;
 292                 self.deadflag = DEAD_RESPAWNING;
 293                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 294                 {
 295                         self.pos1 = self.origin;
 296                         self.pos2 = self.angles;
 297                 }
 298                 self.event_damage = func_null;
 299                 self.takedamage = DAMAGE_NO;
 300                 setorigin(self, self.pos1);
 301                 self.angles = self.pos2;
 302                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 303
 304                 self.SendFlags |= MSF_MOVE;
 305                 self.SendFlags |= MSF_STATUS;
 306
 307                 return;
 308         }
 309         SUB_SetFade(self, time + 3, 1);
 310 }
 311
 312 float Monster_CanJump (vector vel)
 313 {
 314         if(self.state)
 315                 return FALSE; // already attacking
 316         if not(self.flags & FL_ONGROUND)
 317                 return FALSE; // not on the ground
 318         if(self.health <= 0)
 319                 return FALSE; // called when dead?
 320         if(time < self.attack_finished_single)
 321                 return FALSE; // still attacking
 322
 323         vector old = self.velocity;
 324
 325         self.velocity = vel;
 326         tracetoss(self, self);
 327         self.velocity = old;
 328         if (trace_ent != self.enemy)
 329                 return FALSE;
 330
 331         return TRUE;
 332 }
 333
 334 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 335 {
 336         if(!Monster_CanJump(vel))
 337                 return FALSE;
 338
 339         monsters_setframe(anm);
 340         self.state = MONSTER_STATE_ATTACK_LEAP;
 341         self.touch = touchfunc;
 342         self.origin_z += 1;
 343         self.velocity = vel;
 344         self.flags &~= FL_ONGROUND;
 345
 346         self.attack_finished_single = time + anim_finished;
 347
 348         return TRUE;
 349 }
 350
 351 void monster_checkattack(entity e, entity targ)
 352 {
 353         if(e == world)
 354                 return;
 355         if(targ == world)
 356                 return;
 357
 358         if not(e.monster_attackfunc)
 359                 return;
 360
 361         if(time < e.attack_finished_single)
 362                 return;
 363
 364         if(vlen(targ.origin - e.origin) <= e.attack_range)
 365         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 366         {
 367                 monster_sound(e.msound_attack_melee, 0, FALSE);
 368                 return;
 369         }
 370
 371         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 372         {
 373                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 374                 return;
 375         }
 376 }
 377
 378 void monster_makevectors(entity e)
 379 {
 380         vector v;
 381
 382         v = CENTER_OR_VIEWOFS(e);
 383         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 384         self.v_angle_x = -self.v_angle_x;
 385
 386         makevectors(self.v_angle);
 387 }
 388
 389 void monster_use ()
 390 {
 391         if (self.enemy)
 392                 return;
 393         if (self.health <= 0)
 394                 return;
 395
 396         if(!monster_isvalidtarget(activator, self))
 397                 return;
 398
 399         self.enemy = activator;
 400 }
 401
 402 float trace_path(vector from, vector to)
 403 {
 404         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 405         float trace1 = trace_fraction;
 406
 407         offset_x = dir_y;
 408         offset_y = -dir_x;
 409         traceline (from+offset, to+offset, TRUE, self);
 410
 411         traceline(from-offset, to-offset, TRUE, self);
 412
 413         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 414 }
 415
 416 .float last_trace;
 417 .float last_enemycheck; // for checking enemy
 418 vector monster_pickmovetarget(entity targ)
 419 {
 420         // enemy is always preferred target
 421         if(self.enemy)
 422         {
 423                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 424                 self.last_trace = time + 1.2;
 425                 return self.enemy.origin;
 426         }
 427
 428         switch(self.monster_moveflags)
 429         {
 430                 case MONSTER_MOVE_OWNER:
 431                 {
 432                         self.monster_movestate = MONSTER_MOVE_OWNER;
 433                         self.last_trace = time + 0.3;
 434                         if(self.monster_owner && self.monster_owner.classname != "td_spawnpoint")
 435                                 return self.monster_owner.origin;
 436                 }
 437                 case MONSTER_MOVE_SPAWNLOC:
 438                 {
 439                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 440                         self.last_trace = time + 2;
 441                         return self.pos1;
 442                 }
 443                 case MONSTER_MOVE_NOMOVE:
 444                 {
 445                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 446                         self.last_trace = time + 2;
 447                         return self.origin;
 448                 }
 449                 default:
 450                 case MONSTER_MOVE_WANDER:
 451                 {
 452                         vector pos;
 453                         self.monster_movestate = MONSTER_MOVE_WANDER;
 454                         self.last_trace = time + 2;
 455
 456                         self.angles_y = random() * 500;
 457                         makevectors(self.angles);
 458                         pos = self.origin + v_forward * 600;
 459
 460                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 461                         {
 462                                 pos_z = random() * 200;
 463                                 if(random() >= 0.5)
 464                                         pos_z *= -1;
 465                         }
 466
 467                         if(targ)
 468                         {
 469                                 self.last_trace = time + 0.5;
 470                                 pos = targ.origin;
 471                         }
 472
 473                         return pos;
 474                 }
 475         }
 476 }
 477
 478 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 479 {
 480         fixedmakevectors(self.angles);
 481
 482         if(self.target2)
 483                 self.goalentity = find(world, targetname, self.target2);
 484
 485         entity targ;
 486
 487         if(self.frozen)
 488         {
 489                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 490                 self.health = max(1, self.max_health * self.revive_progress);
 491
 492                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 493
 494                 movelib_beak_simple(stopspeed);
 495
 496                 self.velocity = '0 0 0';
 497                 self.enemy = world;
 498                 self.nextthink = time + 0.1;
 499
 500                 if(self.revive_progress >= 1)
 501                         Unfreeze(self); // wait for next think before attacking
 502
 503                 self.SendFlags |= MSF_MOVE;
 504
 505                 return; // no moving while frozen
 506         }
 507
 508         if(self.flags & FL_SWIM)
 509         {
 510                 if(self.waterlevel < WATERLEVEL_WETFEET)
 511                 {
 512                         if(time >= self.last_trace)
 513                         {
 514                                 self.last_trace = time + 0.4;
 515
 516                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 517                                 self.angles = '90 90 0';
 518                                 if(random() < 0.5)
 519                                 {
 520                                         self.velocity_y += random() * 50;
 521                                         self.velocity_x -= random() * 50;
 522                                 }
 523                                 else
 524                                 {
 525                                         self.velocity_y -= random() * 50;
 526                                         self.velocity_x += random() * 50;
 527                                 }
 528                                 self.velocity_z += random() * 150;
 529                         }
 530
 531
 532                         self.movetype = MOVETYPE_BOUNCE;
 533                         //self.velocity_z = -200;
 534
 535                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 536
 537                         return;
 538                 }
 539                 else
 540                 {
 541                         self.angles = '0 0 0';
 542                         self.movetype = MOVETYPE_WALK;
 543                 }
 544         }
 545
 546         targ = self.goalentity;
 547
 548         monster_target = targ;
 549         monster_speed_run = runspeed;
 550         monster_speed_walk = walkspeed;
 551
 552         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 553         {
 554                 runspeed = walkspeed = 0;
 555                 if(time >= self.spawn_time)
 556                         monsters_setframe(manim_idle);
 557                 movelib_beak_simple(stopspeed);
 558                 self.SendFlags |= MSF_MOVE;
 559                 return;
 560         }
 561
 562         targ = monster_target;
 563         runspeed = monster_speed_run;
 564         walkspeed = monster_speed_walk;
 565
 566         if(IsDifferentTeam(self.monster_owner, self))
 567                 self.monster_owner = world;
 568
 569         if(time >= self.last_enemycheck)
 570         {
 571                 if not(monster_isvalidtarget(self.enemy, self))
 572                         self.enemy = world;
 573                 self.last_enemycheck = time + 2;
 574         }
 575
 576         if(self.enemy && self.enemy.health < 1)
 577                 self.enemy = world; // enough!
 578
 579         if not(self.enemy)
 580         {
 581                 self.enemy = FindTarget(self);
 582                 if(self.enemy)
 583                         monster_sound(self.msound_sight, 0, FALSE);
 584         }
 585
 586         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 587                 self.state = 0;
 588
 589         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 590         if(time >= self.last_trace || self.enemy) // update enemy instantly
 591                 self.moveto = monster_pickmovetarget(targ);
 592
 593         if not(self.enemy)
 594                 monster_sound(self.msound_idle, 5, TRUE);
 595
 596         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 597                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 598
 599         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 600         {
 601                 self.state = 0;
 602                 self.touch = MonsterTouch;
 603         }
 604
 605         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 606
 607         float turny = 0;
 608         vector real_angle = vectoangles(self.steerto) - self.angles;
 609
 610         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 611                 turny = 20;
 612
 613         if(self.flags & FL_SWIM)
 614                 turny = vlen(self.angles - self.moveto);
 615
 616         if(turny)
 617         {
 618                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 619                 self.angles_y += turny;
 620         }
 621
 622         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 623                 self.moveto = self.origin;
 624         else if(self.enemy)
 625                 self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 626
 627         if not(self.flags & FL_FLY || self.flags & FL_SWIM)
 628                 self.moveto_z = self.origin_z;
 629
 630         float l = vlen(self.moveto - self.origin);
 631         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 632         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 633
 634         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 635                 v_forward = normalize(self.moveto - self.origin);
 636
 637         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 638         if(self.flags & FL_ONGROUND)
 639                 movelib_jump_simple(100);
 640
 641         if(vlen(self.origin - self.moveto) > 64)
 642         {
 643                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 644                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 645                 else
 646                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 647                 if(time > self.pain_finished)
 648                 if(time > self.attack_finished_single)
 649                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 650         }
 651         else
 652         {
 653                 entity e = find(world, targetname, self.target2);
 654                 if(e.target2)
 655                         self.target2 = e.target2;
 656                 else if(e.target)
 657                         self.target2 = e.target;
 658
 659                 movelib_beak_simple(stopspeed);
 660                 if(time > self.attack_finished_single)
 661                 if(time > self.pain_finished)
 662                 if (vlen(self.velocity) <= 30)
 663                         monsters_setframe(manim_idle);
 664         }
 665
 666         monster_checkattack(self, self.enemy);
 667
 668         self.SendFlags |= MSF_ANG;
 669         self.SendFlags |= MSF_MOVE;
 670 }
 671
 672 void monster_dead_think()
 673 {
 674         self.think = monster_dead_think;
 675         self.nextthink = time + 0.3; // don't need to update so often now
 676
 677         self.deadflag = DEAD_DEAD;
 678
 679         if(time >= self.ltime)
 680         {
 681                 Monster_Fade();
 682                 return;
 683         }
 684
 685         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 686 }
 687
 688 void monsters_setstatus()
 689 {
 690         self.stat_monsters_total = monsters_total;
 691         self.stat_monsters_killed = monsters_killed;
 692 }
 693
 694 void Monster_Appear()
 695 {
 696         self.enemy = activator;
 697         self.spawnflags &~= MONSTERFLAG_APPEAR;
 698         self.monster_spawnfunc();
 699 }
 700
 701 float Monster_CheckAppearFlags(entity ent)
 702 {
 703         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 704                 return FALSE;
 705
 706         ent.think = func_null;
 707         ent.nextthink = 0;
 708         ent.use = Monster_Appear;
 709         ent.flags = FL_MONSTER; // set so this monster can get butchered
 710
 711         return TRUE;
 712 }
 713
 714 void monsters_reset()
 715 {
 716         setorigin(self, self.pos1);
 717         self.angles = self.pos2;
 718
 719         self.health = self.max_health;
 720         self.velocity = '0 0 0';
 721         self.enemy = world;
 722         self.goalentity = world;
 723         self.attack_finished_single = 0;
 724         self.moveto = self.origin;
 725
 726         WaypointSprite_UpdateHealth(self.sprite, self.health);
 727 }
 728
 729 float monster_send(entity to, float sf)
 730 {
 731         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 732         WriteByte(MSG_ENTITY, sf);
 733         if(sf & MSF_SETUP)
 734         {
 735             WriteByte(MSG_ENTITY, self.monsterid);
 736
 737             WriteCoord(MSG_ENTITY, self.origin_x);
 738             WriteCoord(MSG_ENTITY, self.origin_y);
 739             WriteCoord(MSG_ENTITY, self.origin_z);
 740
 741             WriteAngle(MSG_ENTITY, self.angles_x);
 742             WriteAngle(MSG_ENTITY, self.angles_y);
 743
 744                 WriteByte(MSG_ENTITY, self.skin);
 745                 WriteByte(MSG_ENTITY, self.team);
 746     }
 747
 748     if(sf & MSF_ANG)
 749     {
 750         WriteShort(MSG_ENTITY, rint(self.angles_x));
 751         WriteShort(MSG_ENTITY, rint(self.angles_y));
 752     }
 753
 754     if(sf & MSF_MOVE)
 755     {
 756         WriteShort(MSG_ENTITY, rint(self.origin_x));
 757         WriteShort(MSG_ENTITY, rint(self.origin_y));
 758         WriteShort(MSG_ENTITY, rint(self.origin_z));
 759
 760         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 761         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 762         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 763
 764         WriteShort(MSG_ENTITY, rint(self.angles_y));
 765     }
 766
 767     if(sf & MSF_ANIM)
 768     {
 769         WriteCoord(MSG_ENTITY, self.anim_start_time);
 770         WriteByte(MSG_ENTITY, self.frame);
 771     }
 772
 773     if(sf & MSF_STATUS)
 774     {
 775                 WriteByte(MSG_ENTITY, self.skin);
 776
 777         WriteByte(MSG_ENTITY, self.team);
 778
 779                 WriteByte(MSG_ENTITY, self.deadflag);
 780
 781         if(self.health <= 0)
 782             WriteByte(MSG_ENTITY, 0);
 783         else
 784             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 785     }
 786
 787         return TRUE;
 788 }
 789
 790 void monster_link(void() spawnproc)
 791 {
 792     Net_LinkEntity(self, TRUE, 0, monster_send);
 793     self.think      = spawnproc;
 794     self.nextthink  = time;
 795 }
 796
 797 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 798 {
 799         self.health -= damage;
 800
 801         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 802
 803         if(self.health <= -100) // 100 health until gone?
 804         {
 805                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 806
 807                 self.think = SUB_Remove;
 808                 self.nextthink = time + 0.1;
 809         }
 810 }
 811
 812 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 813 {
 814         if(self.frozen && deathtype != DEATH_KILL)
 815                 return;
 816
 817         if(time < self.pain_finished && deathtype != DEATH_KILL)
 818                 return;
 819
 820         if(time < self.spawnshieldtime)
 821                 return;
 822
 823         if(deathtype != DEATH_KILL)
 824                 damage *= self.armorvalue;
 825
 826         if(self.weaponentity && self.weaponentity.classname == "shield")
 827                 self.weaponentity.health -= damage;
 828
 829         self.health -= damage;
 830
 831         if(self.sprite)
 832                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 833
 834         self.dmg_time = time;
 835
 836         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 837                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 838
 839         self.velocity += force * self.damageforcescale;
 840
 841         if(deathtype != DEATH_DROWN)
 842         {
 843                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 844                 if (damage > 50)
 845                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 846                 if (damage > 100)
 847                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 848         }
 849
 850         if(self.health <= 0)
 851         {
 852                 if(self.sprite)
 853                 {
 854                         // Update one more time to avoid waypoint fading without emptying healthbar
 855                         WaypointSprite_UpdateHealth(self.sprite, 0);
 856                 }
 857
 858                 if(deathtype == DEATH_KILL)
 859                         self.candrop = FALSE; // killed by mobkill command
 860
 861                 // TODO: fix this?
 862                 activator = attacker;
 863                 other = self.enemy;
 864                 SUB_UseTargets();
 865                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 866
 867                 self.monster_die();
 868
 869                 frag_attacker = attacker;
 870                 frag_target = self;
 871                 MUTATOR_CALLHOOK(MonsterDies);
 872
 873                 if(self.health <= -100) // check if we're already gibbed
 874                 {
 875                         Violence_GibSplash(self, 1, 0.5, attacker);
 876
 877                         self.think = SUB_Remove;
 878                         self.nextthink = time + 0.1;
 879                 }
 880         }
 881
 882         self.SendFlags |= MSF_STATUS;
 883 }
 884
 885 // post-death functions
 886 void monster_hook_death()
 887 {
 888         WaypointSprite_Kill(self.sprite);
 889
 890         if(self.weaponentity)
 891         {
 892                 remove(self.weaponentity);
 893                 self.weaponentity = world;
 894         }
 895
 896         monster_sound(self.msound_death, 0, FALSE);
 897
 898         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 899                 monsters_killed += 1;
 900
 901         if(self.candrop && self.weapon)
 902                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 903
 904         if(IS_CLIENT(self.realowner))
 905                 self.realowner.monstercount -= 1;
 906
 907         self.event_damage       = monsters_corpse_damage;
 908         self.solid                      = SOLID_CORPSE;
 909         self.takedamage         = DAMAGE_AIM;
 910         self.enemy                      = world;
 911         self.movetype           = MOVETYPE_TOSS;
 912         self.moveto                     = self.origin;
 913         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 914
 915         if not(self.flags & FL_FLY)
 916                 self.velocity = '0 0 0';
 917
 918         self.SendFlags |= MSF_MOVE;
 919
 920         totalspawned -= 1;
 921 }
 922
 923 // post-spawn functions
 924 void monster_hook_spawn()
 925 {
 926         if not(self.monster_respawned)
 927                 Monster_CheckMinibossFlag();
 928
 929         self.max_health = self.health;
 930         self.pain_finished = self.nextthink;
 931         self.anim_start_time = time;
 932
 933         if not(self.noalign)
 934         {
 935                 setorigin(self, self.origin + '0 0 20');
 936                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 937                 setorigin(self, trace_endpos);
 938         }
 939
 940         if not(self.monster_respawned)
 941         if not(self.skin)
 942                 self.skin = rint(random() * 4);
 943
 944         self.pos1 = self.origin;
 945
 946         monster_precachesounds(self);
 947
 948         if(teamplay)
 949                 self.monster_attack = TRUE; // we can have monster enemies in team games
 950
 951         if(autocvar_g_monsters_healthbars)
 952         {
 953                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 954                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 955                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 956         }
 957
 958         monster_sound(self.msound_spawn, 0, FALSE);
 959
 960         MUTATOR_CALLHOOK(MonsterSpawn);
 961
 962         self.SendFlags = MSF_SETUP;
 963 }
 964
 965 float monster_initialize(string  net_name, float mon_id,
 966                                                  vector  min_s,
 967                                                  vector  max_s,
 968                                                  float   nodrop,
 969                                                  void() dieproc,
 970                                                  void() spawnproc)
 971 {
 972         if not(autocvar_g_monsters)
 973                 return FALSE;
 974
 975         // support for quake style removing monsters based on skill
 976         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 977         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 978         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 979         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 980         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 981
 982         if(self.netname == "")
 983                 self.netname = ((net_name == "") ? self.classname : net_name);
 984
 985         if(self.team && !teamplay)
 986                 self.team = 0;
 987
 988         self.flags = FL_MONSTER;
 989
 990         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 991         if not(self.monster_respawned)
 992                 monsters_total += 1;
 993
 994         setsize(self, min_s, max_s);
 995         self.takedamage                 = DAMAGE_AIM;
 996         self.bot_attack                 = TRUE;
 997         self.iscreature                 = TRUE;
 998         self.teleportable               = TRUE;
 999         self.damagedbycontents  = TRUE;
1000         self.monsterid                  = mon_id;
1001         self.damageforcescale   = 0.003;
1002         self.monster_die                = dieproc;
1003         self.event_damage               = monsters_damage;
1004         self.touch                              = MonsterTouch;
1005         self.use                                = monster_use;
1006         self.solid                              = SOLID_BBOX;
1007         self.scale                              = 1;
1008         self.movetype                   = MOVETYPE_WALK;
1009         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1010         monsters_spawned           += 1;
1011         self.enemy                              = world;
1012         self.velocity                   = '0 0 0';
1013         self.moveto                             = self.origin;
1014         self.pos2                               = self.angles;
1015         self.reset                              = monsters_reset;
1016         self.candrop                    = TRUE;
1017         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1018         self.oldtarget2                 = self.target2;
1019         self.deadflag                   = DEAD_NO; // UNDEAD
1020         self.noalign                    = nodrop;
1021         self.spawn_time                 = time;
1022         self.gravity                    = 1;
1023         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1024
1025         if not(self.attack_range)
1026                 self.attack_range = 120;
1027
1028         if not(self.ticrate)
1029                 self.ticrate = autocvar_g_monsters_think_delay;
1030
1031         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1032
1033         if not(self.armorvalue)
1034                 self.armorvalue = 1; // multiplier
1035
1036         if not(self.target_range)
1037                 self.target_range = autocvar_g_monsters_target_range;
1038
1039         if not(self.respawntime)
1040                 self.respawntime = autocvar_g_monsters_respawn_delay;
1041
1042         if not(self.monster_moveflags)
1043                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1044
1045         monster_link(spawnproc);
1046
1047         return TRUE;
1048 }