qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void monster_item_spawn()
  14 {
  15         self.monster_delayedattack();
  16
  17         self.gravity = 1;
  18         self.velocity = randomvec() * 175 + '0 0 325';
  19         self.touch = M_Item_Touch;
  20
  21         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  22 }
  23
  24 void Monster_DropItem (string itype, string itemsize)
  25 {
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         switch(itype)
  32         {
  33                 case "armor":
  34                 {
  35                         switch(itemsize)
  36                         {
  37                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  38                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  39                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  40                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  41                         }
  42                         break; // break here?
  43                 }
  44                 case "health":
  45                 {
  46                         switch(itemsize)
  47                         {
  48                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  49                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  50                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  51                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  52                         }
  53                         break; // break here?
  54                 }
  55                 case "ammo":
  56                 {
  57                         switch(itemsize)
  58                         {
  59                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  60                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  61                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  62                                 case "bullets":
  63                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  64                         }
  65                         break;
  66                 }
  67         }
  68
  69         if(g_minstagib)
  70                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  71
  72         e.think = monster_item_spawn;
  73         e.nextthink = time + 0.1;
  74 }
  75
  76 void monsters_setframe(float _frame)
  77 {
  78         if(self.frame == _frame)
  79                 return;
  80
  81         self.anim_start_time = time;
  82         self.frame = _frame;
  83         self.SendFlags |= MSF_ANIM;
  84 }
  85
  86 float monster_isvalidtarget (entity targ, entity ent)
  87 {
  88         if(!targ || !ent)
  89                 return FALSE; // someone doesn't exist
  90
  91         if(time < game_starttime)
  92                 return FALSE; // monsters do nothing before the match has started
  93
  94         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  95
  96         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  97                 return FALSE; // enemy is too far away
  98
  99         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 100         if(trace_ent != targ)
 101                 return FALSE; // we can't see the enemy
 102
 103         if(targ.takedamage == DAMAGE_NO)
 104                 return FALSE; // enemy can't be damaged
 105
 106         if(targ.items & IT_INVISIBILITY)
 107                 return FALSE; // enemy is invisible
 108
 109         if(substring(targ.classname, 0, 10) == "onslaught_")
 110                 return FALSE; // don't attack onslaught targets
 111
 112         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 113                 return FALSE; // enemy is a spectator
 114
 115         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 116         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 117                 return FALSE; // enemy/self is dead
 118
 119         if(targ.monster_owner == ent || ent.monster_owner == targ)
 120                 return FALSE; // enemy owns us, or we own them
 121
 122         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 123         if(targ.flags & FL_NOTARGET)
 124                 return FALSE; // enemy can't be targetted
 125
 126         if not(autocvar_g_monsters_typefrag)
 127         if(targ.BUTTON_CHAT)
 128                 return FALSE; // no typefragging!
 129
 130         if not(IsDifferentTeam(targ, ent))
 131                 return FALSE; // enemy is on our team
 132
 133         if(autocvar_g_monsters_target_infront)
 134         if(ent.enemy != targ)
 135         {
 136                 float dot;
 137
 138                 makevectors (ent.angles);
 139                 dot = normalize (targ.origin - ent.origin) * v_forward;
 140
 141                 if(dot <= 0.3)
 142                         return FALSE;
 143         }
 144
 145         return TRUE;
 146 }
 147
 148 entity FindTarget (entity ent)
 149 {
 150         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 151         entity e;
 152
 153         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 154         if(monster_isvalidtarget(e, ent))
 155                 return e;
 156
 157         return world;
 158 }
 159
 160 void MonsterTouch ()
 161 {
 162         if(other == world)
 163                 return;
 164
 165         if(self.enemy != other)
 166         if not(other.flags & FL_MONSTER)
 167         if(monster_isvalidtarget(other, self))
 168                 self.enemy = other;
 169 }
 170
 171 void monster_sound(string msound, float sound_delay, float delaytoo)
 172 {
 173         if(delaytoo && time < self.msound_delay)
 174                 return; // too early
 175
 176         if(msound == "")
 177                 return; // sound doesn't exist
 178
 179         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 180
 181         self.msound_delay = time + sound_delay;
 182 }
 183
 184 void monster_precachesounds(entity e)
 185 {
 186         precache_sound(e.msound_idle);
 187         precache_sound(e.msound_death);
 188         precache_sound(e.msound_attack_melee);
 189         precache_sound(e.msound_attack_ranged);
 190         precache_sound(e.msound_sight);
 191         precache_sound(e.msound_pain);
 192 }
 193
 194 void monster_setupsounds(string mon)
 195 {
 196         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 197         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 198         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 199         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 200         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 201         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 202 }
 203
 204 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 205 {
 206         float dot, rdmg = damg * random();
 207
 208         if (self.health <= 0)
 209                 return;
 210         if (targ == world)
 211                 return;
 212
 213         if(dostop)
 214         {
 215                 self.velocity_x = 0;
 216                 self.velocity_y = 0;
 217                 self.state = MONSTER_STATE_ATTACK_MELEE;
 218                 self.SendFlags |= MSF_MOVE;
 219         }
 220
 221         makevectors (self.angles);
 222         dot = normalize (targ.origin - self.origin) * v_forward;
 223
 224         if(dot > er)
 225                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 226 }
 227
 228 void Monster_CheckDropCvars (string mon)
 229 {
 230         if not(self.candrop)
 231                 return; // forced off
 232
 233         string dropitem;
 234         string dropsize;
 235
 236         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 237         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 238
 239         monster_dropitem = dropitem;
 240         monster_dropsize = dropsize;
 241         MUTATOR_CALLHOOK(MonsterDropItem);
 242         dropitem = monster_dropitem;
 243         dropsize = monster_dropsize;
 244
 245         if(autocvar_g_monsters_forcedrop)
 246                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 247         else if(dropitem != "")
 248                 Monster_DropItem(dropitem, dropsize);
 249         else
 250                 Monster_DropItem("armor", "medium");
 251 }
 252
 253 void Monster_CheckMinibossFlag ()
 254 {
 255         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 256                 return;
 257
 258         float chance = random() * 100;
 259
 260         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 261         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 262         {
 263                 self.health += autocvar_g_monsters_miniboss_healthboost;
 264                 self.flags |= MONSTERFLAG_MINIBOSS;
 265                 if not(self.weapon)
 266                         self.weapon = WEP_NEX;
 267         }
 268 }
 269
 270 float Monster_CanRespawn(entity ent)
 271 {
 272         other = ent;
 273         if(MUTATOR_CALLHOOK(MonsterRespawn))
 274                 return TRUE; // enabled by a mutator
 275
 276         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 277                 return FALSE;
 278
 279         if not(autocvar_g_monsters_respawn)
 280                 return FALSE;
 281
 282         return TRUE;
 283 }
 284
 285 void Monster_Fade ()
 286 {
 287         if(Monster_CanRespawn(self))
 288         {
 289                 self.monster_respawned = TRUE;
 290                 self.think = self.monster_spawnfunc;
 291                 self.nextthink = time + self.respawntime;
 292                 self.deadflag = DEAD_RESPAWNING;
 293                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 294                 {
 295                         self.pos1 = self.origin;
 296                         self.pos2 = self.angles;
 297                 }
 298                 self.event_damage = func_null;
 299                 self.takedamage = DAMAGE_NO;
 300                 setorigin(self, self.pos1);
 301                 self.angles = self.pos2;
 302                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 303
 304                 self.SendFlags |= MSF_MOVE;
 305                 self.SendFlags |= MSF_STATUS;
 306
 307                 return;
 308         }
 309         SUB_SetFade(self, time + 3, 1);
 310 }
 311
 312 float Monster_CanJump (vector vel)
 313 {
 314         if(self.state)
 315                 return FALSE; // already attacking
 316         if not(self.flags & FL_ONGROUND)
 317                 return FALSE; // not on the ground
 318         if(self.health <= 0)
 319                 return FALSE; // called when dead?
 320         if(time < self.attack_finished_single)
 321                 return FALSE; // still attacking
 322
 323         vector old = self.velocity;
 324
 325         self.velocity = vel;
 326         tracetoss(self, self);
 327         self.velocity = old;
 328         if (trace_ent != self.enemy)
 329                 return FALSE;
 330
 331         return TRUE;
 332 }
 333
 334 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 335 {
 336         if(!Monster_CanJump(vel))
 337                 return FALSE;
 338
 339         monsters_setframe(anm);
 340         self.state = MONSTER_STATE_ATTACK_LEAP;
 341         self.touch = touchfunc;
 342         self.origin_z += 1;
 343         self.velocity = vel;
 344         self.flags &~= FL_ONGROUND;
 345
 346         self.attack_finished_single = time + anim_finished;
 347
 348         return TRUE;
 349 }
 350
 351 float GenericCheckAttack ()
 352 {
 353         // checking attack while dead?
 354         if (self.health <= 0)
 355                 return FALSE;
 356
 357         // reset delays when we have no enemy
 358         if not(self.enemy)
 359         {
 360                 self.monster_delayedattack = func_null;
 361                 self.delay = -1;
 362         }
 363
 364         if(self.monster_delayedattack && self.delay != -1)
 365         {
 366                 if(time < self.delay)
 367                         return FALSE;
 368
 369                 self.monster_delayedattack();
 370         }
 371
 372         if (time < self.attack_finished_single)
 373                 return FALSE;
 374
 375         if(self.attack_melee)
 376         if(vlen(self.enemy.origin - self.origin) <= 100)
 377         {
 378                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 379                 self.attack_melee(); // don't wait for nextthink - too slow
 380                 return TRUE;
 381         }
 382
 383         // monster doesn't have a ranged attack function, so stop here
 384         if not(self.attack_ranged)
 385                 return FALSE;
 386
 387         // see if any entities are in the way of the shot
 388         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 389                 return FALSE;
 390
 391         if(self.attack_ranged())
 392         {
 393                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 394                 return TRUE;
 395         }
 396
 397         return FALSE;
 398 }
 399
 400 void monster_use ()
 401 {
 402         if (self.enemy)
 403                 return;
 404         if (self.health <= 0)
 405                 return;
 406
 407         if(!monster_isvalidtarget(activator, self))
 408                 return;
 409
 410         self.enemy = activator;
 411 }
 412
 413 float trace_path(vector from, vector to)
 414 {
 415         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 416         float trace1 = trace_fraction;
 417
 418         offset_x = dir_y;
 419         offset_y = -dir_x;
 420         traceline (from+offset, to+offset, TRUE, self);
 421
 422         traceline(from-offset, to-offset, TRUE, self);
 423
 424         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 425 }
 426
 427 .float last_trace;
 428 vector monster_pickmovetarget(entity targ)
 429 {
 430         // enemy is always preferred target
 431         if(self.enemy)
 432         {
 433                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 434                 self.last_trace = time + 0.1;
 435                 return self.enemy.origin;
 436         }
 437
 438         switch(self.monster_moveflags)
 439         {
 440                 case MONSTER_MOVE_OWNER:
 441                 {
 442                         self.monster_movestate = MONSTER_MOVE_OWNER;
 443                         self.last_trace = time + 0.3;
 444                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 445                                 return self.monster_owner.origin;
 446                 }
 447                 case MONSTER_MOVE_SPAWNLOC:
 448                 {
 449                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 450                         self.last_trace = time + 2;
 451                         return self.pos1;
 452                 }
 453                 case MONSTER_MOVE_NOMOVE:
 454                 {
 455                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 456                         self.last_trace = time + 2;
 457                         return self.origin;
 458                 }
 459                 default:
 460                 case MONSTER_MOVE_WANDER:
 461                 {
 462                         vector pos;
 463                         self.monster_movestate = MONSTER_MOVE_WANDER;
 464                         self.last_trace = time + 2;
 465
 466                         self.angles_y = random() * 500;
 467                         makevectors(self.angles);
 468                         pos = self.origin + v_forward * 600;
 469
 470                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 471                         {
 472                                 pos_z = random() * 200;
 473                                 if(random() >= 0.5)
 474                                         pos_z *= -1;
 475                         }
 476
 477                         if(targ)
 478                         {
 479                                 self.last_trace = time + 0.5;
 480                                 pos = targ.origin;
 481                         }
 482
 483                         return pos;
 484                 }
 485         }
 486 }
 487
 488 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 489 {
 490         if(self.target2)
 491                 self.goalentity = find(world, targetname, self.target2);
 492
 493         entity targ;
 494
 495         if(self.frozen)
 496         {
 497                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 498                 self.health = max(1, self.max_health * self.revive_progress);
 499
 500                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 501
 502                 movelib_beak_simple(stopspeed);
 503
 504                 self.velocity = '0 0 0';
 505                 self.enemy = world;
 506                 self.nextthink = time + 0.1;
 507
 508                 if(self.revive_progress >= 1)
 509                         Unfreeze(self); // wait for next think before attacking
 510
 511                 self.SendFlags |= MSF_MOVE;
 512
 513                 return; // no moving while frozen
 514         }
 515
 516         if(self.flags & FL_SWIM)
 517         {
 518                 if(self.waterlevel < WATERLEVEL_WETFEET)
 519                 {
 520                         if(time >= self.last_trace)
 521                         {
 522                                 self.last_trace = time + 0.4;
 523
 524                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 525                                 self.angles = '90 90 0';
 526                                 if(random() < 0.5)
 527                                 {
 528                                         self.velocity_y += random() * 50;
 529                                         self.velocity_x -= random() * 50;
 530                                 }
 531                                 else
 532                                 {
 533                                         self.velocity_y -= random() * 50;
 534                                         self.velocity_x += random() * 50;
 535                                 }
 536                                 self.velocity_z += random() * 150;
 537                         }
 538
 539
 540                         self.movetype = MOVETYPE_BOUNCE;
 541                         //self.velocity_z = -200;
 542
 543                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 544
 545                         return;
 546                 }
 547                 else
 548                 {
 549                         self.angles = '0 0 0';
 550                         self.movetype = MOVETYPE_WALK;
 551                 }
 552         }
 553
 554         targ = self.goalentity;
 555
 556         monster_target = targ;
 557         monster_speed_run = runspeed;
 558         monster_speed_walk = walkspeed;
 559
 560         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 561         {
 562                 runspeed = walkspeed = 0;
 563                 if(time >= self.spawn_time)
 564                         monsters_setframe(manim_idle);
 565                 movelib_beak_simple(stopspeed);
 566                 self.SendFlags |= MSF_MOVE;
 567                 return;
 568         }
 569
 570         targ = monster_target;
 571         runspeed = monster_speed_run;
 572         walkspeed = monster_speed_walk;
 573
 574         if(IsDifferentTeam(self.monster_owner, self))
 575                 self.monster_owner = world;
 576
 577         if not(monster_isvalidtarget(self.enemy, self))
 578                 self.enemy = world; // check enemy each think frame?
 579
 580         if not(self.enemy)
 581         {
 582                 self.enemy = FindTarget(self);
 583                 if(self.enemy)
 584                         monster_sound(self.msound_sight, 0, FALSE);
 585         }
 586
 587         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 588                 self.state = 0;
 589
 590         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 591         if(time >= self.last_trace || self.enemy) // update enemy instantly
 592                 self.moveto = monster_pickmovetarget(targ);
 593
 594         if not(self.enemy)
 595                 monster_sound(self.msound_idle, 5, TRUE);
 596
 597         vector angles_face = vectoangles(self.moveto - self.origin);
 598         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 599         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 600
 601         if(!(self.flags & FL_FLY || self.flags & FL_SWIM))
 602                 self.moveto_z = self.origin_z;
 603
 604         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 605         {
 606                 self.angles_y = angles_face_y;
 607                 self.v_angle = self.angles;
 608         }
 609
 610         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 611         {
 612                 self.state = 0;
 613                 self.touch = MonsterTouch;
 614         }
 615
 616         v_forward = normalize(self.moveto - self.origin);
 617
 618         float l = vlen(self.moveto - self.origin);
 619         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 620         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 621
 622         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 623         if(self.flags & FL_ONGROUND)
 624                 movelib_jump_simple(100);
 625
 626         if(vlen(self.origin - self.moveto) > 64)
 627         {
 628                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 629                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 630                 else
 631                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 632                 if(time > self.pain_finished)
 633                 if(time > self.attack_finished_single)
 634                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 635         }
 636         else
 637         {
 638                 if(targ.target)
 639                         self.target2 = targ.target;
 640                 else if(targ.target2)
 641                         self.target2 = targ.target2;
 642                 else
 643                 {
 644                         movelib_beak_simple(stopspeed);
 645                         if(time > self.attack_finished_single)
 646                         if(time > self.pain_finished)
 647                         if (vlen(self.velocity) <= 30)
 648                         {
 649                                 monsters_setframe(manim_idle);
 650                                 if(self.enemy)
 651                                         self.angles_y = enemy_face_y;
 652                                 else
 653                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 654                         }
 655                 }
 656         }
 657
 658         if(self.enemy && self.checkattack)
 659                 self.checkattack();
 660
 661         self.SendFlags |= MSF_ANG;
 662         self.SendFlags |= MSF_MOVE;
 663 }
 664
 665 void monster_dead_think()
 666 {
 667         self.think = monster_dead_think;
 668         self.nextthink = time + 0.3; // don't need to update so often now
 669
 670         self.deadflag = DEAD_DEAD;
 671
 672         if(time >= self.ltime)
 673         {
 674                 Monster_Fade();
 675                 return;
 676         }
 677
 678         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 679 }
 680
 681 void monsters_setstatus()
 682 {
 683         self.stat_monsters_total = monsters_total;
 684         self.stat_monsters_killed = monsters_killed;
 685 }
 686
 687 void Monster_Appear()
 688 {
 689         self.enemy = activator;
 690         self.spawnflags &~= MONSTERFLAG_APPEAR;
 691         self.monster_spawnfunc();
 692 }
 693
 694 float Monster_CheckAppearFlags(entity ent)
 695 {
 696         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 697                 return FALSE;
 698
 699         ent.think = func_null;
 700         ent.nextthink = 0;
 701         ent.use = Monster_Appear;
 702         ent.flags = FL_MONSTER; // set so this monster can get butchered
 703
 704         return TRUE;
 705 }
 706
 707 void monsters_reset()
 708 {
 709         setorigin(self, self.pos1);
 710         self.angles = self.pos2;
 711
 712         self.health = self.max_health;
 713         self.velocity = '0 0 0';
 714         self.enemy = world;
 715         self.goalentity = world;
 716         self.attack_finished_single = 0;
 717         self.moveto = self.origin;
 718
 719         WaypointSprite_UpdateHealth(self.sprite, self.health);
 720 }
 721
 722 float monster_send(entity to, float sf)
 723 {
 724         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 725         WriteByte(MSG_ENTITY, sf);
 726         if(sf & MSF_SETUP)
 727         {
 728             WriteByte(MSG_ENTITY, self.monsterid);
 729
 730             WriteCoord(MSG_ENTITY, self.origin_x);
 731             WriteCoord(MSG_ENTITY, self.origin_y);
 732             WriteCoord(MSG_ENTITY, self.origin_z);
 733
 734             WriteAngle(MSG_ENTITY, self.angles_x);
 735             WriteAngle(MSG_ENTITY, self.angles_y);
 736
 737                 WriteByte(MSG_ENTITY, self.skin);
 738     }
 739
 740     if(sf & MSF_ANG)
 741     {
 742         WriteShort(MSG_ENTITY, rint(self.angles_x));
 743         WriteShort(MSG_ENTITY, rint(self.angles_y));
 744     }
 745
 746     if(sf & MSF_MOVE)
 747     {
 748         WriteShort(MSG_ENTITY, rint(self.origin_x));
 749         WriteShort(MSG_ENTITY, rint(self.origin_y));
 750         WriteShort(MSG_ENTITY, rint(self.origin_z));
 751
 752         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 753         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 754         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 755
 756         WriteShort(MSG_ENTITY, rint(self.angles_y));
 757     }
 758
 759     if(sf & MSF_ANIM)
 760     {
 761         WriteCoord(MSG_ENTITY, self.anim_start_time);
 762         WriteByte(MSG_ENTITY, self.frame);
 763     }
 764
 765     if(sf & MSF_STATUS)
 766     {
 767                 WriteByte(MSG_ENTITY, self.skin);
 768
 769         WriteByte(MSG_ENTITY, self.team);
 770
 771                 WriteByte(MSG_ENTITY, self.deadflag);
 772
 773         if(self.health <= 0)
 774             WriteByte(MSG_ENTITY, 0);
 775         else
 776             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 777     }
 778
 779         return TRUE;
 780 }
 781
 782 void monster_link(void() spawnproc)
 783 {
 784     Net_LinkEntity(self, TRUE, 0, monster_send);
 785     self.think      = spawnproc;
 786     self.nextthink  = time;
 787 }
 788
 789 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 790 {
 791         self.health -= damage;
 792
 793         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 794
 795         if(self.health <= -100) // 100 health until gone?
 796         {
 797                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 798
 799                 self.think = SUB_Remove;
 800                 self.nextthink = time + 0.1;
 801         }
 802 }
 803
 804 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 805 {
 806         if(self.frozen && deathtype != DEATH_KILL)
 807                 return;
 808
 809         if(time < self.pain_finished && deathtype != DEATH_KILL)
 810                 return;
 811
 812         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 813         if(monster_isvalidtarget(attacker, self))
 814                 self.enemy = attacker;
 815
 816         if(deathtype != DEATH_KILL)
 817                 damage *= self.armorvalue;
 818
 819         if(self.weaponentity && self.weaponentity.classname == "shield")
 820                 self.weaponentity.health -= damage;
 821
 822         self.health -= damage;
 823
 824         if(self.sprite)
 825                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 826
 827         self.dmg_time = time;
 828
 829         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 830                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 831
 832         self.velocity += force * self.damageforcescale;
 833
 834         if(deathtype != DEATH_DROWN)
 835         {
 836                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 837                 if (damage > 50)
 838                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 839                 if (damage > 100)
 840                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 841         }
 842
 843         if(self.health <= 0)
 844         {
 845                 if(self.sprite)
 846                 {
 847                         // Update one more time to avoid waypoint fading without emptying healthbar
 848                         WaypointSprite_UpdateHealth(self.sprite, 0);
 849                 }
 850
 851                 if(deathtype == DEATH_KILL)
 852                         self.candrop = FALSE; // killed by mobkill command
 853
 854                 // TODO: fix this?
 855                 activator = attacker;
 856                 other = self.enemy;
 857                 SUB_UseTargets();
 858                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 859
 860                 self.monster_die();
 861
 862                 frag_attacker = attacker;
 863                 frag_target = self;
 864                 MUTATOR_CALLHOOK(MonsterDies);
 865
 866                 if(self.health <= -100) // check if we're already gibbed
 867                 {
 868                         Violence_GibSplash(self, 1, 0.5, attacker);
 869
 870                         self.think = SUB_Remove;
 871                         self.nextthink = time + 0.1;
 872                 }
 873         }
 874
 875         self.SendFlags |= MSF_STATUS;
 876 }
 877
 878 // used to hook into monster post death functions without a mutator
 879 void monster_hook_death()
 880 {
 881         WaypointSprite_Kill(self.sprite);
 882
 883         if(self.weaponentity)
 884         {
 885                 remove(self.weaponentity);
 886                 self.weaponentity = world;
 887         }
 888
 889         monster_sound(self.msound_death, 0, FALSE);
 890
 891         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 892                 monsters_killed += 1;
 893
 894         if(self.candrop && self.weapon)
 895                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 896
 897         if(IS_CLIENT(self.realowner))
 898                 self.realowner.monstercount -= 1;
 899
 900         self.event_damage       = monsters_corpse_damage;
 901         self.solid                      = SOLID_CORPSE;
 902         self.takedamage         = DAMAGE_AIM;
 903         self.enemy                      = world;
 904         self.movetype           = MOVETYPE_TOSS;
 905         self.moveto                     = self.origin;
 906
 907         if not(self.flags & FL_FLY)
 908                 self.velocity = '0 0 0';
 909
 910         self.SendFlags |= MSF_MOVE;
 911
 912         totalspawned -= 1;
 913 }
 914
 915 // used to hook into monster post spawn functions without a mutator
 916 void monster_hook_spawn()
 917 {
 918         if not(self.monster_respawned)
 919                 Monster_CheckMinibossFlag();
 920
 921         self.max_health = self.health;
 922         self.pain_finished = self.nextthink;
 923         self.anim_start_time = time;
 924
 925         if not(self.noalign)
 926         {
 927                 setorigin(self, self.origin + '0 0 20');
 928                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 929                 setorigin(self, trace_endpos);
 930         }
 931
 932         if not(self.monster_respawned)
 933                 self.skin = rint(random() * 4);
 934
 935         self.pos1 = self.origin;
 936
 937         monster_precachesounds(self);
 938
 939         if(teamplay)
 940                 self.monster_attack = TRUE; // we can have monster enemies in team games
 941
 942         if(autocvar_g_monsters_healthbars)
 943         {
 944                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 945                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 946                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 947         }
 948
 949         monster_sound(self.msound_spawn, 0, FALSE);
 950
 951         MUTATOR_CALLHOOK(MonsterSpawn);
 952
 953         self.SendFlags = MSF_SETUP;
 954 }
 955
 956 float monster_initialize(string  net_name, float mon_id,
 957                                                  vector  min_s,
 958                                                  vector  max_s,
 959                                                  float   nodrop,
 960                                                  void() dieproc,
 961                                                  void() spawnproc)
 962 {
 963         if not(autocvar_g_monsters)
 964                 return FALSE;
 965
 966         // support for quake style removing monsters based on skill
 967         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 968         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 969         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 970         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 971         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 972
 973         if(self.netname == "")
 974                 self.netname = ((net_name == "") ? self.classname : net_name);
 975
 976         if(self.team && !teamplay)
 977                 self.team = 0;
 978
 979         self.flags = FL_MONSTER;
 980
 981         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 982         if not(self.monster_respawned)
 983                 monsters_total += 1;
 984
 985         setsize(self, min_s, max_s);
 986         self.takedamage                 = DAMAGE_AIM;
 987         self.bot_attack                 = TRUE;
 988         self.iscreature                 = TRUE;
 989         self.teleportable               = TRUE;
 990         self.damagedbycontents  = TRUE;
 991         self.monsterid                  = mon_id;
 992         self.damageforcescale   = 0.003;
 993         self.monster_die                = dieproc;
 994         self.event_damage               = monsters_damage;
 995         self.touch                              = MonsterTouch;
 996         self.use                                = monster_use;
 997         self.solid                              = SOLID_BBOX;
 998         self.scale                              = 1;
 999         self.movetype                   = MOVETYPE_WALK;
1000         self.delay                              = -1; // used in attack delay code
1001         monsters_spawned           += 1;
1002         self.enemy                              = world;
1003         self.velocity                   = '0 0 0';
1004         self.moveto                             = self.origin;
1005         self.pos2                               = self.angles;
1006         self.reset                              = monsters_reset;
1007         self.candrop                    = TRUE;
1008         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1009         self.oldtarget2                 = self.target2;
1010         self.deadflag                   = DEAD_NO; // UNDEAD
1011         self.noalign                    = nodrop;
1012         self.spawn_time                 = time;
1013         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1014
1015         if not(self.ticrate)
1016                 self.ticrate = autocvar_g_monsters_think_delay;
1017
1018         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1019
1020         if not(self.armorvalue)
1021                 self.armorvalue = 1; // multiplier
1022
1023         if not(self.target_range)
1024                 self.target_range = autocvar_g_monsters_target_range;
1025
1026         if not(self.respawntime)
1027                 self.respawntime = autocvar_g_monsters_respawn_delay;
1028
1029         if not(self.monster_moveflags)
1030                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1031
1032         monster_link(spawnproc);
1033
1034         return TRUE;
1035 }