qcsrc/server/vote.qc

   1 float VoteCheckNasty(string cmd)
   2 {
   3         if(strstrofs(cmd, ";", 0) >= 0)
   4                 return TRUE;
   5         if(strstrofs(cmd, "\n", 0) >= 0)
   6                 return TRUE;
   7         if(strstrofs(cmd, "\r", 0) >= 0)
   8                 return TRUE;
   9         if(strstrofs(cmd, "$", 0) >= 0)
  10                 return TRUE;
  11         return FALSE;
  12 }
  13
  14 string GetKickVoteVictim_newcommand;
  15 string GetKickVoteVictim_reason;
  16
  17 entity GetKickVoteVictim(string vote, string cmd, entity caller)
  18 {
  19         float tokens;
  20         string ns;
  21         entity e;
  22         string reason;
  23
  24         tokens = tokenize_console(vote);
  25         ns = "";
  26
  27         e = GetCommandPlayerSlotTargetFromTokenizedCommand(tokens, 1);
  28         if(e)
  29         {
  30                 if(ParseCommandPlayerSlotTarget_firsttoken < tokens)
  31                         GetKickVoteVictim_reason = substring(vote, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken));
  32                 else
  33                         GetKickVoteVictim_reason = "";
  34
  35                 reason = "";
  36                 if(cmd != "vdo" || GetKickVoteVictim_reason == "")
  37                         reason = "~"; // by convention, ~ prefixes a "unverified" kickban which will not be networked
  38
  39                 if(substring(GetKickVoteVictim_reason, 0, 1) == "~")
  40                 {
  41                         reason = "~";
  42                         GetKickVoteVictim_reason = substring(GetKickVoteVictim_reason, 1, strlen(GetKickVoteVictim_reason) - 1);
  43                 }
  44
  45                 if(caller)
  46                         reason = strcat(reason, "player ", strdecolorize(caller.netname));
  47                 else
  48                         reason = strcat(reason, "console vote");
  49                 if(GetKickVoteVictim_reason != "")
  50                         reason = strcat(reason, ": ", strdecolorize(GetKickVoteVictim_reason));
  51
  52                 if not(cvar_value_issafe(reason))
  53                         reason = uri_escape(reason);
  54
  55                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ftos(num_for_edict(e)));
  56                 if(argv(0) == "kickban")
  57                 {
  58                         GetKickVoteVictim_newcommand = strcat(GetKickVoteVictim_newcommand, " ", ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ", reason);
  59                 }
  60                 else if(argv(0) == "kick")
  61                 {
  62                         GetKickVoteVictim_newcommand = strcat(GetKickVoteVictim_newcommand, " ", reason);
  63                 }
  64                 return e;
  65         }
  66
  67         print_to(caller, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
  68         return world;
  69 }
  70
  71 string RemapVote_display;
  72 string RemapVote_vote;
  73 float RemapVote(string vote, string cmd, entity e)
  74 {
  75         float vote_argc;
  76         entity victim;
  77         vote_argc = tokenize_console(vote);
  78
  79         if(!VoteAllowed(argv(0), cmd))
  80                 return FALSE;
  81
  82         // VoteAllowed tokenizes!
  83         vote_argc = tokenize_console(vote);
  84
  85         // remap chmap to gotomap (forces intermission)
  86         if(vote_argc < 2)
  87                 if(argv(0) == "chmap" || argv(0) == "gotomap" || argv(0) == "kick" || argv(0) == "kickban") // won't work without arguments
  88                         return FALSE;
  89         if(argv(0) == "chmap")
  90         {
  91                 vote = strcat("gotomap ", substring(vote, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  92                 vote_argc = tokenize_console(vote);
  93         }
  94         if(argv(0) == "gotomap")
  95         {
  96                 if(!(vote = ValidateMap(substring(vote, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), e)))
  97                         return FALSE;
  98                 vote = strcat("gotomap ", vote);
  99                 vote_argc = tokenize_console(vote); // ValidateMap may have done some stuff to it
 100         }
 101
 102         // make kick and kickban votes a bit nicer (and reject them if formatted badly)
 103         if(argv(0) == "kick" || argv(0) == "kickban")
 104         {
 105                 if(!(victim = GetKickVoteVictim(vote, cmd, e)))
 106                         return FALSE;
 107                 RemapVote_vote = GetKickVoteVictim_newcommand;
 108                 RemapVote_display = strcat("^1", vote, " (^7", victim.netname, "^1): ", GetKickVoteVictim_reason);
 109         }
 110         else
 111         {
 112                 RemapVote_vote = vote;
 113                 RemapVote_display = strzone(strcat("^1", vote));
 114         }
 115
 116         return TRUE;
 117 }
 118
 119 float GameCommand_Vote(string s, entity e) {
 120         local float playercount;
 121         float argc;
 122         argc = tokenize_console(s);
 123         if(argv(0) == "help") {
 124                 print_to(e, "  vote COMMANDS ARGUMENTS. See 'vhelp' for more info.");
 125                 return TRUE;
 126         } else if(argv(0) == "vote") {
 127                 if(argv(1) == "") {
 128                         print_to(e, "^1You have to supply a vote command. See 'vhelp' for more info.");
 129                 } else if(argv(1) == "help") {
 130                         VoteHelp(e);
 131                 } else if(argv(1) == "status") {
 132                         if(votecalled) {
 133                                 print_to(e, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", VoteNetname(votecaller), "^7."));
 134                         } else {
 135                                 print_to(e, "^1No vote called.");
 136                         }
 137                 } else if(argv(1) == "call") {
 138                         if(!e || autocvar_sv_vote_call) {
 139                                 if(autocvar_sv_vote_nospectators && e && e.classname != "player") {
 140                                         print_to(e, "^1Error: Only players can call a vote."); // TODO invent a cvar name for allowing votes by spectators during warmup anyway
 141                                 }
 142                                 else if(timeoutStatus) { //don't allow a vote call during a timeout
 143                                         print_to(e, "^1Error: You can not call a vote while a timeout is active.");
 144                                 }
 145                                 else if(votecalled) {
 146                                         print_to(e, "^1There is already a vote called.");
 147                                 } else {
 148                                         local string vote;
 149                                         vote = VoteParse(s, argc);
 150                                         if(vote == "") {
 151                                                 print_to(e, "^1Your vote is empty. See 'vhelp' for more info.");
 152                                         } else if(e
 153                                                         && time < e.vote_next) {
 154                                                 print_to(e, strcat("^1You have to wait ^2", ftos(ceil(e.vote_next - time)), "^1 seconds before you can again call a vote."));
 155                                         } else if(VoteCheckNasty(vote)) {
 156                                                 print_to(e, "Syntax error in command. See 'vhelp' for more info.");
 157                                         } else if(RemapVote(vote, "vcall", e)) {
 158                                                 votecalledvote = strzone(RemapVote_vote);
 159                                                 votecalledvote_display = strzone(RemapVote_display);
 160                                                 votecalled = TRUE;
 161                                                 votecalledmaster = FALSE;
 162                                                 votefinished = time + autocvar_sv_vote_timeout;
 163                                                 votecaller = e; // remember who called the vote
 164                                                 if(e) {
 165                                                         e.vote_vote = 1; // of course you vote yes
 166                                                         e.vote_next = time + autocvar_sv_vote_wait;
 167                                                 }
 168                                                 bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote for ", votecalledvote_display, "\n");
 169                                                 if(autocvar_sv_eventlog)
 170                                                         GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display));
 171                                                 Nagger_VoteChanged();
 172                                                 VoteCount(); // needed if you are the only one
 173                                                 msg_entity = e;
 174
 175                                                 local entity player;
 176                                                 FOR_EACH_REALCLIENT(player)
 177                                                 {
 178                                                         ++playercount;
 179                                                 }
 180                                                 if(playercount > 1) // don't announce a "vote now" sound if player is alone
 181                                                         Announce("votecall");
 182                                         } else {
 183                                                 print_to(e, "^1This vote is not ok. See 'vhelp' for more info.");
 184                                         }
 185                                 }
 186                         } else {
 187                                 print_to(e, "^1Vote calling is NOT allowed.");
 188                         }
 189                 } else if(argv(1) == "stop") {
 190                         if(!votecalled) {
 191                                 print_to(e, "^1No vote called.");
 192                         } else if(e == votecaller) { // the votecaller can stop a vote
 193                                 VoteStop(e);
 194                         } else if(!e) { // server admin / console can too
 195                                 VoteStop(e);
 196                         } else if(e.vote_master) { // masters can too
 197                                 VoteStop(e);
 198                         } else {
 199                                 print_to(e, "^1You are not allowed to stop that Vote.");
 200                         }
 201                 } else if(argv(1) == "master") {
 202                         if(autocvar_sv_vote_master) {
 203                                 if(votecalled) {
 204                                         print_to(e, "^1There is already a vote called.");
 205                                 } else {
 206                                         votecalled = TRUE;
 207                                         votecalledmaster = TRUE;
 208                                         votecalledvote = strzone("XXX");
 209                                         votecalledvote_display = strzone("^3master");
 210                                         votefinished = time + autocvar_sv_vote_timeout;
 211                                         votecaller = e; // remember who called the vote
 212                                         if(e) {
 213                                                 e.vote_vote = 1; // of course you vote yes
 214                                                 e.vote_next = time + autocvar_sv_vote_wait;
 215                                         }
 216                                         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote to become ^3master^2.\n");
 217                                         if(autocvar_sv_eventlog)
 218                                                 GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display));
 219                                         Nagger_VoteChanged();
 220                                         VoteCount(); // needed if you are the only one
 221                                 }
 222                         } else {
 223                                 print_to(e, "^1Vote to become master is NOT allowed.");
 224                         }
 225                 } else if(argv(1) == "do") {
 226                         if(!e || e.vote_master) {
 227                                 local string dovote;
 228                                 dovote = VoteParse(s, argc);
 229                                 if(dovote == "") {
 230                                         print_to(e, "^1Your command was empty. See 'vhelp' for more info.");
 231                                 } else if(VoteCheckNasty(dovote)) {
 232                                         print_to(e, "Syntax error in command. See 'vhelp' for more info.");
 233                                 } else if(RemapVote(dovote, "vdo", e)) { // strcat seems to be necessary
 234                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 used their ^3master^2 status to do \"^2", RemapVote_display, "^2\".\n");
 235                                         if(autocvar_sv_eventlog)
 236                                                 GameLogEcho(strcat(":vote:vdo:", ftos(e.playerid), ":", RemapVote_display));
 237                                         localcmd(strcat(RemapVote_vote, "\n"));
 238                                 } else {
 239                                         print_to(e, "^1This command is not ok. See 'vhelp' for more info.");
 240                                 }
 241                         } else {
 242                                 print_to(e, "^1You are NOT a master.  You might need to login or vote to become master first. See 'vhelp' for more info.");
 243                         }
 244                 } else if(argv(1) == "login") {
 245                         local string masterpwd;
 246                         masterpwd = autocvar_sv_vote_master_password;
 247                         if(masterpwd != "") {
 248                                 local float granted;
 249                                 granted = (masterpwd == argv(2));
 250                                 if (e)
 251                                         e.vote_master = granted;
 252                                 if(granted) {
 253                                         print("Accepted master login from ", VoteNetname(e), "\n");
 254                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 logged in as ^3master^2\n");
 255                                         if(autocvar_sv_eventlog)
 256                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(e.playerid)));
 257                                 }
 258                                 else
 259                                         print("REJECTED master login from ", VoteNetname(e), "\n");
 260                         }
 261                         else
 262                                 print_to(e, "^1Login to become master is NOT allowed.");
 263                 } else if(argv(1) == "yes") {
 264                         if(!votecalled) {
 265                                 print_to(e, "^1No vote called.");
 266                         } else if (!e) {
 267                                 print_to(e, "^1You can't vote from the server console.");
 268                         } else if(e.vote_vote == 0
 269                                   || autocvar_sv_vote_change) {
 270                                 msg_entity = e;
 271                                 print_to(e, "^1You accepted the vote.");
 272                                 e.vote_vote = 1;
 273                                 if(!autocvar_sv_vote_singlecount) {
 274                                         VoteCount();
 275                                 }
 276                         } else {
 277                                 print_to(e, "^1You have already voted.");
 278                         }
 279                 } else if(argv(1) == "no") {
 280                         if(!votecalled) {
 281                                 print_to(e, "^1No vote called.");
 282                         } else if (!e) {
 283                                 print_to(e, "^1You can't vote from the server console.");
 284                         } else if(e.vote_vote == 0
 285                                   || autocvar_sv_vote_change) {
 286                                 msg_entity = e;
 287                                 print_to(e, "^1You rejected the vote.");
 288                                 e.vote_vote = -1;
 289                                 if(!autocvar_sv_vote_singlecount) {
 290                                         VoteCount();
 291                                 }
 292                         } else {
 293                                 print_to(e, "^1You have already voted.");
 294                         }
 295                 } else if(argv(1) == "abstain" || argv(1) == "dontcare") {
 296                         if(!votecalled) {
 297                                 print_to(e, "^1No vote called.");
 298                         } else if (!e) {
 299                                 print_to(e, "^1You can't vote from the server console.");
 300                         } else if(e.vote_vote == 0
 301                                   || autocvar_sv_vote_change) {
 302                                 msg_entity = e;
 303                                 print_to(e, "^1You abstained from your vote.");
 304                                 e.vote_vote = -2;
 305                                 if(!autocvar_sv_vote_singlecount) {
 306                                         VoteCount();
 307                                 }
 308                         } else {
 309                                 print_to(e, "^1You have already voted.");
 310                         }
 311                 } else {
 312                         // ignore this?
 313                         print_to(e, "^1Unknown vote command.");
 314                 }
 315                 return TRUE;
 316         }
 317         return FALSE;
 318 }
 319
 320 void VoteHelp(entity e) {
 321         local string vmasterdis;
 322         if(!autocvar_sv_vote_master) {
 323                 vmasterdis = " ^1(disabled)";
 324         }
 325
 326         local string vlogindis;
 327         if("" == autocvar_sv_vote_master_password) {
 328                 vlogindis = " ^1(disabled)";
 329         }
 330
 331         local string vcalldis;
 332         if(!autocvar_sv_vote_call) {
 333                 vcalldis = " ^1(disabled)";
 334         }
 335
 336         print_to(e, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote login^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\" \"^2cmd vote abstain^7\" \"^2cmd vote dontcare^7\".");
 337         print_to(e, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vlogin^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\" \"^2abstain^7\" \"^2vdontcare^7\".");
 338         print_to(e, "^7\"^2help^7\" shows this info.");
 339         print_to(e, "^7\"^2status^7\" shows if there is a vote called and who called it.");
 340         print_to(e, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7"));
 341         print_to(e, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.");
 342         print_to(e, strcat("^7\"^2master^7\" call a vote to become master who can execute commands without a vote", vmasterdis, "^7"));
 343         print_to(e, strcat("^7\"^2login^7\" login to become master who can execute commands without a vote.", vlogindis, "^7"));
 344         print_to(e, "^7\"^2do^7\" executes a command if you are a master. See the list of allowed commands.");
 345         print_to(e, "^7\"^2yes^7\", \"^2no^7\", \"^2abstain^7\" and \"^2dontcare^7\" to make your vote.");
 346         print_to(e, "^7If enough of the players vote yes the vote is accepted.");
 347         print_to(e, "^7If enough of the players vote no the vote is rejected.");
 348         print_to(e, strcat("^7If neither the vote will timeout after ", ftos(autocvar_sv_vote_timeout), "^7 seconds."));
 349         print_to(e, "^7You can call a vote for or execute these commands:");
 350         print_to(e, strcat("^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 351 }
 352
 353 string VoteNetname(entity e)
 354 {
 355         if(e) {
 356                 return e.netname;
 357         } else {
 358                 if(autocvar_sv_adminnick != "") {
 359                         return autocvar_sv_adminnick;
 360                 } else {
 361                         return autocvar_hostname;
 362                 }
 363         }
 364 }
 365
 366 string ValidateMap(string m, entity e)
 367 {
 368         m = MapInfo_FixName(m);
 369         if(!m)
 370         {
 371                 print_to(e, "This map is not available on this server.");
 372                 return string_null;
 373         }
 374         if(!autocvar_sv_vote_override_mostrecent)
 375                 if(Map_IsRecent(m))
 376                 {
 377                         print_to(e, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 378                         return string_null;
 379                 }
 380         if(!MapInfo_CheckMap(m))
 381         {
 382                 print_to(e, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode."));
 383                 return string_null;
 384         }
 385
 386         return m;
 387 }
 388
 389
 390 void VoteThink() {
 391         if(votefinished > 0) // a vote was called
 392         if(time > votefinished) // time is up
 393         {
 394                 VoteCount();
 395         }
 396 }
 397
 398 string VoteParse(string all, float argc) {
 399         if(argc < 3)
 400                 return "";
 401         return substring(all, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 402 }
 403
 404 float VoteCommandInList(string votecommand, string list)
 405 {
 406         string l;
 407         l = strcat(" ", list, " ");
 408
 409         if(strstrofs(l, strcat(" ", votecommand, " "), 0) >= 0)
 410                 return TRUE;
 411
 412         // if gotomap is allowed, chmap is too, and vice versa
 413         if(votecommand == "gotomap")
 414                 if(strstrofs(l, " chmap ", 0) >= 0)
 415                         return TRUE;
 416         if(votecommand == "chmap")
 417                 if(strstrofs(l, " gotomap ", 0) >= 0)
 418                         return TRUE;
 419
 420         return FALSE;
 421 }
 422
 423 float VoteAllowed(string votecommand, string cmd) {
 424         if(VoteCommandInList(votecommand, autocvar_sv_vote_commands))
 425                 return TRUE;
 426
 427         if(cmd == "vdo")
 428         {
 429                 if(VoteCommandInList(votecommand, autocvar_sv_vote_master_commands))
 430                         return TRUE;
 431         }
 432         else
 433         {
 434                 if(VoteCommandInList(votecommand, autocvar_sv_vote_only_commands))
 435                         return TRUE;
 436         }
 437
 438         return FALSE;
 439 }
 440
 441 void VoteReset() {
 442         local entity player;
 443
 444         FOR_EACH_CLIENT(player)
 445         {
 446                 player.vote_vote = 0;
 447         }
 448
 449         if(votecalled)
 450         {
 451                 strunzone(votecalledvote);
 452                 strunzone(votecalledvote_display);
 453         }
 454
 455         votecalled = FALSE;
 456         votecalledmaster = FALSE;
 457         votefinished = 0;
 458         votecalledvote = string_null;
 459         votecalledvote_display = string_null;
 460
 461         Nagger_VoteChanged();
 462 }
 463
 464 void VoteAccept() {
 465         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
 466         if(votecalledmaster)
 467         {
 468                 if(votecaller) {
 469                         votecaller.vote_master = 1;
 470                 }
 471         } else {
 472                 localcmd(strcat(votecalledvote, "\n"));
 473         }
 474         if(votecaller) {
 475                 votecaller.vote_next = 0; // people like your votes,
 476                                           // no wait for next vote
 477         }
 478         VoteReset();
 479         Announce("voteaccept");
 480 }
 481
 482 void VoteReject() {
 483         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
 484         VoteReset();
 485         Announce("votefail");
 486 }
 487
 488 void VoteTimeout() {
 489         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 timed out\n");
 490         VoteReset();
 491         Announce("votefail");
 492 }
 493
 494 void VoteStop(entity stopper) {
 495         bprint("\{1}^2* ^3", VoteNetname(stopper), "^2 stopped ^3", VoteNetname(votecaller), "^2's vote\n");
 496         if(autocvar_sv_eventlog)
 497                 GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 498         if(stopper == votecaller) {
 499                 // no wait for next vote so you can correct your vote
 500                 if(votecaller) {
 501                         votecaller.vote_next = time + autocvar_sv_vote_stop;
 502                 }
 503         }
 504         VoteReset();
 505 }
 506
 507 void VoteSpam(float notvoters, float mincount, string result)
 508 {
 509         string s;
 510         if(mincount >= 0)
 511         {
 512                 s = strcat("\{1}^2* vote results: ^1", ftos(vote_yescount), "^2:^1");
 513                 s = strcat(s, ftos(vote_nocount), "^2 (^1");
 514                 s = strcat(s, ftos(mincount), "^2 needed), ^1");
 515                 s = strcat(s, ftos(vote_abstaincount), "^2 didn't care, ^1");
 516                 s = strcat(s, ftos(notvoters), "^2 didn't vote\n");
 517         }
 518         else
 519         {
 520                 s = strcat("\{1}^2* vote results: ^1", ftos(vote_yescount), "^2:^1");
 521                 s = strcat(s, ftos(vote_nocount), "^2, ^1");
 522                 s = strcat(s, ftos(vote_abstaincount), "^2 didn't care, ^1");
 523                 s = strcat(s, ftos(notvoters), "^2 didn't have to vote\n");
 524         }
 525         bprint(s);
 526         if(autocvar_sv_eventlog)
 527         {
 528                 s = strcat(":vote:v", result, ":", ftos(vote_yescount));
 529                 s = strcat(s, ":", ftos(vote_nocount));
 530                 s = strcat(s, ":", ftos(vote_abstaincount));
 531                 s = strcat(s, ":", ftos(notvoters));
 532                 s = strcat(s, ":", ftos(mincount));
 533                 GameLogEcho(s);
 534         }
 535 }
 536
 537 void VoteCount() {
 538         local float playercount;
 539         playercount = 0;
 540         vote_yescount = 0;
 541         vote_nocount = 0;
 542         vote_abstaincount = 0;
 543         local entity player;
 544         //same for real players
 545         local float realplayercount;
 546         local float realplayeryescount;
 547         local float realplayernocount;
 548         local float realplayerabstaincount;
 549         realplayercount = realplayernocount = realplayerabstaincount = realplayeryescount = 0;
 550
 551         Nagger_VoteCountChanged();
 552
 553         FOR_EACH_REALCLIENT(player)
 554         {
 555                 if(player.vote_vote == -1) {
 556                         ++vote_nocount;
 557                 } else if(player.vote_vote == 1) {
 558                         ++vote_yescount;
 559                 } else if(player.vote_vote == -2) {
 560                         ++vote_abstaincount;
 561                 }
 562                 ++playercount;
 563                 //do the same for real players
 564                 if(player.classname == "player") {
 565                         if(player.vote_vote == -1) {
 566                                 ++realplayernocount;
 567                         } else if(player.vote_vote == 1) {
 568                                 ++realplayeryescount;
 569                         } else if(player.vote_vote == -2) {
 570                                 ++realplayerabstaincount;
 571                         }
 572                         ++realplayercount;
 573                 }
 574         }
 575
 576         //in tournament mode, if we have at least one player then don't make the vote dependent on spectators (so specs don't have to press F1)
 577         if(autocvar_sv_vote_nospectators)
 578         if(realplayercount > 0) {
 579                 vote_yescount = realplayeryescount;
 580                 vote_nocount = realplayernocount;
 581                 vote_abstaincount = realplayerabstaincount;
 582                 playercount = realplayercount;
 583         }
 584
 585         float votefactor, simplevotefactor;
 586         votefactor = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 587         simplevotefactor = autocvar_sv_vote_simple_majority_factor;
 588
 589         // FIXME this number is a guess
 590         vote_needed_absolute = floor((playercount - vote_abstaincount) * votefactor) + 1;
 591         if(simplevotefactor)
 592         {
 593                 simplevotefactor = bound(votefactor, simplevotefactor, 0.999);
 594                 vote_needed_simple = floor((vote_yescount + vote_nocount) * simplevotefactor) + 1;
 595         }
 596         else
 597                 vote_needed_simple = 0;
 598
 599         if(votecalledmaster
 600            && playercount == 1) {
 601                 // if only one player is on the server becoming vote
 602                 // master is not allowed.  This could be used for
 603                 // trolling or worse. 'self' is the user who has
 604                 // called the vote because this function is called
 605                 // by SV_ParseClientCommand. Maybe all voting should
 606                 // be disabled for a single player?
 607                 print_to(votecaller, "^1You are the only player on this server so you can not become vote master.");
 608                 if(votecaller) {
 609                         votecaller.vote_next = 0;
 610                 }
 611                 VoteReset();
 612         } else {
 613                 if(vote_yescount >= vote_needed_absolute)
 614                 {
 615                         VoteSpam(playercount - vote_yescount - vote_nocount - vote_abstaincount, -1, "yes");
 616                         VoteAccept();
 617                 }
 618                 else if(vote_nocount > playercount - vote_abstaincount - vote_needed_absolute) // that means, vote_yescount cannot reach vote_needed_absolute any more
 619                 {
 620                         VoteSpam(playercount - vote_yescount - vote_nocount - vote_abstaincount, -1, "no");
 621                         VoteReject();
 622                 }
 623                 else if(time > votefinished)
 624                 {
 625                         if(simplevotefactor)
 626                         {
 627                                 string result;
 628                                 if(vote_yescount >= vote_needed_simple)
 629                                         result = "yes";
 630                                 else if(vote_yescount + vote_nocount > 0)
 631                                         result = "no";
 632                                 else
 633                                         result = "timeout";
 634                                 VoteSpam(playercount - vote_yescount - vote_nocount - vote_abstaincount, min(vote_needed_absolute, vote_needed_simple), result);
 635                                 if(result == "yes")
 636                                         VoteAccept();
 637                                 else if(result == "no")
 638                                         VoteReject();
 639                                 else
 640                                         VoteTimeout();
 641                         }
 642                         else
 643                         {
 644                                 VoteSpam(playercount - vote_yescount - vote_nocount - vote_abstaincount, vote_needed_absolute, "timeout");
 645                                 VoteTimeout();
 646                         }
 647                 }
 648         }
 649 }