qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_ENGINE "sound/vehicles/racer.wav"
   4
   5 #ifdef SVQC
   6 void racer_exit(float eject);
   7 void racer_enter();
   8
   9 // Auto cvars
  10 float autocvar_g_vehicle_racer_speed_afterburn;
  11 float autocvar_g_vehicle_racer_afterburn_cost;
  12
  13 float autocvar_g_vehicle_racer_anglestabilizer;
  14 float autocvar_g_vehicle_racer_downforce;
  15
  16 float autocvar_g_vehicle_racer_speed_forward;
  17 float autocvar_g_vehicle_racer_speed_strafe;
  18 float autocvar_g_vehicle_racer_springlength;
  19 float autocvar_g_vehicle_racer_upforcedamper;
  20 float autocvar_g_vehicle_racer_friction;
  21
  22 float autocvar_g_vehicle_racer_hovertype;
  23 float autocvar_g_vehicle_racer_hoverpower;
  24
  25 float autocvar_g_vehicle_racer_turnroll;
  26 float autocvar_g_vehicle_racer_turnspeed;
  27 float autocvar_g_vehicle_racer_pitchspeed;
  28
  29 float autocvar_g_vehicle_racer_energy;
  30 float autocvar_g_vehicle_racer_energy_regen;
  31 float autocvar_g_vehicle_racer_energy_regen_pause;
  32
  33 float autocvar_g_vehicle_racer_health;
  34 float autocvar_g_vehicle_racer_health_regen;
  35 float autocvar_g_vehicle_racer_health_regen_pause;
  36
  37 float autocvar_g_vehicle_racer_shield;
  38 float autocvar_g_vehicle_racer_shield_regen;
  39 float autocvar_g_vehicle_racer_shield_regen_pause;
  40
  41 float autocvar_g_vehicle_racer_cannon_cost;
  42 float autocvar_g_vehicle_racer_cannon_damage;
  43 float autocvar_g_vehicle_racer_cannon_radius;
  44 float autocvar_g_vehicle_racer_cannon_refire;
  45 float autocvar_g_vehicle_racer_cannon_speed;
  46 float autocvar_g_vehicle_racer_cannon_spread;
  47 float autocvar_g_vehicle_racer_cannon_force;
  48
  49 float autocvar_g_vehicle_racer_rocket_accel;
  50 float autocvar_g_vehicle_racer_rocket_damage;
  51 float autocvar_g_vehicle_racer_rocket_radius;
  52 float autocvar_g_vehicle_racer_rocket_force;
  53 float autocvar_g_vehicle_racer_rocket_refire;
  54 float autocvar_g_vehicle_racer_rocket_speed;
  55 float autocvar_g_vehicle_racer_rocket_turnrate;
  56
  57 float autocvar_g_vehicle_racer_rocket_locktarget;
  58 float autocvar_g_vehicle_racer_rocket_locking_time;
  59 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  60 float autocvar_g_vehicle_racer_rocket_locked_time;
  61 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  62
  63 float autocvar_g_vehicle_racer_respawntime;
  64
  65 float autocvar_g_vehicle_racer_blowup_radius;
  66 float autocvar_g_vehicle_racer_blowup_coredamage;
  67 float autocvar_g_vehicle_racer_blowup_edgedamage;
  68 float autocvar_g_vehicle_racer_blowup_forceintensity;
  69
  70 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  71
  72 void racer_align4point()
  73 {
  74     vector push_vector, v_add;
  75     float fl_push, fr_push, bl_push, br_push;
  76
  77
  78     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fr_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fl_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     br_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     bl_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     self.velocity += (push_vector * frametime);
  95
  96     // Anti ocilation
  97     if(self.velocity_z  > 0)
  98         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  99
 100     self.velocity   += v_add;
 101     //self.velocity_z -= autocvar_sv_gravity * frametime;
 102
 103     push_vector_x =  (fl_push - bl_push);
 104     push_vector_x += (fr_push - br_push);
 105     push_vector_x *= 360;
 106
 107     push_vector_z = (fr_push - fl_push);
 108     push_vector_z += (br_push - bl_push);
 109     push_vector_z *= 360;
 110
 111     // Apply angle diffrance
 112     self.angles_z += push_vector_z * frametime;
 113     self.angles_x += push_vector_x * frametime;
 114
 115     // Apply stabilizer
 116     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 118 }
 119
 120 void racer_fire_cannon(string tagname)
 121 {
 122     vector v;
 123     entity bolt;
 124
 125     v = gettaginfo(self, gettagindex(self, tagname));
 126     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 127                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 128                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 129                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 130
 131         // Fix z-aim (for chase mode)
 132     v = normalize(trace_endpos - bolt.origin);
 133     v_forward_z = v_z * 0.5;
 134     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 135 }
 136
 137 void racer_rocket_groundhugger()
 138 {
 139     vector olddir, newdir;
 140     float oldvel, newvel;
 141
 142     self.nextthink  = time;
 143
 144     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 145     {
 146         self.use();
 147         return;
 148     }
 149
 150     if not (self.realowner.vehicle)
 151     {
 152         UpdateCSQCProjectile(self);
 153         return;
 154     }
 155
 156     olddir = normalize(self.velocity);
 157     oldvel = vlen(self.velocity);
 158     newvel = oldvel + self.lip;
 159
 160     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 161     if(trace_fraction <= 0.5)
 162     {
 163         // Hitting somethign soon, just speed ahead
 164         self.velocity = olddir * newvel;
 165         UpdateCSQCProjectile(self);
 166         return;
 167     }
 168
 169     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 170     if(trace_fraction != 1.0)
 171     {
 172         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 173         self.velocity = normalize(olddir + newdir) * newvel;
 174     }
 175     else
 176     {
 177         self.velocity = olddir * newvel;
 178         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 179     }
 180
 181     UpdateCSQCProjectile(self);
 182     return;
 183 }
 184
 185 void racer_rocket_tracker()
 186 {
 187     vector olddir, newdir;
 188     float oldvel, newvel;
 189
 190     self.nextthink  = time;
 191
 192     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 193     {
 194         self.use();
 195         return;
 196     }
 197
 198     if not (self.realowner.vehicle)
 199     {
 200         UpdateCSQCProjectile(self);
 201         return;
 202     }
 203
 204     olddir = normalize(self.velocity);
 205     oldvel = vlen(self.velocity);
 206     newvel = oldvel + self.lip;
 207     makevectors(vectoangles(olddir));
 208
 209     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 210     newdir = normalize(self.enemy.origin - self.origin);
 211
 212     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 213     {
 214         //bprint("Target lost!\n");
 215         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 216         self.think = racer_rocket_groundhugger;
 217         return;
 218     }
 219
 220     if(trace_fraction != 1.0)
 221         newdir_z += 16 * sys_frametime;
 222
 223     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 224     self.velocity_z -= 800 * sys_frametime;
 225
 226     UpdateCSQCProjectile(self);
 227     return;
 228 }
 229
 230 void racer_fire_rocket(string tagname, entity trg)
 231 {
 232     vector v;
 233     entity rocket;
 234
 235     v = gettaginfo(self, gettagindex(self, tagname));
 236     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259     player          = self;
 260     racer           = self.vehicle;
 261
 262     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 263
 264     self = racer;
 265
 266     if(player.BUTTON_USE)
 267     {
 268         vehicles_exit(VHEF_NORMAL);
 269         self = player;
 270         return 0;
 271     }
 272
 273     if(racer.deadflag != DEAD_NO)
 274     {
 275         self = player;
 276         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 277         return 1;
 278     }
 279
 280     racer_align4point();
 281
 282     crosshair_trace(player);
 283
 284     racer.angles_x *= -1;
 285
 286     // Yaw
 287     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 288     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 289     racer.angles_y = anglemods(racer.angles_y + ftmp);
 290
 291     // Roll
 292     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 293
 294     // Pitch
 295     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 296     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 297     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 298
 299     makevectors(racer.angles);
 300     racer.angles_x *= -1;
 301
 302
 303     ftmp = racer.velocity_z;
 304     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 305     racer.velocity_z = ftmp;
 306
 307     if(player.movement_x != 0)
 308     {
 309         if(player.movement_x > 0)
 310             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 311         else if(player.movement_x < 0)
 312             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 313     }
 314
 315     if(player.movement_y != 0)
 316     {
 317         if(player.movement_y < 0)
 318             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 319         else if(player.movement_y > 0)
 320             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 321     }
 322
 323     if(vlen(player.movement) != 0)
 324     {
 325         if(self.sound_nexttime < time || self.sounds != 1)
 326         {
 327             self.sounds = 1;
 328             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 329             sound (self, CHAN_TRIGGER, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 330         }
 331     }
 332     else
 333     {
 334         if(self.sound_nexttime < time || self.sounds != 0)
 335         {
 336             self.sounds = 0;
 337             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 338             sound (self, CHAN_TRIGGER, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 339         }
 340     }
 341
 342     // Afterburn
 343     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 344     {
 345         racer.wait = time;
 346         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 347         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 348
 349         if(self.strength_finished < time)
 350         {
 351             //self.sounds = 2;
 352             self.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 353             sound (self, CHAN_PAIN, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 354         }
 355     }
 356     else
 357     {
 358         self.strength_finished = 0;
 359         sound (self, CHAN_PAIN, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 360     }
 361
 362
 363     racer.velocity  += df * frametime;
 364
 365     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 366     racer.velocity  = racer.velocity - df;
 367     player.movement = racer.velocity;
 368
 369     if(player.BUTTON_ATCK)
 370     if(time > racer.attack_finished_single)
 371     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 372     {
 373         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 374         racer.wait = time;
 375
 376         crosshair_trace(player);
 377         if(racer.cnt)
 378         {
 379             racer_fire_cannon("tag_fire1");
 380             racer.cnt = 0;
 381         }
 382         else
 383         {
 384             racer_fire_cannon("tag_fire2");
 385             racer.cnt = 1;
 386         }
 387         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 388         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 389     }
 390
 391     if(autocvar_g_vehicle_racer_rocket_locktarget)
 392     {
 393         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 394                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 395                          autocvar_g_vehicle_racer_rocket_locked_time);
 396
 397         if(self.lock_target)
 398         {
 399             if(racer.lock_strength == 1)
 400                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 401             else if(self.lock_strength > 0.5)
 402                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 403             else if(self.lock_strength < 0.5)
 404                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 405         }
 406     }
 407
 408     if(time > racer.delay)
 409     if(player.BUTTON_ATCK2)
 410     {
 411         self.misc_bulletcounter += 1;
 412         racer.delay = time + 0.3;
 413         if(self.misc_bulletcounter == 1)
 414             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 415         else if(self.misc_bulletcounter == 2)
 416         {
 417             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 418             self.lock_strength  = 0;
 419             self.lock_target    = world;
 420             self.misc_bulletcounter = 0;
 421
 422             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 423             racer.lip = time;
 424         }
 425     }
 426     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 427
 428     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 429         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 430
 431     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 432         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 433
 434     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 435         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 436
 437
 438     VEHICLE_UPDATE_PLAYER(health, racer);
 439     VEHICLE_UPDATE_PLAYER(energy, racer);
 440
 441     if(self.vehicle_flags & VHF_HASSHIELD)
 442         VEHICLE_UPDATE_PLAYER(shield, racer);
 443
 444
 445     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 446     setorigin(player,racer.origin + '0 0 32');
 447     player.velocity = racer.velocity;
 448
 449     self = player;
 450     return 1;
 451 }
 452
 453 void racer_think()
 454 {
 455     /*
 456     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 457     b = autocvar_g_vehicle_racer_springlength;
 458     c = autocvar_g_vehicle_racer_hoverpower;
 459
 460     autocvar_g_vehicle_racer_anglestabilizer = 36;
 461     autocvar_g_vehicle_racer_springlength = 96;
 462     autocvar_g_vehicle_racer_hoverpower = 300;
 463     */
 464
 465     racer_align4point(); //time - self.nextthink);
 466
 467     /*
 468     //if(self.velocity_z > 0)
 469     //    self.velocity_z *= 0.95;
 470
 471     autocvar_g_vehicle_racer_anglestabilizer = a;
 472     autocvar_g_vehicle_racer_springlength = b;
 473     autocvar_g_vehicle_racer_hoverpower = c;
 474     */
 475
 476     self.velocity_x *= 0.9;
 477     self.velocity_y *= 0.9;
 478     self.velocity_z *= 0.8;
 479     self.velocity_z += sin(time * 2) * 16;
 480     self.nextthink = time; // + 0.05;
 481 }
 482
 483 void racer_enter()
 484 {
 485     self.movetype = MOVETYPE_BOUNCE;
 486     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 487     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 488 }
 489
 490 void racer_exit(float eject)
 491 {
 492     vector spot;
 493
 494     self.think      = racer_think;
 495     self.nextthink  = time;
 496     self.movetype   = MOVETYPE_TOSS;
 497
 498     if not (self.owner)
 499         return;
 500
 501         makevectors(self.angles);
 502         if(eject)
 503         {
 504             spot = self.origin + v_forward * 100 + '0 0 64';
 505             spot = vehicles_findgoodexit(spot);
 506             setorigin(self.owner , spot);
 507             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 508         }
 509         else
 510         {
 511             spot = self.origin - v_forward * 200 + '0 0 64';
 512             spot = vehicles_findgoodexit(spot);
 513             setorigin(self.owner , spot);
 514         }
 515
 516     self.owner = world;
 517 }
 518
 519 void racer_spawn()
 520 {
 521     self.think          = racer_think;
 522     self.nextthink      = time;
 523     self.vehicle_health = autocvar_g_vehicle_racer_health;
 524     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 525
 526     self.movetype       = MOVETYPE_TOSS;
 527     self.solid          = SOLID_SLIDEBOX;
 528     self.delay          = time;
 529     self.scale          = 0.5;
 530
 531     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 532 }
 533
 534
 535 void racer_blowup()
 536 {
 537     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 538     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 539
 540     self.deadflag    = DEAD_DEAD;
 541     self.vehicle_exit(VHEF_NORMAL);
 542
 543     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 544                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 545                                         autocvar_g_vehicle_racer_blowup_radius, world,
 546                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 547                                         DEATH_WAKIBLOWUP, world);
 548
 549     self.alpha = -1;
 550     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 551     self.think      = racer_spawn;
 552     self.movetype   = MOVETYPE_NONE;
 553     self.effects    = EF_NODRAW;
 554
 555     self.colormod  = '0 0 0';
 556     self.avelocity = '0 0 0';
 557     self.velocity  = '0 0 0';
 558
 559     setorigin(self, self.pos1);
 560         self.think     = racer_spawn;
 561         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 562 }
 563
 564 void racer_deadtouch()
 565 {
 566     dprint("Boink!\n");
 567     self.avelocity_x *= 0.7;
 568     self.cnt -= 1;
 569     if(self.cnt <= 0)
 570         racer_blowup();
 571 }
 572
 573 void racer_die()
 574 {
 575     self.health       = 0;
 576     self.event_damage = SUB_Null;
 577     self.iscreature   = FALSE;
 578     self.solid        = SOLID_CORPSE;
 579     self.takedamage   = DAMAGE_NO;
 580     self.deadflag     = DEAD_DYING;
 581     self.movetype     = MOVETYPE_BOUNCE;
 582     self.wait         = time;
 583     self.cnt          = 1 + random() * 2;
 584     self.touch        = racer_deadtouch;
 585
 586     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 587
 588     if(random() < 0.5)
 589         self.avelocity_z  = 32;
 590     else
 591         self.avelocity_z  = -32;
 592
 593     self.avelocity_x = -vlen(self.velocity) * 0.2;
 594     self.velocity   += '0 0 700';
 595     self.colormod    = '-0.5 -0.5 -0.5';
 596
 597         self.think     = racer_blowup;
 598         self.nextthink = 2 + time + random() * 3;
 599 }
 600
 601 void racer_dinit()
 602 {
 603     if not (vehicle_initialize(
 604              "Wakizashi",
 605              "models/vehicles/wakizashi.dpm",
 606              "",
 607              "models/vehicles/wakizashi_cockpit.dpm",
 608              "", "", "tag_viewport",
 609              HUD_WAKIZASHI,
 610              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 611              FALSE,
 612              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 613              racer_frame,
 614              racer_enter, racer_exit,
 615              racer_die,   racer_think,
 616              TRUE))
 617     {
 618         remove(self);
 619         return;
 620     }
 621
 622     if(autocvar_g_vehicle_racer_hovertype != 0)
 623         racer_force_from_tag = vehicles_force_fromtag_maglev;
 624     else
 625         racer_force_from_tag = vehicles_force_fromtag_hover;
 626
 627     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 628     self.scale = 0.5;
 629     setattachment(self.vehicle_hudmodel, self, "");
 630     setattachment(self.vehicle_viewport, self, "tag_viewport");
 631
 632     self.mass               = 900;
 633 }
 634
 635 void spawnfunc_vehicle_racer()
 636 {
 637
 638     precache_sound ("weapons/laserimpact.wav");
 639     precache_sound ("weapons/lasergun_fire.wav");
 640     precache_sound ("weapons/rocket_fire.wav");
 641     precache_sound ("weapons/rocket_impact.wav");
 642
 643     precache_sound ("vehicles/racer_idle.wav");
 644     precache_sound ("vehicles/racer_move.wav");
 645     precache_sound ("vehicles/racer_boost.wav");
 646
 647     precache_model ("models/vhshield.md3");
 648     precache_model ("models/vehicles/wakizashi.dpm");
 649     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 650
 651     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 652     if(autocvar_g_vehicle_racer_energy)
 653         if(autocvar_g_vehicle_racer_energy_regen)
 654             self.vehicle_flags |= VHF_ENERGYREGEN;
 655
 656     if(autocvar_g_vehicle_racer_shield)
 657         self.vehicle_flags |= VHF_HASSHIELD;
 658
 659     if(autocvar_g_vehicle_racer_shield_regen)
 660         self.vehicle_flags |= VHF_SHIELDREGEN;
 661
 662     if(autocvar_g_vehicle_racer_health_regen)
 663         self.vehicle_flags |= VHF_HEALTHREGEN;
 664
 665     self.think = racer_dinit;
 666     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 667 }
 668 #endif // SVQC