qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "waypointsprites.qh"
   9
  10     #include "bot/bot.qh"
  11     #include "bot/waypoints.qh"
  12
  13     #include "mutators/mutators_include.qh"
  14
  15     #include "weapons/common.qh"
  16     #include "weapons/selection.qh"
  17     #include "weapons/weaponsystem.qh"
  18
  19     #include "../common/constants.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "../common/notifications.qh"
  22         #include "../common/triggers/subs.qh"
  23     #include "../common/util.qh"
  24
  25     #include "../common/monsters/all.qh"
  26
  27     #include "../common/weapons/all.qh"
  28
  29     #include "../warpzonelib/util_server.qh"
  30 #endif
  31
  32 #ifdef CSQC
  33 void ItemDraw()
  34 {
  35     if(self.gravity)
  36     {
  37         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  38         if(self.move_flags & FL_ONGROUND)
  39         { // For some reason move_avelocity gets set to '0 0 0' here ...
  40             self.oldorigin = self.origin;
  41             self.gravity = 0;
  42
  43             if(autocvar_cl_animate_items)
  44             { // ... so reset it if animations are requested.
  45                 if(self.ItemStatus & ITS_ANIMATE1)
  46                     self.move_avelocity = '0 180 0';
  47
  48                 if(self.ItemStatus & ITS_ANIMATE2)
  49                     self.move_avelocity = '0 -90 0';
  50             }
  51         }
  52     }
  53     else if (autocvar_cl_animate_items)
  54     {
  55         if(self.ItemStatus & ITS_ANIMATE1)
  56         {
  57             self.angles += self.move_avelocity * frametime;
  58             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  59         }
  60
  61         if(self.ItemStatus & ITS_ANIMATE2)
  62         {
  63             self.angles += self.move_avelocity * frametime;
  64             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  65         }
  66     }
  67 }
  68
  69 void ItemDrawSimple()
  70 {
  71     if(self.gravity)
  72     {
  73         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74
  75         if(self.move_flags & FL_ONGROUND)
  76             self.gravity = 0;
  77     }
  78 }
  79
  80 void ItemRead(float _IsNew)
  81 {
  82     int sf = ReadByte();
  83
  84     if(sf & ISF_LOCATION)
  85     {
  86         self.origin_x = ReadCoord();
  87         self.origin_y = ReadCoord();
  88         self.origin_z = ReadCoord();
  89         setorigin(self, self.origin);
  90         self.oldorigin = self.origin;
  91     }
  92
  93     if(sf & ISF_ANGLES)
  94     {
  95         self.angles_x = ReadCoord();
  96         self.angles_y = ReadCoord();
  97         self.angles_z = ReadCoord();
  98         self.move_angles = self.angles;
  99     }
 100
 101     if(sf & ISF_SIZE)
 102     {
 103         self.mins_x = ReadCoord();
 104         self.mins_y = ReadCoord();
 105         self.mins_z = ReadCoord();
 106         self.maxs_x = ReadCoord();
 107         self.maxs_y = ReadCoord();
 108         self.maxs_z = ReadCoord();
 109         setsize(self, self.mins, self.maxs);
 110     }
 111
 112     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 113     {
 114         self.ItemStatus = ReadByte();
 115
 116         if(self.ItemStatus & ITS_AVAILABLE)
 117         {
 118             self.alpha = 1;
 119             self.colormod = self.glowmod = '1 1 1';
 120         }
 121         else
 122         {
 123             if (autocvar_cl_ghost_items_color)
 124             {
 125                 self.alpha = autocvar_cl_ghost_items;
 126                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 127             }
 128             else
 129                 self.alpha = -1;
 130         }
 131
 132         if(autocvar_cl_fullbright_items)
 133             if(self.ItemStatus & ITS_ALLOWFB)
 134                 self.effects |= EF_FULLBRIGHT;
 135
 136         if(self.ItemStatus & ITS_STAYWEP)
 137         {
 138             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 139             self.alpha = autocvar_cl_weapon_stay_alpha;
 140
 141         }
 142
 143         if(self.ItemStatus & ITS_POWERUP)
 144         {
 145             if(self.ItemStatus & ITS_AVAILABLE)
 146                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 147             else
 148                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 149         }
 150     }
 151
 152     if(sf & ISF_MODEL)
 153     {
 154         self.drawmask  = MASK_NORMAL;
 155         self.movetype  = MOVETYPE_TOSS;
 156         self.draw       = ItemDraw;
 157
 158         if(self.mdl)
 159             strunzone(self.mdl);
 160
 161         self.mdl = "";
 162         string _fn = ReadString();
 163
 164         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 165         {
 166             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 167             self.draw = ItemDrawSimple;
 168
 169
 170
 171             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 177             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 178                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 179             else
 180             {
 181                 self.draw = ItemDraw;
 182                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 183             }
 184         }
 185
 186         if(self.draw != ItemDrawSimple)
 187             self.mdl = strzone(_fn);
 188
 189
 190         if(self.mdl == "")
 191             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 192
 193         precache_model(self.mdl);
 194         setmodel(self, self.mdl);
 195     }
 196
 197     if(sf & ISF_COLORMAP)
 198         self.colormap = ReadShort();
 199
 200     if(sf & ISF_DROP)
 201     {
 202         self.gravity = 1;
 203         //self.move_angles = '0 0 0';
 204         self.move_movetype = MOVETYPE_TOSS;
 205         self.move_velocity_x = ReadCoord();
 206         self.move_velocity_y = ReadCoord();
 207         self.move_velocity_z = ReadCoord();
 208         self.velocity = self.move_velocity;
 209         self.move_origin = self.oldorigin;
 210
 211         if(!self.move_time)
 212         {
 213             self.move_time = time;
 214             self.spawntime = time;
 215         }
 216         else
 217             self.move_time = max(self.move_time, time);
 218     }
 219
 220     if(autocvar_cl_animate_items)
 221     {
 222         if(self.ItemStatus & ITS_ANIMATE1)
 223             self.move_avelocity = '0 180 0';
 224
 225         if(self.ItemStatus & ITS_ANIMATE2)
 226             self.move_avelocity = '0 -90 0';
 227     }
 228 }
 229
 230 #endif
 231
 232 #ifdef SVQC
 233 bool ItemSend(entity to, int sf)
 234 {
 235     if(self.gravity)
 236         sf |= ISF_DROP;
 237     else
 238         sf &= ~ISF_DROP;
 239
 240         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 241         WriteByte(MSG_ENTITY, sf);
 242
 243         //WriteByte(MSG_ENTITY, self.cnt);
 244     if(sf & ISF_LOCATION)
 245     {
 246         WriteCoord(MSG_ENTITY, self.origin.x);
 247         WriteCoord(MSG_ENTITY, self.origin.y);
 248         WriteCoord(MSG_ENTITY, self.origin.z);
 249     }
 250
 251     if(sf & ISF_ANGLES)
 252     {
 253         WriteCoord(MSG_ENTITY, self.angles.x);
 254         WriteCoord(MSG_ENTITY, self.angles.y);
 255         WriteCoord(MSG_ENTITY, self.angles.z);
 256     }
 257
 258     if(sf & ISF_SIZE)
 259     {
 260         WriteCoord(MSG_ENTITY, self.mins.x);
 261         WriteCoord(MSG_ENTITY, self.mins.y);
 262         WriteCoord(MSG_ENTITY, self.mins.z);
 263         WriteCoord(MSG_ENTITY, self.maxs.x);
 264         WriteCoord(MSG_ENTITY, self.maxs.y);
 265         WriteCoord(MSG_ENTITY, self.maxs.z);
 266     }
 267
 268     if(sf & ISF_STATUS)
 269         WriteByte(MSG_ENTITY, self.ItemStatus);
 270
 271     if(sf & ISF_MODEL)
 272     {
 273
 274         if(self.mdl == "")
 275             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 276
 277         WriteString(MSG_ENTITY, self.mdl);
 278     }
 279
 280
 281     if(sf & ISF_COLORMAP)
 282         WriteShort(MSG_ENTITY, self.colormap);
 283
 284     if(sf & ISF_DROP)
 285     {
 286         WriteCoord(MSG_ENTITY, self.velocity.x);
 287         WriteCoord(MSG_ENTITY, self.velocity.y);
 288         WriteCoord(MSG_ENTITY, self.velocity.z);
 289     }
 290
 291     return true;
 292 }
 293
 294 void ItemUpdate(entity item)
 295 {
 296         item.SendFlags |= ISF_LOCATION;
 297 }
 298
 299 float have_pickup_item(void)
 300 {
 301         if(self.flags & FL_POWERUP)
 302         {
 303                 if(autocvar_g_powerups > 0)
 304                         return true;
 305                 if(autocvar_g_powerups == 0)
 306                         return false;
 307         }
 308         else
 309         {
 310                 if(autocvar_g_pickup_items > 0)
 311                         return true;
 312                 if(autocvar_g_pickup_items == 0)
 313                         return false;
 314                 if(g_weaponarena)
 315                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 316                                 return false;
 317         }
 318         return true;
 319 }
 320
 321 /*
 322 float Item_Customize()
 323 {
 324         if(self.spawnshieldtime)
 325                 return true;
 326         if(self.weapons & ~other.weapons)
 327         {
 328                 self.colormod = '0 0 0';
 329                 self.glowmod = self.colormod;
 330                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 331                 return true;
 332         }
 333         else
 334         {
 335                 if(g_ghost_items)
 336                 {
 337                         self.colormod = stov(autocvar_g_ghost_items_color);
 338                         self.glowmod = self.colormod;
 339                         self.alpha = g_ghost_items;
 340                         return true;
 341                 }
 342                 else
 343                         return false;
 344         }
 345 }
 346 */
 347
 348 void Item_Show (entity e, float mode)
 349 {
 350         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 351         e.ItemStatus &= ~ITS_STAYWEP;
 352         if (mode > 0)
 353         {
 354                 // make the item look normal, and be touchable
 355                 e.model = e.mdl;
 356                 e.solid = SOLID_TRIGGER;
 357                 e.spawnshieldtime = 1;
 358                 e.ItemStatus |= ITS_AVAILABLE;
 359         }
 360         else if (mode < 0)
 361         {
 362                 // hide the item completely
 363                 e.model = string_null;
 364                 e.solid = SOLID_NOT;
 365                 e.spawnshieldtime = 1;
 366                 e.ItemStatus &= ~ITS_AVAILABLE;
 367         }
 368         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 369         {
 370                 // make the item translucent and not touchable
 371                 e.model = e.mdl;
 372                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 373                 e.effects |= EF_STARDUST;
 374                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 375                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 376         }
 377         else
 378         {
 379                 //setmodel(e, "null");
 380                 e.solid = SOLID_NOT;
 381                 e.colormod = '0 0 0';
 382                 e.glowmod = e.colormod;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus &= ~ITS_AVAILABLE;
 385         }
 386
 387         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 388             e.ItemStatus |= ITS_POWERUP;
 389
 390         if (autocvar_g_nodepthtestitems)
 391                 e.effects |= EF_NODEPTHTEST;
 392
 393
 394     if (autocvar_g_fullbrightitems)
 395                 e.ItemStatus |= ITS_ALLOWFB;
 396
 397         if (autocvar_sv_simple_items)
 398         e.ItemStatus |= ITS_ALLOWSI;
 399
 400         // relink entity (because solid may have changed)
 401         setorigin(e, e.origin);
 402     e.SendFlags |= ISF_STATUS;
 403 }
 404
 405 void Item_Think()
 406 {
 407         self.nextthink = time;
 408         if(self.origin != self.oldorigin)
 409         {
 410                 self.oldorigin = self.origin;
 411                 ItemUpdate(self);
 412         }
 413 }
 414
 415 float Item_ItemsTime_UpdateTime(entity e, float t);
 416 void Item_ItemsTime_SetTime(entity e, float t);
 417 void Item_ItemsTime_SetTimesForAllPlayers();
 418
 419 void Item_Respawn (void)
 420 {
 421         Item_Show(self, 1);
 422         // this is ugly...
 423         if(self.items == ITEM_Strength.m_itemid)
 424                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 425         else if(self.items == ITEM_Shield.m_itemid)
 426                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 427         else
 428                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 429         setorigin (self, self.origin);
 430
 431         if(self.flags & FL_POWERUP || self.itemdef == ITEM_ArmorMega || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 432         {
 433                 float t = Item_ItemsTime_UpdateTime(self, 0);
 434                 Item_ItemsTime_SetTime(self, t);
 435                 Item_ItemsTime_SetTimesForAllPlayers();
 436         }
 437
 438         self.think = Item_Think;
 439         self.nextthink = time;
 440
 441         //Send_Effect("item_respawn", self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 442         Send_Effect("item_respawn", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 443 }
 444
 445 void Item_RespawnCountdown (void)
 446 {
 447         if(self.count >= ITEM_RESPAWN_TICKS)
 448         {
 449                 if(self.waypointsprite_attached)
 450                         WaypointSprite_Kill(self.waypointsprite_attached);
 451                 Item_Respawn();
 452         }
 453         else
 454         {
 455                 self.nextthink = time + 1;
 456                 self.count += 1;
 457                 if(self.count == 1)
 458                 {
 459                         string name;
 460                         vector rgb = '1 0 1';
 461                         name = string_null;
 462                         switch (self.items)
 463                         {
 464                                 case ITEM_JetpackRegen.m_itemid: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 465                                 case ITEM_Jetpack.m_itemid:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 466                                 case ITEM_Strength.m_itemid:   name = "item-strength"; rgb = '0 0 1'; break;
 467                                 case ITEM_Shield.m_itemid: name = "item-shield"; rgb = '1 0 1'; break;
 468                                 case ITEM_HealthMega.m_itemid:
 469                                         //if (self.classname == "item_health_mega")
 470                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 471                                         break;
 472                                 case ITEM_ArmorMega.m_itemid:
 473                                         if (self.itemdef == ITEM_ArmorMega)
 474                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 475                                         break;
 476                         }
 477                         MUTATOR_CALLHOOK(Item_RespawnCountdown, name, rgb);
 478                         name = item_name;
 479                         rgb = item_color;
 480                         if(self.flags & FL_WEAPON)
 481                         {
 482                                 entity wi = get_weaponinfo(self.weapon);
 483                                 if(wi)
 484                                 {
 485                                         name = wi.wpmodel;
 486                                         rgb = '1 0 0';
 487                                 }
 488                         }
 489                         if(name)
 490                         {
 491                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 492                                 if(self.waypointsprite_attached)
 493                                 {
 494                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 495                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 496                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 497                                 }
 498                         }
 499                         else
 500                         {
 501                                 print("Unknown powerup-marked item is wanting to respawn\n");
 502                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 503                         }
 504                 }
 505
 506                 if(self.waypointsprite_attached)
 507                 {
 508                         entity e;
 509                         entity it = self;
 510                         self = self.waypointsprite_attached;
 511                         FOR_EACH_REALCLIENT(e)
 512                                 if(self.waypointsprite_visible_for_player(e))
 513                                 {
 514                                         msg_entity = e;
 515                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 516                                 }
 517                         self = it;
 518
 519                         WaypointSprite_Ping(self.waypointsprite_attached);
 520                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 521                 }
 522                 else
 523                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 524         }
 525 }
 526
 527 void Item_RespawnThink()
 528 {
 529         self.nextthink = time;
 530         if(self.origin != self.oldorigin)
 531         {
 532                 self.oldorigin = self.origin;
 533                 ItemUpdate(self);
 534         }
 535
 536         if(time >= self.wait)
 537                 Item_Respawn();
 538 }
 539
 540 void Item_ScheduleRespawnIn(entity e, float t)
 541 {
 542         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.itemdef == ITEM_ArmorMega || e.items == IT_HEALTH)
 543         {
 544                 e.think = Item_RespawnCountdown;
 545                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 546                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 547                 e.count = 0;
 548                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 549                 Item_ItemsTime_SetTime(e, t);
 550                 Item_ItemsTime_SetTimesForAllPlayers();
 551         }
 552         else
 553         {
 554                 e.think = Item_RespawnThink;
 555                 e.nextthink = time;
 556                 e.scheduledrespawntime = time + t;
 557                 e.wait = time + t;
 558         }
 559 }
 560
 561 void Item_ScheduleRespawn(entity e)
 562 {
 563         if(e.respawntime > 0)
 564         {
 565                 Item_Show(e, 0);
 566                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 567         }
 568         else // if respawntime is -1, this item does not respawn
 569                 Item_Show(e, -1);
 570 }
 571
 572 void Item_ScheduleInitialRespawn(entity e)
 573 {
 574         Item_Show(e, 0);
 575         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 576 }
 577
 578 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 579 {
 580         if (!item.(ammotype))
 581                 return false;
 582
 583         if (item.spawnshieldtime)
 584         {
 585                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 586                 {
 587                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 588                         goto YEAH;
 589                 }
 590         }
 591         else if(g_weapon_stay == 2)
 592         {
 593                 float mi = min(item.(ammotype), ammomax);
 594                 if (player.(ammotype) < mi)
 595                 {
 596                         player.(ammotype) = mi;
 597                         goto YEAH;
 598                 }
 599         }
 600
 601         return false;
 602
 603 :YEAH
 604         switch(mode)
 605         {
 606                 case ITEM_MODE_FUEL:
 607                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 608                         break;
 609                 case ITEM_MODE_HEALTH:
 610                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 611                         break;
 612                 case ITEM_MODE_ARMOR:
 613                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 614                         break;
 615                 default:
 616                         break;
 617         }
 618         return true;
 619 }
 620
 621 float Item_GiveTo(entity item, entity player)
 622 {
 623         float _switchweapon;
 624         float pickedup;
 625         float it;
 626         float i;
 627
 628         // if nothing happens to player, just return without taking the item
 629         pickedup = false;
 630         _switchweapon = false;
 631         // in case the player has autoswitch enabled do the following:
 632         // if the player is using their best weapon before items are given, they
 633         // probably want to switch to an even better weapon after items are given
 634         if (player.autoswitch)
 635         if (player.switchweapon == w_getbestweapon(player))
 636                 _switchweapon = true;
 637
 638         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 639                 _switchweapon = true;
 640
 641         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 642         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 643         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 644         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 645         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 646         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 647         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 648         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 649
 650         if (item.flags & FL_WEAPON)
 651         {
 652                 WepSet it;
 653                 it = item.weapons;
 654                 it &= ~player.weapons;
 655
 656                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 657                 {
 658                         pickedup = true;
 659                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 660                         if(it & WepSet_FromWeapon(i))
 661                         {
 662                                 W_DropEvent(WR_PICKUP, player, i, item);
 663                                 W_GiveWeapon(player, i);
 664                         }
 665                 }
 666         }
 667
 668         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 669         {
 670                 pickedup = true;
 671                 player.items |= it;
 672                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 673         }
 674
 675         if (item.strength_finished)
 676         {
 677                 pickedup = true;
 678                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 679         }
 680         if (item.invincible_finished)
 681         {
 682                 pickedup = true;
 683                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 684         }
 685         if (item.superweapons_finished)
 686         {
 687                 pickedup = true;
 688                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 689         }
 690
 691 :skip
 692
 693         // always eat teamed entities
 694         if(item.team)
 695                 pickedup = true;
 696
 697         if (!pickedup)
 698                 return 0;
 699
 700         if (_switchweapon)
 701                 if (player.switchweapon != w_getbestweapon(player))
 702                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 703
 704         return 1;
 705 }
 706
 707 void Item_Touch (void)
 708 {
 709         entity e, head;
 710
 711         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 712         if(self.classname == "droppedweapon")
 713         {
 714                 if (ITEM_TOUCH_NEEDKILL())
 715                 {
 716                         remove(self);
 717                         return;
 718                 }
 719         }
 720
 721         if (!IS_PLAYER(other))
 722                 return;
 723         if (other.frozen)
 724                 return;
 725         if (other.deadflag)
 726                 return;
 727         if (self.solid != SOLID_TRIGGER)
 728                 return;
 729         if (self.owner == other)
 730                 return;
 731         if (time < self.item_spawnshieldtime)
 732                 return;
 733
 734         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 735         {
 736                 case MUT_ITEMTOUCH_RETURN: { return; }
 737                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 738         }
 739
 740         if (self.classname == "droppedweapon")
 741         {
 742                 self.strength_finished = max(0, self.strength_finished - time);
 743                 self.invincible_finished = max(0, self.invincible_finished - time);
 744                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 745         }
 746         entity it = self.itemdef;
 747         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 748         if (!gave)
 749         {
 750                 if (self.classname == "droppedweapon")
 751                 {
 752                         // undo what we did above
 753                         self.strength_finished += time;
 754                         self.invincible_finished += time;
 755                         self.superweapons_finished += time;
 756                 }
 757                 return;
 758         }
 759
 760         :pickup
 761
 762         other.last_pickup = time;
 763
 764         Send_Effect("item_pickup", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 765         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 766
 767         if (self.classname == "droppedweapon")
 768                 remove (self);
 769         else if (self.spawnshieldtime)
 770         {
 771                 if(self.team)
 772                 {
 773                         RandomSelection_Init();
 774                         for(head = world; (head = findfloat(head, team, self.team)); )
 775                         {
 776                                 if(head.flags & FL_ITEM)
 777                                 {
 778                                         Item_Show(head, -1);
 779                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 780                                 }
 781                         }
 782                         e = RandomSelection_chosen_ent;
 783
 784                 }
 785                 else
 786                         e = self;
 787                 Item_ScheduleRespawn(e);
 788         }
 789 }
 790
 791 void Item_Reset()
 792 {
 793         Item_Show(self, !self.state);
 794         setorigin (self, self.origin);
 795
 796         if(self.classname != "droppedweapon")
 797         {
 798                 self.think = Item_Think;
 799                 self.nextthink = time;
 800
 801                 if(self.waypointsprite_attached)
 802                         WaypointSprite_Kill(self.waypointsprite_attached);
 803
 804                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 805                         Item_ScheduleInitialRespawn(self);
 806         }
 807 }
 808
 809 void Item_FindTeam()
 810 {
 811         entity head, e;
 812
 813         if(self.effects & EF_NODRAW)
 814         {
 815                 // marker for item team search
 816                 dprint("Initializing item team ", ftos(self.team), "\n");
 817                 RandomSelection_Init();
 818                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 819                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 820                 e = RandomSelection_chosen_ent;
 821                 e.state = 0;
 822                 Item_Show(e, 1);
 823
 824                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 825                 {
 826                         if(head != e)
 827                         {
 828                                 // make it a non-spawned item
 829                                 Item_Show(head, -1);
 830                                 head.state = 1; // state 1 = initially hidden item
 831                         }
 832                         head.effects &= ~EF_NODRAW;
 833                 }
 834
 835                 Item_Reset();
 836         }
 837 }
 838
 839 // Savage: used for item garbage-collection
 840 // TODO: perhaps nice special effect?
 841 void RemoveItem(void)
 842 {
 843         Send_Effect("item_pickup", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 844         remove(self);
 845 }
 846
 847 // pickup evaluation functions
 848 // these functions decide how desirable an item is to the bots
 849
 850 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 851
 852 float weapon_pickupevalfunc(entity player, entity item)
 853 {
 854         float c;
 855
 856         // See if I have it already
 857         if(item.weapons & ~player.weapons)
 858         {
 859                 // If I can pick it up
 860                 if(!item.spawnshieldtime)
 861                         c = 0;
 862                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 863                 {
 864                         // Skilled bots will grab more
 865                         c = bound(0, skill / 10, 1) * 0.5;
 866                 }
 867                 else
 868                         c = 0;
 869         }
 870         else
 871                 c = 1;
 872
 873         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 874         if( bot_custom_weapon && c )
 875         {
 876                 // Find the highest position on any range
 877                 int position = -1;
 878                 for (int j = 0; j < WEP_LAST ; ++j){
 879                         if(
 880                                         bot_weapons_far[j] == item.weapon ||
 881                                         bot_weapons_mid[j] == item.weapon ||
 882                                         bot_weapons_close[j] == item.weapon
 883                           )
 884                         {
 885                                 position = j;
 886                                 break;
 887                         }
 888                 }
 889
 890                 // Rate it
 891                 if (position >= 0 )
 892                 {
 893                         position = WEP_LAST - position;
 894                         // item.bot_pickupbasevalue is overwritten here
 895                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 896                 }
 897         }
 898
 899         return item.bot_pickupbasevalue * c;
 900 }
 901
 902 float commodity_pickupevalfunc(entity player, entity item)
 903 {
 904         float c, i;
 905         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 906         entity wi;
 907         c = 0;
 908
 909         // Detect needed ammo
 910         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 911         {
 912                 wi = get_weaponinfo(i);
 913
 914                 if (!(player.weapons & WepSet_FromWeapon(i)))
 915                         continue;
 916
 917                 if(wi.items & ITEM_Shells.m_itemid)
 918                         need_shells = true;
 919                 else if(wi.items & ITEM_Bullets.m_itemid)
 920                         need_nails = true;
 921                 else if(wi.items & ITEM_Rockets.m_itemid)
 922                         need_rockets = true;
 923                 else if(wi.items & ITEM_Cells.m_itemid)
 924                         need_cells = true;
 925                 else if(wi.items & ITEM_Plasma.m_itemid)
 926                         need_plasma = true;
 927                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 928                         need_fuel = true;
 929         }
 930
 931         // TODO: figure out if the player even has the weapon this ammo is for?
 932         // may not affect strategy much though...
 933         // find out how much more ammo/armor/health the player can hold
 934         if (need_shells)
 935         if (item.ammo_shells)
 936         if (player.ammo_shells < g_pickup_shells_max)
 937                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 938         if (need_nails)
 939         if (item.ammo_nails)
 940         if (player.ammo_nails < g_pickup_nails_max)
 941                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 942         if (need_rockets)
 943         if (item.ammo_rockets)
 944         if (player.ammo_rockets < g_pickup_rockets_max)
 945                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 946         if (need_cells)
 947         if (item.ammo_cells)
 948         if (player.ammo_cells < g_pickup_cells_max)
 949                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 950         if (need_plasma)
 951         if (item.ammo_plasma)
 952         if (player.ammo_plasma < g_pickup_plasma_max)
 953                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 954         if (need_fuel)
 955         if (item.ammo_fuel)
 956         if (player.ammo_fuel < g_pickup_fuel_max)
 957                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 958         if (item.armorvalue)
 959         if (player.armorvalue < item.max_armorvalue)
 960                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 961         if (item.health)
 962         if (player.health < item.max_health)
 963                 c = c + max(0, 1 - player.health / item.max_health);
 964
 965         return item.bot_pickupbasevalue * c;
 966 }
 967
 968 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 969 {
 970         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 971                 RemoveItem();
 972 }
 973
 974 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 975 {
 976         startitem_failed = false;
 977
 978         if(self.model == "")
 979                 self.model = itemmodel;
 980
 981         if(self.model == "")
 982     {
 983         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 984         return;
 985     }
 986
 987         if(self.item_pickupsound == "")
 988                 self.item_pickupsound = pickupsound;
 989
 990         if(!self.respawntime) // both need to be set
 991         {
 992                 self.respawntime = defaultrespawntime;
 993                 self.respawntimejitter = defaultrespawntimejitter;
 994         }
 995
 996         self.items = itemid;
 997         self.weapon = weaponid;
 998
 999         if(weaponid)
1000                 self.weapons = WepSet_FromWeapon(weaponid);
1001
1002         self.flags = FL_ITEM | itemflags;
1003
1004         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1005         {
1006                 startitem_failed = true;
1007                 remove(self);
1008                 return;
1009         }
1010
1011         // is it a dropped weapon?
1012         if (self.classname == "droppedweapon")
1013         {
1014                 self.reset = SUB_Remove;
1015                 // it's a dropped weapon
1016                 self.movetype = MOVETYPE_TOSS;
1017
1018                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1019                 self.think = RemoveItem;
1020                 self.nextthink = time + 20;
1021
1022                 self.takedamage = DAMAGE_YES;
1023                 self.event_damage = Item_Damage;
1024
1025                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1026                 /*
1027                 if(self.items == 0)
1028                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1029                 if(self.ammo_nails == 0)
1030                 if(self.ammo_cells == 0)
1031                 if(self.ammo_rockets == 0)
1032                 if(self.ammo_shells == 0)
1033                 if(self.ammo_fuel == 0)
1034                 if(self.health == 0)
1035                 if(self.armorvalue == 0)
1036                 */
1037                 {
1038                         // if item is worthless after a timer, have it expire then
1039                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1040                 }
1041
1042                 // don't drop if in a NODROP zone (such as lava)
1043                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1044                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1045                 {
1046                         startitem_failed = true;
1047                         remove(self);
1048                         return;
1049                 }
1050         }
1051         else
1052         {
1053                 if(!have_pickup_item())
1054                 {
1055                         startitem_failed = true;
1056                         remove (self);
1057                         return;
1058                 }
1059
1060                 self.reset = Item_Reset;
1061                 // it's a level item
1062                 if(self.spawnflags & 1)
1063                         self.noalign = 1;
1064                 if (self.noalign)
1065                         self.movetype = MOVETYPE_NONE;
1066                 else
1067                         self.movetype = MOVETYPE_TOSS;
1068                 // do item filtering according to game mode and other things
1069                 if (!self.noalign)
1070                 {
1071                         // first nudge it off the floor a little bit to avoid math errors
1072                         setorigin(self, self.origin + '0 0 1');
1073                         // set item size before we spawn a spawnfunc_waypoint
1074                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1075                                 setsize (self, '-16 -16 0', '16 16 48');
1076                         else
1077                                 setsize (self, '-16 -16 0', '16 16 32');
1078
1079                         // note droptofloor returns false if stuck/or would fall too far
1080                         droptofloor();
1081                         waypoint_spawnforitem(self);
1082                 }
1083
1084                 /*
1085                  * can't do it that way, as it would break maps
1086                  * TODO make a target_give like entity another way, that perhaps has
1087                  * the weapon name in a key
1088                 if(self.targetname)
1089                 {
1090                         // target_give not yet supported; maybe later
1091                         print("removed targeted ", self.classname, "\n");
1092                         startitem_failed = true;
1093                         remove (self);
1094                         return;
1095                 }
1096                 */
1097
1098                 if(autocvar_spawn_debug >= 2)
1099                 {
1100                         entity otheritem;
1101                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1102                         {
1103                             // why not flags & fl_item?
1104                                 if(otheritem.is_item)
1105                                 {
1106                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1107                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1108                                         error("Mapper sucks.");
1109                                 }
1110                         }
1111                         self.is_item = true;
1112                 }
1113
1114                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1115
1116                 precache_model (self.model);
1117                 precache_sound (self.item_pickupsound);
1118
1119                 precache_sound ("misc/itemrespawncountdown.wav");
1120                 if(itemid == ITEM_Strength.m_itemid)
1121                         precache_sound ("misc/strength_respawn.wav");
1122                 else if(itemid == ITEM_Shield.m_itemid)
1123                         precache_sound ("misc/shield_respawn.wav");
1124                 else
1125                         precache_sound ("misc/itemrespawn.wav");
1126
1127                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1128                         self.target = "###item###"; // for finding the nearest item using find()
1129
1130                 Item_ItemsTime_SetTime(self, 0);
1131         }
1132
1133         self.bot_pickup = true;
1134         self.bot_pickupevalfunc = pickupevalfunc;
1135         self.bot_pickupbasevalue = pickupbasevalue;
1136         self.mdl = self.model;
1137         self.netname = itemname;
1138         self.touch = Item_Touch;
1139         setmodel(self, "null"); // precision set below
1140         //self.effects |= EF_LOWPRECISION;
1141
1142         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1143     {
1144         self.pos1 = '-16 -16 0';
1145         self.pos2 = '16 16 48';
1146     }
1147         else
1148     {
1149         self.pos1 = '-16 -16 0';
1150         self.pos2 = '16 16 32';
1151     }
1152     setsize (self, self.pos1, self.pos2);
1153
1154     if(itemflags & FL_POWERUP)
1155         self.ItemStatus |= ITS_ANIMATE1;
1156
1157         if(self.armorvalue || self.health)
1158         self.ItemStatus |= ITS_ANIMATE2;
1159
1160         if(itemflags & FL_WEAPON)
1161         {
1162                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1163             self.colormap = 1024; // color shirt=0 pants=0 grey
1164         else
1165             self.gravity = 1;
1166
1167                 self.ItemStatus |= ITS_ANIMATE1;
1168                 self.ItemStatus |= ISF_COLORMAP;
1169         }
1170
1171         self.state = 0;
1172         if(self.team) // broken, no idea why.
1173         {
1174                 if(!self.cnt)
1175                         self.cnt = 1; // item probability weight
1176
1177                 self.effects |= EF_NODRAW; // marker for item team search
1178                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1179         }
1180         else
1181                 Item_Reset();
1182
1183     Net_LinkEntity(self, false, 0, ItemSend);
1184
1185         self.SendFlags |= ISF_SIZE;
1186         if(self.angles)
1187                 self.SendFlags |= ISF_ANGLES;
1188
1189         // call this hook after everything else has been done
1190         if(MUTATOR_CALLHOOK(Item_Spawn, self))
1191         {
1192                 startitem_failed = true;
1193                 remove(self);
1194                 return;
1195         }
1196 }
1197
1198 void StartItemA (entity a)
1199 {
1200     self.itemdef = a;
1201     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1202 }
1203
1204 void spawnfunc_item_rockets (void) {
1205         if(!self.ammo_rockets)
1206                 self.ammo_rockets = g_pickup_rockets;
1207         if(!self.pickup_anyway)
1208                 self.pickup_anyway = g_pickup_ammo_anyway;
1209     StartItemA (ITEM_Rockets);
1210 }
1211
1212 void spawnfunc_item_bullets (void) {
1213         if(!weaponswapping)
1214         if(autocvar_sv_q3acompat_machineshotgunswap)
1215         if(self.classname != "droppedweapon")
1216         {
1217                 weaponswapping = true;
1218                 spawnfunc_item_shells();
1219                 weaponswapping = false;
1220                 return;
1221         }
1222
1223         if(!self.ammo_nails)
1224                 self.ammo_nails = g_pickup_nails;
1225         if(!self.pickup_anyway)
1226                 self.pickup_anyway = g_pickup_ammo_anyway;
1227     StartItemA (ITEM_Bullets);
1228 }
1229
1230 void spawnfunc_item_cells (void) {
1231         if(!self.ammo_cells)
1232                 self.ammo_cells = g_pickup_cells;
1233         if(!self.pickup_anyway)
1234                 self.pickup_anyway = g_pickup_ammo_anyway;
1235         StartItemA (ITEM_Cells);
1236 }
1237
1238 void spawnfunc_item_plasma()
1239 {
1240         if(!self.ammo_plasma)
1241                 self.ammo_plasma = g_pickup_plasma;
1242         if(!self.pickup_anyway)
1243                 self.pickup_anyway = g_pickup_ammo_anyway;
1244         StartItemA (ITEM_Plasma);
1245 }
1246
1247 void spawnfunc_item_shells (void) {
1248         if(!weaponswapping)
1249         if(autocvar_sv_q3acompat_machineshotgunswap)
1250         if(self.classname != "droppedweapon")
1251         {
1252                 weaponswapping = true;
1253                 spawnfunc_item_bullets();
1254                 weaponswapping = false;
1255                 return;
1256         }
1257
1258         if(!self.ammo_shells)
1259                 self.ammo_shells = g_pickup_shells;
1260         if(!self.pickup_anyway)
1261                 self.pickup_anyway = g_pickup_ammo_anyway;
1262         StartItemA (ITEM_Shells);
1263 }
1264
1265 void spawnfunc_item_armor_small (void) {
1266         if(!self.armorvalue)
1267                 self.armorvalue = g_pickup_armorsmall;
1268         if(!self.max_armorvalue)
1269                 self.max_armorvalue = g_pickup_armorsmall_max;
1270         if(!self.pickup_anyway)
1271                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1272         StartItemA (ITEM_ArmorSmall);
1273 }
1274
1275 void spawnfunc_item_armor_medium (void) {
1276         if(!self.armorvalue)
1277                 self.armorvalue = g_pickup_armormedium;
1278         if(!self.max_armorvalue)
1279                 self.max_armorvalue = g_pickup_armormedium_max;
1280         if(!self.pickup_anyway)
1281                 self.pickup_anyway = g_pickup_armormedium_anyway;
1282         StartItemA (ITEM_ArmorMedium);
1283 }
1284
1285 void spawnfunc_item_armor_big (void) {
1286         if(!self.armorvalue)
1287                 self.armorvalue = g_pickup_armorbig;
1288         if(!self.max_armorvalue)
1289                 self.max_armorvalue = g_pickup_armorbig_max;
1290         if(!self.pickup_anyway)
1291                 self.pickup_anyway = g_pickup_armorbig_anyway;
1292         StartItemA (ITEM_ArmorLarge);
1293 }
1294
1295 void spawnfunc_item_armor_large (void) {
1296         if(!self.armorvalue)
1297                 self.armorvalue = g_pickup_armorlarge;
1298         if(!self.max_armorvalue)
1299                 self.max_armorvalue = g_pickup_armorlarge_max;
1300         if(!self.pickup_anyway)
1301                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1302         StartItemA (ITEM_ArmorMega);
1303 }
1304
1305 void spawnfunc_item_health_small (void) {
1306         if(!self.max_health)
1307                 self.max_health = g_pickup_healthsmall_max;
1308         if(!self.health)
1309                 self.health = g_pickup_healthsmall;
1310         if(!self.pickup_anyway)
1311                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1312         StartItemA (ITEM_HealthSmall);
1313 }
1314
1315 void spawnfunc_item_health_medium (void) {
1316         if(!self.max_health)
1317                 self.max_health = g_pickup_healthmedium_max;
1318         if(!self.health)
1319                 self.health = g_pickup_healthmedium;
1320         if(!self.pickup_anyway)
1321                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1322     StartItemA (ITEM_HealthMedium);
1323 }
1324
1325 void spawnfunc_item_health_large (void) {
1326         if(!self.max_health)
1327                 self.max_health = g_pickup_healthlarge_max;
1328         if(!self.health)
1329                 self.health = g_pickup_healthlarge;
1330         if(!self.pickup_anyway)
1331                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1332         StartItemA (ITEM_HealthLarge);
1333 }
1334
1335 void spawnfunc_item_health_mega (void) {
1336     if(!self.max_health)
1337         self.max_health = g_pickup_healthmega_max;
1338     if(!self.health)
1339         self.health = g_pickup_healthmega;
1340     if(!self.pickup_anyway)
1341         self.pickup_anyway = g_pickup_healthmega_anyway;
1342     StartItemA (ITEM_HealthMega);
1343 }
1344
1345 // support old misnamed entities
1346 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1347 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1348 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1349 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1350 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1351
1352 void spawnfunc_item_strength (void) {
1353                 precache_sound("weapons/strength_fire.wav");
1354                 if(!self.strength_finished)
1355                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1356                 StartItemA (ITEM_Strength);
1357 }
1358
1359 void spawnfunc_item_invincible (void) {
1360                 if(!self.invincible_finished)
1361                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1362                 StartItemA (ITEM_Shield);
1363 }
1364
1365 // compatibility:
1366 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1367
1368 void target_items_use (void)
1369 {
1370         if(activator.classname == "droppedweapon")
1371         {
1372                 EXACTTRIGGER_TOUCH;
1373                 remove(activator);
1374                 return;
1375         }
1376
1377         if (!IS_PLAYER(activator))
1378                 return;
1379         if(activator.deadflag != DEAD_NO)
1380                 return;
1381         EXACTTRIGGER_TOUCH;
1382
1383         entity e;
1384         for(e = world; (e = find(e, classname, "droppedweapon")); )
1385                 if(e.enemy == activator)
1386                         remove(e);
1387
1388         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1389                 centerprint(activator, self.message);
1390 }
1391
1392 void spawnfunc_target_items (void)
1393 {
1394         float n, i, j;
1395         entity e;
1396         string s;
1397
1398         self.use = target_items_use;
1399         if(!self.strength_finished)
1400                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1401         if(!self.invincible_finished)
1402                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1403         if(!self.superweapons_finished)
1404                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1405
1406         precache_sound("misc/itempickup.wav");
1407         precache_sound("misc/megahealth.wav");
1408         precache_sound("misc/armor25.wav");
1409         precache_sound("misc/powerup.wav");
1410         precache_sound("misc/poweroff.wav");
1411         precache_sound("weapons/weaponpickup.wav");
1412
1413         n = tokenize_console(self.netname);
1414         if(argv(0) == "give")
1415         {
1416                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1417         }
1418         else
1419         {
1420                 for(i = 0; i < n; ++i)
1421                 {
1422                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1423                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1424                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1425                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1426                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1427                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1428                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1429                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1430                         else
1431                         {
1432                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1433                                 {
1434                                         e = get_weaponinfo(j);
1435                                         s = W_UndeprecateName(argv(i));
1436                                         if(s == e.netname)
1437                                         {
1438                                                 self.weapons |= WepSet_FromWeapon(j);
1439                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1440                                                         WEP_ACTION(e.weapon, WR_INIT);
1441                                                 break;
1442                                         }
1443                                 }
1444                                 if(j > WEP_LAST)
1445                                         print("target_items: invalid item ", argv(i), "\n");
1446                         }
1447                 }
1448
1449                 string itemprefix, valueprefix;
1450                 if(self.spawnflags == 0)
1451                 {
1452                         itemprefix = "";
1453                         valueprefix = "";
1454                 }
1455                 else if(self.spawnflags == 1)
1456                 {
1457                         itemprefix = "max ";
1458                         valueprefix = "max ";
1459                 }
1460                 else if(self.spawnflags == 2)
1461                 {
1462                         itemprefix = "min ";
1463                         valueprefix = "min ";
1464                 }
1465                 else if(self.spawnflags == 4)
1466                 {
1467                         itemprefix = "minus ";
1468                         valueprefix = "max ";
1469                 }
1470                 else
1471                 {
1472                         error("invalid spawnflags");
1473                         itemprefix = valueprefix = string_null;
1474                 }
1475
1476                 self.netname = "";
1477                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1478                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1479                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1480                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1481                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1482                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1483                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1484                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1485                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1486                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1487                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1488                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1489                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1490                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1491                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1492                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1493                 {
1494                         e = get_weaponinfo(j);
1495                         if(e.weapon)
1496                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1497                 }
1498         }
1499         self.netname = strzone(self.netname);
1500         //print(self.netname, "\n");
1501
1502         n = tokenize_console(self.netname);
1503         for(i = 0; i < n; ++i)
1504         {
1505                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1506                 {
1507                         e = get_weaponinfo(j);
1508                         if(argv(i) == e.netname)
1509                         {
1510                                 WEP_ACTION(e.weapon, WR_INIT);
1511                                 break;
1512                         }
1513                 }
1514         }
1515 }
1516
1517 void spawnfunc_item_fuel(void)
1518 {
1519         if(!self.ammo_fuel)
1520                 self.ammo_fuel = g_pickup_fuel;
1521         if(!self.pickup_anyway)
1522                 self.pickup_anyway = g_pickup_ammo_anyway;
1523         StartItemA (ITEM_JetpackFuel);
1524 }
1525
1526 void spawnfunc_item_fuel_regen(void)
1527 {
1528         if(start_items & ITEM_JetpackRegen.m_itemid)
1529         {
1530                 spawnfunc_item_fuel();
1531                 return;
1532         }
1533         StartItemA (ITEM_JetpackRegen);
1534 }
1535
1536 void spawnfunc_item_jetpack(void)
1537 {
1538         if(!self.ammo_fuel)
1539                 self.ammo_fuel = g_pickup_fuel_jetpack;
1540         if(start_items & ITEM_Jetpack.m_itemid)
1541         {
1542                 spawnfunc_item_fuel();
1543                 return;
1544         }
1545         StartItemA (ITEM_Jetpack);
1546 }
1547
1548 float GiveWeapon(entity e, float wpn, float op, float val)
1549 {
1550         WepSet v0, v1;
1551         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1552         switch(op)
1553         {
1554                 case OP_SET:
1555                         if(val > 0)
1556                                 e.weapons |= WepSet_FromWeapon(wpn);
1557                         else
1558                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1559                         break;
1560                 case OP_MIN:
1561                 case OP_PLUS:
1562                         if(val > 0)
1563                                 e.weapons |= WepSet_FromWeapon(wpn);
1564                         break;
1565                 case OP_MAX:
1566                         if(val <= 0)
1567                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1568                         break;
1569                 case OP_MINUS:
1570                         if(val > 0)
1571                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1572                         break;
1573         }
1574         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1575         return (v0 != v1);
1576 }
1577
1578 float GiveBit(entity e, .float fld, float bit, float op, float val)
1579 {
1580         float v0, v1;
1581         v0 = (e.(fld) & bit);
1582         switch(op)
1583         {
1584                 case OP_SET:
1585                         if(val > 0)
1586                                 e.(fld) |= bit;
1587                         else
1588                                 e.(fld) &= ~bit;
1589                         break;
1590                 case OP_MIN:
1591                 case OP_PLUS:
1592                         if(val > 0)
1593                                 e.(fld) |= bit;
1594                         break;
1595                 case OP_MAX:
1596                         if(val <= 0)
1597                                 e.(fld) &= ~bit;
1598                         break;
1599                 case OP_MINUS:
1600                         if(val > 0)
1601                                 e.(fld) &= ~bit;
1602                         break;
1603         }
1604         v1 = (e.(fld) & bit);
1605         return (v0 != v1);
1606 }
1607
1608 float GiveValue(entity e, .float fld, float op, float val)
1609 {
1610         float v0, v1;
1611         v0 = e.(fld);
1612         switch(op)
1613         {
1614                 case OP_SET:
1615                         e.(fld) = val;
1616                         break;
1617                 case OP_MIN:
1618                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1619                         break;
1620                 case OP_MAX:
1621                         e.(fld) = min(e.(fld), val);
1622                         break;
1623                 case OP_PLUS:
1624                         e.(fld) += val;
1625                         break;
1626                 case OP_MINUS:
1627                         e.(fld) -= val;
1628                         break;
1629         }
1630         v1 = e.(fld);
1631         return (v0 != v1);
1632 }
1633
1634 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1635 {
1636         if(v1 == v0)
1637                 return;
1638         if(v1 <= v0 - t)
1639         {
1640                 if(snd_decr != "")
1641                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1642         }
1643         else if(v0 >= v0 + t)
1644         {
1645                 if(snd_incr != "")
1646                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1647         }
1648 }
1649
1650 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1651 {
1652         if(v0 < v1)
1653                 e.(rotfield) = max(e.(rotfield), time + rottime);
1654         else if(v0 > v1)
1655                 e.(regenfield) = max(e.(regenfield), time + regentime);
1656 }
1657 float GiveItems(entity e, float beginarg, float endarg)
1658 {
1659         float got, i, j, val, op;
1660         float _switchweapon;
1661         entity wi;
1662         string cmd;
1663
1664         val = 999;
1665         op = OP_SET;
1666
1667         got = 0;
1668
1669         _switchweapon = false;
1670         if (e.autoswitch)
1671                 if (e.switchweapon == w_getbestweapon(e))
1672                         _switchweapon = true;
1673
1674         e.strength_finished = max(0, e.strength_finished - time);
1675         e.invincible_finished = max(0, e.invincible_finished - time);
1676         e.superweapons_finished = max(0, e.superweapons_finished - time);
1677
1678         PREGIVE(e, items);
1679         PREGIVE_WEAPONS(e);
1680         PREGIVE(e, strength_finished);
1681         PREGIVE(e, invincible_finished);
1682         PREGIVE(e, superweapons_finished);
1683         PREGIVE(e, ammo_nails);
1684         PREGIVE(e, ammo_cells);
1685         PREGIVE(e, ammo_plasma);
1686         PREGIVE(e, ammo_shells);
1687         PREGIVE(e, ammo_rockets);
1688         PREGIVE(e, ammo_fuel);
1689         PREGIVE(e, armorvalue);
1690         PREGIVE(e, health);
1691
1692         for(i = beginarg; i < endarg; ++i)
1693         {
1694                 cmd = argv(i);
1695
1696                 if(cmd == "0" || stof(cmd))
1697                 {
1698                         val = stof(cmd);
1699                         continue;
1700                 }
1701                 switch(cmd)
1702                 {
1703                         case "no":
1704                                 op = OP_MAX;
1705                                 val = 0;
1706                                 continue;
1707                         case "max":
1708                                 op = OP_MAX;
1709                                 continue;
1710                         case "min":
1711                                 op = OP_MIN;
1712                                 continue;
1713                         case "plus":
1714                                 op = OP_PLUS;
1715                                 continue;
1716                         case "minus":
1717                                 op = OP_MINUS;
1718                                 continue;
1719                         case "ALL":
1720                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1721                                 got += GiveValue(e, strength_finished, op, val);
1722                                 got += GiveValue(e, invincible_finished, op, val);
1723                                 got += GiveValue(e, superweapons_finished, op, val);
1724                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1725                         case "all":
1726                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1727                                 got += GiveValue(e, health, op, val);
1728                                 got += GiveValue(e, armorvalue, op, val);
1729                         case "allweapons":
1730                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1731                                 {
1732                                         wi = get_weaponinfo(j);
1733                                         if(wi.weapon)
1734                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1735                                                         got += GiveWeapon(e, j, op, val);
1736                                 }
1737                         case "allammo":
1738                                 got += GiveValue(e, ammo_cells, op, val);
1739                                 got += GiveValue(e, ammo_plasma, op, val);
1740                                 got += GiveValue(e, ammo_shells, op, val);
1741                                 got += GiveValue(e, ammo_nails, op, val);
1742                                 got += GiveValue(e, ammo_rockets, op, val);
1743                                 got += GiveValue(e, ammo_fuel, op, val);
1744                                 break;
1745                         case "unlimited_ammo":
1746                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1747                                 break;
1748                         case "unlimited_weapon_ammo":
1749                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1750                                 break;
1751                         case "unlimited_superweapons":
1752                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1753                                 break;
1754                         case "jetpack":
1755                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1756                                 break;
1757                         case "fuel_regen":
1758                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1759                                 break;
1760                         case "strength":
1761                                 got += GiveValue(e, strength_finished, op, val);
1762                                 break;
1763                         case "invincible":
1764                                 got += GiveValue(e, invincible_finished, op, val);
1765                                 break;
1766                         case "superweapons":
1767                                 got += GiveValue(e, superweapons_finished, op, val);
1768                                 break;
1769                         case "cells":
1770                                 got += GiveValue(e, ammo_cells, op, val);
1771                                 break;
1772                         case "plasma":
1773                                 got += GiveValue(e, ammo_plasma, op, val);
1774                                 break;
1775                         case "shells":
1776                                 got += GiveValue(e, ammo_shells, op, val);
1777                                 break;
1778                         case "nails":
1779                         case "bullets":
1780                                 got += GiveValue(e, ammo_nails, op, val);
1781                                 break;
1782                         case "rockets":
1783                                 got += GiveValue(e, ammo_rockets, op, val);
1784                                 break;
1785                         case "health":
1786                                 got += GiveValue(e, health, op, val);
1787                                 break;
1788                         case "armor":
1789                                 got += GiveValue(e, armorvalue, op, val);
1790                                 break;
1791                         case "fuel":
1792                                 got += GiveValue(e, ammo_fuel, op, val);
1793                                 break;
1794                         default:
1795                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1796                                 {
1797                                         wi = get_weaponinfo(j);
1798                                         if(cmd == wi.netname)
1799                                         {
1800                                                 got += GiveWeapon(e, j, op, val);
1801                                                 break;
1802                                         }
1803                                 }
1804                                 if(j > WEP_LAST)
1805                                         print("give: invalid item ", cmd, "\n");
1806                                 break;
1807                 }
1808                 val = 999;
1809                 op = OP_SET;
1810         }
1811
1812         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, "misc/itempickup.wav", string_null);
1813         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1814         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1815         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, "misc/itempickup.wav", string_null);
1816         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1817         {
1818                 wi = get_weaponinfo(j);
1819                 if(wi.weapon)
1820                 {
1821                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1822                         if (!(save_weapons & WepSet_FromWeapon(j)))
1823                                 if(e.weapons & WepSet_FromWeapon(j))
1824                                         WEP_ACTION(wi.weapon, WR_INIT);
1825                 }
1826         }
1827         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1828         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1829         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1830         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1831         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1832         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1833         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1834         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1835         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1836         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1837
1838         if(e.superweapons_finished <= 0)
1839                 if(self.weapons & WEPSET_SUPERWEAPONS)
1840                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1841
1842         if(e.strength_finished <= 0)
1843                 e.strength_finished = 0;
1844         else
1845                 e.strength_finished += time;
1846         if(e.invincible_finished <= 0)
1847                 e.invincible_finished = 0;
1848         else
1849                 e.invincible_finished += time;
1850         if(e.superweapons_finished <= 0)
1851                 e.superweapons_finished = 0;
1852         else
1853                 e.superweapons_finished += time;
1854
1855         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1856                 _switchweapon = true;
1857         if(_switchweapon)
1858                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1859
1860         return got;
1861 }
1862 #endif