qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6
   7     #include "bot/bot.qh"
   8     #include "bot/waypoints.qh"
   9
  10     #include "mutators/all.qh"
  11
  12     #include "weapons/common.qh"
  13     #include "weapons/selection.qh"
  14     #include "weapons/weaponsystem.qh"
  15
  16     #include "../common/constants.qh"
  17     #include "../common/deathtypes/all.qh"
  18     #include "../common/notifications.qh"
  19         #include "../common/triggers/subs.qh"
  20     #include "../common/util.qh"
  21
  22     #include "../common/monsters/all.qh"
  23
  24     #include "../common/weapons/all.qh"
  25
  26     #include "../lib/warpzone/util_server.qh"
  27 #endif
  28
  29 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  30
  31 #ifdef CSQC
  32 void ItemDraw(entity self)
  33 {
  34     if(self.gravity)
  35     {
  36         Movetype_Physics_MatchServer(self, autocvar_cl_projectiles_sloppy);
  37         if(self.move_flags & FL_ONGROUND)
  38         { // For some reason move_avelocity gets set to '0 0 0' here ...
  39             self.oldorigin = self.origin;
  40             self.gravity = 0;
  41
  42             if(autocvar_cl_animate_items)
  43             { // ... so reset it if animations are requested.
  44                 if(self.ItemStatus & ITS_ANIMATE1)
  45                     self.move_avelocity = '0 180 0';
  46
  47                 if(self.ItemStatus & ITS_ANIMATE2)
  48                     self.move_avelocity = '0 -90 0';
  49             }
  50         }
  51     }
  52     else if (autocvar_cl_animate_items)
  53     {
  54         if(self.ItemStatus & ITS_ANIMATE1)
  55         {
  56             self.angles += self.move_avelocity * frametime;
  57             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  58         }
  59
  60         if(self.ItemStatus & ITS_ANIMATE2)
  61         {
  62             self.angles += self.move_avelocity * frametime;
  63             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  64         }
  65     }
  66 }
  67
  68 void ItemDrawSimple(entity this)
  69 {
  70     if(self.gravity)
  71     {
  72         Movetype_Physics_MatchServer(self, autocvar_cl_projectiles_sloppy);
  73
  74         if(self.move_flags & FL_ONGROUND)
  75             self.gravity = 0;
  76     }
  77 }
  78
  79 void Item_PreDraw()
  80 {SELFPARAM();
  81         vector org;
  82         float alph;
  83         org = getpropertyvec(VF_ORIGIN);
  84         if(!checkpvs(org, self)) // this makes sense as long as we don't support recursive warpzones
  85                 alph = 0;
  86         else if(self.fade_start)
  87                 alph = bound(0, (self.fade_end - vlen(org - self.origin - 0.5 * (self.mins + self.maxs))) / (self.fade_end - self.fade_start), 1);
  88         else
  89                 alph = 1;
  90         //printf("%v <-> %v\n", view_origin, self.origin + 0.5 * (self.mins + self.maxs));
  91         if(self.ItemStatus & ITS_AVAILABLE)
  92                 self.alpha = alph;
  93         if(alph <= 0)
  94                 self.drawmask = 0;
  95         else
  96                 self.drawmask = MASK_NORMAL;
  97 }
  98
  99 void ItemRemove()
 100 {SELFPARAM();
 101         if (self.mdl)
 102                 strunzone(self.mdl);
 103 }
 104
 105 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 106 {
 107     int sf = ReadByte();
 108
 109     if(sf & ISF_LOCATION)
 110     {
 111         self.origin_x = ReadCoord();
 112         self.origin_y = ReadCoord();
 113         self.origin_z = ReadCoord();
 114         setorigin(self, self.origin);
 115         self.oldorigin = self.origin;
 116     }
 117
 118     if(sf & ISF_ANGLES)
 119     {
 120         self.angles_x = ReadAngle();
 121         self.angles_y = ReadAngle();
 122         self.angles_z = ReadAngle();
 123         self.move_angles = self.angles;
 124     }
 125
 126     if(sf & ISF_SIZE)
 127     {
 128         float use_bigsize = ReadByte();
 129         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 130     }
 131
 132     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 133     {
 134         self.ItemStatus = ReadByte();
 135
 136         if(self.ItemStatus & ITS_AVAILABLE)
 137         {
 138             self.alpha = 1;
 139             self.colormod = self.glowmod = '1 1 1';
 140         }
 141         else
 142         {
 143             if (autocvar_cl_ghost_items_color)
 144             {
 145                 self.alpha = autocvar_cl_ghost_items;
 146                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 147             }
 148             else
 149                 self.alpha = -1;
 150         }
 151
 152         if(autocvar_cl_fullbright_items)
 153             if(self.ItemStatus & ITS_ALLOWFB)
 154                 self.effects |= EF_FULLBRIGHT;
 155
 156         if(self.ItemStatus & ITS_STAYWEP)
 157         {
 158             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 159             self.alpha = autocvar_cl_weapon_stay_alpha;
 160
 161         }
 162
 163         if(self.ItemStatus & ITS_POWERUP)
 164         {
 165             if(self.ItemStatus & ITS_AVAILABLE)
 166                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 167             else
 168                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 169         }
 170     }
 171
 172     if(sf & ISF_MODEL)
 173     {
 174         self.drawmask  = MASK_NORMAL;
 175                 self.move_movetype = self.movetype = MOVETYPE_TOSS;
 176         self.draw       = ItemDraw;
 177         //self.move_flags |= FL_ITEM;
 178
 179         bool use_bigsize = ReadByte();
 180
 181         self.fade_end = ReadShort();
 182         self.fade_start = ReadShort();
 183         if(self.fade_start && !autocvar_cl_items_nofade)
 184                 self.predraw = Item_PreDraw;
 185
 186         if(self.mdl)
 187             strunzone(self.mdl);
 188
 189         self.mdl = "";
 190         string _fn = ReadString();
 191
 192         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 193         {
 194             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 195             self.draw = ItemDrawSimple;
 196
 197             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 198                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 199             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 200                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 201             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 202                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 203             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 204                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 205             else
 206             {
 207                 self.draw = ItemDraw;
 208                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 209             }
 210         }
 211
 212         if(self.draw != ItemDrawSimple)
 213             self.mdl = strzone(_fn);
 214
 215
 216         if(self.mdl == "")
 217             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 218
 219         precache_model(self.mdl);
 220         _setmodel(self, self.mdl);
 221
 222         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 223     }
 224
 225     if(sf & ISF_COLORMAP)
 226         self.colormap = ReadShort();
 227
 228     if(sf & ISF_DROP)
 229     {
 230         self.gravity = 1;
 231         //self.move_angles = '0 0 0';
 232         self.move_movetype = MOVETYPE_TOSS;
 233         self.move_velocity_x = ReadCoord();
 234         self.move_velocity_y = ReadCoord();
 235         self.move_velocity_z = ReadCoord();
 236         self.velocity = self.move_velocity;
 237         self.move_origin = self.oldorigin;
 238
 239         if(!self.move_time)
 240         {
 241             self.move_time = time;
 242             self.spawntime = time;
 243         }
 244         else
 245             self.move_time = max(self.move_time, time);
 246     }
 247
 248     if(autocvar_cl_animate_items)
 249     {
 250         if(self.ItemStatus & ITS_ANIMATE1)
 251             self.move_avelocity = '0 180 0';
 252
 253         if(self.ItemStatus & ITS_ANIMATE2)
 254             self.move_avelocity = '0 -90 0';
 255     }
 256
 257     self.entremove = ItemRemove;
 258
 259     return true;
 260 }
 261
 262 #endif
 263
 264 #ifdef SVQC
 265 bool ItemSend(entity this, entity to, int sf)
 266 {
 267         if(self.gravity)
 268                 sf |= ISF_DROP;
 269         else
 270                 sf &= ~ISF_DROP;
 271
 272         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 273         WriteByte(MSG_ENTITY, sf);
 274
 275         //WriteByte(MSG_ENTITY, self.cnt);
 276         if(sf & ISF_LOCATION)
 277         {
 278                 WriteCoord(MSG_ENTITY, self.origin.x);
 279                 WriteCoord(MSG_ENTITY, self.origin.y);
 280                 WriteCoord(MSG_ENTITY, self.origin.z);
 281         }
 282
 283         if(sf & ISF_ANGLES)
 284         {
 285                 WriteAngle(MSG_ENTITY, self.angles_x);
 286                 WriteAngle(MSG_ENTITY, self.angles_y);
 287                 WriteAngle(MSG_ENTITY, self.angles_z);
 288         }
 289
 290         if(sf & ISF_SIZE)
 291         {
 292                 Pickup p = this.itemdef;
 293                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 294         }
 295
 296         if(sf & ISF_STATUS)
 297                 WriteByte(MSG_ENTITY, self.ItemStatus);
 298
 299         if(sf & ISF_MODEL)
 300         {
 301                 Pickup p = this.itemdef;
 302                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 303                 WriteShort(MSG_ENTITY, self.fade_end);
 304                 WriteShort(MSG_ENTITY, self.fade_start);
 305
 306                 if(self.mdl == "")
 307                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 308
 309                 WriteString(MSG_ENTITY, self.mdl);
 310         }
 311
 312
 313         if(sf & ISF_COLORMAP)
 314                 WriteShort(MSG_ENTITY, self.colormap);
 315
 316         if(sf & ISF_DROP)
 317         {
 318                 WriteCoord(MSG_ENTITY, self.velocity.x);
 319                 WriteCoord(MSG_ENTITY, self.velocity.y);
 320                 WriteCoord(MSG_ENTITY, self.velocity.z);
 321         }
 322
 323         return true;
 324 }
 325
 326 void ItemUpdate(entity this)
 327 {
 328         this.oldorigin = this.origin;
 329         this.SendFlags |= ISF_LOCATION;
 330 }
 331
 332 void UpdateItemAfterTeleport(entity this)
 333 {
 334         if(this.SendEntity3 == ItemSend)
 335                 ItemUpdate(this);
 336 }
 337
 338 bool have_pickup_item(entity this)
 339 {
 340         if(this.itemdef.instanceOfPowerup)
 341         {
 342                 if(autocvar_g_powerups > 0)
 343                         return true;
 344                 if(autocvar_g_powerups == 0)
 345                         return false;
 346         }
 347         else
 348         {
 349                 if(autocvar_g_pickup_items > 0)
 350                         return true;
 351                 if(autocvar_g_pickup_items == 0)
 352                         return false;
 353                 if(g_weaponarena)
 354                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 355                                 return false;
 356         }
 357         return true;
 358 }
 359
 360 /*
 361 float Item_Customize()
 362 {
 363         if(self.spawnshieldtime)
 364                 return true;
 365         if(self.weapons & ~other.weapons)
 366         {
 367                 self.colormod = '0 0 0';
 368                 self.glowmod = self.colormod;
 369                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 370                 return true;
 371         }
 372         else
 373         {
 374                 if(g_ghost_items)
 375                 {
 376                         self.colormod = stov(autocvar_g_ghost_items_color);
 377                         self.glowmod = self.colormod;
 378                         self.alpha = g_ghost_items;
 379                         return true;
 380                 }
 381                 else
 382                         return false;
 383         }
 384 }
 385 */
 386
 387 void Item_Show (entity e, float mode)
 388 {
 389         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 390         e.ItemStatus &= ~ITS_STAYWEP;
 391         if (mode > 0)
 392         {
 393                 // make the item look normal, and be touchable
 394                 e.model = e.mdl;
 395                 e.solid = SOLID_TRIGGER;
 396                 e.spawnshieldtime = 1;
 397                 e.ItemStatus |= ITS_AVAILABLE;
 398         }
 399         else if (mode < 0)
 400         {
 401                 // hide the item completely
 402                 e.model = string_null;
 403                 e.solid = SOLID_NOT;
 404                 e.spawnshieldtime = 1;
 405                 e.ItemStatus &= ~ITS_AVAILABLE;
 406         }
 407         else {
 408         entity def = e.itemdef;
 409         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 410                 || e.team // weapon stay isn't supported for teamed weapons
 411                 ;
 412         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 413         {
 414                 // make the item translucent and not touchable
 415                 e.model = e.mdl;
 416                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 417                 e.effects |= EF_STARDUST;
 418                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 419                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 420         }
 421         else
 422         {
 423                 //setmodel(e, "null");
 424                 e.solid = SOLID_NOT;
 425                 e.colormod = '0 0 0';
 426                 e.glowmod = e.colormod;
 427                 e.spawnshieldtime = 1;
 428                 e.ItemStatus &= ~ITS_AVAILABLE;
 429         }}
 430
 431         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 432                 e.ItemStatus |= ITS_POWERUP;
 433
 434         if (autocvar_g_nodepthtestitems)
 435                 e.effects |= EF_NODEPTHTEST;
 436
 437
 438         if (autocvar_g_fullbrightitems)
 439                 e.ItemStatus |= ITS_ALLOWFB;
 440
 441         if (autocvar_sv_simple_items)
 442                 e.ItemStatus |= ITS_ALLOWSI;
 443
 444         // relink entity (because solid may have changed)
 445         setorigin(e, e.origin);
 446         e.SendFlags |= ISF_STATUS;
 447 }
 448
 449 void Item_Think()
 450 {SELFPARAM();
 451         self.nextthink = time;
 452         if(self.origin != self.oldorigin)
 453                 ItemUpdate(self);
 454 }
 455
 456 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 457 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 458 float Item_ItemsTime_UpdateTime(entity e, float t);
 459 void Item_ItemsTime_SetTime(entity e, float t);
 460 void Item_ItemsTime_SetTimesForAllPlayers();
 461
 462 void Item_Respawn ()
 463 {SELFPARAM();
 464         Item_Show(self, 1);
 465         // this is ugly...
 466         if(self.items == ITEM_Strength.m_itemid)
 467                 sound (self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
 468         else if(self.items == ITEM_Shield.m_itemid)
 469                 sound (self, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
 470         else
 471                 sound (self, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 472         setorigin (self, self.origin);
 473
 474     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 475         {
 476                 float t = Item_ItemsTime_UpdateTime(self, 0);
 477                 Item_ItemsTime_SetTime(self, t);
 478                 Item_ItemsTime_SetTimesForAllPlayers();
 479         }
 480
 481         self.think = Item_Think;
 482         self.nextthink = time;
 483
 484         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 485         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 486 }
 487
 488 void Item_RespawnCountdown ()
 489 {SELFPARAM();
 490         if(self.count >= ITEM_RESPAWN_TICKS)
 491         {
 492                 if(self.waypointsprite_attached)
 493                         WaypointSprite_Kill(self.waypointsprite_attached);
 494                 Item_Respawn();
 495         }
 496         else
 497         {
 498                 self.nextthink = time + 1;
 499                 self.count += 1;
 500                 if(self.count == 1)
 501                 {
 502                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 503                         do {
 504                                 {
 505                                         entity wi = Weapons_from(self.weapon);
 506                                         if (wi != WEP_Null) {
 507                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Weapon);
 508                                                 wp.wp_extra = wi.m_id;
 509                                                 break;
 510                                         }
 511                                 }
 512                                 {
 513                                         entity ii = self.itemdef;
 514                                         if (ii != NULL) {
 515                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Item);
 516                                                 wp.wp_extra = ii.m_id;
 517                                                 break;
 518                                         }
 519                                 }
 520                         } while (0);
 521             if(self.waypointsprite_attached)
 522             {
 523                 GameItem def = self.itemdef;
 524                 if (Item_ItemsTime_SpectatorOnly(def))
 525                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 526                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 527             }
 528                 }
 529
 530                 if(self.waypointsprite_attached)
 531                 {
 532                         setself(self.waypointsprite_attached);
 533                         entity e;
 534                         FOR_EACH_REALCLIENT(e)
 535                                 if(self.waypointsprite_visible_for_player(e))
 536                                 {
 537                                         msg_entity = e;
 538                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 539                                 }
 540                         setself(this);
 541
 542                         WaypointSprite_Ping(self.waypointsprite_attached);
 543                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 544                 }
 545         }
 546 }
 547
 548 void Item_RespawnThink()
 549 {SELFPARAM();
 550         self.nextthink = time;
 551         if(self.origin != self.oldorigin)
 552                 ItemUpdate(self);
 553
 554         if(time >= self.wait)
 555                 Item_Respawn();
 556 }
 557
 558 void Item_ScheduleRespawnIn(entity e, float t)
 559 {
 560         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 561         {
 562                 e.think = Item_RespawnCountdown;
 563                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 564                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 565                 e.count = 0;
 566                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 567                 Item_ItemsTime_SetTime(e, t);
 568                 Item_ItemsTime_SetTimesForAllPlayers();
 569         }
 570         else
 571         {
 572                 e.think = Item_RespawnThink;
 573                 e.nextthink = time;
 574                 e.scheduledrespawntime = time + t;
 575                 e.wait = time + t;
 576         }
 577 }
 578
 579 void Item_ScheduleRespawn(entity e)
 580 {
 581         if(e.respawntime > 0)
 582         {
 583                 Item_Show(e, 0);
 584                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 585         }
 586         else // if respawntime is -1, this item does not respawn
 587                 Item_Show(e, -1);
 588 }
 589
 590 void Item_ScheduleInitialRespawn(entity e)
 591 {
 592         Item_Show(e, 0);
 593         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 594 }
 595
 596 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 597 {
 598         if (!item.(ammotype))
 599                 return false;
 600
 601         if (item.spawnshieldtime)
 602         {
 603                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 604                 {
 605                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 606                         goto YEAH;
 607                 }
 608         }
 609         else if(g_weapon_stay == 2)
 610         {
 611                 float mi = min(item.(ammotype), ammomax);
 612                 if (player.(ammotype) < mi)
 613                 {
 614                         player.(ammotype) = mi;
 615                         goto YEAH;
 616                 }
 617         }
 618
 619         return false;
 620
 621 :YEAH
 622         switch(mode)
 623         {
 624                 case ITEM_MODE_FUEL:
 625                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 626                         break;
 627                 case ITEM_MODE_HEALTH:
 628                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 629                         break;
 630                 case ITEM_MODE_ARMOR:
 631                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 632                         break;
 633                 default:
 634                         break;
 635         }
 636         return true;
 637 }
 638
 639 float Item_GiveTo(entity item, entity player)
 640 {
 641         float _switchweapon;
 642         float pickedup;
 643         float it;
 644         float i;
 645
 646         // if nothing happens to player, just return without taking the item
 647         pickedup = false;
 648         _switchweapon = false;
 649         // in case the player has autoswitch enabled do the following:
 650         // if the player is using their best weapon before items are given, they
 651         // probably want to switch to an even better weapon after items are given
 652         if (player.autoswitch)
 653         if (PS(player).m_switchweapon == w_getbestweapon(player))
 654                 _switchweapon = true;
 655
 656         if (!(player.weapons & WepSet_FromWeapon(PS(player).m_switchweapon)))
 657                 _switchweapon = true;
 658
 659         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 660         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 661         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 662         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 663         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 664         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 665         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 666         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 667
 668         if (item.itemdef.instanceOfWeaponPickup)
 669         {
 670                 WepSet it;
 671                 it = item.weapons;
 672                 it &= ~player.weapons;
 673
 674                 if (it || (item.spawnshieldtime && item.pickup_anyway > 0))
 675                 {
 676                         pickedup = true;
 677                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 678                         if(it & WepSet_FromWeapon(Weapons_from(i)))
 679                         {
 680                                 W_DropEvent(wr_pickup, player, i, item);
 681                                 W_GiveWeapon(player, i);
 682                         }
 683                 }
 684         }
 685
 686         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 687         {
 688                 pickedup = true;
 689                 player.items |= it;
 690                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 691         }
 692
 693         if (item.strength_finished)
 694         {
 695                 pickedup = true;
 696                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 697         }
 698         if (item.invincible_finished)
 699         {
 700                 pickedup = true;
 701                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 702         }
 703         if (item.superweapons_finished)
 704         {
 705                 pickedup = true;
 706                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 707         }
 708
 709 :skip
 710
 711         // always eat teamed entities
 712         if(item.team)
 713                 pickedup = true;
 714
 715         if (!pickedup)
 716                 return 0;
 717
 718         // crude hack to enforce switching weapons
 719         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 720         {
 721                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon));
 722                 return 1;
 723         }
 724
 725         if (_switchweapon)
 726                 if (PS(player).m_switchweapon != w_getbestweapon(player))
 727                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 728
 729         return 1;
 730 }
 731
 732 void Item_Touch()
 733 {
 734         SELFPARAM();
 735
 736         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 737         if (this.classname == "droppedweapon")
 738         {
 739                 if (ITEM_TOUCH_NEEDKILL())
 740                 {
 741                         remove(this);
 742                         return;
 743                 }
 744         }
 745
 746         if(!(other.flags & FL_PICKUPITEMS)
 747         || other.frozen
 748         || other.deadflag
 749         || (this.solid != SOLID_TRIGGER)
 750         || (this.owner == other)
 751         || (time < this.item_spawnshieldtime)
 752         ) { return; }
 753
 754         switch (MUTATOR_CALLHOOK(ItemTouch, this, other))
 755         {
 756                 case MUT_ITEMTOUCH_RETURN: { return; }
 757                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 758         }
 759
 760         if (this.classname == "droppedweapon")
 761         {
 762                 this.strength_finished = max(0, this.strength_finished - time);
 763                 this.invincible_finished = max(0, this.invincible_finished - time);
 764                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 765         }
 766         entity it = this.itemdef;
 767         bool gave = ITEM_HANDLE(Pickup, it, this, other);
 768         if (!gave)
 769         {
 770                 if (this.classname == "droppedweapon")
 771                 {
 772                         // undo what we did above
 773                         this.strength_finished += time;
 774                         this.invincible_finished += time;
 775                         this.superweapons_finished += time;
 776                 }
 777                 return;
 778         }
 779
 780         :pickup
 781
 782         other.last_pickup = time;
 783
 784         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 785         _sound (other, CH_TRIGGER, (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 786
 787         if (this.classname == "droppedweapon")
 788                 remove (this);
 789         else if (this.spawnshieldtime)
 790         {
 791                 entity e;
 792                 if(this.team)
 793                 {
 794                         RandomSelection_Init();
 795                         for(entity head = world; (head = findfloat(head, team, this.team)); )
 796                         {
 797                                 if(head.flags & FL_ITEM)
 798                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 799                                 {
 800                                         Item_Show(head, -1);
 801                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 802                                 }
 803                         }
 804                         e = RandomSelection_chosen_ent;
 805
 806                 }
 807                 else
 808                         e = this;
 809                 Item_ScheduleRespawn(e);
 810         }
 811 }
 812
 813 void Item_Reset(entity this)
 814 {
 815         Item_Show(this, !this.state);
 816         setorigin(this, this.origin);
 817
 818         if (this.classname != "droppedweapon")
 819         {
 820                 this.think = Item_Think;
 821                 this.nextthink = time;
 822
 823                 if (this.waypointsprite_attached)
 824                         WaypointSprite_Kill(this.waypointsprite_attached);
 825
 826                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 827                         Item_ScheduleInitialRespawn(this);
 828         }
 829 }
 830 void Item_Reset_self() { SELFPARAM(); Item_Reset(this); }
 831
 832 void Item_FindTeam()
 833 {SELFPARAM();
 834         entity head, e;
 835
 836         if(self.effects & EF_NODRAW)
 837         {
 838                 // marker for item team search
 839                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 840                 RandomSelection_Init();
 841                 for(head = world; (head = findfloat(head, team, self.team)); )
 842                 if(head.flags & FL_ITEM)
 843                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 844                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 845                 e = RandomSelection_chosen_ent;
 846                 e.state = 0;
 847                 Item_Show(e, 1);
 848
 849                 for(head = world; (head = findfloat(head, team, self.team)); )
 850                 if(head.flags & FL_ITEM)
 851                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 852                 {
 853                         if(head != e)
 854                         {
 855                                 // make it a non-spawned item
 856                                 Item_Show(head, -1);
 857                                 head.state = 1; // state 1 = initially hidden item
 858                         }
 859                         head.effects &= ~EF_NODRAW;
 860                 }
 861
 862                 Item_Reset(self);
 863         }
 864 }
 865
 866 // Savage: used for item garbage-collection
 867 // TODO: perhaps nice special effect?
 868 void RemoveItem()
 869 {SELFPARAM();
 870         if(wasfreed(self) || !self) { return; }
 871         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 872         remove(self);
 873 }
 874
 875 // pickup evaluation functions
 876 // these functions decide how desirable an item is to the bots
 877
 878 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 879
 880 float weapon_pickupevalfunc(entity player, entity item)
 881 {
 882         float c;
 883
 884         // See if I have it already
 885         if(item.weapons & ~player.weapons)
 886         {
 887                 // If I can pick it up
 888                 if(!item.spawnshieldtime)
 889                         c = 0;
 890                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 891                 {
 892                         // Skilled bots will grab more
 893                         c = bound(0, skill / 10, 1) * 0.5;
 894                 }
 895                 else
 896                         c = 0;
 897         }
 898         else
 899                 c = 1;
 900
 901         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 902         if( bot_custom_weapon && c )
 903         {
 904                 // Find the highest position on any range
 905                 int position = -1;
 906                 for (int j = 0; j < WEP_LAST ; ++j){
 907                         if(
 908                                         bot_weapons_far[j] == item.weapon ||
 909                                         bot_weapons_mid[j] == item.weapon ||
 910                                         bot_weapons_close[j] == item.weapon
 911                           )
 912                         {
 913                                 position = j;
 914                                 break;
 915                         }
 916                 }
 917
 918                 // Rate it
 919                 if (position >= 0 )
 920                 {
 921                         position = WEP_LAST - position;
 922                         // item.bot_pickupbasevalue is overwritten here
 923                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 924                 }
 925         }
 926
 927         return item.bot_pickupbasevalue * c;
 928 }
 929
 930 float commodity_pickupevalfunc(entity player, entity item)
 931 {
 932         float c, i;
 933         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 934         entity wi;
 935         c = 0;
 936
 937         // Detect needed ammo
 938         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 939         {
 940                 wi = Weapons_from(i);
 941
 942                 if (!(player.weapons & (wi.m_wepset)))
 943                         continue;
 944
 945                 if(wi.items & ITEM_Shells.m_itemid)
 946                         need_shells = true;
 947                 else if(wi.items & ITEM_Bullets.m_itemid)
 948                         need_nails = true;
 949                 else if(wi.items & ITEM_Rockets.m_itemid)
 950                         need_rockets = true;
 951                 else if(wi.items & ITEM_Cells.m_itemid)
 952                         need_cells = true;
 953                 else if(wi.items & ITEM_Plasma.m_itemid)
 954                         need_plasma = true;
 955                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 956                         need_fuel = true;
 957         }
 958
 959         // TODO: figure out if the player even has the weapon this ammo is for?
 960         // may not affect strategy much though...
 961         // find out how much more ammo/armor/health the player can hold
 962         if (need_shells)
 963         if (item.ammo_shells)
 964         if (player.ammo_shells < g_pickup_shells_max)
 965                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 966         if (need_nails)
 967         if (item.ammo_nails)
 968         if (player.ammo_nails < g_pickup_nails_max)
 969                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 970         if (need_rockets)
 971         if (item.ammo_rockets)
 972         if (player.ammo_rockets < g_pickup_rockets_max)
 973                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 974         if (need_cells)
 975         if (item.ammo_cells)
 976         if (player.ammo_cells < g_pickup_cells_max)
 977                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 978         if (need_plasma)
 979         if (item.ammo_plasma)
 980         if (player.ammo_plasma < g_pickup_plasma_max)
 981                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 982         if (need_fuel)
 983         if (item.ammo_fuel)
 984         if (player.ammo_fuel < g_pickup_fuel_max)
 985                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 986         if (item.armorvalue)
 987         if (player.armorvalue < item.max_armorvalue)
 988                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 989         if (item.health)
 990         if (player.health < item.max_health)
 991                 c = c + max(0, 1 - player.health / item.max_health);
 992
 993         return item.bot_pickupbasevalue * c;
 994 }
 995
 996 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 997 {
 998         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 999                 RemoveItem();
1000 }
1001
1002 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1003 {
1004         string itemname = def.m_name;
1005         Model itemmodel = def.m_model;
1006     Sound pickupsound = def.m_sound;
1007         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1008         float pickupbasevalue = def.m_botvalue;
1009         int itemflags = def.m_itemflags;
1010
1011         startitem_failed = false;
1012
1013         this.item_model_ent = itemmodel;
1014     this.item_pickupsound_ent = pickupsound;
1015
1016         if(!this.respawntime) // both need to be set
1017         {
1018                 this.respawntime = defaultrespawntime;
1019                 this.respawntimejitter = defaultrespawntimejitter;
1020         }
1021
1022         int itemid = def.m_itemid;
1023         this.items = itemid;
1024         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1025         this.weapon = weaponid;
1026
1027         if(!this.fade_end)
1028         {
1029                 this.fade_start = autocvar_g_items_mindist;
1030                 this.fade_end = autocvar_g_items_maxdist;
1031         }
1032
1033         if(weaponid)
1034                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1035
1036         this.flags = FL_ITEM | itemflags;
1037
1038         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1039         {
1040                 startitem_failed = true;
1041                 remove(this);
1042                 return;
1043         }
1044
1045         // is it a dropped weapon?
1046         if (this.classname == "droppedweapon")
1047         {
1048                 this.reset = SUB_Remove;
1049                 // it's a dropped weapon
1050                 this.movetype = MOVETYPE_TOSS;
1051
1052                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1053                 this.think = RemoveItem;
1054                 this.nextthink = time + 20;
1055
1056                 this.takedamage = DAMAGE_YES;
1057                 this.event_damage = Item_Damage;
1058
1059                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1060                 {
1061                         // if item is worthless after a timer, have it expire then
1062                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1063                 }
1064
1065                 // don't drop if in a NODROP zone (such as lava)
1066                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1067                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1068                 {
1069                         startitem_failed = true;
1070                         remove(this);
1071                         return;
1072                 }
1073         }
1074         else
1075         {
1076                 if(!have_pickup_item(this))
1077                 {
1078                         startitem_failed = true;
1079                         remove (this);
1080                         return;
1081                 }
1082
1083                 if(this.angles != '0 0 0')
1084                         this.SendFlags |= ISF_ANGLES;
1085
1086                 this.reset = Item_Reset;
1087                 // it's a level item
1088                 if(this.spawnflags & 1)
1089                         this.noalign = 1;
1090                 if (this.noalign > 0)
1091                         this.movetype = MOVETYPE_NONE;
1092                 else
1093                         this.movetype = MOVETYPE_TOSS;
1094                 // do item filtering according to game mode and other things
1095                 if (this.noalign <= 0)
1096                 {
1097                         // first nudge it off the floor a little bit to avoid math errors
1098                         setorigin(this, this.origin + '0 0 1');
1099                         // set item size before we spawn a spawnfunc_waypoint
1100                         setsize(this, def.m_mins, def.m_maxs);
1101                         this.SendFlags |= ISF_SIZE;
1102                         // note droptofloor returns false if stuck/or would fall too far
1103                         if (!this.noalign)
1104                                 WITH(entity, self, this, droptofloor());
1105                         waypoint_spawnforitem(this);
1106                 }
1107
1108                 /*
1109                  * can't do it that way, as it would break maps
1110                  * TODO make a target_give like entity another way, that perhaps has
1111                  * the weapon name in a key
1112                 if(this.targetname)
1113                 {
1114                         // target_give not yet supported; maybe later
1115                         print("removed targeted ", this.classname, "\n");
1116                         startitem_failed = true;
1117                         remove (this);
1118                         return;
1119                 }
1120                 */
1121
1122                 if(autocvar_spawn_debug >= 2)
1123                 {
1124                         for(entity otheritem = findradius(this.origin, 3); otheritem; otheritem = otheritem.chain)
1125                         {
1126                             // why not flags & fl_item?
1127                                 if(otheritem.is_item)
1128                                 {
1129                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1130                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1131                                         error("Mapper sucks.");
1132                                 }
1133                         }
1134                         this.is_item = true;
1135                 }
1136
1137                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1138
1139                 precache_model(this.model);
1140                 precache_sound(this.item_pickupsound);
1141
1142                 if (   def.instanceOfPowerup
1143                         || def.instanceOfWeaponPickup
1144                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1145                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1146                         || (itemid & (IT_KEY1 | IT_KEY2))
1147                 ) this.target = "###item###"; // for finding the nearest item using find()
1148
1149                 Item_ItemsTime_SetTime(this, 0);
1150         }
1151
1152         this.bot_pickup = true;
1153         this.bot_pickupevalfunc = pickupevalfunc;
1154         this.bot_pickupbasevalue = pickupbasevalue;
1155         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1156         this.netname = itemname;
1157         this.touch = Item_Touch;
1158         setmodel(this, MDL_Null); // precision set below
1159         //this.effects |= EF_LOWPRECISION;
1160
1161         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1162
1163         this.SendFlags |= ISF_SIZE;
1164
1165         if (!(this.spawnflags & 1024)) {
1166                 if(def.instanceOfPowerup)
1167                         this.ItemStatus |= ITS_ANIMATE1;
1168
1169                 if(this.armorvalue || this.health)
1170                         this.ItemStatus |= ITS_ANIMATE2;
1171         }
1172
1173         if(def.instanceOfWeaponPickup)
1174         {
1175                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1176                         this.colormap = 1024; // color shirt=0 pants=0 grey
1177                 else
1178                         this.gravity = 1;
1179                 if (!(this.spawnflags & 1024))
1180                         this.ItemStatus |= ITS_ANIMATE1;
1181                 this.ItemStatus |= ISF_COLORMAP;
1182         }
1183
1184         this.state = 0;
1185         if(this.team) // broken, no idea why.
1186         {
1187                 if(!this.cnt)
1188                         this.cnt = 1; // item probability weight
1189
1190                 this.effects |= EF_NODRAW; // marker for item team search
1191                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1192         }
1193         else
1194                 Item_Reset(this);
1195
1196         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1197
1198         // call this hook after everything else has been done
1199         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1200         {
1201                 startitem_failed = true;
1202                 remove(this);
1203                 return;
1204         }
1205 }
1206
1207 void StartItem(entity this, GameItem def)
1208 {
1209     _StartItem(
1210         this,
1211         this.itemdef = def,
1212         def.m_respawntime(), // defaultrespawntime
1213         def.m_respawntimejitter() // defaultrespawntimejitter
1214         );
1215 }
1216
1217 spawnfunc(item_rockets)
1218 {
1219         if(!this.ammo_rockets)
1220                 this.ammo_rockets = g_pickup_rockets;
1221         if(!this.pickup_anyway)
1222                 this.pickup_anyway = g_pickup_ammo_anyway;
1223     StartItem(this, ITEM_Rockets);
1224 }
1225
1226 spawnfunc(item_bullets)
1227 {
1228         if(!weaponswapping)
1229         if(autocvar_sv_q3acompat_machineshotgunswap)
1230         if(this.classname != "droppedweapon")
1231         {
1232                 weaponswapping = true;
1233                 spawnfunc_item_shells(this);
1234                 weaponswapping = false;
1235                 return;
1236         }
1237
1238         if(!this.ammo_nails)
1239                 this.ammo_nails = g_pickup_nails;
1240         if(!this.pickup_anyway)
1241                 this.pickup_anyway = g_pickup_ammo_anyway;
1242     StartItem(this, ITEM_Bullets);
1243 }
1244
1245 spawnfunc(item_cells)
1246 {
1247         if(!this.ammo_cells)
1248                 this.ammo_cells = g_pickup_cells;
1249         if(!this.pickup_anyway)
1250                 this.pickup_anyway = g_pickup_ammo_anyway;
1251         StartItem(this, ITEM_Cells);
1252 }
1253
1254 spawnfunc(item_plasma)
1255 {
1256         if(!this.ammo_plasma)
1257                 this.ammo_plasma = g_pickup_plasma;
1258         if(!this.pickup_anyway)
1259                 this.pickup_anyway = g_pickup_ammo_anyway;
1260         StartItem(this, ITEM_Plasma);
1261 }
1262
1263 spawnfunc(item_shells)
1264 {
1265         if(!weaponswapping)
1266         if(autocvar_sv_q3acompat_machineshotgunswap)
1267         if(this.classname != "droppedweapon")
1268         {
1269                 weaponswapping = true;
1270                 spawnfunc_item_bullets(this);
1271                 weaponswapping = false;
1272                 return;
1273         }
1274
1275         if(!this.ammo_shells)
1276                 this.ammo_shells = g_pickup_shells;
1277         if(!this.pickup_anyway)
1278                 this.pickup_anyway = g_pickup_ammo_anyway;
1279         StartItem(this, ITEM_Shells);
1280 }
1281
1282 spawnfunc(item_armor_small)
1283 {
1284         if(!this.armorvalue)
1285                 this.armorvalue = g_pickup_armorsmall;
1286         if(!this.max_armorvalue)
1287                 this.max_armorvalue = g_pickup_armorsmall_max;
1288         if(!this.pickup_anyway)
1289                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1290         StartItem(this, ITEM_ArmorSmall);
1291 }
1292
1293 spawnfunc(item_armor_medium)
1294 {
1295         if(!this.armorvalue)
1296                 this.armorvalue = g_pickup_armormedium;
1297         if(!this.max_armorvalue)
1298                 this.max_armorvalue = g_pickup_armormedium_max;
1299         if(!this.pickup_anyway)
1300                 this.pickup_anyway = g_pickup_armormedium_anyway;
1301         StartItem(this, ITEM_ArmorMedium);
1302 }
1303
1304 spawnfunc(item_armor_big)
1305 {
1306         if(!this.armorvalue)
1307                 this.armorvalue = g_pickup_armorbig;
1308         if(!this.max_armorvalue)
1309                 this.max_armorvalue = g_pickup_armorbig_max;
1310         if(!this.pickup_anyway)
1311                 this.pickup_anyway = g_pickup_armorbig_anyway;
1312         StartItem(this, ITEM_ArmorLarge);
1313 }
1314
1315 spawnfunc(item_armor_large)
1316 {
1317         if(!this.armorvalue)
1318                 this.armorvalue = g_pickup_armorlarge;
1319         if(!this.max_armorvalue)
1320                 this.max_armorvalue = g_pickup_armorlarge_max;
1321         if(!this.pickup_anyway)
1322                 this.pickup_anyway = g_pickup_armorlarge_anyway;
1323         StartItem(this, ITEM_ArmorMega);
1324 }
1325
1326 spawnfunc(item_health_small)
1327 {
1328         if(!this.max_health)
1329                 this.max_health = g_pickup_healthsmall_max;
1330         if(!this.health)
1331                 this.health = g_pickup_healthsmall;
1332         if(!this.pickup_anyway)
1333                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1334         StartItem(this, ITEM_HealthSmall);
1335 }
1336
1337 spawnfunc(item_health_medium)
1338 {
1339         if(!this.max_health)
1340                 this.max_health = g_pickup_healthmedium_max;
1341         if(!this.health)
1342                 this.health = g_pickup_healthmedium;
1343         if(!this.pickup_anyway)
1344                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1345     StartItem(this, ITEM_HealthMedium);
1346 }
1347
1348 spawnfunc(item_health_large)
1349 {
1350         if(!this.max_health)
1351                 this.max_health = g_pickup_healthlarge_max;
1352         if(!this.health)
1353                 this.health = g_pickup_healthlarge;
1354         if(!this.pickup_anyway)
1355                 this.pickup_anyway = g_pickup_healthlarge_anyway;
1356         StartItem(this, ITEM_HealthLarge);
1357 }
1358
1359 spawnfunc(item_health_mega)
1360 {
1361     if(!this.max_health)
1362         this.max_health = g_pickup_healthmega_max;
1363     if(!this.health)
1364         this.health = g_pickup_healthmega;
1365     if(!this.pickup_anyway)
1366         this.pickup_anyway = g_pickup_healthmega_anyway;
1367     StartItem(this, ITEM_HealthMega);
1368 }
1369
1370 // support old misnamed entities
1371 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1372 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1373 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1374 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1375 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1376
1377 spawnfunc(item_strength)
1378 {
1379                 if(!this.strength_finished)
1380                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1381                 StartItem(this, ITEM_Strength);
1382 }
1383
1384 spawnfunc(item_invincible)
1385 {
1386                 if(!this.invincible_finished)
1387                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1388                 StartItem(this, ITEM_Shield);
1389 }
1390
1391 // compatibility:
1392 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1393
1394 void target_items_use()
1395 {SELFPARAM();
1396         if(activator.classname == "droppedweapon")
1397         {
1398                 EXACTTRIGGER_TOUCH;
1399                 remove(activator);
1400                 return;
1401         }
1402
1403         if (!IS_PLAYER(activator))
1404                 return;
1405         if(activator.deadflag != DEAD_NO)
1406                 return;
1407         EXACTTRIGGER_TOUCH;
1408
1409         entity e;
1410         for(e = world; (e = find(e, classname, "droppedweapon")); )
1411                 if(e.enemy == activator)
1412                         remove(e);
1413
1414         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1415                 centerprint(activator, self.message);
1416 }
1417
1418 spawnfunc(target_items)
1419 {
1420         float n, i, j;
1421         entity e;
1422         string s;
1423
1424         self.use = target_items_use;
1425         if(!self.strength_finished)
1426                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1427         if(!self.invincible_finished)
1428                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1429         if(!self.superweapons_finished)
1430                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1431
1432         n = tokenize_console(self.netname);
1433         if(argv(0) == "give")
1434         {
1435                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1436         }
1437         else
1438         {
1439                 for(i = 0; i < n; ++i)
1440                 {
1441                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1442                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1443                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1444                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1445                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1446                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1447                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1448                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1449                         else
1450                         {
1451                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1452                                 {
1453                                         e = Weapons_from(j);
1454                                         s = W_UndeprecateName(argv(i));
1455                                         if(s == e.netname)
1456                                         {
1457                                                 self.weapons |= (e.m_wepset);
1458                                                 if(self.spawnflags == 0 || self.spawnflags == 2) {
1459                                                         e.wr_init(e);
1460                                                 }
1461                                                 break;
1462                                         }
1463                                 }
1464                                 if(j > WEP_LAST)
1465                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1466                         }
1467                 }
1468
1469                 string itemprefix, valueprefix;
1470                 if(self.spawnflags == 0)
1471                 {
1472                         itemprefix = "";
1473                         valueprefix = "";
1474                 }
1475                 else if(self.spawnflags == 1)
1476                 {
1477                         itemprefix = "max ";
1478                         valueprefix = "max ";
1479                 }
1480                 else if(self.spawnflags == 2)
1481                 {
1482                         itemprefix = "min ";
1483                         valueprefix = "min ";
1484                 }
1485                 else if(self.spawnflags == 4)
1486                 {
1487                         itemprefix = "minus ";
1488                         valueprefix = "max ";
1489                 }
1490                 else
1491                 {
1492                         error("invalid spawnflags");
1493                         itemprefix = valueprefix = string_null;
1494                 }
1495
1496                 self.netname = "";
1497                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1498                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1499                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * boolean(self.items & ITEM_Strength.m_itemid), "strength");
1500                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * boolean(self.items & ITEM_Shield.m_itemid), "invincible");
1501                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * boolean(self.items & IT_SUPERWEAPON), "superweapons");
1502                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1503                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1504                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1505                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1506                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1507                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1508                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1509                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1510                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1511                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1512                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1513                 {
1514                         e = Weapons_from(j);
1515                         if(e == WEP_Null) continue;
1516                         self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & (e.m_wepset)), e.netname);
1517                 }
1518         }
1519         self.netname = strzone(self.netname);
1520         //print(self.netname, "\n");
1521
1522         n = tokenize_console(self.netname);
1523         for(i = 0; i < n; ++i)
1524         {
1525                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1526                 {
1527                         e = Weapons_from(j);
1528                         if(argv(i) == e.netname)
1529                         {
1530                                 e.wr_init(e);
1531                                 break;
1532                         }
1533                 }
1534         }
1535 }
1536
1537 spawnfunc(item_fuel)
1538 {
1539         if(!this.ammo_fuel)
1540                 this.ammo_fuel = g_pickup_fuel;
1541         if(!this.pickup_anyway)
1542                 this.pickup_anyway = g_pickup_ammo_anyway;
1543         StartItem(this, ITEM_JetpackFuel);
1544 }
1545
1546 spawnfunc(item_fuel_regen)
1547 {
1548         if(start_items & ITEM_JetpackRegen.m_itemid)
1549         {
1550                 spawnfunc_item_fuel(this);
1551                 return;
1552         }
1553         StartItem(this, ITEM_JetpackRegen);
1554 }
1555
1556 spawnfunc(item_jetpack)
1557 {
1558         if(!this.ammo_fuel)
1559                 this.ammo_fuel = g_pickup_fuel_jetpack;
1560         if(start_items & ITEM_Jetpack.m_itemid)
1561         {
1562                 spawnfunc_item_fuel(this);
1563                 return;
1564         }
1565         StartItem(this, ITEM_Jetpack);
1566 }
1567
1568 float GiveWeapon(entity e, float wpn, float op, float val)
1569 {
1570         WepSet v0, v1;
1571         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1572         v0 = (e.weapons & s);
1573         switch(op)
1574         {
1575                 case OP_SET:
1576                         if(val > 0)
1577                                 e.weapons |= s;
1578                         else
1579                                 e.weapons &= ~s;
1580                         break;
1581                 case OP_MIN:
1582                 case OP_PLUS:
1583                         if(val > 0)
1584                                 e.weapons |= s;
1585                         break;
1586                 case OP_MAX:
1587                         if(val <= 0)
1588                                 e.weapons &= ~s;
1589                         break;
1590                 case OP_MINUS:
1591                         if(val > 0)
1592                                 e.weapons &= ~s;
1593                         break;
1594         }
1595         v1 = (e.weapons & s);
1596         return (v0 != v1);
1597 }
1598
1599 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1600 {
1601         if(v1 == v0)
1602                 return;
1603         if(v1 <= v0 - t)
1604         {
1605                 if(snd_decr != "")
1606                         _sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1607         }
1608         else if(v0 >= v0 + t)
1609         {
1610                 if(snd_incr != "")
1611                         _sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1612         }
1613 }
1614
1615 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1616 {
1617         if(v0 < v1)
1618                 e.(rotfield) = max(e.(rotfield), time + rottime);
1619         else if(v0 > v1)
1620                 e.(regenfield) = max(e.(regenfield), time + regentime);
1621 }
1622 float GiveItems(entity e, float beginarg, float endarg)
1623 {SELFPARAM();
1624         float got, i, j, val, op;
1625         float _switchweapon;
1626         entity wi;
1627         string cmd;
1628
1629         val = 999;
1630         op = OP_SET;
1631
1632         got = 0;
1633
1634         _switchweapon = false;
1635         if (e.autoswitch)
1636                 if (PS(e).m_switchweapon == w_getbestweapon(e))
1637                         _switchweapon = true;
1638
1639         e.strength_finished = max(0, e.strength_finished - time);
1640         e.invincible_finished = max(0, e.invincible_finished - time);
1641         e.superweapons_finished = max(0, e.superweapons_finished - time);
1642
1643         PREGIVE(e, items);
1644         PREGIVE_WEAPONS(e);
1645         PREGIVE(e, strength_finished);
1646         PREGIVE(e, invincible_finished);
1647         PREGIVE(e, superweapons_finished);
1648         PREGIVE(e, ammo_nails);
1649         PREGIVE(e, ammo_cells);
1650         PREGIVE(e, ammo_plasma);
1651         PREGIVE(e, ammo_shells);
1652         PREGIVE(e, ammo_rockets);
1653         PREGIVE(e, ammo_fuel);
1654         PREGIVE(e, armorvalue);
1655         PREGIVE(e, health);
1656
1657         for(i = beginarg; i < endarg; ++i)
1658         {
1659                 cmd = argv(i);
1660
1661                 if(cmd == "0" || stof(cmd))
1662                 {
1663                         val = stof(cmd);
1664                         continue;
1665                 }
1666                 switch(cmd)
1667                 {
1668                         case "no":
1669                                 op = OP_MAX;
1670                                 val = 0;
1671                                 continue;
1672                         case "max":
1673                                 op = OP_MAX;
1674                                 continue;
1675                         case "min":
1676                                 op = OP_MIN;
1677                                 continue;
1678                         case "plus":
1679                                 op = OP_PLUS;
1680                                 continue;
1681                         case "minus":
1682                                 op = OP_MINUS;
1683                                 continue;
1684                         case "ALL":
1685                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1686                                 got += GiveValue(e, strength_finished, op, val);
1687                                 got += GiveValue(e, invincible_finished, op, val);
1688                                 got += GiveValue(e, superweapons_finished, op, val);
1689                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1690                         case "all":
1691                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1692                                 got += GiveValue(e, health, op, val);
1693                                 got += GiveValue(e, armorvalue, op, val);
1694                         case "allweapons":
1695                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1696                                 {
1697                                         wi = Weapons_from(j);
1698                                         if(wi == WEP_Null) continue;
1699                                         if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1700                                                 got += GiveWeapon(e, j, op, val);
1701                                 }
1702                         case "allammo":
1703                                 got += GiveValue(e, ammo_cells, op, val);
1704                                 got += GiveValue(e, ammo_plasma, op, val);
1705                                 got += GiveValue(e, ammo_shells, op, val);
1706                                 got += GiveValue(e, ammo_nails, op, val);
1707                                 got += GiveValue(e, ammo_rockets, op, val);
1708                                 got += GiveValue(e, ammo_fuel, op, val);
1709                                 break;
1710                         case "unlimited_ammo":
1711                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1712                                 break;
1713                         case "unlimited_weapon_ammo":
1714                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1715                                 break;
1716                         case "unlimited_superweapons":
1717                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1718                                 break;
1719                         case "jetpack":
1720                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1721                                 break;
1722                         case "fuel_regen":
1723                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1724                                 break;
1725                         case "strength":
1726                                 got += GiveValue(e, strength_finished, op, val);
1727                                 break;
1728                         case "invincible":
1729                                 got += GiveValue(e, invincible_finished, op, val);
1730                                 break;
1731                         case "superweapons":
1732                                 got += GiveValue(e, superweapons_finished, op, val);
1733                                 break;
1734                         case "cells":
1735                                 got += GiveValue(e, ammo_cells, op, val);
1736                                 break;
1737                         case "plasma":
1738                                 got += GiveValue(e, ammo_plasma, op, val);
1739                                 break;
1740                         case "shells":
1741                                 got += GiveValue(e, ammo_shells, op, val);
1742                                 break;
1743                         case "nails":
1744                         case "bullets":
1745                                 got += GiveValue(e, ammo_nails, op, val);
1746                                 break;
1747                         case "rockets":
1748                                 got += GiveValue(e, ammo_rockets, op, val);
1749                                 break;
1750                         case "health":
1751                                 got += GiveValue(e, health, op, val);
1752                                 break;
1753                         case "armor":
1754                                 got += GiveValue(e, armorvalue, op, val);
1755                                 break;
1756                         case "fuel":
1757                                 got += GiveValue(e, ammo_fuel, op, val);
1758                                 break;
1759                         default:
1760                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1761                                 {
1762                                         wi = Weapons_from(j);
1763                                         if(cmd == wi.netname)
1764                                         {
1765                                                 got += GiveWeapon(e, j, op, val);
1766                                                 break;
1767                                         }
1768                                 }
1769                                 if(j > WEP_LAST)
1770                                         LOG_INFO("give: invalid item ", cmd, "\n");
1771                                 break;
1772                 }
1773                 val = 999;
1774                 op = OP_SET;
1775         }
1776
1777         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND(ITEMPICKUP), string_null);
1778         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND(POWERUP), SND(POWEROFF));
1779         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND(POWERUP), SND(POWEROFF));
1780         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND(ITEMPICKUP), string_null);
1781         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1782         {
1783                 wi = Weapons_from(j);
1784                 if (wi == WEP_Null) continue;
1785                 POSTGIVE_WEAPON(e, Weapons_from(j), SND(WEAPONPICKUP), string_null);
1786                 if (!(save_weapons & (wi.m_wepset)))
1787                         if(e.weapons & (wi.m_wepset)) {
1788                                 wi.wr_init(wi);
1789                         }
1790         }
1791         POSTGIVE_VALUE(e, strength_finished, 1, SND(POWERUP), SND(POWEROFF));
1792         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", SND(POWEROFF));
1793         POSTGIVE_VALUE(e, ammo_nails, 0, SND(ITEMPICKUP), string_null);
1794         POSTGIVE_VALUE(e, ammo_cells, 0, SND(ITEMPICKUP), string_null);
1795         POSTGIVE_VALUE(e, ammo_plasma, 0, SND(ITEMPICKUP), string_null);
1796         POSTGIVE_VALUE(e, ammo_shells, 0, SND(ITEMPICKUP), string_null);
1797         POSTGIVE_VALUE(e, ammo_rockets, 0, SND(ITEMPICKUP), string_null);
1798         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND(ITEMPICKUP), string_null);
1799         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(ARMOR25), string_null);
1800         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(MEGAHEALTH), string_null);
1801
1802         if(e.superweapons_finished <= 0)
1803                 if(self.weapons & WEPSET_SUPERWEAPONS)
1804                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1805
1806         if(e.strength_finished <= 0)
1807                 e.strength_finished = 0;
1808         else
1809                 e.strength_finished += time;
1810         if(e.invincible_finished <= 0)
1811                 e.invincible_finished = 0;
1812         else
1813                 e.invincible_finished += time;
1814         if(e.superweapons_finished <= 0)
1815                 e.superweapons_finished = 0;
1816         else
1817                 e.superweapons_finished += time;
1818
1819         if (!(e.weapons & WepSet_FromWeapon(PS(e).m_switchweapon)))
1820                 _switchweapon = true;
1821         if(_switchweapon)
1822                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1823
1824         return got;
1825 }
1826 #endif