qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 float autocvar_g_vehicle_raptor_bouncefactor;
  61 float autocvar_g_vehicle_raptor_bouncestop;
  62 vector autocvar_g_vehicle_raptor_bouncepain;
  63
  64 void raptor_spawn();
  65 float raptor_frame();
  66 float raptor_takeoff();
  67
  68 .entity bomb1;
  69 .entity bomb2;
  70
  71 float raptor_altitude(float amax)
  72 {
  73         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  74     return vlen(self.origin - trace_endpos);
  75 }
  76
  77
  78 void raptor_bomblet_boom()
  79 {
  80     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  81                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  82                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  83                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  84     remove(self);
  85 }
  86
  87 void raptor_bomblet_touch()
  88 {
  89     if(other == self.owner)
  90         return;
  91
  92     PROJECTILE_TOUCH;
  93     self.think = raptor_bomblet_boom;
  94     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  95 }
  96
  97 void raptor_bomb_burst()
  98 {
  99     if(self.cnt > time)
 100     if(autocvar_g_vehicle_raptor_bomblet_alt)
 101     {
 102         self.nextthink = time;
 103         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 104         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 105         {
 106             UpdateCSQCProjectile(self);
 107             return;
 108         }
 109     }
 110
 111     entity bomblet;
 112     float i;
 113
 114     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 115
 116     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 117     {
 118         bomblet = spawn();
 119         setorigin(bomblet, self.origin);
 120
 121         bomblet.movetype    = MOVETYPE_TOSS;
 122         bomblet.touch       = raptor_bomblet_touch;
 123         bomblet.think       = raptor_bomblet_boom;
 124         bomblet.nextthink   = time + 5;
 125         bomblet.owner       = self.owner;
 126         bomblet.realowner   = self.realowner;
 127         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 128
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bombdrop()
 137 {
 138     entity bomb_1, bomb_2;
 139
 140     bomb_1 = spawn();
 141     bomb_2 = spawn();
 142
 143     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 144     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 145
 146     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 147     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 148     bomb_1.touch        = bomb_2.touch      = raptor_bomb_burst;
 149     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 150     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 151
 152     if(autocvar_g_vehicle_raptor_bomblet_alt)
 153         bomb_1.nextthink = bomb_2.nextthink  = time;
 154     else
 155         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 156
 157     bomb_1.owner     = bomb_2.owner      = self;
 158     bomb_1.realowner = bomb_2.realowner  = self.owner;
 159     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 160     bomb_1.gravity   = bomb_2.gravity    = 1;
 161
 162     PROJECTILE_MAKETRIGGER(bomb_1);
 163     PROJECTILE_MAKETRIGGER(bomb_2);
 164
 165     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 166     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167 }
 168
 169
 170 void raptor_fire_cannon(entity gun, string tagname)
 171 {
 172     vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 173                            gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 174                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 175                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 176 }
 177
 178 void raptor_think()
 179 {
 180 }
 181
 182 void raptor_enter()
 183 {
 184     self.owner.PlayerPhysplug = raptor_takeoff;
 185     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 186     self.solid          = SOLID_SLIDEBOX;
 187     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 188     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 189     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 190     self.tur_head.exteriormodeltoclient = self.owner;
 191
 192     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 193     self.lip   = time;
 194
 195     if(self.owner.flagcarried)
 196        setorigin(self.owner.flagcarried, '-20 0 96');
 197
 198 }
 199
 200 void raptor_land()
 201 {
 202     float hgt;
 203
 204     hgt = raptor_altitude(512);
 205     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 206     self.angles_x *= 0.95;
 207     self.angles_z *= 0.95;
 208
 209     if(hgt < 128)
 210     if(hgt > 0)
 211         self.frame = (hgt / 128) * 25;
 212
 213     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 214     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 215
 216     if(hgt < 16)
 217     {
 218         self.movetype = MOVETYPE_TOSS;
 219         self.think    = raptor_think;
 220         self.frame    = 0;
 221     }
 222
 223     self.nextthink  = time;
 224 }
 225
 226 void raptor_exit(float eject)
 227 {
 228     vector spot;
 229     self.tur_head.exteriormodeltoclient = world;
 230
 231     if(self.deadflag == DEAD_NO)
 232     {
 233         self.think      = raptor_land;
 234         self.nextthink  = time;
 235     }
 236
 237     if not (self.owner)
 238         return;
 239
 240         makevectors(self.angles);
 241         if(eject)
 242         {
 243             spot = self.origin + v_forward * 100 + '0 0 64';
 244             spot = vehicles_findgoodexit(spot);
 245             setorigin(self.owner , spot);
 246             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 247         }
 248         else
 249         {
 250             self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed;
 251             self.owner.oldvelocity = self.owner.velocity;
 252             spot = self.origin - v_forward * 200 + '0 0 64';
 253             spot = vehicles_findgoodexit(spot);
 254             setorigin(self.owner , spot);
 255         }
 256         antilag_clear(self.owner);
 257     self.owner = world;
 258 }
 259
 260 float raptor_takeoff()
 261 {
 262     entity player, raptor;
 263
 264     player = self;
 265     raptor = self.vehicle;
 266     self   = raptor;
 267     if(self.sound_nexttime < time)
 268     {
 269         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 270         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 271     }
 272
 273     // Takeoff sequense
 274     if(raptor.frame < 25)
 275     {
 276         raptor.frame += 0.25;
 277         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 278         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 279         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 280         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 281
 282         setorigin(player, raptor.origin + '0 0 32');
 283     }
 284     else
 285         player.PlayerPhysplug = raptor_frame;
 286
 287     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 288         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 289
 290     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 291         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 292
 293     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 294         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 295
 296
 297     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 298     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 299
 300     VEHICLE_UPDATE_PLAYER(health, raptor);
 301     VEHICLE_UPDATE_PLAYER(energy, raptor);
 302     if(self.vehicle_flags & VHF_HASSHIELD)
 303         VEHICLE_UPDATE_PLAYER(shield, raptor);
 304
 305     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 306     self = player;
 307     return 1;
 308 }
 309
 310 float raptor_frame()
 311 {
 312     entity player, raptor;
 313     float ftmp, ftmp2;
 314     vector df;
 315
 316         if(intermission_running)
 317                 return 1;
 318
 319     player = self;
 320     raptor = self.vehicle;
 321     self   = raptor;
 322     vehicles_painframe();
 323     /*
 324     ftmp = vlen(self.velocity);
 325     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 326         ftmp = 1;
 327     else
 328         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 329     */
 330
 331     if(self.sound_nexttime < time)
 332     {
 333         self.sound_nexttime = time + 7.955812;
 334         //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 335         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 336         self.wait = ftmp;
 337     }
 338     /*
 339     else if(fabs(ftmp - self.wait) > 0.2)
 340     {
 341         sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTN_NORM );
 342         sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTN_NORM);
 343         self.wait = ftmp;
 344     }
 345     */
 346
 347     if(raptor.deadflag != DEAD_NO)
 348     {
 349         self = player;
 350         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 351         return 1;
 352     }
 353     crosshair_trace(player);
 354
 355     vector vang;
 356     vang = raptor.angles;
 357     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 358     vang_x *= -1;
 359     df_x *= -1;
 360     if(df_x > 180)  df_x -= 360;
 361     if(df_x < -180) df_x += 360;
 362     if(df_y > 180)  df_y -= 360;
 363     if(df_y < -180) df_y += 360;
 364
 365     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 366     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 367     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 368
 369     // Pitch
 370     ftmp = 0;
 371     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 372     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 373
 374     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 375     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 376     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 377
 378     raptor.angles_x = anglemods(raptor.angles_x);
 379     raptor.angles_y = anglemods(raptor.angles_y);
 380     raptor.angles_z = anglemods(raptor.angles_z);
 381
 382     if(autocvar_g_vehicle_raptor_movestyle == 1)
 383         makevectors('0 1 0' * raptor.angles_y);
 384     else
 385         makevectors(player.v_angle);
 386
 387     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 388
 389     if(player.movement_x != 0)
 390     {
 391         if(player.movement_x > 0)
 392             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 393         else if(player.movement_x < 0)
 394             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 395     }
 396
 397     if(player.movement_y != 0)
 398     {
 399         if(player.movement_y < 0)
 400             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 401         else if(player.movement_y > 0)
 402             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 403
 404         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 405     }
 406     else
 407     {
 408         raptor.angles_z *= 0.95;
 409         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 410             raptor.angles_z = 0;
 411     }
 412
 413     if(player.BUTTON_CROUCH)
 414         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 415     else if (player.BUTTON_JUMP)
 416         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 417
 418     raptor.velocity  += df * frametime;
 419     player.velocity = player.movement  = raptor.velocity;
 420     setorigin(player, raptor.origin + '0 0 32');
 421
 422     vector vf, ad;
 423     // Target lock & predict
 424     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 425     {
 426
 427         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 428                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 429                              autocvar_g_vehicle_raptor_cannon_locked_time);
 430
 431         if(self.lock_target != world)
 432         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 433         if(self.lock_strength == 1)
 434         {
 435             float i, distance, impact_time;
 436
 437             vf = real_origin(raptor.lock_target);
 438             ad = vf;
 439             for(i = 0; i < 4; ++i)
 440             {
 441                 distance = vlen(ad - raptor.origin);
 442                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 443                 ad = vf + raptor.lock_target.velocity * impact_time;
 444             }
 445             trace_endpos = ad;
 446         }
 447
 448         if(self.lock_target)
 449         {
 450             if(raptor.lock_strength == 1)
 451                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 452             else if(self.lock_strength > 0.5)
 453                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 454             else if(self.lock_strength < 0.5)
 455                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 456         }
 457     }
 458
 459     // Aim the gunz
 460     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 461     ftmp = -ftmp2;
 462
 463     // Gun1
 464     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 465     //ad = df;
 466     //vf = v_forward;
 467     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 468     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun1.angles;
 469     df = shortangle_vxy(df, raptor.gun1.angles);
 470
 471     // Bind to aimspeed
 472     df_x = bound(ftmp, df_x, ftmp2);
 473     df_y = bound(ftmp, df_y, ftmp2);
 474     // Bind to limts
 475     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 476     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 477
 478     // Gun2
 479     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 480     //ad += df;
 481     //vf += v_forward;
 482     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 483     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun2.angles;
 484     df = shortangle_vxy(df, raptor.gun2.angles);
 485
 486     // Bind to aimspeed
 487     df_x = bound(ftmp, df_x, ftmp2);
 488     df_y = bound(ftmp, df_y, ftmp2);
 489     // Bind to limts
 490     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 491     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 492
 493     /*
 494     ad = ad * 0.5;
 495     v_forward = vf * 0.5;
 496     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 497     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 498     */
 499
 500     if(player.BUTTON_ATCK)
 501     if(raptor.attack_finished_single <= time)
 502     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 503     {
 504         raptor.misc_bulletcounter += 1;
 505         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 506         if(raptor.misc_bulletcounter <= 2)
 507             raptor_fire_cannon(self.gun1, "fire1");
 508         else if(raptor.misc_bulletcounter == 3)
 509             raptor_fire_cannon(self.gun2, "fire1");
 510         else
 511         {
 512             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 513             raptor_fire_cannon(self.gun2, "fire1");
 514             raptor.misc_bulletcounter = 0;
 515         }
 516         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 517         self.cnt = time;
 518     }
 519
 520     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 521         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 522
 523     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 524         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 525
 526     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 527         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 528
 529
 530     if(time > raptor.delay)
 531     if(player.BUTTON_ATCK2)
 532     {
 533         raptor_bombdrop();
 534         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 535         raptor.lip   = time;
 536     }
 537
 538     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 539     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 540
 541     VEHICLE_UPDATE_PLAYER(health, raptor);
 542     VEHICLE_UPDATE_PLAYER(energy, raptor);
 543     if(self.vehicle_flags & VHF_HASSHIELD)
 544         VEHICLE_UPDATE_PLAYER(shield, raptor);
 545
 546     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 547
 548     self = player;
 549     return 1;
 550 }
 551
 552 void raptor_blowup()
 553 {
 554     self.deadflag    = DEAD_DEAD;
 555     self.vehicle_exit(VHEF_NORMAL);
 556     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 557
 558     self.alpha          = -1;
 559     self.movetype       = MOVETYPE_NONE;
 560     self.effects        = EF_NODRAW;
 561     self.colormod       = '0 0 0';
 562     self.avelocity      = '0 0 0';
 563     self.velocity       = '0 0 0';
 564
 565     setorigin(self, self.pos1);
 566     self.touch = SUB_Null;
 567     self.nextthink = 0;
 568 }
 569
 570 void raptor_diethink()
 571 {
 572     if(random() < 0.1)
 573     {
 574         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 575         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 576     }
 577     self.nextthink = time + 0.1;
 578 }
 579
 580 void raptor_die()
 581 {
 582     self.health       = 0;
 583     self.event_damage = SUB_Null;
 584     self.solid        = SOLID_CORPSE;
 585     self.takedamage   = DAMAGE_NO;
 586     self.deadflag     = DEAD_DYING;
 587     self.movetype     = MOVETYPE_BOUNCE;
 588     self.think        = raptor_diethink;
 589     self.nextthink    = time;
 590
 591     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 592
 593     self.velocity_z += 600;
 594
 595     self.avelocity = '0 0.5 1' * (random() * 400);
 596     self.avelocity -= '0 0.5 1' * (random() * 400);
 597
 598     self.colormod = '-0.5 -0.5 -0.5';
 599         self.touch     = raptor_blowup;
 600 }
 601
 602 void raptor_impact()
 603 {
 604     if(autocvar_g_vehicle_raptor_bouncepain_x)
 605         vehilces_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 606 }
 607
 608 void raptor_spawn()
 609 {
 610     self.frame          = 0;
 611     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 612     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 613     self.movetype       = MOVETYPE_TOSS;
 614     self.solid          = SOLID_SLIDEBOX;
 615     self.vehicle_energy = 1;
 616
 617     self.bomb1.gun1.avelocity_y = 90;
 618     self.bomb1.gun2.avelocity_y = -90;
 619
 620     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 621     self.delay = time;
 622
 623     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 624     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 625     self.vehicle_impact = raptor_impact;
 626 }
 627
 628 // If we dont do this ever now and then, the raptors rotors
 629 // stop working, presumably due to angle overflow. cute.
 630 void raptor_rotor_anglefix()
 631 {
 632     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 633     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 634     self.nextthink = time + 15;
 635 }
 636
 637 void raptor_dinit()
 638 {
 639     entity spinner;
 640     vector ofs;
 641
 642     if not (vehicle_initialize(
 643              "Raptor",
 644              "models/vehicles/raptor.dpm",
 645              "",
 646              "models/vehicles/raptor_cockpit.dpm",
 647              "", "tag_hud", "tag_camera",
 648              HUD_RAPTOR,
 649              RAPTOR_MIN, RAPTOR_MAX,
 650              FALSE,
 651              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 652              raptor_frame,
 653              raptor_enter, raptor_exit,
 654              raptor_die,   raptor_think,
 655              FALSE))
 656     {
 657         remove(self);
 658         return;
 659     }
 660
 661     //FIXME: Camera is in a bad place in HUD model.
 662     //setorigin(self.vehicle_viewport, '25 0 5');
 663
 664     self.frame = 0;
 665
 666     self.bomb1 = spawn();
 667     self.bomb2 = spawn();
 668     self.gun1  = spawn();
 669     self.gun2  = spawn();
 670
 671     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 672     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 673     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 674     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 675     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 676
 677     setattachment(self.bomb1, self,"bombmount_left");
 678     setattachment(self.bomb2, self,"bombmount_right");
 679     setattachment(self.tur_head, self,"root");
 680
 681
 682     // FIXME Guns mounts to angled bones
 683     self.bomb1.angles = self.angles;
 684     self.angles = '0 0 0';
 685     // This messes up gun-aim, so work arround it.
 686     //setattachment(self.gun1, self, "gunmount_left");
 687     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 688     ofs -= self.origin;
 689     setattachment(self.gun1, self, "");
 690     setorigin(self.gun1, ofs);
 691
 692     //setattachment(self.gun2, self, "gunmount_right");
 693     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 694     ofs -= self.origin;
 695     setattachment(self.gun2, self, "");
 696     setorigin(self.gun2, ofs);
 697
 698     self.angles = self.bomb1.angles;
 699     self.bomb1.angles = '0 0 0';
 700
 701     spinner = spawn();
 702     spinner.owner = self;
 703     setmodel(spinner,"models/vehicles/spinner.dpm");
 704     setattachment(spinner, self, "engine_left");
 705     spinner.movetype = MOVETYPE_NOCLIP;
 706     spinner.avelocity = '0 90 0';
 707     self.bomb1.gun1 = spinner;
 708
 709     spinner = spawn();
 710     spinner.owner = self;
 711     setmodel(spinner,"models/vehicles/spinner.dpm");
 712     setattachment(spinner, self, "engine_right");
 713     spinner.movetype = MOVETYPE_NOCLIP;
 714     spinner.avelocity = '0 -90 0';
 715     self.bomb1.gun2 = spinner;
 716
 717     // Sigh.
 718     self.bomb1.think = raptor_rotor_anglefix;
 719     self.bomb1.nextthink = time;
 720
 721     self.mass               = 1 ;
 722 }
 723
 724 void spawnfunc_vehicle_raptor()
 725 {
 726     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 727
 728     self.vehicle_flags |= VHF_DMGSHAKE;
 729     self.vehicle_flags |= VHF_DMGROLL;
 730
 731     if(autocvar_g_vehicle_raptor_shield)
 732         self.vehicle_flags |= VHF_HASSHIELD;
 733
 734     if(autocvar_g_vehicle_raptor_shield_regen)
 735         self.vehicle_flags |= VHF_SHIELDREGEN;
 736
 737     if(autocvar_g_vehicle_raptor_health_regen)
 738         self.vehicle_flags |= VHF_HEALTHREGEN;
 739
 740     if(autocvar_g_vehicle_raptor_energy_regen)
 741         self.vehicle_flags |= VHF_ENERGYREGEN;
 742
 743     precache_model ("models/vehicles/raptor.dpm");
 744     precache_model ("models/vehicles/raptor_gun.dpm");
 745     precache_model ("models/vehicles/spinner.dpm");
 746     precache_model ("models/vehicles/raptor_cockpit.dpm");
 747     //precache_model ("models/vehicles/clusterbomb.md3");
 748     precache_model ("models/vehicles/clusterbomb_folded.md3");
 749     precache_model ("models/vehicles/raptor_body.dpm");
 750
 751     precache_sound ("vehicles/raptor_fly.wav");
 752     precache_sound ("vehicles/raptor_speed.wav");
 753
 754     self.think = raptor_dinit;
 755
 756     if(g_assault)
 757         self.nextthink = time + 0.5;
 758     else
 759         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 760 }
 761 #endif // SVQC