qcsrc/server/mutators/gamemode_ctf.qc

   1 // ================================================================
   2 //  Official capture the flag game mode coding, reworked by Samual
   3 //  Last updated: March 30th, 2012
   4 // ================================================================
   5
   6 float ctf_ReadScore(string parameter) // make this obsolete
   7 {
   8         //if(g_ctf_win_mode != 2)
   9                 return cvar(strcat("g_ctf_personal", parameter));
  10         //else
  11         //      return cvar(strcat("g_ctf_flag", parameter));
  12 }
  13
  14 void ctf_FakeTimeLimit(entity e, float t)
  15 {
  16         msg_entity = e;
  17         WriteByte(MSG_ONE, 3); // svc_updatestat
  18         WriteByte(MSG_ONE, 236); // STAT_TIMELIMIT
  19         if(t < 0)
  20                 WriteCoord(MSG_ONE, autocvar_timelimit);
  21         else
  22                 WriteCoord(MSG_ONE, (t + 1) / 60);
  23 }
  24
  25 void ctf_EventLog(string mode, float flagteam, entity actor) // use an alias for easy changing and quick editing later
  26 {
  27         if(autocvar_sv_eventlog)
  28                 GameLogEcho(strcat(":ctf:", mode, ":", ftos(flagteam), ((actor != world) ? (strcat(":", ftos(actor.playerid))) : "")));
  29 }
  30
  31 string ctf_CaptureRecord(entity flag, entity player)
  32 {
  33         float cap_time, cap_record, success;
  34         string cap_message, refername;
  35
  36         if((autocvar_g_ctf_captimerecord_always) || (player_count - currentbots))
  37         {
  38                 cap_record = ctf_captimerecord;
  39                 cap_time = (time - flag.ctf_pickuptime);
  40
  41                 refername = db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"));
  42                 refername = ((refername == player.netname) ? "their" : strcat(refername, "^7's"));
  43
  44                 if(!ctf_captimerecord)
  45                         { cap_message = strcat(" in ", ftos_decimals(cap_time, 2), " seconds"); success = TRUE; }
  46                 else if(cap_time < cap_record)
  47                         { cap_message = strcat(" in ", ftos_decimals(cap_time, 2), " seconds, breaking ", refername, " previous record of ", ftos_decimals(cap_record, 2), " seconds"); success = TRUE; }
  48                 else
  49                         { cap_message = strcat(" in ", ftos_decimals(cap_time, 2), " seconds, failing to break ", refername, " record of ", ftos_decimals(cap_record, 2), " seconds"); success = FALSE; }
  50
  51                 if(success)
  52                 {
  53                         ctf_captimerecord = cap_time;
  54                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(cap_time));
  55                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), player.netname);
  56                         write_recordmarker(player, (time - cap_time), cap_time);
  57                 }
  58         }
  59
  60         return cap_message;
  61 }
  62
  63 void ctf_FlagcarrierWaypoints(entity player)
  64 {
  65         WaypointSprite_Spawn("flagcarrier", 0, 0, player, FLAG_WAYPOINT_OFFSET, world, player.team, player, wps_flagcarrier, TRUE, RADARICON_FLAG, WPCOLOR_FLAGCARRIER(player.team));
  66         WaypointSprite_UpdateMaxHealth(player.wps_flagcarrier, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, autocvar_g_balance_armor_blockpercent) * 2);
  67         WaypointSprite_UpdateHealth(player.wps_flagcarrier, '1 0 0' * healtharmor_maxdamage(player.health, player.armorvalue, autocvar_g_balance_armor_blockpercent));
  68         WaypointSprite_UpdateTeamRadar(player.wps_flagcarrier, RADARICON_FLAGCARRIER, WPCOLOR_FLAGCARRIER(player.team));
  69 }
  70
  71
  72 // =======================
  73 // CaptureShield Functions
  74 // =======================
  75
  76 float ctf_CaptureShield_CheckStatus(entity p)
  77 {
  78         float s, se;
  79         entity e;
  80         float players_worseeq, players_total;
  81
  82         if(ctf_captureshield_max_ratio <= 0)
  83                 return FALSE;
  84
  85         s = PlayerScore_Add(p, SP_SCORE, 0);
  86         if(s >= -ctf_captureshield_min_negscore)
  87                 return FALSE;
  88
  89         players_total = players_worseeq = 0;
  90         FOR_EACH_PLAYER(e)
  91         {
  92                 if(IsDifferentTeam(e, p))
  93                         continue;
  94                 se = PlayerScore_Add(e, SP_SCORE, 0);
  95                 if(se <= s)
  96                         ++players_worseeq;
  97                 ++players_total;
  98         }
  99
 100         // player is in the worse half, if >= half the players are better than him, or consequently, if < half of the players are worse
 101         // use this rule here
 102
 103         if(players_worseeq >= players_total * ctf_captureshield_max_ratio)
 104                 return FALSE;
 105
 106         return TRUE;
 107 }
 108
 109 void ctf_CaptureShield_Update(entity player, float wanted_status)
 110 {
 111         float updated_status = ctf_CaptureShield_CheckStatus(player);
 112         if((wanted_status == player.ctf_captureshielded) && (updated_status != wanted_status)) // 0: shield only, 1: unshield only
 113         {
 114                 if(updated_status) // TODO csqc notifier for this // Samual: How?
 115                         Send_CSQC_Centerprint_Generic(player, CPID_CTF_CAPTURESHIELD, "^3You are now ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Make some defensive scores before trying again.", 5, 0);
 116                 else
 117                         Send_CSQC_Centerprint_Generic(player, CPID_CTF_CAPTURESHIELD, "^3You are now free.\n\n^3Feel free to ^1try to capture^3 the flag again\n^3if you think you will succeed.", 5, 0);
 118
 119                 player.ctf_captureshielded = updated_status;
 120         }
 121 }
 122
 123 float ctf_CaptureShield_Customize()
 124 {
 125         if(!other.ctf_captureshielded) { return FALSE; }
 126         if(!IsDifferentTeam(self, other)) { return FALSE; }
 127
 128         return TRUE;
 129 }
 130
 131 void ctf_CaptureShield_Touch()
 132 {
 133         if(!other.ctf_captureshielded) { return; }
 134         if(!IsDifferentTeam(self, other)) { return; }
 135
 136         vector mymid = (self.absmin + self.absmax) * 0.5;
 137         vector othermid = (other.absmin + other.absmax) * 0.5;
 138
 139         Damage(other, self, self, 0, DEATH_HURTTRIGGER, mymid, normalize(othermid - mymid) * ctf_captureshield_force);
 140         Send_CSQC_Centerprint_Generic(other, CPID_CTF_CAPTURESHIELD, "^3You are ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Get some defensive scores before trying again.", 5, 0);
 141 }
 142
 143 void ctf_CaptureShield_Spawn(entity flag)
 144 {
 145         entity shield = spawn();
 146
 147         shield.enemy = self;
 148         shield.team = self.team;
 149         shield.touch = ctf_CaptureShield_Touch;
 150         shield.customizeentityforclient = ctf_CaptureShield_Customize;
 151         shield.classname = "ctf_captureshield";
 152         shield.effects = EF_ADDITIVE;
 153         shield.movetype = MOVETYPE_NOCLIP;
 154         shield.solid = SOLID_TRIGGER;
 155         shield.avelocity = '7 0 11';
 156         shield.scale = 0.5;
 157
 158         setorigin(shield, self.origin);
 159         setmodel(shield, "models/ctf/shield.md3");
 160         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 161 }
 162
 163
 164 // ====================
 165 // Drop/Pass/Throw Code
 166 // ====================
 167
 168 void ctf_Handle_Drop(entity flag, entity player, float droptype)
 169 {
 170         // declarations
 171         player = (player ? player : flag.pass_sender);
 172
 173         // main
 174         flag.movetype = MOVETYPE_TOSS;
 175         flag.takedamage = DAMAGE_YES;
 176         flag.health = flag.max_flag_health;
 177         flag.ctf_droptime = time;
 178         flag.ctf_dropper = player;
 179         flag.ctf_status = FLAG_DROPPED;
 180
 181         // messages and sounds
 182         Send_KillNotification(player.netname, flag.netname, "", INFO_LOSTFLAG, MSG_INFO);
 183         sound(flag, CH_TRIGGER, flag.snd_flag_dropped, VOL_BASE, ATTN_NONE);
 184         ctf_EventLog("dropped", player.team, player);
 185
 186         // scoring
 187         PlayerTeamScore_AddScore(player, -ctf_ReadScore("penalty_drop"));
 188         PlayerScore_Add(player, SP_CTF_DROPS, 1);
 189
 190         // waypoints
 191         if(autocvar_g_ctf_flag_dropped_waypoint)
 192                 WaypointSprite_Spawn("flagdropped", 0, 0, flag, FLAG_WAYPOINT_OFFSET, world, ((autocvar_g_ctf_flag_dropped_waypoint == 2) ? 0 : player.team), flag, wps_flagdropped, TRUE, RADARICON_FLAG, WPCOLOR_DROPPEDFLAG(flag.team));
 193
 194         if(autocvar_g_ctf_flag_return_time || (autocvar_g_ctf_flag_return_damage && autocvar_g_ctf_flag_health))
 195         {
 196                 WaypointSprite_UpdateMaxHealth(flag.wps_flagdropped, flag.max_flag_health);
 197                 WaypointSprite_UpdateHealth(flag.wps_flagdropped, flag.health);
 198         }
 199
 200         player.throw_antispam = time + autocvar_g_ctf_pass_wait;
 201
 202         if(droptype == DROP_PASS)
 203         {
 204                 flag.pass_sender = world;
 205                 flag.pass_target = world;
 206         }
 207 }
 208
 209 void ctf_Handle_Retrieve(entity flag, entity player)
 210 {
 211         entity tmp_player; // temporary entity which the FOR_EACH_PLAYER loop uses to scan players
 212         entity sender = flag.pass_sender;
 213
 214         // transfer flag to player
 215         flag.ctf_carrier = player;
 216         flag.owner = player;
 217         flag.owner.flagcarried = flag;
 218
 219         // reset flag
 220         setattachment(flag, player, "");
 221         setorigin(flag, FLAG_CARRY_OFFSET);
 222         flag.movetype = MOVETYPE_NONE;
 223         flag.takedamage = DAMAGE_NO;
 224         flag.solid = SOLID_NOT;
 225         flag.ctf_carrier = player;
 226         flag.ctf_status = FLAG_CARRY;
 227
 228         // messages and sounds
 229         sound(player, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTN_NORM); // FIXCTF
 230         ctf_EventLog("recieve", flag.team, player);
 231
 232         FOR_EACH_REALPLAYER(tmp_player)
 233         {
 234                 if(tmp_player == sender)
 235                         centerprint(tmp_player, strcat("You passed the ", flag.netname, " to ", player.netname));
 236                 else if(tmp_player == player)
 237                         centerprint(tmp_player, strcat("You recieved the ", flag.netname, " from ", sender.netname));
 238                 else if(!IsDifferentTeam(tmp_player, sender))
 239                         centerprint(tmp_player, strcat(sender.netname, " passed the ", flag.netname, " to ", player.netname));
 240         }
 241
 242         // create new waypoint
 243         ctf_FlagcarrierWaypoints(player);
 244
 245         sender.throw_antispam = time + autocvar_g_ctf_pass_wait;
 246         player.throw_antispam = sender.throw_antispam;
 247
 248         flag.pass_sender = world;
 249         flag.pass_target = world;
 250 }
 251
 252 void ctf_Handle_Throw(entity player, entity reciever, float droptype)
 253 {
 254         entity flag = player.flagcarried;
 255
 256         if(!flag) { return; }
 257         if((droptype == DROP_PASS) && !reciever) { return; }
 258
 259         if(flag.speedrunning) { ctf_RespawnFlag(flag); return; }
 260
 261         // reset the flag
 262         setattachment(flag, world, "");
 263         setorigin(flag, player.origin + FLAG_DROP_OFFSET);
 264         flag.owner.flagcarried = world;
 265         flag.owner = world;
 266         flag.solid = SOLID_TRIGGER;
 267         flag.ctf_droptime = time;
 268
 269         flag.flags = FL_ITEM | FL_NOTARGET; // clear FL_ONGROUND for MOVETYPE_TOSS
 270
 271         switch(droptype)
 272         {
 273                 case DROP_PASS:
 274                 {
 275                         vector targ_origin = (0.5 * (reciever.absmin + reciever.absmax));
 276                         flag.velocity = (normalize(targ_origin - player.origin) * autocvar_g_ctf_pass_velocity);
 277                         break;
 278                 }
 279
 280                 case DROP_THROW:
 281                 {
 282                         makevectors((player.v_angle_y * '0 1 0') + (player.v_angle_x * '0.5 0 0'));
 283                         flag.velocity = W_CalculateProjectileVelocity(player.velocity, ('0 0 200' + (v_forward * autocvar_g_ctf_drop_velocity)), FALSE);
 284                         break;
 285                 }
 286
 287                 case DROP_RESET:
 288                 {
 289                         flag.velocity = '0 0 0'; // do nothing
 290                         break;
 291                 }
 292
 293                 default:
 294                 case DROP_NORMAL:
 295                 {
 296                         flag.velocity = W_CalculateProjectileVelocity(player.velocity, ('0 0 200' + ('0 100 0' * crandom()) + ('100 0 0' * crandom())), FALSE);
 297                         break;
 298                 }
 299         }
 300
 301         switch(droptype)
 302         {
 303                 case DROP_PASS:
 304                 {
 305                         // main
 306                         flag.movetype = MOVETYPE_FLY;
 307                         flag.takedamage = DAMAGE_NO;
 308                         flag.pass_sender = player;
 309                         flag.pass_target = reciever;
 310                         flag.ctf_status = FLAG_PASSING;
 311
 312                         // other
 313                         sound(player, CH_TRIGGER, flag.snd_flag_touch, VOL_BASE, ATTN_NORM);
 314                         ctf_EventLog("pass", flag.team, player);
 315                         te_lightning2(world, reciever.origin, player.origin);
 316                         break;
 317                 }
 318
 319                 case DROP_RESET:
 320                 {
 321                         // do nothing
 322                         break;
 323                 }
 324
 325                 default:
 326                 case DROP_THROW:
 327                 case DROP_NORMAL:
 328                 {
 329                         ctf_Handle_Drop(flag, player, droptype);
 330                         break;
 331                 }
 332         }
 333
 334         // kill old waypointsprite
 335         WaypointSprite_Ping(player.wps_flagcarrier);
 336         WaypointSprite_Kill(player.wps_flagcarrier);
 337
 338         if(player.wps_enemyflagcarrier)
 339                 WaypointSprite_Kill(player.wps_enemyflagcarrier);
 340
 341         // captureshield
 342         ctf_CaptureShield_Update(player, 0); // shield player from picking up flag
 343 }
 344
 345
 346 // ==============
 347 // Event Handlers
 348 // ==============
 349
 350 void ctf_Handle_Capture(entity flag, entity toucher, float capturetype)
 351 {
 352         entity enemy_flag = ((capturetype == CAPTURE_NORMAL) ? toucher.flagcarried : toucher);
 353         entity player = ((capturetype == CAPTURE_NORMAL) ? toucher : enemy_flag.ctf_dropper);
 354
 355         if not(player) { return; } // without someone to give the reward to, we can't possibly cap
 356
 357         // messages and sounds
 358         Send_KillNotification(player.netname, enemy_flag.netname, ctf_CaptureRecord(enemy_flag, player), INFO_CAPTUREFLAG, MSG_INFO);
 359         sound(player, CH_TRIGGER, flag.snd_flag_capture, VOL_BASE, ATTN_NONE);
 360
 361         switch(capturetype)
 362         {
 363                 case CAPTURE_NORMAL: ctf_EventLog("capture", enemy_flag.team, player); break;
 364                 case CAPTURE_DROPPED: ctf_EventLog("droppedcapture", enemy_flag.team, player); break;
 365                 default: break;
 366         }
 367
 368         // scoring
 369         PlayerTeamScore_AddScore(player, ctf_ReadScore("score_capture"));
 370         PlayerTeamScore_Add(player, SP_CTF_CAPS, ST_CTF_CAPS, 1);
 371
 372         // effects
 373         if(autocvar_g_ctf_flag_capture_effects)
 374         {
 375                 pointparticles(particleeffectnum((player.team == COLOR_TEAM1) ? "red_ground_quake" : "blue_ground_quake"), flag.origin, '0 0 0', 1);
 376                 shockwave_spawn("models/ctf/shockwavetransring.md3", flag.origin - '0 0 15', -0.8, 0, 1);
 377         }
 378
 379         // other
 380         if(capturetype == CAPTURE_NORMAL)
 381         {
 382                 WaypointSprite_Kill(player.wps_flagcarrier);
 383                 if(flag.speedrunning) { ctf_FakeTimeLimit(player, -1); }
 384         }
 385
 386         // reset the flag
 387         player.next_take_time = time + autocvar_g_ctf_flag_collect_delay;
 388         ctf_RespawnFlag(enemy_flag);
 389 }
 390
 391 void ctf_Handle_Return(entity flag, entity player)
 392 {
 393         // messages and sounds
 394         //centerprint(player, strcat("You returned the ", flag.netname));
 395         Send_KillNotification(player.netname, flag.netname, "", INFO_RETURNFLAG, MSG_INFO);
 396         sound(player, CH_TRIGGER, flag.snd_flag_returned, VOL_BASE, ATTN_NONE);
 397         ctf_EventLog("return", flag.team, player);
 398
 399         // scoring
 400         PlayerTeamScore_AddScore(player, ctf_ReadScore("score_return")); // reward for return
 401         PlayerScore_Add(player, SP_CTF_RETURNS, 1); // add to count of returns
 402
 403         TeamScore_AddToTeam(flag.team, ST_SCORE, -ctf_ReadScore("penalty_returned")); // punish the team who was last carrying it
 404
 405         if(flag.ctf_dropper)
 406         {
 407                 PlayerScore_Add(flag.ctf_dropper, SP_SCORE, -ctf_ReadScore("penalty_returned")); // punish the player who dropped the flag
 408                 ctf_CaptureShield_Update(flag.ctf_dropper, 0); // shield player from picking up flag
 409                 flag.ctf_dropper.next_take_time = time + autocvar_g_ctf_flag_collect_delay; // set next take time
 410         }
 411
 412         // reset the flag
 413         ctf_RespawnFlag(flag);
 414 }
 415
 416 void ctf_Handle_Pickup(entity flag, entity player, float pickuptype)
 417 {
 418         // declarations
 419         entity tmp_player; // temporary entity which the FOR_EACH_PLAYER loop uses to scan players
 420         string verbosename; // holds the name of the player OR no name at all for printing in the centerprints
 421         float pickup_dropped_score; // used to calculate dropped pickup score
 422
 423         // attach the flag to the player
 424         flag.owner = player;
 425         player.flagcarried = flag;
 426         setattachment(flag, player, "");
 427         setorigin(flag, FLAG_CARRY_OFFSET);
 428
 429         // flag setup
 430         flag.movetype = MOVETYPE_NONE;
 431         flag.takedamage = DAMAGE_NO;
 432         flag.solid = SOLID_NOT;
 433         flag.angles = '0 0 0';
 434         flag.ctf_carrier = player;
 435         flag.ctf_status = FLAG_CARRY;
 436
 437         switch(pickuptype)
 438         {
 439                 case PICKUP_BASE: flag.ctf_pickuptime = time; break; // used for timing runs
 440                 case PICKUP_DROPPED: flag.health = flag.max_flag_health; break; // reset health/return timelimit
 441                 default: break;
 442         }
 443
 444         // messages and sounds
 445         Send_KillNotification (player.netname, flag.netname, "", INFO_GOTFLAG, MSG_INFO);
 446         sound(player, CH_TRIGGER, flag.snd_flag_taken, VOL_BASE, ATTN_NONE);
 447         verbosename = ((autocvar_g_ctf_flag_pickup_verbosename) ? strcat(Team_ColorCode(player.team), "(^7", player.netname, Team_ColorCode(player.team), ") ") : "");
 448
 449         FOR_EACH_REALPLAYER(tmp_player)
 450         {
 451                 if(tmp_player == player)
 452                         centerprint(tmp_player, strcat("You got the ", flag.netname, "!"));
 453                 else if(!IsDifferentTeam(tmp_player, player))
 454                         centerprint(tmp_player, strcat("Your ", Team_ColorCode(player.team), "team mate ", verbosename, "^7got the flag! Protect them!"));
 455                 else if(!IsDifferentTeam(tmp_player, flag))
 456                         centerprint(tmp_player, strcat("The ", Team_ColorCode(player.team), "enemy ", verbosename, "^7got your flag! Retrieve it!"));
 457         }
 458
 459         switch(pickuptype)
 460         {
 461                 case PICKUP_BASE: ctf_EventLog("steal", flag.team, player); break;
 462                 case PICKUP_DROPPED: ctf_EventLog("pickup", flag.team, player); break;
 463                 default: break;
 464         }
 465
 466         // scoring
 467         PlayerScore_Add(player, SP_CTF_PICKUPS, 1);
 468         switch(pickuptype)
 469         {
 470                 case PICKUP_BASE:
 471                 {
 472                         PlayerTeamScore_AddScore(player, ctf_ReadScore("score_pickup_base"));
 473                         break;
 474                 }
 475
 476                 case PICKUP_DROPPED:
 477                 {
 478                         pickup_dropped_score = (autocvar_g_ctf_flag_return_time ? bound(0, ((flag.ctf_droptime + autocvar_g_ctf_flag_return_time) - time) / autocvar_g_ctf_flag_return_time, 1) : 1);
 479                         pickup_dropped_score = floor((ctf_ReadScore("score_pickup_dropped_late") * (1 - pickup_dropped_score) + ctf_ReadScore("score_pickup_dropped_early") * pickup_dropped_score) + 0.5);
 480                         print("pickup_dropped_score is ", ftos(pickup_dropped_score), "\n");
 481                         PlayerTeamScore_AddScore(player, pickup_dropped_score);
 482                         break;
 483                 }
 484
 485                 default: break;
 486         }
 487
 488         // speedrunning
 489         if(pickuptype == PICKUP_BASE)
 490         {
 491                 flag.speedrunning = player.speedrunning; // if speedrunning, flag will flag-return and teleport the owner back after the record
 492                 if((player.speedrunning) && (ctf_captimerecord))
 493                         ctf_FakeTimeLimit(player, time + ctf_captimerecord);
 494         }
 495
 496         // effects
 497         if(autocvar_g_ctf_flag_pickup_effects)
 498                 pointparticles(particleeffectnum("smoke_ring"), 0.5 * (flag.absmin + flag.absmax), '0 0 0', 1);
 499
 500         // waypoints
 501         if(pickuptype == PICKUP_DROPPED) { WaypointSprite_Kill(flag.wps_flagdropped); }
 502         ctf_FlagcarrierWaypoints(player);
 503         WaypointSprite_Ping(player.wps_flagcarrier);
 504 }
 505
 506
 507 // ===================
 508 // Main Flag Functions
 509 // ===================
 510
 511 void ctf_CheckFlagReturn(entity flag, float returntype)
 512 {
 513         if(flag.wps_flagdropped) { WaypointSprite_UpdateHealth(flag.wps_flagdropped, flag.health); }
 514
 515         if((flag.health <= 0) || (time >= flag.ctf_droptime + autocvar_g_ctf_flag_return_time))
 516         {
 517                 switch(returntype)
 518                 {
 519                         case RETURN_DROPPED: bprint("The ", flag.netname, " was dropped in the base and returned itself\n"); break;
 520                         case RETURN_DAMAGE: bprint("The ", flag.netname, " was destroyed and returned to base\n"); break;
 521                         case RETURN_SPEEDRUN: bprint("The ", flag.netname, " became impatient after ", ftos_decimals(ctf_captimerecord, 2), " seconds and returned itself\n"); break;
 522                         case RETURN_NEEDKILL: bprint("The ", flag.netname, " fell somewhere it couldn't be reached and returned to base\n"); break;
 523
 524                         default:
 525                         case RETURN_TIMEOUT:
 526                                 { bprint("The ", flag.netname, " has returned to base\n"); break; }
 527                 }
 528                 sound(flag, CH_TRIGGER, flag.snd_flag_respawn, VOL_BASE, ATTN_NONE);
 529                 ctf_EventLog("returned", flag.team, world);
 530                 ctf_RespawnFlag(flag);
 531         }
 532 }
 533
 534 void ctf_CheckStalemate(void)
 535 {
 536         // declarations
 537         float stale_red_flags, stale_blue_flags;
 538         entity tmp_entity;
 539
 540         entity ctf_staleflaglist; // reset the list, we need to build the list each time this function runs
 541
 542         // build list of stale flags
 543         for(tmp_entity = ctf_worldflaglist; tmp_entity; tmp_entity = tmp_entity.ctf_worldflagnext)
 544         {
 545                 if(autocvar_g_ctf_flagcarrier_waypointforenemy_stalemate)
 546                 if(tmp_entity.ctf_status != FLAG_BASE)
 547                 if(time >= tmp_entity.ctf_pickuptime + autocvar_g_ctf_flagcarrier_waypointforenemy_stalemate)
 548                 {
 549                         tmp_entity.ctf_staleflagnext = ctf_staleflaglist; // link flag into staleflaglist
 550                         ctf_staleflaglist = tmp_entity;
 551
 552                         switch(tmp_entity.team)
 553                         {
 554                                 case COLOR_TEAM1: ++stale_red_flags; break;
 555                                 case COLOR_TEAM2: ++stale_blue_flags; break;
 556                         }
 557                 }
 558         }
 559
 560         if(stale_red_flags && stale_blue_flags)
 561                 ctf_stalemate = TRUE;
 562         else if(!stale_red_flags && !stale_blue_flags)
 563                 ctf_stalemate = FALSE;
 564
 565         // if sufficient stalemate, then set up the waypointsprite and announce the stalemate if necessary
 566         if(ctf_stalemate)
 567         {
 568                 for(tmp_entity = ctf_staleflaglist; tmp_entity; tmp_entity = tmp_entity.ctf_staleflagnext)
 569                 {
 570                         if((tmp_entity.owner) && (!tmp_entity.owner.wps_enemyflagcarrier))
 571                                 WaypointSprite_Spawn("enemyflagcarrier", 0, 0, tmp_entity.owner, FLAG_WAYPOINT_OFFSET, world, tmp_entity.team, tmp_entity.owner, wps_enemyflagcarrier, TRUE, RADARICON_FLAG, WPCOLOR_ENEMYFC(tmp_entity.owner.team));
 572                 }
 573
 574                 if not(wpforenemy_announced)
 575                 {
 576                         FOR_EACH_REALPLAYER(tmp_entity)
 577                                 if(tmp_entity.flagcarried)
 578                                         centerprint(tmp_entity, "Stalemate! Enemies can now see you on radar!");
 579                                 else
 580                                         centerprint(tmp_entity, "Stalemate! Flag carriers can now be seen by enemies on radar!");
 581
 582                         wpforenemy_announced = TRUE;
 583                 }
 584         }
 585 }
 586
 587 void ctf_FlagDamage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 588 {
 589         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 590         {
 591                 // automatically kill the flag and return it
 592                 self.health = 0;
 593                 ctf_CheckFlagReturn(self, RETURN_NEEDKILL);
 594                 return;
 595         }
 596         if(autocvar_g_ctf_flag_return_damage)
 597         {
 598                 // reduce health and check if it should be returned
 599                 self.health = self.health - damage;
 600                 ctf_CheckFlagReturn(self, RETURN_DAMAGE);
 601                 return;
 602         }
 603 }
 604
 605 void ctf_FlagThink()
 606 {
 607         // declarations
 608         entity tmp_entity;
 609
 610         self.nextthink = time + FLAG_THINKRATE; // only 5 fps, more is unnecessary.
 611
 612         // captureshield
 613         if(self == ctf_worldflaglist) // only for the first flag
 614                 FOR_EACH_CLIENT(tmp_entity)
 615                         ctf_CaptureShield_Update(tmp_entity, 1); // release shield only
 616
 617         // sanity checks
 618         if(self.mins != FLAG_MIN || self.maxs != FLAG_MAX) { // reset the flag boundaries in case it got squished
 619                 dprint("wtf the flag got squashed?\n");
 620                 tracebox(self.origin, FLAG_MIN, FLAG_MAX, self.origin, MOVE_NOMONSTERS, self);
 621                 if(!trace_startsolid) // can we resize it without getting stuck?
 622                         setsize(self, FLAG_MIN, FLAG_MAX); }
 623
 624         switch(self.ctf_status) // reset flag angles in case warpzones adjust it
 625         {
 626                 case FLAG_DROPPED:
 627                 case FLAG_PASSING:
 628                 {
 629                         self.angles = '0 0 0';
 630                         break;
 631                 }
 632
 633                 default: break;
 634         }
 635
 636         // main think method
 637         switch(self.ctf_status)
 638         {
 639                 case FLAG_BASE:
 640                 {
 641                         if(autocvar_g_ctf_dropped_capture_radius)
 642                         {
 643                                 for(tmp_entity = ctf_worldflaglist; tmp_entity; tmp_entity = tmp_entity.ctf_worldflagnext)
 644                                         if(tmp_entity.ctf_status == FLAG_DROPPED)
 645                                                 if(vlen(self.origin - tmp_entity.origin) < autocvar_g_ctf_dropped_capture_radius)
 646                                                         ctf_Handle_Capture(self, tmp_entity, CAPTURE_DROPPED);
 647                         }
 648                         return;
 649                 }
 650
 651                 case FLAG_DROPPED:
 652                 {
 653                         if(autocvar_g_ctf_flag_dropped_floatinwater && (self.flags & FL_INWATER))
 654                                 self.velocity_z = autocvar_g_ctf_flag_dropped_floatinwater;
 655
 656                         if(autocvar_g_ctf_flag_return_dropped)
 657                         {
 658                                 if((vlen(self.origin - self.ctf_spawnorigin) <= autocvar_g_ctf_flag_return_dropped) || (autocvar_g_ctf_flag_return_dropped == -1))
 659                                 {
 660                                         self.health = 0;
 661                                         ctf_CheckFlagReturn(self, RETURN_DROPPED);
 662                                         return;
 663                                 }
 664                         }
 665                         if(autocvar_g_ctf_flag_return_time)
 666                         {
 667                                 self.health -= ((self.max_flag_health / autocvar_g_ctf_flag_return_time) * FLAG_THINKRATE);
 668                                 ctf_CheckFlagReturn(self, RETURN_TIMEOUT);
 669                                 return;
 670                         }
 671                         return;
 672                 }
 673
 674                 case FLAG_CARRY:
 675                 {
 676                         if(self.speedrunning && ctf_captimerecord && (time >= self.ctf_pickuptime + ctf_captimerecord))
 677                         {
 678                                 self.health = 0;
 679                                 ctf_CheckFlagReturn(self, RETURN_SPEEDRUN);
 680
 681                                 tmp_entity = self;
 682                                 self = self.owner;
 683                                 self.impulse = CHIMPULSE_SPEEDRUN; // move the player back to the waypoint they set
 684                                 ImpulseCommands();
 685                                 self = tmp_entity;
 686                         }
 687                         if(autocvar_g_ctf_flagcarrier_waypointforenemy_stalemate)
 688                         {
 689                                 if(time >= wpforenemy_nextthink)
 690                                 {
 691                                         ctf_CheckStalemate();
 692                                         wpforenemy_nextthink = time + WPFE_THINKRATE; // waypoint for enemy think rate (to reduce unnecessary spam of this check)
 693                                 }
 694                         }
 695                         return;
 696                 }
 697
 698                 case FLAG_PASSING: // todo make work with warpzones
 699                 {
 700                         vector targ_origin = ((self.pass_target.absmin + self.pass_target.absmax) * 0.5);
 701                         traceline(self.origin, targ_origin, MOVE_NOMONSTERS, self);
 702
 703                         if((self.pass_target.deadflag != DEAD_NO)
 704                                 || (vlen(self.origin - targ_origin) > autocvar_g_ctf_pass_radius)
 705                                 || ((trace_fraction < 1) && (trace_ent != self.pass_target))
 706                                 || (time > self.ctf_droptime + autocvar_g_ctf_pass_timelimit))
 707                         {
 708                                 ctf_Handle_Drop(self, world, DROP_PASS);
 709                         }
 710                         else // still a viable target, go for it
 711                         {
 712                                 vector desired_direction = normalize(targ_origin - self.origin);
 713                                 vector current_direction = normalize(self.velocity);
 714
 715                                 self.velocity = (normalize(current_direction + (desired_direction * autocvar_g_ctf_pass_turnrate)) * autocvar_g_ctf_pass_velocity);
 716                         }
 717                         return;
 718                 }
 719
 720                 default: // this should never happen
 721                 {
 722                         dprint("ctf_FlagThink(): Flag exists with no status?\n");
 723                         return;
 724                 }
 725         }
 726 }
 727
 728 void ctf_FlagTouch()
 729 {
 730         if(gameover) { return; }
 731
 732         entity toucher = other;
 733
 734         // automatically kill the flag and return it if it touched lava/slime/nodrop surfaces
 735         if(ITEM_TOUCH_NEEDKILL())
 736         {
 737                 self.health = 0;
 738                 ctf_CheckFlagReturn(self, RETURN_NEEDKILL);
 739                 return;
 740         }
 741
 742         // special touch behaviors
 743         if(toucher.vehicle_flags & VHF_ISVEHICLE)
 744         {
 745                 if(autocvar_g_ctf_allow_vehicle_touch)
 746                         toucher = toucher.owner; // the player is actually the vehicle owner, not other
 747                 else
 748                         return; // do nothing
 749         }
 750         else if(toucher.classname != "player") // The flag just touched an object, most likely the world
 751         {
 752                 if(time > self.wait) // if we haven't in a while, play a sound/effect
 753                 {
 754                         pointparticles(particleeffectnum("kaball_sparks"), self.origin, '0 0 0', 1);
 755                         sound(self, CH_TRIGGER, self.snd_flag_touch, VOL_BASE, ATTN_NORM);
 756                         self.wait = time + FLAG_TOUCHRATE;
 757                 }
 758                 return;
 759         }
 760         else if(toucher.deadflag != DEAD_NO) { return; }
 761
 762         switch(self.ctf_status)
 763         {
 764                 case FLAG_BASE:
 765                 {
 766                         if(!IsDifferentTeam(toucher, self) && (toucher.flagcarried) && IsDifferentTeam(toucher.flagcarried, self))
 767                                 ctf_Handle_Capture(self, toucher, CAPTURE_NORMAL); // toucher just captured the enemies flag to his base
 768                         else if(IsDifferentTeam(toucher, self) && (!toucher.flagcarried) && (!toucher.ctf_captureshielded) && (time > toucher.next_take_time))
 769                                 ctf_Handle_Pickup(self, toucher, PICKUP_BASE); // toucher just stole the enemies flag
 770                         break;
 771                 }
 772
 773                 case FLAG_DROPPED:
 774                 {
 775                         if(!IsDifferentTeam(toucher, self))
 776                                 ctf_Handle_Return(self, toucher); // toucher just returned his own flag
 777                         else if((!toucher.flagcarried) && ((toucher != self.ctf_dropper) || (time > self.ctf_droptime + autocvar_g_ctf_flag_collect_delay)))
 778                                 ctf_Handle_Pickup(self, toucher, PICKUP_DROPPED); // toucher just picked up a dropped enemy flag
 779                         break;
 780                 }
 781
 782                 case FLAG_CARRY:
 783                 {
 784                         dprint("Someone touched a flag even though it was being carried?\n");
 785                         break;
 786                 }
 787
 788                 case FLAG_PASSING:
 789                 {
 790                         if((toucher.classname == "player") && (toucher.deadflag == DEAD_NO) && (toucher != self.pass_sender))
 791                         {
 792                                 if(IsDifferentTeam(toucher, self.pass_sender))
 793                                         ctf_Handle_Return(self, toucher);
 794                                 else
 795                                         ctf_Handle_Retrieve(self, toucher);
 796                         }
 797                         break;
 798                 }
 799         }
 800 }
 801
 802 void ctf_RespawnFlag(entity flag)
 803 {
 804         // reset the player (if there is one)
 805         if((flag.owner) && (flag.owner.flagcarried == flag))
 806         {
 807                 if(flag.owner.wps_enemyflagcarrier)
 808                         WaypointSprite_Kill(flag.owner.wps_enemyflagcarrier);
 809
 810                 WaypointSprite_Kill(flag.wps_flagcarrier);
 811
 812                 flag.owner.flagcarried = world;
 813
 814                 if(flag.speedrunning)
 815                         ctf_FakeTimeLimit(flag.owner, -1);
 816         }
 817
 818         if((flag.ctf_status == FLAG_DROPPED) && (flag.wps_flagdropped))
 819                 { WaypointSprite_Kill(flag.wps_flagdropped); }
 820
 821         // reset the flag
 822         setattachment(flag, world, "");
 823         setorigin(flag, flag.ctf_spawnorigin);
 824
 825         flag.movetype = ((flag.noalign) ? MOVETYPE_NONE : MOVETYPE_TOSS);
 826         flag.takedamage = DAMAGE_NO;
 827         flag.health = flag.max_flag_health;
 828         flag.solid = SOLID_TRIGGER;
 829         flag.velocity = '0 0 0';
 830         flag.angles = flag.mangle;
 831         flag.flags = FL_ITEM | FL_NOTARGET;
 832
 833         flag.ctf_status = FLAG_BASE;
 834         flag.owner = world;
 835         flag.pass_sender = world;
 836         flag.pass_target = world;
 837         flag.ctf_carrier = world;
 838         flag.ctf_dropper = world;
 839         flag.ctf_pickuptime = 0;
 840         flag.ctf_droptime = 0;
 841
 842         wpforenemy_announced = FALSE;
 843 }
 844
 845 void ctf_Reset()
 846 {
 847         if(self.owner)
 848                 if(self.owner.classname == "player")
 849                         ctf_Handle_Throw(self.owner, world, DROP_RESET);
 850
 851         ctf_RespawnFlag(self);
 852 }
 853
 854 void ctf_DelayedFlagSetup(void) // called after a flag is placed on a map by ctf_FlagSetup()
 855 {
 856         // bot waypoints
 857         waypoint_spawnforitem_force(self, self.origin);
 858         self.nearestwaypointtimeout = 0; // activate waypointing again
 859         self.bot_basewaypoint = self.nearestwaypoint;
 860
 861         // waypointsprites
 862         WaypointSprite_SpawnFixed(((self.team == COLOR_TEAM1) ? "redbase" : "bluebase"), self.origin + FLAG_WAYPOINT_OFFSET, self, wps_flagbase, RADARICON_FLAG, colormapPaletteColor(self.team - 1, FALSE));
 863         WaypointSprite_UpdateTeamRadar(self.wps_flagbase, RADARICON_FLAG, colormapPaletteColor(self.team - 1, FALSE));
 864
 865         // captureshield setup
 866         ctf_CaptureShield_Spawn(self);
 867 }
 868
 869 void ctf_FlagSetup(float teamnumber, entity flag) // called when spawning a flag entity on the map as a spawnfunc
 870 {
 871         // declarations
 872         teamnumber = fabs(teamnumber - bound(0, autocvar_g_ctf_reverse, 1)); // if we were originally 1, this will become 0. If we were originally 0, this will become 1.
 873         self = flag; // for later usage with droptofloor()
 874
 875         // main setup
 876         flag.ctf_worldflagnext = ctf_worldflaglist; // link flag into ctf_worldflaglist
 877         ctf_worldflaglist = flag;
 878
 879         setattachment(flag, world, "");
 880
 881         flag.netname = ((teamnumber) ? "^1RED^7 flag" : "^4BLUE^7 flag");
 882         flag.team = ((teamnumber) ? COLOR_TEAM1 : COLOR_TEAM2); // COLOR_TEAM1: color 4 team (red) - COLOR_TEAM2: color 13 team (blue)
 883         flag.items = ((teamnumber) ? IT_KEY2 : IT_KEY1); // IT_KEY2: gold key (redish enough) - IT_KEY1: silver key (bluish enough)
 884         flag.classname = "item_flag_team";
 885         flag.target = "###item###"; // wut?
 886         flag.flags = FL_ITEM | FL_NOTARGET;
 887         flag.solid = SOLID_TRIGGER;
 888         flag.takedamage = DAMAGE_NO;
 889         flag.damageforcescale = autocvar_g_ctf_flag_damageforcescale;
 890         flag.max_flag_health = ((autocvar_g_ctf_flag_return_damage && autocvar_g_ctf_flag_health) ? autocvar_g_ctf_flag_health : 100);
 891         flag.health = flag.max_flag_health;
 892         flag.event_damage = ctf_FlagDamage;
 893         flag.pushable = TRUE;
 894         flag.teleportable = TELEPORT_NORMAL;
 895         flag.damagedbytriggers = autocvar_g_ctf_flag_return_when_unreachable;
 896         flag.damagedbycontents = autocvar_g_ctf_flag_return_when_unreachable;
 897         flag.velocity = '0 0 0';
 898         flag.mangle = flag.angles;
 899         flag.reset = ctf_Reset;
 900         flag.touch = ctf_FlagTouch;
 901         flag.think = ctf_FlagThink;
 902         flag.nextthink = time + FLAG_THINKRATE;
 903         flag.ctf_status = FLAG_BASE;
 904
 905         if(!flag.model) { flag.model = ((teamnumber) ? autocvar_g_ctf_flag_red_model : autocvar_g_ctf_flag_blue_model); }
 906         if(!flag.scale) { flag.scale = FLAG_SCALE; }
 907         if(!flag.skin) { flag.skin = ((teamnumber) ? autocvar_g_ctf_flag_red_skin : autocvar_g_ctf_flag_blue_skin); }
 908
 909         // sound
 910         if(!flag.snd_flag_taken) { flag.snd_flag_taken  = ((teamnumber) ? "ctf/red_taken.wav" : "ctf/blue_taken.wav"); }
 911         if(!flag.snd_flag_returned) { flag.snd_flag_returned = ((teamnumber) ? "ctf/red_returned.wav" : "ctf/blue_returned.wav"); }
 912         if(!flag.snd_flag_capture) { flag.snd_flag_capture = ((teamnumber) ? "ctf/red_capture.wav" : "ctf/blue_capture.wav"); } // blue team scores by capturing the red flag
 913         if(!flag.snd_flag_respawn) { flag.snd_flag_respawn = "ctf/flag_respawn.wav"; } // if there is ever a team-based sound for this, update the code to match.
 914         if(!flag.snd_flag_dropped) { flag.snd_flag_dropped = ((teamnumber) ? "ctf/red_dropped.wav" : "ctf/blue_dropped.wav"); }
 915         if(!flag.snd_flag_touch) { flag.snd_flag_touch = "keepaway/touch.wav"; } // again has no team-based sound // FIXME
 916
 917         // precache
 918         precache_sound(flag.snd_flag_taken);
 919         precache_sound(flag.snd_flag_returned);
 920         precache_sound(flag.snd_flag_capture);
 921         precache_sound(flag.snd_flag_respawn);
 922         precache_sound(flag.snd_flag_dropped);
 923         precache_sound(flag.snd_flag_touch);
 924         precache_model(flag.model);
 925         precache_model("models/ctf/shield.md3");
 926         precache_model("models/ctf/shockwavetransring.md3");
 927
 928         // appearence
 929         setmodel(flag, flag.model); // precision set below
 930         setsize(flag, FLAG_MIN, FLAG_MAX);
 931         setorigin(flag, (flag.origin + FLAG_SPAWN_OFFSET));
 932
 933         if(autocvar_g_ctf_flag_glowtrails)
 934         {
 935                 flag.glow_color = ((teamnumber) ? 251 : 210); // 251: red - 210: blue
 936                 flag.glow_size = 25;
 937                 flag.glow_trail = 1;
 938         }
 939
 940         flag.effects |= EF_LOWPRECISION;
 941         if(autocvar_g_ctf_fullbrightflags) { flag.effects |= EF_FULLBRIGHT; }
 942         if(autocvar_g_ctf_dynamiclights)   { flag.effects |= ((teamnumber) ? EF_RED : EF_BLUE); }
 943
 944         // flag placement
 945         if((flag.spawnflags & 1) || flag.noalign) // don't drop to floor, just stay at fixed location
 946         {
 947                 flag.dropped_origin = flag.origin;
 948                 flag.noalign = TRUE;
 949                 flag.movetype = MOVETYPE_NONE;
 950         }
 951         else // drop to floor, automatically find a platform and set that as spawn origin
 952         {
 953                 flag.noalign = FALSE;
 954                 self = flag;
 955                 droptofloor();
 956                 flag.movetype = MOVETYPE_TOSS;
 957         }
 958
 959         InitializeEntity(flag, ctf_DelayedFlagSetup, INITPRIO_SETLOCATION);
 960 }
 961
 962
 963 // ==============
 964 // Hook Functions
 965 // ==============
 966
 967 MUTATOR_HOOKFUNCTION(ctf_PlayerPreThink)
 968 {
 969         entity flag;
 970
 971         // initially clear items so they can be set as necessary later.
 972         self.items &~= (IT_RED_FLAG_CARRYING | IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST
 973                 | IT_BLUE_FLAG_CARRYING | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST | IT_CTF_SHIELDED);
 974
 975         // scan through all the flags and notify the client about them
 976         for(flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext)
 977         {
 978                 switch(flag.ctf_status)
 979                 {
 980                         case FLAG_CARRY:
 981                         {
 982                                 if(flag.owner == self)
 983                                         self.items |= ((flag.items & IT_KEY2) ? IT_RED_FLAG_CARRYING : IT_BLUE_FLAG_CARRYING); // carrying: self is currently carrying the flag
 984                                 else
 985                                         self.items |= ((flag.items & IT_KEY2) ? IT_RED_FLAG_TAKEN : IT_BLUE_FLAG_TAKEN); // taken: someone on self's team is carrying the flag
 986                                 break;
 987                         }
 988                         case FLAG_DROPPED:
 989                         {
 990                                 self.items |= ((flag.items & IT_KEY2) ? IT_RED_FLAG_LOST : IT_BLUE_FLAG_LOST); // lost: the flag is dropped somewhere on the map
 991                                 break;
 992                         }
 993                 }
 994         }
 995
 996         // item for stopping players from capturing the flag too often
 997         if(self.ctf_captureshielded)
 998                 self.items |= IT_CTF_SHIELDED;
 999
1000         // update the health of the flag carrier waypointsprite
1001         if(self.wps_flagcarrier)
1002                 WaypointSprite_UpdateHealth(self.wps_flagcarrier, self.health);
1003
1004         return 0;
1005 }
1006
1007 MUTATOR_HOOKFUNCTION(ctf_PlayerDamage) // for changing damage and force values that are applied to players in g_damage.qc
1008 {
1009         if(frag_attacker.flagcarried) // if the attacker is a flagcarrier
1010         {
1011                 if(frag_target == frag_attacker) // damage done to yourself
1012                 {
1013                         frag_damage *= autocvar_g_ctf_flagcarrier_selfdamagefactor;
1014                         frag_force *= autocvar_g_ctf_flagcarrier_selfforcefactor;
1015                 }
1016                 else // damage done to everyone else
1017                 {
1018                         frag_damage *= autocvar_g_ctf_flagcarrier_damagefactor;
1019                         frag_force *= autocvar_g_ctf_flagcarrier_forcefactor;
1020                 }
1021         }
1022         else if(frag_target.flagcarried && (frag_target.deadflag == DEAD_NO) && IsDifferentTeam(frag_target, frag_attacker)) // if the target is a flagcarrier
1023         {
1024                 if(autocvar_g_ctf_flagcarrier_auto_helpme_when_damaged > frag_target.health)
1025                         WaypointSprite_HelpMePing(frag_target.wps_flagcarrier); // TODO: only do this if there is a significant loss of health?
1026         }
1027         return 0;
1028 }
1029
1030 MUTATOR_HOOKFUNCTION(ctf_PlayerDies)
1031 {
1032         if((frag_attacker != frag_target) && (frag_attacker.classname == "player") && (frag_target.flagcarried))
1033         {
1034                 PlayerTeamScore_AddScore(frag_attacker, ctf_ReadScore("score_kill"));
1035                 PlayerScore_Add(frag_attacker, SP_CTF_FCKILLS, 1);
1036         }
1037
1038         if(frag_target.flagcarried)
1039                 { ctf_Handle_Throw(frag_target, world, DROP_NORMAL); }
1040
1041         return 0;
1042 }
1043
1044 MUTATOR_HOOKFUNCTION(ctf_GiveFragsForKill)
1045 {
1046         frag_score = 0;
1047         return (autocvar_g_ctf_ignore_frags); // no frags counted in ctf if this is true
1048 }
1049
1050 MUTATOR_HOOKFUNCTION(ctf_RemovePlayer)
1051 {
1052         if(self.flagcarried)
1053                 { ctf_Handle_Throw(self, world, DROP_NORMAL); }
1054
1055         return 0;
1056 }
1057
1058 MUTATOR_HOOKFUNCTION(ctf_PortalTeleport)
1059 {
1060         if(self.flagcarried)
1061         if(!autocvar_g_ctf_portalteleport)
1062                 { ctf_Handle_Throw(self, world, DROP_NORMAL); }
1063
1064         return 0;
1065 }
1066
1067 MUTATOR_HOOKFUNCTION(ctf_PlayerUseKey)
1068 {
1069         entity player = self;
1070
1071         if((time > player.throw_antispam) && (player.deadflag == DEAD_NO) && !player.speedrunning && (!player.vehicle || autocvar_g_ctf_allow_vehicle_touch))
1072         {
1073                 // pass the flag to a team mate
1074                 if(autocvar_g_ctf_pass)
1075                 {
1076                         entity head, closest_target;
1077                         head = findradius(player.origin, autocvar_g_ctf_pass_radius);
1078
1079                         while(head) // find the closest acceptable target to pass to
1080                         {
1081                                 if(head.classname == "player" && head.deadflag == DEAD_NO)
1082                                 if(head != player && !IsDifferentTeam(head, player))
1083                                 if(!head.speedrunning && (!head.vehicle || autocvar_g_ctf_allow_vehicle_touch))
1084                                 {
1085                                         traceline(player.origin, head.origin, MOVE_NOMONSTERS, player);
1086                                         if not((trace_fraction < 1) && (trace_ent != head))
1087                                         {
1088                                                 if(autocvar_g_ctf_pass_request && !player.flagcarried && head.flagcarried)
1089                                                 {
1090                                                         if(clienttype(head) == CLIENTTYPE_BOT)
1091                                                         {
1092                                                                 centerprint(player, strcat("Requesting ", head.netname, " to pass you the ", head.flagcarried.netname));
1093                                                                 ctf_Handle_Throw(head, player, DROP_PASS);
1094                                                         }
1095                                                         else
1096                                                         {
1097                                                                 centerprint(head, strcat(player.netname, " requests you to pass the ", head.flagcarried.netname));
1098                                                                 centerprint(player, strcat("Requesting ", head.netname, " to pass you the ", head.flagcarried.netname));
1099                                                         }
1100                                                         player.throw_antispam = time + autocvar_g_ctf_pass_wait;
1101                                                         return 0;
1102                                                 }
1103                                                 else if(player.flagcarried)
1104                                                 {
1105                                                         if(closest_target) { if(vlen(player.origin - head.origin) < vlen(player.origin - closest_target.origin)) { closest_target = head; } }
1106                                                         else { closest_target = head; }
1107                                                 }
1108                                         }
1109                                 }
1110                                 head = head.chain;
1111                         }
1112
1113                         if(closest_target) { ctf_Handle_Throw(player, closest_target, DROP_PASS); return 0; }
1114                 }
1115
1116                 // throw the flag in front of you
1117                 if(autocvar_g_ctf_drop && player.flagcarried)
1118                         { ctf_Handle_Throw(player, world, DROP_THROW); }
1119         }
1120
1121         return 0;
1122 }
1123
1124 MUTATOR_HOOKFUNCTION(ctf_HelpMePing)
1125 {
1126         if(self.wps_flagcarrier) // update the flagcarrier waypointsprite with "NEEDING HELP" notification
1127         {
1128                 WaypointSprite_HelpMePing(self.wps_flagcarrier);
1129         }
1130         else // create a normal help me waypointsprite
1131         {
1132                 WaypointSprite_Spawn("helpme", waypointsprite_deployed_lifetime, waypointsprite_limitedrange, self, FLAG_WAYPOINT_OFFSET, world, self.team, self, wps_helpme, FALSE, RADARICON_HELPME, '1 0.5 0');
1133                 WaypointSprite_Ping(self.wps_helpme);
1134         }
1135
1136         return 1;
1137 }
1138
1139 MUTATOR_HOOKFUNCTION(ctf_VehicleEnter)
1140 {
1141         if(other.flagcarried)
1142         {
1143                 if(!autocvar_g_ctf_flagcarrier_allow_vehicle_carry)
1144                 {
1145                         ctf_Handle_Throw(self, world, DROP_NORMAL);
1146                 }
1147                 else
1148                 {
1149                         setattachment(other.flagcarried, self, "");
1150                         setorigin(other, VEHICLE_FLAG_OFFSET);
1151                         other.flagcarried.scale = VEHICLE_FLAG_SCALE;
1152                         //other.flagcarried.angles = '0 0 0';
1153                 }
1154         }
1155
1156         return 0;
1157 }
1158
1159 MUTATOR_HOOKFUNCTION(ctf_VehicleExit)
1160 {
1161         if(self.owner.flagcarried)
1162         {
1163                 setattachment(self.owner.flagcarried, self.owner, "");
1164                 setorigin(self.owner.flagcarried, FLAG_CARRY_OFFSET);
1165                 self.owner.flagcarried.scale = FLAG_SCALE;
1166                 self.owner.flagcarried.angles = '0 0 0';
1167         }
1168
1169         return 0;
1170 }
1171
1172 MUTATOR_HOOKFUNCTION(ctf_AbortSpeedrun)
1173 {
1174         if(self.flagcarried)
1175         {
1176                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
1177                 ctf_RespawnFlag(self);
1178         }
1179
1180         return 0;
1181 }
1182
1183 MUTATOR_HOOKFUNCTION(ctf_MatchEnd)
1184 {
1185         entity flag; // temporary entity for the search method
1186
1187         for(flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext)
1188         {
1189                 switch(flag.ctf_status)
1190                 {
1191                         case FLAG_DROPPED:
1192                         case FLAG_PASSING:
1193                         {
1194                                 // lock the flag, game is over
1195                                 flag.movetype = MOVETYPE_NONE;
1196                                 flag.takedamage = DAMAGE_NO;
1197                                 flag.solid = SOLID_NOT;
1198                                 flag.nextthink = 0; // stop thinking
1199
1200                                 print("stopping the ", flag.netname, " from moving.\n");
1201                                 break;
1202                         }
1203
1204                         default:
1205                         case FLAG_BASE:
1206                         case FLAG_CARRY:
1207                         {
1208                                 // do nothing for these flags
1209                                 break;
1210                         }
1211                 }
1212         }
1213
1214         return 0;
1215 }
1216
1217
1218 // ==========
1219 // Spawnfuncs
1220 // ==========
1221
1222 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
1223 CTF Starting point for a player in team one (Red).
1224 Keys: "angle" viewing angle when spawning. */
1225 void spawnfunc_info_player_team1()
1226 {
1227         if(g_assault) { remove(self); return; }
1228
1229         self.team = COLOR_TEAM1; // red
1230         spawnfunc_info_player_deathmatch();
1231 }
1232
1233
1234 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
1235 CTF Starting point for a player in team two (Blue).
1236 Keys: "angle" viewing angle when spawning. */
1237 void spawnfunc_info_player_team2()
1238 {
1239         if(g_assault) { remove(self); return; }
1240
1241         self.team = COLOR_TEAM2; // blue
1242         spawnfunc_info_player_deathmatch();
1243 }
1244
1245 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
1246 CTF Starting point for a player in team three (Yellow).
1247 Keys: "angle" viewing angle when spawning. */
1248 void spawnfunc_info_player_team3()
1249 {
1250         if(g_assault) { remove(self); return; }
1251
1252         self.team = COLOR_TEAM3; // yellow
1253         spawnfunc_info_player_deathmatch();
1254 }
1255
1256
1257 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
1258 CTF Starting point for a player in team four (Purple).
1259 Keys: "angle" viewing angle when spawning. */
1260 void spawnfunc_info_player_team4()
1261 {
1262         if(g_assault) { remove(self); return; }
1263
1264         self.team = COLOR_TEAM4; // purple
1265         spawnfunc_info_player_deathmatch();
1266 }
1267
1268 /*QUAKED spawnfunc_item_flag_team1 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
1269 CTF flag for team one (Red).
1270 Keys:
1271 "angle" Angle the flag will point (minus 90 degrees)...
1272 "model" model to use, note this needs red and blue as skins 0 and 1...
1273 "noise" sound played when flag is picked up...
1274 "noise1" sound played when flag is returned by a teammate...
1275 "noise2" sound played when flag is captured...
1276 "noise3" sound played when flag is lost in the field and respawns itself...
1277 "noise4" sound played when flag is dropped by a player...
1278 "noise5" sound played when flag touches the ground... */
1279 void spawnfunc_item_flag_team1()
1280 {
1281         if(!g_ctf) { remove(self); return; }
1282
1283         ctf_FlagSetup(1, self); // 1 = red
1284 }
1285
1286 /*QUAKED spawnfunc_item_flag_team2 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
1287 CTF flag for team two (Blue).
1288 Keys:
1289 "angle" Angle the flag will point (minus 90 degrees)...
1290 "model" model to use, note this needs red and blue as skins 0 and 1...
1291 "noise" sound played when flag is picked up...
1292 "noise1" sound played when flag is returned by a teammate...
1293 "noise2" sound played when flag is captured...
1294 "noise3" sound played when flag is lost in the field and respawns itself...
1295 "noise4" sound played when flag is dropped by a player...
1296 "noise5" sound played when flag touches the ground... */
1297 void spawnfunc_item_flag_team2()
1298 {
1299         if(!g_ctf) { remove(self); return; }
1300
1301         ctf_FlagSetup(0, self); // the 0 is misleading, but -- 0 = blue.
1302 }
1303
1304 /*QUAKED spawnfunc_ctf_team (0 .5 .8) (-16 -16 -24) (16 16 32)
1305 Team declaration for CTF gameplay, this allows you to decide what team names and control point models are used in your map.
1306 Note: If you use spawnfunc_ctf_team entities you must define at least 2!  However, unlike domination, you don't need to make a blank one too.
1307 Keys:
1308 "netname" Name of the team (for example Red, Blue, Green, Yellow, Life, Death, Offense, Defense, etc)...
1309 "cnt" Scoreboard color of the team (for example 4 is red and 13 is blue)... */
1310 void spawnfunc_ctf_team()
1311 {
1312         if(!g_ctf) { remove(self); return; }
1313
1314         self.classname = "ctf_team";
1315         self.team = self.cnt + 1;
1316 }
1317
1318
1319 // ==============
1320 // Initialization
1321 // ==============
1322
1323 // code from here on is just to support maps that don't have flag and team entities
1324 void ctf_SpawnTeam (string teamname, float teamcolor)
1325 {
1326         entity oldself;
1327         oldself = self;
1328         self = spawn();
1329         self.classname = "ctf_team";
1330         self.netname = teamname;
1331         self.cnt = teamcolor;
1332
1333         spawnfunc_ctf_team();
1334
1335         self = oldself;
1336 }
1337
1338 void ctf_DelayedInit() // Do this check with a delay so we can wait for teams to be set up.
1339 {
1340         // if no teams are found, spawn defaults
1341         if(find(world, classname, "ctf_team") == world)
1342         {
1343                 print("No ""ctf_team"" entities found on this map, creating them anyway.\n");
1344                 ctf_SpawnTeam("Red", COLOR_TEAM1 - 1);
1345                 ctf_SpawnTeam("Blue", COLOR_TEAM2 - 1);
1346         }
1347
1348         ScoreRules_ctf();
1349 }
1350
1351 void ctf_Initialize()
1352 {
1353         ctf_captimerecord = stof(db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time")));
1354
1355         ctf_captureshield_min_negscore = autocvar_g_ctf_shield_min_negscore;
1356         ctf_captureshield_max_ratio = autocvar_g_ctf_shield_max_ratio;
1357         ctf_captureshield_force = autocvar_g_ctf_shield_force;
1358
1359         InitializeEntity(world, ctf_DelayedInit, INITPRIO_GAMETYPE);
1360 }
1361
1362
1363 MUTATOR_DEFINITION(gamemode_ctf)
1364 {
1365         MUTATOR_HOOK(MakePlayerObserver, ctf_RemovePlayer, CBC_ORDER_ANY);
1366         MUTATOR_HOOK(ClientDisconnect, ctf_RemovePlayer, CBC_ORDER_ANY);
1367         MUTATOR_HOOK(PlayerDies, ctf_PlayerDies, CBC_ORDER_ANY);
1368         MUTATOR_HOOK(MatchEnd, ctf_MatchEnd, CBC_ORDER_ANY);
1369         MUTATOR_HOOK(PortalTeleport, ctf_PortalTeleport, CBC_ORDER_ANY);
1370         MUTATOR_HOOK(GiveFragsForKill, ctf_GiveFragsForKill, CBC_ORDER_ANY);
1371         MUTATOR_HOOK(PlayerPreThink, ctf_PlayerPreThink, CBC_ORDER_ANY);
1372         MUTATOR_HOOK(PlayerDamage_Calculate, ctf_PlayerDamage, CBC_ORDER_ANY);
1373         MUTATOR_HOOK(PlayerUseKey, ctf_PlayerUseKey, CBC_ORDER_ANY);
1374         MUTATOR_HOOK(HelpMePing, ctf_HelpMePing, CBC_ORDER_ANY);
1375         MUTATOR_HOOK(VehicleEnter, ctf_VehicleEnter, CBC_ORDER_ANY);
1376         MUTATOR_HOOK(VehicleExit, ctf_VehicleExit, CBC_ORDER_ANY);
1377         MUTATOR_HOOK(AbortSpeedrun, ctf_AbortSpeedrun, CBC_ORDER_ANY);
1378
1379         MUTATOR_ONADD
1380         {
1381                 if(time > 1) // game loads at time 1
1382                         error("This is a game type and it cannot be added at runtime.");
1383                 g_ctf = 1;
1384                 ctf_Initialize();
1385         }
1386
1387         MUTATOR_ONREMOVE
1388         {
1389                 g_ctf = 0;
1390                 error("This is a game type and it cannot be removed at runtime.");
1391         }
1392
1393         return 0;
1394 }