qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_ca)
 119         {
 120                 ActivateTeamplay();
 121                 fraglimit_override = autocvar_g_ca_point_limit;
 122                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 123                 MUTATOR_ADD(gamemode_ca);
 124                 if(autocvar_g_ca_team_spawns)
 125                         have_team_spawns = -1; // request team spawns
 126         }
 127
 128         if(g_keyhunt)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 132                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 133                 MUTATOR_ADD(gamemode_keyhunt);
 134         }
 135
 136         if(g_freezetag)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_freezetag_point_limit;
 140                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_freezetag);
 142                 if(autocvar_g_freezetag_team_spawns)
 143                         have_team_spawns = -1; // request team spawns
 144         }
 145
 146         if(g_assault)
 147         {
 148                 ActivateTeamplay();
 149                 MUTATOR_ADD(gamemode_assault);
 150                 have_team_spawns = -1; // request team spawns
 151         }
 152
 153         if(g_onslaught)
 154         {
 155                 ActivateTeamplay();
 156                 have_team_spawns = -1; // request team spawns
 157                 MUTATOR_ADD(gamemode_onslaught);
 158         }
 159
 160         if(g_race)
 161         {
 162                 if(autocvar_g_race_teams)
 163                 {
 164                         ActivateTeamplay();
 165                         race_teams = bound(2, autocvar_g_race_teams, 4);
 166                         have_team_spawns = -1; // request team spawns
 167                 }
 168                 else
 169                         race_teams = 0;
 170
 171                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 172                 fraglimit_override = autocvar_g_race_laps_limit;
 173                 leadlimit_override = 0; // currently not supported by race
 174
 175                 MUTATOR_ADD(gamemode_race);
 176         }
 177
 178         if(g_cts)
 179         {
 180                 g_race_qualifying = 1;
 181                 fraglimit_override = 0;
 182                 leadlimit_override = 0;
 183                 MUTATOR_ADD(gamemode_cts);
 184         }
 185
 186         if(g_nexball)
 187         {
 188         fraglimit_override = autocvar_g_nexball_goallimit;
 189         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 190         ActivateTeamplay();
 191         have_team_spawns = -1; // request team spawns
 192             MUTATOR_ADD(gamemode_nexball);
 193         }
 194
 195         if(g_keepaway)
 196         {
 197                 MUTATOR_ADD(gamemode_keepaway);
 198         }
 199
 200         if(g_invasion)
 201         {
 202                 fraglimit_override = autocvar_g_invasion_point_limit;
 203                 if(autocvar_g_invasion_teams >= 2)
 204                 {
 205                         ActivateTeamplay();
 206                         if(autocvar_g_invasion_team_spawns)
 207                                 have_team_spawns = -1; // request team spawns
 208                 }
 209                 MUTATOR_ADD(gamemode_invasion);
 210         }
 211
 212         if(teamplay)
 213                 entcs_init();
 214
 215         cache_mutatormsg = strzone("");
 216         cache_lastmutatormsg = strzone("");
 217
 218         // enforce the server's universal frag/time limits
 219         if(!autocvar_g_campaign)
 220         {
 221                 if(fraglimit_override >= 0)
 222                         cvar_set("fraglimit", ftos(fraglimit_override));
 223                 if(timelimit_override >= 0)
 224                         cvar_set("timelimit", ftos(timelimit_override));
 225                 if(leadlimit_override >= 0)
 226                         cvar_set("leadlimit", ftos(leadlimit_override));
 227                 if(qualifying_override >= 0)
 228                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 229         }
 230
 231         if(g_race)
 232         {
 233                 // we need to find out the correct value for g_race_qualifying
 234                 if(autocvar_g_campaign)
 235                 {
 236                         g_race_qualifying = 1;
 237                 }
 238                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 239                 {
 240                         g_race_qualifying = 2;
 241                         race_fraglimit = autocvar_fraglimit;
 242                         race_leadlimit = autocvar_leadlimit;
 243                         race_timelimit = autocvar_timelimit;
 244                         cvar_set("fraglimit", "0");
 245                         cvar_set("leadlimit", "0");
 246                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 247                 }
 248                 else
 249                         g_race_qualifying = 0;
 250         }
 251
 252         if(g_race || g_cts)
 253         if(g_race_qualifying)
 254                 independent_players = 1;
 255
 256         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 257 }
 258
 259 string GetClientVersionMessage() {
 260         string versionmsg;
 261         if (self.version_mismatch) {
 262                 if(self.version < autocvar_gameversion) {
 263                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 264                 } else {
 265                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 266                 }
 267         } else {
 268                 versionmsg = "^2client version and server version are compatible.^8";
 269         }
 270         return versionmsg;
 271 }
 272
 273 string getwelcomemessage(void)
 274 {
 275         string s, modifications, motd;
 276
 277         ret_string = "";
 278         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 279         modifications = ret_string;
 280
 281         if(g_weaponarena)
 282         {
 283                 if(g_weaponarena_random)
 284                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 285                 else
 286                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 287         }
 288         if(autocvar_g_start_weapon_laser == 0)
 289                 modifications = strcat(modifications, ", No start weapons");
 290         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 291                 modifications = strcat(modifications, ", Low gravity");
 292         if(g_cloaked && !g_cts)
 293                 modifications = strcat(modifications, ", Cloaked");
 294         if(g_grappling_hook)
 295                 modifications = strcat(modifications, ", Hook");
 296         if(g_weapon_stay && !g_cts)
 297                 modifications = strcat(modifications, ", Weapons stay");
 298         if(g_jetpack)
 299                 modifications = strcat(modifications, ", Jet pack");
 300         if(autocvar_g_powerups == 0)
 301                 modifications = strcat(modifications, ", No powerups");
 302         if(autocvar_g_powerups > 0)
 303                 modifications = strcat(modifications, ", Powerups");
 304         modifications = substring(modifications, 2, strlen(modifications) - 2);
 305
 306         string versionmessage;
 307         versionmessage = GetClientVersionMessage();
 308
 309         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 310         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 311
 312         if(modifications != "")
 313                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 314
 315         if (g_grappling_hook)
 316                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 317
 318         if (cvar("g_nades"))
 319                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 320
 321         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 322         {
 323                 if(cache_lastmutatormsg)
 324                         strunzone(cache_lastmutatormsg);
 325                 if(cache_mutatormsg)
 326                         strunzone(cache_mutatormsg);
 327                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 328                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 329         }
 330
 331         if (cache_mutatormsg != "") {
 332                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 333         }
 334
 335         motd = autocvar_sv_motd;
 336         if (motd != "") {
 337                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 338         }
 339         return s;
 340 }
 341
 342 void SetPlayerColors(entity pl, float _color)
 343 {
 344         /*string s;
 345         s = ftos(cl);
 346         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 347         pl.team = cl + 1;
 348         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 349         pl.clientcolors = 16*cl + cl;*/
 350
 351         float pants, shirt;
 352         pants = _color & 0x0F;
 353         shirt = _color & 0xF0;
 354
 355
 356         if(teamplay) {
 357                 setcolor(pl, 16*pants + pants);
 358         } else {
 359                 setcolor(pl, shirt + pants);
 360         }
 361 }
 362
 363 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 364 {
 365         float _color;
 366
 367         if(t == 4)
 368                 _color = NUM_TEAM_4 - 1;
 369         else if(t == 3)
 370                 _color = NUM_TEAM_3 - 1;
 371         else if(t == 2)
 372                 _color = NUM_TEAM_2 - 1;
 373         else
 374                 _color = NUM_TEAM_1 - 1;
 375
 376         SetPlayerColors(pl,_color);
 377
 378         if(t != s) {
 379                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 380
 381                 if(!noprint)
 382                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 383         }
 384
 385 }
 386
 387 // set c1...c4 to show what teams are allowed
 388 void CheckAllowedTeams (entity for_whom)
 389 {
 390         float dm;
 391         entity head;
 392         string teament_name;
 393
 394         c1 = c2 = c3 = c4 = -1;
 395         cb1 = cb2 = cb3 = cb4 = 0;
 396
 397         teament_name = string_null;
 398         if(g_onslaught)
 399         {
 400                 // onslaught is special
 401                 head = findchain(classname, "onslaught_generator");
 402                 while (head)
 403                 {
 404                         if (head.team == NUM_TEAM_1) c1 = 0;
 405                         if (head.team == NUM_TEAM_2) c2 = 0;
 406                         if (head.team == NUM_TEAM_3) c3 = 0;
 407                         if (head.team == NUM_TEAM_4) c4 = 0;
 408                         head = head.chain;
 409                 }
 410         }
 411         else if(g_domination)
 412                 teament_name = "dom_team";
 413         else if(g_ctf)
 414                 teament_name = "ctf_team";
 415         else if(g_tdm)
 416                 teament_name = "tdm_team";
 417         else if(g_nexball)
 418                 teament_name = "nexball_team";
 419         else if(g_assault)
 420                 c1 = c2 = 0; // Assault always has 2 teams
 421         else
 422         {
 423                 // cover anything else by treating it like tdm with no teams spawned
 424                 dm = 2;
 425
 426                 ret_float = dm;
 427                 MUTATOR_CALLHOOK(GetTeamCount);
 428                 dm = ret_float;
 429
 430                 if(dm >= 4)
 431                         c1 = c2 = c3 = c4 = 0;
 432                 else if(dm >= 3)
 433                         c1 = c2 = c3 = 0;
 434                 else
 435                         c1 = c2 = 0;
 436         }
 437
 438         // find out what teams are allowed if necessary
 439         if(teament_name)
 440         {
 441                 head = find(world, classname, teament_name);
 442                 while(head)
 443                 {
 444                         if(!(g_domination && head.netname == ""))
 445                         {
 446                                 if(head.team == NUM_TEAM_1)
 447                                         c1 = 0;
 448                                 else if(head.team == NUM_TEAM_2)
 449                                         c2 = 0;
 450                                 else if(head.team == NUM_TEAM_3)
 451                                         c3 = 0;
 452                                 else if(head.team == NUM_TEAM_4)
 453                                         c4 = 0;
 454                         }
 455                         head = find(head, classname, teament_name);
 456                 }
 457         }
 458
 459         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 460         if(c3==-1 && c4==-1)
 461         if(autocvar_bot_vs_human && for_whom)
 462         {
 463                 if(autocvar_bot_vs_human > 0)
 464                 {
 465                         // bots are all blue
 466                         if(IS_BOT_CLIENT(for_whom))
 467                                 c1 = c3 = c4 = -1;
 468                         else
 469                                 c2 = -1;
 470                 }
 471                 else
 472                 {
 473                         // bots are all red
 474                         if(IS_BOT_CLIENT(for_whom))
 475                                 c2 = c3 = c4 = -1;
 476                         else
 477                                 c1 = -1;
 478                 }
 479         }
 480
 481         // if player has a forced team, ONLY allow that one
 482         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 483                 c2 = c3 = c4 = -1;
 484         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 485                 c1 = c3 = c4 = -1;
 486         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 487                 c1 = c2 = c4 = -1;
 488         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 489                 c1 = c2 = c3 = -1;
 490 }
 491
 492 float PlayerValue(entity p)
 493 {
 494         return 1;
 495         // FIXME: it always returns 1...
 496 }
 497
 498 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 499 // teams that are allowed will now have their player counts stored in c1...c4
 500 void GetTeamCounts(entity ignore)
 501 {
 502         entity head;
 503         float value, bvalue;
 504         // now count how many players are on each team already
 505
 506         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 507         // also remember the lowest-scoring player
 508
 509         FOR_EACH_CLIENT(head)
 510         {
 511                 float t;
 512                 if(IS_PLAYER(head))
 513                         t = head.team;
 514                 else if(head.team_forced > 0)
 515                         t = head.team_forced; // reserve the spot
 516                 else
 517                         continue;
 518                 if(head != ignore)// && head.netname != "")
 519                 {
 520                         value = PlayerValue(head);
 521                         if(IS_BOT_CLIENT(head))
 522                                 bvalue = value;
 523                         else
 524                                 bvalue = 0;
 525                         if(t == NUM_TEAM_1)
 526                         {
 527                                 if(c1 >= 0)
 528                                 {
 529                                         c1 = c1 + value;
 530                                         cb1 = cb1 + bvalue;
 531                                 }
 532                         }
 533                         if(t == NUM_TEAM_2)
 534                         {
 535                                 if(c2 >= 0)
 536                                 {
 537                                         c2 = c2 + value;
 538                                         cb2 = cb2 + bvalue;
 539                                 }
 540                         }
 541                         if(t == NUM_TEAM_3)
 542                         {
 543                                 if(c3 >= 0)
 544                                 {
 545                                         c3 = c3 + value;
 546                                         cb3 = cb3 + bvalue;
 547                                 }
 548                         }
 549                         if(t == NUM_TEAM_4)
 550                         {
 551                                 if(c4 >= 0)
 552                                 {
 553                                         c4 = c4 + value;
 554                                         cb4 = cb4 + bvalue;
 555                                 }
 556                         }
 557                 }
 558         }
 559
 560         // if the player who has a forced team has not joined yet, reserve the spot
 561         if(autocvar_g_campaign)
 562         {
 563                 switch(autocvar_g_campaign_forceteam)
 564                 {
 565                         case 1: if(c1 == cb1) ++c1; break;
 566                         case 2: if(c2 == cb2) ++c2; break;
 567                         case 3: if(c3 == cb3) ++c3; break;
 568                         case 4: if(c4 == cb4) ++c4; break;
 569                 }
 570         }
 571 }
 572
 573 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 574 {
 575         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 576         float f;
 577         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 578
 579         switch(ta)
 580         {
 581                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 582                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 583                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 584                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 585         }
 586         switch(tb)
 587         {
 588                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 589                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 590                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 591                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 592         }
 593
 594         // invalid
 595         if(ca < 0 || cb < 0)
 596                 return FALSE;
 597
 598         // equal
 599         if(ta == tb)
 600                 return TRUE;
 601
 602         if(IS_REAL_CLIENT(e))
 603         {
 604                 if(bots_would_leave)
 605                 {
 606                         ca -= cba * 0.999;
 607                         cb -= cbb * 0.999;
 608                 }
 609         }
 610
 611         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 612         if(ca < 1)
 613                 if(cb >= 1)
 614                         return TRUE;
 615         if(ca >= 1)
 616                 if(cb < 1)
 617                         return FALSE;
 618
 619         // first, normalize
 620         f = max(ca, cb, 1);
 621         ca /= f;
 622         cb /= f;
 623         f = max(sa, sb, 1);
 624         sa /= f;
 625         sb /= f;
 626
 627         // the more we're at the end of the match, the more take scores into account
 628         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 629         ca += (sa - ca) * f;
 630         cb += (sb - cb) * f;
 631
 632         return ca <= cb;
 633 }
 634
 635 // returns # of smallest team (1, 2, 3, 4)
 636 // NOTE: Assumes CheckAllowedTeams has already been called!
 637 float FindSmallestTeam(entity pl, float ignore_pl)
 638 {
 639         float totalteams, t;
 640         totalteams = 0;
 641
 642         // find out what teams are available
 643         //CheckAllowedTeams();
 644
 645         // make sure there are at least 2 teams to join
 646         if(c1 >= 0)
 647                 totalteams = totalteams + 1;
 648         if(c2 >= 0)
 649                 totalteams = totalteams + 1;
 650         if(c3 >= 0)
 651                 totalteams = totalteams + 1;
 652         if(c4 >= 0)
 653                 totalteams = totalteams + 1;
 654
 655         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 656                 totalteams += 1;
 657
 658         if(totalteams <= 1)
 659         {
 660                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 661                         return 1; // special case for campaign and player joining
 662                 else if(g_domination)
 663                         error("Too few teams available for domination\n");
 664                 else if(g_ctf)
 665                         error("Too few teams available for ctf\n");
 666                 else if(g_keyhunt)
 667                         error("Too few teams available for key hunt\n");
 668                 else if(g_freezetag)
 669                         error("Too few teams available for freeze tag\n");
 670                 else
 671                         error("Too few teams available for team deathmatch\n");
 672         }
 673
 674         // count how many players are in each team
 675         if(ignore_pl)
 676                 GetTeamCounts(pl);
 677         else
 678                 GetTeamCounts(world);
 679
 680         RandomSelection_Init();
 681
 682         t = 1;
 683         if(TeamSmallerEqThanTeam(2, t, pl))
 684                 t = 2;
 685         if(TeamSmallerEqThanTeam(3, t, pl))
 686                 t = 3;
 687         if(TeamSmallerEqThanTeam(4, t, pl))
 688                 t = 4;
 689
 690         // now t is the minimum, or A minimum!
 691         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 692                 RandomSelection_Add(world, 1, string_null, 1, 1);
 693         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 694                 RandomSelection_Add(world, 2, string_null, 1, 1);
 695         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 696                 RandomSelection_Add(world, 3, string_null, 1, 1);
 697         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 698                 RandomSelection_Add(world, 4, string_null, 1, 1);
 699
 700         return RandomSelection_chosen_float;
 701 }
 702
 703 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 704 {
 705         float smallest, selectedteam;
 706
 707         // don't join a team if we're not playing a team game
 708         if(!teamplay)
 709                 return 0;
 710
 711         // find out what teams are available
 712         CheckAllowedTeams(pl);
 713
 714         // if we don't care what team he ends up on, put him on whatever team he entered as.
 715         // if he's not on a valid team, then let other code put him on the smallest team
 716         if(!forcebestteam)
 717         {
 718                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 719                         selectedteam = pl.team;
 720                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 721                         selectedteam = pl.team;
 722                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 723                         selectedteam = pl.team;
 724                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 725                         selectedteam = pl.team;
 726                 else
 727                         selectedteam = -1;
 728
 729                 if(selectedteam > 0)
 730                 {
 731                         if(!only_return_best)
 732                         {
 733                                 SetPlayerColors(pl, selectedteam - 1);
 734
 735                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 736                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 737                                 LogTeamchange(pl.playerid, pl.team, 99);
 738                         }
 739                         return selectedteam;
 740                 }
 741                 // otherwise end up on the smallest team (handled below)
 742         }
 743
 744         smallest = FindSmallestTeam(pl, TRUE);
 745
 746         if(!only_return_best && !pl.bot_forced_team)
 747         {
 748                 TeamchangeFrags(self);
 749                 if(smallest == 1)
 750                 {
 751                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 752                 }
 753                 else if(smallest == 2)
 754                 {
 755                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 756                 }
 757                 else if(smallest == 3)
 758                 {
 759                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 760                 }
 761                 else if(smallest == 4)
 762                 {
 763                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 764                 }
 765                 else
 766                 {
 767                         error("smallest team: invalid team\n");
 768                 }
 769
 770                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 771
 772                 if(pl.deadflag == DEAD_NO)
 773                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 774         }
 775
 776         return smallest;
 777 }
 778
 779 //void() ctf_playerchanged;
 780 void SV_ChangeTeam(float _color)
 781 {
 782         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 783
 784         // in normal deathmatch we can just apply the color and we're done
 785         if(!teamplay) {
 786                 SetPlayerColors(self, _color);
 787                 return;
 788         }
 789
 790         scolor = self.clientcolors & 0x0F;
 791         dcolor = _color & 0x0F;
 792
 793         if(scolor == NUM_TEAM_1 - 1)
 794                 steam = 1;
 795         else if(scolor == NUM_TEAM_2 - 1)
 796                 steam = 2;
 797         else if(scolor == NUM_TEAM_3 - 1)
 798                 steam = 3;
 799         else // if(scolor == NUM_TEAM_4 - 1)
 800                 steam = 4;
 801         if(dcolor == NUM_TEAM_1 - 1)
 802                 dteam = 1;
 803         else if(dcolor == NUM_TEAM_2 - 1)
 804                 dteam = 2;
 805         else if(dcolor == NUM_TEAM_3 - 1)
 806                 dteam = 3;
 807         else // if(dcolor == NUM_TEAM_4 - 1)
 808                 dteam = 4;
 809
 810         CheckAllowedTeams(self);
 811
 812         if(dteam == 1 && c1 < 0) dteam = 4;
 813         if(dteam == 4 && c4 < 0) dteam = 3;
 814         if(dteam == 3 && c3 < 0) dteam = 2;
 815         if(dteam == 2 && c2 < 0) dteam = 1;
 816
 817         // not changing teams
 818         if(scolor == dcolor)
 819         {
 820                 //bprint("same team change\n");
 821                 SetPlayerTeam(self, dteam, steam, TRUE);
 822                 return;
 823         }
 824
 825         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 826                 sprint(self, "Team changes not allowed\n");
 827                 return; // changing teams is not allowed
 828         }
 829
 830         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 831         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 832         {
 833                 GetTeamCounts(self);
 834                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 835                 {
 836                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 837                         return;
 838                 }
 839         }
 840
 841 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 842
 843         if(IS_PLAYER(self) && steam != dteam)
 844         {
 845                 // reduce frags during a team change
 846                 TeamchangeFrags(self);
 847         }
 848
 849         SetPlayerTeam(self, dteam, steam, FALSE);
 850
 851         if(IS_PLAYER(self) && steam != dteam)
 852         {
 853                 // kill player when changing teams
 854                 if(self.deadflag == DEAD_NO)
 855                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 856         }
 857 }
 858
 859 void ShufflePlayerOutOfTeam (float source_team)
 860 {
 861         float smallestteam, smallestteam_count, steam;
 862         float lowest_bot_score, lowest_player_score;
 863         entity head, lowest_bot, lowest_player, selected;
 864
 865         smallestteam = 0;
 866         smallestteam_count = 999999999;
 867
 868         if(c1 >= 0 && c1 < smallestteam_count)
 869         {
 870                 smallestteam = 1;
 871                 smallestteam_count = c1;
 872         }
 873         if(c2 >= 0 && c2 < smallestteam_count)
 874         {
 875                 smallestteam = 2;
 876                 smallestteam_count = c2;
 877         }
 878         if(c3 >= 0 && c3 < smallestteam_count)
 879         {
 880                 smallestteam = 3;
 881                 smallestteam_count = c3;
 882         }
 883         if(c4 >= 0 && c4 < smallestteam_count)
 884         {
 885                 smallestteam = 4;
 886                 smallestteam_count = c4;
 887         }
 888
 889         if(!smallestteam)
 890         {
 891                 bprint("warning: no smallest team\n");
 892                 return;
 893         }
 894
 895         if(source_team == 1)
 896                 steam = NUM_TEAM_1;
 897         else if(source_team == 2)
 898                 steam = NUM_TEAM_2;
 899         else if(source_team == 3)
 900                 steam = NUM_TEAM_3;
 901         else // if(source_team == 4)
 902                 steam = NUM_TEAM_4;
 903
 904         lowest_bot = world;
 905         lowest_bot_score = 999999999;
 906         lowest_player = world;
 907         lowest_player_score = 999999999;
 908
 909         // find the lowest-scoring player & bot of that team
 910         FOR_EACH_PLAYER(head)
 911         {
 912                 if(head.team == steam)
 913                 {
 914                         if(head.isbot)
 915                         {
 916                                 if(head.totalfrags < lowest_bot_score)
 917                                 {
 918                                         lowest_bot = head;
 919                                         lowest_bot_score = head.totalfrags;
 920                                 }
 921                         }
 922                         else
 923                         {
 924                                 if(head.totalfrags < lowest_player_score)
 925                                 {
 926                                         lowest_player = head;
 927                                         lowest_player_score = head.totalfrags;
 928                                 }
 929                         }
 930                 }
 931         }
 932
 933         // prefers to move a bot...
 934         if(lowest_bot != world)
 935                 selected = lowest_bot;
 936         // but it will move a player if it has to
 937         else
 938                 selected = lowest_player;
 939         // don't do anything if it couldn't find anyone
 940         if(!selected)
 941         {
 942                 bprint("warning: couldn't find a player to move from team\n");
 943                 return;
 944         }
 945
 946         // smallest team gains a member
 947         if(smallestteam == 1)
 948         {
 949                 c1 = c1 + 1;
 950         }
 951         else if(smallestteam == 2)
 952         {
 953                 c2 = c2 + 1;
 954         }
 955         else if(smallestteam == 3)
 956         {
 957                 c3 = c3 + 1;
 958         }
 959         else if(smallestteam == 4)
 960         {
 961                 c4 = c4 + 1;
 962         }
 963         else
 964         {
 965                 bprint("warning: destination team invalid\n");
 966                 return;
 967         }
 968         // source team loses a member
 969         if(source_team == 1)
 970         {
 971                 c1 = c1 + 1;
 972         }
 973         else if(source_team == 2)
 974         {
 975                 c2 = c2 + 2;
 976         }
 977         else if(source_team == 3)
 978         {
 979                 c3 = c3 + 3;
 980         }
 981         else if(source_team == 4)
 982         {
 983                 c4 = c4 + 4;
 984         }
 985         else
 986         {
 987                 bprint("warning: source team invalid\n");
 988                 return;
 989         }
 990
 991         // move the player to the new team
 992         TeamchangeFrags(selected);
 993         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 994
 995         if(selected.deadflag == DEAD_NO)
 996                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 997         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
 998 }
 999
1000 // code from here on is just to support maps that don't have team entities
1001 void tdm_spawnteam (string teamname, float teamcolor)
1002 {
1003         entity e;
1004         e = spawn();
1005         e.classname = "tdm_team";
1006         e.netname = teamname;
1007         e.cnt = teamcolor;
1008         e.team = e.cnt + 1;
1009 }
1010
1011 // spawn some default teams if the map is not set up for tdm
1012 void tdm_spawnteams()
1013 {
1014         float numteams;
1015
1016         numteams = autocvar_g_tdm_teams_override;
1017         if(numteams < 2)
1018                 numteams = autocvar_g_tdm_teams;
1019         numteams = bound(2, numteams, 4);
1020
1021         tdm_spawnteam("Red", NUM_TEAM_1-1);
1022         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1023         if(numteams >= 3)
1024                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1025         if(numteams >= 4)
1026                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1027 }
1028
1029 void tdm_delayedinit()
1030 {
1031         // if no teams are found, spawn defaults
1032         if (find(world, classname, "tdm_team") == world)
1033                 tdm_spawnteams();
1034 }
1035
1036 void tdm_init()
1037 {
1038         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1039 }